qcsrc/common/weapons/weapon/electro.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Electro, Weapon)
   3 /* ammotype  */ ATTRIB(Electro, ammo_field, .int, ammo_cells)
   4 /* impulse   */ ATTRIB(Electro, impulse, int, 5)
   5 /* flags     */ ATTRIB(Electro, spawnflags, int, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
   6 /* rating    */ ATTRIB(Electro, bot_pickupbasevalue, float, BOT_PICKUP_RATING_MID);
   7 /* color     */ ATTRIB(Electro, wpcolor, vector, '0 0.5 1');
   8 /* modelname */ ATTRIB(Electro, mdl, string, "electro");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Electro, m_model, Model, MDL_ELECTRO_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Electro, w_crosshair, string, "gfx/crosshairelectro");
  13 /* crosshair */ ATTRIB(Electro, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(Electro, model2, string, "weaponelectro");
  15 /* refname   */ ATTRIB(Electro, netname, string, "electro");
  16 /* wepname   */ ATTRIB(Electro, m_name, string, _("Electro"));
  17
  18 #define X(BEGIN, P, END, class, prefix) \
  19         BEGIN(class) \
  20                 P(class, prefix, ammo, float, BOTH) \
  21                 P(class, prefix, animtime, float, BOTH) \
  22                 P(class, prefix, bouncefactor, float, SEC) \
  23                 P(class, prefix, bouncestop, float, SEC) \
  24                 P(class, prefix, comboradius, float, PRI) \
  25                 P(class, prefix, combo_comboradius, float, NONE) \
  26                 P(class, prefix, combo_comboradius_thruwall, float, NONE) \
  27                 P(class, prefix, combo_damage, float, NONE) \
  28                 P(class, prefix, combo_edgedamage, float, NONE) \
  29                 P(class, prefix, combo_force, float, NONE) \
  30                 P(class, prefix, combo_radius, float, NONE) \
  31                 P(class, prefix, combo_safeammocheck, float, NONE) \
  32                 P(class, prefix, combo_speed, float, NONE) \
  33                 P(class, prefix, count, float, SEC) \
  34                 P(class, prefix, damagedbycontents, float, SEC) \
  35                 P(class, prefix, damageforcescale, float, SEC) \
  36                 P(class, prefix, damage, float, BOTH) \
  37                 P(class, prefix, edgedamage, float, BOTH) \
  38                 P(class, prefix, force, float, BOTH) \
  39                 P(class, prefix, health, float, SEC) \
  40                 P(class, prefix, lifetime, float, BOTH) \
  41                 P(class, prefix, midaircombo_explode, float, PRI) \
  42                 P(class, prefix, midaircombo_interval, float, PRI) \
  43                 P(class, prefix, midaircombo_radius, float, PRI) \
  44                 P(class, prefix, radius, float, BOTH) \
  45                 P(class, prefix, refire2, float, SEC) \
  46                 P(class, prefix, refire, float, BOTH) \
  47                 P(class, prefix, reload_ammo, float, NONE) \
  48                 P(class, prefix, reload_time, float, NONE) \
  49                 P(class, prefix, speed, float, BOTH) \
  50                 P(class, prefix, speed_up, float, SEC) \
  51                 P(class, prefix, speed_z, float, SEC) \
  52                 P(class, prefix, spread, float, BOTH) \
  53                 P(class, prefix, stick, float, SEC) \
  54                 P(class, prefix, switchdelay_drop, float, NONE) \
  55                 P(class, prefix, switchdelay_raise, float, NONE) \
  56                 P(class, prefix, touchexplode, float, SEC) \
  57                 P(class, prefix, weaponreplace, string,NONE) \
  58                 P(class, prefix, weaponstartoverride, float, NONE) \
  59                 P(class, prefix, weaponstart, float, NONE) \
  60                 P(class, prefix, weaponthrowable, float, NONE) \
  61         END()
  62         W_PROPS(X, Electro, electro)
  63 #undef X
  64
  65 ENDCLASS(Electro)
  66 REGISTER_WEAPON(ELECTRO, electro, NEW(Electro));
  67
  68
  69 #ifdef SVQC
  70 .float electro_count;
  71 .float electro_secondarytime;
  72 void W_Electro_ExplodeCombo(entity this);
  73 #endif
  74 #endif
  75 #ifdef IMPLEMENTATION
  76 #ifdef SVQC
  77 spawnfunc(weapon_electro) { weapon_defaultspawnfunc(this, WEP_ELECTRO); }
  78
  79 void W_Electro_TriggerCombo(vector org, float rad, entity own)
  80 {
  81         entity e = WarpZone_FindRadius(org, rad, !WEP_CVAR(electro, combo_comboradius_thruwall));
  82         while(e)
  83         {
  84                 if(e.classname == "electro_orb")
  85                 {
  86                         // do we allow thruwall triggering?
  87                         if(WEP_CVAR(electro, combo_comboradius_thruwall))
  88                         {
  89                                 // if distance is greater than thruwall distance, check to make sure it's not through a wall
  90                                 if(vdist(e.WarpZone_findradius_dist, >, WEP_CVAR(electro, combo_comboradius_thruwall)))
  91                                 {
  92                                         WarpZone_TraceLine(org, e.origin, MOVE_NOMONSTERS, e);
  93                                         if(trace_fraction != 1)
  94                                         {
  95                                                 // trigger is through a wall and outside of thruwall range, abort
  96                                                 e = e.chain;
  97                                                 continue;
  98                                         }
  99                                 }
 100                         }
 101
 102                         // change owner to whoever caused the combo explosion
 103                         e.realowner = own;
 104                         e.takedamage = DAMAGE_NO;
 105                         e.classname = "electro_orb_chain";
 106
 107                         // now set the next one to trigger as well
 108                         setthink(e, W_Electro_ExplodeCombo);
 109
 110                         // delay combo chains, looks cooler
 111                         e.nextthink =
 112                                 (
 113                                         time
 114                                         +
 115                                         (WEP_CVAR(electro, combo_speed) ?
 116                                                 (vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed))
 117                                                 :
 118                                                 0
 119                                         )
 120                                 );
 121                 }
 122                 e = e.chain;
 123         }
 124 }
 125
 126 void W_Electro_ExplodeCombo(entity this)
 127 {
 128         W_Electro_TriggerCombo(this.origin, WEP_CVAR(electro, combo_comboradius), this.realowner);
 129
 130         this.event_damage = func_null;
 131
 132         RadiusDamage(
 133                 this,
 134                 this.realowner,
 135                 WEP_CVAR(electro, combo_damage),
 136                 WEP_CVAR(electro, combo_edgedamage),
 137                 WEP_CVAR(electro, combo_radius),
 138                 NULL,
 139                 NULL,
 140                 WEP_CVAR(electro, combo_force),
 141                 WEP_ELECTRO.m_id | HITTYPE_BOUNCE, // use THIS type for a combo because primary can't bounce
 142                 NULL
 143         );
 144
 145         delete(this);
 146 }
 147
 148 void W_Electro_Explode(entity this, entity directhitentity)
 149 {
 150         if(directhitentity.takedamage == DAMAGE_AIM)
 151                 if(IS_PLAYER(directhitentity))
 152                         if(DIFF_TEAM(this.realowner, directhitentity))
 153                                 if(!IS_DEAD(directhitentity))
 154                                         if(IsFlying(directhitentity))
 155                                                 Send_Notification(NOTIF_ONE, this.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
 156
 157         this.event_damage = func_null;
 158         this.takedamage = DAMAGE_NO;
 159
 160         if(this.move_movetype == MOVETYPE_BOUNCE || this.classname == "electro_orb") // TODO: classname is more reliable anyway?
 161         {
 162                 RadiusDamage(
 163                         this,
 164                         this.realowner,
 165                         WEP_CVAR_SEC(electro, damage),
 166                         WEP_CVAR_SEC(electro, edgedamage),
 167                         WEP_CVAR_SEC(electro, radius),
 168                         NULL,
 169                         NULL,
 170                         WEP_CVAR_SEC(electro, force),
 171                         this.projectiledeathtype,
 172                         directhitentity
 173                 );
 174         }
 175         else
 176         {
 177                 W_Electro_TriggerCombo(this.origin, WEP_CVAR_PRI(electro, comboradius), this.realowner);
 178                 RadiusDamage(
 179                         this,
 180                         this.realowner,
 181                         WEP_CVAR_PRI(electro, damage),
 182                         WEP_CVAR_PRI(electro, edgedamage),
 183                         WEP_CVAR_PRI(electro, radius),
 184                         NULL,
 185                         NULL,
 186                         WEP_CVAR_PRI(electro, force),
 187                         this.projectiledeathtype,
 188                         directhitentity
 189                 );
 190         }
 191
 192         delete(this);
 193 }
 194
 195 void W_Electro_Explode_use(entity this, entity actor, entity trigger)
 196 {
 197         W_Electro_Explode(this, trigger);
 198 }
 199
 200 void W_Electro_TouchExplode(entity this, entity toucher)
 201 {
 202         PROJECTILE_TOUCH(this, toucher);
 203         W_Electro_Explode(this, toucher);
 204 }
 205
 206
 207 void sys_phys_update_single(entity this);
 208
 209 void W_Electro_Bolt_Think(entity this)
 210 {
 211         // sys_phys_update_single(this);
 212         if(time >= this.ltime)
 213         {
 214                 this.use(this, NULL, NULL);
 215                 return;
 216         }
 217
 218         if(WEP_CVAR_PRI(electro, midaircombo_radius))
 219         {
 220                 float found = 0;
 221                 entity e = WarpZone_FindRadius(this.origin, WEP_CVAR_PRI(electro, midaircombo_radius), true);
 222
 223                 // loop through nearby orbs and trigger them
 224                 while(e)
 225                 {
 226                         if(e.classname == "electro_orb")
 227                         {
 228                                 // change owner to whoever caused the combo explosion
 229                                 e.realowner = this.realowner;
 230                                 e.takedamage = DAMAGE_NO;
 231                                 e.classname = "electro_orb_chain";
 232
 233                                 // now set the next one to trigger as well
 234                                 setthink(e, W_Electro_ExplodeCombo);
 235
 236                                 // delay combo chains, looks cooler
 237                                 e.nextthink =
 238                                         (
 239                                                 time
 240                                                 +
 241                                                 (WEP_CVAR(electro, combo_speed) ?
 242                                                         (vlen(e.WarpZone_findradius_dist) / WEP_CVAR(electro, combo_speed))
 243                                                         :
 244                                                         0
 245                                                 )
 246                                         );
 247
 248                                 ++found;
 249                         }
 250                         e = e.chain;
 251                 }
 252
 253                 // if we triggered an orb, should we explode? if not, lets try again next time
 254                 if(found && WEP_CVAR_PRI(electro, midaircombo_explode))
 255                         { this.use(this, NULL, NULL); }
 256                 else
 257                         { this.nextthink = min(time + WEP_CVAR_PRI(electro, midaircombo_interval), this.ltime); }
 258         }
 259         else { this.nextthink = this.ltime; }
 260         // this.nextthink = time;
 261 }
 262
 263 void W_Electro_Attack_Bolt(Weapon thiswep, entity actor)
 264 {
 265         entity proj;
 266
 267         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_PRI(electro, ammo));
 268
 269         W_SetupShot_ProjectileSize(
 270                 actor,
 271                 '0 0 -3',
 272                 '0 0 -3',
 273                 false,
 274                 2,
 275                 SND_ELECTRO_FIRE,
 276                 CH_WEAPON_A,
 277                 WEP_CVAR_PRI(electro, damage)
 278         );
 279
 280         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 281
 282         proj = new(electro_bolt);
 283         proj.owner = proj.realowner = actor;
 284         proj.bot_dodge = true;
 285         proj.bot_dodgerating = WEP_CVAR_PRI(electro, damage);
 286         proj.use = W_Electro_Explode_use;
 287         setthink(proj, W_Electro_Bolt_Think);
 288         proj.nextthink = time;
 289         proj.ltime = time + WEP_CVAR_PRI(electro, lifetime);
 290         PROJECTILE_MAKETRIGGER(proj);
 291         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 292         setorigin(proj, w_shotorg);
 293
 294         // if (IS_CSQC)
 295         set_movetype(proj, MOVETYPE_FLY);
 296         W_SetupProjVelocity_PRI(proj, electro);
 297         proj.angles = vectoangles(proj.velocity);
 298         settouch(proj, W_Electro_TouchExplode);
 299         setsize(proj, '0 0 -3', '0 0 -3');
 300         proj.flags = FL_PROJECTILE;
 301         proj.missile_flags = MIF_SPLASH;
 302
 303         CSQCProjectile(proj, true, PROJECTILE_ELECTRO_BEAM, true);
 304
 305         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 306         // proj.com_phys_pos = proj.origin;
 307         // proj.com_phys_vel = proj.velocity;
 308 }
 309
 310 void W_Electro_Orb_Stick(entity this, entity to)
 311 {
 312         entity newproj = spawn();
 313         newproj.classname = this.classname;
 314
 315         newproj.bot_dodge = this.bot_dodge;
 316         newproj.bot_dodgerating = this.bot_dodgerating;
 317
 318         newproj.owner = this.owner;
 319         newproj.realowner = this.realowner;
 320         setsize(newproj, this.mins, this.maxs);
 321         setorigin(newproj, this.origin);
 322         setmodel(newproj, MDL_PROJECTILE_ELECTRO);
 323         newproj.angles = vectoangles(-trace_plane_normal); // face against the surface
 324
 325         newproj.takedamage = this.takedamage;
 326         newproj.damageforcescale = this.damageforcescale;
 327         newproj.health = this.health;
 328         newproj.event_damage = this.event_damage;
 329         newproj.spawnshieldtime = this.spawnshieldtime;
 330         newproj.damagedbycontents = true;
 331
 332         set_movetype(newproj, MOVETYPE_NONE); // lock the orb in place
 333         newproj.projectiledeathtype = this.projectiledeathtype;
 334
 335         settouch(newproj, func_null);
 336         setthink(newproj, getthink(this));
 337         newproj.nextthink = this.nextthink;
 338         newproj.use = this.use;
 339         newproj.flags = this.flags;
 340
 341         delete(this);
 342
 343         if(to)
 344                 SetMovetypeFollow(this, to);
 345 }
 346
 347 void W_Electro_Orb_Touch(entity this, entity toucher)
 348 {
 349         PROJECTILE_TOUCH(this, toucher);
 350         if(toucher.takedamage == DAMAGE_AIM)
 351                 { if(WEP_CVAR_SEC(electro, touchexplode)) { W_Electro_Explode(this, toucher); } }
 352         else
 353         {
 354                 //UpdateCSQCProjectile(this);
 355                 spamsound(this, CH_SHOTS, SND(ELECTRO_BOUNCE), VOL_BASE, ATTEN_NORM);
 356                 this.projectiledeathtype |= HITTYPE_BOUNCE;
 357
 358                 if(WEP_CVAR_SEC(electro, stick))
 359                         W_Electro_Orb_Stick(this, toucher);
 360         }
 361 }
 362
 363 void W_Electro_Orb_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 364 {
 365         if(this.health <= 0)
 366                 return;
 367
 368         // note: combos are usually triggered by W_Electro_TriggerCombo, not damage
 369         float is_combo = (inflictor.classname == "electro_orb_chain" || inflictor.classname == "electro_bolt");
 370
 371         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, (is_combo ? 1 : -1)))
 372                 return; // g_projectiles_damage says to halt
 373
 374         this.health = this.health - damage;
 375         if(this.health <= 0)
 376         {
 377                 this.takedamage = DAMAGE_NO;
 378                 this.nextthink = time;
 379                 if(is_combo)
 380                 {
 381                         // change owner to whoever caused the combo explosion
 382                         this.realowner = inflictor.realowner;
 383                         this.classname = "electro_orb_chain";
 384                         setthink(this, W_Electro_ExplodeCombo);
 385                         this.nextthink = time +
 386                                 (
 387                                         // bound the length, inflictor may be in a galaxy far far away (warpzones)
 388                                         min(
 389                                                 WEP_CVAR(electro, combo_radius),
 390                                                 vlen(this.origin - inflictor.origin)
 391                                         )
 392                                         /
 393                                         // delay combo chains, looks cooler
 394                                         WEP_CVAR(electro, combo_speed)
 395                                 );
 396                 }
 397                 else
 398                 {
 399                         this.use = W_Electro_Explode_use;
 400                         setthink(this, adaptor_think2use); // not _hittype_splash, as this runs "immediately"
 401                 }
 402         }
 403 }
 404
 405 void W_Electro_Attack_Orb(Weapon thiswep, entity actor)
 406 {
 407         W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(electro, ammo));
 408
 409         W_SetupShot_ProjectileSize(
 410                 actor,
 411                 '-4 -4 -4',
 412                 '4 4 4',
 413                 false,
 414                 2,
 415                 SND_ELECTRO_FIRE2,
 416                 CH_WEAPON_A,
 417                 WEP_CVAR_SEC(electro, damage)
 418         );
 419
 420         w_shotdir = v_forward; // no TrueAim for grenades please
 421
 422         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 423
 424         entity proj = new(electro_orb);
 425         proj.owner = proj.realowner = actor;
 426         proj.use = W_Electro_Explode_use;
 427         setthink(proj, adaptor_think2use_hittype_splash);
 428         proj.bot_dodge = true;
 429         proj.bot_dodgerating = WEP_CVAR_SEC(electro, damage);
 430         proj.nextthink = time + WEP_CVAR_SEC(electro, lifetime);
 431         PROJECTILE_MAKETRIGGER(proj);
 432         proj.projectiledeathtype = WEP_ELECTRO.m_id | HITTYPE_SECONDARY;
 433         setorigin(proj, w_shotorg);
 434
 435         //proj.glow_size = 50;
 436         //proj.glow_color = 45;
 437         set_movetype(proj, MOVETYPE_BOUNCE);
 438         W_SetupProjVelocity_UP_SEC(proj, electro);
 439         settouch(proj, W_Electro_Orb_Touch);
 440         setsize(proj, '-4 -4 -4', '4 4 4');
 441         proj.takedamage = DAMAGE_YES;
 442         proj.damageforcescale = WEP_CVAR_SEC(electro, damageforcescale);
 443         proj.health = WEP_CVAR_SEC(electro, health);
 444         proj.event_damage = W_Electro_Orb_Damage;
 445         proj.flags = FL_PROJECTILE;
 446         proj.damagedbycontents = (WEP_CVAR_SEC(electro, damagedbycontents));
 447
 448         proj.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
 449         proj.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
 450         proj.missile_flags = MIF_SPLASH | MIF_ARC;
 451
 452 #if 0
 453         entity p2;
 454         p2 = spawn();
 455         copyentity(proj, p2);
 456         setmodel(p2, MDL_PROJECTILE_ELECTRO);
 457         setsize(p2, proj.mins, proj.maxs);
 458 #endif
 459
 460         CSQCProjectile(proj, true, PROJECTILE_ELECTRO, false); // no culling, it has sound
 461
 462         MUTATOR_CALLHOOK(EditProjectile, actor, proj);
 463 }
 464
 465 void W_Electro_CheckAttack(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 466 {
 467         if(actor.electro_count > 1)
 468         if(PHYS_INPUT_BUTTON_ATCK2(actor))
 469         if(weapon_prepareattack(thiswep, actor, weaponentity, true, -1))
 470         {
 471                 W_Electro_Attack_Orb(WEP_ELECTRO, actor);
 472                 actor.electro_count -= 1;
 473                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 474                 return;
 475         }
 476         // WEAPONTODO: when the player releases the button, cut down the length of refire2?
 477         w_ready(thiswep, actor, weaponentity, fire);
 478 }
 479
 480 .float bot_secondary_electromooth;
 481
 482 METHOD(Electro, wr_aim, void(entity thiswep, entity actor))
 483 {
 484     PHYS_INPUT_BUTTON_ATCK(actor) = PHYS_INPUT_BUTTON_ATCK2(actor) = false;
 485     if(vdist(actor.origin - actor.enemy.origin, >, 1000)) { actor.bot_secondary_electromooth = 0; }
 486     if(actor.bot_secondary_electromooth == 0)
 487     {
 488         float shoot;
 489
 490         if(WEP_CVAR_PRI(electro, speed))
 491             shoot = bot_aim(actor, WEP_CVAR_PRI(electro, speed), 0, WEP_CVAR_PRI(electro, lifetime), false);
 492         else
 493             shoot = bot_aim(actor, 1000000, 0, 0.001, false);
 494
 495         if(shoot)
 496         {
 497             PHYS_INPUT_BUTTON_ATCK(actor) = true;
 498             if(random() < 0.01) actor.bot_secondary_electromooth = 1;
 499         }
 500     }
 501     else
 502     {
 503         if(bot_aim(actor, WEP_CVAR_SEC(electro, speed), WEP_CVAR_SEC(electro, speed_up), WEP_CVAR_SEC(electro, lifetime), true))
 504         {
 505             PHYS_INPUT_BUTTON_ATCK2(actor) = true;
 506             if(random() < 0.03) actor.bot_secondary_electromooth = 0;
 507         }
 508     }
 509 }
 510 METHOD(Electro, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 511 {
 512     if(autocvar_g_balance_electro_reload_ammo) // forced reload // WEAPONTODO
 513     {
 514         float ammo_amount = 0;
 515         if(actor.clip_load >= WEP_CVAR_PRI(electro, ammo))
 516             ammo_amount = 1;
 517         if(actor.clip_load >= WEP_CVAR_SEC(electro, ammo))
 518             ammo_amount += 1;
 519
 520         if(!ammo_amount)
 521         {
 522             thiswep.wr_reload(thiswep, actor, weaponentity);
 523             return;
 524         }
 525     }
 526
 527     if(fire & 1)
 528     {
 529         if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(electro, refire)))
 530         {
 531                 W_Electro_Attack_Bolt(thiswep, actor);
 532                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(electro, animtime), w_ready);
 533         }
 534     }
 535     else if(fire & 2)
 536     {
 537         if(time >= actor.electro_secondarytime)
 538         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(electro, refire)))
 539         {
 540             W_Electro_Attack_Orb(thiswep, actor);
 541             actor.electro_count = WEP_CVAR_SEC(electro, count);
 542             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(electro, animtime), W_Electro_CheckAttack);
 543             actor.electro_secondarytime = time + WEP_CVAR_SEC(electro, refire2) * W_WeaponRateFactor(actor);
 544         }
 545     }
 546 }
 547 METHOD(Electro, wr_checkammo1, bool(entity thiswep, entity actor))
 548 {
 549     float ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_PRI(electro, ammo);
 550     ammo_amount += actor.(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_PRI(electro, ammo);
 551     return ammo_amount;
 552 }
 553 METHOD(Electro, wr_checkammo2, bool(entity thiswep, entity actor))
 554 {
 555     float ammo_amount;
 556     if(WEP_CVAR(electro, combo_safeammocheck)) // true if you can fire at least one secondary blob AND one primary shot after it, otherwise false.
 557     {
 558         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 559         ammo_amount += actor.(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_SEC(electro, ammo) + WEP_CVAR_PRI(electro, ammo);
 560     }
 561     else
 562     {
 563         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR_SEC(electro, ammo);
 564         ammo_amount += actor.(weapon_load[WEP_ELECTRO.m_id]) >= WEP_CVAR_SEC(electro, ammo);
 565     }
 566     return ammo_amount;
 567 }
 568 METHOD(Electro, wr_resetplayer, void(entity thiswep, entity actor))
 569 {
 570     actor.electro_secondarytime = time;
 571 }
 572 METHOD(Electro, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 573 {
 574     W_Reload(actor, min(WEP_CVAR_PRI(electro, ammo), WEP_CVAR_SEC(electro, ammo)), SND_RELOAD);
 575 }
 576 METHOD(Electro, wr_suicidemessage, Notification(entity thiswep))
 577 {
 578     if(w_deathtype & HITTYPE_SECONDARY)
 579         return WEAPON_ELECTRO_SUICIDE_ORBS;
 580     else
 581         return WEAPON_ELECTRO_SUICIDE_BOLT;
 582 }
 583 METHOD(Electro, wr_killmessage, Notification(entity thiswep))
 584 {
 585     if(w_deathtype & HITTYPE_SECONDARY)
 586     {
 587         return WEAPON_ELECTRO_MURDER_ORBS;
 588     }
 589     else
 590     {
 591         if(w_deathtype & HITTYPE_BOUNCE)
 592             return WEAPON_ELECTRO_MURDER_COMBO;
 593         else
 594             return WEAPON_ELECTRO_MURDER_BOLT;
 595     }
 596 }
 597
 598 #endif
 599 #ifdef CSQC
 600
 601 METHOD(Electro, wr_impacteffect, void(entity thiswep, entity actor))
 602 {
 603     vector org2;
 604     org2 = w_org + w_backoff * 6;
 605     if(w_deathtype & HITTYPE_SECONDARY)
 606     {
 607         pointparticles(EFFECT_ELECTRO_BALLEXPLODE, org2, '0 0 0', 1);
 608         if(!w_issilent)
 609             sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_NORM);
 610     }
 611     else
 612     {
 613         if(w_deathtype & HITTYPE_BOUNCE)
 614         {
 615             // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 616             pointparticles(EFFECT_ELECTRO_COMBO, org2, '0 0 0', 1);
 617             if(!w_issilent)
 618                 sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT_COMBO, VOL_BASE, ATTEN_NORM);
 619         }
 620         else
 621         {
 622             pointparticles(EFFECT_ELECTRO_IMPACT, org2, '0 0 0', 1);
 623             if(!w_issilent)
 624                 sound(actor, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_NORM);
 625         }
 626     }
 627 }
 628
 629 #endif
 630 #endif