qcsrc/common/weapons/weapon/arc.qc

   1 #include "arc.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(Arc, Weapon)
   4 /* ammotype  */ ATTRIB(Arc, ammo_field, .int, ammo_cells);
   5 /* impulse   */ ATTRIB(Arc, impulse, int, 3);
   6 /* flags     */ ATTRIB(Arc, spawnflags, int, WEP_FLAG_NORMAL);
   7 /* rating    */ ATTRIB(Arc, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   8 /* color     */ ATTRIB(Arc, wpcolor, vector, '1 1 1');
   9 /* modelname */ ATTRIB(Arc, mdl, string, "arc");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(Arc, m_model, Model, MDL_ARC_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(Arc, w_crosshair, string, "gfx/crosshairhlac");
  14 /* crosshair */ ATTRIB(Arc, w_crosshair_size, float, 0.7);
  15 /* wepimg    */ ATTRIB(Arc, model2, string, "weaponarc");
  16 /* refname   */ ATTRIB(Arc, netname, string, "arc");
  17 /* wepname   */ ATTRIB(Arc, m_name, string, _("Arc"));
  18
  19 #define X(BEGIN, P, END, class, prefix) \
  20         BEGIN(class) \
  21                 P(class, prefix, bolt, float, NONE) \
  22                 P(class, prefix, bolt_ammo, float, NONE) \
  23         P(class, prefix, bolt_damageforcescale, float, NONE) \
  24         P(class, prefix, bolt_damage, float, NONE) \
  25         P(class, prefix, bolt_edgedamage, float, NONE) \
  26         P(class, prefix, bolt_force, float, NONE) \
  27         P(class, prefix, bolt_health, float, NONE) \
  28         P(class, prefix, bolt_lifetime, float, NONE) \
  29         P(class, prefix, bolt_radius, float, NONE) \
  30         P(class, prefix, bolt_refire, float, NONE) \
  31         P(class, prefix, bolt_speed, float, NONE) \
  32         P(class, prefix, bolt_spread, float, NONE) \
  33                 P(class, prefix, beam_ammo, float, NONE) \
  34         P(class, prefix, beam_animtime, float, NONE) \
  35         P(class, prefix, beam_botaimlifetime, float, NONE) \
  36         P(class, prefix, beam_botaimspeed, float, NONE) \
  37         P(class, prefix, beam_damage, float, NONE) \
  38         P(class, prefix, beam_degreespersegment, float, NONE) \
  39         P(class, prefix, beam_distancepersegment, float, NONE) \
  40         P(class, prefix, beam_falloff_halflifedist, float, NONE) \
  41         P(class, prefix, beam_falloff_maxdist, float, NONE) \
  42         P(class, prefix, beam_falloff_mindist, float, NONE) \
  43         P(class, prefix, beam_force, float, NONE) \
  44         P(class, prefix, beam_healing_amax, float, NONE) \
  45         P(class, prefix, beam_healing_aps, float, NONE) \
  46         P(class, prefix, beam_healing_hmax, float, NONE) \
  47         P(class, prefix, beam_healing_hps, float, NONE) \
  48         P(class, prefix, beam_heat, float, NONE) /* heat increase per second (primary) */ \
  49         P(class, prefix, beam_maxangle, float, NONE) \
  50         P(class, prefix, beam_nonplayerdamage, float, NONE) \
  51         P(class, prefix, beam_range, float, NONE) \
  52         P(class, prefix, beam_refire, float, NONE) \
  53         P(class, prefix, beam_returnspeed, float, NONE) \
  54         P(class, prefix, beam_tightness, float, NONE) \
  55         P(class, prefix, burst_ammo, float, NONE) \
  56         P(class, prefix, burst_damage, float, NONE) \
  57         P(class, prefix, burst_healing_aps, float, NONE) \
  58         P(class, prefix, burst_healing_hps, float, NONE) \
  59         P(class, prefix, burst_heat, float, NONE) /* heat increase per second (secondary) */ \
  60         P(class, prefix, cooldown, float, NONE) /* heat decrease per second when resting */ \
  61         P(class, prefix, cooldown_release, float, NONE) /* delay weapon re-use when releasing button */ \
  62         P(class, prefix, overheat_max, float, NONE) /* maximum heat before jamming */ \
  63         P(class, prefix, overheat_min, float, NONE) /* minimum heat to wait for cooldown */ \
  64         P(class, prefix, switchdelay_drop, float, NONE) \
  65         P(class, prefix, switchdelay_raise, float, NONE) \
  66         P(class, prefix, weaponreplace, string, NONE) \
  67         P(class, prefix, weaponstartoverride, float, NONE) \
  68         P(class, prefix, weaponstart, float, NONE) \
  69         P(class, prefix, weaponthrowable, float, NONE) \
  70     END()
  71     W_PROPS(X, Arc, arc)
  72 #undef X
  73
  74 ENDCLASS(Arc)
  75 REGISTER_WEAPON(ARC, arc, NEW(Arc));
  76
  77
  78 #ifdef GAMEQC
  79 const float ARC_MAX_SEGMENTS = 20;
  80 vector arc_shotorigin[4];
  81 .vector beam_start;
  82 .vector beam_dir;
  83 .vector beam_wantdir;
  84 .int beam_type;
  85
  86 const int ARC_BT_MISS =        0x00;
  87 const int ARC_BT_WALL =        0x01;
  88 const int ARC_BT_HEAL =        0x02;
  89 const int ARC_BT_HIT =         0x03;
  90 const int ARC_BT_BURST_MISS =  0x10;
  91 const int ARC_BT_BURST_WALL =  0x11;
  92 const int ARC_BT_BURST_HEAL =  0x12;
  93 const int ARC_BT_BURST_HIT =   0x13;
  94 const int ARC_BT_BURSTMASK =   0x10;
  95
  96 const int ARC_SF_SETTINGS =    BIT(0);
  97 const int ARC_SF_START =       BIT(1);
  98 const int ARC_SF_WANTDIR =     BIT(2);
  99 const int ARC_SF_BEAMDIR =     BIT(3);
 100 const int ARC_SF_BEAMTYPE =    BIT(4);
 101 const int ARC_SF_LOCALMASK =   ARC_SF_START | ARC_SF_WANTDIR | ARC_SF_BEAMDIR;
 102 #endif
 103 #ifdef SVQC
 104 .entity arc_beam;
 105 .bool arc_BUTTON_ATCK_prev[MAX_WEAPONSLOTS]; // for better animation control
 106 .float beam_prev;
 107 .float beam_initialized;
 108 .float beam_bursting;
 109 .float beam_teleporttime;
 110 .float beam_heat; // (beam) amount of heat produced
 111 .float arc_overheat; // (dropped arc/player) time during which it's too hot
 112 .float arc_cooldown; // (dropped arc/player) cooling speed
 113 .float arc_heat_percent = _STAT(ARC_HEAT);
 114 .float arc_smoke_sound;
 115 #endif
 116 #ifdef CSQC
 117
 118 .vector beam_color;
 119 .float beam_alpha;
 120 .float beam_thickness;
 121 .entity beam_traileffect;
 122 .entity beam_hiteffect;
 123 .float beam_hitlight[4]; // 0: radius, 123: rgb
 124 .entity beam_muzzleeffect;
 125 .float beam_muzzlelight[4]; // 0: radius, 123: rgb
 126 .string beam_image;
 127
 128 .entity beam_muzzleentity;
 129
 130 .float beam_degreespersegment;
 131 .float beam_distancepersegment;
 132 .float beam_usevieworigin;
 133 .float beam_initialized;
 134 .float beam_maxangle;
 135 .float beam_range;
 136 .float beam_returnspeed;
 137 .float beam_tightness;
 138 .vector beam_shotorigin;
 139
 140 entity Draw_ArcBeam_callback_entity;
 141 float Draw_ArcBeam_callback_last_thickness;
 142 vector Draw_ArcBeam_callback_last_top; // NOTE: in same coordinate system as player.
 143 vector Draw_ArcBeam_callback_last_bottom; // NOTE: in same coordinate system as player.
 144 #endif
 145 #endif
 146 #ifdef IMPLEMENTATION
 147 #ifdef SVQC
 148 spawnfunc(weapon_arc) { weapon_defaultspawnfunc(this, WEP_ARC); }
 149
 150 bool W_Arc_Beam_Send(entity this, entity to, int sf)
 151 {
 152         WriteHeader(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
 153
 154         // Truncate information when this beam is displayed to the owner client
 155         // - The owner client has no use for beam start position or directions,
 156         //    it always figures this information out for itself with csqc code.
 157         // - Spectating the owner also truncates this information.
 158         float drawlocal = ((to == this.owner) || ((to.enemy == this.owner) && IS_SPEC(to)));
 159         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
 160
 161         WriteByte(MSG_ENTITY, sf);
 162
 163         if(sf & ARC_SF_SETTINGS) // settings information
 164         {
 165                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
 166                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
 167                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
 168                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
 169                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
 170                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
 171
 172                 WriteByte(MSG_ENTITY, drawlocal);
 173                 WriteByte(MSG_ENTITY, etof(this.owner));
 174         }
 175         if(sf & ARC_SF_START) // starting location
 176         {
 177                 WriteCoord(MSG_ENTITY, this.beam_start.x);
 178                 WriteCoord(MSG_ENTITY, this.beam_start.y);
 179                 WriteCoord(MSG_ENTITY, this.beam_start.z);
 180         }
 181         if(sf & ARC_SF_WANTDIR) // want/aim direction
 182         {
 183                 WriteCoord(MSG_ENTITY, this.beam_wantdir.x);
 184                 WriteCoord(MSG_ENTITY, this.beam_wantdir.y);
 185                 WriteCoord(MSG_ENTITY, this.beam_wantdir.z);
 186         }
 187         if(sf & ARC_SF_BEAMDIR) // beam direction
 188         {
 189                 WriteCoord(MSG_ENTITY, this.beam_dir.x);
 190                 WriteCoord(MSG_ENTITY, this.beam_dir.y);
 191                 WriteCoord(MSG_ENTITY, this.beam_dir.z);
 192         }
 193         if(sf & ARC_SF_BEAMTYPE) // beam type
 194         {
 195                 WriteByte(MSG_ENTITY, this.beam_type);
 196         }
 197
 198         return true;
 199 }
 200
 201 void Reset_ArcBeam(entity player, vector forward)
 202 {
 203         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 204         {
 205                 .entity weaponentity = weaponentities[slot];
 206                 if(!player.(weaponentity).arc_beam)
 207                         continue;
 208                 player.(weaponentity).arc_beam.beam_dir = forward;
 209                 player.(weaponentity).arc_beam.beam_teleporttime = time;
 210         }
 211 }
 212
 213 float Arc_GetHeat_Percent(entity player, .entity weaponentity)
 214 {
 215         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
 216         {
 217                 player.arc_overheat = 0;
 218                 return 0;
 219         }
 220
 221         if ( player.(weaponentity).arc_beam )
 222                 return player.(weaponentity).arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
 223
 224         if ( player.arc_overheat > time )
 225         {
 226                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
 227                         * player.arc_cooldown;
 228         }
 229
 230         return 0;
 231 }
 232 void Arc_Player_SetHeat(entity player, .entity weaponentity)
 233 {
 234         player.arc_heat_percent = Arc_GetHeat_Percent(player, weaponentity);
 235         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
 236 }
 237
 238 void W_Arc_Bolt_Explode(entity this, entity directhitentity)
 239 {
 240         this.event_damage = func_null;
 241         RadiusDamage(this, this.realowner, WEP_CVAR(arc, bolt_damage), WEP_CVAR(arc, bolt_edgedamage), WEP_CVAR(arc, bolt_radius), NULL, NULL, WEP_CVAR(arc, bolt_force), this.projectiledeathtype, directhitentity);
 242
 243         delete(this);
 244 }
 245
 246 void W_Arc_Bolt_Explode_use(entity this, entity actor, entity trigger)
 247 {
 248         W_Arc_Bolt_Explode(this, trigger);
 249 }
 250
 251 void W_Arc_Bolt_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 252 {
 253         if(this.health <= 0)
 254                 return;
 255
 256         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1))
 257                 return; // g_projectiles_damage says to halt
 258
 259         this.health = this.health - damage;
 260         this.angles = vectoangles(this.velocity);
 261
 262         if(this.health <= 0)
 263                 W_PrepareExplosionByDamage(this, attacker, getthink(this));
 264 }
 265
 266 void W_Arc_Bolt_Touch(entity this, entity toucher)
 267 {
 268         PROJECTILE_TOUCH(this, toucher);
 269         this.use(this, NULL, toucher);
 270 }
 271
 272 void W_Arc_Attack_Bolt(Weapon thiswep, entity actor, .entity weaponentity)
 273 {
 274         entity missile;
 275
 276         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(arc, bolt_ammo));
 277
 278         W_SetupShot(actor, weaponentity, false, 2, SND_LASERGUN_FIRE, CH_WEAPON_A, WEP_CVAR(arc, bolt_damage));
 279
 280         Send_Effect(EFFECT_ARC_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 281
 282         missile = new(missile);
 283         missile.owner = missile.realowner = actor;
 284         missile.bot_dodge = true;
 285         IL_PUSH(g_bot_dodge, missile);
 286         missile.bot_dodgerating = WEP_CVAR(arc, bolt_damage);
 287
 288         missile.takedamage = DAMAGE_YES;
 289         missile.health = WEP_CVAR(arc, bolt_health);
 290         missile.damageforcescale = WEP_CVAR(arc, bolt_damageforcescale);
 291         missile.event_damage = W_Arc_Bolt_Damage;
 292         missile.damagedbycontents = true;
 293
 294         settouch(missile, W_Arc_Bolt_Touch);
 295         missile.use = W_Arc_Bolt_Explode_use;
 296         setthink(missile, adaptor_think2use_hittype_splash);
 297         missile.nextthink = time + WEP_CVAR(arc, bolt_lifetime);
 298         PROJECTILE_MAKETRIGGER(missile);
 299         missile.projectiledeathtype = WEP_ARC.m_id | HITTYPE_SECONDARY;
 300         setorigin(missile, w_shotorg);
 301         setsize(missile, '0 0 0', '0 0 0');
 302
 303         set_movetype(missile, MOVETYPE_FLY);
 304         W_SetupProjVelocity_PRE(missile, arc, bolt_);
 305
 306         missile.angles = vectoangles(missile.velocity);
 307         missile.flags = FL_PROJECTILE;
 308         missile.missile_flags = MIF_SPLASH;
 309
 310         CSQCProjectile(missile, true, PROJECTILE_ARC_BOLT, true);
 311
 312         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 313 }
 314
 315 void W_Arc_Beam_Think(entity this)
 316 {
 317         .entity weaponentity = this.weaponentity_fld;
 318         if(this != this.owner.(weaponentity).arc_beam)
 319         {
 320                 delete(this);
 321                 return;
 322         }
 323
 324         float burst = 0;
 325         if( (PHYS_INPUT_BUTTON_ATCK2(this.owner) && !WEP_CVAR(arc, bolt)) || this.beam_bursting)
 326         {
 327                 if(!this.beam_bursting)
 328                         this.beam_bursting = true;
 329                 burst = ARC_BT_BURSTMASK;
 330         }
 331
 332         Weapon thiswep = WEP_ARC;
 333
 334         if(
 335                 !IS_PLAYER(this.owner)
 336                 ||
 337                 (this.owner.(thiswep.ammo_field) <= 0 && !(this.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 338                 ||
 339                 IS_DEAD(this.owner)
 340                 ||
 341                 forbidWeaponUse(this.owner)
 342                 ||
 343                 PS(this.owner).m_switchweapon != WEP_ARC
 344                 ||
 345                 (!PHYS_INPUT_BUTTON_ATCK(this.owner) && !burst )
 346                 ||
 347                 this.owner.vehicle
 348                 ||
 349                 (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max))
 350         )
 351         {
 352                 if ( WEP_CVAR(arc, cooldown) > 0 )
 353                 {
 354                         float cooldown_speed = 0;
 355                         if ( this.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 356                         {
 357                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 358                         }
 359                         else if ( !burst )
 360                         {
 361                                 cooldown_speed = this.beam_heat / WEP_CVAR(arc, beam_refire);
 362                         }
 363
 364                         if ( cooldown_speed )
 365                         {
 366                                 if ( WEP_CVAR(arc, cooldown_release) || (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max)) )
 367                                         this.owner.arc_overheat = time + this.beam_heat / cooldown_speed;
 368                                 this.owner.arc_cooldown = cooldown_speed;
 369                         }
 370
 371                         if ( WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max) )
 372                         {
 373                                 Send_Effect(EFFECT_ARC_OVERHEAT,
 374                                         this.beam_start, this.beam_wantdir, 1 );
 375                                 sound(this, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 376                         }
 377                 }
 378
 379                 if(this == this.owner.(weaponentity).arc_beam) { this.owner.(weaponentity).arc_beam = NULL; }
 380                 entity own = this.owner;
 381                 Weapon w = WEP_ARC;
 382                 if(!w.wr_checkammo1(w, own) && !w.wr_checkammo2(w, own))
 383                 if(!(own.items & IT_UNLIMITED_WEAPON_AMMO))
 384                 {
 385                         // note: this doesn't force the switch
 386                         W_SwitchToOtherWeapon(own);
 387                 }
 388                 delete(this);
 389                 return;
 390         }
 391
 392         // decrease ammo
 393         float coefficient = frametime;
 394         if(!(this.owner.items & IT_UNLIMITED_WEAPON_AMMO))
 395         {
 396                 float rootammo;
 397                 if(burst)
 398                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 399                 else
 400                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 401
 402                 if(rootammo)
 403                 {
 404                         coefficient = min(coefficient, this.owner.(thiswep.ammo_field) / rootammo);
 405                         this.owner.(thiswep.ammo_field) = max(0, this.owner.(thiswep.ammo_field) - (rootammo * frametime));
 406                 }
 407         }
 408         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 409         this.beam_heat = min( WEP_CVAR(arc, overheat_max), this.beam_heat + heat_speed*frametime );
 410
 411         makevectors(this.owner.v_angle);
 412
 413         W_SetupShot_Range(
 414                 this.owner,
 415                 weaponentity, // TODO
 416                 true,
 417                 0,
 418                 SND_Null,
 419                 0,
 420                 WEP_CVAR(arc, beam_damage) * coefficient,
 421                 WEP_CVAR(arc, beam_range)
 422         );
 423
 424         // After teleport, "lock" the beam until the teleport is confirmed.
 425         if (time < this.beam_teleporttime + ANTILAG_LATENCY(this.owner)) {
 426                 w_shotdir = this.beam_dir;
 427         }
 428
 429         // network information: shot origin and want/aim direction
 430         if(this.beam_start != w_shotorg)
 431         {
 432                 this.SendFlags |= ARC_SF_START;
 433                 this.beam_start = w_shotorg;
 434         }
 435         if(this.beam_wantdir != w_shotdir)
 436         {
 437                 this.SendFlags |= ARC_SF_WANTDIR;
 438                 this.beam_wantdir = w_shotdir;
 439         }
 440
 441         if(!this.beam_initialized)
 442         {
 443                 this.beam_dir = w_shotdir;
 444                 this.beam_initialized = true;
 445         }
 446
 447         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 448         // idea: blend together this.beam_dir with the inverted direction the player is moving in
 449         // might have to make some special accomodation so that it only uses view_right and view_up
 450
 451         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 452
 453         float segments;
 454         if(this.beam_dir != w_shotdir)
 455         {
 456                 // calculate how much we're going to move the end of the beam to the want position
 457                 // WEAPONTODO (server and client):
 458                 // blendfactor never actually becomes 0 in this situation, which is a problem
 459                 // regarding precision... this means that this.beam_dir and w_shotdir approach
 460                 // eachother, however they never actually become the same value with this method.
 461                 // Perhaps we should do some form of rounding/snapping?
 462                 float angle = vlen(w_shotdir - this.beam_dir) * RAD2DEG;
 463                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 464                 {
 465                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 466                         float blendfactor = bound(
 467                                 0,
 468                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 469                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 470                         );
 471                         this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 472                 }
 473                 else
 474                 {
 475                         // the radius is not too far yet, no worries :D
 476                         float blendfactor = bound(
 477                                 0,
 478                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 479                                 1
 480                         );
 481                         this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 482                 }
 483
 484                 // network information: beam direction
 485                 this.SendFlags |= ARC_SF_BEAMDIR;
 486
 487                 // calculate how many segments are needed
 488                 float max_allowed_segments;
 489
 490                 if(WEP_CVAR(arc, beam_distancepersegment))
 491                 {
 492                         max_allowed_segments = min(
 493                                 ARC_MAX_SEGMENTS,
 494                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 495                         );
 496                 }
 497                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 498
 499                 if(WEP_CVAR(arc, beam_degreespersegment))
 500                 {
 501                         segments = bound(
 502                                 1,
 503                                 (
 504                                         min(
 505                                                 angle,
 506                                                 WEP_CVAR(arc, beam_maxangle)
 507                                         )
 508                                         /
 509                                         WEP_CVAR(arc, beam_degreespersegment)
 510                                 ),
 511                                 max_allowed_segments
 512                         );
 513                 }
 514                 else { segments = 1; }
 515         }
 516         else { segments = 1; }
 517
 518         vector beam_endpos = (w_shotorg + (this.beam_dir * WEP_CVAR(arc, beam_range)));
 519         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 520
 521         float i;
 522         float new_beam_type = 0;
 523         vector last_origin = w_shotorg;
 524         for(i = 1; i <= segments; ++i)
 525         {
 526                 // WEAPONTODO (client):
 527                 // In order to do nice fading and pointing on the starting segment, we must always
 528                 // have that drawn as a separate triangle... However, that is difficult to do when
 529                 // keeping in mind the above problems and also optimizing the amount of segments
 530                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 531
 532                 vector new_origin = bezier_quadratic_getpoint(
 533                         w_shotorg,
 534                         beam_controlpoint,
 535                         beam_endpos,
 536                         i / segments);
 537                 vector new_dir = normalize(new_origin - last_origin);
 538
 539                 WarpZone_traceline_antilag(
 540                         this.owner,
 541                         last_origin,
 542                         new_origin,
 543                         MOVE_NORMAL,
 544                         this.owner,
 545                         ANTILAG_LATENCY(this.owner)
 546                 );
 547
 548                 // Do all the transforms for warpzones right now, as we already
 549                 // "are" in the post-trace system (if we hit a player, that's
 550                 // always BEHIND the last passed wz).
 551                 last_origin = trace_endpos;
 552                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 553                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 554                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 555                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 556
 557                 float is_player = (
 558                         IS_PLAYER(trace_ent)
 559                         ||
 560                         trace_ent.classname == "body"
 561                         ||
 562                         IS_MONSTER(trace_ent)
 563                 );
 564
 565                 if(trace_ent && trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 566                 {
 567                         // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 568                         // NO. trace_endpos should be just fine. If not,
 569                         // that's an engine bug that needs proper debugging.
 570                         vector hitorigin = trace_endpos;
 571
 572                         float falloff = ExponentialFalloff(
 573                                 WEP_CVAR(arc, beam_falloff_mindist),
 574                                 WEP_CVAR(arc, beam_falloff_maxdist),
 575                                 WEP_CVAR(arc, beam_falloff_halflifedist),
 576                                 vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 577                         );
 578
 579                         if(is_player && SAME_TEAM(this.owner, trace_ent))
 580                         {
 581                                 float roothealth, rootarmor;
 582                                 if(burst)
 583                                 {
 584                                         roothealth = WEP_CVAR(arc, burst_healing_hps);
 585                                         rootarmor = WEP_CVAR(arc, burst_healing_aps);
 586                                 }
 587                                 else
 588                                 {
 589                                         roothealth = WEP_CVAR(arc, beam_healing_hps);
 590                                         rootarmor = WEP_CVAR(arc, beam_healing_aps);
 591                                 }
 592
 593                                 if(trace_ent.health <= WEP_CVAR(arc, beam_healing_hmax) && roothealth)
 594                                 {
 595                                         trace_ent.health = min(
 596                                                 trace_ent.health + (roothealth * coefficient),
 597                                                 WEP_CVAR(arc, beam_healing_hmax)
 598                                         );
 599                                 }
 600                                 if(trace_ent.armorvalue <= WEP_CVAR(arc, beam_healing_amax) && rootarmor)
 601                                 {
 602                                         trace_ent.armorvalue = min(
 603                                                 trace_ent.armorvalue + (rootarmor * coefficient),
 604                                                 WEP_CVAR(arc, beam_healing_amax)
 605                                         );
 606                                 }
 607
 608                                 // stop rot, set visual effect
 609                                 if(roothealth || rootarmor)
 610                                 {
 611                                         trace_ent.pauserothealth_finished = max(
 612                                                 trace_ent.pauserothealth_finished,
 613                                                 time + autocvar_g_balance_pause_health_rot
 614                                         );
 615                                         trace_ent.pauserotarmor_finished = max(
 616                                                 trace_ent.pauserotarmor_finished,
 617                                                 time + autocvar_g_balance_pause_armor_rot
 618                                         );
 619                                         new_beam_type = ARC_BT_HEAL;
 620                                 }
 621                         }
 622                         else
 623                         {
 624                                 float rootdamage;
 625                                 if(is_player)
 626                                 {
 627                                         if(burst)
 628                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 629                                         else
 630                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 631                                 }
 632                                 else
 633                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 634
 635                                 if(accuracy_isgooddamage(this.owner, trace_ent))
 636                                 {
 637                                         accuracy_add(
 638                                                 this.owner,
 639                                                 WEP_ARC.m_id,
 640                                                 0,
 641                                                 rootdamage * coefficient * falloff
 642                                         );
 643                                 }
 644
 645                                 Damage(
 646                                         trace_ent,
 647                                         this.owner,
 648                                         this.owner,
 649                                         rootdamage * coefficient * falloff,
 650                                         WEP_ARC.m_id,
 651                                         hitorigin,
 652                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 653                                 );
 654
 655                                 new_beam_type = ARC_BT_HIT;
 656                         }
 657                         break;
 658                 }
 659                 else if(trace_fraction != 1)
 660                 {
 661                         // we collided with geometry
 662                         new_beam_type = ARC_BT_WALL;
 663                         break;
 664                 }
 665         }
 666
 667         // te_explosion(trace_endpos);
 668
 669         // if we're bursting, use burst visual effects
 670         new_beam_type |= burst;
 671
 672         // network information: beam type
 673         if(new_beam_type != this.beam_type)
 674         {
 675                 this.SendFlags |= ARC_SF_BEAMTYPE;
 676                 this.beam_type = new_beam_type;
 677         }
 678
 679         this.owner.beam_prev = time;
 680         this.nextthink = time;
 681 }
 682
 683 void W_Arc_Beam(float burst, entity actor, .entity weaponentity)
 684 {
 685
 686         // only play fire sound if 1 sec has passed since player let go the fire button
 687         if(time - actor.beam_prev > 1)
 688                 sound(actor, CH_WEAPON_A, SND_ARC_FIRE, VOL_BASE, ATTN_NORM);
 689
 690         entity beam = actor.(weaponentity).arc_beam = new(W_Arc_Beam);
 691         beam.weaponentity_fld = weaponentity;
 692         beam.solid = SOLID_NOT;
 693         setthink(beam, W_Arc_Beam_Think);
 694         beam.owner = actor;
 695         set_movetype(beam, MOVETYPE_NONE);
 696         beam.bot_dodge = true;
 697         IL_PUSH(g_bot_dodge, beam);
 698         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 699         beam.beam_bursting = burst;
 700         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 701
 702         getthink(beam)(beam);
 703 }
 704 void Arc_Smoke(entity actor, .entity weaponentity)
 705 {
 706         makevectors(actor.v_angle);
 707         W_SetupShot_Range(actor,weaponentity,true,0,SND_Null,0,0,0);
 708
 709         vector smoke_origin = w_shotorg + actor.velocity*frametime;
 710         if ( actor.arc_overheat > time )
 711         {
 712                 if ( random() < actor.arc_heat_percent )
 713                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 714                 if ( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) )
 715                 {
 716                         Send_Effect(EFFECT_ARC_OVERHEAT_FIRE, smoke_origin, w_shotdir, 1 );
 717                         if ( !actor.arc_smoke_sound )
 718                         {
 719                                 actor.arc_smoke_sound = 1;
 720                                 sound(actor, CH_SHOTS_SINGLE, SND_ARC_LOOP_OVERHEAT, VOL_BASE, ATTN_NORM);
 721                         }
 722                 }
 723         }
 724         else if ( actor.(weaponentity).arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 725                         actor.(weaponentity).arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 726         {
 727                 if ( random() < (actor.(weaponentity).arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 728                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 729                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 730         }
 731
 732         if (  actor.arc_smoke_sound && ( actor.arc_overheat <= time ||
 733                 !( PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor) ) ) || PS(actor).m_switchweapon != WEP_ARC )
 734         {
 735                 actor.arc_smoke_sound = 0;
 736                 sound(actor, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 737         }
 738 }
 739
 740 METHOD(Arc, wr_aim, void(entity thiswep, entity actor))
 741 {
 742     if(WEP_CVAR(arc, beam_botaimspeed))
 743     {
 744         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 745                 actor,
 746             WEP_CVAR(arc, beam_botaimspeed),
 747             0,
 748             WEP_CVAR(arc, beam_botaimlifetime),
 749             false
 750         );
 751     }
 752     else
 753     {
 754         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 755                 actor,
 756             1000000,
 757             0,
 758             0.001,
 759             false
 760         );
 761     }
 762 }
 763 METHOD(Arc, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 764 {
 765     Arc_Player_SetHeat(actor, weaponentity);
 766     Arc_Smoke(actor, weaponentity);
 767
 768     bool beam_fire2 = ((fire & 2) && !WEP_CVAR(arc, bolt));
 769     int slot = weaponslot(weaponentity);
 770
 771     if (time >= actor.arc_overheat)
 772     if ((fire & 1) || beam_fire2 || actor.(weaponentity).arc_beam.beam_bursting)
 773     {
 774
 775         if(actor.arc_BUTTON_ATCK_prev[slot])
 776         {
 777             #if 0
 778             if(actor.animstate_startframe == actor.anim_shoot.x && actor.animstate_numframes == actor.anim_shoot.y)
 779                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 780             else
 781             #endif
 782                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), w_ready);
 783         }
 784
 785         if((!actor.(weaponentity).arc_beam) || wasfreed(actor.(weaponentity).arc_beam))
 786         {
 787             if(weapon_prepareattack(thiswep, actor, weaponentity, boolean(beam_fire2), 0))
 788             {
 789                 W_Arc_Beam(boolean(beam_fire2), actor, weaponentity);
 790
 791                 if(!actor.arc_BUTTON_ATCK_prev[slot])
 792                 {
 793                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 794                     actor.arc_BUTTON_ATCK_prev[slot] = true;
 795                 }
 796             }
 797         }
 798
 799         return;
 800     }
 801     else if(fire & 2)
 802     {
 803         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(arc, bolt_refire)))
 804         {
 805             W_Arc_Attack_Bolt(thiswep, actor, weaponentity);
 806             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, bolt_refire), w_ready);
 807         }
 808     }
 809
 810     if(actor.arc_BUTTON_ATCK_prev[slot])
 811     {
 812         sound(actor, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 813         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 814         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor(actor);
 815     }
 816     actor.arc_BUTTON_ATCK_prev[slot] = false;
 817
 818     #if 0
 819     if(fire & 2)
 820     if(weapon_prepareattack(thiswep, actor, weaponentity, true, autocvar_g_balance_arc_secondary_refire))
 821     {
 822         W_Arc_Attack2();
 823         actor.arc_count = autocvar_g_balance_arc_secondary_count;
 824         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 825         actor.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor(actor);
 826     }
 827     #endif
 828 }
 829 METHOD(Arc, wr_init, void(entity thiswep))
 830 {
 831     if(!arc_shotorigin[0])
 832     {
 833         arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 834         arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 835         arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 836         arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 837     }
 838 }
 839 METHOD(Arc, wr_checkammo1, bool(entity thiswep, entity actor))
 840 {
 841     return ((!WEP_CVAR(arc, beam_ammo)) || (actor.(thiswep.ammo_field) > 0));
 842 }
 843 METHOD(Arc, wr_checkammo2, bool(entity thiswep, entity actor))
 844 {
 845     if(WEP_CVAR(arc, bolt))
 846     {
 847         float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(arc, bolt_ammo);
 848         ammo_amount += actor.(weapon_load[WEP_ARC.m_id]) >= WEP_CVAR(arc, bolt_ammo);
 849         return ammo_amount;
 850     }
 851     else
 852         return WEP_CVAR(arc, overheat_max) > 0 &&
 853             ((!WEP_CVAR(arc, burst_ammo)) || (actor.(thiswep.ammo_field) > 0));
 854 }
 855 METHOD(Arc, wr_killmessage, Notification(entity thiswep))
 856 {
 857     if(w_deathtype & HITTYPE_SECONDARY)
 858         return WEAPON_ARC_MURDER_SPRAY;
 859     else
 860         return WEAPON_ARC_MURDER;
 861 }
 862 METHOD(Arc, wr_drop, void(entity thiswep, entity actor))
 863 {
 864     weapon_dropevent_item.arc_overheat = actor.arc_overheat;
 865     weapon_dropevent_item.arc_cooldown = actor.arc_cooldown;
 866     actor.arc_overheat = 0;
 867     actor.arc_cooldown = 0;
 868     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 869         actor.arc_BUTTON_ATCK_prev[slot] = false;
 870 }
 871 METHOD(Arc, wr_pickup, void(entity thiswep, entity actor))
 872 {
 873     if ( !client_hasweapon(actor, thiswep, false, false) &&
 874         weapon_dropevent_item.arc_overheat > time )
 875     {
 876         actor.arc_overheat = weapon_dropevent_item.arc_overheat;
 877         actor.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 878     }
 879 }
 880 METHOD(Arc, wr_resetplayer, void(entity thiswep, entity actor))
 881 {
 882     actor.arc_overheat = 0;
 883     actor.arc_cooldown = 0;
 884     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 885         actor.arc_BUTTON_ATCK_prev[slot] = false;
 886 }
 887 METHOD(Arc, wr_playerdeath, void(entity thiswep, entity actor, .entity weaponentity))
 888 {
 889     actor.arc_overheat = 0;
 890     actor.arc_cooldown = 0;
 891     int slot = weaponslot(weaponentity);
 892     actor.arc_BUTTON_ATCK_prev[slot] = false;
 893 }
 894 #endif
 895 #ifdef CSQC
 896 bool autocvar_cl_arcbeam_teamcolor = true;
 897
 898 METHOD(Arc, wr_impacteffect, void(entity thiswep, entity actor))
 899 {
 900     if(w_deathtype & HITTYPE_SECONDARY)
 901     {
 902         vector org2;
 903         org2 = w_org + w_backoff * 6;
 904         pointparticles(EFFECT_ARC_BOLT_EXPLODE, org2, w_backoff * 1000, 1);
 905         if(!w_issilent) { sound(actor, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 906     }
 907 }
 908
 909 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 910 {
 911         entity beam = Draw_ArcBeam_callback_entity;
 912         vector transformed_view_org;
 913         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 914
 915         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 916         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 917         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 918
 919         vector hitorigin;
 920
 921         // draw segment
 922         #if 0
 923         if(trace_fraction != 1)
 924         {
 925                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 926                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 927                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 928         }
 929         else
 930         {
 931                 hitorigin = hit;
 932         }
 933         #else
 934         hitorigin = hit;
 935         #endif
 936
 937         // decide upon thickness
 938         float thickness = beam.beam_thickness;
 939
 940         // draw primary beam render
 941         vector top    = hitorigin + (thickdir * thickness);
 942         vector bottom = hitorigin - (thickdir * thickness);
 943
 944         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 945         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 946
 947         R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL); // DRAWFLAG_ADDITIVE
 948         R_PolygonVertex(
 949                 top,
 950                 '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 951                 beam.beam_color,
 952                 beam.beam_alpha
 953         );
 954         R_PolygonVertex(
 955                 last_top,
 956                 '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 957                 beam.beam_color,
 958                 beam.beam_alpha
 959         );
 960         R_PolygonVertex(
 961                 last_bottom,
 962                 '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 963                 beam.beam_color,
 964                 beam.beam_alpha
 965         );
 966         R_PolygonVertex(
 967                 bottom,
 968                 '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 969                 beam.beam_color,
 970                 beam.beam_alpha
 971         );
 972         R_EndPolygon();
 973
 974         // draw trailing particles
 975         // NOTES:
 976         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 977         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 978         if(beam.beam_traileffect)
 979         {
 980                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 981         }
 982
 983         // set up for the next
 984         Draw_ArcBeam_callback_last_thickness = thickness;
 985         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 986         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 987 }
 988
 989 void Reset_ArcBeam()
 990 {
 991         entity e;
 992         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 993                 e.beam_initialized = false;
 994         }
 995         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 996                 e.beam_initialized = false;
 997         }
 998 }
 999
