qcsrc/common/weapons/weapon/blaster.qc

   1 #include "blaster.qh"
   2
   3 #ifdef SVQC
   4
   5 void W_Blaster_Touch(entity this, entity toucher)
   6 {
   7         PROJECTILE_TOUCH(this, toucher);
   8
   9         this.event_damage = func_null;
  10         bool isprimary = !(this.projectiledeathtype & HITTYPE_SECONDARY);
  11
  12         RadiusDamageForSource(
  13                 this,
  14                 (this.origin + (this.mins + this.maxs) * 0.5),
  15                 this.velocity,
  16                 this.realowner,
  17                 WEP_CVAR_BOTH(blaster, isprimary, damage),
  18                 WEP_CVAR_BOTH(blaster, isprimary, edgedamage),
  19                 WEP_CVAR_BOTH(blaster, isprimary, radius),
  20                 NULL,
  21                 NULL,
  22                 false,
  23                 WEP_CVAR_BOTH(blaster, isprimary, force),
  24                 WEP_CVAR_BOTH(blaster, isprimary, force_zscale),
  25                 this.projectiledeathtype,
  26                 this.weaponentity_fld,
  27                 toucher
  28         );
  29
  30         delete(this);
  31 }
  32
  33 void W_Blaster_Think(entity this)
  34 {
  35         set_movetype(this, MOVETYPE_FLY);
  36         setthink(this, SUB_Remove);
  37         bool isprimary = !(this.projectiledeathtype & HITTYPE_SECONDARY);
  38         this.nextthink = time + WEP_CVAR_BOTH(blaster, isprimary, lifetime);
  39         CSQCProjectile(this, true, PROJECTILE_BLASTER, true);
  40 }
  41
  42 void W_Blaster_Attack(
  43         entity actor,
  44         .entity weaponentity,
  45         float atk_deathtype)
  46 {
  47         bool isprimary = !(atk_deathtype & HITTYPE_SECONDARY);
  48         float atk_shotangle = WEP_CVAR_BOTH(blaster, isprimary, shotangle);
  49         float atk_damage = WEP_CVAR_BOTH(blaster, isprimary, damage);
  50         vector s_forward = v_forward * cos(atk_shotangle * DEG2RAD) + v_up * sin(atk_shotangle * DEG2RAD);
  51
  52         W_SetupShot_Dir(actor, weaponentity, s_forward, false, 3, SND_LASERGUN_FIRE, CH_WEAPON_B, atk_damage, atk_deathtype);
  53         W_MuzzleFlash(WEP_BLASTER, actor, weaponentity, w_shotorg, w_shotdir);
  54
  55         entity missile = new(blasterbolt);
  56         missile.owner = missile.realowner = actor;
  57         missile.bot_dodge = true;
  58         missile.bot_dodgerating = atk_damage;
  59         PROJECTILE_MAKETRIGGER(missile);
  60
  61         setorigin(missile, w_shotorg);
  62         setsize(missile, '0 0 0', '0 0 0');
  63
  64         float atk_speed = WEP_CVAR_BOTH(blaster, isprimary, speed);
  65         float atk_spread = WEP_CVAR_BOTH(blaster, isprimary, spread);
  66         W_SetupProjVelocity_Explicit(missile, w_shotdir, v_up, atk_speed, 0, 0, atk_spread, false);
  67
  68         missile.angles = vectoangles(missile.velocity);
  69
  70         //missile.glow_color = 250; // 244, 250
  71         //missile.glow_size = 120;
  72
  73         settouch(missile, W_Blaster_Touch);
  74         missile.flags = FL_PROJECTILE;
  75         IL_PUSH(g_projectiles, missile);
  76         IL_PUSH(g_bot_dodge, missile);
  77         missile.missile_flags = MIF_SPLASH;
  78         missile.projectiledeathtype = atk_deathtype;
  79         missile.weaponentity_fld = weaponentity;
  80         setthink(missile, W_Blaster_Think);
  81         missile.nextthink = time + WEP_CVAR_BOTH(blaster, isprimary, delay);
  82
  83         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
  84
  85         if (time >= missile.nextthink)
  86         {
  87                 getthink(missile)(missile);
  88         }
  89 }
  90
  91 METHOD(Blaster, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
  92 {
  93     if(WEP_CVAR(blaster, secondary))
  94     {
  95         if((random() * (WEP_CVAR_PRI(blaster, damage) + WEP_CVAR_SEC(blaster, damage))) > WEP_CVAR_PRI(blaster, damage))
  96             { PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, WEP_CVAR_SEC(blaster, speed), 0, WEP_CVAR_SEC(blaster, lifetime), false, true); }
  97         else
  98             { PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), false, true); }
  99     }
 100     else
 101         { PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, WEP_CVAR_PRI(blaster, speed), 0, WEP_CVAR_PRI(blaster, lifetime), false, true); }
 102 }
 103
 104 METHOD(Blaster, wr_think, void(Blaster thiswep, entity actor, .entity weaponentity, int fire))
 105 {
 106     if(fire & 1)
 107     {
 108         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(blaster, refire)))
 109         {
 110             W_Blaster_Attack(actor, weaponentity, WEP_BLASTER.m_id);
 111             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(blaster, animtime), w_ready);
 112         }
 113     }
 114     else if(fire & 2)
 115     {
 116         switch(WEP_CVAR(blaster, secondary))
 117         {
 118             case 0: // switch to last used weapon
 119             {
 120                 if(actor.(weaponentity).m_switchweapon == WEP_BLASTER) // don't do this if already switching
 121                     W_LastWeapon(actor, weaponentity);
 122                 break;
 123             }
 124
 125             case 1: // normal projectile secondary
 126             {
 127                 if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(blaster, refire)))
 128                 {
 129                     W_Blaster_Attack(actor, weaponentity, WEP_BLASTER.m_id | HITTYPE_SECONDARY);
 130                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(blaster, animtime), w_ready);
 131                 }
 132
 133                 break;
 134             }
 135         }
 136     }
 137 }
 138
 139 METHOD(Blaster, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 140 {
 141     return true; // infinite ammo
 142 }
 143
 144 METHOD(Blaster, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 145 {
 146     return true; // blaster has infinite ammo
 147 }
 148
 149 METHOD(Blaster, wr_suicidemessage, Notification(entity thiswep))
 150 {
 151     return WEAPON_BLASTER_SUICIDE;
 152 }
 153
 154 METHOD(Blaster, wr_killmessage, Notification(entity thiswep))
 155 {
 156     return WEAPON_BLASTER_MURDER;
 157 }
 158
 159 METHOD(OffhandBlaster, offhand_think, void(OffhandBlaster this, entity actor, bool key_pressed))
 160 {
 161         if (!key_pressed || (time < actor.jump_interval))
 162         {
 163                 return;
 164         }
 165         actor.jump_interval = time + WEP_CVAR_SEC(blaster, refire) * W_WeaponRateFactor(actor);
 166         .entity weaponentity = weaponentities[1];
 167         makevectors(actor.v_angle);
 168         W_Blaster_Attack(actor, weaponentity, WEP_BLASTER.m_id | HITTYPE_SECONDARY);
 169 }
 170
 171 #endif
 172 #ifdef CSQC
 173
 174 METHOD(Blaster, wr_impacteffect, void(entity thiswep, entity actor))
 175 {
 176     vector org2 = w_org + w_backoff * 2;
 177     pointparticles(EFFECT_BLASTER_IMPACT, org2, w_backoff * 1000, 1);
 178     if(!w_issilent) { sound(actor, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 179 }
 180
 181 #endif