qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include "../constants.qh"
   7         #include "../stats.qh"
   8         #include <lib/warpzone/anglestransform.qh>
   9         #include <lib/warpzone/common.qh>
  10         #include <lib/warpzone/client.qh>
  11         #include "../util.qh"
  12         #include <client/autocvars.qh>
  13         #include "../deathtypes/all.qh"
  14         #include <lib/csqcmodel/interpolate.qh>
  15         #include "../physics/movetypes/movetypes.qh"
  16         #include <client/main.qh>
  17         #include <lib/csqcmodel/cl_model.qh>
  18 #elif defined(MENUQC)
  19 #elif defined(SVQC)
  20         #include <common/items/_mod.qh>
  21     #include <lib/warpzone/anglestransform.qh>
  22     #include <lib/warpzone/common.qh>
  23     #include <lib/warpzone/util_server.qh>
  24     #include <lib/warpzone/server.qh>
  25     #include "../constants.qh"
  26     #include "../stats.qh"
  27     #include "../teams.qh"
  28     #include <common/util.qh>
  29     #include "../monsters/_mod.qh"
  30     #include "config.qh"
  31     #include <server/weapons/common.qh>
  32     #include <server/weapons/csqcprojectile.qh>
  33     #include <server/weapons/tracing.qh>
  34     #include <server/items/spawning.qh>
  35     #include <server/autocvars.qh>
  36     #include "../notifications/all.qh"
  37     #include "../deathtypes/all.qh"
  38     #include <server/mutators/_mod.qh>
  39     #include "../mapinfo.qh"
  40     #include <server/command/_mod.qh>
  41     #include <lib/csqcmodel/sv_model.qh>
  42     #include <server/portals.qh>
  43     #include <server/hook.qh>
  44 #endif
  45 #ifdef GAMEQC
  46         #include "calculations.qc"
  47 #endif
  48 #ifdef SVQC
  49         #include "config.qc"
  50 #endif
  51
  52 #include "weapon/_mod.inc"
  53
  54
  55 // WEAPON PLUGIN SYSTEM
  56
  57 WepSet _WepSet_FromWeapon(int a)
  58 {
  59         a -= WEP_FIRST;
  60         if (REGISTRY_MAX(Weapons) > 24)
  61                 if (a >= 24)
  62                 {
  63                         a -= 24;
  64                         if (REGISTRY_MAX(Weapons) > 48)
  65                                 if (a >= 24)
  66                                 {
  67                                         a -= 24;
  68                                         return '0 0 1' * (2 ** a);
  69                                 }
  70                         return '0 1 0' * (2 ** a);
  71                 }
  72         return '1 0 0' * (2 ** a);
  73 }
  74 #ifdef SVQC
  75         void WriteWepSet(float dst, WepSet w)
  76         {
  77                 if (REGISTRY_MAX(Weapons) > 48) WriteInt72_t(dst, w);
  78                 else if (REGISTRY_MAX(Weapons) > 24) WriteInt48_t(dst, w);
  79                 else WriteInt24_t(dst, w.x);
  80         }
  81 #endif
  82 #ifdef CSQC
  83         WepSet WepSet_GetFromStat()
  84         {
  85                 return STAT(WEAPONS);
  86         }
  87         WepSet WepSet_GetFromStat_InMap()
  88         {
  89                 return STAT(WEAPONSINMAP);
  90         }
  91         WepSet ReadWepSet()
  92         {
  93                 if (REGISTRY_MAX(Weapons) > 48) return ReadInt72_t();
  94                 if (REGISTRY_MAX(Weapons) > 24) return ReadInt48_t();
  95                 return ReadInt24_t() * '1 0 0';
  96         }
  97 #endif
  98
  99 string W_FixWeaponOrder(string order, float complete)
 100 {
 101         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 102 }
 103 string W_NameWeaponOrder_MapFunc(string s)
 104 {
 105         int i = stof(s);
 106         if (s == "0" || i)
 107         {
 108                 entity wi = REGISTRY_GET(Weapons, i);
 109                 if (wi != WEP_Null) return wi.netname;
 110         }
 111         return s;
 112 }
 113
 114 string W_UndeprecateName(string s)
 115 {
 116         switch (s)
 117         {
 118                 case "nex": return "vortex";
 119                 case "rocketlauncher": return "devastator";
 120                 case "laser": return "blaster";
 121                 case "minstanex": return "vaporizer";
 122                 case "grenadelauncher": return "mortar";
 123                 case "uzi": return "machinegun";
 124                 case "hmg": return "okhmg";
 125                 case "rpc": return "okrpc";
 126                 default: return s;
 127         }
 128 }
 129 string W_NameWeaponOrder(string order)
 130 {
 131         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 132 }
 133 string W_NumberWeaponOrder_MapFunc(string s)
 134 {
 135         if (s == "0" || stof(s)) return s;
 136         s = W_UndeprecateName(s);
 137         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 138         return s;
 139 }
 140 string W_NumberWeaponOrder(string order)
 141 {
 142         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 143 }
 144
 145 float W_FixWeaponOrder_BuildImpulseList_buf[REGISTRY_MAX(Weapons)];
 146 string W_FixWeaponOrder_BuildImpulseList_order;
 147 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 148 {
 149         float h;
 150         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 151         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 152         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 153 }
 154 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 155 {
 156         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 157         Weapon e1 = REGISTRY_GET(Weapons, si);
 158         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 159         Weapon e2 = REGISTRY_GET(Weapons, sj);
 160         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 161         if (d != 0) return -d;  // high impulse first!
 162         return strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 163                 sprintf(" %d ", si), 0)
 164                -
 165                strstrofs(strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " "),
 166                 sprintf(" %d ", sj), 0)
 167         ;  // low char index first!
 168 }
 169 string W_FixWeaponOrder_BuildImpulseList(string o)
 170 {
 171         int i;
 172         W_FixWeaponOrder_BuildImpulseList_order = o;
 173         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 174                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 175         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 176                 NULL);
 177         o = "";
 178         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 179                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 180         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 181         return substring(o, 1, -1);
 182 }
 183
 184 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 185 {
 186         return W_FixWeaponOrder(order, 0);
 187 }
 188
 189 string W_FixWeaponOrder_ForceComplete(string order)
 190 {
 191         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 192         return W_FixWeaponOrder(order, 1);
 193 }
 194
 195 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
 196 {
 197         WepSet result = '0 0 0';
 198         for (int j = 0; j < n; ++j)
 199         {
 200                 RandomSelection_Init();
 201                 FOREACH(Weapons, it != WEP_Null, {
 202                         if (remaining & (it.m_wepset))
 203                                 RandomSelection_AddEnt(it, 1, 1);
 204                 });
 205                 Weapon w = RandomSelection_chosen_ent;
 206                 result |= WepSet_FromWeapon(w);
 207                 remaining &= ~WepSet_FromWeapon(w);
 208         }
 209         return result;
 210 }
 211
 212 string GetAmmoPicture(int ammotype)
 213 {
 214         switch (ammotype)
 215         {
 216                 case RES_SHELLS:  return ITEM_Shells.m_icon;
 217                 case RES_BULLETS: return ITEM_Bullets.m_icon;
 218                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
 219                 case RES_CELLS:   return ITEM_Cells.m_icon;
 220                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
 221                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
 222                 default: return "";  // wtf, no ammo type?
 223         }
 224 }
 225
 226 string GetAmmoName(int ammotype)
 227 {
 228         switch (ammotype)
 229         {
 230                 case RES_SHELLS:  return ITEM_Shells.m_name;
 231                 case RES_BULLETS: return ITEM_Bullets.m_name;
 232                 case RES_ROCKETS: return ITEM_Rockets.m_name;
 233                 case RES_CELLS:   return ITEM_Cells.m_name;
 234                 case RES_PLASMA:  return ITEM_Plasma.m_name;
 235                 case RES_FUEL:    return ITEM_JetpackFuel.m_name;
 236                 default:          return "batteries";
 237         }
 238 }
 239
 240 #ifdef CSQC
 241 int GetAmmoTypeFromNum(int i)
 242 {
 243         switch (i)
 244         {
 245                 case 0: return RES_SHELLS;
 246                 case 1: return RES_BULLETS;
 247                 case 2: return RES_ROCKETS;
 248                 case 3: return RES_CELLS;
 249                 case 4: return RES_PLASMA;
 250                 case 5: return RES_FUEL;
 251                 default: return RES_NONE;
 252         }
 253 }
 254
 255 int GetAmmoStat(int ammotype)
 256 {
 257         switch (ammotype)
 258         {
 259                 case RES_SHELLS: return STAT_SHELLS;
 260                 case RES_BULLETS: return STAT_NAILS;
 261                 case RES_ROCKETS: return STAT_ROCKETS;
 262                 case RES_CELLS: return STAT_CELLS;
 263                 case RES_PLASMA: return STAT_PLASMA.m_id;
 264                 case RES_FUEL: return STAT_FUEL.m_id;
 265                 default: return -1;
 266         }
 267 }
 268 #endif
 269
 270 string W_Sound(string w_snd)
 271 {
 272         string output = strcat("weapons/", w_snd);
 273         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 274         return M_ARGV(1, string);
 275 }
 276
 277 string W_Model(string w_mdl)
 278 {
 279         string output = strcat("models/weapons/", w_mdl);
 280         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 281         return M_ARGV(1, string);
 282 }
 283
 284 #ifdef GAMEQC
 285 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 286 {
 287         switch (algn)
 288         {
 289                 default:
 290                 case 3:
 291                         // right alignment
 292                         break;
 293                 case 4:
 294                         // left
 295                         vecs.y = -vecs.y;
 296                         break;
 297                 case 1:
 298                 case 2:
 299                         // center
 300                         vecs.y = 0;
 301                         vecs.z -= 2;
 302                         break;
 303         }
 304         return vecs;
 305 }
 306
 307 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 308 {
 309         string s;
 310         if (visual)
 311         {
 312                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 313         }
 314         else if (STAT(SHOOTFROMEYE))
 315         {
 316                 vecs.y = vecs.z = 0;
 317         }
 318         else if (STAT(SHOOTFROMCENTER))
 319         {
 320                 vecs.y = 0;
 321                 vecs.z -= 2;
 322         }
 323         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 324         {
 325                 vector v = stov(s);
 326                 if (y_is_right) v.y = -v.y;
 327                 if (v.x != 0) vecs.x = v.x;
 328                 vecs.y = v.y;
 329                 vecs.z = v.z;
 330         }
 331         else  // just do the same as top
 332         {
 333                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 334         }
 335
 336         return vecs;
 337 }
 338
 339 #define shotorg_adjust shotorg_adjust_values
 340
 341 /**
 342  * supported formats:
 343  *
 344  * 1. simple animated model, muzzle flash handling on h_ model:
 345  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 346  *      tags:
 347  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 348  *        shell = casings ejection point (must be on the right hand side of the gun)
 349  *        weapon = attachment for v_tuba.md3
 350  *    v_tuba.md3 - first and third person model
 351  *    g_tuba.md3 - pickup model
 352  *
 353  * 2. simple animated model, muzzle flash handling on v_ model:
 354  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 355  *      tags:
 356  *        weapon = attachment for v_tuba.md3
 357  *    v_tuba.md3 - first and third person model
 358  *      tags:
 359  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 360  *        shell = casings ejection point (must be on the right hand side of the gun)
 361  *    g_tuba.md3 - pickup model
 362  *
 363  * 3. fully animated model, muzzle flash handling on h_ model:
 364  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 365  *      tags:
 366  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 367  *        shell = casings ejection point (must be on the right hand side of the gun)
 368  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 369  *    v_tuba.md3 - third person model
 370  *    g_tuba.md3 - pickup model
 371  *
 372  * 4. fully animated model, muzzle flash handling on v_ model:
 373  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 374  *      tags:
 375  *        shot = muzzle end (shot origin)
 376  *        shell = casings ejection point (must be on the right hand side of the gun)
 377  *    v_tuba.md3 - third person model
 378  *      tags:
 379  *        shot = muzzle end (for muzzle flashes)
 380  *    g_tuba.md3 - pickup model
 381  *
 382  * writes:
 383  *   this.origin, this.angles
 384  *   this.weaponchild
 385  *   this.movedir, this.view_ofs, this.movedir_aligned
 386  *   attachment stuff
 387  *   anim stuff
 388  * to free:
 389  *   call again with ""
 390  *   remove the ent
 391  */
 392 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 393 {
 394         if (name == "")
 395         {
 396                 vector oldmin = this.mins, oldmax = this.maxs;
 397                 setmodel(this, MDL_Null);
 398                 setsize(this, oldmin, oldmax);
 399                 if (this.weaponchild) delete(this.weaponchild);
 400                 this.weaponchild = NULL;
 401                 this.movedir = '0 0 0';
 402                 this.spawnorigin = '0 0 0';
 403                 this.oldorigin = '0 0 0';
 404                 this.anim_fire1  = '0 1 0.01';
 405                 this.anim_fire2  = '0 1 0.01';
 406                 this.anim_idle   = '0 1 0.01';
 407                 this.anim_reload = '0 1 0.01';
 408         }
 409         else
 410         {
 411                 // if there is a child entity, hide it until we're sure we use it
 412                 if (this.weaponchild) this.weaponchild.model = "";
 413                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 414                 int v_shot_idx;  // used later
 415                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 416
 417                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 418                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 419                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 420                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 421                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 422                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 423
 424                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 425                 // if we don't, this is a "real" animated model
 426                 string t;
 427                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 428                 {
 429                         if (!this.weaponchild)
 430                         {
 431                                 this.weaponchild = new(weaponchild);
 432 #ifdef CSQC
 433                                 this.weaponchild.drawmask = MASK_NORMAL;
 434                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 435 #endif
 436                         }
 437                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 438                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 439                         setattachment(this.weaponchild, this, t);
 440                 }
 441                 else
 442                 {
 443                         if (this.weaponchild) delete(this.weaponchild);
 444                         this.weaponchild = NULL;
 445                 }
 446
 447                 setsize(this, '0 0 0', '0 0 0');
 448                 setorigin(this, '0 0 0');
 449                 this.angles = '0 0 0';
 450                 this.frame = 0;
 451 #ifdef SVQC
 452                 this.viewmodelforclient = NULL;
 453 #else
 454                 this.renderflags &= ~RF_VIEWMODEL;
 455 #endif
 456                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 457                 {
 458                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 459                 }
 460                 else
 461                 {
 462                         int idx;
 463                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 464                         {
 465                                 this.movedir = gettaginfo(this, idx);
 466                         }
 467                         else
 468                         {
 469                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 470                                         this.model);
 471                                 this.movedir = '0 0 0';
 472                         }
 473                 }
 474                 {
 475                         int idx = 0;
 476                         // v_ model attached to invisible h_ model
 477                         if (this.weaponchild
 478                             && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 479                         {
 480                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 481                         }
 482                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 483                         {
 484                                 this.spawnorigin = gettaginfo(this, idx);
 485                         }
 486                         else
 487                         {
 488                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 489                                         this.model);
 490                                 this.spawnorigin = this.movedir;
 491                         }
 492                 }
 493                 if (v_shot_idx)
 494                 {
 495                         this.oldorigin = '0 0 0';  // use regular attachment
 496                 }
 497                 else
 498                 {
 499                         int idx;
 500                         if (this.weaponchild)
 501                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 502                         else
 503                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 504                         if (idx)
 505                         {
 506                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 507                         }
 508                         else
 509                         {
 510                                 LOG_WARNF(
 511                                         "weapon model %s does not support the 'handle' tag "
 512                                         "and neither does the v_ model support the 'shot' tag, "
 513                                         "will display muzzle flashes TOTALLY wrong\n",
 514                                         this.model);
 515                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 516                         }
 517                 }
 518
 519 #ifdef SVQC
 520                 this.viewmodelforclient = this.owner;
 521 #else
 522                 this.renderflags |= RF_VIEWMODEL;
 523 #endif
 524         }
 525
 526         this.view_ofs = '0 0 0';
 527         this.movedir_aligned = this.movedir;
 528
 529         if (this.movedir.x >= 0)
 530         {
 531                 //int algn = STAT(GUNALIGN, this.owner);
 532                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 533         #ifdef SVQC
 534                 this.m_gunalign = algn;
 535         #endif
 536                 vector v = this.movedir;
 537                 this.movedir = shotorg_adjust(v, false, false, algn);
 538                 this.movedir_aligned = shotorg_adjust(v, false, true, algn);
 539                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 540         }
 541         int compressed_shotorg = compressShotOrigin(this.movedir);
 542         // make them match perfectly
 543 #ifdef SVQC
 544     // null during init
 545     if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 546         this.movedir = decompressShotOrigin(compressed_shotorg);
 547 #else
 548         this.movedir = decompressShotOrigin(compressed_shotorg);
 549 #endif
 550
 551         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 552
 553         // check if an instant weapon switch occurred
 554         setorigin(this, this.view_ofs);
 555         if (!_anim) return;
 556         // reset animstate now
 557         this.wframe = WFRAME_IDLE;
 558         setanim(this, this.anim_idle, true, false, true);
 559 }
 560 #endif
 561
 562 #ifdef GAMEQC
 563
 564 REGISTER_NET_TEMP(wframe)
 565 #ifdef CSQC
 566 NET_HANDLE(wframe, bool isNew)
 567 {
 568         WFRAME fr = ReadByte();
 569         float t = ReadFloat();
 570     int slot = ReadByte();
 571         bool restartanim = ReadByte();
 572         entity wepent = viewmodels[slot];
 573         if(fr == WFRAME_IDLE)
 574                 wepent.animstate_looping = false; // we don't need to enforce idle animation
 575         else
 576         {
 577                 vector a = '0 0 0';
 578                 switch(fr)
 579                 {
 580                         default:
 581                         case WFRAME_IDLE: a = wepent.anim_idle; break;
 582                         case WFRAME_FIRE1: a = wepent.anim_fire1; break;
 583                         case WFRAME_FIRE2: a = wepent.anim_fire2; break;
 584                         case WFRAME_RELOAD: a = wepent.anim_reload; break;
 585                 }
 586                 a.z *= t;
 587                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 588         }
 589         wepent.state = ReadByte();
 590         wepent.weapon_nextthink = ReadFloat();
 591         switch (wepent.state)
 592         {
 593                 case WS_RAISE:
 594                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 595                         break;
 596                 case WS_DROP:
 597                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 598                         break;
 599         default:
 600             wepent.weapon_switchdelay = 0;
 601             break;
 602         }
 603         return true;
 604 }
 605 #endif
 606
 607 #ifdef SVQC
 608 void wframe_send(entity actor, entity weaponentity, int wepframe, float attackrate, bool restartanim)
 609 {
 610         if (!IS_REAL_CLIENT(actor)) return;
 611         int channel = MSG_ONE;
 612         msg_entity = actor;
 613         WriteHeader(channel, wframe);
 614         WriteByte(channel, wepframe);
 615         WriteFloat(channel, attackrate);
 616         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 617         WriteByte(channel, restartanim);
 618         WriteByte(channel, weaponentity.state);
 619         WriteFloat(channel, weaponentity.weapon_nextthink);
 620 }
 621 #endif
 622
 623 REGISTER_NET_C2S(w_whereis)
 624 #ifdef SVQC
 625 void Weapon_whereis(Weapon this, entity cl);
 626 NET_HANDLE(w_whereis, bool)
 627 {
 628         Weapon wpn = ReadRegistered(Weapons);
 629         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 630         return true;
 631 }
 632 #else
 633 void w_whereis(Weapon this)
 634 {
 635         int channel = MSG_C2S;
 636         WriteHeader(channel, w_whereis);
 637         WriteRegistered(Weapons, channel, this);
 638 }
 639 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 640 {
 641         switch (request)
 642         {
 643                 case CMD_REQUEST_COMMAND:
 644                 {
 645                         string s = argv(1);
 646                         if (s == "all")
 647                         {
 648                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 649                                 return;
 650                         }
 651                         if (s == "unowned")
 652                         {
 653                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 654                                 return;
 655                         }
 656                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 657                         {
 658                                 w_whereis(it);
 659                                 return;
 660                         });
 661                 }
 662                 default:
 663                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 664                 case CMD_REQUEST_USAGE:
 665                 {
 666                         LOG_HELP("Usage:^3 cl_cmd weapon_find weapon");
 667                         LOG_HELP("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.");
 668                         return;
 669                 }
 670         }
 671 }
 672 #endif
 673
 674 #ifdef SVQC
 675 void W_MuzzleFlash_Model_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 676 {
 677         flash.owner = actor;
 678         flash.angles_z = random() * 360;
 679
 680         entity view = actor.(weaponentity);
 681         entity exterior = actor.exteriorweaponentity;
 682
 683         if (view.oldorigin.x > 0)
 684         {
 685                 setattachment(flash, exterior, "");
 686                 setorigin(flash, view.oldorigin + offset);
 687         }
 688         else
 689         {
 690                 if (gettagindex(exterior, "shot")) setattachment(flash, exterior, "shot");
 691                 else setattachment(flash, exterior, "tag_shot");
 692                 setorigin(flash, offset);
 693         }
 694 }
 695 #elif defined(CSQC)
 696 void W_MuzzleFlash_Model_AttachToShotorg(entity wepent, entity flash, vector offset)
 697 {
 698         flash.owner = wepent;
 699         flash.angles_z = random() * 360;
 700
 701         if (gettagindex(wepent, "shot")) setattachment(flash, wepent, "shot");
 702         else setattachment(flash, wepent, "tag_shot");
 703         setorigin(flash, offset);
 704 }
 705 #endif
 706
 707 void W_MuzzleFlash_Model_Think(entity this)
 708 {
 709         this.frame += 2;
 710         this.scale *= 0.5;
 711         this.alpha -= 0.25;
 712         this.nextthink = time + 0.05;
 713
 714         if(this.alpha <= 0)
 715         {
 716                 setthink(this, SUB_Remove);
 717                 this.nextthink = time;
 718                 this.realowner.muzzle_flash = NULL;
 719                 return;
 720         }
 721 }
 722
 723 void W_MuzzleFlash_Model(entity wepent, entity muzzlemodel)
 724 {
 725         if(wepent.muzzle_flash == NULL)
 726                 wepent.muzzle_flash = spawn();
 727
 728         entity flash = wepent.muzzle_flash;
 729         setmodel(flash, muzzlemodel); // precision set below
 730
 731         flash.scale = 0.75;
 732         setthink(flash, W_MuzzleFlash_Model_Think);
 733         flash.nextthink = time + 0.02;
 734         flash.frame = 2;
 735         flash.alpha = 0.75;
 736         flash.angles_z = random() * 180;
 737         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
 738         flash.owner = flash.realowner = wepent;
 739
 740 #ifdef CSQC
 741         flash.drawmask = MASK_NORMAL;
 742 #endif
 743 }
 744
 745 REGISTER_NET_TEMP(w_muzzleflash)
 746
 747 #ifdef SVQC
 748 void W_MuzzleFlash(Weapon thiswep, entity actor, .entity weaponentity, vector shotorg, vector shotdir)
 749 {
 750         // don't show an exterior muzzle effect for the off-hand
 751         if(weaponslot(weaponentity) == 0)
 752         {
 753                 Send_Effect_Except(thiswep.m_muzzleeffect, shotorg, shotdir * 1000, 1, actor);
 754
 755                 if(thiswep.m_muzzlemodel != MDL_Null)
 756                 {
 757                         W_MuzzleFlash_Model(actor.exteriorweaponentity, thiswep.m_muzzlemodel);
 758                         W_MuzzleFlash_Model_AttachToShotorg(actor, weaponentity, actor.exteriorweaponentity.muzzle_flash, '5 0 0');
 759                 }
 760         }
 761
 762         FOREACH_CLIENT(it == actor || (IS_SPEC(it) && it.enemy == actor),
 763         {
 764                 if(!IS_REAL_CLIENT(it))
 765                         continue;
 766                 int channel = MSG_ONE;
 767                 msg_entity = it;
 768                 WriteHeader(channel, w_muzzleflash);
 769                 WriteByte(channel, thiswep.m_id);
 770                 WriteByte(channel, weaponslot(weaponentity));
 771                 WriteVector(channel, shotorg);
 772         });
 773 }
 774 #elif defined(CSQC)
 775 NET_HANDLE(w_muzzleflash, bool isNew)
 776 {
 777         return = true;
 778         int weapon_id = ReadByte();
 779     int slot = ReadByte();
 780     vector sv_shotorg = ReadVector();
 781
 782         Weapon thiswep = REGISTRY_GET(Weapons, weapon_id);
 783     vector viewangles = getpropertyvec(VF_CL_VIEWANGLES);
 784         vector forward, right, up;
 785         MAKE_VECTORS(viewangles, forward, right, up);
 786
 787         if(autocvar_chase_active)
 788         {
 789                 // in third person mode, show the muzzle flash from the server side weapon position
 790                 // we don't have a view model to reference in this case
 791                 pointparticles(thiswep.m_muzzleeffect, sv_shotorg, forward * 1000, 1);
 792                 return;
 793         }
 794     if(!autocvar_r_drawviewmodel) return;
 795
 796         entity wepent = viewmodels[slot];
 797         // get the local player entity to calculate shot origin
 798         entity rlplayer = CSQCModel_server2csqc(player_localentnum - 1);
 799         if(!rlplayer)
 800                 rlplayer = csqcplayer; // fall back to the global
 801
 802         vector md = wepent.movedir_aligned;
 803         vector vecs = ((md.x > 0) ? md : '0 0 0');
 804         vector dv = forward * vecs.x + right * -vecs.y + up * vecs.z;
 805         vector org = rlplayer.origin + rlplayer.view_ofs + dv;
 806
 807         pointparticles(thiswep.m_muzzleeffect, org, forward * 1000, 1);
 808
 809         if(thiswep.m_muzzlemodel != MDL_Null)
 810         {
 811                 W_MuzzleFlash_Model(wepent, thiswep.m_muzzlemodel);
 812                 W_MuzzleFlash_Model_AttachToShotorg(wepent, wepent.muzzle_flash, '5 0 0');
 813         }
 814 }
 815 #endif
 816
 817
 818 #endif
 819
 820 #endif