1000 void Draw_ArcBeam(entity this)
1001 {
1002         float dt = time - this.move_time;
1003         this.move_time = time;
1004         if(dt <= 0) { return; }
1005
1006         if(!this.beam_usevieworigin)
1007         {
1008                 InterpolateOrigin_Do(this);
1009         }
1010
1011         // origin = beam starting origin
1012         // v_angle = wanted/aim direction
1013         // angles = current direction of beam
1014
1015         vector start_pos;
1016         vector wantdir; //= view_forward;
1017         vector beamdir; //= this.beam_dir;
1018
1019         float segments;
1020         if(this.beam_usevieworigin)
1021         {
1022                 // WEAPONTODO:
1023                 // Currently we have to replicate nearly the same method of figuring
1024                 // out the shotdir that the server does... Ideally in the future we
1025                 // should be able to acquire this from a generalized function built
1026                 // into a weapon system for client code.
1027
1028                 // find where we are aiming
1029                 makevectors(warpzone_save_view_angles);
1030                 vector forward = v_forward;
1031                 vector right = v_right;
1032                 vector up = v_up;
1033
1034                 // decide upon start position
1035                 if(this.beam_usevieworigin == 2)
1036                         { start_pos = warpzone_save_view_origin; }
1037                 else
1038                         { start_pos = this.origin; }
1039
1040                 // trace forward with an estimation
1041                 WarpZone_TraceLine(
1042                         start_pos,
1043                         start_pos + forward * this.beam_range,
1044                         MOVE_NOMONSTERS,
1045                         this
1046                 );
1047
1048                 // untransform in case our trace went through a warpzone
1049                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
1050
1051                 // un-adjust trueaim if shotend is too close
1052                 if(vdist(end_pos - start_pos, <, g_trueaim_minrange))
1053                         end_pos = start_pos + (forward * g_trueaim_minrange);
1054
1055                 // move shot origin to the actual gun muzzle origin
1056                 vector origin_offset =
1057                           right * -this.beam_shotorigin.y
1058                         + up * this.beam_shotorigin.z;
1059
1060                 start_pos = start_pos + origin_offset;
1061
1062                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
1063                 traceline(start_pos, start_pos + forward * this.beam_shotorigin.x, MOVE_NORMAL, this);
1064                 start_pos = trace_endpos;
1065
1066                 // calculate the aim direction now
1067                 wantdir = normalize(end_pos - start_pos);
1068
1069                 if(!this.beam_initialized)
1070                 {
1071                         this.beam_dir = wantdir;
1072                         this.beam_initialized = true;
1073                 }
1074
1075                 if(this.beam_dir != wantdir)
1076                 {
1077                         // calculate how much we're going to move the end of the beam to the want position
1078                         // WEAPONTODO (server and client):
1079                         // blendfactor never actually becomes 0 in this situation, which is a problem
1080                         // regarding precision... this means that this.beam_dir and w_shotdir approach
1081                         // eachother, however they never actually become the same value with this method.
1082                         // Perhaps we should do some form of rounding/snapping?
1083                         float angle = vlen(wantdir - this.beam_dir) * RAD2DEG;
1084                         if(angle && (angle > this.beam_maxangle))
1085                         {
1086                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
1087                                 float blendfactor = bound(
1088                                         0,
1089                                         (1 - (this.beam_returnspeed * frametime)),
1090                                         min(this.beam_maxangle / angle, 1)
1091                                 );
1092                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
1093                         }
1094                         else
1095                         {
1096                                 // the radius is not too far yet, no worries :D
1097                                 float blendfactor = bound(
1098                                         0,
1099                                         (1 - (this.beam_returnspeed * frametime)),
1100                                         1
1101                                 );
1102                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
1103                         }
1104
1105                         // calculate how many segments are needed
1106                         float max_allowed_segments;
1107
1108                         if(this.beam_distancepersegment)
1109                         {
1110                                 max_allowed_segments = min(
1111                                         ARC_MAX_SEGMENTS,
1112                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1113                                 );
1114                         }
1115                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1116
1117                         if(this.beam_degreespersegment)
1118                         {
1119                                 segments = bound(
1120                                         1,
1121                                         (
1122                                                 min(
1123                                                         angle,
1124                                                         this.beam_maxangle
1125                                                 )
1126                                                 /
1127                                                 this.beam_degreespersegment
1128                                         ),
1129                                         max_allowed_segments
1130                                 );
1131                         }
1132                         else { segments = 1; }
1133                 }
1134                 else { segments = 1; }
1135
1136                 // set the beam direction which the rest of the code will refer to
1137                 beamdir = this.beam_dir;
1138
1139                 // finally, set this.angles to the proper direction so that muzzle attachment points in proper direction
1140                 this.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1141         }
1142         else
1143         {
1144                 // set the values from the provided info from the networked entity
1145                 start_pos = this.origin;
1146                 wantdir = this.v_angle;
1147                 beamdir = this.angles;
1148
1149                 if(beamdir != wantdir)
1150                 {
1151                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1152
1153                         // calculate how many segments are needed
1154                         float max_allowed_segments;
1155
1156                         if(this.beam_distancepersegment)
1157                         {
1158                                 max_allowed_segments = min(
1159                                         ARC_MAX_SEGMENTS,
1160                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1161                                 );
1162                         }
1163                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1164
1165                         if(this.beam_degreespersegment)
1166                         {
1167                                 segments = bound(
1168                                         1,
1169                                         (
1170                                                 min(
1171                                                         angle,
1172                                                         this.beam_maxangle
1173                                                 )
1174                                                 /
1175                                                 this.beam_degreespersegment
1176                                         ),
1177                                         max_allowed_segments
1178                                 );
1179                         }
1180                         else { segments = 1; }
1181                 }
1182                 else { segments = 1; }
1183         }
1184
1185         setorigin(this, start_pos);
1186         this.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1187
1188         vector beam_endpos = (start_pos + (beamdir * this.beam_range));
1189         vector beam_controlpoint = start_pos + wantdir * (this.beam_range * (1 - this.beam_tightness));
1190
1191         Draw_ArcBeam_callback_entity = this;
1192         Draw_ArcBeam_callback_last_thickness = 0;
1193         Draw_ArcBeam_callback_last_top = start_pos;
1194         Draw_ArcBeam_callback_last_bottom = start_pos;
1195
1196         vector last_origin = start_pos;
1197         vector original_start_pos = start_pos;
1198
1199         float i;
1200         for(i = 1; i <= segments; ++i)
1201         {
1202                 // WEAPONTODO (client):
1203                 // In order to do nice fading and pointing on the starting segment, we must always
1204                 // have that drawn as a separate triangle... However, that is difficult to do when
1205                 // keeping in mind the above problems and also optimizing the amount of segments
1206                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1207
1208                 vector new_origin = bezier_quadratic_getpoint(
1209                         start_pos,
1210                         beam_controlpoint,
1211                         beam_endpos,
1212                         i / segments);
1213
1214                 WarpZone_TraceBox_ThroughZone(
1215                         last_origin,
1216                         '0 0 0',
1217                         '0 0 0',
1218                         new_origin,
1219                         MOVE_NORMAL,
1220                         NULL,
1221                         NULL,
1222                         Draw_ArcBeam_callback
1223                 );
1224
1225                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1226                 // system (if we hit a player, that's always BEHIND the last passed wz).
1227                 last_origin = trace_endpos;
1228                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1229                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1230                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1231                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1232                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1233                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1234
1235                 if(trace_fraction < 1) { break; }
1236         }
1237
1238         // visual effects for startpoint and endpoint
1239         if(this.beam_hiteffect)
1240         {
1241                 // FIXME we really should do this on the server so it actually
1242                 // matches gameplay. What this client side stuff is doing is no
1243                 // more than guesswork.
1244                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1245                 pointparticles(
1246                         this.beam_hiteffect,
1247                         last_origin,
1248                         beamdir * -1,
1249                         frametime * 2
1250                 );
1251         }
1252         if(this.beam_hitlight[0])
1253         {
1254                 adddynamiclight(
1255                         last_origin,
1256                         this.beam_hitlight[0],
1257                         vec3(
1258                                 this.beam_hitlight[1],
1259                                 this.beam_hitlight[2],
1260                                 this.beam_hitlight[3]
1261                         )
1262                 );
1263         }
1264         if(this.beam_muzzleeffect)
1265         {
1266                 pointparticles(
1267                         this.beam_muzzleeffect,
1268                         original_start_pos + wantdir * 20,
1269                         wantdir * 1000,
1270                         frametime * 0.1
1271                 );
1272         }
1273         if(this.beam_muzzlelight[0])
1274         {
1275                 adddynamiclight(
1276                         original_start_pos + wantdir * 20,
1277                         this.beam_muzzlelight[0],
1278                         vec3(
1279                                 this.beam_muzzlelight[1],
1280                                 this.beam_muzzlelight[2],
1281                                 this.beam_muzzlelight[3]
1282                         )
1283                 );
1284         }
1285
1286         // cleanup
1287         Draw_ArcBeam_callback_entity = NULL;
1288         Draw_ArcBeam_callback_last_thickness = 0;
1289         Draw_ArcBeam_callback_last_top = '0 0 0';
1290         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1291 }
1292
1293 void Remove_ArcBeam(entity this)
1294 {
1295         delete(this.beam_muzzleentity);
1296         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
1297 }
1298
1299 NET_HANDLE(ENT_CLIENT_ARC_BEAM, bool isnew)
1300 {
1301         int sf = ReadByte();
1302         entity flash;
1303
1304         if(isnew)
1305         {
1306                 int gunalign = W_GetGunAlignment(NULL);
1307
1308                 this.beam_shotorigin = arc_shotorigin[gunalign];
1309
1310                 // set other main attributes of the beam
1311                 this.draw = Draw_ArcBeam;
1312                 IL_PUSH(g_drawables, this);
1313                 this.entremove = Remove_ArcBeam;
1314                 this.move_time = time;
1315                 loopsound(this, CH_SHOTS_SINGLE, SND(ARC_LOOP), VOL_BASE, ATTEN_NORM);
1316
1317                 flash = spawn();
1318                 flash.owner = this;
1319                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1320                 flash.drawmask = MASK_NORMAL;
1321                 flash.solid = SOLID_NOT;
1322                 flash.avelocity_z = 5000;
1323                 setattachment(flash, this, "");
1324                 setorigin(flash, '0 0 0');
1325
1326                 this.beam_muzzleentity = flash;
1327         }
1328         else
1329         {
1330                 flash = this.beam_muzzleentity;
1331         }
1332
1333         if(sf & ARC_SF_SETTINGS) // settings information
1334         {
1335                 this.beam_degreespersegment = ReadShort();
1336                 this.beam_distancepersegment = ReadShort();
1337                 this.beam_maxangle = ReadShort();
1338                 this.beam_range = ReadCoord();
1339                 this.beam_returnspeed = ReadShort();
1340                 this.beam_tightness = (ReadByte() / 10);
1341
1342                 if(ReadByte())
1343                 {
1344                         if(autocvar_chase_active)
1345                                 { this.beam_usevieworigin = 1; }
1346                         else // use view origin
1347                                 { this.beam_usevieworigin = 2; }
1348                 }
1349                 else
1350                 {
1351                         this.beam_usevieworigin = 0;
1352                 }
1353
1354                 this.sv_entnum = ReadByte();
1355         }
1356
1357         if(!this.beam_usevieworigin)
1358         {
1359                 // this.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1360                 this.iflags = IFLAG_ORIGIN;
1361
1362                 InterpolateOrigin_Undo(this);
1363         }
1364
1365         if(sf & ARC_SF_START) // starting location
1366         {
1367                 this.origin_x = ReadCoord();
1368                 this.origin_y = ReadCoord();
1369                 this.origin_z = ReadCoord();
1370         }
1371         else if(this.beam_usevieworigin) // infer the location from player location
1372         {
1373                 if(this.beam_usevieworigin == 2)
1374                 {
1375                         // use view origin
1376                         this.origin = view_origin;
1377                 }
1378                 else
1379                 {
1380                         // use player origin so that third person display still works
1381                         this.origin = entcs_receiver(player_localnum).origin + ('0 0 1' * STAT(VIEWHEIGHT));
1382                 }
1383         }
1384
1385         setorigin(this, this.origin);
1386
1387         if(sf & ARC_SF_WANTDIR) // want/aim direction
1388         {
1389                 this.v_angle_x = ReadCoord();
1390                 this.v_angle_y = ReadCoord();
1391                 this.v_angle_z = ReadCoord();
1392         }
1393
1394         if(sf & ARC_SF_BEAMDIR) // beam direction
1395         {
1396                 this.angles_x = ReadCoord();
1397                 this.angles_y = ReadCoord();
1398                 this.angles_z = ReadCoord();
1399         }
1400
1401         if(sf & ARC_SF_BEAMTYPE) // beam type
1402         {
1403                 this.beam_type = ReadByte();
1404
1405                 vector beamcolor = ((autocvar_cl_arcbeam_teamcolor) ? colormapPaletteColor(entcs_GetClientColors(this.sv_entnum - 1) & 0x0F, true) : '1 1 1');
1406                 switch(this.beam_type)
1407                 {
1408                         case ARC_BT_MISS:
1409                         {
1410                                 this.beam_color = beamcolor;
1411                                 this.beam_alpha = 0.5;
1412                                 this.beam_thickness = 8;
1413                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1414                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1415                                 this.beam_hitlight[0] = 0;
1416                                 this.beam_hitlight[1] = 1;
1417                                 this.beam_hitlight[2] = 1;
1418                                 this.beam_hitlight[3] = 1;
1419                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1420                                 this.beam_muzzlelight[0] = 0;
1421                                 this.beam_muzzlelight[1] = 1;
1422                                 this.beam_muzzlelight[2] = 1;
1423                                 this.beam_muzzlelight[3] = 1;
1424                                 if(this.beam_muzzleeffect)
1425                                 {
1426                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1427                                         flash.alpha = this.beam_alpha;
1428                                         flash.colormod = this.beam_color;
1429                                         flash.scale = 0.5;
1430                                 }
1431                                 break;
1432                         }
1433                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1434                         {
1435                                 this.beam_color = beamcolor;
1436                                 this.beam_alpha = 0.5;
1437                                 this.beam_thickness = 8;
1438                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1439                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1440                                 this.beam_hitlight[0] = 0;
1441                                 this.beam_hitlight[1] = 1;
1442                                 this.beam_hitlight[2] = 1;
1443                                 this.beam_hitlight[3] = 1;
1444                                 this.beam_muzzleeffect = NULL; // (EFFECT_GRENADE_MUZZLEFLASH);
1445                                 this.beam_muzzlelight[0] = 0;
1446                                 this.beam_muzzlelight[1] = 1;
1447                                 this.beam_muzzlelight[2] = 1;
1448                                 this.beam_muzzlelight[3] = 1;
1449                                 this.beam_image = "particles/lgbeam";
1450                                 if(this.beam_muzzleeffect)
1451                                 {
1452                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1453                                         flash.alpha = this.beam_alpha;
1454                                         flash.colormod = this.beam_color;
1455                                         flash.scale = 0.5;
1456                                 }
1457                                 break;
1458                         }
1459                         case ARC_BT_HEAL:
1460                         {
1461                                 this.beam_color = beamcolor;
1462                                 this.beam_alpha = 0.5;
1463                                 this.beam_thickness = 8;
1464                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1465                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT);
1466                                 this.beam_hitlight[0] = 0;
1467                                 this.beam_hitlight[1] = 1;
1468                                 this.beam_hitlight[2] = 1;
1469                                 this.beam_hitlight[3] = 1;
1470                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1471                                 this.beam_muzzlelight[0] = 0;
1472                                 this.beam_muzzlelight[1] = 1;
1473                                 this.beam_muzzlelight[2] = 1;
1474                                 this.beam_muzzlelight[3] = 1;
1475                                 this.beam_image = "particles/lgbeam";
1476                                 if(this.beam_muzzleeffect)
1477                                 {
1478                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1479                                         flash.alpha = this.beam_alpha;
1480                                         flash.colormod = this.beam_color;
1481                                         flash.scale = 0.5;
1482                                 }
1483                                 break;
1484                         }
1485                         case ARC_BT_HIT:
1486                         {
1487                                 this.beam_color = beamcolor;
1488                                 this.beam_alpha = 0.5;
1489                                 this.beam_thickness = 8;
1490                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1491                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1492                                 this.beam_hitlight[0] = 20;
1493                                 this.beam_hitlight[1] = 1;
1494                                 this.beam_hitlight[2] = 0;
1495                                 this.beam_hitlight[3] = 0;
1496                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1497                                 this.beam_muzzlelight[0] = 50;
1498                                 this.beam_muzzlelight[1] = 1;
1499                                 this.beam_muzzlelight[2] = 0;
1500                                 this.beam_muzzlelight[3] = 0;
1501                                 this.beam_image = "particles/lgbeam";
1502                                 if(this.beam_muzzleeffect)
1503                                 {
1504                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1505                                         flash.alpha = this.beam_alpha;
1506                                         flash.colormod = this.beam_color;
1507                                         flash.scale = 0.5;
1508                                 }
1509                                 break;
1510                         }
1511                         case ARC_BT_BURST_MISS:
1512                         {
1513                                 this.beam_color = beamcolor;
1514                                 this.beam_alpha = 0.5;
1515                                 this.beam_thickness = 14;
1516                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1517                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1518                                 this.beam_hitlight[0] = 0;
1519                                 this.beam_hitlight[1] = 1;
1520                                 this.beam_hitlight[2] = 1;
1521                                 this.beam_hitlight[3] = 1;
1522                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1523                                 this.beam_muzzlelight[0] = 0;
1524                                 this.beam_muzzlelight[1] = 1;
1525                                 this.beam_muzzlelight[2] = 1;
1526                                 this.beam_muzzlelight[3] = 1;
1527                                 this.beam_image = "particles/lgbeam";
1528                                 if(this.beam_muzzleeffect)
1529                                 {
1530                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1531                                         flash.alpha = this.beam_alpha;
1532                                         flash.colormod = this.beam_color;
1533                                         flash.scale = 0.5;
1534                                 }
1535                                 break;
1536                         }
1537                         case ARC_BT_BURST_WALL:
1538                         {
1539                                 this.beam_color = beamcolor;
1540                                 this.beam_alpha = 0.5;
1541                                 this.beam_thickness = 14;
1542                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1543                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1544                                 this.beam_hitlight[0] = 0;
1545                                 this.beam_hitlight[1] = 1;
1546                                 this.beam_hitlight[2] = 1;
1547                                 this.beam_hitlight[3] = 1;
1548                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1549                                 this.beam_muzzlelight[0] = 0;
1550                                 this.beam_muzzlelight[1] = 1;
1551                                 this.beam_muzzlelight[2] = 1;
1552                                 this.beam_muzzlelight[3] = 1;
1553                                 this.beam_image = "particles/lgbeam";
1554                                 if(this.beam_muzzleeffect)
1555                                 {
1556                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1557                                         flash.alpha = this.beam_alpha;
1558                                         flash.colormod = this.beam_color;
1559                                         flash.scale = 0.5;
1560                                 }
1561                                 break;
1562                         }
1563                         case ARC_BT_BURST_HEAL:
1564                         {
1565                                 this.beam_color = beamcolor;
1566                                 this.beam_alpha = 0.5;
1567                                 this.beam_thickness = 14;
1568                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1569                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT2);
1570                                 this.beam_hitlight[0] = 0;
1571                                 this.beam_hitlight[1] = 1;
1572                                 this.beam_hitlight[2] = 1;
1573                                 this.beam_hitlight[3] = 1;
1574                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1575                                 this.beam_muzzlelight[0] = 0;
1576                                 this.beam_muzzlelight[1] = 1;
1577                                 this.beam_muzzlelight[2] = 1;
1578                                 this.beam_muzzlelight[3] = 1;
1579                                 this.beam_image = "particles/lgbeam";
1580                                 if(this.beam_muzzleeffect)
1581                                 {
1582                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1583                                         flash.alpha = this.beam_alpha;
1584                                         flash.colormod = this.beam_color;
1585                                         flash.scale = 0.5;
1586                                 }
1587                                 break;
1588                         }
1589                         case ARC_BT_BURST_HIT:
1590                         {
1591                                 this.beam_color = beamcolor;
1592                                 this.beam_alpha = 0.5;
1593                                 this.beam_thickness = 14;
1594                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1595                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1596                                 this.beam_hitlight[0] = 0;
1597                                 this.beam_hitlight[1] = 1;
1598                                 this.beam_hitlight[2] = 1;
1599                                 this.beam_hitlight[3] = 1;
1600                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1601                                 this.beam_muzzlelight[0] = 0;
1602                                 this.beam_muzzlelight[1] = 1;
1603                                 this.beam_muzzlelight[2] = 1;
1604                                 this.beam_muzzlelight[3] = 1;
1605                                 this.beam_image = "particles/lgbeam";
1606                                 if(this.beam_muzzleeffect)
1607                                 {
1608                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1609                                         flash.alpha = this.beam_alpha;
1610                                         flash.colormod = this.beam_color;
1611                                         flash.scale = 0.5;
1612                                 }
1613                                 break;
1614                         }
1615
1616                         // shouldn't be possible, but lets make it colorful if it does :D
1617                         default:
1618                         {
1619                                 this.beam_color = randomvec();
1620                                 this.beam_alpha = 1;
1621                                 this.beam_thickness = 8;
1622                                 this.beam_traileffect = NULL;
1623                                 this.beam_hiteffect = NULL;
1624                                 this.beam_hitlight[0] = 0;
1625                                 this.beam_hitlight[1] = 1;
1626                                 this.beam_hitlight[2] = 1;
1627                                 this.beam_hitlight[3] = 1;
1628                                 this.beam_muzzleeffect = NULL; //(EFFECT_VORTEX_MUZZLEFLASH);
1629                                 this.beam_muzzlelight[0] = 0;
1630                                 this.beam_muzzlelight[1] = 1;
1631                                 this.beam_muzzlelight[2] = 1;
1632                                 this.beam_muzzlelight[3] = 1;
1633                                 this.beam_image = "particles/lgbeam";
1634                                 if(this.beam_muzzleeffect)
1635                                 {
1636                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1637                                         flash.alpha = this.beam_alpha;
1638                                         flash.colormod = this.beam_color;
1639                                         flash.scale = 0.5;
1640                                 }
1641                                 break;
1642                         }
1643                 }
1644         }
1645
1646         if(!this.beam_usevieworigin)
1647         {
1648                 InterpolateOrigin_Note(this);
1649         }
1650         return true;
1651 }
1652
1653 #endif
1654 #endif