qcsrc/common/weapons/all.qc

   1 #include "all.qh"
   2 #ifndef WEAPONS_ALL_C
   3 #define WEAPONS_ALL_C
   4
   5 #if defined(CSQC)
   6         #include "../constants.qh"
   7         #include "../stats.qh"
   8         #include <lib/warpzone/anglestransform.qh>
   9         #include <lib/warpzone/common.qh>
  10         #include <lib/warpzone/client.qh>
  11         #include "../util.qh"
  12         #include <client/autocvars.qh>
  13         #include "../deathtypes/all.qh"
  14         #include <lib/csqcmodel/interpolate.qh>
  15         #include "../physics/movetypes/movetypes.qh"
  16         #include <client/main.qh>
  17         #include <lib/csqcmodel/cl_model.qh>
  18 #elif defined(MENUQC)
  19 #elif defined(SVQC)
  20         #include <common/items/_mod.qh>
  21         #include <lib/warpzone/anglestransform.qh>
  22         #include <lib/warpzone/common.qh>
  23         #include <lib/warpzone/util_server.qh>
  24         #include <lib/warpzone/server.qh>
  25         #include "../constants.qh"
  26         #include "../stats.qh"
  27         #include "../teams.qh"
  28         #include <common/util.qh>
  29         #include "../monsters/_mod.qh"
  30         #include "config.qh"
  31         #include <server/weapons/common.qh>
  32         #include <server/weapons/csqcprojectile.qh>
  33         #include <server/weapons/tracing.qh>
  34         #include <server/items/spawning.qh>
  35         #include <server/autocvars.qh>
  36         #include "../notifications/all.qh"
  37         #include "../deathtypes/all.qh"
  38         #include <server/mutators/_mod.qh>
  39         #include "../mapinfo.qh"
  40         #include <server/command/_mod.qh>
  41         #include <lib/csqcmodel/sv_model.qh>
  42         #include <server/portals.qh>
  43 #include <server/hook.qh>
  44 #endif
  45 #ifdef GAMEQC
  46         #include "calculations.qc"
  47 #endif
  48 #ifdef SVQC
  49         #include "config.qc"
  50 #endif
  51
  52 #include "weapon/_mod.inc"
  53
  54
  55 // WEAPON PLUGIN SYSTEM
  56
  57 WepSet _WepSet_FromWeapon(int a)
  58 {
  59         a -= WEP_FIRST;
  60         if (REGISTRY_MAX(Weapons) > 24)
  61                 if (a >= 24)
  62                 {
  63                         a -= 24;
  64                         if (REGISTRY_MAX(Weapons) > 48)
  65                                 if (a >= 24)
  66                                 {
  67                                         a -= 24;
  68                                         return '0 0 1' * (2 ** a);
  69                                 }
  70                         return '0 1 0' * (2 ** a);
  71                 }
  72         return '1 0 0' * (2 ** a);
  73 }
  74 #ifdef SVQC
  75         void WriteWepSet(float dst, WepSet w)
  76         {
  77                 if (REGISTRY_MAX(Weapons) > 48) WriteInt72_t(dst, w);
  78                 else if (REGISTRY_MAX(Weapons) > 24) WriteInt48_t(dst, w);
  79                 else WriteInt24_t(dst, w.x);
  80         }
  81 #endif
  82 #ifdef CSQC
  83         WepSet WepSet_GetFromStat()
  84         {
  85                 return STAT(WEAPONS);
  86         }
  87         WepSet WepSet_GetFromStat_InMap()
  88         {
  89                 return STAT(WEAPONSINMAP);
  90         }
  91         WepSet ReadWepSet()
  92         {
  93                 if (REGISTRY_MAX(Weapons) > 48) return ReadInt72_t();
  94                 if (REGISTRY_MAX(Weapons) > 24) return ReadInt48_t();
  95                 return ReadInt24_t() * '1 0 0';
  96         }
  97 #endif
  98
  99 string W_FixWeaponOrder(string order, float complete)
 100 {
 101         return fixPriorityList(order, WEP_FIRST, WEP_LAST, WEP_IMPULSE_BEGIN - WEP_FIRST, complete);
 102 }
 103 string W_NameWeaponOrder_MapFunc(string s)
 104 {
 105         int i = stof(s);
 106         if (s == "0" || i)
 107         {
 108                 entity wi = REGISTRY_GET(Weapons, i);
 109                 if (wi != WEP_Null) return wi.netname;
 110         }
 111         return s;
 112 }
 113
 114 string W_UndeprecateName(string s)
 115 {
 116         switch (s)
 117         {
 118                 case "nex": return "vortex";
 119                 case "rocketlauncher": return "devastator";
 120                 case "laser": return "blaster";
 121                 case "minstanex": return "vaporizer";
 122                 case "grenadelauncher": return "mortar";
 123                 case "uzi": return "machinegun";
 124                 case "hmg": return "okhmg";
 125                 case "rpc": return "okrpc";
 126                 default: return s;
 127         }
 128 }
 129 string W_NameWeaponOrder(string order)
 130 {
 131         return mapPriorityList(order, W_NameWeaponOrder_MapFunc);
 132 }
 133 string W_NumberWeaponOrder_MapFunc(string s)
 134 {
 135         if (s == "0" || stof(s)) return s;
 136         s = W_UndeprecateName(s);
 137         FOREACH(Weapons, it != WEP_Null && it.netname == s, return ftos(i));
 138         return s;
 139 }
 140 string W_NumberWeaponOrder(string order)
 141 {
 142         return mapPriorityList(order, W_NumberWeaponOrder_MapFunc);
 143 }
 144
 145 float W_FixWeaponOrder_BuildImpulseList_buf[REGISTRY_MAX(Weapons)];
 146 string W_FixWeaponOrder_BuildImpulseList_order;
 147 void W_FixWeaponOrder_BuildImpulseList_swap(int i, int j, entity pass)
 148 {
 149         float h;
 150         h = W_FixWeaponOrder_BuildImpulseList_buf[i];
 151         W_FixWeaponOrder_BuildImpulseList_buf[i] = W_FixWeaponOrder_BuildImpulseList_buf[j];
 152         W_FixWeaponOrder_BuildImpulseList_buf[j] = h;
 153 }
 154 float W_FixWeaponOrder_BuildImpulseList_cmp(int i, int j, entity pass)
 155 {
 156         int si = W_FixWeaponOrder_BuildImpulseList_buf[i];
 157         Weapon e1 = REGISTRY_GET(Weapons, si);
 158         int sj = W_FixWeaponOrder_BuildImpulseList_buf[j];
 159         Weapon e2 = REGISTRY_GET(Weapons, sj);
 160         int d = (e1.impulse + 9) % 10 - (e2.impulse + 9) % 10;
 161         if (d != 0) return -d;  // high impulse first!
 162         string s = strcat(" ", W_FixWeaponOrder_BuildImpulseList_order, " ");
 163         return strstrofs(s, sprintf(" %d ", si), 0)
 164                 - strstrofs(s, sprintf(" %d ", sj), 0); // low char index first!
 165 }
 166 string W_FixWeaponOrder_BuildImpulseList(string o)
 167 {
 168         int i;
 169         W_FixWeaponOrder_BuildImpulseList_order = o;
 170         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 171                 W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST] = i;
 172         heapsort(WEP_LAST - WEP_FIRST + 1, W_FixWeaponOrder_BuildImpulseList_swap, W_FixWeaponOrder_BuildImpulseList_cmp,
 173                 NULL);
 174         o = "";
 175         for (i = WEP_FIRST; i <= WEP_LAST; ++i)
 176                 o = strcat(o, " ", ftos(W_FixWeaponOrder_BuildImpulseList_buf[i - WEP_FIRST]));
 177         W_FixWeaponOrder_BuildImpulseList_order = string_null;
 178         return substring(o, 1, -1);
 179 }
 180
 181 string W_FixWeaponOrder_AllowIncomplete(entity this, string order)
 182 {
 183         return W_FixWeaponOrder(order, 0);
 184 }
 185
 186 string W_FixWeaponOrder_ForceComplete(string order)
 187 {
 188         if (order == "") order = W_NumberWeaponOrder(cvar_defstring("cl_weaponpriority"));
 189         return W_FixWeaponOrder(order, 1);
 190 }
 191
 192 WepSet W_RandomWeapons(entity e, WepSet remaining, int n)
 193 {
 194         WepSet result = '0 0 0';
 195         for (int j = 0; j < n; ++j)
 196         {
 197                 RandomSelection_Init();
 198                 FOREACH(Weapons, it != WEP_Null, {
 199                         if (remaining & (it.m_wepset))
 200                                 RandomSelection_AddEnt(it, 1, 1);
 201                 });
 202                 Weapon w = RandomSelection_chosen_ent;
 203                 result |= WepSet_FromWeapon(w);
 204                 remaining &= ~WepSet_FromWeapon(w);
 205         }
 206         return result;
 207 }
 208
 209 string GetAmmoPicture(int ammotype)
 210 {
 211         switch (ammotype)
 212         {
 213                 case RES_SHELLS:  return ITEM_Shells.m_icon;
 214                 case RES_BULLETS: return ITEM_Bullets.m_icon;
 215                 case RES_ROCKETS: return ITEM_Rockets.m_icon;
 216                 case RES_CELLS:   return ITEM_Cells.m_icon;
 217                 case RES_PLASMA:  return ITEM_Plasma.m_icon;
 218                 case RES_FUEL:    return ITEM_JetpackFuel.m_icon;
 219                 default: return "";  // wtf, no ammo type?
 220         }
 221 }
 222
 223 string GetAmmoName(int ammotype)
 224 {
 225         switch (ammotype)
 226         {
 227                 case RES_SHELLS:  return ITEM_Shells.m_name;
 228                 case RES_BULLETS: return ITEM_Bullets.m_name;
 229                 case RES_ROCKETS: return ITEM_Rockets.m_name;
 230                 case RES_CELLS:   return ITEM_Cells.m_name;
 231                 case RES_PLASMA:  return ITEM_Plasma.m_name;
 232                 case RES_FUEL:    return ITEM_JetpackFuel.m_name;
 233                 default:          return "batteries";
 234         }
 235 }
 236
 237 entity GetAmmoItem(int ammotype)
 238 {
 239         switch (ammotype)
 240         {
 241                 case RES_SHELLS:  return ITEM_Shells;
 242                 case RES_BULLETS: return ITEM_Bullets;
 243                 case RES_ROCKETS: return ITEM_Rockets;
 244                 case RES_CELLS:   return ITEM_Cells;
 245                 case RES_PLASMA:  return ITEM_Plasma;
 246                 case RES_FUEL:    return ITEM_JetpackFuel;
 247         }
 248         LOG_WARNF("Invalid ammo type %d ", ammotype);
 249         return NULL;
 250         // WEAPONTODO: use this generic func to reduce duplication ?
 251         // GetAmmoPicture  GetAmmoName  notif_arg_item_wepammo  ammo_pickupevalfunc ?
 252 }
 253
 254 #ifdef SVQC
 255 int GetAmmoConsumptionPrimary(string netname)
 256 // Returns ammo consumed per shot by the primary/default fire mode
 257 {
 258         switch (netname)
 259         {
 260                 case "arc":        return cvar("g_balance_arc_beam_ammo");
 261                 case "devastator": return cvar("g_balance_devastator_ammo");
 262                 case "machinegun": return cvar("g_balance_machinegun_sustained_ammo");
 263                 case "minelayer":  return cvar("g_balance_minelayer_ammo");
 264                 case "seeker":     return cvar("g_balance_seeker_tag_ammo");
 265                 default:           return cvar(strcat("g_balance_", netname, "_primary_ammo"));
 266         }
 267 }
 268 #endif
 269
 270 #ifdef CSQC
 271 int GetAmmoTypeFromNum(int i)
 272 {
 273         switch (i)
 274         {
 275                 case 0: return RES_SHELLS;
 276                 case 1: return RES_BULLETS;
 277                 case 2: return RES_ROCKETS;
 278                 case 3: return RES_CELLS;
 279                 case 4: return RES_PLASMA;
 280                 case 5: return RES_FUEL;
 281                 default: return RES_NONE;
 282         }
 283 }
 284
 285 int GetAmmoStat(int ammotype)
 286 {
 287         switch (ammotype)
 288         {
 289                 case RES_SHELLS: return STAT_SHELLS;
 290                 case RES_BULLETS: return STAT_NAILS;
 291                 case RES_ROCKETS: return STAT_ROCKETS;
 292                 case RES_CELLS: return STAT_CELLS;
 293                 case RES_PLASMA: return STAT_PLASMA.m_id;
 294                 case RES_FUEL: return STAT_FUEL.m_id;
 295                 default: return -1;
 296         }
 297 }
 298 #endif
 299
 300 string W_Sound(string w_snd)
 301 {
 302         string output = strcat("weapons/", w_snd);
 303         MUTATOR_CALLHOOK(WeaponSound, w_snd, output);
 304         return M_ARGV(1, string);
 305 }
 306
 307 string W_Model(string w_mdl)
 308 {
 309         string output = strcat("models/weapons/", w_mdl);
 310         MUTATOR_CALLHOOK(WeaponModel, w_mdl, output);
 311         return M_ARGV(1, string);
 312 }
 313
 314 #ifdef GAMEQC
 315 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
 316 {
 317         switch (algn)
 318         {
 319                 default:
 320                 case 3:
 321                         // right alignment
 322                         break;
 323                 case 4:
 324                         // left
 325                         vecs.y = -vecs.y;
 326                         break;
 327                 case 1:
 328                 case 2:
 329                         // center
 330                         vecs.y = 0;
 331                         vecs.z -= 2;
 332                         break;
 333         }
 334         return vecs;
 335 }
 336
 337 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
 338 {
 339         string s;
 340         if (visual)
 341         {
 342                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 343         }
 344         else if (STAT(SHOOTFROMEYE))
 345         {
 346                 vecs.y = vecs.z = 0;
 347         }
 348         else if (STAT(SHOOTFROMCENTER))
 349         {
 350                 vecs.y = 0;
 351                 vecs.z -= 2;
 352         }
 353         else if ((s = G_SHOOTFROMFIXEDORIGIN) != "")
 354         {
 355                 vector v = stov(s);
 356                 if (y_is_right) v.y = -v.y;
 357                 if (v.x != 0) vecs.x = v.x;
 358                 vecs.y = v.y;
 359                 vecs.z = v.z;
 360         }
 361         else  // just do the same as top
 362         {
 363                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
 364         }
 365
 366         return vecs;
 367 }
 368
 369 #define shotorg_adjust shotorg_adjust_values
 370
 371 /**
 372  * supported formats:
 373  *
 374  * 1. simple animated model, muzzle flash handling on h_ model:
 375  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 376  *      tags:
 377  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 378  *        shell = casings ejection point (must be on the right hand side of the gun)
 379  *        weapon = attachment for v_tuba.md3
 380  *    v_tuba.md3 - first and third person model
 381  *    g_tuba.md3 - pickup model
 382  *
 383  * 2. simple animated model, muzzle flash handling on v_ model:
 384  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 385  *      tags:
 386  *        weapon = attachment for v_tuba.md3
 387  *    v_tuba.md3 - first and third person model
 388  *      tags:
 389  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 390  *        shell = casings ejection point (must be on the right hand side of the gun)
 391  *    g_tuba.md3 - pickup model
 392  *
 393  * 3. fully animated model, muzzle flash handling on h_ model:
 394  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 395  *      tags:
 396  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 397  *        shell = casings ejection point (must be on the right hand side of the gun)
 398  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 399  *    v_tuba.md3 - third person model
 400  *    g_tuba.md3 - pickup model
 401  *
 402  * 4. fully animated model, muzzle flash handling on v_ model:
 403  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 404  *      tags:
 405  *        shot = muzzle end (shot origin)
 406  *        shell = casings ejection point (must be on the right hand side of the gun)
 407  *    v_tuba.md3 - third person model
 408  *      tags:
 409  *        shot = muzzle end (for muzzle flashes)
 410  *    g_tuba.md3 - pickup model
 411  *
 412  * writes:
 413  *   this.origin, this.angles
 414  *   this.weaponchild
 415  *   this.movedir, this.view_ofs, this.movedir_aligned
 416  *   attachment stuff
 417  *   anim stuff
 418  * to free:
 419  *   call again with ""
 420  *   remove the ent
 421  */
 422 void CL_WeaponEntity_SetModel(entity this, string name, bool _anim)
 423 {
 424         if (name == "")
 425         {
 426                 vector oldmin = this.mins, oldmax = this.maxs;
 427                 setmodel(this, MDL_Null);
 428                 setsize(this, oldmin, oldmax);
 429                 if (this.weaponchild) delete(this.weaponchild);
 430                 this.weaponchild = NULL;
 431                 this.movedir = '0 0 0';
 432                 this.spawnorigin = '0 0 0';
 433                 this.oldorigin = '0 0 0';
 434                 this.anim_fire1  = '0 1 0.01';
 435                 this.anim_fire2  = '0 1 0.01';
 436                 this.anim_idle   = '0 1 0.01';
 437                 this.anim_reload = '0 1 0.01';
 438         }
 439         else
 440         {
 441                 // if there is a child entity, hide it until we're sure we use it
 442                 if (this.weaponchild) this.weaponchild.model = "";
 443                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 444                 int v_shot_idx;  // used later
 445                 (v_shot_idx = gettagindex(this, "shot")) || (v_shot_idx = gettagindex(this, "tag_shot"));
 446
 447                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 448                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 449                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 450                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 451                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 452                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 453
 454                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 455                 // if we don't, this is a "real" animated model
 456                 string t;
 457                 if ((t = "weapon", gettagindex(this, t)) || (t = "tag_weapon", gettagindex(this, t)))
 458                 {
 459                         if (!this.weaponchild)
 460                         {
 461                                 this.weaponchild = new(weaponchild);
 462 #ifdef CSQC
 463                                 this.weaponchild.drawmask = MASK_NORMAL;
 464                                 this.weaponchild.renderflags |= RF_VIEWMODEL;
 465 #endif
 466                         }
 467                         _setmodel(this.weaponchild, W_Model(strcat("v_", name, ".md3")));
 468                         setsize(this.weaponchild, '0 0 0', '0 0 0');
 469                         setattachment(this.weaponchild, this, t);
 470                 }
 471                 else
 472                 {
 473                         if (this.weaponchild) delete(this.weaponchild);
 474                         this.weaponchild = NULL;
 475                 }
 476
 477                 setsize(this, '0 0 0', '0 0 0');
 478                 setorigin(this, '0 0 0');
 479                 this.angles = '0 0 0';
 480                 this.frame = 0;
 481 #ifdef SVQC
 482                 this.viewmodelforclient = NULL;
 483 #else
 484                 this.renderflags &= ~RF_VIEWMODEL;
 485 #endif
 486                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 487                 {
 488                         this.movedir = gettaginfo(this.weaponchild, v_shot_idx);
 489                 }
 490                 else
 491                 {
 492                         int idx;
 493                         if ((idx = gettagindex(this, "shot")) || (idx = gettagindex(this, "tag_shot")))
 494                         {
 495                                 this.movedir = gettaginfo(this, idx);
 496                         }
 497                         else
 498                         {
 499                                 LOG_WARNF("weapon model %s does not support the 'shot' tag, will display shots TOTALLY wrong",
 500                                         this.model);
 501                                 this.movedir = '0 0 0';
 502                         }
 503                 }
 504                 {
 505                         int idx = 0;
 506                         // v_ model attached to invisible h_ model
 507                         if (this.weaponchild
 508                                 && ((idx = gettagindex(this.weaponchild, "shell")) || (idx = gettagindex(this.weaponchild, "tag_shell"))))
 509                         {
 510                                 this.spawnorigin = gettaginfo(this.weaponchild, idx);
 511                         }
 512                         else if ((idx = gettagindex(this, "shell")) || (idx = gettagindex(this, "tag_shell")))
 513                         {
 514                                 this.spawnorigin = gettaginfo(this, idx);
 515                         }
 516                         else
 517                         {
 518                                 LOG_WARNF("weapon model %s does not support the 'shell' tag, will display casings wrong",
 519                                         this.model);
 520                                 this.spawnorigin = this.movedir;
 521                         }
 522                 }
 523                 if (v_shot_idx)
 524                 {
 525                         this.oldorigin = '0 0 0';  // use regular attachment
 526                 }
 527                 else
 528                 {
 529                         int idx;
 530                         if (this.weaponchild)
 531                                 (idx = gettagindex(this, "weapon")) || (idx = gettagindex(this, "tag_weapon"));
 532                         else
 533                                 (idx = gettagindex(this, "handle")) || (idx = gettagindex(this, "tag_handle"));
 534                         if (idx)
 535                         {
 536                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 537                         }
 538                         else
 539                         {
 540                                 LOG_WARNF(
 541                                         "weapon model %s does not support the 'handle' tag "
 542                                         "and neither does the v_ model support the 'shot' tag, "
 543                                         "will display muzzle flashes TOTALLY wrong\n",
 544                                         this.model);
 545                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 546                         }
 547                 }
 548
 549 #ifdef SVQC
 550                 this.viewmodelforclient = this.owner;
 551 #else
 552                 this.renderflags |= RF_VIEWMODEL;
 553 #endif
 554         }
 555
 556         this.view_ofs = '0 0 0';
 557         this.movedir_aligned = this.movedir;
 558
 559         if (this.movedir.x >= 0)
 560         {
 561                 //int algn = STAT(GUNALIGN, this.owner);
 562                 int algn = W_GunAlign(this, STAT(GUNALIGN, this.owner));
 563         #ifdef SVQC
 564                 this.m_gunalign = algn;
 565         #endif
 566                 vector v = this.movedir;
 567                 this.movedir = shotorg_adjust(v, false, false, algn);
 568                 this.movedir_aligned = shotorg_adjust(v, false, true, algn);
 569                 this.view_ofs = shotorg_adjust(v, false, true, algn) - v;
 570         }
 571         int compressed_shotorg = compressShotOrigin(this.movedir);
 572         // make them match perfectly
 573 #ifdef SVQC
 574         // null during init
 575         if (this.owner) STAT(SHOTORG, this.owner) = compressed_shotorg;
 576 #endif
 577         this.movedir = decompressShotOrigin(compressed_shotorg);
 578
 579         this.spawnorigin += this.view_ofs;  // offset the casings origin by the same amount
 580
 581         // check if an instant weapon switch occurred
 582         setorigin(this, this.view_ofs);
 583         if (!_anim) return;
 584         // reset animstate now
 585         this.wframe = WFRAME_IDLE;
 586         setanim(this, this.anim_idle, true, false, true);
 587 }
 588 #endif
 589
 590 #ifdef GAMEQC
 591
 592 REGISTER_NET_TEMP(wframe)
 593 #ifdef CSQC
 594 NET_HANDLE(wframe, bool isNew)
 595 {
 596         WFRAME fr = ReadByte();
 597         float t = ReadFloat();
 598         int slot = ReadByte();
 599         bool restartanim = ReadByte();
 600         entity wepent = viewmodels[slot];
 601         if(fr == WFRAME_IDLE)
 602                 wepent.animstate_looping = false; // we don't need to enforce idle animation
 603         else
 604         {
 605                 vector a = '0 0 0';
 606                 switch(fr)
 607                 {
 608                         default:
 609                         case WFRAME_IDLE: a = wepent.anim_idle; break;
 610                         case WFRAME_FIRE1: a = wepent.anim_fire1; break;
 611                         case WFRAME_FIRE2: a = wepent.anim_fire2; break;
 612                         case WFRAME_RELOAD: a = wepent.anim_reload; break;
 613                 }
 614                 a.z *= t;
 615                 anim_set(wepent, a, !restartanim, restartanim, restartanim);
 616         }
 617         wepent.state = ReadByte();
 618         wepent.weapon_nextthink = ReadFloat();
 619         switch (wepent.state)
 620         {
 621                 case WS_RAISE:
 622                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_raise;
 623                         break;
 624                 case WS_DROP:
 625                         wepent.weapon_switchdelay = wepent.activeweapon.switchdelay_drop;
 626                         break;
 627                 default:
 628                         wepent.weapon_switchdelay = 0;
 629                         break;
 630         }
 631         return true;
 632 }
 633 #endif
 634
 635 #ifdef SVQC
 636 void wframe_send(entity actor, entity weaponentity, int wepframe, float attackrate, bool restartanim)
 637 {
 638         if (!IS_REAL_CLIENT(actor)) return;
 639         int channel = MSG_ONE;
 640         msg_entity = actor;
 641         WriteHeader(channel, wframe);
 642         WriteByte(channel, wepframe);
 643         WriteFloat(channel, attackrate);
 644         WriteByte(channel, weaponslot(weaponentity.weaponentity_fld));
 645         WriteByte(channel, restartanim);
 646         WriteByte(channel, weaponentity.state);
 647         WriteFloat(channel, weaponentity.weapon_nextthink);
 648 }
 649 #endif
 650
 651 REGISTER_NET_C2S(w_whereis)
 652 #ifdef SVQC
 653 void Weapon_whereis(Weapon this, entity cl);
 654 NET_HANDLE(w_whereis, bool)
 655 {
 656         Weapon wpn = ReadRegistered(Weapons);
 657         if (wpn != WEP_Null) Weapon_whereis(wpn, sender);
 658         return true;
 659 }
 660 #else
 661 void w_whereis(Weapon this)
 662 {
 663         int channel = MSG_C2S;
 664         WriteHeader(channel, w_whereis);
 665         WriteRegistered(Weapons, channel, this);
 666 }
 667 CLIENT_COMMAND(weapon_find, "Show spawn locations of a weapon")
 668 {
 669         switch (request)
 670         {
 671                 case CMD_REQUEST_COMMAND:
 672                 {
 673                         string s = argv(1);
 674                         if (s == "all")
 675                         {
 676                                 FOREACH(Weapons, it != WEP_Null, w_whereis(it));
 677                                 return;
 678                         }
 679                         if (s == "unowned")
 680                         {
 681                                 FOREACH(Weapons, it != WEP_Null && !(STAT(WEAPONS) & it.m_wepset), w_whereis(it));
 682                                 return;
 683                         }
 684                         FOREACH(Weapons, it != WEP_Null && it.netname == s,
 685                         {
 686                                 w_whereis(it);
 687                                 return;
 688                         });
 689                 }
 690                 default:
 691                         LOG_INFOF("Incorrect parameters for ^2%s^7", argv(0));
 692                 case CMD_REQUEST_USAGE:
 693                 {
 694                         LOG_HELP("Usage:^3 cl_cmd weapon_find weapon");
 695                         LOG_HELP("  Where 'weapon' is the lowercase weapon name, 'all' or 'unowned'.");
 696                         return;
 697                 }
 698         }
 699 }
 700 #endif
 701
 702 #ifdef SVQC
 703 void W_MuzzleFlash_Model_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 704 {
 705         flash.owner = actor;
 706         flash.angles_z = random() * 360;
 707
 708         entity view = actor.(weaponentity);
 709         entity exterior = actor.exteriorweaponentity;
 710
 711         if (view.oldorigin.x > 0)
 712         {
 713                 setattachment(flash, exterior, "");
 714                 setorigin(flash, view.oldorigin + offset);
 715         }
 716         else
 717         {
 718                 if (gettagindex(exterior, "shot")) setattachment(flash, exterior, "shot");
 719                 else setattachment(flash, exterior, "tag_shot");
 720                 setorigin(flash, offset);
 721         }
 722 }
 723 #elif defined(CSQC)
 724 void W_MuzzleFlash_Model_AttachToShotorg(entity wepent, entity flash, vector offset)
 725 {
 726         flash.owner = wepent;
 727         flash.angles_z = random() * 360;
 728
 729         if (gettagindex(wepent, "shot")) setattachment(flash, wepent, "shot");
 730         else setattachment(flash, wepent, "tag_shot");
 731         setorigin(flash, offset);
 732 }
 733 #endif
 734
 735 void W_MuzzleFlash_Model_Think(entity this)
 736 {
 737         this.frame += 2;
 738         this.scale *= 0.5;
 739         this.alpha -= 0.25;
 740         this.nextthink = time + 0.05;
 741
 742         if(this.alpha <= 0)
 743         {
 744                 setthink(this, SUB_Remove);
 745                 this.nextthink = time;
 746                 this.realowner.muzzle_flash = NULL;
 747                 return;
 748         }
 749 }
 750
 751 void W_MuzzleFlash_Model(entity wepent, entity muzzlemodel)
 752 {
 753         if(wepent.muzzle_flash == NULL)
 754                 wepent.muzzle_flash = spawn();
 755
 756         entity flash = wepent.muzzle_flash;
 757         setmodel(flash, muzzlemodel); // precision set below
 758
 759         flash.scale = 0.75;
 760         setthink(flash, W_MuzzleFlash_Model_Think);
 761         flash.nextthink = time + 0.02;
 762         flash.frame = 2;
 763         flash.alpha = 0.75;
 764         flash.angles_z = random() * 180;
 765         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
 766         flash.owner = flash.realowner = wepent;
 767
 768 #ifdef CSQC
 769         flash.drawmask = MASK_NORMAL;
 770 #endif
 771 }
 772
 773 REGISTER_NET_TEMP(w_muzzleflash)
 774
 775 #ifdef SVQC
 776 void W_MuzzleFlash(Weapon thiswep, entity actor, .entity weaponentity, vector shotorg, vector shotdir)
 777 {
 778         // don't show an exterior muzzle effect for the off-hand
 779         if(weaponslot(weaponentity) == 0)
 780         {
 781                 Send_Effect_Except(thiswep.m_muzzleeffect, shotorg, shotdir * 1000, 1, actor);
 782
 783                 if(thiswep.m_muzzlemodel != MDL_Null)
 784                 {
 785                         W_MuzzleFlash_Model(actor.exteriorweaponentity, thiswep.m_muzzlemodel);
 786                         W_MuzzleFlash_Model_AttachToShotorg(actor, weaponentity, actor.exteriorweaponentity.muzzle_flash, '5 0 0');
 787                 }
 788         }
 789
 790         FOREACH_CLIENT(it == actor || (IS_SPEC(it) && it.enemy == actor),
 791         {
 792                 if(!IS_REAL_CLIENT(it))
 793                         continue;
 794                 int channel = MSG_ONE;
 795                 msg_entity = it;
 796                 WriteHeader(channel, w_muzzleflash);
 797                 WriteByte(channel, thiswep.m_id);
 798                 WriteByte(channel, weaponslot(weaponentity));
 799                 WriteVector(channel, shotorg);
 800         });
 801 }
 802 #elif defined(CSQC)
 803 NET_HANDLE(w_muzzleflash, bool isNew)
 804 {
 805         return = true;
 806         int weapon_id = ReadByte();
 807         int slot = ReadByte();
 808         vector sv_shotorg = ReadVector();
 809
 810         Weapon thiswep = REGISTRY_GET(Weapons, weapon_id);
 811         vector viewangles = getpropertyvec(VF_CL_VIEWANGLES);
 812         vector forward, right, up;
 813         MAKE_VECTORS(viewangles, forward, right, up);
 814
 815         if(autocvar_chase_active)
 816         {
 817                 // in third person mode, show the muzzle flash from the server side weapon position
 818                 // we don't have a view model to reference in this case
 819                 pointparticles(thiswep.m_muzzleeffect, sv_shotorg, forward * 1000, 1);
 820                 return;
 821         }
 822         if(!autocvar_r_drawviewmodel) return;
 823
 824         entity wepent = viewmodels[slot];
 825         // get the local player entity to calculate shot origin
 826         entity rlplayer = CSQCModel_server2csqc(player_localentnum - 1);
 827         if(!rlplayer)
 828                 rlplayer = csqcplayer; // fall back to the global
 829
 830         vector md = wepent.movedir_aligned;
 831         vector vecs = ((md.x > 0) ? md : '0 0 0');
 832         vector dv = forward * vecs.x + right * -vecs.y + up * vecs.z;
 833         vector org = rlplayer.origin + rlplayer.view_ofs + dv;
 834
 835         pointparticles(thiswep.m_muzzleeffect, org, forward * 1000, 1);
 836
 837         if(thiswep.m_muzzlemodel != MDL_Null)
 838         {
 839                 W_MuzzleFlash_Model(wepent, thiswep.m_muzzlemodel);
 840                 W_MuzzleFlash_Model_AttachToShotorg(wepent, wepent.muzzle_flash, '5 0 0');
 841         }
 842 }
 843 #endif
 844
 845
 846 #endif
 847
 848 #endif