qcsrc/common/weapons/weapon/electro.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Electro, Weapon)
   3 /* ammotype  */ ATTRIB(Electro, ammo_field, .int, ammo_cells)
   4 /* impulse   */ ATTRIB(Electro, impulse, int, 5)
   5 /* flags     */ ATTRIB(Electro, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
   6 /* rating    */ ATTRIB(Electro, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
   7 /* color     */ ATTRIB(Electro, wpcolor, vector, '0 0.5 1');
   8 /* modelname */ ATTRIB(Electro, mdl, string, "electro");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Electro, m_model, Model, MDL_ELECTRO_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Electro, w_crosshair, string, "gfx/crosshairelectro");
  13 /* crosshair */ ATTRIB(Electro, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(Electro, model2, string, "weaponelectro");
  15 /* refname   */ ATTRIB(Electro, netname, string, "electro");
  16 /* wepname   */ ATTRIB(Electro, m_name, string, _("Electro"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20                 P(class, prefix, ammo, float, BOTH) \
  21                 P(class, prefix, animtime, float, BOTH) \
  22                 P(class, prefix, bouncefactor, float, SEC) \
  23                 P(class, prefix, bouncestop, float, SEC) \
  24                 P(class, prefix, comboradius, float, PRI) \
  25                 P(class, prefix, combo_comboradius, float, NONE) \
  26                 P(class, prefix, combo_comboradius_thruwall, float, NONE) \
  27                 P(class, prefix, combo_damage, float, NONE) \
  28                 P(class, prefix, combo_edgedamage, float, NONE) \
  29                 P(class, prefix, combo_force, float, NONE) \
  30                 P(class, prefix, combo_radius, float, NONE) \
  31                 P(class, prefix, combo_safeammocheck, float, NONE) \
  32                 P(class, prefix, combo_speed, float, NONE) \
  33                 P(class, prefix, count, float, SEC) \
  34                 P(class, prefix, damagedbycontents, float, SEC) \
  35                 P(class, prefix, damageforcescale, float, SEC) \
  36                 P(class, prefix, damage, float, BOTH) \
  37                 P(class, prefix, edgedamage, float, BOTH) \
  38                 P(class, prefix, force, float, BOTH) \
  39                 P(class, prefix, health, float, SEC) \
  40                 P(class, prefix, lifetime, float, BOTH) \
  41                 P(class, prefix, midaircombo_explode, float, PRI) \
  42                 P(class, prefix, midaircombo_interval, float, PRI) \
  43                 P(class, prefix, midaircombo_radius, float, PRI) \
  44                 P(class, prefix, radius, float, BOTH) \
  45                 P(class, prefix, refire2, float, SEC) \
  46                 P(class, prefix, refire, float, BOTH) \
  47                 P(class, prefix, reload_ammo, float, NONE) \
  48                 P(class, prefix, reload_time, float, NONE) \
  49                 P(class, prefix, speed, float, BOTH) \
  50                 P(class, prefix, speed_up, float, SEC) \
  51                 P(class, prefix, speed_z, float, SEC) \
  52                 P(class, prefix, spread, float, BOTH) \
  53                 P(class, prefix, stick, float, SEC) \
  54                 P(class, prefix, switchdelay_drop, float, NONE) \
  55                 P(class, prefix, switchdelay_raise, float, NONE) \
  56                 P(class, prefix, touchexplode, float, SEC) \
  57                 P(class, prefix, weaponreplace, string,NONE) \
  58                 P(class, prefix, weaponstartoverride, float, NONE) \
  59                 P(class, prefix, weaponstart, float, NONE) \
  60                 P(class, prefix, weaponthrowable, float, NONE) \
  61         END()
  62         W_PROPS(X, Electro, electro)
  63 #undef X
  64
  65 ENDCLASS(Electro)
  66 REGISTER_WEAPON(ELECTRO, electro, NEW(Electro));
  67
  68
  69 #ifdef SVQC
  70 .float electro_count;
  71 .float electro_secondarytime;
  72 void W_Electro_ExplodeCombo(entity this);
  73 #endif
  74 #endif
  75 #ifdef IMPLEMENTATION
  76 #ifdef SVQC
  77 spawnfunc(weapon_electro) { weapon_defaultspawnfunc(this, WEP_ELECTRO); }
  78
  79 void W_Electro_TriggerCombo(vector org, float rad, entity own)
  80 {
  81         entity e = WarpZone_FindRadius(org, rad, !WEP_CVAR(electro, combo_comboradius_thruwall));
  82         while(e)
  83         {
  84                 if(e.classname == "electro_orb")
  85                 {
  86                         // do we allow thruwall triggering?
  87                         if(WEP_CVAR(electro, combo_comboradius_thruwall))
  88                         {
  89                                 // if distance is greater than thruwall distance, check to make sure it's not through a wall
  90                                 if(vdist(e.WarpZone_findradius_dist, >, WEP_CVAR(electro, combo_comboradius_thruwall)))
  91                                 {
  92                                         WarpZone_TraceLine(org, e.origin, MOVE_NOMONSTERS, e);
  93                                         if(trace_fraction != 1)
  94                                         {
  95                                                 // trigger is through a wall and outside of thruwall range, abort
  96                                                 e = e.chain;
  97                                                 continue;
  98                                         }
  99                                 }
 100                         }
 101
 102                         // change owner to whoever caused the combo explosion
 103                         e.realowner = own;
 104                         e.takedamage = DAMAGE_NO;
 105                         e.classname = "electro_orb_chain";
 106
 107                         // now set the next one to trigger as well
 108                         setthink(e, W_Electro_ExplodeCombo);
 109
 110                         // delay combo chains, looks cooler
 111                         e.nextthink =
 112                                 (
 113                                         time
 114                                         +
 115                                         (WEP_CVAR(electro, combo_speed) ?
 116                                                 (vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed))
 117                                                 :
 118                                                 0
 119                                         )
 120                                 );
 121                 }
 122                 e = e.chain;
 123         }
 124 }
 125
 126 void W_Electro_ExplodeCombo(entity this)
 127 {
 128         W_Electro_TriggerCombo(this.origin, WEP_CVAR(electro, combo_comboradius), this.realowner);
 129
 130         this.event_damage = func_null;
 131
 132         RadiusDamage(
 133                 this,
 134                 this.realowner,
 135                 WEP_CVAR(electro, combo_damage),
 136                 WEP_CVAR(electro, combo_edgedamage),
 137                 WEP_CVAR(electro, combo_radius),
 138                 NULL,
 139                 NULL,
 140                 WEP_CVAR(electro, combo_force),
 141                 WEP_ELECTRO.m_id | HITTYPE_BOUNCE, // use THIS type for a combo because primary can't bounce
 142                 NULL
 143         );
 144
 145         remove(this);
 146 }
 147
 148 void W_Electro_Explode(entity this, entity directhitentity)
 149 {
 150         if(directhitentity.takedamage == DAMAGE_AIM)
 151                 if(IS_PLAYER(directhitentity))
 152                         if(DIFF_TEAM(this.realowner, directhitentity))
 153                                 if(!IS_DEAD(directhitentity))
 154                                         if(IsFlying(directhitentity))
 155                                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
 156
 157         this.event_damage = func_null;
 158         this.takedamage = DAMAGE_NO;
 159
 160         if(this.move_movetype == MOVETYPE_BOUNCE || this.classname == "electro_orb") // TODO: classname is more reliable anyway?
 161         {
 162                 RadiusDamage(
 163                         this,
 164                         this.realowner,
 165                         WEP_CVAR_SEC(electro, damage),
 166                         WEP_CVAR_SEC(electro, edgedamage),
 167                         WEP_CVAR_SEC(electro, radius),
 168                         NULL,
 169                         NULL,
 170                         WEP_CVAR_SEC(electro, force),
 171                         this.projectiledeathtype,
 172                         directhitentity
 173                 );
 174         }
 175         else
 176         {
 177                 W_Electro_TriggerCombo(this.origin, WEP_CVAR_PRI(electro, comboradius), this.realowner);
 178                 RadiusDamage(
 179                         this,
 180                         this.realowner,
 181                         WEP_CVAR_PRI(electro, damage),
 182                         WEP_CVAR_PRI(electro, edgedamage),
 183                         WEP_CVAR_PRI(electro, radius),
 184                         NULL,
 185                         NULL,
 186                         WEP_CVAR_PRI(electro, force),
 187                         this.projectiledeathtype,
 188                         directhitentity
 189                 );
 190         }
 191
 192         remove(this);
 193 }
 194
 195 void W_Electro_Explode_use(entity this, entity actor, entity trigger)
 196 {
 197         W_Electro_Explode(this, trigger);
 198 }
 199
 200 void W_Electro_TouchExplode(entity this, entity toucher)
 201 {
 202         PROJECTILE_TOUCH(this, toucher);
 203         W_Electro_Explode(this, toucher);
 204 }
 205
 206 void W_Electro_Bolt_Think(entity this)
 207 {
 208         if(time >= this.ltime)
 209         {
 210                 this.use(this, NULL, NULL);
 211                 return;
 212         }
 213
 214         if(WEP_CVAR_PRI(electro, midaircombo_radius))
 215         {
 216                 float found = 0;
 217                 entity e = WarpZone_FindRadius(this.origin, WEP_CVAR_PRI(electro, midaircombo_radius), true);
 218
 219                 // loop through nearby orbs and trigger them
 220                 while(e)
 221                 {
 222                         if(e.classname == "electro_orb")
 223                         {
 224                                 // change owner to whoever caused the combo explosion
 225                                 e.realowner = this.realowner;
 226                                 e.takedamage = DAMAGE_NO;
 227                                 e.classname = "electro_orb_chain";
 228
 229                                 // now set the next one to trigger as well
 230                                 setthink(e, W_Electro_ExplodeCombo);
 231
 232                                 // delay combo chains, looks cooler
 233                                 e.nextthink =
 234                                         (
 235                                                 time
 236                                                 +
 237                                                 (WEP_CVAR(electro, combo_speed) ?
 238                                                         (vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed))
 239                                                         :
 240                                                         0
 241                                                 )
 242                                         );
 243
 244                                 ++found;
 245                         }
 246                         e = e.chain;
 247                 }
 248
 249                 // if we triggered an orb, should we explode? if not, lets try again next time
 250                 if(found && WEP_CVAR_PRI(electro, midaircombo_explode))
 251                         { this.use(this, NULL, NULL); }
 252                 else
 253                         { this.nextthink = min(time + WEP_CVAR_PRI(electro, midaircombo_interval), this.ltime); }
 254         }
 255         else { this.nextthink = this.ltime; }
 256 }
 257
 258 void W_Electro_Attack_Bolt(Weapon thiswep, entity actor)
 259 {
 260         entity proj;
 261
 262         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_PRI(electro, ammo));
 263
 264         W_SetupShot_ProjectileSize(
 265                 actor,
 266                 '0 0 -3',
 267                 '0 0 -3',
 268                 false,
 269                 2,
 270                 SND_ELECTRO_FIRE,
 271                 CH_WEAPON_A,
 272                 WEP_CVAR_PRI(electro, damage)
 273         );
 274
 275         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 276
 277         proj = new(electro_bolt);
 278         proj.owner = proj.realowner = actor;
 279         proj.bot_dodge = true;
 280         proj.bot_dodgerating = WEP_CVAR_PRI(electro, damage);
 281         proj.use = W_Electro_Explode_use;
 282         setthink(proj, W_Electro_Bolt_Think);
 283         proj.nextthink = time;
 284         proj.ltime = time + WEP_CVAR_PRI(electro, lifetime);
 285         PROJECTILE_MAKETRIGGER(proj);
 286         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 287         setorigin(proj, w_shotorg);
 288
 289         set_movetype(proj, MOVETYPE_FLY);
 290         W_SetupProjVelocity_PRI(proj, electro);
 291         proj.angles = vectoangles(proj.velocity);
 292         settouch(proj, W_Electro_TouchExplode);
 293         setsize(proj, '0 0 -3', '0 0 -3');
 294         proj.flags = FL_PROJECTILE;
 295         proj.missile_flags = MIF_SPLASH;
 296
 297         CSQCProjectile(proj, true, PROJECTILE_ELECTRO_BEAM, true);
 298
 299         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 300 }
 301
 302 void W_Electro_Orb_Stick(entity this, entity to)
 303 {
 304         entity newproj = spawn();
 305         newproj.classname = this.classname;
 306
 307         newproj.bot_dodge = this.bot_dodge;
 308         newproj.bot_dodgerating = this.bot_dodgerating;
 309
 310         newproj.owner = this.owner;
 311         newproj.realowner = this.realowner;
 312         setsize(newproj, this.mins, this.maxs);
 313         setorigin(newproj, this.origin);
 314         setmodel(newproj, MDL_PROJECTILE_ELECTRO);
 315         newproj.angles = vectoangles(-trace_plane_normal); // face against the surface
 316
 317         newproj.takedamage = this.takedamage;
 318         newproj.damageforcescale = this.damageforcescale;
 319         newproj.health = this.health;
 320         newproj.event_damage = this.event_damage;
 321         newproj.spawnshieldtime = this.spawnshieldtime;
 322         newproj.damagedbycontents = true;
 323
 324         set_movetype(newproj, MOVETYPE_NONE); // lock the orb in place
 325         newproj.projectiledeathtype = this.projectiledeathtype;
 326
 327         settouch(newproj, func_null);
 328         setthink(newproj, getthink(this));
 329         newproj.nextthink = this.nextthink;
 330         newproj.use = this.use;
 331         newproj.flags = this.flags;
 332
 333         remove(this);
 334
 335         if(to)
 336                 SetMovetypeFollow(this, to);
 337 }
 338
 339 void W_Electro_Orb_Touch(entity this, entity toucher)
 340 {
 341         PROJECTILE_TOUCH(this, toucher);
 342         if(toucher.takedamage == DAMAGE_AIM)
 343                 { if(WEP_CVAR_SEC(electro, touchexplode)) { W_Electro_Explode(this, toucher); } }
 344         else
 345         {
 346                 //UpdateCSQCProjectile(this);
 347                 spamsound(this, CH_SHOTS, SND(ELECTRO_BOUNCE), VOL_BASE, ATTEN_NORM);
 348                 this.projectiledeathtype |= HITTYPE_BOUNCE;
 349
 350                 if(WEP_CVAR_SEC(electro, stick))
 351                         W_Electro_Orb_Stick(this, toucher);
 352         }
 353 }
 354
 355 void W_Electro_Orb_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 356 {
 357         if(this.health <= 0)
 358                 return;
 359
 360         // note: combos are usually triggered by W_Electro_TriggerCombo, not damage
 361         float is_combo = (inflictor.classname == "electro_orb_chain" || inflictor.classname == "electro_bolt");
 362
 363         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, (is_combo ? 1 : -1)))
 364                 return; // g_projectiles_damage says to halt
 365
 366         this.health = this.health - damage;
 367         if(this.health <= 0)
 368         {
 369                 this.takedamage = DAMAGE_NO;
 370                 this.nextthink = time;
 371                 if(is_combo)
 372                 {
 373                         // change owner to whoever caused the combo explosion
 374                         this.realowner = inflictor.realowner;
 375                         this.classname = "electro_orb_chain";
 376                         setthink(this, W_Electro_ExplodeCombo);
 377                         this.nextthink = time +
 378                                 (
 379                                         // bound the length, inflictor may be in a galaxy far far away (warpzones)
 380                                         min(
 381                                                 WEP_CVAR(electro, combo_radius),
 382                                                 vlen(this.origin - inflictor.origin)
 383                                         )
 384                                         /
 385                                         // delay combo chains, looks cooler
 386                                         WEP_CVAR(electro, combo_speed)
 387                                 );
 388                 }
 389                 else
 390                 {
 391                         this.use = W_Electro_Explode_use;
 392                         setthink(this, adaptor_think2use); // not _hittype_splash, as this runs "immediately"
 393                 }
 394         }
 395 }
 396
 397 void W_Electro_Attack_Orb(Weapon thiswep, entity actor)
 398 {
 399         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(electro, ammo));
 400
 401         W_SetupShot_ProjectileSize(
 402                 actor,
 403                 '-4 -4 -4',
 404                 '4 4 4',
 405                 false,
 406                 2,
 407                 SND_ELECTRO_FIRE2,
 408                 CH_WEAPON_A,
 409                 WEP_CVAR_SEC(electro, damage)
 410         );
 411
 412         w_shotdir = v_forward; // no TrueAim for grenades please
 413
 414         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 415
 416         entity proj = new(electro_orb);
 417         proj.owner = proj.realowner = actor;
 418         proj.use = W_Electro_Explode_use;
 419         setthink(proj, adaptor_think2use_hittype_splash);
 420         proj.bot_dodge = true;
 421         proj.bot_dodgerating = WEP_CVAR_SEC(electro, damage);
 422         proj.nextthink = time + WEP_CVAR_SEC(electro, lifetime);
 423         PROJECTILE_MAKETRIGGER(proj);
 424         proj.projectiledeathtype = WEP_ELECTRO.m_id | HITTYPE_SECONDARY;
 425         setorigin(proj, w_shotorg);
 426
 427         //proj.glow_size = 50;
 428         //proj.glow_color = 45;
 429         set_movetype(proj, MOVETYPE_BOUNCE);
 430         W_SetupProjVelocity_UP_SEC(proj, electro);
 431         settouch(proj, W_Electro_Orb_Touch);
 432         setsize(proj, '-4 -4 -4', '4 4 4');
 433         proj.takedamage = DAMAGE_YES;
 434         proj.damageforcescale = WEP_CVAR_SEC(electro, damageforcescale);
 435         proj.health = WEP_CVAR_SEC(electro, health);
 436         proj.event_damage = W_Electro_Orb_Damage;
 437         proj.flags = FL_PROJECTILE;
 438         proj.damagedbycontents = (WEP_CVAR_SEC(electro, damagedbycontents));
 439
 440         proj.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
 441         proj.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
 442         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 443
 444 #if 0
 445         entity p2;
 446         p2 = spawn();
 447         copyentity(proj, p2);
 448         setmodel(p2, MDL_PROJECTILE_ELECTRO);
 449         setsize(p2, proj.mins, proj.maxs);
 450 #endif
 451
 452         CSQCProjectile(proj, true, PROJECTILE_ELECTRO, false); // no culling, it has sound
 453
 454         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 455 }
 456
 457 void W_Electro_CheckAttack(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 458 {
 459         if(actor.electro_count > 1)
 460         if(PHYS_INPUT_BUTTON_ATCK2(actor))
 461         if(weapon_prepareattack(thiswep, actor, weaponentity, true, -1))
 462         {
 463                 W_Electro_Attack_Orb(WEP_ELECTRO, actor);
 464                 actor.electro_count -= 1;
 465                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 466                 return;
 467         }
 468         // WEAPONTODO: when the player releases the button, cut down the length of refire2?
 469         w_ready(thiswep, actor, weaponentity, fire);
 470 }
 471
 472 .float bot_secondary_electromooth;
 473
 474 METHOD(Electro, wr_aim, void(entity thiswep, entity actor))
 475 {
 476     PHYS_INPUT_BUTTON_ATCK(actor) = PHYS_INPUT_BUTTON_ATCK2(actor) = false;
 477     if(vdist(actor.origin - actor.enemy.origin, >, 1000)) { actor.bot_secondary_electromooth = 0; }
 478     if(actor.bot_secondary_electromooth == 0)
 479     {
 480         float shoot;
 481
 482         if(WEP_CVAR_PRI(electro, speed))
 483             shoot = bot_aim(actor, WEP_CVAR_PRI(electro, speed), 0, WEP_CVAR_PRI(electro, lifetime), false);
 484         else
 485             shoot = bot_aim(actor, 1000000, 0, 0.001, false);
 486
 487         if(shoot)
 488         {
 489             PHYS_INPUT_BUTTON_ATCK(actor) = true;
 490             if(random() < 0.01) actor.bot_secondary_electromooth = 1;
 491         }
 492     }
 493     else
 494     {
 495         if(bot_aim(actor, WEP_CVAR_SEC(electro, speed), WEP_CVAR_SEC(electro, speed_up), WEP_CVAR_SEC(electro, lifetime), true))
 496         {
 497             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 498             if(random() < 0.03) actor.bot_secondary_electromooth = 0;
 499         }
 500     }
 501 }
 502 METHOD(Electro, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 503 {
 504     if(autocvar_g_balance_electro_reload_ammo) // forced reload // WEAPONTODO
 505     {
 506         float ammo_amount = 0;
 507         if(actor.clip_load >= WEP_CVAR_PRI(electro, ammo))
 508             ammo_amount = 1;
 509         if(actor.clip_load >= WEP_CVAR_SEC(electro, ammo))
 510             ammo_amount += 1;
 511
 512         if(!ammo_amount)
 513         {
 514             thiswep.wr_reload(thiswep, actor, weaponentity);
 515             return;
 516         }
 517     }
 518
 519     if(fire & 1)
 520     {
 521         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(electro, refire)))
 522         {
 523                 W_Electro_Attack_Bolt(thiswep, actor);
 524                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(electro, animtime), w_ready);
 525         }
 526     }
 527     else if(fire & 2)
 528     {
 529         if(time >= actor.electro_secondarytime)
 530         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(electro, refire)))
 531         {
 532             W_Electro_Attack_Orb(thiswep, actor);
 533             actor.electro_count = WEP_CVAR_SEC(electro, count);
 534             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 535             actor.electro_secondarytime = time + WEP_CVAR_SEC(electro, refire2) * W_WeaponRateFactor(actor);
 536         }
 537     }
 538 }
 539 METHOD(Electro, wr_checkammo1, bool(entity thiswep, entity actor))
 540 {
 541     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_PRI(electro, ammo);
 542     ammo_amount += actor.(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_PRI(electro, ammo);
 543     return ammo_amount;
 544 }
 545 METHOD(Electro, wr_checkammo2, bool(entity thiswep, entity actor))
 546 {
 547     float ammo_amount;
 548     if(WEP_CVAR(electro, combo_safeammocheck)) // true if you can fire at least one secondary blob AND one primary shot after it, otherwise false.
 549     {
 550         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 551         ammo_amount += actor.(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 552     }
 553     else
 554     {
 555         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(electro, ammo);
 556         ammo_amount += actor.(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_SEC(electro, ammo);
 557     }
 558     return ammo_amount;
 559 }
 560 METHOD(Electro, wr_resetplayer, void(entity thiswep, entity actor))
 561 {
 562     actor.electro_secondarytime = time;
 563 }
 564 METHOD(Electro, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 565 {
 566     W_Reload(actor, min(WEP_CVAR_PRI(electro, ammo), WEP_CVAR_SEC(electro, ammo)), SND_RELOAD);
 567 }
 568 METHOD(Electro, wr_suicidemessage, Notification(entity thiswep))
 569 {
 570     if(w_deathtype & HITTYPE_SECONDARY)
 571         return WEAPON_ELECTRO_SUICIDE_ORBS;
 572     else
 573         return WEAPON_ELECTRO_SUICIDE_BOLT;
 574 }
 575 METHOD(Electro, wr_killmessage, Notification(entity thiswep))
 576 {
 577     if(w_deathtype & HITTYPE_SECONDARY)
 578     {
 579         return WEAPON_ELECTRO_MURDER_ORBS;
 580     }
 581     else
 582     {
 583         if(w_deathtype & HITTYPE_BOUNCE)
 584             return WEAPON_ELECTRO_MURDER_COMBO;
 585         else
 586             return WEAPON_ELECTRO_MURDER_BOLT;
 587     }
 588 }
 589
 590 #endif
 591 #ifdef CSQC
 592
 593 METHOD(Electro, wr_impacteffect, void(entity thiswep, entity actor))
 594 {
 595     vector org2;
 596     org2 = w_org + w_backoff * 6;
 597     if(w_deathtype & HITTYPE_SECONDARY)
 598     {
 599         pointparticles(EFFECT_ELECTRO_BALLEXPLODE, org2, '0 0 0', 1);
 600         if(!w_issilent)
 601             sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_NORM);
 602     }
 603     else
 604     {
 605         if(w_deathtype & HITTYPE_BOUNCE)
 606         {
 607             // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 608             pointparticles(EFFECT_ELECTRO_COMBO, org2, '0 0 0', 1);
 609             if(!w_issilent)
 610                 sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT_COMBO, VOL_BASE, ATTEN_NORM);
 611         }
 612         else
 613         {
 614             pointparticles(EFFECT_ELECTRO_IMPACT, org2, '0 0 0', 1);
 615             if(!w_issilent)
 616                 sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_NORM);
 617         }
 618     }
 619 }
 620
 621 #endif
 622 #endif