qcsrc/common/weapons/weapon/devastator.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Devastator, Weapon)
   3 /* ammotype  */ ATTRIB(Devastator, ammo_field, .int, ammo_rockets)
   4 /* impulse   */ ATTRIB(Devastator, impulse, int, 9)
   5 /* flags     */ ATTRIB(Devastator, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
   6 /* rating    */ ATTRIB(Devastator, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(Devastator, wpcolor, vector, '1 1 0');
   8 /* modelname */ ATTRIB(Devastator, mdl, string, "rl");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Devastator, m_model, Model, MDL_DEVASTATOR_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Devastator, w_crosshair, string, "gfx/crosshairrocketlauncher");
  13 /* crosshair */ ATTRIB(Devastator, w_crosshair_size, float, 0.7);
  14 /* wepimg    */ ATTRIB(Devastator, model2, string, "weaponrocketlauncher");
  15 /* refname   */ ATTRIB(Devastator, netname, string, "devastator");
  16 /* wepname   */ ATTRIB(Devastator, m_name, string, _("Devastator"));
  17 ENDCLASS(Devastator)
  18 REGISTER_WEAPON(DEVASTATOR, NEW(Devastator));
  19
  20 #define DEVASTATOR_SETTINGS(w_cvar,w_prop) DEVASTATOR_SETTINGS_LIST(w_cvar, w_prop, DEVASTATOR, devastator)
  21 #define DEVASTATOR_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  22         w_cvar(id, sn, NONE, ammo) \
  23         w_cvar(id, sn, NONE, animtime) \
  24         w_cvar(id, sn, NONE, damage) \
  25         w_cvar(id, sn, NONE, damageforcescale) \
  26         w_cvar(id, sn, NONE, detonatedelay) \
  27         w_cvar(id, sn, NONE, edgedamage) \
  28         w_cvar(id, sn, NONE, force) \
  29         w_cvar(id, sn, NONE, guidedelay) \
  30         w_cvar(id, sn, NONE, guidegoal) \
  31         w_cvar(id, sn, NONE, guiderate) \
  32         w_cvar(id, sn, NONE, guideratedelay) \
  33         w_cvar(id, sn, NONE, guidestop) \
  34         w_cvar(id, sn, NONE, health) \
  35         w_cvar(id, sn, NONE, lifetime) \
  36         w_cvar(id, sn, NONE, radius) \
  37         w_cvar(id, sn, NONE, refire) \
  38         w_cvar(id, sn, NONE, remote_damage) \
  39         w_cvar(id, sn, NONE, remote_edgedamage) \
  40         w_cvar(id, sn, NONE, remote_force) \
  41         w_cvar(id, sn, NONE, remote_jump_damage) \
  42         w_cvar(id, sn, NONE, remote_jump_radius) \
  43         w_cvar(id, sn, NONE, remote_jump_velocity_z_add) \
  44         w_cvar(id, sn, NONE, remote_jump_velocity_z_max) \
  45         w_cvar(id, sn, NONE, remote_jump_velocity_z_min) \
  46         w_cvar(id, sn, NONE, remote_radius) \
  47         w_cvar(id, sn, NONE, speed) \
  48         w_cvar(id, sn, NONE, speedaccel) \
  49         w_cvar(id, sn, NONE, speedstart) \
  50         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  51         w_prop(id, sn, float,  reloading_time, reload_time) \
  52         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  53         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  54         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  55         w_prop(id, sn, float,  weaponstart, weaponstart) \
  56         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  57         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  58
  59 #ifdef SVQC
  60 DEVASTATOR_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  61 .float rl_release;
  62 .float rl_detonate_later;
  63 #endif
  64 #endif
  65 #ifdef IMPLEMENTATION
  66 #ifdef SVQC
  67 spawnfunc(weapon_devastator) { weapon_defaultspawnfunc(this, WEP_DEVASTATOR); }
  68 spawnfunc(weapon_rocketlauncher) { spawnfunc_weapon_devastator(this); }
  69
  70 .entity lastrocket;
  71
  72 void W_Devastator_Unregister()
  73 {SELFPARAM();
  74         if(self.realowner && self.realowner.lastrocket == self)
  75         {
  76                 self.realowner.lastrocket = world;
  77                 // self.realowner.rl_release = 1;
  78         }
  79 }
  80
  81 void W_Devastator_Explode()
  82 {SELFPARAM();
  83         W_Devastator_Unregister();
  84
  85         if(other.takedamage == DAMAGE_AIM)
  86                 if(IS_PLAYER(other))
  87                         if(DIFF_TEAM(self.realowner, other))
  88                                 if(other.deadflag == DEAD_NO)
  89                                         if(IsFlying(other))
  90                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_AIRSHOT);
  91
  92         self.event_damage = func_null;
  93         self.takedamage = DAMAGE_NO;
  94
  95         RadiusDamage(
  96                 self,
  97                 self.realowner,
  98                 WEP_CVAR(devastator, damage),
  99                 WEP_CVAR(devastator, edgedamage),
 100                 WEP_CVAR(devastator, radius),
 101                 world,
 102                 world,
 103                 WEP_CVAR(devastator, force),
 104                 self.projectiledeathtype,
 105                 other
 106         );
 107
 108         if(self.realowner.weapon == WEP_DEVASTATOR.m_id)
 109         {
 110                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 111                 if(!(self.realowner.items & IT_UNLIMITED_WEAPON_AMMO))
 112                 {
 113                         self.realowner.cnt = WEP_DEVASTATOR.m_id;
 114                         int slot = 0; // TODO: unhardcode
 115                         ATTACK_FINISHED(self.realowner, slot) = time;
 116                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 117                 }
 118         }
 119         remove(self);
 120 }
 121
 122 void W_Devastator_DoRemoteExplode(.entity weaponentity)
 123 {SELFPARAM();
 124         W_Devastator_Unregister();
 125
 126         self.event_damage = func_null;
 127         self.takedamage = DAMAGE_NO;
 128
 129         float handled_as_rocketjump = false;
 130
 131         entity head = WarpZone_FindRadius(
 132                 self.origin,
 133                 WEP_CVAR(devastator, remote_jump_radius),
 134                 false
 135         );
 136
 137         while(head)
 138         {
 139                 if(head.takedamage && (head == self.realowner))
 140                 {
 141                         float distance_to_head = vlen(self.origin - head.WarpZone_findradius_nearest);
 142                         if(distance_to_head <= WEP_CVAR(devastator, remote_jump_radius))
 143                         {
 144                                 // we handled this as a rocketjump :)
 145                                 handled_as_rocketjump = true;
 146
 147                                 // modify velocity
 148                                 head.velocity_x *= 0.9;
 149                                 head.velocity_y *= 0.9;
 150                                 head.velocity_z = bound(
 151                                         WEP_CVAR(devastator, remote_jump_velocity_z_min),
 152                                         head.velocity.z + WEP_CVAR(devastator, remote_jump_velocity_z_add),
 153                                         WEP_CVAR(devastator, remote_jump_velocity_z_max)
 154                                 );
 155
 156                                 // now do the damage
 157                                 RadiusDamage(
 158                                         self,
 159                                         head,
 160                                         WEP_CVAR(devastator, remote_jump_damage),
 161                                         WEP_CVAR(devastator, remote_jump_damage),
 162                                         WEP_CVAR(devastator, remote_jump_radius),
 163                                         world,
 164                                         head,
 165                                         0,
 166                                         self.projectiledeathtype | HITTYPE_BOUNCE,
 167                                         world
 168                                 );
 169                                 break;
 170                         }
 171                 }
 172                 head = head.chain;
 173         }
 174
 175         RadiusDamage(
 176                 self,
 177                 self.realowner,
 178                 WEP_CVAR(devastator, remote_damage),
 179                 WEP_CVAR(devastator, remote_edgedamage),
 180                 WEP_CVAR(devastator, remote_radius),
 181                 (handled_as_rocketjump ? head : world),
 182                 world,
 183                 WEP_CVAR(devastator, remote_force),
 184                 self.projectiledeathtype | HITTYPE_BOUNCE,
 185                 world
 186         );
 187
 188         if(self.realowner.weapon == WEP_DEVASTATOR.m_id)
 189         {
 190                 if(self.realowner.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 191                 if(!(self.realowner.items & IT_UNLIMITED_WEAPON_AMMO))
 192                 {
 193                         self.realowner.cnt = WEP_DEVASTATOR.m_id;
 194                         int slot = weaponslot(weaponentity);
 195                         ATTACK_FINISHED(self.realowner, slot) = time;
 196                         self.realowner.switchweapon = w_getbestweapon(self.realowner);
 197                 }
 198         }
 199         remove(self);
 200 }
 201
 202 void W_Devastator_RemoteExplode(.entity weaponentity)
 203 {SELFPARAM();
 204         if(self.realowner.deadflag == DEAD_NO)
 205         if(self.realowner.lastrocket)
 206         {
 207                 if((self.spawnshieldtime >= 0)
 208                         ? (time >= self.spawnshieldtime) // timer
 209                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > WEP_CVAR(devastator, remote_radius)) // safety device
 210                 )
 211                 {
 212                         W_Devastator_DoRemoteExplode(weaponentity);
 213                 }
 214         }
 215 }
 216
 217 vector W_Devastator_SteerTo(vector thisdir, vector goaldir, float maxturn_cos)
 218 {
 219         if(thisdir * goaldir > maxturn_cos)
 220                 return goaldir;
 221         if(thisdir * goaldir < -0.9998) // less than 1 degree and opposite
 222                 return thisdir; // refuse to guide (better than letting a numerical error happen)
 223         float f, m2;
 224         vector v;
 225         // solve:
 226         //   g = normalize(thisdir + goaldir * X)
 227         //   thisdir * g = maxturn
 228         //
 229         //   gg = thisdir + goaldir * X
 230         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 231         //
 232         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 233         f = thisdir * goaldir;
 234         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 235         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 236         m2 = maxturn_cos * maxturn_cos;
 237         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 238         return normalize(thisdir + goaldir * v.y); // the larger solution!
 239 }
 240 // assume thisdir == -goaldir:
 241 //   f == -1
 242 //   v = solve_qadratic(m2 - 1, -2 * (m2 - 1), m2 - 1)
 243 //   (m2 - 1) x^2 - 2 * (m2 - 1) * x + (m2 - 1) = 0
 244 //   x^2 - 2 * x + 1 = 0
 245 //   (x - 1)^2 = 0
 246 //   x = 1
 247 //   normalize(thisdir + goaldir)
 248 //   normalize(0)
 249
 250 void W_Devastator_Think()
 251 {SELFPARAM();
 252         vector desireddir, olddir, newdir, desiredorigin, goal;
 253         float velspeed, f;
 254         self.nextthink = time;
 255         if(time > self.cnt)
 256         {
 257                 other = world;
 258                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 259                 W_Devastator_Explode();
 260                 return;
 261         }
 262
 263         // accelerate
 264         makevectors(self.angles.x * '-1 0 0' + self.angles.y * '0 1 0');
 265         velspeed = WEP_CVAR(devastator, speed) * W_WeaponSpeedFactor() - (self.velocity * v_forward);
 266         if(velspeed > 0)
 267                 self.velocity = self.velocity + v_forward * min(WEP_CVAR(devastator, speedaccel) * W_WeaponSpeedFactor() * frametime, velspeed);
 268
 269         // laser guided, or remote detonation
 270         if(self.realowner.weapon == WEP_DEVASTATOR.m_id)
 271         {
 272                 if(self == self.realowner.lastrocket)
 273                 if(!self.realowner.rl_release)
 274                 if(!self.BUTTON_ATCK2)
 275                 if(WEP_CVAR(devastator, guiderate))
 276                 if(time > self.pushltime)
 277                 if(self.realowner.deadflag == DEAD_NO)
 278                 {
 279                         f = WEP_CVAR(devastator, guideratedelay);
 280                         if(f)
 281                                 f = bound(0, (time - self.pushltime) / f, 1);
 282                         else
 283                                 f = 1;
 284
 285                         velspeed = vlen(self.velocity);
 286
 287                         makevectors(self.realowner.v_angle);
 288                         desireddir = WarpZone_RefSys_TransformVelocity(self.realowner, self, v_forward);
 289                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.realowner, self, self.realowner.origin + self.realowner.view_ofs);
 290                         olddir = normalize(self.velocity);
 291
 292                         // now it gets tricky... we want to move like some curve to approximate the target direction
 293                         // but we are limiting the rate at which we can turn!
 294                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + WEP_CVAR(devastator, guidegoal)) * desireddir;
 295                         newdir = W_Devastator_SteerTo(olddir, normalize(goal - self.origin), cos(WEP_CVAR(devastator, guiderate) * f * frametime * DEG2RAD));
 296
 297                         self.velocity = newdir * velspeed;
 298                         self.angles = vectoangles(self.velocity);
 299
 300                         if(!self.count)
 301                         {
 302                                 Send_Effect(EFFECT_ROCKET_GUIDE, self.origin, self.velocity, 1);
 303                                 // TODO add a better sound here
 304                                 sound(self.realowner, CH_WEAPON_B, SND_ROCKET_MODE, VOL_BASE, ATTN_NORM);
 305                                 self.count = 1;
 306                         }
 307                 }
 308
 309                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 310                 if(self.rl_detonate_later)
 311                         W_Devastator_RemoteExplode(weaponentity);
 312         }
 313
 314         if(self.csqcprojectile_clientanimate == 0)
 315                 UpdateCSQCProjectile(self);
 316 }
 317
 318 void W_Devastator_Touch()
 319 {SELFPARAM();
 320         if(WarpZone_Projectile_Touch())
 321         {
 322                 if(wasfreed(self))
 323                         W_Devastator_Unregister();
 324                 return;
 325         }
 326         W_Devastator_Unregister();
 327         W_Devastator_Explode();
 328 }
 329
 330 void W_Devastator_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 331 {SELFPARAM();
 332         if(self.health <= 0)
 333                 return;
 334
 335         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 336                 return; // g_projectiles_damage says to halt
 337
 338         self.health = self.health - damage;
 339         self.angles = vectoangles(self.velocity);
 340
 341         if(self.health <= 0)
 342                 W_PrepareExplosionByDamage(attacker, W_Devastator_Explode);
 343 }
 344
 345 void W_Devastator_Attack(Weapon thiswep)
 346 {SELFPARAM();
 347         entity missile;
 348         entity flash;
 349
 350         W_DecreaseAmmo(thiswep, self, WEP_CVAR(devastator, ammo));
 351
 352         W_SetupShot_ProjectileSize(self, '-3 -3 -3', '3 3 3', false, 5, SND(ROCKET_FIRE), CH_WEAPON_A, WEP_CVAR(devastator, damage));
 353         Send_Effect(EFFECT_ROCKET_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 354
 355         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 356         missile.owner = missile.realowner = self;
 357         self.lastrocket = missile;
 358         if(WEP_CVAR(devastator, detonatedelay) >= 0)
 359                 missile.spawnshieldtime = time + WEP_CVAR(devastator, detonatedelay);
 360         else
 361                 missile.spawnshieldtime = -1;
 362         missile.pushltime = time + WEP_CVAR(devastator, guidedelay);
 363         missile.classname = "rocket";
 364         missile.bot_dodge = true;
 365         missile.bot_dodgerating = WEP_CVAR(devastator, damage) * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 366
 367         missile.takedamage = DAMAGE_YES;
 368         missile.damageforcescale = WEP_CVAR(devastator, damageforcescale);
 369         missile.health = WEP_CVAR(devastator, health);
 370         missile.event_damage = W_Devastator_Damage;
 371         missile.damagedbycontents = true;
 372
 373         missile.movetype = MOVETYPE_FLY;
 374         PROJECTILE_MAKETRIGGER(missile);
 375         missile.projectiledeathtype = WEP_DEVASTATOR.m_id;
 376         setsize(missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 377
 378         setorigin(missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 379         W_SetupProjVelocity_Basic(missile, WEP_CVAR(devastator, speedstart), 0);
 380         missile.angles = vectoangles(missile.velocity);
 381
 382         missile.touch = W_Devastator_Touch;
 383         missile.think = W_Devastator_Think;
 384         missile.nextthink = time;
 385         missile.cnt = time + WEP_CVAR(devastator, lifetime);
 386         missile.flags = FL_PROJECTILE;
 387         missile.missile_flags = MIF_SPLASH;
 388
 389         CSQCProjectile(missile, WEP_CVAR(devastator, guiderate) == 0 && WEP_CVAR(devastator, speedaccel) == 0, PROJECTILE_ROCKET, false); // because of fly sound
 390
 391         // muzzle flash for 1st person view
 392         flash = spawn();
 393         setmodel(flash, MDL_DEVASTATOR_MUZZLEFLASH); // precision set below
 394         SUB_SetFade(flash, time, 0.1);
 395         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 396         W_AttachToShotorg(self, flash, '5 0 0');
 397
 398         // common properties
 399         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 400 }
 401
 402                 #if 0
 403                 METHOD(Devastator, wr_aim, void(entity thiswep))
 404                 {
 405                         // aim and decide to fire if appropriate
 406                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), false);
 407                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 408                         {
 409                                 // decide whether to detonate rockets
 410                                 entity missile, targetlist, targ;
 411                                 targetlist = findchainfloat(bot_attack, true);
 412                                 for(missile = world; (missile = find(missile, classname, "rocket")); ) if(missile.realowner == self)
 413                                 {
 414                                         targ = targetlist;
 415                                         while(targ)
 416                                         {
 417                                                 if(targ != missile.realowner && vlen(targ.origin - missile.origin) < WEP_CVAR(devastator, radius))
 418                                                 {
 419                                                         self.BUTTON_ATCK2 = true;
 420                                                         break;
 421                                                 }
 422                                                 targ = targ.chain;
 423                                         }
 424                                 }
 425
 426                                 if(self.BUTTON_ATCK2) self.BUTTON_ATCK = false;
 427                         }
 428                 }
 429                 #else
 430                 METHOD(Devastator, wr_aim, void(entity thiswep))
 431                 {
 432                         // aim and decide to fire if appropriate
 433                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(devastator, speed), 0, WEP_CVAR(devastator, lifetime), false);
 434                         if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 435                         {
 436                                 // decide whether to detonate rockets
 437                                 entity missile, targetlist, targ;
 438                                 float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 439                                 float selfdamage, teamdamage, enemydamage;
 440                                 edgedamage = WEP_CVAR(devastator, edgedamage);
 441                                 coredamage = WEP_CVAR(devastator, damage);
 442                                 edgeradius = WEP_CVAR(devastator, radius);
 443                                 recipricoledgeradius = 1 / edgeradius;
 444                                 selfdamage = 0;
 445                                 teamdamage = 0;
 446                                 enemydamage = 0;
 447                                 targetlist = findchainfloat(bot_attack, true);
 448                                 missile = find(world, classname, "rocket");
 449                                 while(missile)
 450                                 {
 451                                         if(missile.realowner != self)
 452                                         {
 453                                                 missile = find(missile, classname, "rocket");
 454                                                 continue;
 455                                         }
 456                                         targ = targetlist;
 457                                         while(targ)
 458                                         {
 459                                                 d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 460                                                 d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 461                                                 // count potential damage according to type of target
 462                                                 if(targ == self)
 463                                                         selfdamage = selfdamage + d;
 464                                                 else if(targ.team == self.team && teamplay)
 465                                                         teamdamage = teamdamage + d;
 466                                                 else if(bot_shouldattack(targ))
 467                                                         enemydamage = enemydamage + d;
 468                                                 targ = targ.chain;
 469                                         }
 470                                         missile = find(missile, classname, "rocket");
 471                                 }
 472                                 float desirabledamage;
 473                                 desirabledamage = enemydamage;
 474                                 if(time > self.invincible_finished && time > self.spawnshieldtime)
 475                                         desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 476                                 if(teamplay && self.team)
 477                                         desirabledamage = desirabledamage - teamdamage;
 478
 479                                 missile = find(world, classname, "rocket");
 480                                 while(missile)
 481                                 {
 482                                         if(missile.realowner != self)
 483                                         {
 484                                                 missile = find(missile, classname, "rocket");
 485                                                 continue;
 486                                         }
 487                                         makevectors(missile.v_angle);
 488                                         targ = targetlist;
 489                                         if(skill > 9) // normal players only do this for the target they are tracking
 490                                         {
 491                                                 targ = targetlist;
 492                                                 while(targ)
 493                                                 {
 494                                                         if(
 495                                                                 (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 496                                                                 && desirabledamage > 0.1*coredamage
 497                                                         )self.BUTTON_ATCK2 = true;
 498                                                         targ = targ.chain;
 499                                                 }
 500                                         }else{
 501                                                 float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 502                                                 //As the distance gets larger, a correct detonation gets near imposible
 503                                                 //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 504                                                 if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 505                                                         if(IS_PLAYER(self.enemy))
 506                                                                 if(desirabledamage >= 0.1*coredamage)
 507                                                                         if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 508                                                                                 self.BUTTON_ATCK2 = true;
 509                                         //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 510                                         }
 511
 512                                         missile = find(missile, classname, "rocket");
 513                                 }
 514                                 // if we would be doing at X percent of the core damage, detonate it
 515                                 // but don't fire a new shot at the same time!
 516                                 if(desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 517                                         self.BUTTON_ATCK2 = true;
 518                                 if((skill > 6.5) && (selfdamage > self.health))
 519                                         self.BUTTON_ATCK2 = false;
 520                                 //if(self.BUTTON_ATCK2 == true)
 521                                 //      dprint(ftos(desirabledamage),"\n");
 522                                 if(self.BUTTON_ATCK2 == true) self.BUTTON_ATCK = false;
 523                         }
 524                 }
 525                 #endif
 526                 METHOD(Devastator, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 527                 {
 528                         if(WEP_CVAR(devastator, reload_ammo) && actor.clip_load < WEP_CVAR(devastator, ammo)) { // forced reload
 529                                 Weapon w = get_weaponinfo(actor.weapon);
 530                                 w.wr_reload(w);
 531                         } else {
 532                                 if(fire & 1)
 533                                 {
 534                                         if(actor.rl_release || WEP_CVAR(devastator, guidestop))
 535                                         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(devastator, refire)))
 536                                         {
 537                                                 W_Devastator_Attack(thiswep);
 538                                                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(devastator, animtime), w_ready);
 539                                                 actor.rl_release = 0;
 540                                         }
 541                                 }
 542                                 else
 543                                         actor.rl_release = 1;
 544
 545                                 if(fire & 2)
 546                                 if(actor.switchweapon == WEP_DEVASTATOR.m_id)
 547                                 {
 548                                         entity rock;
 549                                         bool rockfound = false;
 550                                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.realowner == actor)
 551                                         {
 552                                                 if(!rock.rl_detonate_later)
 553                                                 {
 554                                                         rock.rl_detonate_later = true;
 555                                                         rockfound = true;
 556                                                 }
 557                                         }
 558                                         if(rockfound)
 559                                                 sound(actor, CH_WEAPON_B, SND_ROCKET_DET, VOL_BASE, ATTN_NORM);
 560                                 }
 561                         }
 562                 }
 563                 METHOD(Devastator, wr_init, void(entity thiswep))
 564                 {
 565                         DEVASTATOR_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 566                 }
 567                 METHOD(Devastator, wr_setup, void(entity thiswep))
 568                 {
 569                         self.rl_release = 1;
 570                 }
 571                 METHOD(Devastator, wr_checkammo1, bool(entity thiswep))
 572                 {
 573                         #if 0
 574                         // don't switch while guiding a missile
 575                         if(ATTACK_FINISHED(self, slot) <= time || self.weapon != WEP_DEVASTATOR.m_id)
 576                         {
 577                                 ammo_amount = false;
 578                                 if(WEP_CVAR(devastator, reload_ammo))
 579                                 {
 580                                         if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo) && self.(weapon_load[WEP_DEVASTATOR.m_id]) < WEP_CVAR(devastator, ammo))
 581                                                 ammo_amount = true;
 582                                 }
 583                                 else if(self.WEP_AMMO(DEVASTATOR) < WEP_CVAR(devastator, ammo))
 584                                         ammo_amount = true;
 585                                 return !ammo_amount;
 586                         }
 587                         #endif
 588                         #if 0
 589                         if(self.rl_release == 0)
 590                         {
 591                                 LOG_INFOF("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: TRUE\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo));
 592                                 return true;
 593                         }
 594                         else
 595                         {
 596                                 ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 597                                 ammo_amount += self.(weapon_load[WEP_DEVASTATOR.m_id]) >= WEP_CVAR(devastator, ammo);
 598                                 LOG_INFOF("W_Devastator(WR_CHECKAMMO1): %d, %.2f, %d: %s\n", self.rl_release, self.WEP_AMMO(DEVASTATOR), WEP_CVAR(devastator, ammo), (ammo_amount ? "TRUE" : "FALSE"));
 599                                 return ammo_amount;
 600                         }
 601                         #else
 602                         float ammo_amount = self.WEP_AMMO(DEVASTATOR) >= WEP_CVAR(devastator, ammo);
 603                         ammo_amount += self.(weapon_load[WEP_DEVASTATOR.m_id]) >= WEP_CVAR(devastator, ammo);
 604                         return ammo_amount;
 605                         #endif
 606                 }
 607                 METHOD(Devastator, wr_checkammo2, bool(entity thiswep))
 608                 {
 609                         return false;
 610                 }
 611                 METHOD(Devastator, wr_config, void(entity thiswep))
 612                 {
 613                         DEVASTATOR_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 614                 }
 615                 METHOD(Devastator, wr_resetplayer, void(entity thiswep))
 616                 {
 617                         self.lastrocket = NULL; // stop rocket guiding, no revenge from the grave!
 618                         self.rl_release = 0;
 619                 }
 620                 METHOD(Devastator, wr_reload, void(entity thiswep))
 621                 {
 622                         W_Reload(self, WEP_CVAR(devastator, ammo), SND(RELOAD));
 623                 }
 624                 METHOD(Devastator, wr_suicidemessage, int(entity thiswep))
 625                 {
 626                         return WEAPON_DEVASTATOR_SUICIDE;
 627                 }
 628                 METHOD(Devastator, wr_killmessage, int(entity thiswep))
 629                 {
 630                         if((w_deathtype & HITTYPE_BOUNCE) || (w_deathtype & HITTYPE_SPLASH))
 631                                 return WEAPON_DEVASTATOR_MURDER_SPLASH;
 632                         else
 633                                 return WEAPON_DEVASTATOR_MURDER_DIRECT;
 634                 }
 635
 636 #endif
 637 #ifdef CSQC
 638
 639                 METHOD(Devastator, wr_impacteffect, void(entity thiswep))
 640                 {
 641                         vector org2;
 642                         org2 = w_org + w_backoff * 12;
 643                         pointparticles(EFFECT_ROCKET_EXPLODE, org2, '0 0 0', 1);
 644                         if(!w_issilent)
 645                                 sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTN_NORM);
 646                 }
 647
 648 #endif
 649 #endif