qcsrc/common/vehicles/vehicle/raptor.qc

   1 #ifndef VEHICLE_RAPTOR
   2 #define VEHICLE_RAPTOR
   3 #include "raptor.qh"
   4
   5 #include "raptor_weapons.qh"
   6
   7 CLASS(Raptor, Vehicle)
   8 /* spawnflags */ ATTRIB(Raptor, spawnflags, int, VHF_DMGSHAKE | VHF_DMGROLL);
   9 /* mins       */ ATTRIB(Raptor, mins, vector, '-80 -80 0');
  10 /* maxs       */ ATTRIB(Raptor, maxs, vector, '80 80 70');
  11 /* view offset*/ ATTRIB(Raptor, view_ofs, vector, '0 0 160');
  12 /* view dist  */ ATTRIB(Raptor, height, float, 200);
  13 /* model          */ ATTRIB(Raptor, mdl, string, "models/vehicles/raptor.dpm");
  14 /* model          */ ATTRIB(Raptor, model, string, "models/vehicles/raptor.dpm");
  15 /* head_model */ ATTRIB(Raptor, head_model, string, "");
  16 /* hud_model  */ ATTRIB(Raptor, hud_model, string, "models/vehicles/raptor_cockpit.dpm");
  17 /* tags       */ ATTRIB(Raptor, tag_head, string, "");
  18 /* tags       */ ATTRIB(Raptor, tag_hud, string, "tag_hud");
  19 /* tags       */ ATTRIB(Raptor, tag_view, string, "tag_camera");
  20 /* netname    */ ATTRIB(Raptor, netname, string, "raptor");
  21 /* fullname   */ ATTRIB(Raptor, vehicle_name, string, _("Raptor"));
  22 /* icon       */ ATTRIB(Raptor, m_icon, string, "vehicle_raptor");
  23 ENDCLASS(Raptor)
  24 REGISTER_VEHICLE(RAPTOR, NEW(Raptor));
  25
  26 #endif
  27
  28 #ifdef IMPLEMENTATION
  29
  30 #ifdef SVQC
  31
  32 bool autocvar_g_vehicle_raptor = true;
  33
  34 float autocvar_g_vehicle_raptor_respawntime = 40;
  35 float autocvar_g_vehicle_raptor_takeofftime = 1.5;
  36
  37 // 0: go where player aims, +forward etc relative to aim angles
  38 // 1: ignore aim for up/down movement. +forward always moved forward, +jump always moves up
  39 int autocvar_g_vehicle_raptor_movestyle = 1;
  40 float autocvar_g_vehicle_raptor_turnspeed = 200;
  41 float autocvar_g_vehicle_raptor_pitchspeed = 50;
  42 float autocvar_g_vehicle_raptor_pitchlimit = 45;
  43
  44 float autocvar_g_vehicle_raptor_speed_forward = 1700;
  45 float autocvar_g_vehicle_raptor_speed_strafe = 900;
  46 float autocvar_g_vehicle_raptor_speed_up = 1700;
  47 float autocvar_g_vehicle_raptor_speed_down = 1700;
  48 float autocvar_g_vehicle_raptor_friction = 2;
  49
  50 float autocvar_g_vehicle_raptor_cannon_turnspeed = 120;
  51 float autocvar_g_vehicle_raptor_cannon_turnlimit = 20;
  52 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up = 12;
  53 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down = 32;
  54
  55 float autocvar_g_vehicle_raptor_cannon_locktarget = 0;
  56 float autocvar_g_vehicle_raptor_cannon_locking_time = 0.2;
  57 float autocvar_g_vehicle_raptor_cannon_locking_releasetime = 0.45;
  58 float autocvar_g_vehicle_raptor_cannon_locked_time = 1;
  59 float autocvar_g_vehicle_raptor_cannon_predicttarget = 1;
  60
  61 float autocvar_g_vehicle_raptor_energy = 100;
  62 float autocvar_g_vehicle_raptor_energy_regen = 25;
  63 float autocvar_g_vehicle_raptor_energy_regen_pause = 0.25;
  64
  65 float autocvar_g_vehicle_raptor_health = 150;
  66 float autocvar_g_vehicle_raptor_health_regen = 0;
  67 float autocvar_g_vehicle_raptor_health_regen_pause = 0;
  68
  69 float autocvar_g_vehicle_raptor_shield = 75;
  70 float autocvar_g_vehicle_raptor_shield_regen = 25;
  71 float autocvar_g_vehicle_raptor_shield_regen_pause = 1.5;
  72
  73 float autocvar_g_vehicle_raptor_bouncefactor = 0.2;
  74 float autocvar_g_vehicle_raptor_bouncestop = 0;
  75 vector autocvar_g_vehicle_raptor_bouncepain = '1 4 1000';
  76
  77 .entity bomb1;
  78 .entity bomb2;
  79
  80 float raptor_altitude(entity this, float amax)
  81 {
  82         tracebox(this.origin, this.mins, this.maxs, this.origin - ('0 0 1' * amax), MOVE_WORLDONLY, this);
  83         return vlen(this.origin - trace_endpos);
  84 }
  85
  86 void raptor_land(entity this)
  87 {
  88         float hgt;
  89
  90         hgt = raptor_altitude(this, 512);
  91         this.velocity = (this.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
  92         this.angles_x *= 0.95;
  93         this.angles_z *= 0.95;
  94
  95         if(hgt < 128)
  96         if(hgt > 0)
  97                 this.frame = (hgt / 128) * 25;
  98
  99         this.bomb1.gun1.avelocity_y = 90 + ((this.frame / 25) * 2000);
 100         this.bomb1.gun2.avelocity_y = -this.bomb1.gun1.avelocity_y;
 101
 102         if(hgt < 16)
 103         {
 104                 this.movetype = MOVETYPE_TOSS;
 105                 setthink(this, vehicles_think);
 106                 this.frame      = 0;
 107         }
 108
 109         this.nextthink  = time;
 110
 111         CSQCMODEL_AUTOUPDATE(this);
 112 }
 113
 114 void raptor_exit(entity this, int eject)
 115 {
 116         vector spot;
 117         this.tur_head.exteriormodeltoclient = world;
 118
 119         if(!IS_DEAD(this))
 120         {
 121                 setthink(this, raptor_land);
 122                 this.nextthink  = time;
 123         }
 124
 125         if(!this.owner)
 126                 return;
 127
 128         makevectors(this.angles);
 129         if(eject)
 130         {
 131                 spot = this.origin + v_forward * 100 + '0 0 64';
 132                 spot = vehicles_findgoodexit(this, spot);
 133                 setorigin(this.owner , spot);
 134                 this.owner.velocity = (v_up + v_forward * 0.25) * 750;
 135                 this.owner.oldvelocity = this.owner.velocity;
 136         }
 137         else
 138         {
 139                 if(vdist(this.velocity, >, 2 * autocvar_sv_maxairspeed))
 140                 {
 141                         this.owner.velocity = normalize(this.velocity) * autocvar_sv_maxairspeed * 2;
 142                         this.owner.velocity_z += 200;
 143                         spot = this.origin + v_forward * 32 + '0 0 64';
 144                         spot = vehicles_findgoodexit(this, spot);
 145                 }
 146                 else
 147                 {
 148                         this.owner.velocity = this.velocity * 0.5;
 149                         this.owner.velocity_z += 10;
 150                         spot = this.origin - v_forward * 200 + '0 0 64';
 151                         spot = vehicles_findgoodexit(this, spot);
 152                 }
 153                 this.owner.oldvelocity = this.owner.velocity;
 154                 setorigin(this.owner , spot);
 155         }
 156
 157         antilag_clear(this.owner, CS(this.owner));
 158         this.owner = world;
 159 }
 160
 161 bool raptor_frame(entity this)
 162 {
 163         entity vehic = this.vehicle;
 164         return = true;
 165
 166         if(intermission_running)
 167         {
 168                 vehic.velocity = '0 0 0';
 169                 vehic.avelocity = '0 0 0';
 170                 return;
 171         }
 172
 173         vehicles_frame(vehic, this);
 174
 175         float ftmp = 0;
 176         /*
 177         ftmp = vlen(vehic.velocity);
 178         if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 179                 ftmp = 1;
 180         else
 181                 ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 182         */
 183
 184         if(vehic.sound_nexttime < time)
 185         {
 186                 vehic.sound_nexttime = time + 7.955812;
 187                 //sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_FLY, 1 - ftmp,   ATTEN_NORM );
 188                 sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, 1, ATTEN_NORM);
 189                 vehic.wait = ftmp;
 190         }
 191         /*
 192         else if(fabs(ftmp - vehic.wait) > 0.2)
 193         {
 194                 sound (vehic.tur_head, CH_TRIGGER_SINGLE, SND_Null, 1 - ftmp,   ATTEN_NORM );
 195                 sound (vehic, CH_TRIGGER_SINGLE, SND_Null, ftmp, ATTEN_NORM);
 196                 vehic.wait = ftmp;
 197         }
 198         */
 199
 200         if(IS_DEAD(vehic))
 201         {
 202                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 203                 return;
 204         }
 205         crosshair_trace(this);
 206
 207         //if(time - vehic.lastteleporttime < 1)
 208         //{
 209                 if(vehic.angles_z > 50 || vehic.angles_z < -50)
 210                 {
 211                         if(PHYS_INPUT_BUTTON_JUMP(this))
 212                         {
 213                                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 214                                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 215                         }
 216                 }
 217         //}
 218
 219         vector vang;
 220         vang = vehic.angles;
 221         vector df = vectoangles(normalize(trace_endpos - vehic.origin + '0 0 32'));
 222         vang_x *= -1;
 223         df_x *= -1;
 224         if(df_x > 180)  df_x -= 360;
 225         if(df_x < -180) df_x += 360;
 226         if(df_y > 180)  df_y -= 360;
 227         if(df_y < -180) df_y += 360;
 228
 229         ftmp = shortangle_f(this.v_angle_y - vang_y, vang_y);
 230         if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 231         vehic.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + vehic.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 232
 233         // Pitch
 234         ftmp = 0;
 235         if(this.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 236         else if(this.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 237
 238         df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 239         ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 240         vehic.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + vehic.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 241
 242         vehic.angles_x = anglemods(vehic.angles_x);
 243         vehic.angles_y = anglemods(vehic.angles_y);
 244         vehic.angles_z = anglemods(vehic.angles_z);
 245
 246         if(autocvar_g_vehicle_raptor_movestyle == 1)
 247                 makevectors('0 1 0' * vehic.angles_y);
 248         else
 249                 makevectors(this.v_angle);
 250
 251         df = vehic.velocity * -autocvar_g_vehicle_raptor_friction;
 252
 253         if(this.movement_x != 0)
 254         {
 255                 if(this.movement_x > 0)
 256                         df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 257                 else if(this.movement_x < 0)
 258                         df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 259         }
 260
 261         if(this.movement_y != 0)
 262         {
 263                 if(this.movement_y < 0)
 264                         df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 265                 else if(this.movement_y > 0)
 266                         df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 267
 268                 vehic.angles_z = bound(-30,vehic.angles_z + (this.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 269         }
 270         else
 271         {
 272                 vehic.angles_z *= 0.95;
 273                 if(vehic.angles_z >= -1 && vehic.angles_z <= -1)
 274                         vehic.angles_z = 0;
 275         }
 276
 277         if(PHYS_INPUT_BUTTON_CROUCH(this))
 278                 df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 279         else if (PHYS_INPUT_BUTTON_JUMP(this))
 280                 df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 281
 282         vehic.velocity  += df * frametime;
 283         this.velocity = this.movement  = vehic.velocity;
 284         setorigin(this, vehic.origin + '0 0 32');
 285
 286         this.vehicle_weapon2mode = vehic.vehicle_weapon2mode;
 287
 288         vector vf, ad;
 289         // Target lock & predict
 290         if(autocvar_g_vehicle_raptor_cannon_locktarget == 2)
 291         {
 292                 if(vehic.gun1.lock_time < time || IS_DEAD(vehic.gun1.enemy) || STAT(FROZEN, vehic.gun1.enemy))
 293                         vehic.gun1.enemy = world;
 294
 295                 if(trace_ent)
 296                 if(trace_ent.movetype)
 297                 if(trace_ent.takedamage)
 298                 if(!IS_DEAD(trace_ent) && !STAT(FROZEN, trace_ent))
 299                 {
 300                         if(teamplay)
 301                         {
 302                                 if(trace_ent.team != this.team)
 303                                 {
 304                                         vehic.gun1.enemy = trace_ent;
 305                                         vehic.gun1.lock_time = time + 5;
 306                                 }
 307                         }
 308                         else
 309                         {
 310                                 vehic.gun1.enemy = trace_ent;
 311                                 vehic.gun1.lock_time = time + 0.5;
 312                         }
 313                 }
 314
 315                 if(vehic.gun1.enemy)
 316                 {
 317                         float distance, impact_time;
 318
 319                         vf = real_origin(vehic.gun1.enemy);
 320                         UpdateAuxiliaryXhair(this, vf, '1 0 0', 1);
 321                         vector _vel = vehic.gun1.enemy.velocity;
 322                         if(vehic.gun1.enemy.movetype == MOVETYPE_WALK)
 323                                 _vel_z *= 0.1;
 324
 325                         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 326                         {
 327                                 ad = vf;
 328                                 distance = vlen(ad - this.origin);
 329                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 330                                 ad = vf + _vel * impact_time;
 331                                 trace_endpos = ad;
 332                         }
 333                         else
 334                                 trace_endpos = vf;
 335                 }
 336         }
 337         else if(autocvar_g_vehicle_raptor_cannon_locktarget == 1)
 338         {
 339
 340                 vehicles_locktarget(vehic, (1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 341                                                          (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 342                                                          autocvar_g_vehicle_raptor_cannon_locked_time);
 343
 344                 if(vehic.lock_target != world)
 345                 if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 346                 if(vehic.lock_strength == 1)
 347                 {
 348                         float i, distance, impact_time;
 349
 350                         vf = real_origin(vehic.lock_target);
 351                         ad = vf;
 352                         for(i = 0; i < 4; ++i)
 353                         {
 354                                 distance = vlen(ad - vehic.origin);
 355                                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 356                                 ad = vf + vehic.lock_target.velocity * impact_time;
 357                         }
 358                         trace_endpos = ad;
 359                 }
 360
 361                 if(vehic.lock_target)
 362                 {
 363                         if(vehic.lock_strength == 1)
 364                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '1 0 0', 1);
 365                         else if(vehic.lock_strength > 0.5)
 366                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 1 0', 1);
 367                         else if(vehic.lock_strength < 0.5)
 368                                 UpdateAuxiliaryXhair(this, real_origin(vehic.lock_target), '0 0 1', 1);
 369                 }
 370         }
 371
 372
 373         vehicle_aimturret(vehic, trace_endpos, vehic.gun1, "fire1",
 374                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 375                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 376
 377         vehicle_aimturret(vehic, trace_endpos, vehic.gun2, "fire1",
 378                                                   autocvar_g_vehicle_raptor_cannon_pitchlimit_down * -1,  autocvar_g_vehicle_raptor_cannon_pitchlimit_up,
 379                                                   autocvar_g_vehicle_raptor_cannon_turnlimit * -1,  autocvar_g_vehicle_raptor_cannon_turnlimit,  autocvar_g_vehicle_raptor_cannon_turnspeed);
 380
 381         /*
 382         ad = ad * 0.5;
 383         v_forward = vf * 0.5;
 384         traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, vehic);
 385         UpdateAuxiliaryXhair(this, trace_endpos, '0 1 0', 0);
 386         */
 387
 388         Weapon wep1 = WEP_RAPTOR;
 389         if(!forbidWeaponUse(this))
 390         if(PHYS_INPUT_BUTTON_ATCK(this))
 391         if (wep1.wr_checkammo1(wep1, vehic))
 392         {
 393             .entity weaponentity = weaponentities[0];
 394                 wep1.wr_think(wep1, vehic, weaponentity, 1);
 395         }
 396
 397         if(vehic.vehicle_flags  & VHF_SHIELDREGEN)
 398                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 399
 400         if(vehic.vehicle_flags  & VHF_HEALTHREGEN)
 401                 vehicles_regen(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 402
 403         if(vehic.vehicle_flags  & VHF_ENERGYREGEN)
 404                 vehicles_regen(vehic, vehic.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 405
 406         Weapon wep2a = WEP_RAPTOR_BOMB;
 407         if(!forbidWeaponUse(this))
 408         if(vehic.vehicle_weapon2mode == RSM_BOMB)
 409         {
 410                 if(time > vehic.lip + autocvar_g_vehicle_raptor_bombs_refire)
 411                 if(PHYS_INPUT_BUTTON_ATCK2(this))
 412                 {
 413                     .entity weaponentity = weaponentities[1];
 414                         wep2a.wr_think(wep2a, vehic, weaponentity, 2);
 415                         vehic.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 416                         vehic.lip   = time;
 417                 }
 418         }
 419         else
 420         {
 421                 Weapon wep2b = WEP_RAPTOR_FLARE;
 422                 if(time > vehic.lip + autocvar_g_vehicle_raptor_flare_refire)
 423                 if(PHYS_INPUT_BUTTON_ATCK2(this))
 424                 {
 425                     .entity weaponentity = weaponentities[1];
 426                         wep2b.wr_think(wep2b, vehic, weaponentity, 2);
 427                         vehic.delay = time + autocvar_g_vehicle_raptor_flare_refire;
 428                         vehic.lip   = time;
 429                 }
 430         }
 431
 432         vehic.bomb1.alpha = vehic.bomb2.alpha = (time - vehic.lip) / (vehic.delay - vehic.lip);
 433         this.vehicle_reload2 = bound(0, vehic.bomb1.alpha * 100, 100);
 434         this.vehicle_ammo2 = (this.vehicle_reload2 == 100) ? 100 : 0;
 435
 436         if(vehic.bomb1.cnt < time)
 437         {
 438                 bool incoming = false;
 439                 FOREACH_ENTITY_ENT(enemy, vehic,
 440                 {
 441                         if(it.flags & FL_PROJECTILE)
 442                         if(MISSILE_IS_TRACKING(it))
 443                         if(vdist(vehic.origin - it.origin, <, 2 * autocvar_g_vehicle_raptor_flare_range))
 444                         {
 445                                 incoming = true;
 446                                 break;
 447                         }
 448                 });
 449
 450                 if(incoming)
 451                 {
 452                         msg_entity = this;
 453                         soundto(MSG_ONE, vehic, CH_PAIN_SINGLE, SND(VEH_MISSILE_ALARM), VOL_BASE, ATTEN_NONE);
 454                 }
 455
 456                 vehic.bomb1.cnt = time + 1;
 457         }
 458
 459
 460         VEHICLE_UPDATE_PLAYER(this, vehic, health, raptor);
 461         VEHICLE_UPDATE_PLAYER(this, vehic, energy, raptor);
 462         if(vehic.vehicle_flags & VHF_HASSHIELD)
 463                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, raptor);
 464
 465         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 466 }
 467
 468 bool raptor_takeoff(entity this)
 469 {
 470         entity vehic = this.vehicle;
 471         return = true;
 472
 473         vehic.nextthink = time;
 474         CSQCMODEL_AUTOUPDATE(vehic);
 475         vehic.nextthink = 0; // will this work?
 476
 477         if(vehic.sound_nexttime < time)
 478         {
 479                 vehic.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 480                 sound (vehic, CH_TRIGGER_SINGLE, SND_VEH_RAPTOR_SPEED, VOL_VEHICLEENGINE, ATTEN_NORM);
 481         }
 482
 483         // Takeoff sequense
 484         if(vehic.frame < 25)
 485         {
 486                 vehic.frame += 25 / (autocvar_g_vehicle_raptor_takeofftime / sys_frametime);
 487                 vehic.velocity_z = min(vehic.velocity_z * 1.5, 256);
 488                 vehic.bomb1.gun1.avelocity_y = 90 + ((vehic.frame / 25) * 25000);
 489                 vehic.bomb1.gun2.avelocity_y = -vehic.bomb1.gun1.avelocity_y;
 490                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 491
 492                 setorigin(this, vehic.origin + '0 0 32');
 493         }
 494         else
 495                 this.PlayerPhysplug = raptor_frame;
 496
 497         if(vehic.vehicle_flags  & VHF_SHIELDREGEN)
 498                 vehicles_regen(vehic, vehic.dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime, true);
 499
 500         if(vehic.vehicle_flags  & VHF_HEALTHREGEN)
 501                 vehicles_regen(vehic, vehic.dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime, false);
 502
 503         if(vehic.vehicle_flags  & VHF_ENERGYREGEN)
 504                 vehicles_regen(vehic, vehic.cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime, false);
 505
 506
 507         vehic.bomb1.alpha = vehic.bomb2.alpha = (time - vehic.lip) / (vehic.delay - vehic.lip);
 508         this.vehicle_reload2 = bound(0, vehic.bomb1.alpha * 100, 100);
 509         this.vehicle_ammo2 = (this.vehicle_reload2 == 100) ? 100 : 0;
 510
 511         VEHICLE_UPDATE_PLAYER(this, vehic, health, raptor);
 512         VEHICLE_UPDATE_PLAYER(this, vehic, energy, raptor);
 513         if(vehic.vehicle_flags & VHF_HASSHIELD)
 514                 VEHICLE_UPDATE_PLAYER(this, vehic, shield, raptor);
 515
 516         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_ATCK2(this) = PHYS_INPUT_BUTTON_CROUCH(this) = false;
 517 }
 518
 519 void raptor_blowup(entity this)
 520 {
 521         this.deadflag   = DEAD_DEAD;
 522         this.vehicle_exit(this, VHEF_NORMAL);
 523         RadiusDamage (this, this.enemy, 250, 15, 250, world, world, 250, DEATH_VH_RAPT_DEATH.m_id, world);
 524
 525         this.alpha                = -1;
 526         this.movetype      = MOVETYPE_NONE;
 527         this.effects            = EF_NODRAW;
 528         this.colormod      = '0 0 0';
 529         this.avelocity    = '0 0 0';
 530         this.velocity      = '0 0 0';
 531
 532         setorigin(this, this.pos1);
 533         settouch(this, func_null);
 534         this.nextthink = 0;
 535 }
 536
 537 void raptor_diethink(entity this)
 538 {
 539         if(time >= this.wait)
 540                 setthink(this, raptor_blowup);
 541
 542         if(random() < 0.05)
 543         {
 544                 sound (this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 545                 Send_Effect(EFFECT_EXPLOSION_SMALL, randomvec() * 80 + (this.origin + '0 0 100'), '0 0 0', 1);
 546         }
 547         this.nextthink = time;
 548
 549         CSQCMODEL_AUTOUPDATE(this);
 550 }
 551
 552 // If we dont do this ever now and then, the raptors rotors
 553 // stop working, presumably due to angle overflow. cute.
 554 void raptor_rotor_anglefix(entity this)
 555 {
 556         this.gun1.angles_y = anglemods(this.gun1.angles_y);
 557         this.gun2.angles_y = anglemods(this.gun2.angles_y);
 558         this.nextthink = time + 15;
 559 }
 560
 561 bool raptor_impulse(entity this, int _imp)
 562 {
 563         switch(_imp)
 564         {
 565                 case IMP_weapon_group_1.impulse:
 566                         this.vehicle.vehicle_weapon2mode = RSM_BOMB;
 567                         CSQCVehicleSetup(this, 0);
 568                         return true;
 569                 case IMP_weapon_group_2.impulse:
 570                         this.vehicle.vehicle_weapon2mode = RSM_FLARE;
 571                         CSQCVehicleSetup(this, 0);
 572                         return true;
 573
 574                 case IMP_weapon_next_byid.impulse:
 575                 case IMP_weapon_next_bypriority.impulse:
 576                 case IMP_weapon_next_bygroup.impulse:
 577                         this.vehicle.vehicle_weapon2mode += 1;
 578                         if(this.vehicle.vehicle_weapon2mode > RSM_LAST)
 579                                 this.vehicle.vehicle_weapon2mode = RSM_FIRST;
 580
 581                         CSQCVehicleSetup(this, 0);
 582                         return true;
 583                 case IMP_weapon_last.impulse:
 584                 case IMP_weapon_prev_byid.impulse:
 585                 case IMP_weapon_prev_bypriority.impulse:
 586                 case IMP_weapon_prev_bygroup.impulse:
 587                         this.vehicle.vehicle_weapon2mode -= 1;
 588                         if(this.vehicle.vehicle_weapon2mode < RSM_FIRST)
 589                                 this.vehicle.vehicle_weapon2mode = RSM_LAST;
 590
 591                         CSQCVehicleSetup(this, 0);
 592                         return true;
 593
 594                 /*
 595                 case IMP_weapon_drop.impulse: // toss gun, could be used to exit?
 596                         break;
 597                 case IMP_weapon_reload.impulse: // Manual minigun reload?
 598                         break;
 599                 */
 600         }
 601         return false;
 602 }
 603
 604 spawnfunc(vehicle_raptor)
 605 {
 606         if(!autocvar_g_vehicle_raptor) { remove(this); return; }
 607         if(!vehicle_initialize(this, VEH_RAPTOR, false)) { remove(this); return; }
 608 }
 609
 610 METHOD(Raptor, vr_impact, void(Raptor thisveh, entity instance))
 611 {
 612     if(autocvar_g_vehicle_raptor_bouncepain)
 613         vehicles_impact(instance, autocvar_g_vehicle_raptor_bouncepain_x, autocvar_g_vehicle_raptor_bouncepain_y, autocvar_g_vehicle_raptor_bouncepain_z);
 614 }
 615 METHOD(Raptor, vr_enter, void(Raptor thisveh, entity instance))
 616 {
 617     instance.vehicle_weapon2mode = RSM_BOMB;
 618     instance.owner.PlayerPhysplug = raptor_takeoff;
 619     instance.movetype      = MOVETYPE_BOUNCEMISSILE;
 620     instance.solid                = SOLID_SLIDEBOX;
 621     instance.owner.vehicle_health = (instance.vehicle_health / autocvar_g_vehicle_raptor_health) * 100;
 622     instance.owner.vehicle_shield = (instance.vehicle_shield / autocvar_g_vehicle_raptor_shield) * 100;
 623     instance.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 624     instance.tur_head.exteriormodeltoclient = instance.owner;
 625
 626     instance.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 627     instance.lip   = time;
 628
 629     if(instance.owner.flagcarried)
 630        setorigin(instance.owner.flagcarried, '-20 0 96');
 631
 632     CSQCVehicleSetup(instance.owner, 0);
 633 }
 634 METHOD(Raptor, vr_death, void(Raptor thisveh, entity instance))
 635 {
 636     instance.health                             = 0;
 637     instance.event_damage               = func_null;
 638     instance.solid                              = SOLID_CORPSE;
 639     instance.takedamage                 = DAMAGE_NO;
 640     instance.deadflag                   = DEAD_DYING;
 641     instance.movetype                   = MOVETYPE_BOUNCE;
 642     setthink(instance, raptor_diethink);
 643     instance.nextthink                  = time;
 644     instance.wait                               = time + 5 + (random() * 5);
 645
 646     Send_Effect(EFFECT_EXPLOSION_MEDIUM, findbetterlocation (instance.origin, 16), '0 0 0', 1);
 647
 648     instance.velocity_z += 600;
 649
 650     instance.avelocity = '0 0.5 1' * (random() * 400);
 651     instance.avelocity -= '0 0.5 1' * (random() * 400);
 652
 653     instance.colormod = '-0.5 -0.5 -0.5';
 654     settouch(instance, raptor_blowup);
 655 }
 656 METHOD(Raptor, vr_spawn, void(Raptor thisveh, entity instance))
 657 {
 658     if(!instance.gun1)
 659     {
 660         entity spinner;
 661         vector ofs;
 662
 663         //FIXME: Camera is in a bad place in HUD model.
 664         //setorigin(instance.vehicle_viewport, '25 0 5');
 665
 666         instance.vehicles_impulse = raptor_impulse;
 667
 668         instance.frame = 0;
 669
 670         instance.bomb1 = new(raptor_bomb);
 671         instance.bomb2 = new(raptor_bomb);
 672         instance.gun1  = new(raptor_gun);
 673         instance.gun2  = new(raptor_gun);
 674
 675         setmodel(instance.bomb1, MDL_VEH_RAPTOR_CB_FOLDED);
 676         setmodel(instance.bomb2, MDL_VEH_RAPTOR_CB_FOLDED);
 677         setmodel(instance.gun1, MDL_VEH_RAPTOR_GUN);
 678         setmodel(instance.gun2, MDL_VEH_RAPTOR_GUN);
 679         setmodel(instance.tur_head, MDL_VEH_RAPTOR_TAIL);
 680
 681         setattachment(instance.bomb1, instance, "bombmount_left");
 682         setattachment(instance.bomb2, instance, "bombmount_right");
 683         setattachment(instance.tur_head, instance,"root");
 684
 685         // FIXMODEL Guns mounts to angled bones
 686         instance.bomb1.angles = instance.angles;
 687         instance.angles = '0 0 0';
 688         // This messes up gun-aim, so work arround it.
 689         //setattachment(instance.gun1, instance, "gunmount_left");
 690         ofs = gettaginfo(instance, gettagindex(instance, "gunmount_left"));
 691         ofs -= instance.origin;
 692         setattachment(instance.gun1, instance, "");
 693         setorigin(instance.gun1, ofs);
 694
 695         //setattachment(instance.gun2, instance, "gunmount_right");
 696         ofs = gettaginfo(instance, gettagindex(instance, "gunmount_right"));
 697         ofs -= instance.origin;
 698         setattachment(instance.gun2, instance, "");
 699         setorigin(instance.gun2, ofs);
 700
 701         instance.angles = instance.bomb1.angles;
 702         instance.bomb1.angles = '0 0 0';
 703
 704         spinner = new(raptor_spinner);
 705         spinner.owner = instance;
 706         setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 707         setattachment(spinner, instance, "engine_left");
 708         spinner.movetype = MOVETYPE_NOCLIP;
 709         spinner.avelocity = '0 90 0';
 710         instance.bomb1.gun1 = spinner;
 711
 712         spinner = new(raptor_spinner);
 713         spinner.owner = instance;
 714         setmodel(spinner, MDL_VEH_RAPTOR_PROP);
 715         setattachment(spinner, instance, "engine_right");
 716         spinner.movetype = MOVETYPE_NOCLIP;
 717         spinner.avelocity = '0 -90 0';
 718         instance.bomb1.gun2 = spinner;
 719
 720         // Sigh.
 721         setthink(instance.bomb1, raptor_rotor_anglefix);
 722         instance.bomb1.nextthink = time;
 723
 724         instance.mass                      = 1 ;
 725     }
 726
 727     instance.frame                = 0;
 728     instance.vehicle_health = autocvar_g_vehicle_raptor_health;
 729     instance.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 730     instance.movetype      = MOVETYPE_TOSS;
 731     instance.solid                = SOLID_SLIDEBOX;
 732     instance.vehicle_energy = 1;
 733
 734     instance.PlayerPhysplug = raptor_frame;
 735
 736     instance.bomb1.gun1.avelocity_y = 90;
 737     instance.bomb1.gun2.avelocity_y = -90;
 738
 739     instance.delay = time;
 740
 741     instance.bouncefactor = autocvar_g_vehicle_raptor_bouncefactor;
 742     instance.bouncestop = autocvar_g_vehicle_raptor_bouncestop;
 743     instance.damageforcescale = 0.25;
 744     instance.vehicle_health = autocvar_g_vehicle_raptor_health;
 745     instance.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 746 }
 747 METHOD(Raptor, vr_setup, void(Raptor thisveh, entity instance))
 748 {
 749     if(autocvar_g_vehicle_raptor_shield)
 750         instance.vehicle_flags |= VHF_HASSHIELD;
 751
 752     if(autocvar_g_vehicle_raptor_shield_regen)
 753         instance.vehicle_flags |= VHF_SHIELDREGEN;
 754
 755     if(autocvar_g_vehicle_raptor_health_regen)
 756         instance.vehicle_flags |= VHF_HEALTHREGEN;
 757
 758     if(autocvar_g_vehicle_raptor_energy_regen)
 759         instance.vehicle_flags |= VHF_ENERGYREGEN;
 760
 761     instance.vehicle_exit = raptor_exit;
 762     instance.respawntime = autocvar_g_vehicle_raptor_respawntime;
 763     instance.vehicle_health = autocvar_g_vehicle_raptor_health;
 764     instance.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 765     instance.max_health = instance.vehicle_health;
 766 }
 767
 768 #endif
 769 #ifdef CSQC
 770
 771 METHOD(Raptor, vr_hud, void(Raptor thisveh))
 772 {
 773     Vehicles_drawHUD(VEH_RAPTOR.m_icon, "vehicle_raptor_weapon1", "vehicle_raptor_weapon2",
 774                      "vehicle_icon_ammo1", autocvar_hud_progressbar_vehicles_ammo1_color,
 775                      "vehicle_icon_ammo2", autocvar_hud_progressbar_vehicles_ammo2_color);
 776 }
 777 METHOD(Raptor, vr_crosshair, void(Raptor thisveh, entity player))
 778 {
 779     string crosshair;
 780
 781     switch(weapon2mode)
 782     {
 783         case RSM_FLARE: crosshair = vCROSS_RAIN;  break;
 784         case RSM_BOMB:  crosshair = vCROSS_BURST; break;
 785         default:        crosshair = vCROSS_BURST;
 786     }
 787
 788     vector tmpSize = '0 0 0';
 789     if(weapon2mode != RSM_FLARE)
 790     {
 791         vector where;
 792
 793         if(!dropmark)
 794         {
 795             dropmark = spawn();
 796             dropmark.owner = player;
 797             dropmark.gravity = 1;
 798         }
 799
 800         float reload2 = STAT(VEHICLESTAT_RELOAD2) * 0.01;
 801         if(reload2 == 1)
 802         {
 803             setorigin(dropmark, pmove_org);
 804             dropmark.velocity = pmove_vel;
 805             tracetoss(dropmark, player);
 806
 807             where = project_3d_to_2d(trace_endpos);
 808
 809             setorigin(dropmark, trace_endpos);
 810             tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size;
 811
 812             if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 813             {
 814                 where.x -= tmpSize.x * 0.5;
 815                 where.y -= tmpSize.y * 0.5;
 816                 where.z = 0;
 817                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 818                 drawpic(where, vCROSS_DROP, tmpSize, '0 1 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 819             }
 820             dropmark.cnt = time + 5;
 821         }
 822         else
 823         {
 824             if(dropmark.cnt > time)
 825             {
 826                 where = project_3d_to_2d(dropmark.origin);
 827                 tmpSize = draw_getimagesize(vCROSS_DROP) * autocvar_cl_vehicles_crosshair_size * 1.25;
 828
 829                 if (!(where.z < 0 || where.x < 0 || where.y < 0 || where.x > vid_conwidth || where.y > vid_conheight))
 830                 {
 831                     where.x -= tmpSize.x * 0.5;
 832                     where.y -= tmpSize.y * 0.5;
 833                     where.z = 0;
 834                     drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.9, DRAWFLAG_ADDITIVE);
 835                     drawpic(where, vCROSS_DROP, tmpSize, '1 0 0', autocvar_crosshair_alpha * 0.6, DRAWFLAG_NORMAL); // Ensure visibility against bright bg
 836                 }
 837             }
 838         }
 839     }
 840
 841     Vehicles_drawCrosshair(crosshair);
 842 }
 843 METHOD(Raptor, vr_setup, void(Raptor thisveh, entity instance))
 844 {
 845     AuxiliaryXhair[1].axh_image = vCROSS_LOCK;
 846 }
 847
 848 #endif
 849 #endif