qcsrc/common/weapons/w_devastator.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ DEVASTATOR,
   4 /* function  */ W_Devastator,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 9,
   7 /* flags     */ WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_HIGH,
   9 /* color     */ '1 1 0',
  10 /* model     */ "rl",
  11 /* crosshair */ "gfx/crosshairrocketlauncher 0.5875",
  12 /* refname   */ "devastator",
  13 /* wepname   */ _("Devastator")
  14 );
  15
  16 #define DEVASTATOR_SETTINGS(w_cvar,w_prop) DEVASTATOR_SETTINGS_LIST(w_cvar, w_prop, DEVASTATOR, devastator)
  17 #define DEVASTATOR_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  18         w_cvar(id, sn, NONE, ammo) \
  19         w_cvar(id, sn, NONE, animtime) \
  20         w_cvar(id, sn, NONE, damage) \
  21         w_cvar(id, sn, NONE, damageforcescale) \
  22         w_cvar(id, sn, NONE, detonatedelay) \
  23         w_cvar(id, sn, NONE, edgedamage) \
  24         w_cvar(id, sn, NONE, force) \
  25         w_cvar(id, sn, NONE, guidedelay) \
  26         w_cvar(id, sn, NONE, guidegoal) \
  27         w_cvar(id, sn, NONE, guiderate) \
  28         w_cvar(id, sn, NONE, guideratedelay) \
  29         w_cvar(id, sn, NONE, guidestop) \
  30         w_cvar(id, sn, NONE, health) \
  31         w_cvar(id, sn, NONE, lifetime) \
  32         w_cvar(id, sn, NONE, radius) \
  33         w_cvar(id, sn, NONE, refire) \
  34         w_cvar(id, sn, NONE, remote_damage) \
  35         w_cvar(id, sn, NONE, remote_edgedamage) \
  36         w_cvar(id, sn, NONE, remote_force) \
  37         w_cvar(id, sn, NONE, remote_radius) \
  38         w_cvar(id, sn, NONE, speed) \
  39         w_cvar(id, sn, NONE, speedaccel) \
  40         w_cvar(id, sn, NONE, speedstart) \
  41         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  42         w_prop(id, sn, float,  reloading_time, reload_time) \
  43         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  44         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  45         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  46         w_prop(id, sn, float,  weaponstart, weaponstart) \
  47         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride)
  48
  49 #ifdef SVQC
  50 DEVASTATOR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  51 .float rl_release;
  52 .float rl_detonate_later;
  53 #endif
  54 #else
  55 #ifdef SVQC
  56 void spawnfunc_weapon_devastator() { weapon_defaultspawnfunc(WEP_DEVASTATOR); }
  57 void spawnfunc_weapon_rocketlauncher() { spawnfunc_weapon_devastator(); }
  58
  59 void W_Devastator_Unregister()
  60 {
  61         if(self.realowner && self.realowner.lastrocket == self)
  62         {
  63                 self.realowner.lastrocket = world;
  64                 // self.realowner.rl_release = 1;
  65         }
  66 }
  67
  68 void W_Devastator_Explode()
  69 {
  70         W_Devastator_Unregister();
  71
  72         if(other.takedamage == DAMAGE_AIM)
  73                 if(IS_PLAYER(other))
  74                         if(DIFF_TEAM(self.realowner, other))
  75                                 if(other.deadflag == DEAD_NO)
  76                                         if(IsFlying(other))
  77                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  78
  79         self.event_damage = func_null;
  80         self.takedamage = DAMAGE_NO;
  81
  82         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, damage), WEP_CVAR(devastator, edgedamage), WEP_CVAR(devastator, radius), world, world, WEP_CVAR(devastator, force), self.projectiledeathtype, other);
  83
  84         if (self.realowner.weapon == WEP_DEVASTATOR)
  85         {
  86                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
  87                 {
  88                         self.realowner.cnt = WEP_DEVASTATOR;
  89                         ATTACK_FINISHED(self.realowner) = time;
  90                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
  91                 }
  92         }
  93         remove (self);
  94 }
  95
  96 void W_Devastator_DoRemoteExplode()
  97 {
  98         W_Devastator_Unregister();
  99
 100         self.event_damage = func_null;
 101         self.takedamage = DAMAGE_NO;
 102
 103         RadiusDamage (self, self.realowner, WEP_CVAR(devastator, remote_damage), WEP_CVAR(devastator, remote_edgedamage), WEP_CVAR(devastator, remote_radius), world, world, WEP_CVAR(devastator, remote_force), self.projectiledeathtype | HITTYPE_BOUNCE, world);
 104
 105         if (self.realowner.weapon == WEP_DEVASTATOR)
 106         {
 107                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 108                 {
 109                         self.realowner.cnt = WEP_DEVASTATOR;
 110                         ATTACK_FINISHED(self.realowner) = time;
 111                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 112                 }
 113         }
 114         remove (self);
 115 }
 116
 117 void W_Devastator_RemoteExplode()
 118 {
 119         if(self.realowner.deadflag == DEAD_NO)
 120         if(self.realowner.lastrocket)
 121         {
 122                 if((self.spawnshieldtime >= 0)
 123                         ? (time >= self.spawnshieldtime) // timer
 124                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 125                 )
 126                 {
 127                         W_Devastator_DoRemoteExplode();
 128                 }
 129         }
 130 }
 131
 132 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 133 {
 134         if(thisdir * goaldir > maxturn_cos)
 135                 return goaldir;
 136         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 137                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 138         float f, m2;
 139         vector v;
 140         // solve:
 141         //   g = normalize(thisdir + goaldir * X)
 142         //   thisdir * g = maxturn
 143         //
 144         //   gg = thisdir + goaldir * X
 145         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 146         //
 147         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 148         f = thisdir * goaldir;
 149         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 150         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 151         m2 = maxturn_cos * maxturn_cos;
 152         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 153         return normalize(thisdir + goaldir * v_y); // the larger solution!
 154 }
 155 // assume thisdir == -goaldir:
 156 //   f == -1
 157 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 158 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 159 //   x^2 - 2 * x + 1 = 0
 160 //   (x - 1)^2 = 0
 161 //   x = 1
 162 //   normalize(thisdir + goaldir)
 163 //   normalize(0)
 164
 165 void W_Devastator_Think (void)
 166 {
 167         vector desireddir, olddir, newdir, desiredorigin, goal;
 168 #if 0
 169         float cosminang, cosmaxang, cosang;
 170 #endif
 171         float velspeed, f;
 172         self.nextthink = time;
 173         if (time > self.cnt)
 174         {
 175                 other = world;
 176                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 177                 W_Devastator_Explode ();
 178                 return;
 179         }
 180
 181         // accelerate
 182         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 183         velspeed = WEP_CVAR(devastator, speed) * g_weaponspeedfactor - (self.velocity * v_forward);
 184         if (velspeed > 0)
 185                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * g_weaponspeedfactor * frametime, velspeed);
 186
 187         // laser guided, or remote detonation
 188         if (self.realowner.weapon == WEP_DEVASTATOR)
 189         {
 190                 if(self == self.realowner.lastrocket)
 191                 if(!self.realowner.rl_release)
 192                 if(!self.BUTTON_ATCK2)
 193                 if(WEP_CVAR(devastator, guiderate))
 194                 if(time > self.pushltime)
 195                 if(self.realowner.deadflag == DEAD_NO)
 196                 {
 197                         f = WEP_CVAR(devastator, guideratedelay);
 198                         if(f)
 199                                 f = bound(0, (time - self.pushltime) / f, 1);
 200                         else
 201                                 f = 1;
 202
 203                         velspeed = vlen(self.velocity);
 204
 205                         makevectors(self.realowner.v_angle);
 206                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 207                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 208                         olddir = normalize(self.velocity);
 209
 210                         // now it gets tricky... we want to move like some curve to approximate the target direction
 211                         // but we are limiting the rate at which we can turn!
 212                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 213                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 214
 215                         self.velocity = newdir * velspeed;
 216                         self.angles = vectoangles(self.velocity);
 217
 218                         if(!self.count)
 219                         {
 220                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 221                                 // TODO add a better sound here
 222                                 sound (self.realowner, CH_WEAPON_B, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 223                                 self.count = 1;
 224                         }
 225                 }
 226
 227                 if(self.rl_detonate_later)
 228                         W_Devastator_RemoteExplode();
 229         }
 230
 231         if(self.csqcprojectile_clientanimate == 0)
 232                 UpdateCSQCProjectile(self);
 233 }
 234
 235 void W_Devastator_Touch (void)
 236 {
 237         if(WarpZone_Projectile_Touch())
 238         {
 239                 if(wasfreed(self))
 240                         W_Devastator_Unregister();
 241                 return;
 242         }
 243         W_Devastator_Unregister();
 244         W_Devastator_Explode ();
 245 }
 246
 247 void W_Devastator_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 248 {
 249         if (self.health <= 0)
 250                 return;
 251
 252         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 253                 return; // g_projectiles_damage says to halt
 254
 255         self.health = self.health - damage;
 256         self.angles = vectoangles(self.velocity);
 257
 258         if (self.health <= 0)
 259                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 260 }
 261
 262 void W_Devastator_Attack (void)
 263 {
 264         entity missile;
 265         entity flash;
 266
 267         W_DecreaseAmmo(WEP_CVAR(devastator, ammo));
 268
 269         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CH_WEAPON_A, WEP_CVAR(devastator, damage));
 270         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 271
 272         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 273         missile.owner = missile.realowner = self;
 274         self.lastrocket = missile;
 275         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 276                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 277         else
 278                 missile.spawnshieldtime = -1;
 279         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 280         missile.classname = "rocket";
 281         missile.bot_dodge = TRUE;
 282         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 283
 284         missile.takedamage = DAMAGE_YES;
 285         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 286         missile.health = WEP_CVAR(devastator, health);
 287         missile.event_damage = W_Devastator_Damage;
 288         missile.damagedbycontents = TRUE;
 289
 290         missile.movetype = MOVETYPE_FLY;
 291         PROJECTILE_MAKETRIGGER(missile);
 292         missile.projectiledeathtype = WEP_DEVASTATOR;
 293         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 294
 295         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 296         W_SetupProjVelocity_Basic(missile, WEP_CVAR(devastator, speedstart), 0);
 297         missile.angles = vectoangles (missile.velocity);
 298
 299         missile.touch = W_Devastator_Touch;
 300         missile.think = W_Devastator_Think;
 301         missile.nextthink = time;
 302         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 303         missile.flags = FL_PROJECTILE;
 304         missile.missile_flags = MIF_SPLASH;
 305
 306         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 307
 308         // muzzle flash for 1st person view
 309         flash = spawn ();
 310         setmodel (flash, "models/flash.md3"); // precision set below
 311         SUB_SetFade (flash, time, 0.1);
 312         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 313         W_AttachToShotorg(flash, '5 0 0');
 314
 315         // common properties
 316         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 317 }
 318
 319 float W_Devastator(float req)
 320 {
 321         entity rock;
 322         float rockfound;
 323         float ammo_amount;
 324         switch(req)
 325         {
 326                 case WR_AIM: // WEAPONTODO: rewrite this, it's WAY too complicated for what it should be
 327                 {
 328                         // aim and decide to fire if appropriate
 329                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), FALSE);
 330                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 331                         {
 332                                 // decide whether to detonate rockets
 333                                 entity missile, targetlist, targ;
 334                                 targetlist = findchainfloat(bot_attack, TRUE);
 335                                 for(missile = world; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == self)
 336                                 {
 337                                         targ = targetlist;
 338                                         while(targ)
 339                                         {
 340                                                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 341                                                 {
 342                                                         self.BUTTON_ATCK2 = TRUE;
 343                                                         break;
 344                                                 }
 345                                                 targ = targ.chain;
 346                                         }
 347                                 }
 348
 349                                 if(self.BUTTON_ATCK2) self.BUTTON_ATCK = FALSE;
 350                         }
 351
 352                         return TRUE;
 353                 }
 354                 case WR_THINK:
 355                 {
 356                         if(WEP_CVAR(devastator, reload_ammo) && self.clip_load < WEP_CVAR(devastator, ammo)) // forced reload
 357                                 WEP_ACTION(self.weapon, WR_RELOAD);
 358                         else
 359                         {
 360                                 if(self.BUTTON_ATCK)
 361                                 {
 362                                         if(self.rl_release || WEP_CVAR(devastator, guidestop))
 363                                         if(weapon_prepareattack(0, WEP_CVAR(devastator, refire)))
 364                                         {
 365                                                 W_Devastator_Attack();
 366                                                 weapon_thinkf(WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 367                                                 self.rl_release = 0;
 368                                         }
 369                                 }
 370                                 else
 371                                         self.rl_release = 1;
 372
 373                                 if(self.BUTTON_ATCK2)
 374                                 {
 375                                         rockfound = 0;
 376                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == self)
 377                                         {
 378                                                 if(!rock.rl_detonate_later)
 379                                                 {
 380                                                         rock.rl_detonate_later = TRUE;
 381                                                         rockfound = 1;
 382                                                 }
 383                                         }
 384                                         if(rockfound)
 385                                                 sound (self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 386                                 }
 387                         }
 388
 389                         return TRUE;
 390                 }
 391                 case WR_INIT:
 392                 {
 393                         if(autocvar_sv_precacheweapons)
 394                         {
 395                                 precache_model("models/flash.md3");
 396                                 precache_model("models/weapons/g_rl.md3");
 397                                 precache_model("models/weapons/v_rl.md3");
 398                                 precache_model("models/weapons/h_rl.iqm");
 399                                 precache_sound("weapons/rocket_det.wav");
 400                                 precache_sound("weapons/rocket_fire.wav");
 401                                 precache_sound("weapons/rocket_mode.wav");
 402                         }
 403                         DEVASTATOR_SETTINGS(WEP_SKIPCVAR, WEP_SET_PROP)
 404                         return TRUE;
 405                 }
 406                 case WR_SETUP:
 407                 {
 408                         self.rl_release = 1;
 409                         return TRUE;
 410                 }
 411                 case WR_CHECKAMMO1:
 412                 {
 413                         // don't switch while guiding a missile
 414                         if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_DEVASTATOR)
 415                         {
 416                                 ammo_amount = FALSE;
 417                                 if(WEP_CVAR(devastator, reload_ammo))
 418                                 {
 419                                         if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR]) < WEP_CVAR(devastator, ammo))
 420                                                 ammo_amount = TRUE;
 421                                 }
 422                                 else if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 423                                         ammo_amount = TRUE;
 424                                 return !ammo_amount;
 425                         }
 426
 427                         return TRUE;
 428                 }
 429                 case WR_CHECKAMMO2:
 430                 {
 431                         return FALSE;
 432                 }
 433                 case WR_CONFIG:
 434                 {
 435                         DEVASTATOR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS)
 436                         return TRUE;
 437                 }
 438                 case WR_RESETPLAYER:
 439                 {
 440                         self.rl_release = 0;
 441                         return TRUE;
 442                 }
 443                 case WR_RELOAD:
 444                 {
 445                         W_Reload(WEP_CVAR(devastator, ammo), "weapons/reload.wav");
 446                         return TRUE;
 447                 }
 448                 case WR_SUICIDEMESSAGE:
 449                 {
 450                         return WEAPON_ROCKETLAUNCHER_SUICIDE;
 451                 }
 452                 case WR_KILLMESSAGE:
 453                 {
 454                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 455                                 return WEAPON_ROCKETLAUNCHER_MURDER_SPLASH;
 456                         else
 457                                 return WEAPON_ROCKETLAUNCHER_MURDER_DIRECT;
 458                 }
 459         }
 460         return TRUE;
 461 }
 462 #endif
 463 #ifdef CSQC
 464 float W_Devastator(float req)
 465 {
 466         switch(req)
 467         {
 468                 case WR_IMPACTEFFECT:
 469                 {
 470                         vector org2;
 471                         org2 = w_org + w_backoff * 12;
 472                         pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 473                         if(!w_issilent)
 474                                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 475
 476                         return TRUE;
 477                 }
 478                 case WR_INIT:
 479                 {
 480                         precache_sound("weapons/rocket_impact.wav");
 481                         return TRUE;
 482                 }
 483                 case WR_ZOOMRETICLE:
 484                 {
 485                         // no weapon specific image for this weapon
 486                         return FALSE;
 487                 }
 488         }
 489         return TRUE;
 490 }
 491 #endif
 492 #endif