qcsrc/common/weapons/w_arc.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ ARC,
   4 /* function  */ W_Arc,
   5 /* ammotype  */ ammo_cells,
   6 /* impulse   */ 3,
   7 /* flags     */ WEP_FLAG_NORMAL,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '1 1 1',
  10 /* modelname */ "arc",
  11 /* simplemdl */ "foobar",
  12 /* crosshair */ "gfx/crosshairhlac 0.7",
  13 /* wepimg    */ "weaponarc",
  14 /* refname   */ "arc",
  15 /* wepname   */ _("Arc")
  16 );
  17
  18 #define ARC_SETTINGS(w_cvar,w_prop) ARC_SETTINGS_LIST(w_cvar, w_prop, ARC, arc)
  19 #define ARC_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  20         w_cvar(id, sn, NONE, beam_ammo) \
  21         w_cvar(id, sn, NONE, beam_animtime) \
  22         w_cvar(id, sn, NONE, beam_botaimspeed) \
  23         w_cvar(id, sn, NONE, beam_botaimlifetime) \
  24         w_cvar(id, sn, NONE, beam_damage) \
  25         w_cvar(id, sn, NONE, beam_degreespersegment) \
  26         w_cvar(id, sn, NONE, beam_distancepersegment) \
  27         w_cvar(id, sn, NONE, beam_falloff_halflifedist) \
  28         w_cvar(id, sn, NONE, beam_falloff_maxdist) \
  29         w_cvar(id, sn, NONE, beam_falloff_mindist) \
  30         w_cvar(id, sn, NONE, beam_force) \
  31         w_cvar(id, sn, NONE, beam_healing_amax) \
  32         w_cvar(id, sn, NONE, beam_healing_aps) \
  33         w_cvar(id, sn, NONE, beam_healing_hmax) \
  34         w_cvar(id, sn, NONE, beam_healing_hps) \
  35         w_cvar(id, sn, NONE, beam_maxangle) \
  36         w_cvar(id, sn, NONE, beam_nonplayerdamage) \
  37         w_cvar(id, sn, NONE, beam_range) \
  38         w_cvar(id, sn, NONE, beam_refire) \
  39         w_cvar(id, sn, NONE, beam_returnspeed) \
  40         w_cvar(id, sn, NONE, beam_tightness) \
  41         w_cvar(id, sn, NONE, burst_ammo) \
  42         w_cvar(id, sn, NONE, burst_damage) \
  43         w_cvar(id, sn, NONE, burst_healing_aps) \
  44         w_cvar(id, sn, NONE, burst_healing_hps) \
  45         w_cvar(id, sn, NONE, overheat_max)/* maximum heat before jamming */ \
  46         w_cvar(id, sn, NONE, overheat_min)/* minimum heat to wait for cooldown */ \
  47         w_cvar(id, sn, NONE, beam_heat)   /* heat increase per second (primary) */ \
  48         w_cvar(id, sn, NONE, burst_heat)  /* heat increase per second (secondary) */ \
  49         w_cvar(id, sn, NONE, cooldown)    /* heat decrease per second when resting */ \
  50         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  51         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  52         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  53         w_prop(id, sn, float,  weaponstart, weaponstart) \
  54         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  55         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  56
  57 #ifndef MENUQC
  58 const float ARC_MAX_SEGMENTS = 20;
  59 vector arc_shotorigin[4];
  60 .vector beam_start;
  61 .vector beam_dir;
  62 .vector beam_wantdir;
  63 .int beam_type;
  64
  65 const int ARC_BT_MISS =        0x00;
  66 const int ARC_BT_WALL =        0x01;
  67 const int ARC_BT_HEAL =        0x02;
  68 const int ARC_BT_HIT =         0x03;
  69 const int ARC_BT_BURST_MISS =  0x10;
  70 const int ARC_BT_BURST_WALL =  0x11;
  71 const int ARC_BT_BURST_HEAL =  0x12;
  72 const int ARC_BT_BURST_HIT =   0x13;
  73 const int ARC_BT_BURSTMASK =   0x10;
  74
  75 const int ARC_SF_SETTINGS =    1;
  76 const int ARC_SF_START =       2;
  77 const int ARC_SF_WANTDIR =     4;
  78 const int ARC_SF_BEAMDIR =     8;
  79 const int ARC_SF_BEAMTYPE =    16;
  80 const int ARC_SF_LOCALMASK =   14;
  81 #endif
  82 #ifdef SVQC
  83 ARC_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  84 .entity arc_beam;
  85 .float arc_BUTTON_ATCK_prev; // for better animation control
  86 .float beam_prev;
  87 .float beam_initialized;
  88 .float beam_bursting;
  89 .float beam_teleporttime;
  90 .float beam_heat; // (beam) amount of heat produced
  91 .float arc_overheat; // (dropped arc/player) time during which it's too hot
  92 .float arc_cooldown; // (dropped arc/player) cooling speed
  93 .float arc_heat_percent; // (player) arc heat in [0,1] (stat)
  94 .float arc_smoke_sound;
  95 #endif
  96 #ifdef CSQC
  97 void Ent_ReadArcBeam(float isnew);
  98
  99 .vector beam_color;
 100 .float beam_alpha;
 101 .float beam_thickness;
 102 .float beam_traileffect;
 103 .float beam_hiteffect;
 104 .float beam_hitlight[4]; // 0: radius, 123: rgb
 105 .float beam_muzzleeffect;
 106 .float beam_muzzlelight[4]; // 0: radius, 123: rgb
 107 .string beam_image;
 108
 109 .entity beam_muzzleentity;
 110
 111 .float beam_degreespersegment;
 112 .float beam_distancepersegment;
 113 .float beam_usevieworigin;
 114 .float beam_initialized;
 115 .float beam_maxangle;
 116 .float beam_range;
 117 .float beam_returnspeed;
 118 .float beam_tightness;
 119 .vector beam_shotorigin;
 120
 121 entity Draw_ArcBeam_callback_entity;
 122 float Draw_ArcBeam_callback_last_thickness;
 123 vector Draw_ArcBeam_callback_last_top; // NOTE: in same coordinate system as player.
 124 vector Draw_ArcBeam_callback_last_bottom; // NOTE: in same coordinate system as player.
 125 #endif
 126 #endif
 127 #ifdef IMPLEMENTATION
 128 #ifdef SVQC
 129 void spawnfunc_weapon_arc(void) { weapon_defaultspawnfunc(WEP_ARC.m_id); }
 130
 131 float W_Arc_Beam_Send(entity to, int sf)
 132 {
 133         WriteByte(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
 134
 135         // Truncate information when this beam is displayed to the owner client
 136         // - The owner client has no use for beam start position or directions,
 137         //    it always figures this information out for itself with csqc code.
 138         // - Spectating the owner also truncates this information.
 139         float drawlocal = ((to == self.owner) || ((to.enemy == self.owner) && IS_SPEC(to)));
 140         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
 141
 142         WriteByte(MSG_ENTITY, sf);
 143
 144         if(sf & ARC_SF_SETTINGS) // settings information
 145         {
 146                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
 147                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
 148                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
 149                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
 150                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
 151                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
 152
 153                 WriteByte(MSG_ENTITY, drawlocal);
 154         }
 155         if(sf & ARC_SF_START) // starting location
 156         {
 157                 WriteCoord(MSG_ENTITY, self.beam_start.x);
 158                 WriteCoord(MSG_ENTITY, self.beam_start.y);
 159                 WriteCoord(MSG_ENTITY, self.beam_start.z);
 160         }
 161         if(sf & ARC_SF_WANTDIR) // want/aim direction
 162         {
 163                 WriteCoord(MSG_ENTITY, self.beam_wantdir.x);
 164                 WriteCoord(MSG_ENTITY, self.beam_wantdir.y);
 165                 WriteCoord(MSG_ENTITY, self.beam_wantdir.z);
 166         }
 167         if(sf & ARC_SF_BEAMDIR) // beam direction
 168         {
 169                 WriteCoord(MSG_ENTITY, self.beam_dir.x);
 170                 WriteCoord(MSG_ENTITY, self.beam_dir.y);
 171                 WriteCoord(MSG_ENTITY, self.beam_dir.z);
 172         }
 173         if(sf & ARC_SF_BEAMTYPE) // beam type
 174         {
 175                 WriteByte(MSG_ENTITY, self.beam_type);
 176         }
 177
 178         return true;
 179 }
 180
 181 void Reset_ArcBeam(entity player, vector forward)
 182 {
 183         if (!player.arc_beam) {
 184                 return;
 185         }
 186         player.arc_beam.beam_dir = forward;
 187         player.arc_beam.beam_teleporttime = time;
 188 }
 189
 190 float Arc_GetHeat_Percent(entity player)
 191 {
 192         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
 193         {
 194                 player.arc_overheat = 0;
 195                 return 0;
 196         }
 197
 198         if ( player.arc_beam )
 199                 return player.arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
 200
 201         if ( player.arc_overheat > time )
 202         {
 203                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
 204                         * player.arc_cooldown;
 205         }
 206
 207         return 0;
 208 }
 209 void Arc_Player_SetHeat(entity player)
 210 {
 211         player.arc_heat_percent = Arc_GetHeat_Percent(player);
 212         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
 213 }
 214
 215 void W_Arc_Beam_Think(void)
 216 {
 217         if(self != self.owner.arc_beam)
 218         {
 219                 remove(self);
 220                 return;
 221         }
 222
 223
 224         float burst = 0;
 225         if( self.owner.BUTTON_ATCK2 || self.beam_bursting)
 226         {
 227                 if(!self.beam_bursting)
 228                         self.beam_bursting = true;
 229                 burst = ARC_BT_BURSTMASK;
 230         }
 231
 232         if(
 233                 !IS_PLAYER(self.owner)
 234                 ||
 235                 (self.owner.WEP_AMMO(ARC) <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 236                 ||
 237                 self.owner.deadflag != DEAD_NO
 238                 ||
 239                 (!self.owner.BUTTON_ATCK && !burst )
 240                 ||
 241                 self.owner.frozen
 242                 ||
 243                 self.owner.vehicle
 244                 ||
 245                 (WEP_CVAR(arc, overheat_max) > 0 && self.beam_heat >= WEP_CVAR(arc, overheat_max))
 246         )
 247         {
 248                 if ( WEP_CVAR(arc, cooldown) > 0 )
 249                 {
 250                         float cooldown_speed = 0;
 251                         if ( self.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 252                         {
 253                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 254                         }
 255                         else if ( !burst )
 256                         {
 257                                 cooldown_speed = self.beam_heat / WEP_CVAR(arc, beam_refire);
 258                         }
 259
 260                         if ( cooldown_speed )
 261                         {
 262                                 self.owner.arc_overheat = time + self.beam_heat / cooldown_speed;
 263                                 self.owner.arc_cooldown = cooldown_speed;
 264                         }
 265
 266                         if ( WEP_CVAR(arc, overheat_max) > 0 && self.beam_heat >= WEP_CVAR(arc, overheat_max) )
 267                         {
 268                                 pointparticles( particleeffectnum("arc_overheat"),
 269                                         self.beam_start, self.beam_wantdir, 1 );
 270                                 sound(self, CH_WEAPON_A, "weapons/arc_stop.wav", VOL_BASE, ATTN_NORM);
 271                         }
 272                 }
 273
 274                 if(self == self.owner.arc_beam) { self.owner.arc_beam = world; }
 275                 entity oldself = self;
 276                 self = self.owner;
 277                 if(!WEP_ACTION(WEP_ARC.m_id, WR_CHECKAMMO1) && !WEP_ACTION(WEP_ARC.m_id, WR_CHECKAMMO2))
 278                 if(!(self.items & IT_UNLIMITED_WEAPON_AMMO))
 279                 {
 280                         // note: this doesn't force the switch
 281                         W_SwitchToOtherWeapon(self);
 282                 }
 283                 self = oldself;
 284                 remove(self);
 285                 return;
 286         }
 287
 288         // decrease ammo
 289         float coefficient = frametime;
 290         if(!(self.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 291         {
 292                 float rootammo;
 293                 if(burst)
 294                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 295                 else
 296                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 297
 298                 if(rootammo)
 299                 {
 300                         coefficient = min(coefficient, self.owner.WEP_AMMO(ARC) / rootammo);
 301                         self.owner.WEP_AMMO(ARC) = max(0, self.owner.WEP_AMMO(ARC) - (rootammo * frametime));
 302                 }
 303         }
 304         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 305         self.beam_heat = min( WEP_CVAR(arc, overheat_max), self.beam_heat + heat_speed*frametime );
 306
 307         makevectors(self.owner.v_angle);
 308
 309         W_SetupShot_Range(
 310                 self.owner,
 311                 true,
 312                 0,
 313                 "",
 314                 0,
 315                 WEP_CVAR(arc, beam_damage) * coefficient,
 316                 WEP_CVAR(arc, beam_range)
 317         );
 318
 319         // After teleport, "lock" the beam until the teleport is confirmed.
 320         if (time < self.beam_teleporttime + ANTILAG_LATENCY(self.owner)) {
 321                 w_shotdir = self.beam_dir;
 322         }
 323
 324         // network information: shot origin and want/aim direction
 325         if(self.beam_start != w_shotorg)
 326         {
 327                 self.SendFlags |= ARC_SF_START;
 328                 self.beam_start = w_shotorg;
 329         }
 330         if(self.beam_wantdir != w_shotdir)
 331         {
 332                 self.SendFlags |= ARC_SF_WANTDIR;
 333                 self.beam_wantdir = w_shotdir;
 334         }
 335
 336         if(!self.beam_initialized)
 337         {
 338                 self.beam_dir = w_shotdir;
 339                 self.beam_initialized = true;
 340         }
 341
 342         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 343         // idea: blend together self.beam_dir with the inverted direction the player is moving in
 344         // might have to make some special accomodation so that it only uses view_right and view_up
 345
 346         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 347
 348         float segments;
 349         if(self.beam_dir != w_shotdir)
 350         {
 351                 // calculate how much we're going to move the end of the beam to the want position
 352                 // WEAPONTODO (server and client):
 353                 // blendfactor never actually becomes 0 in this situation, which is a problem
 354                 // regarding precision... this means that self.beam_dir and w_shotdir approach
 355                 // eachother, however they never actually become the same value with this method.
 356                 // Perhaps we should do some form of rounding/snapping?
 357                 float angle = vlen(w_shotdir - self.beam_dir) * RAD2DEG;
 358                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 359                 {
 360                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 361                         float blendfactor = bound(
 362                                 0,
 363                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 364                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 365                         );
 366                         self.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 367                 }
 368                 else
 369                 {
 370                         // the radius is not too far yet, no worries :D
 371                         float blendfactor = bound(
 372                                 0,
 373                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 374                                 1
 375                         );
 376                         self.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 377                 }
 378
 379                 // network information: beam direction
 380                 self.SendFlags |= ARC_SF_BEAMDIR;
 381
 382                 // calculate how many segments are needed
 383                 float max_allowed_segments;
 384
 385                 if(WEP_CVAR(arc, beam_distancepersegment))
 386                 {
 387                         max_allowed_segments = min(
 388                                 ARC_MAX_SEGMENTS,
 389                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 390                         );
 391                 }
 392                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 393
 394                 if(WEP_CVAR(arc, beam_degreespersegment))
 395                 {
 396                         segments = bound(
 397                                 1,
 398                                 (
 399                                         min(
 400                                                 angle,
 401                                                 WEP_CVAR(arc, beam_maxangle)
 402                                         )
 403                                         /
 404                                         WEP_CVAR(arc, beam_degreespersegment)
 405                                 ),
 406                                 max_allowed_segments
 407                         );
 408                 }
 409                 else { segments = 1; }
 410         }
 411         else { segments = 1; }
 412
 413         vector beam_endpos = (w_shotorg + (self.beam_dir * WEP_CVAR(arc, beam_range)));
 414         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 415
 416         float i;
 417         float new_beam_type = 0;
 418         vector last_origin = w_shotorg;
 419         for(i = 1; i <= segments; ++i)
 420         {
 421                 // WEAPONTODO (client):
 422                 // In order to do nice fading and pointing on the starting segment, we must always
 423                 // have that drawn as a separate triangle... However, that is difficult to do when
 424                 // keeping in mind the above problems and also optimizing the amount of segments
 425                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 426
 427                 vector new_origin = bezier_quadratic_getpoint(
 428                         w_shotorg,
 429                         beam_controlpoint,
 430                         beam_endpos,
 431                         i / segments);
 432                 vector new_dir = normalize(new_origin - last_origin);
 433
 434                 WarpZone_traceline_antilag(
 435                         self.owner,
 436                         last_origin,
 437                         new_origin,
 438                         MOVE_NORMAL,
 439                         self.owner,
 440                         ANTILAG_LATENCY(self.owner)
 441                 );
 442
 443                 // Do all the transforms for warpzones right now, as we already
 444                 // "are" in the post-trace system (if we hit a player, that's
 445                 // always BEHIND the last passed wz).
 446                 last_origin = trace_endpos;
 447                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 448                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 449                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 450                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 451
 452                 float is_player = (
 453                         trace_ent.classname == "player"
 454                         ||
 455                         trace_ent.classname == "body"
 456                         ||
 457                         (trace_ent.flags & FL_MONSTER)
 458                 );
 459
 460                 if(trace_ent && trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 461                 {
 462                         // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 463                         // NO. trace_endpos should be just fine. If not,
 464                         // that's an engine bug that needs proper debugging.
 465                         vector hitorigin = trace_endpos;
 466
 467                         float falloff = ExponentialFalloff(
 468                                 WEP_CVAR(arc, beam_falloff_mindist),
 469                                 WEP_CVAR(arc, beam_falloff_maxdist),
 470                                 WEP_CVAR(arc, beam_falloff_halflifedist),
 471                                 vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 472                         );
 473
 474                         if(is_player && SAME_TEAM(self.owner, trace_ent))
 475                         {
 476                                 float roothealth, rootarmor;
 477                                 if(burst)
 478                                 {
 479                                         roothealth = WEP_CVAR(arc, burst_healing_hps);
 480                                         rootarmor = WEP_CVAR(arc, burst_healing_aps);
 481                                 }
 482                                 else
 483                                 {
 484                                         roothealth = WEP_CVAR(arc, beam_healing_hps);
 485                                         rootarmor = WEP_CVAR(arc, beam_healing_aps);
 486                                 }
 487
 488                                 if(trace_ent.health <= WEP_CVAR(arc, beam_healing_hmax) && roothealth)
 489                                 {
 490                                         trace_ent.health = min(
 491                                                 trace_ent.health + (roothealth * coefficient),
 492                                                 WEP_CVAR(arc, beam_healing_hmax)
 493                                         );
 494                                 }
 495                                 if(trace_ent.armorvalue <= WEP_CVAR(arc, beam_healing_amax) && rootarmor)
 496                                 {
 497                                         trace_ent.armorvalue = min(
 498                                                 trace_ent.armorvalue + (rootarmor * coefficient),
 499                                                 WEP_CVAR(arc, beam_healing_amax)
 500                                         );
 501                                 }
 502
 503                                 // stop rot, set visual effect
 504                                 if(roothealth || rootarmor)
 505                                 {
 506                                         trace_ent.pauserothealth_finished = max(
 507                                                 trace_ent.pauserothealth_finished,
 508                                                 time + autocvar_g_balance_pause_health_rot
 509                                         );
 510                                         trace_ent.pauserotarmor_finished = max(
 511                                                 trace_ent.pauserotarmor_finished,
 512                                                 time + autocvar_g_balance_pause_armor_rot
 513                                         );
 514                                         new_beam_type = ARC_BT_HEAL;
 515                                 }
 516                         }
 517                         else
 518                         {
 519                                 float rootdamage;
 520                                 if(is_player)
 521                                 {
 522                                         if(burst)
 523                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 524                                         else
 525                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 526                                 }
 527                                 else
 528                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 529
 530                                 if(accuracy_isgooddamage(self.owner, trace_ent))
 531                                 {
 532                                         accuracy_add(
 533                                                 self.owner,
 534                                                 WEP_ARC.m_id,
 535                                                 0,
 536                                                 rootdamage * coefficient * falloff
 537                                         );
 538                                 }
 539
 540                                 Damage(
 541                                         trace_ent,
 542                                         self.owner,
 543                                         self.owner,
 544                                         rootdamage * coefficient * falloff,
 545                                         WEP_ARC.m_id,
 546                                         hitorigin,
 547                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 548                                 );
 549
 550                                 new_beam_type = ARC_BT_HIT;
 551                         }
 552                         break;
 553                 }
 554                 else if(trace_fraction != 1)
 555                 {
 556                         // we collided with geometry
 557                         new_beam_type = ARC_BT_WALL;
 558                         break;
 559                 }
 560         }
 561
 562         // te_explosion(trace_endpos);
 563
 564         // if we're bursting, use burst visual effects
 565         new_beam_type |= burst;
 566
 567         // network information: beam type
 568         if(new_beam_type != self.beam_type)
 569         {
 570                 self.SendFlags |= ARC_SF_BEAMTYPE;
 571                 self.beam_type = new_beam_type;
 572         }
 573
 574         self.owner.beam_prev = time;
 575         self.nextthink = time;
 576 }
 577
 578 void W_Arc_Beam(float burst)
 579 {
 580
 581         // only play fire sound if 1 sec has passed since player let go the fire button
 582         if(time - self.beam_prev > 1)
 583         {
 584                 sound(self, CH_WEAPON_A, "weapons/arc_fire.wav", VOL_BASE, ATTN_NORM);
 585         }
 586
 587         entity beam = self.arc_beam = spawn();
 588         beam.classname = "W_Arc_Beam";
 589         beam.solid = SOLID_NOT;
 590         beam.think = W_Arc_Beam_Think;
 591         beam.owner = self;
 592         beam.movetype = MOVETYPE_NONE;
 593         beam.bot_dodge = true;
 594         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 595         beam.beam_bursting = burst;
 596         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 597
 598         entity oldself = self;
 599         self = beam;
 600         self.think();
 601         self = oldself;
 602 }
 603
 604 void Arc_Smoke()
 605 {
 606         makevectors(self.v_angle);
 607         W_SetupShot_Range(self,true,0,"",0,0,0);
 608
 609         vector smoke_origin = w_shotorg + self.velocity*frametime;
 610         if ( self.arc_overheat > time )
 611         {
 612                 if ( random() < self.arc_heat_percent )
 613                         pointparticles( particleeffectnum("arc_smoke"), smoke_origin, '0 0 0', 1 );
 614                 if ( self.BUTTON_ATCK || self.BUTTON_ATCK2 )
 615                 {
 616                         pointparticles( particleeffectnum("arc_overheat_fire"), smoke_origin, w_shotdir, 1 );
 617                         if ( !self.arc_smoke_sound )
 618                         {
 619                                 self.arc_smoke_sound = 1;
 620                                 sound(self, CH_SHOTS_SINGLE, "weapons/arc_loop_overheat.wav", VOL_BASE, ATTN_NORM);
 621                         }
 622                 }
 623         }
 624         else if ( self.arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 625                         self.arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 626         {
 627                 if ( random() < (self.arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 628                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 629                         pointparticles( particleeffectnum("arc_smoke"), smoke_origin, '0 0 0', 1 );
 630         }
 631
 632         if (  self.arc_smoke_sound && ( self.arc_overheat <= time ||
 633                 !( self.BUTTON_ATCK || self.BUTTON_ATCK2 ) ) || self.switchweapon != WEP_ARC.m_id )
 634         {
 635                 self.arc_smoke_sound = 0;
 636                 sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
 637         }
 638 }
 639
 640 bool W_Arc(int req)
 641 {
 642         switch(req)
 643         {
 644                 case WR_AIM:
 645                 {
 646                         if(WEP_CVAR(arc, beam_botaimspeed))
 647                         {
 648                                 self.BUTTON_ATCK = bot_aim(
 649                                         WEP_CVAR(arc, beam_botaimspeed),
 650                                         0,
 651                                         WEP_CVAR(arc, beam_botaimlifetime),
 652                                         false
 653                                 );
 654                         }
 655                         else
 656                         {
 657                                 self.BUTTON_ATCK = bot_aim(
 658                                         1000000,
 659                                         0,
 660                                         0.001,
 661                                         false
 662                                 );
 663                         }
 664                         return true;
 665                 }
 666                 case WR_THINK:
 667                 {
 668                         Arc_Player_SetHeat(self);
 669                         Arc_Smoke();
 670
 671                         if ( self.arc_overheat <= time )
 672                         if(self.BUTTON_ATCK || self.BUTTON_ATCK2 || self.arc_beam.beam_bursting )
 673                         {
 674
 675                                 if(self.arc_BUTTON_ATCK_prev)
 676                                 {
 677                                         #if 0
 678                                         if(self.animstate_startframe == self.anim_shoot.x && self.animstate_numframes == self.anim_shoot.y)
 679                                                 weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 680                                         else
 681                                         #endif
 682                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 683                                 }
 684
 685                                 if((!self.arc_beam) || wasfreed(self.arc_beam))
 686                                 {
 687                                         if(weapon_prepareattack(!!self.BUTTON_ATCK2, 0))
 688                                         {
 689                                                 W_Arc_Beam(!!self.BUTTON_ATCK2);
 690
 691                                                 if(!self.arc_BUTTON_ATCK_prev)
 692                                                 {
 693                                                         weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 694                                                         self.arc_BUTTON_ATCK_prev = 1;
 695                                                 }
 696                                         }
 697                                 }
 698
 699                                 return true;
 700                         }
 701
 702                         if(self.arc_BUTTON_ATCK_prev != 0)
 703                         {
 704                                 sound(self, CH_WEAPON_A, "weapons/arc_stop.wav", VOL_BASE, ATTN_NORM);
 705                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 706                                 ATTACK_FINISHED(self) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor();
 707                         }
 708                         self.arc_BUTTON_ATCK_prev = 0;
 709
 710                         #if 0
 711                         if(self.BUTTON_ATCK2)
 712                         if(weapon_prepareattack(1, autocvar_g_balance_arc_secondary_refire))
 713                         {
 714                                 W_Arc_Attack2();
 715                                 self.arc_count = autocvar_g_balance_arc_secondary_count;
 716                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 717                                 self.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor();
 718                         }
 719                         #endif
 720
 721                         return true;
 722                 }
 723                 case WR_INIT:
 724                 {
 725                         precache_model("models/weapons/g_arc.md3");
 726                         precache_model("models/weapons/v_arc.md3");
 727                         precache_model("models/weapons/h_arc.iqm");
 728                         precache_sound("weapons/arc_fire.wav");
 729                         precache_sound("weapons/arc_loop.wav");
 730                         precache_sound("weapons/arc_stop.wav");
 731                         precache_sound("weapons/arc_loop_overheat.wav");
 732                         if(!arc_shotorigin[0])
 733                         {
 734                                 arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 735                                 arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 736                                 arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 737                                 arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 738                         }
 739                         ARC_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 740                         return true;
 741                 }
 742                 case WR_CHECKAMMO1:
 743                 {
 744                         return ((!WEP_CVAR(arc, beam_ammo)) || (self.WEP_AMMO(ARC) > 0));
 745                 }
 746                 case WR_CHECKAMMO2:
 747                 {
 748                         return WEP_CVAR(arc, overheat_max) > 0 &&
 749                                 ((!WEP_CVAR(arc, burst_ammo)) || (self.WEP_AMMO(ARC) > 0));
 750                 }
 751                 case WR_CONFIG:
 752                 {
 753                         ARC_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 754                         return true;
 755                 }
 756                 case WR_KILLMESSAGE:
 757                 {
 758                         return WEAPON_ARC_MURDER;
 759                 }
 760                 case WR_DROP:
 761                 {
 762                         weapon_dropevent_item.arc_overheat = self.arc_overheat;
 763                         weapon_dropevent_item.arc_cooldown = self.arc_cooldown;
 764                         self.arc_overheat = 0;
 765                         self.arc_cooldown = 0;
 766                         return true;
 767                 }
 768                 case WR_PICKUP:
 769                 {
 770                         if ( !client_hasweapon(self, WEP_ARC.m_id, false, false) &&
 771                                 weapon_dropevent_item.arc_overheat > time )
 772                         {
 773                                 self.arc_overheat = weapon_dropevent_item.arc_overheat;
 774                                 self.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 775                         }
 776                         return true;
 777                 }
 778         }
 779         return false;
 780 }
 781 #endif
 782 #ifdef CSQC
 783 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 784 {
 785         entity beam = Draw_ArcBeam_callback_entity;
 786         vector transformed_view_org;
 787         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 788
 789         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 790         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 791         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 792
 793         vector hitorigin;
 794
 795         // draw segment
 796         #if 0
 797         if(trace_fraction != 1)
 798         {
 799                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 800                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 801                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 802         }
 803         else
 804         {
 805                 hitorigin = hit;
 806         }
 807         #else
 808         hitorigin = hit;
 809         #endif
 810
 811         // decide upon thickness
 812         float thickness = beam.beam_thickness;
 813
 814         // draw primary beam render
 815         vector top    = hitorigin + (thickdir * thickness);
 816         vector bottom = hitorigin - (thickdir * thickness);
 817
 818         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 819         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 820
 821         R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
 822         R_PolygonVertex(
 823                 top,
 824                 '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 825                 beam.beam_color,
 826                 beam.beam_alpha
 827         );
 828         R_PolygonVertex(
 829                 last_top,
 830                 '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 831                 beam.beam_color,
 832                 beam.beam_alpha
 833         );
 834         R_PolygonVertex(
 835                 last_bottom,
 836                 '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 837                 beam.beam_color,
 838                 beam.beam_alpha
 839         );
 840         R_PolygonVertex(
 841                 bottom,
 842                 '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 843                 beam.beam_color,
 844                 beam.beam_alpha
 845         );
 846         R_EndPolygon();
 847
 848         // draw trailing particles
 849         // NOTES:
 850         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 851         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 852         if(beam.beam_traileffect)
 853         {
 854                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 855         }
 856
 857         // set up for the next
 858         Draw_ArcBeam_callback_last_thickness = thickness;
 859         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 860         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 861 }
 862
 863 void Reset_ArcBeam(void)
 864 {
 865         entity e;
 866         for (e = world; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 867                 e.beam_initialized = false;
 868         }
 869         for (e = world; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 870                 e.beam_initialized = false;
 871         }
 872 }
 873
 874 void Draw_ArcBeam(void)
 875 {
 876         float dt = time - self.move_time;
 877         self.move_time = time;
 878         if(dt <= 0) { return; }
 879
 880         if(!self.beam_usevieworigin)
 881         {
 882                 InterpolateOrigin_Do();
 883         }
 884
 885         // origin = beam starting origin
 886         // v_angle = wanted/aim direction
 887         // angles = current direction of beam
 888
 889         vector start_pos;
 890         vector wantdir; //= view_forward;
 891         vector beamdir; //= self.beam_dir;
 892
 893         float segments;
 894         if(self.beam_usevieworigin)
 895         {
 896                 // WEAPONTODO:
 897                 // Currently we have to replicate nearly the same method of figuring
 898                 // out the shotdir that the server does... Ideally in the future we
 899                 // should be able to acquire this from a generalized function built
 900                 // into a weapon system for client code.
 901
 902                 // find where we are aiming
 903                 makevectors(warpzone_save_view_angles);
 904                 vector forward = v_forward;
 905                 vector right = v_right;
 906                 vector up = v_up;
 907
 908                 // decide upon start position
 909                 if(self.beam_usevieworigin == 2)
 910                         { start_pos = warpzone_save_view_origin; }
 911                 else
 912                         { start_pos = self.origin; }
 913
 914                 // trace forward with an estimation
 915                 WarpZone_TraceLine(
 916                         start_pos,
 917                         start_pos + forward * self.beam_range,
 918                         MOVE_NOMONSTERS,
 919                         self
 920                 );
 921
 922                 // untransform in case our trace went through a warpzone
 923                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 924
 925                 // un-adjust trueaim if shotend is too close
 926                 if(vlen(end_pos - start_pos) < g_trueaim_minrange)
 927                         end_pos = start_pos + (forward * g_trueaim_minrange);
 928
 929                 // move shot origin to the actual gun muzzle origin
 930                 vector origin_offset =
 931                           right * -self.beam_shotorigin.y
 932                         + up * self.beam_shotorigin.z;
 933
 934                 start_pos = start_pos + origin_offset;
 935
 936                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
 937                 traceline(start_pos, start_pos + forward * self.beam_shotorigin.x, MOVE_NORMAL, self);
 938                 start_pos = trace_endpos;
 939
 940                 // calculate the aim direction now
 941                 wantdir = normalize(end_pos - start_pos);
 942
 943                 if(!self.beam_initialized)
 944                 {
 945                         self.beam_dir = wantdir;
 946                         self.beam_initialized = true;
 947                 }
 948
 949                 if(self.beam_dir != wantdir)
 950                 {
 951                         // calculate how much we're going to move the end of the beam to the want position
 952                         // WEAPONTODO (server and client):
 953                         // blendfactor never actually becomes 0 in this situation, which is a problem
 954                         // regarding precision... this means that self.beam_dir and w_shotdir approach
 955                         // eachother, however they never actually become the same value with this method.
 956                         // Perhaps we should do some form of rounding/snapping?
 957                         float angle = vlen(wantdir - self.beam_dir) * RAD2DEG;
 958                         if(angle && (angle > self.beam_maxangle))
 959                         {
 960                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 961                                 float blendfactor = bound(
 962                                         0,
 963                                         (1 - (self.beam_returnspeed * frametime)),
 964                                         min(self.beam_maxangle / angle, 1)
 965                                 );
 966                                 self.beam_dir = normalize((wantdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 967                         }
 968                         else
 969                         {
 970                                 // the radius is not too far yet, no worries :D
 971                                 float blendfactor = bound(
 972                                         0,
 973                                         (1 - (self.beam_returnspeed * frametime)),
 974                                         1
 975                                 );
 976                                 self.beam_dir = normalize((wantdir * (1 - blendfactor)) + (self.beam_dir * blendfactor));
 977                         }
 978
 979                         // calculate how many segments are needed
 980                         float max_allowed_segments;
 981
 982                         if(self.beam_distancepersegment)
 983                         {
 984                                 max_allowed_segments = min(
 985                                         ARC_MAX_SEGMENTS,
 986                                         1 + (vlen(wantdir / self.beam_distancepersegment))
 987                                 );
 988                         }
 989                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 990
 991                         if(self.beam_degreespersegment)
 992                         {
 993                                 segments = bound(
 994                                         1,
 995                                         (
 996                                                 min(
 997                                                         angle,
 998                                                         self.beam_maxangle
 999                                                 )
1000                                                 /
1001                                                 self.beam_degreespersegment
1002                                         ),
1003                                         max_allowed_segments
1004                                 );
1005                         }
1006                         else { segments = 1; }
1007                 }
1008                 else { segments = 1; }
1009
1010                 // set the beam direction which the rest of the code will refer to
1011                 beamdir = self.beam_dir;
1012
1013                 // finally, set self.angles to the proper direction so that muzzle attachment points in proper direction
1014                 self.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1015         }
1016         else
1017         {
1018                 // set the values from the provided info from the networked entity
1019                 start_pos = self.origin;
1020                 wantdir = self.v_angle;
1021                 beamdir = self.angles;
1022
1023                 if(beamdir != wantdir)
1024                 {
1025                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1026
1027                         // calculate how many segments are needed
1028                         float max_allowed_segments;
1029
1030                         if(self.beam_distancepersegment)
1031                         {
1032                                 max_allowed_segments = min(
1033                                         ARC_MAX_SEGMENTS,
1034                                         1 + (vlen(wantdir / self.beam_distancepersegment))
1035                                 );
1036                         }
1037                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1038
1039                         if(self.beam_degreespersegment)
1040                         {
1041                                 segments = bound(
1042                                         1,
1043                                         (
1044                                                 min(
1045                                                         angle,
1046                                                         self.beam_maxangle
1047                                                 )
1048                                                 /
1049                                                 self.beam_degreespersegment
1050                                         ),
1051                                         max_allowed_segments
1052                                 );
1053                         }
1054                         else { segments = 1; }
1055                 }
1056                 else { segments = 1; }
1057         }
1058
1059         setorigin(self, start_pos);
1060         self.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1061
1062         vector beam_endpos = (start_pos + (beamdir * self.beam_range));
1063         vector beam_controlpoint = start_pos + wantdir * (self.beam_range * (1 - self.beam_tightness));
1064
1065         Draw_ArcBeam_callback_entity = self;
1066         Draw_ArcBeam_callback_last_thickness = 0;
1067         Draw_ArcBeam_callback_last_top = start_pos;
1068         Draw_ArcBeam_callback_last_bottom = start_pos;
1069
1070         vector last_origin = start_pos;
1071         vector original_start_pos = start_pos;
1072
1073         float i;
1074         for(i = 1; i <= segments; ++i)
1075         {
1076                 // WEAPONTODO (client):
1077                 // In order to do nice fading and pointing on the starting segment, we must always
1078                 // have that drawn as a separate triangle... However, that is difficult to do when
1079                 // keeping in mind the above problems and also optimizing the amount of segments
1080                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1081
1082                 vector new_origin = bezier_quadratic_getpoint(
1083                         start_pos,
1084                         beam_controlpoint,
1085                         beam_endpos,
1086                         i / segments);
1087
1088                 WarpZone_TraceBox_ThroughZone(
1089                         last_origin,
1090                         '0 0 0',
1091                         '0 0 0',
1092                         new_origin,
1093                         MOVE_NORMAL,
1094                         world,
1095                         world,
1096                         Draw_ArcBeam_callback
1097                 );
1098
1099                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1100                 // system (if we hit a player, that's always BEHIND the last passed wz).
1101                 last_origin = trace_endpos;
1102                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1103                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1104                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1105                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1106                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1107                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1108
1109                 if(trace_fraction < 1) { break; }
1110         }
1111
1112         // visual effects for startpoint and endpoint
1113         if(self.beam_hiteffect)
1114         {
1115                 // FIXME we really should do this on the server so it actually
1116                 // matches gameplay. What this client side stuff is doing is no
1117                 // more than guesswork.
1118                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1119                 pointparticles(
1120                         self.beam_hiteffect,
1121                         last_origin,
1122                         beamdir * -1,
1123                         frametime * 2
1124                 );
1125         }
1126         if(self.beam_hitlight[0])
1127         {
1128                 adddynamiclight(
1129                         last_origin,
1130                         self.beam_hitlight[0],
1131                         vec3(
1132                                 self.beam_hitlight[1],
1133                                 self.beam_hitlight[2],
1134                                 self.beam_hitlight[3]
1135                         )
1136                 );
1137         }
1138         if(self.beam_muzzleeffect)
1139         {
1140                 pointparticles(
1141                         self.beam_muzzleeffect,
1142                         original_start_pos + wantdir * 20,
1143                         wantdir * 1000,
1144                         frametime * 0.1
1145                 );
1146         }
1147         if(self.beam_muzzlelight[0])
1148         {
1149                 adddynamiclight(
1150                         original_start_pos + wantdir * 20,
1151                         self.beam_muzzlelight[0],
1152                         vec3(
1153                                 self.beam_muzzlelight[1],
1154                                 self.beam_muzzlelight[2],
1155                                 self.beam_muzzlelight[3]
1156                         )
1157                 );
1158         }
1159
1160         // cleanup
1161         Draw_ArcBeam_callback_entity = world;
1162         Draw_ArcBeam_callback_last_thickness = 0;
1163         Draw_ArcBeam_callback_last_top = '0 0 0';
1164         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1165 }
1166
1167 void Remove_ArcBeam(void)
1168 {
1169         remove(self.beam_muzzleentity);
1170         sound(self, CH_SHOTS_SINGLE, "misc/null.wav", VOL_BASE, ATTEN_NORM);
1171 }
1172
1173 void Ent_ReadArcBeam(float isnew)
1174 {
1175         int sf = ReadByte();
1176         entity flash;
1177
1178         if(isnew)
1179         {
1180                 // calculate shot origin offset from gun alignment
1181                 int gunalign = autocvar_cl_gunalign;
1182                 if(gunalign != 1 && gunalign != 2 && gunalign != 4)
1183                         gunalign = 3; // default value
1184                 --gunalign;
1185
1186                 self.beam_shotorigin = arc_shotorigin[gunalign];
1187
1188                 // set other main attributes of the beam
1189                 self.draw = Draw_ArcBeam;
1190                 self.entremove = Remove_ArcBeam;
1191                 self.move_time = time;
1192                 loopsound(self, CH_SHOTS_SINGLE, "weapons/arc_loop.wav", VOL_BASE, ATTEN_NORM);
1193
1194                 flash = spawn();
1195                 flash.owner = self;
1196                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1197                 flash.drawmask = MASK_NORMAL;
1198                 flash.solid = SOLID_NOT;
1199                 flash.avelocity_z = 5000;
1200                 setattachment(flash, self, "");
1201                 setorigin(flash, '0 0 0');
1202
1203                 self.beam_muzzleentity = flash;
1204         }
1205         else
1206         {
1207                 flash = self.beam_muzzleentity;
1208         }
1209
1210         if(sf & ARC_SF_SETTINGS) // settings information
1211         {
1212                 self.beam_degreespersegment = ReadShort();
1213                 self.beam_distancepersegment = ReadShort();
1214                 self.beam_maxangle = ReadShort();
1215                 self.beam_range = ReadCoord();
1216                 self.beam_returnspeed = ReadShort();
1217                 self.beam_tightness = (ReadByte() / 10);
1218
1219                 if(ReadByte())
1220                 {
1221                         if(autocvar_chase_active)
1222                                 { self.beam_usevieworigin = 1; }
1223                         else // use view origin
1224                                 { self.beam_usevieworigin = 2; }
1225                 }
1226                 else
1227                 {
1228                         self.beam_usevieworigin = 0;
1229                 }
1230         }
1231
1232         if(!self.beam_usevieworigin)
1233         {
1234                 // self.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1235                 self.iflags = IFLAG_ORIGIN;
1236
1237                 InterpolateOrigin_Undo();
1238         }
1239
1240         if(sf & ARC_SF_START) // starting location
1241         {
1242                 self.origin_x = ReadCoord();
1243                 self.origin_y = ReadCoord();
1244                 self.origin_z = ReadCoord();
1245         }
1246         else if(self.beam_usevieworigin) // infer the location from player location
1247         {
1248                 if(self.beam_usevieworigin == 2)
1249                 {
1250                         // use view origin
1251                         self.origin = view_origin;
1252                 }
1253                 else
1254                 {
1255                         // use player origin so that third person display still works
1256                         self.origin = getplayerorigin(player_localnum) + ('0 0 1' * getstati(STAT_VIEWHEIGHT));
1257                 }
1258         }
1259
1260         setorigin(self, self.origin);
1261
1262         if(sf & ARC_SF_WANTDIR) // want/aim direction
1263         {
1264                 self.v_angle_x = ReadCoord();
1265                 self.v_angle_y = ReadCoord();
1266                 self.v_angle_z = ReadCoord();
1267         }
1268
1269         if(sf & ARC_SF_BEAMDIR) // beam direction
1270         {
1271                 self.angles_x = ReadCoord();
1272                 self.angles_y = ReadCoord();
1273                 self.angles_z = ReadCoord();
1274         }
1275
1276         if(sf & ARC_SF_BEAMTYPE) // beam type
1277         {
1278                 self.beam_type = ReadByte();
1279                 switch(self.beam_type)
1280                 {
1281                         case ARC_BT_MISS:
1282                         {
1283                                 self.beam_color = '1 1 1';
1284                                 self.beam_alpha = 0.5;
1285                                 self.beam_thickness = 8;
1286                                 self.beam_traileffect = particleeffectnum("arc_beam");
1287                                 self.beam_hiteffect = particleeffectnum("arc_lightning");
1288                                 self.beam_hitlight[0] = 0;
1289                                 self.beam_hitlight[1] = 1;
1290                                 self.beam_hitlight[2] = 1;
1291                                 self.beam_hitlight[3] = 1;
1292                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1293                                 self.beam_muzzlelight[0] = 0;
1294                                 self.beam_muzzlelight[1] = 1;
1295                                 self.beam_muzzlelight[2] = 1;
1296                                 self.beam_muzzlelight[3] = 1;
1297                                 if(self.beam_muzzleeffect >= 0)
1298                                 {
1299                                         setmodel(flash, "models/flash.md3");
1300                                         flash.alpha = self.beam_alpha;
1301                                         flash.colormod = self.beam_color;
1302                                         flash.scale = 0.5;
1303                                 }
1304                                 break;
1305                         }
1306                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1307                         {
1308                                 self.beam_color = '1 1 1';
1309                                 self.beam_alpha = 0.5;
1310                                 self.beam_thickness = 8;
1311                                 self.beam_traileffect = particleeffectnum("arc_beam");
1312                                 self.beam_hiteffect = particleeffectnum("arc_lightning");
1313                                 self.beam_hitlight[0] = 0;
1314                                 self.beam_hitlight[1] = 1;
1315                                 self.beam_hitlight[2] = 1;
1316                                 self.beam_hitlight[3] = 1;
1317                                 self.beam_muzzleeffect = -1; // particleeffectnum("grenadelauncher_muzzleflash");
1318                                 self.beam_muzzlelight[0] = 0;
1319                                 self.beam_muzzlelight[1] = 1;
1320                                 self.beam_muzzlelight[2] = 1;
1321                                 self.beam_muzzlelight[3] = 1;
1322                                 self.beam_image = "particles/lgbeam";
1323                                 if(self.beam_muzzleeffect >= 0)
1324                                 {
1325                                         setmodel(flash, "models/flash.md3");
1326                                         flash.alpha = self.beam_alpha;
1327                                         flash.colormod = self.beam_color;
1328                                         flash.scale = 0.5;
1329                                 }
1330                                 break;
1331                         }
1332                         case ARC_BT_HEAL:
1333                         {
1334                                 self.beam_color = '1 1 1';
1335                                 self.beam_alpha = 0.5;
1336                                 self.beam_thickness = 8;
1337                                 self.beam_traileffect = particleeffectnum("arc_beam_heal");
1338                                 self.beam_hiteffect = particleeffectnum("arc_beam_healimpact");
1339                                 self.beam_hitlight[0] = 0;
1340                                 self.beam_hitlight[1] = 1;
1341                                 self.beam_hitlight[2] = 1;
1342                                 self.beam_hitlight[3] = 1;
1343                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1344                                 self.beam_muzzlelight[0] = 0;
1345                                 self.beam_muzzlelight[1] = 1;
1346                                 self.beam_muzzlelight[2] = 1;
1347                                 self.beam_muzzlelight[3] = 1;
1348                                 self.beam_image = "particles/lgbeam";
1349                                 if(self.beam_muzzleeffect >= 0)
1350                                 {
1351                                         setmodel(flash, "models/flash.md3");
1352                                         flash.alpha = self.beam_alpha;
1353                                         flash.colormod = self.beam_color;
1354                                         flash.scale = 0.5;
1355                                 }
1356                                 break;
1357                         }
1358                         case ARC_BT_HIT:
1359                         {
1360                                 self.beam_color = '1 1 1';
1361                                 self.beam_alpha = 0.5;
1362                                 self.beam_thickness = 8;
1363                                 self.beam_traileffect = particleeffectnum("arc_beam");
1364                                 self.beam_hiteffect = particleeffectnum("arc_lightning");
1365                                 self.beam_hitlight[0] = 20;
1366                                 self.beam_hitlight[1] = 1;
1367                                 self.beam_hitlight[2] = 0;
1368                                 self.beam_hitlight[3] = 0;
1369                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1370                                 self.beam_muzzlelight[0] = 50;
1371                                 self.beam_muzzlelight[1] = 1;
1372                                 self.beam_muzzlelight[2] = 0;
1373                                 self.beam_muzzlelight[3] = 0;
1374                                 self.beam_image = "particles/lgbeam";
1375                                 if(self.beam_muzzleeffect >= 0)
1376                                 {
1377                                         setmodel(flash, "models/flash.md3");
1378                                         flash.alpha = self.beam_alpha;
1379                                         flash.colormod = self.beam_color;
1380                                         flash.scale = 0.5;
1381                                 }
1382                                 break;
1383                         }
1384                         case ARC_BT_BURST_MISS:
1385                         {
1386                                 self.beam_color = '1 1 1';
1387                                 self.beam_alpha = 0.5;
1388                                 self.beam_thickness = 14;
1389                                 self.beam_traileffect = particleeffectnum("arc_beam");
1390                                 self.beam_hiteffect = particleeffectnum("arc_lightning");
1391                                 self.beam_hitlight[0] = 0;
1392                                 self.beam_hitlight[1] = 1;
1393                                 self.beam_hitlight[2] = 1;
1394                                 self.beam_hitlight[3] = 1;
1395                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1396                                 self.beam_muzzlelight[0] = 0;
1397                                 self.beam_muzzlelight[1] = 1;
1398                                 self.beam_muzzlelight[2] = 1;
1399                                 self.beam_muzzlelight[3] = 1;
1400                                 self.beam_image = "particles/lgbeam";
1401                                 if(self.beam_muzzleeffect >= 0)
1402                                 {
1403                                         setmodel(flash, "models/flash.md3");
1404                                         flash.alpha = self.beam_alpha;
1405                                         flash.colormod = self.beam_color;
1406                                         flash.scale = 0.5;
1407                                 }
1408                                 break;
1409                         }
1410                         case ARC_BT_BURST_WALL:
1411                         {
1412                                 self.beam_color = '1 1 1';
1413                                 self.beam_alpha = 0.5;
1414                                 self.beam_thickness = 14;
1415                                 self.beam_traileffect = particleeffectnum("arc_beam");
1416                                 self.beam_hiteffect = particleeffectnum("arc_lightning");
1417                                 self.beam_hitlight[0] = 0;
1418                                 self.beam_hitlight[1] = 1;
1419                                 self.beam_hitlight[2] = 1;
1420                                 self.beam_hitlight[3] = 1;
1421                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1422                                 self.beam_muzzlelight[0] = 0;
1423                                 self.beam_muzzlelight[1] = 1;
1424                                 self.beam_muzzlelight[2] = 1;
1425                                 self.beam_muzzlelight[3] = 1;
1426                                 self.beam_image = "particles/lgbeam";
1427                                 if(self.beam_muzzleeffect >= 0)
1428                                 {
1429                                         setmodel(flash, "models/flash.md3");
1430                                         flash.alpha = self.beam_alpha;
1431                                         flash.colormod = self.beam_color;
1432                                         flash.scale = 0.5;
1433                                 }
1434                                 break;
1435                         }
1436                         case ARC_BT_BURST_HEAL:
1437                         {
1438                                 self.beam_color = '1 1 1';
1439                                 self.beam_alpha = 0.5;
1440                                 self.beam_thickness = 14;
1441                                 self.beam_traileffect = particleeffectnum("arc_beam_heal");
1442                                 self.beam_hiteffect = particleeffectnum("healray_impact");
1443                                 self.beam_hitlight[0] = 0;
1444                                 self.beam_hitlight[1] = 1;
1445                                 self.beam_hitlight[2] = 1;
1446                                 self.beam_hitlight[3] = 1;
1447                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1448                                 self.beam_muzzlelight[0] = 0;
1449                                 self.beam_muzzlelight[1] = 1;
1450                                 self.beam_muzzlelight[2] = 1;
1451                                 self.beam_muzzlelight[3] = 1;
1452                                 self.beam_image = "particles/lgbeam";
1453                                 if(self.beam_muzzleeffect >= 0)
1454                                 {
1455                                         setmodel(flash, "models/flash.md3");
1456                                         flash.alpha = self.beam_alpha;
1457                                         flash.colormod = self.beam_color;
1458                                         flash.scale = 0.5;
1459                                 }
1460                                 break;
1461                         }
1462                         case ARC_BT_BURST_HIT:
1463                         {
1464                                 self.beam_color = '1 1 1';
1465                                 self.beam_alpha = 0.5;
1466                                 self.beam_thickness = 14;
1467                                 self.beam_traileffect = particleeffectnum("arc_beam");
1468                                 self.beam_hiteffect = particleeffectnum("arc_lightning");
1469                                 self.beam_hitlight[0] = 0;
1470                                 self.beam_hitlight[1] = 1;
1471                                 self.beam_hitlight[2] = 1;
1472                                 self.beam_hitlight[3] = 1;
1473                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1474                                 self.beam_muzzlelight[0] = 0;
1475                                 self.beam_muzzlelight[1] = 1;
1476                                 self.beam_muzzlelight[2] = 1;
1477                                 self.beam_muzzlelight[3] = 1;
1478                                 self.beam_image = "particles/lgbeam";
1479                                 if(self.beam_muzzleeffect >= 0)
1480                                 {
1481                                         setmodel(flash, "models/flash.md3");
1482                                         flash.alpha = self.beam_alpha;
1483                                         flash.colormod = self.beam_color;
1484                                         flash.scale = 0.5;
1485                                 }
1486                                 break;
1487                         }
1488
1489                         // shouldn't be possible, but lets make it colorful if it does :D
1490                         default:
1491                         {
1492                                 self.beam_color = randomvec();
1493                                 self.beam_alpha = 1;
1494                                 self.beam_thickness = 8;
1495                                 self.beam_traileffect = false;
1496                                 self.beam_hiteffect = false;
1497                                 self.beam_hitlight[0] = 0;
1498                                 self.beam_hitlight[1] = 1;
1499                                 self.beam_hitlight[2] = 1;
1500                                 self.beam_hitlight[3] = 1;
1501                                 self.beam_muzzleeffect = -1; //particleeffectnum("nex_muzzleflash");
1502                                 self.beam_muzzlelight[0] = 0;
1503                                 self.beam_muzzlelight[1] = 1;
1504                                 self.beam_muzzlelight[2] = 1;
1505                                 self.beam_muzzlelight[3] = 1;
1506                                 self.beam_image = "particles/lgbeam";
1507                                 if(self.beam_muzzleeffect >= 0)
1508                                 {
1509                                         setmodel(flash, "models/flash.md3");
1510                                         flash.alpha = self.beam_alpha;
1511                                         flash.colormod = self.beam_color;
1512                                         flash.scale = 0.5;
1513                                 }
1514                                 break;
1515                         }
1516                 }
1517         }
1518
1519         if(!self.beam_usevieworigin)
1520         {
1521                 InterpolateOrigin_Note();
1522         }
1523 }
1524
1525 bool W_Arc(int req)
1526 {
1527         switch(req)
1528         {
1529                 case WR_IMPACTEFFECT:
1530                 {
1531                         // todo
1532                         return true;
1533                 }
1534                 case WR_INIT:
1535                 {
1536                         precache_sound("weapons/arc_loop.wav");
1537                         return true;
1538                 }
1539                 case WR_ZOOMRETICLE:
1540                 {
1541                         // no weapon specific image for this weapon
1542                         return false;
1543                 }
1544         }
1545         return false;
1546 }
1547 #endif
1548 #endif