qcsrc/common/weapons/weapon/arc.qc

   1 #include "arc.qh"
   2
   3 #ifdef SVQC
   4 #include <common/gamemodes/gamemode/onslaught/sv_generator.qh>
   5 #include <common/gamemodes/gamemode/onslaught/sv_onslaught.qh>
   6
   7 bool W_Arc_Beam_Send(entity this, entity to, int sf)
   8 {
   9         WriteHeader(MSG_ENTITY, ENT_CLIENT_ARC_BEAM);
  10
  11         // Truncate information when this beam is displayed to the owner client
  12         // - The owner client has no use for beam start position or directions,
  13         //    it always figures this information out for itself with csqc code.
  14         // - Spectating the owner also truncates this information.
  15         float drawlocal = ((to == this.owner) || ((to.enemy == this.owner) && IS_SPEC(to)));
  16         if(drawlocal) { sf &= ~ARC_SF_LOCALMASK; }
  17
  18         WriteByte(MSG_ENTITY, sf);
  19         WriteByte(MSG_ENTITY, weaponslot(this.weaponentity_fld));
  20
  21         if(sf & ARC_SF_SETTINGS) // settings information
  22         {
  23                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_degreespersegment));
  24                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_distancepersegment));
  25                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_maxangle));
  26                 WriteCoord(MSG_ENTITY, WEP_CVAR(arc, beam_range));
  27                 WriteShort(MSG_ENTITY, WEP_CVAR(arc, beam_returnspeed));
  28                 WriteByte(MSG_ENTITY, WEP_CVAR(arc, beam_tightness) * 10);
  29
  30                 WriteByte(MSG_ENTITY, drawlocal);
  31                 WriteByte(MSG_ENTITY, etof(this.owner));
  32         }
  33         if(sf & ARC_SF_START) // starting location
  34         {
  35                 WriteVector(MSG_ENTITY, this.beam_start);
  36         }
  37         if(sf & ARC_SF_WANTDIR) // want/aim direction
  38         {
  39                 WriteVector(MSG_ENTITY, this.beam_wantdir);
  40         }
  41         if(sf & ARC_SF_BEAMDIR) // beam direction
  42         {
  43                 WriteAngleVector(MSG_ENTITY, this.beam_dir);
  44         }
  45         if(sf & ARC_SF_BEAMTYPE) // beam type
  46         {
  47                 WriteByte(MSG_ENTITY, this.beam_type);
  48         }
  49
  50         return true;
  51 }
  52
  53 void Reset_ArcBeam(entity player, vector forward)
  54 {
  55         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  56         {
  57                 .entity weaponentity = weaponentities[slot];
  58                 if(!player.(weaponentity).arc_beam)
  59                         continue;
  60                 player.(weaponentity).arc_beam.beam_dir = forward;
  61                 player.(weaponentity).arc_beam.beam_teleporttime = time;
  62         }
  63 }
  64
  65 float Arc_GetHeat_Percent(entity player, .entity weaponentity)
  66 {
  67         if ( WEP_CVAR(arc, overheat_max) <= 0 ||  WEP_CVAR(arc, overheat_max) <= 0 )
  68         {
  69                 player.arc_overheat = 0;
  70                 return 0;
  71         }
  72
  73         if ( player.(weaponentity).arc_beam )
  74                 return player.(weaponentity).arc_beam.beam_heat/WEP_CVAR(arc, overheat_max);
  75
  76         if ( player.arc_overheat > time )
  77         {
  78                 return (player.arc_overheat-time) / WEP_CVAR(arc, overheat_max)
  79                         * player.arc_cooldown;
  80         }
  81
  82         return 0;
  83 }
  84 void Arc_Player_SetHeat(entity player, .entity weaponentity)
  85 {
  86         player.(weaponentity).arc_heat_percent = Arc_GetHeat_Percent(player, weaponentity);
  87         //dprint("Heat: ",ftos(player.arc_heat_percent*100),"%\n");
  88 }
  89
  90 void W_Arc_Bolt_Explode(entity this, entity directhitentity)
  91 {
  92         this.event_damage = func_null;
  93         RadiusDamage(this, this.realowner, WEP_CVAR(arc, bolt_damage), WEP_CVAR(arc, bolt_edgedamage), WEP_CVAR(arc, bolt_radius), NULL, NULL, WEP_CVAR(arc, bolt_force), this.projectiledeathtype, this.weaponentity_fld, directhitentity);
  94
  95         delete(this);
  96 }
  97
  98 void W_Arc_Bolt_Explode_use(entity this, entity actor, entity trigger)
  99 {
 100         W_Arc_Bolt_Explode(this, trigger);
 101 }
 102
 103 void W_Arc_Bolt_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 104 {
 105         if(GetResource(this, RES_HEALTH) <= 0)
 106                 return;
 107
 108         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1))
 109                 return; // g_projectiles_damage says to halt
 110
 111         TakeResource(this, RES_HEALTH, damage);
 112         this.angles = vectoangles(this.velocity);
 113
 114         if(GetResource(this, RES_HEALTH) <= 0)
 115                 W_PrepareExplosionByDamage(this, attacker, getthink(this));
 116 }
 117
 118 void W_Arc_Bolt_Touch(entity this, entity toucher)
 119 {
 120         PROJECTILE_TOUCH(this, toucher);
 121         if(this.cnt >= WEP_CVAR(arc, bolt_bounce_count) || !WEP_CVAR(arc, bolt_bounce_count) || toucher.takedamage == DAMAGE_AIM) {
 122                 this.use(this, NULL, toucher);
 123         } else {
 124                 this.cnt++;
 125                 Send_Effect(EFFECT_BALL_SPARKS, this.origin, this.velocity, 1);
 126                 this.angles = vectoangles(this.velocity);
 127                 this.owner = NULL;
 128                 this.projectiledeathtype |= HITTYPE_BOUNCE;
 129                 if(WEP_CVAR(arc, bolt_bounce_explode))
 130                         RadiusDamage(this, this.realowner, WEP_CVAR(arc, bolt_damage), WEP_CVAR(arc, bolt_edgedamage), WEP_CVAR(arc, bolt_radius), NULL, NULL, WEP_CVAR(arc, bolt_force), this.projectiledeathtype, this.weaponentity_fld, toucher);
 131                 if(this.cnt == 1 && WEP_CVAR(arc, bolt_bounce_lifetime))
 132                         this.nextthink = time + WEP_CVAR(arc, bolt_bounce_lifetime);
 133         }
 134 }
 135
 136 void W_Arc_Attack_Bolt(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 137 {
 138         W_SetupShot(actor, weaponentity, false, 2, SND_ELECTRO_FIRE2, CH_WEAPON_A, WEP_CVAR(arc, bolt_damage), thiswep.m_id | HITTYPE_SECONDARY);
 139
 140         W_MuzzleFlash(thiswep, actor, weaponentity, w_shotorg, w_shotdir);
 141
 142         entity missile = new(missile);
 143         missile.owner = missile.realowner = actor;
 144         missile.bot_dodge = true;
 145         IL_PUSH(g_bot_dodge, missile);
 146         missile.bot_dodgerating = WEP_CVAR(arc, bolt_damage);
 147
 148         missile.takedamage = DAMAGE_YES;
 149         SetResourceExplicit(missile, RES_HEALTH, WEP_CVAR(arc, bolt_health));
 150         missile.damageforcescale = WEP_CVAR(arc, bolt_damageforcescale);
 151         missile.event_damage = W_Arc_Bolt_Damage;
 152         missile.damagedbycontents = true;
 153         IL_PUSH(g_damagedbycontents, missile);
 154
 155         settouch(missile, W_Arc_Bolt_Touch);
 156         missile.cnt = 0;
 157         missile.use = W_Arc_Bolt_Explode_use;
 158         setthink(missile, adaptor_think2use_hittype_splash);
 159         missile.nextthink = time + WEP_CVAR(arc, bolt_lifetime);
 160         PROJECTILE_MAKETRIGGER(missile);
 161         missile.projectiledeathtype = thiswep.m_id | HITTYPE_SECONDARY;
 162         missile.weaponentity_fld = weaponentity;
 163         setorigin(missile, w_shotorg);
 164         setsize(missile, '0 0 0', '0 0 0');
 165
 166         set_movetype(missile, MOVETYPE_BOUNCEMISSILE);
 167         W_SetupProjVelocity_PRE(missile, arc, bolt_);
 168
 169         missile.angles = vectoangles(missile.velocity);
 170         missile.flags = FL_PROJECTILE;
 171         IL_PUSH(g_projectiles, missile);
 172         missile.missile_flags = MIF_SPLASH;
 173
 174         CSQCProjectile(missile, true, PROJECTILE_ARC_BOLT, true);
 175
 176         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 177
 178         actor.(weaponentity).misc_bulletcounter = actor.(weaponentity).misc_bulletcounter + 1;
 179         if(actor.(weaponentity).misc_bulletcounter == 0)
 180         {
 181                 ATTACK_FINISHED(actor, weaponentity) = time + WEP_CVAR(arc, bolt_refire2) * W_WeaponRateFactor(actor);
 182                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, bolt_refire), w_ready);
 183         }
 184         else
 185         {
 186                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, bolt_refire), W_Arc_Attack_Bolt);
 187         }
 188 }
 189
 190 void W_Arc_Beam_Think(entity this)
 191 {
 192         .entity weaponentity = this.weaponentity_fld;
 193         entity own = this.owner;
 194         if(this != own.(weaponentity).arc_beam)
 195         {
 196                 delete(this);
 197                 return;
 198         }
 199
 200         float burst = 0;
 201         if( (PHYS_INPUT_BUTTON_ATCK2(own) && !WEP_CVAR(arc, bolt)) || this.beam_bursting)
 202         {
 203                 if(!this.beam_bursting)
 204                         this.beam_bursting = true;
 205                 burst = ARC_BT_BURSTMASK;
 206         }
 207
 208         Weapon thiswep = WEP_ARC;
 209
 210         // TODO: use standard weapon use checks here!
 211         if(!IS_PLAYER(own) || IS_DEAD(own) || STAT(FROZEN, own) || game_stopped || own.vehicle
 212                 || !weapon_prepareattack_check(thiswep, own, weaponentity, this.beam_bursting, -1)
 213                 || own.(weaponentity).m_switchweapon != WEP_ARC
 214                 || (!PHYS_INPUT_BUTTON_ATCK(own) && !burst)
 215                 || (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max)) )
 216         {
 217                 if ( WEP_CVAR(arc, cooldown) > 0 )
 218                 {
 219                         float cooldown_speed = 0;
 220                         if ( this.beam_heat > WEP_CVAR(arc, overheat_min) && WEP_CVAR(arc, cooldown) > 0 )
 221                         {
 222                                 cooldown_speed = WEP_CVAR(arc, cooldown);
 223                         }
 224                         else if ( !burst )
 225                         {
 226                                 cooldown_speed = this.beam_heat / WEP_CVAR(arc, beam_refire);
 227                         }
 228
 229                         bool overheat = (WEP_CVAR(arc, overheat_max) > 0 && this.beam_heat >= WEP_CVAR(arc, overheat_max));
 230                         if (overheat)
 231                         {
 232                                 Send_Effect(EFFECT_ARC_OVERHEAT, this.beam_start, this.beam_wantdir, 1);
 233                                 sound(this, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 234                         }
 235
 236                         if ( cooldown_speed )
 237                         {
 238                                 if (WEP_CVAR(arc, cooldown_release) || overheat)
 239                                         own.arc_overheat = time + this.beam_heat / cooldown_speed;
 240                                 own.arc_cooldown = cooldown_speed;
 241                         }
 242
 243                 }
 244
 245                 if(this == own.(weaponentity).arc_beam) { own.(weaponentity).arc_beam = NULL; }
 246                 if(!thiswep.wr_checkammo1(thiswep, own, weaponentity) && !(own.items & IT_UNLIMITED_AMMO))
 247                 {
 248                         // note: this doesn't force the switch
 249                         W_SwitchToOtherWeapon(own, weaponentity);
 250                 }
 251                 own.(weaponentity).arc_BUTTON_ATCK_prev = false; // allow switching weapons
 252                 delete(this);
 253                 return;
 254         }
 255
 256         // decrease ammo
 257         float coefficient = frametime;
 258         if(!(own.items & IT_UNLIMITED_AMMO))
 259         {
 260                 float rootammo;
 261                 if(burst)
 262                         { rootammo = WEP_CVAR(arc, burst_ammo); }
 263                 else
 264                         { rootammo = WEP_CVAR(arc, beam_ammo); }
 265
 266                 if(rootammo)
 267                 {
 268                         coefficient = min(coefficient, GetResource(own, thiswep.ammo_type) / rootammo);
 269                         SetResource(own, thiswep.ammo_type, max(0, GetResource(own, thiswep.ammo_type) - (rootammo * frametime)));
 270                 }
 271         }
 272         float heat_speed = burst ? WEP_CVAR(arc, burst_heat) : WEP_CVAR(arc, beam_heat);
 273         this.beam_heat = min( WEP_CVAR(arc, overheat_max), this.beam_heat + heat_speed*frametime );
 274
 275         makevectors(own.v_angle);
 276
 277         W_SetupShot_Range(
 278                 own,
 279                 weaponentity,
 280                 true,
 281                 0,
 282                 SND_Null,
 283                 0,
 284                 WEP_CVAR(arc, beam_damage) * coefficient,
 285                 WEP_CVAR(arc, beam_range),
 286                 thiswep.m_id
 287         );
 288
 289         // After teleport, "lock" the beam until the teleport is confirmed.
 290         if (time < this.beam_teleporttime + ANTILAG_LATENCY(own)) {
 291                 w_shotdir = this.beam_dir;
 292         }
 293
 294         // network information: shot origin and want/aim direction
 295         if(this.beam_start != w_shotorg)
 296         {
 297                 this.SendFlags |= ARC_SF_START;
 298                 this.beam_start = w_shotorg;
 299         }
 300         if(this.beam_wantdir != w_shotdir)
 301         {
 302                 this.SendFlags |= ARC_SF_WANTDIR;
 303                 this.beam_wantdir = w_shotdir;
 304         }
 305
 306         if(!this.beam_initialized)
 307         {
 308                 this.beam_dir = w_shotdir;
 309                 this.beam_initialized = true;
 310         }
 311
 312         // WEAPONTODO: Detect player velocity so that the beam curves when moving too
 313         // idea: blend together this.beam_dir with the inverted direction the player is moving in
 314         // might have to make some special accomodation so that it only uses view_right and view_up
 315
 316         // note that if we do this, it'll always be corrected to a maximum angle by beam_maxangle handling
 317
 318         float segments;
 319         if(this.beam_dir != w_shotdir)
 320         {
 321                 // calculate how much we're going to move the end of the beam to the want position
 322                 // WEAPONTODO (server and client):
 323                 // blendfactor never actually becomes 0 in this situation, which is a problem
 324                 // regarding precision... this means that this.beam_dir and w_shotdir approach
 325                 // eachother, however they never actually become the same value with this method.
 326                 // Perhaps we should do some form of rounding/snapping?
 327                 float angle = vlen(w_shotdir - this.beam_dir) * RAD2DEG;
 328                 if(angle && (angle > WEP_CVAR(arc, beam_maxangle)))
 329                 {
 330                         // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
 331                         float blendfactor = bound(
 332                                 0,
 333                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 334                                 min(WEP_CVAR(arc, beam_maxangle) / angle, 1)
 335                         );
 336                         if(vdist(this.beam_dir - w_shotdir, <, 0.01))
 337                                 this.beam_dir = w_shotdir;
 338                         else
 339                                 this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 340                 }
 341                 else
 342                 {
 343                         // the radius is not too far yet, no worries :D
 344                         float blendfactor = bound(
 345                                 0,
 346                                 (1 - (WEP_CVAR(arc, beam_returnspeed) * frametime)),
 347                                 1
 348                         );
 349                         if(vdist(this.beam_dir - w_shotdir, <, 0.01))
 350                                 this.beam_dir = w_shotdir;
 351                         else
 352                                 this.beam_dir = normalize((w_shotdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
 353                 }
 354
 355                 // network information: beam direction
 356                 this.SendFlags |= ARC_SF_BEAMDIR;
 357
 358                 // calculate how many segments are needed
 359                 float max_allowed_segments;
 360
 361                 if(WEP_CVAR(arc, beam_distancepersegment))
 362                 {
 363                         max_allowed_segments = min(
 364                                 ARC_MAX_SEGMENTS,
 365                                 1 + (vlen(w_shotdir / WEP_CVAR(arc, beam_distancepersegment)))
 366                         );
 367                 }
 368                 else { max_allowed_segments = ARC_MAX_SEGMENTS; }
 369
 370                 if(WEP_CVAR(arc, beam_degreespersegment))
 371                 {
 372                         segments = bound(
 373                                 1,
 374                                 (
 375                                         min(
 376                                                 angle,
 377                                                 WEP_CVAR(arc, beam_maxangle)
 378                                         )
 379                                         /
 380                                         WEP_CVAR(arc, beam_degreespersegment)
 381                                 ),
 382                                 max_allowed_segments
 383                         );
 384                 }
 385                 else { segments = 1; }
 386         }
 387         else { segments = 1; }
 388
 389         vector beam_endpos = (w_shotorg + (this.beam_dir * WEP_CVAR(arc, beam_range)));
 390         vector beam_controlpoint = w_shotorg + w_shotdir * (WEP_CVAR(arc, beam_range) * (1 - WEP_CVAR(arc, beam_tightness)));
 391
 392         float i;
 393         float new_beam_type = 0;
 394         vector last_origin = w_shotorg;
 395         for(i = 1; i <= segments; ++i)
 396         {
 397                 // WEAPONTODO (client):
 398                 // In order to do nice fading and pointing on the starting segment, we must always
 399                 // have that drawn as a separate triangle... However, that is difficult to do when
 400                 // keeping in mind the above problems and also optimizing the amount of segments
 401                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
 402
 403                 vector new_origin = bezier_quadratic_getpoint(
 404                         w_shotorg,
 405                         beam_controlpoint,
 406                         beam_endpos,
 407                         i / segments);
 408                 vector new_dir = normalize(new_origin - last_origin);
 409
 410                 WarpZone_traceline_antilag(
 411                         own,
 412                         last_origin,
 413                         new_origin,
 414                         MOVE_NORMAL,
 415                         own,
 416                         ANTILAG_LATENCY(own)
 417                 );
 418
 419                 // Do all the transforms for warpzones right now, as we already
 420                 // "are" in the post-trace system (if we hit a player, that's
 421                 // always BEHIND the last passed wz).
 422                 last_origin = trace_endpos;
 423                 w_shotorg = WarpZone_TransformOrigin(WarpZone_trace_transform, w_shotorg);
 424                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
 425                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
 426                 new_dir = WarpZone_TransformVelocity(WarpZone_trace_transform, new_dir);
 427
 428                 if(trace_ent)
 429                 {
 430                         bool is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
 431                         if(SAME_TEAM(own, trace_ent))
 432                         {
 433                                 float roothealth = ((burst) ? WEP_CVAR(arc, burst_healing_hps) : WEP_CVAR(arc, beam_healing_hps));
 434                                 float rootarmor = ((burst) ? WEP_CVAR(arc, burst_healing_aps) : WEP_CVAR(arc, beam_healing_aps));
 435                                 float hplimit = ((IS_PLAYER(trace_ent)) ? WEP_CVAR(arc, beam_healing_hmax) : RES_LIMIT_NONE);
 436                                 Heal(trace_ent, own, (roothealth * coefficient), hplimit);
 437                                 if(IS_PLAYER(trace_ent) && rootarmor)
 438                                 {
 439                                         if(GetResource(trace_ent, RES_ARMOR) <= WEP_CVAR(arc, beam_healing_amax))
 440                                         {
 441                                                 GiveResourceWithLimit(trace_ent, RES_ARMOR, (rootarmor * coefficient), WEP_CVAR(arc, beam_healing_amax));
 442                                                 trace_ent.pauserotarmor_finished = max(
 443                                                         trace_ent.pauserotarmor_finished,
 444                                                         time + autocvar_g_balance_pause_armor_rot
 445                                                 );
 446                                         }
 447                                 }
 448                                 if(roothealth || rootarmor)
 449                                         new_beam_type = ARC_BT_HEAL;
 450                         }
 451                         else if(trace_ent.takedamage && (is_player || WEP_CVAR(arc, beam_nonplayerdamage)))
 452                         {
 453                                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 454                                 // NO. trace_endpos should be just fine. If not,
 455                                 // that's an engine bug that needs proper debugging.
 456                                 vector hitorigin = trace_endpos;
 457
 458                                 float falloff = ExponentialFalloff(
 459                                         WEP_CVAR(arc, beam_falloff_mindist),
 460                                         WEP_CVAR(arc, beam_falloff_maxdist),
 461                                         WEP_CVAR(arc, beam_falloff_halflifedist),
 462                                         vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, hitorigin) - w_shotorg)
 463                                 );
 464
 465                                 float rootdamage;
 466                                 if(is_player)
 467                                 {
 468                                         if(burst)
 469                                                 { rootdamage = WEP_CVAR(arc, burst_damage); }
 470                                         else
 471                                                 { rootdamage = WEP_CVAR(arc, beam_damage); }
 472                                 }
 473                                 else
 474                                         { rootdamage = WEP_CVAR(arc, beam_nonplayerdamage); }
 475
 476                                 if(accuracy_isgooddamage(own, trace_ent))
 477                                 {
 478                                         accuracy_add(
 479                                                 own,
 480                                                 WEP_ARC,
 481                                                 0,
 482                                                 rootdamage * coefficient * falloff
 483                                         );
 484                                 }
 485
 486                                 Damage(
 487                                         trace_ent,
 488                                         own,
 489                                         own,
 490                                         rootdamage * coefficient * falloff,
 491                                         WEP_ARC.m_id,
 492                                         weaponentity,
 493                                         hitorigin,
 494                                         WEP_CVAR(arc, beam_force) * new_dir * coefficient * falloff
 495                                 );
 496
 497                                 new_beam_type = ARC_BT_HIT;
 498                         }
 499                         break;
 500                 }
 501                 else if(trace_fraction != 1)
 502                 {
 503                         // we collided with geometry
 504                         new_beam_type = ARC_BT_WALL;
 505                         break;
 506                 }
 507         }
 508
 509         // te_explosion(trace_endpos);
 510
 511         // if we're bursting, use burst visual effects
 512         new_beam_type |= burst;
 513
 514         // network information: beam type
 515         if(new_beam_type != this.beam_type)
 516         {
 517                 this.SendFlags |= ARC_SF_BEAMTYPE;
 518                 this.beam_type = new_beam_type;
 519         }
 520
 521         own.(weaponentity).beam_prev = time;
 522         this.nextthink = time;
 523 }
 524
 525 void W_Arc_Beam(float burst, entity actor, .entity weaponentity)
 526 {
 527
 528         // only play fire sound if 1 sec has passed since player let go the fire button
 529         if(time - actor.(weaponentity).beam_prev > 1)
 530                 sound(actor, CH_WEAPON_A, SND_ARC_FIRE, VOL_BASE, ATTN_NORM);
 531
 532         entity beam = actor.(weaponentity).arc_beam = new(W_Arc_Beam);
 533         beam.weaponentity_fld = weaponentity;
 534         beam.solid = SOLID_NOT;
 535         setthink(beam, W_Arc_Beam_Think);
 536         beam.owner = actor;
 537         set_movetype(beam, MOVETYPE_NONE);
 538         beam.bot_dodge = true;
 539         IL_PUSH(g_bot_dodge, beam);
 540         beam.bot_dodgerating = WEP_CVAR(arc, beam_damage);
 541         beam.beam_bursting = burst;
 542         Net_LinkEntity(beam, false, 0, W_Arc_Beam_Send);
 543
 544         getthink(beam)(beam);
 545 }
 546 void W_Arc_Attack(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 547 {
 548         if(!actor.(weaponentity).arc_beam || wasfreed(actor.(weaponentity).arc_beam))
 549         {
 550                 w_ready(thiswep, actor, weaponentity, fire);
 551                 return;
 552         }
 553
 554         // attack handled by the beam itself, this is just a loop to keep the attack happening!
 555
 556         // NOTE: arc doesn't use a refire
 557         //ATTACK_FINISHED(actor, weaponentity) = time + WEP_CVAR_PRI(arc, refire) * W_WeaponRateFactor(actor);
 558         actor.(weaponentity).wframe = WFRAME_FIRE1;
 559         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), W_Arc_Attack);
 560 }
 561 void Arc_Smoke(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 562 {
 563         // calculate a rough shot origin to show the effect from TODO: move this to the client side!
 564         makevectors(actor.v_angle);
 565         w_shotdir = v_forward;
 566         vector md = actor.(weaponentity).movedir;
 567         vector vecs = ((md.x > 0) ? md : '0 0 0');
 568         vector dv = v_forward * vecs.x + v_right * -vecs.y + v_up * vecs.z;
 569         w_shotorg = actor.origin + actor.view_ofs + dv;
 570         //W_SetupShot_Range(actor,weaponentity,false,0,SND_Null,0,0,0,thiswep.m_id);
 571
 572         vector smoke_origin = w_shotorg + actor.velocity*frametime;
 573         if ( actor.arc_overheat > time )
 574         {
 575                 if ( random() < actor.(weaponentity).arc_heat_percent )
 576                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 577                 if ( (fire & 1) || (fire & 2) )
 578                 {
 579                         Send_Effect(EFFECT_ARC_OVERHEAT_FIRE, smoke_origin, w_shotdir, 1 );
 580                         if ( !actor.arc_smoke_sound )
 581                         {
 582                                 actor.arc_smoke_sound = 1;
 583                                 sound(actor, CH_SHOTS_SINGLE, SND_ARC_LOOP_OVERHEAT, VOL_BASE, ATTN_NORM);
 584                         }
 585                 }
 586         }
 587         else if ( actor.(weaponentity).arc_beam && WEP_CVAR(arc, overheat_max) > 0 &&
 588                         actor.(weaponentity).arc_beam.beam_heat > WEP_CVAR(arc, overheat_min) )
 589         {
 590                 if ( random() < (actor.(weaponentity).arc_beam.beam_heat-WEP_CVAR(arc, overheat_min)) /
 591                                 ( WEP_CVAR(arc, overheat_max)-WEP_CVAR(arc, overheat_min) ) )
 592                         Send_Effect(EFFECT_ARC_SMOKE, smoke_origin, '0 0 0', 1 );
 593         }
 594
 595         bool attacking = PHYS_INPUT_BUTTON_ATCK(actor) || PHYS_INPUT_BUTTON_ATCK2(actor);
 596         bool stop_smoke_sound = actor.arc_overheat <= time || !attacking;
 597         if ((actor.arc_smoke_sound && stop_smoke_sound) || actor.(weaponentity).m_switchweapon != thiswep)
 598         {
 599                 actor.arc_smoke_sound = 0;
 600                 sound(actor, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 601         }
 602 }
 603
 604 METHOD(Arc, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 605 {
 606     if(WEP_CVAR(arc, beam_botaimspeed))
 607     {
 608         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 609                 actor,
 610                 weaponentity,
 611             WEP_CVAR(arc, beam_botaimspeed),
 612             0,
 613             WEP_CVAR(arc, beam_botaimlifetime),
 614             false
 615         );
 616     }
 617     else
 618     {
 619         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(
 620                 actor,
 621                 weaponentity,
 622             1000000,
 623             0,
 624             0.001,
 625             false
 626         );
 627     }
 628 }
 629 METHOD(Arc, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 630 {
 631     Arc_Player_SetHeat(actor, weaponentity);
 632     Arc_Smoke(thiswep, actor, weaponentity, fire);
 633
 634     bool beam_fire2 = ((fire & 2) && !WEP_CVAR(arc, bolt));
 635
 636     if (time >= actor.arc_overheat)
 637     if ((fire & 1) || beam_fire2 || actor.(weaponentity).arc_beam.beam_bursting)
 638     {
 639         #if 0
 640         if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 641         {
 642             #if 0
 643             if(actor.animstate_startframe == actor.anim_shoot.x && actor.animstate_numframes == actor.anim_shoot.y)
 644                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, autocvar_g_balance_arc_primary_animtime, w_ready);
 645             else
 646             #endif
 647                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), w_ready);
 648         }
 649         #endif
 650
 651         if((!actor.(weaponentity).arc_beam) || wasfreed(actor.(weaponentity).arc_beam))
 652         {
 653             if(weapon_prepareattack(thiswep, actor, weaponentity, boolean(beam_fire2), 0))
 654             {
 655                 W_Arc_Beam(boolean(beam_fire2), actor, weaponentity);
 656
 657                 if(!actor.(weaponentity).arc_BUTTON_ATCK_prev)
 658                 {
 659                         actor.(weaponentity).wframe = WFRAME_FIRE1;
 660                     weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, WEP_CVAR(arc, beam_animtime), W_Arc_Attack);
 661                     actor.(weaponentity).arc_BUTTON_ATCK_prev = true;
 662                 }
 663             }
 664         }
 665
 666         return;
 667     }
 668     else if(fire & 2)
 669     {
 670         if(weapon_prepareattack(thiswep, actor, weaponentity, true, 0))
 671         {
 672             if(!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 673             if(!(actor.items & IT_UNLIMITED_AMMO))
 674             {
 675                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 676                 w_ready(thiswep, actor, weaponentity, fire);
 677                 return;
 678             }
 679             float ammo_available = GetResource(actor, thiswep.ammo_type);
 680             // We don't want to shoot 3 rounds if there's 2 left in the mag, so we'll use a fraction.
 681             // Also keep the fraction <= 1 otherwise we'd mag dump in one burst.
 682             float burst_fraction = min(1, ammo_available / WEP_CVAR(arc, bolt_ammo));
 683             int to_shoot = floor(WEP_CVAR(arc, bolt_count) * burst_fraction);
 684
 685             // We also don't want to use 3 rounds if there's only 2 left.
 686             int to_use = min(WEP_CVAR(arc, bolt_ammo), ammo_available);
 687             W_DecreaseAmmo(thiswep, actor, to_use, weaponentity);
 688
 689             // Bursting counts up to 0 from a negative.
 690             actor.(weaponentity).misc_bulletcounter = -to_shoot;
 691             W_Arc_Attack_Bolt(thiswep, actor, weaponentity, fire);
 692         }
 693     }
 694
 695     if(actor.(weaponentity).arc_BUTTON_ATCK_prev)
 696     {
 697         sound(actor, CH_WEAPON_A, SND_ARC_STOP, VOL_BASE, ATTN_NORM);
 698         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(arc, beam_animtime), w_ready);
 699         ATTACK_FINISHED(actor, weaponentity) = time + WEP_CVAR(arc, beam_refire) * W_WeaponRateFactor(actor);
 700     }
 701     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 702
 703     #if 0
 704     if(fire & 2)
 705     if(weapon_prepareattack(thiswep, actor, weaponentity, true, autocvar_g_balance_arc_secondary_refire))
 706     {
 707         W_Arc_Attack2();
 708         actor.arc_count = autocvar_g_balance_arc_secondary_count;
 709         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, autocvar_g_balance_arc_secondary_animtime, w_arc_checkattack);
 710         actor.arc_secondarytime = time + autocvar_g_balance_arc_secondary_refire2 * W_WeaponRateFactor(actor);
 711     }
 712     #endif
 713 }
 714 METHOD(Arc, wr_suicidemessage, Notification(entity thiswep))
 715 {
 716     if(w_deathtype & HITTYPE_SECONDARY)
 717         return WEAPON_ARC_SUICIDE_BOLT;
 718     else
 719         return WEAPON_THINKING_WITH_PORTALS;
 720 }
 721 METHOD(Arc, wr_init, void(entity thiswep))
 722 {
 723     if(!arc_shotorigin[0])
 724     {
 725         arc_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 1);
 726         arc_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 2);
 727         arc_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 3);
 728         arc_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ARC.m_id), false, false, 4);
 729     }
 730 }
 731 METHOD(Arc, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 732 {
 733     return ((!WEP_CVAR(arc, beam_ammo)) || (GetResource(actor, thiswep.ammo_type) > 0));
 734 }
 735 METHOD(Arc, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 736 {
 737     if(WEP_CVAR(arc, bolt))
 738     {
 739         float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR(arc, bolt_ammo);
 740         ammo_amount += actor.(weaponentity).(weapon_load[WEP_ARC.m_id]) >= WEP_CVAR(arc, bolt_ammo);
 741         return ammo_amount;
 742     }
 743     else
 744         return WEP_CVAR(arc, overheat_max) > 0 &&
 745             ((!WEP_CVAR(arc, burst_ammo)) || (GetResource(actor, thiswep.ammo_type) > 0));
 746 }
 747 METHOD(Arc, wr_killmessage, Notification(entity thiswep))
 748 {
 749     if(w_deathtype & HITTYPE_SECONDARY)
 750         return WEAPON_ARC_MURDER_SPRAY;
 751     else
 752         return WEAPON_ARC_MURDER;
 753 }
 754 METHOD(Arc, wr_drop, void(entity thiswep, entity actor, .entity weaponentity))
 755 {
 756     weapon_dropevent_item.arc_overheat = actor.arc_overheat;
 757     weapon_dropevent_item.arc_cooldown = actor.arc_cooldown;
 758     actor.arc_overheat = 0;
 759     actor.arc_cooldown = 0;
 760     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 761 }
 762 METHOD(Arc, wr_pickup, void(entity thiswep, entity actor, .entity weaponentity))
 763 {
 764     if ( !client_hasweapon(actor, thiswep, weaponentity, false, false) &&
 765         weapon_dropevent_item.arc_overheat > time )
 766     {
 767         actor.arc_overheat = weapon_dropevent_item.arc_overheat;
 768         actor.arc_cooldown = weapon_dropevent_item.arc_cooldown;
 769     }
 770 }
 771 METHOD(Arc, wr_resetplayer, void(entity thiswep, entity actor))
 772 {
 773     actor.arc_overheat = 0;
 774     actor.arc_cooldown = 0;
 775     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 776     {
 777         .entity weaponentity = weaponentities[slot];
 778         actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 779     }
 780 }
 781 METHOD(Arc, wr_playerdeath, void(entity thiswep, entity actor, .entity weaponentity))
 782 {
 783     actor.arc_overheat = 0;
 784     actor.arc_cooldown = 0;
 785     actor.(weaponentity).arc_BUTTON_ATCK_prev = false;
 786 }
 787 #endif
 788 #ifdef CSQC
 789 bool autocvar_cl_arcbeam_teamcolor = true;
 790 bool autocvar_cl_arcbeam_simple = true;
 791
 792 .int beam_slot;
 793
 794 METHOD(Arc, wr_impacteffect, void(entity thiswep, entity actor))
 795 {
 796     if(w_deathtype & HITTYPE_SECONDARY)
 797     {
 798         vector org2;
 799         org2 = w_org + w_backoff * 6;
 800         pointparticles(EFFECT_ELECTRO_IMPACT, org2, w_backoff * 1000, 1);
 801         if(!w_issilent) { sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTN_NORM); }
 802     }
 803 }
 804
 805 void Draw_ArcBeam_callback(vector start, vector hit, vector end)
 806 {
 807         entity beam = Draw_ArcBeam_callback_entity;
 808         vector transformed_view_org;
 809         transformed_view_org = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 810
 811         // Thickdir shall be perpendicular to the beam and to the view-to-beam direction (WEAPONTODO: WHY)
 812         // WEAPONTODO: Wouldn't it be better to be perpendicular to the beam and to the view FORWARD direction?
 813         vector thickdir = normalize(cross(normalize(start - hit), transformed_view_org - start));
 814
 815         vector hitorigin;
 816
 817         // draw segment
 818         #if 0
 819         if(trace_fraction != 1)
 820         {
 821                 // calculate our own hit origin as trace_endpos tends to jump around annoyingly (to player origin?)
 822                 hitorigin = start + (Draw_ArcBeam_callback_new_dir * Draw_ArcBeam_callback_segmentdist * trace_fraction);
 823                 hitorigin = WarpZone_TransformOrigin(WarpZone_trace_transform, hitorigin);
 824         }
 825         else
 826         {
 827                 hitorigin = hit;
 828         }
 829         #else
 830         hitorigin = hit;
 831         #endif
 832
 833         // decide upon thickness
 834         float thickness = beam.beam_thickness;
 835
 836         // draw primary beam render
 837         vector top    = hitorigin + (thickdir * thickness);
 838         vector bottom = hitorigin - (thickdir * thickness);
 839
 840         vector last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
 841         vector last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
 842
 843         if(autocvar_cl_arcbeam_simple)
 844                 Draw_CylindricLine(start, end, thickness, beam.beam_image, 0.25, -time * 3, beam.beam_color, beam.beam_alpha, DRAWFLAG_NORMAL, transformed_view_org);
 845         else
 846         {
 847                 R_BeginPolygon(beam.beam_image, DRAWFLAG_NORMAL, false); // DRAWFLAG_ADDITIVE
 848                 R_PolygonVertex(
 849                         top,
 850                         '0 0.5 0' + ('0 0.5 0' * (thickness / beam.beam_thickness)),
 851                         beam.beam_color,
 852                         beam.beam_alpha
 853                 );
 854                 R_PolygonVertex(
 855                         last_top,
 856                         '0 0.5 0' + ('0 0.5 0' * (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 857                         beam.beam_color,
 858                         beam.beam_alpha
 859                 );
 860                 R_PolygonVertex(
 861                         last_bottom,
 862                         '0 0.5 0' * (1 - (Draw_ArcBeam_callback_last_thickness / beam.beam_thickness)),
 863                         beam.beam_color,
 864                         beam.beam_alpha
 865                 );
 866                 R_PolygonVertex(
 867                         bottom,
 868                         '0 0.5 0' * (1 - (thickness / beam.beam_thickness)),
 869                         beam.beam_color,
 870                         beam.beam_alpha
 871                 );
 872                 R_EndPolygon();
 873         }
 874
 875         // draw trailing particles
 876         // NOTES:
 877         //  - Don't use spammy particle counts here, use a FEW small particles around the beam
 878         //  - We're not using WarpZone_TrailParticles here because we will handle warpzones ourselves.
 879         if(beam.beam_traileffect)
 880         {
 881                 trailparticles(beam, beam.beam_traileffect, start, hitorigin);
 882         }
 883
 884         // set up for the next
 885         Draw_ArcBeam_callback_last_thickness = thickness;
 886         Draw_ArcBeam_callback_last_top = WarpZone_UnTransformOrigin(WarpZone_trace_transform, top);
 887         Draw_ArcBeam_callback_last_bottom = WarpZone_UnTransformOrigin(WarpZone_trace_transform, bottom);
 888 }
 889
 890 void Reset_ArcBeam()
 891 {
 892         entity e;
 893         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 1)); ) {
 894                 e.beam_initialized = false;
 895         }
 896         for (e = NULL; (e = findfloat(e, beam_usevieworigin, 2)); ) {
 897                 e.beam_initialized = false;
 898         }
 899 }
 900
 901 void Draw_ArcBeam(entity this)
 902 {
 903         float dt = time - this.move_time;
 904         this.move_time = time;
 905         if(dt <= 0) { return; }
 906
 907         if(!this.beam_usevieworigin)
 908         {
 909                 InterpolateOrigin_Do(this);
 910         }
 911
 912         // origin = beam starting origin
 913         // v_angle = wanted/aim direction
 914         // angles = current direction of beam
 915
 916         vector start_pos;
 917         vector wantdir; //= view_forward;
 918         vector beamdir; //= this.beam_dir;
 919
 920         float segments;
 921         if(this.beam_usevieworigin)
 922         {
 923                 // WEAPONTODO:
 924                 // Currently we have to replicate nearly the same method of figuring
 925                 // out the shotdir that the server does... Ideally in the future we
 926                 // should be able to acquire this from a generalized function built
 927                 // into a weapon system for client code.
 928
 929                 // find where we are aiming
 930                 vector myviewangle = view_angles;
 931                 if (autocvar_chase_active)
 932                 {
 933                         if (autocvar_cl_lockview)
 934                                 myviewangle = eX * csqcplayer.v_angle.x + eY * csqcplayer.angles.y;
 935                         else
 936                                 myviewangle = warpzone_save_view_angles;
 937                 }
 938                 vector forward, right, up;
 939                 MAKE_VECTORS(myviewangle, forward, right, up);
 940                 entity wepent = viewmodels[this.beam_slot];
 941
 942                 this.beam_usevieworigin = (autocvar_chase_active) ? 1 : 2;
 943
 944                 // decide upon start position
 945                 if(this.beam_usevieworigin == 2)
 946                         { start_pos = warpzone_save_view_origin; }
 947                 else if(csqcplayer)
 948                         { start_pos = csqcplayer.origin + csqcplayer.view_ofs; }
 949                 else
 950                         { start_pos = this.origin; }
 951
 952                 // trace forward with an estimation
 953                 WarpZone_TraceLine(
 954                         start_pos,
 955                         start_pos + forward * this.beam_range,
 956                         MOVE_NOMONSTERS,
 957                         this
 958                 );
 959
 960                 int v_shot_idx;  // used later
 961                 (v_shot_idx = gettagindex(wepent, "shot")) || (v_shot_idx = gettagindex(wepent, "tag_shot"));
 962                 if(v_shot_idx && this.beam_usevieworigin == 2)
 963                         start_pos = gettaginfo(wepent, v_shot_idx) - '0 0 2';
 964
 965                 // untransform in case our trace went through a warpzone
 966                 vector end_pos = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 967
 968                 // un-adjust trueaim if shotend is too close
 969                 if(vdist(end_pos - start_pos, <, g_trueaim_minrange))
 970                         end_pos = start_pos + (forward * g_trueaim_minrange);
 971
 972                 // move shot origin to the actual gun muzzle origin
 973                 vector origin_offset = '0 0 0';
 974                 if(!v_shot_idx || this.beam_usevieworigin != 2)
 975                 {
 976                         this.beam_shotorigin = wepent.movedir;
 977                         origin_offset = right * -this.beam_shotorigin.y + up * this.beam_shotorigin.z;
 978                 }
 979                 else
 980                         this.beam_shotorigin = '0 0 0';
 981
 982                 start_pos = start_pos + origin_offset;
 983
 984                 // Move it also forward, but only as far as possible without hitting anything. Don't poke into walls!
 985                 traceline(start_pos, start_pos + forward * this.beam_shotorigin.x, MOVE_NORMAL, this);
 986                 start_pos = trace_endpos;
 987
 988                 // calculate the aim direction now
 989                 wantdir = normalize(end_pos - start_pos);
 990
 991                 if(!this.beam_initialized)
 992                 {
 993                         this.beam_dir = wantdir;
 994                         this.beam_initialized = true;
 995
 996                         this.beam_muzzleentity.drawmask = MASK_NORMAL; // NOTE: this works around the muzzle entity flashing on the middle of the screen for a frame
 997                 }
 998
 999                 if(this.beam_dir != wantdir)
1000                 {
1001                         // calculate how much we're going to move the end of the beam to the want position
1002                         // WEAPONTODO (server and client):
1003                         // blendfactor never actually becomes 0 in this situation, which is a problem
1004                         // regarding precision... this means that this.beam_dir and w_shotdir approach
1005                         // eachother, however they never actually become the same value with this method.
1006                         // Perhaps we should do some form of rounding/snapping?
1007                         float angle = vlen(wantdir - this.beam_dir) * RAD2DEG;
1008                         if(angle && (angle > this.beam_maxangle))
1009                         {
1010                                 // if the angle is greater than maxangle, force the blendfactor to make this the maximum factor
1011                                 float blendfactor = bound(
1012                                         0,
1013                                         (1 - (this.beam_returnspeed * dt)),
1014                                         min(this.beam_maxangle / angle, 1)
1015                                 );
1016                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
1017                         }
1018                         else
1019                         {
1020                                 // the radius is not too far yet, no worries :D
1021                                 float blendfactor = bound(
1022                                         0,
1023                                         (1 - (this.beam_returnspeed * dt)),
1024                                         1
1025                                 );
1026                                 this.beam_dir = normalize((wantdir * (1 - blendfactor)) + (this.beam_dir * blendfactor));
1027                         }
1028
1029                         // calculate how many segments are needed
1030                         float max_allowed_segments;
1031
1032                         if(this.beam_distancepersegment)
1033                         {
1034                                 max_allowed_segments = min(
1035                                         ARC_MAX_SEGMENTS,
1036                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1037                                 );
1038                         }
1039                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1040
1041                         if(this.beam_degreespersegment)
1042                         {
1043                                 segments = bound(
1044                                         1,
1045                                         (
1046                                                 min(
1047                                                         angle,
1048                                                         this.beam_maxangle
1049                                                 )
1050                                                 /
1051                                                 this.beam_degreespersegment
1052                                         ),
1053                                         max_allowed_segments
1054                                 );
1055                         }
1056                         else { segments = 1; }
1057                 }
1058                 else { segments = 1; }
1059
1060                 // set the beam direction which the rest of the code will refer to
1061                 beamdir = this.beam_dir;
1062
1063                 // finally, set this.angles to the proper direction so that muzzle attachment points in proper direction
1064                 this.angles = fixedvectoangles2(forward, up); // TODO(Samual): is this == warpzone_save_view_angles?
1065         }
1066         else
1067         {
1068                 // set the values from the provided info from the networked entity
1069                 start_pos = this.origin;
1070                 wantdir = this.v_angle;
1071                 beamdir = this.angles;
1072
1073                 if(beamdir != wantdir)
1074                 {
1075                         float angle = vlen(wantdir - beamdir) * RAD2DEG;
1076
1077                         // calculate how many segments are needed
1078                         float max_allowed_segments;
1079
1080                         if(this.beam_distancepersegment)
1081                         {
1082                                 max_allowed_segments = min(
1083                                         ARC_MAX_SEGMENTS,
1084                                         1 + (vlen(wantdir / this.beam_distancepersegment))
1085                                 );
1086                         }
1087                         else { max_allowed_segments = ARC_MAX_SEGMENTS; }
1088
1089                         if(this.beam_degreespersegment)
1090                         {
1091                                 segments = bound(
1092                                         1,
1093                                         (
1094                                                 min(
1095                                                         angle,
1096                                                         this.beam_maxangle
1097                                                 )
1098                                                 /
1099                                                 this.beam_degreespersegment
1100                                         ),
1101                                         max_allowed_segments
1102                                 );
1103                         }
1104                         else { segments = 1; }
1105                 }
1106                 else { segments = 1; }
1107         }
1108
1109         setorigin(this, start_pos);
1110         this.beam_muzzleentity.angles_z = random() * 360; // WEAPONTODO: use avelocity instead?
1111
1112         vector beam_endpos = (start_pos + (beamdir * this.beam_range));
1113         vector beam_controlpoint = start_pos + wantdir * (this.beam_range * (1 - this.beam_tightness));
1114
1115         Draw_ArcBeam_callback_entity = this;
1116         Draw_ArcBeam_callback_last_thickness = 0;
1117         Draw_ArcBeam_callback_last_top = start_pos;
1118         Draw_ArcBeam_callback_last_bottom = start_pos;
1119
1120         vector last_origin = start_pos;
1121         vector original_start_pos = start_pos;
1122
1123         float i;
1124         for(i = 1; i <= segments; ++i)
1125         {
1126                 // WEAPONTODO (client):
1127                 // In order to do nice fading and pointing on the starting segment, we must always
1128                 // have that drawn as a separate triangle... However, that is difficult to do when
1129                 // keeping in mind the above problems and also optimizing the amount of segments
1130                 // drawn on screen at any given time. (Automatic beam quality scaling, essentially)
1131
1132                 vector new_origin = bezier_quadratic_getpoint(
1133                         start_pos,
1134                         beam_controlpoint,
1135                         beam_endpos,
1136                         i / segments);
1137
1138                 WarpZone_TraceBox_ThroughZone(
1139                         last_origin,
1140                         '0 0 0',
1141                         '0 0 0',
1142                         new_origin,
1143                         MOVE_NORMAL,
1144                         NULL,
1145                         NULL,
1146                         Draw_ArcBeam_callback
1147                 );
1148
1149                 // Do all the transforms for warpzones right now, as we already "are" in the post-trace
1150                 // system (if we hit a player, that's always BEHIND the last passed wz).
1151                 last_origin = trace_endpos;
1152                 start_pos = WarpZone_TransformOrigin(WarpZone_trace_transform, start_pos);
1153                 beam_controlpoint = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_controlpoint);
1154                 beam_endpos = WarpZone_TransformOrigin(WarpZone_trace_transform, beam_endpos);
1155                 beamdir = WarpZone_TransformVelocity(WarpZone_trace_transform, beamdir);
1156                 Draw_ArcBeam_callback_last_top = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_top);
1157                 Draw_ArcBeam_callback_last_bottom = WarpZone_TransformOrigin(WarpZone_trace_transform, Draw_ArcBeam_callback_last_bottom);
1158
1159                 if(trace_fraction < 1) { break; }
1160         }
1161
1162         // visual effects for startpoint and endpoint
1163         if(this.beam_hiteffect)
1164         {
1165                 // FIXME we really should do this on the server so it actually
1166                 // matches gameplay. What this client side stuff is doing is no
1167                 // more than guesswork.
1168                 if((trace_ent || trace_fraction < 1) && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
1169                 pointparticles(
1170                         this.beam_hiteffect,
1171                         last_origin,
1172                         beamdir * -1,
1173                         dt * 2
1174                 );
1175         }
1176         if(this.beam_hitlight[0])
1177         {
1178                 adddynamiclight(
1179                         last_origin,
1180                         this.beam_hitlight[0],
1181                         vec3(
1182                                 this.beam_hitlight[1],
1183                                 this.beam_hitlight[2],
1184                                 this.beam_hitlight[3]
1185                         )
1186                 );
1187         }
1188         if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1189         {
1190                 pointparticles(
1191                         this.beam_muzzleeffect,
1192                         original_start_pos + wantdir * 20,
1193                         wantdir * 1000,
1194                         dt * 0.1
1195                 );
1196         }
1197         if(this.beam_muzzlelight[0])
1198         {
1199                 adddynamiclight(
1200                         original_start_pos + wantdir * 20,
1201                         this.beam_muzzlelight[0],
1202                         vec3(
1203                                 this.beam_muzzlelight[1],
1204                                 this.beam_muzzlelight[2],
1205                                 this.beam_muzzlelight[3]
1206                         )
1207                 );
1208         }
1209
1210         // cleanup
1211         Draw_ArcBeam_callback_entity = NULL;
1212         Draw_ArcBeam_callback_last_thickness = 0;
1213         Draw_ArcBeam_callback_last_top = '0 0 0';
1214         Draw_ArcBeam_callback_last_bottom = '0 0 0';
1215 }
1216
1217 void Remove_ArcBeam(entity this)
1218 {
1219         delete(this.beam_muzzleentity);
1220         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
1221 }
1222
1223 NET_HANDLE(ENT_CLIENT_ARC_BEAM, bool isnew)
1224 {
1225         int sf = ReadByte();
1226         int slot = ReadByte();
1227         entity flash;
1228
1229         this.beam_slot = slot;
1230
1231         if(isnew)
1232         {
1233                 int gunalign = W_GunAlign(viewmodels[slot], STAT(GUNALIGN)) - 1;
1234
1235                 this.beam_shotorigin = arc_shotorigin[gunalign]; // get a starting point
1236
1237                 // set other main attributes of the beam
1238                 this.draw = Draw_ArcBeam;
1239                 IL_PUSH(g_drawables, this);
1240                 this.entremove = Remove_ArcBeam;
1241                 this.move_time = time;
1242                 loopsound(this, CH_SHOTS_SINGLE, SND_ARC_LOOP, VOL_BASE, ATTEN_NORM);
1243
1244                 flash = new(arc_flash);
1245                 flash.owner = this;
1246                 flash.effects = EF_ADDITIVE | EF_FULLBRIGHT;
1247                 //flash.drawmask = MASK_NORMAL;
1248                 flash.solid = SOLID_NOT;
1249                 flash.avelocity_z = 5000;
1250                 setattachment(flash, this, "");
1251                 setorigin(flash, '0 0 0');
1252
1253                 this.beam_muzzleentity = flash;
1254         }
1255         else
1256         {
1257                 flash = this.beam_muzzleentity;
1258         }
1259
1260         if(sf & ARC_SF_SETTINGS) // settings information
1261         {
1262                 this.beam_degreespersegment = ReadShort();
1263                 this.beam_distancepersegment = ReadShort();
1264                 this.beam_maxangle = ReadShort();
1265                 this.beam_range = ReadCoord();
1266                 this.beam_returnspeed = ReadShort();
1267                 this.beam_tightness = (ReadByte() / 10);
1268
1269                 if(ReadByte())
1270                 {
1271                         this.beam_usevieworigin = (autocvar_chase_active) ? 1 : 2;
1272                 }
1273                 else
1274                 {
1275                         this.beam_usevieworigin = 0;
1276                 }
1277
1278                 this.sv_entnum = ReadByte();
1279         }
1280
1281         if(!this.beam_usevieworigin)
1282         {
1283                 // this.iflags = IFLAG_ORIGIN | IFLAG_ANGLES | IFLAG_V_ANGLE; // why doesn't this work?
1284                 this.iflags = IFLAG_ORIGIN;
1285
1286                 InterpolateOrigin_Undo(this);
1287         }
1288
1289         if(sf & ARC_SF_START) // starting location
1290         {
1291                 this.origin = ReadVector();
1292         }
1293         else if(this.beam_usevieworigin) // infer the location from player location
1294         {
1295                 if(this.beam_usevieworigin == 2)
1296                 {
1297                         // use view origin
1298                         this.origin = view_origin;
1299                 }
1300                 else
1301                 {
1302                         // use player origin so that third person display still works
1303                         this.origin = entcs_receiver(player_localnum).origin + ('0 0 1' * STAT(VIEWHEIGHT));
1304                 }
1305         }
1306
1307         setorigin(this, this.origin);
1308
1309         if(sf & ARC_SF_WANTDIR) // want/aim direction
1310         {
1311                 this.v_angle = ReadVector();
1312         }
1313
1314         if(sf & ARC_SF_BEAMDIR) // beam direction
1315         {
1316                 this.angles = ReadAngleVector();
1317         }
1318
1319         if(sf & ARC_SF_BEAMTYPE) // beam type
1320         {
1321                 this.beam_type = ReadByte();
1322
1323                 vector beamcolor = ((autocvar_cl_arcbeam_teamcolor) ? colormapPaletteColor(entcs_GetClientColors(this.sv_entnum - 1) & 0x0F, true) : '1 1 1');
1324                 switch(this.beam_type)
1325                 {
1326                         case ARC_BT_MISS:
1327                         {
1328                                 this.beam_color = beamcolor;
1329                                 this.beam_alpha = 0.5;
1330                                 this.beam_thickness = 8;
1331                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1332                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1333                                 this.beam_hitlight[0] = 0;
1334                                 this.beam_hitlight[1] = 1;
1335                                 this.beam_hitlight[2] = 1;
1336                                 this.beam_hitlight[3] = 1;
1337                                 this.beam_muzzleeffect = EFFECT_Null;
1338                                 this.beam_muzzlelight[0] = 0;
1339                                 this.beam_muzzlelight[1] = 1;
1340                                 this.beam_muzzlelight[2] = 1;
1341                                 this.beam_muzzlelight[3] = 1;
1342                                 this.beam_image = "particles/lgbeam";
1343                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1344                                 {
1345                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1346                                         flash.alpha = this.beam_alpha;
1347                                         flash.colormod = this.beam_color;
1348                                         flash.scale = 0.35;
1349                                 }
1350                                 break;
1351                         }
1352                         case ARC_BT_WALL: // grenadelauncher_muzzleflash healray_muzzleflash
1353                         {
1354                                 this.beam_color = beamcolor;
1355                                 this.beam_alpha = 0.5;
1356                                 this.beam_thickness = 8;
1357                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1358                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1359                                 this.beam_hitlight[0] = 0;
1360                                 this.beam_hitlight[1] = 1;
1361                                 this.beam_hitlight[2] = 1;
1362                                 this.beam_hitlight[3] = 1;
1363                                 this.beam_muzzleeffect = EFFECT_Null; // (EFFECT_GRENADE_MUZZLEFLASH);
1364                                 this.beam_muzzlelight[0] = 0;
1365                                 this.beam_muzzlelight[1] = 1;
1366                                 this.beam_muzzlelight[2] = 1;
1367                                 this.beam_muzzlelight[3] = 1;
1368                                 this.beam_image = "particles/lgbeam";
1369                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1370                                 {
1371                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1372                                         flash.alpha = this.beam_alpha;
1373                                         flash.colormod = this.beam_color;
1374                                         flash.scale = 0.35;
1375                                 }
1376                                 break;
1377                         }
1378                         case ARC_BT_HEAL:
1379                         {
1380                                 this.beam_color = beamcolor;
1381                                 this.beam_alpha = 0.5;
1382                                 this.beam_thickness = 8;
1383                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1384                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT);
1385                                 this.beam_hitlight[0] = 0;
1386                                 this.beam_hitlight[1] = 1;
1387                                 this.beam_hitlight[2] = 1;
1388                                 this.beam_hitlight[3] = 1;
1389                                 this.beam_muzzleeffect = EFFECT_Null;
1390                                 this.beam_muzzlelight[0] = 0;
1391                                 this.beam_muzzlelight[1] = 1;
1392                                 this.beam_muzzlelight[2] = 1;
1393                                 this.beam_muzzlelight[3] = 1;
1394                                 this.beam_image = "particles/lgbeam";
1395                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1396                                 {
1397                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1398                                         flash.alpha = this.beam_alpha;
1399                                         flash.colormod = this.beam_color;
1400                                         flash.scale = 0.35;
1401                                 }
1402                                 break;
1403                         }
1404                         case ARC_BT_HIT:
1405                         {
1406                                 this.beam_color = beamcolor;
1407                                 this.beam_alpha = 0.5;
1408                                 this.beam_thickness = 8;
1409                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1410                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1411                                 this.beam_hitlight[0] = 20;
1412                                 this.beam_hitlight[1] = 1;
1413                                 this.beam_hitlight[2] = 0;
1414                                 this.beam_hitlight[3] = 0;
1415                                 this.beam_muzzleeffect = EFFECT_Null;
1416                                 this.beam_muzzlelight[0] = 50;
1417                                 this.beam_muzzlelight[1] = 1;
1418                                 this.beam_muzzlelight[2] = 0;
1419                                 this.beam_muzzlelight[3] = 0;
1420                                 this.beam_image = "particles/lgbeam";
1421                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1422                                 {
1423                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1424                                         flash.alpha = this.beam_alpha;
1425                                         flash.colormod = this.beam_color;
1426                                         flash.scale = 0.35;
1427                                 }
1428                                 break;
1429                         }
1430                         case ARC_BT_BURST_MISS:
1431                         {
1432                                 this.beam_color = beamcolor;
1433                                 this.beam_alpha = 0.5;
1434                                 this.beam_thickness = 14;
1435                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1436                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1437                                 this.beam_hitlight[0] = 0;
1438                                 this.beam_hitlight[1] = 1;
1439                                 this.beam_hitlight[2] = 1;
1440                                 this.beam_hitlight[3] = 1;
1441                                 this.beam_muzzleeffect = EFFECT_Null;
1442                                 this.beam_muzzlelight[0] = 0;
1443                                 this.beam_muzzlelight[1] = 1;
1444                                 this.beam_muzzlelight[2] = 1;
1445                                 this.beam_muzzlelight[3] = 1;
1446                                 this.beam_image = "particles/lgbeam";
1447                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1448                                 {
1449                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1450                                         flash.alpha = this.beam_alpha;
1451                                         flash.colormod = this.beam_color;
1452                                         flash.scale = 0.35;
1453                                 }
1454                                 break;
1455                         }
1456                         case ARC_BT_BURST_WALL:
1457                         {
1458                                 this.beam_color = beamcolor;
1459                                 this.beam_alpha = 0.5;
1460                                 this.beam_thickness = 14;
1461                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1462                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1463                                 this.beam_hitlight[0] = 0;
1464                                 this.beam_hitlight[1] = 1;
1465                                 this.beam_hitlight[2] = 1;
1466                                 this.beam_hitlight[3] = 1;
1467                                 this.beam_muzzleeffect = EFFECT_Null;
1468                                 this.beam_muzzlelight[0] = 0;
1469                                 this.beam_muzzlelight[1] = 1;
1470                                 this.beam_muzzlelight[2] = 1;
1471                                 this.beam_muzzlelight[3] = 1;
1472                                 this.beam_image = "particles/lgbeam";
1473                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1474                                 {
1475                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1476                                         flash.alpha = this.beam_alpha;
1477                                         flash.colormod = this.beam_color;
1478                                         flash.scale = 0.35;
1479                                 }
1480                                 break;
1481                         }
1482                         case ARC_BT_BURST_HEAL:
1483                         {
1484                                 this.beam_color = beamcolor;
1485                                 this.beam_alpha = 0.5;
1486                                 this.beam_thickness = 14;
1487                                 this.beam_traileffect = (EFFECT_ARC_BEAM_HEAL);
1488                                 this.beam_hiteffect = (EFFECT_ARC_BEAM_HEAL_IMPACT2);
1489                                 this.beam_hitlight[0] = 0;
1490                                 this.beam_hitlight[1] = 1;
1491                                 this.beam_hitlight[2] = 1;
1492                                 this.beam_hitlight[3] = 1;
1493                                 this.beam_muzzleeffect = EFFECT_Null;
1494                                 this.beam_muzzlelight[0] = 0;
1495                                 this.beam_muzzlelight[1] = 1;
1496                                 this.beam_muzzlelight[2] = 1;
1497                                 this.beam_muzzlelight[3] = 1;
1498                                 this.beam_image = "particles/lgbeam";
1499                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1500                                 {
1501                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1502                                         flash.alpha = this.beam_alpha;
1503                                         flash.colormod = this.beam_color;
1504                                         flash.scale = 0.35;
1505                                 }
1506                                 break;
1507                         }
1508                         case ARC_BT_BURST_HIT:
1509                         {
1510                                 this.beam_color = beamcolor;
1511                                 this.beam_alpha = 0.5;
1512                                 this.beam_thickness = 14;
1513                                 this.beam_traileffect = (EFFECT_ARC_BEAM);
1514                                 this.beam_hiteffect = (EFFECT_ARC_LIGHTNING);
1515                                 this.beam_hitlight[0] = 0;
1516                                 this.beam_hitlight[1] = 1;
1517                                 this.beam_hitlight[2] = 1;
1518                                 this.beam_hitlight[3] = 1;
1519                                 this.beam_muzzleeffect = EFFECT_Null;
1520                                 this.beam_muzzlelight[0] = 0;
1521                                 this.beam_muzzlelight[1] = 1;
1522                                 this.beam_muzzlelight[2] = 1;
1523                                 this.beam_muzzlelight[3] = 1;
1524                                 this.beam_image = "particles/lgbeam";
1525                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1526                                 {
1527                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1528                                         flash.alpha = this.beam_alpha;
1529                                         flash.colormod = this.beam_color;
1530                                         flash.scale = 0.35;
1531                                 }
1532                                 break;
1533                         }
1534
1535                         // shouldn't be possible, but lets make it colorful if it does :D
1536                         default:
1537                         {
1538                                 this.beam_color = randomvec();
1539                                 this.beam_alpha = 1;
1540                                 this.beam_thickness = 8;
1541                                 this.beam_traileffect = NULL;
1542                                 this.beam_hiteffect = NULL;
1543                                 this.beam_hitlight[0] = 0;
1544                                 this.beam_hitlight[1] = 1;
1545                                 this.beam_hitlight[2] = 1;
1546                                 this.beam_hitlight[3] = 1;
1547                                 this.beam_muzzleeffect = EFFECT_Null;
1548                                 this.beam_muzzlelight[0] = 0;
1549                                 this.beam_muzzlelight[1] = 1;
1550                                 this.beam_muzzlelight[2] = 1;
1551                                 this.beam_muzzlelight[3] = 1;
1552                                 this.beam_image = "particles/lgbeam";
1553                                 if(this.beam_muzzleeffect && autocvar_r_drawviewmodel)
1554                                 {
1555                                         setmodel(flash, MDL_ARC_MUZZLEFLASH);
1556                                         flash.alpha = this.beam_alpha;
1557                                         flash.colormod = this.beam_color;
1558                                         flash.scale = 0.35;
1559                                 }
1560                                 break;
1561                         }
1562                 }
1563         }
1564
1565         if(!this.beam_usevieworigin)
1566         {
1567                 InterpolateOrigin_Note(this);
1568         }
1569         return true;
1570 }
1571
1572 #endif