qcsrc/common/weapons/weapon/hook.qc

   1 #include "hook.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(Hook, Weapon)
   4 /* ammotype  */ ATTRIB(Hook, ammo_field, .int, ammo_fuel);
   5 /* impulse   */ ATTRIB(Hook, impulse, int, 0);
   6 /* flags     */ ATTRIB(Hook, spawnflags, int, WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH);
   7 /* rating    */ ATTRIB(Hook, bot_pickupbasevalue, float, 0);
   8 /* color     */ ATTRIB(Hook, wpcolor, vector, '0 0.5 0');
   9 /* modelname */ ATTRIB(Hook, mdl, string, "hookgun");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(Hook, m_model, Model, MDL_HOOK_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(Hook, w_crosshair, string, "gfx/crosshairhook");
  14 /* crosshair */ ATTRIB(Hook, w_crosshair_size, float, 0.5);
  15 /* wepimg    */ ATTRIB(Hook, model2, string, "weaponhook");
  16 /* refname   */ ATTRIB(Hook, netname, string, "hook");
  17 /* wepname   */ ATTRIB(Hook, m_name, string, _("Grappling Hook"));
  18         ATTRIB(Hook, ammo_factor, float, 1);
  19
  20 #define X(BEGIN, P, END, class, prefix) \
  21         BEGIN(class) \
  22                 P(class, prefix, ammo, float, PRI) \
  23                 P(class, prefix, animtime, float, BOTH) \
  24                 P(class, prefix, damageforcescale, float, SEC) \
  25                 P(class, prefix, damage, float, SEC) \
  26                 P(class, prefix, duration, float, SEC) \
  27                 P(class, prefix, edgedamage, float, SEC) \
  28                 P(class, prefix, force, float, SEC) \
  29                 P(class, prefix, gravity, float, SEC) \
  30                 P(class, prefix, health, float, SEC) \
  31                 P(class, prefix, hooked_ammo, float, PRI) \
  32                 P(class, prefix, hooked_time_free, float, PRI) \
  33                 P(class, prefix, hooked_time_max, float, PRI) \
  34                 P(class, prefix, lifetime, float, SEC) \
  35                 P(class, prefix, power, float, SEC) \
  36                 P(class, prefix, radius, float, SEC) \
  37                 P(class, prefix, refire, float, BOTH) \
  38                 P(class, prefix, speed, float, SEC) \
  39         P(class, prefix, switchdelay_drop, float, NONE) \
  40                 P(class, prefix, switchdelay_raise, float, NONE) \
  41         P(class, prefix, weaponreplace, string, NONE) \
  42         P(class, prefix, weaponstartoverride, float, NONE) \
  43         P(class, prefix, weaponstart, float, NONE) \
  44         P(class, prefix, weaponthrowable, float, NONE) \
  45         END()
  46     W_PROPS(X, Hook, hook)
  47 #undef X
  48
  49 ENDCLASS(Hook)
  50 REGISTER_WEAPON(HOOK, hook, NEW(Hook));
  51
  52 CLASS(OffhandHook, OffhandWeapon)
  53 #ifdef SVQC
  54     METHOD(OffhandHook, offhand_think, void(OffhandHook this, entity actor, bool key_pressed))
  55     {
  56         Weapon wep = WEP_HOOK;
  57         .entity weaponentity = weaponentities[1];
  58         wep.wr_think(wep, actor, weaponentity, key_pressed ? 1 : 0);
  59     }
  60 #endif
  61 ENDCLASS(OffhandHook)
  62 OffhandHook OFFHAND_HOOK; STATIC_INIT(OFFHAND_HOOK) { OFFHAND_HOOK = NEW(OffhandHook); }
  63
  64 #ifdef SVQC
  65
  66 .float dmg;
  67 .float dmg_edge;
  68 .float dmg_radius;
  69 .float dmg_force;
  70 .float dmg_power;
  71 .float dmg_duration;
  72 .float dmg_last;
  73 .float hook_refire;
  74 .float hook_time_hooked;
  75 .float hook_time_fueldecrease;
  76 #endif
  77 #endif
  78 #ifdef IMPLEMENTATION
  79 #ifdef SVQC
  80
  81 spawnfunc(weapon_hook) { weapon_defaultspawnfunc(this, WEP_HOOK); }
  82
  83 void W_Hook_ExplodeThink(entity this)
  84 {
  85         float dt, dmg_remaining_next, f;
  86
  87         dt = time - this.teleport_time;
  88         dmg_remaining_next = pow(bound(0, 1 - dt / this.dmg_duration, 1), this.dmg_power);
  89
  90         f = this.dmg_last - dmg_remaining_next;
  91         this.dmg_last = dmg_remaining_next;
  92
  93         RadiusDamage(this, this.realowner, this.dmg * f, this.dmg_edge * f, this.dmg_radius, this.realowner, NULL, this.dmg_force * f, this.projectiledeathtype, NULL);
  94         this.projectiledeathtype |= HITTYPE_BOUNCE;
  95         //RadiusDamage(this, NULL, this.dmg * f, this.dmg_edge * f, this.dmg_radius, NULL, NULL, this.dmg_force * f, this.projectiledeathtype, NULL);
  96
  97         if(dt < this.dmg_duration)
  98                 this.nextthink = time + 0.05; // soon
  99         else
 100                 delete(this);
 101 }
 102
 103 void W_Hook_Explode2(entity this)
 104 {
 105         this.event_damage = func_null;
 106         settouch(this, func_null);
 107         this.effects |= EF_NODRAW;
 108
 109         setthink(this, W_Hook_ExplodeThink);
 110         this.nextthink = time;
 111         this.dmg = WEP_CVAR_SEC(hook, damage);
 112         this.dmg_edge = WEP_CVAR_SEC(hook, edgedamage);
 113         this.dmg_radius = WEP_CVAR_SEC(hook, radius);
 114         this.dmg_force = WEP_CVAR_SEC(hook, force);
 115         this.dmg_power = WEP_CVAR_SEC(hook, power);
 116         this.dmg_duration = WEP_CVAR_SEC(hook, duration);
 117         this.teleport_time = time;
 118         this.dmg_last = 1;
 119         set_movetype(this, MOVETYPE_NONE);
 120 }
 121
 122 void W_Hook_Explode2_use(entity this, entity actor, entity trigger)
 123 {
 124         W_Hook_Explode2(this);
 125 }
 126
 127 void W_Hook_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 128 {
 129         if(this.health <= 0)
 130                 return;
 131
 132         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 133                 return; // g_projectiles_damage says to halt
 134
 135         this.health = this.health - damage;
 136
 137         if(this.health <= 0)
 138                 W_PrepareExplosionByDamage(this, this.realowner, W_Hook_Explode2);
 139 }
 140
 141 void W_Hook_Touch2(entity this, entity toucher)
 142 {
 143         PROJECTILE_TOUCH(this, toucher);
 144         this.use(this, NULL, NULL);
 145 }
 146
 147 void W_Hook_Attack2(Weapon thiswep, entity actor, .entity weaponentity)
 148 {
 149         //W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(hook, ammo)); // WEAPONTODO: Figure out how to handle ammo with hook secondary (gravitybomb)
 150         W_SetupShot(actor, weaponentity, false, 4, SND_HOOKBOMB_FIRE, CH_WEAPON_A, WEP_CVAR_SEC(hook, damage));
 151
 152         entity gren = new(hookbomb);
 153         gren.owner = gren.realowner = actor;
 154         gren.bot_dodge = true;
 155         gren.bot_dodgerating = WEP_CVAR_SEC(hook, damage);
 156         set_movetype(gren, MOVETYPE_TOSS);
 157         PROJECTILE_MAKETRIGGER(gren);
 158         gren.projectiledeathtype = WEP_HOOK.m_id | HITTYPE_SECONDARY;
 159         setorigin(gren, w_shotorg);
 160         setsize(gren, '0 0 0', '0 0 0');
 161
 162         gren.nextthink = time + WEP_CVAR_SEC(hook, lifetime);
 163         setthink(gren, adaptor_think2use_hittype_splash);
 164         gren.use = W_Hook_Explode2_use;
 165         settouch(gren, W_Hook_Touch2);
 166
 167         gren.takedamage = DAMAGE_YES;
 168         gren.health = WEP_CVAR_SEC(hook, health);
 169         gren.damageforcescale = WEP_CVAR_SEC(hook, damageforcescale);
 170         gren.event_damage = W_Hook_Damage;
 171         gren.damagedbycontents = true;
 172         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 173
 174         gren.velocity = '0 0 1' * WEP_CVAR_SEC(hook, speed);
 175         if (autocvar_g_projectiles_newton_style)
 176                 gren.velocity = gren.velocity + actor.velocity;
 177
 178         gren.gravity = WEP_CVAR_SEC(hook, gravity);
 179         //W_SetupProjVelocity_Basic(gren); // just falling down!
 180
 181         gren.angles = '0 0 0';
 182         gren.flags = FL_PROJECTILE;
 183         IL_PUSH(g_projectiles, gren);
 184
 185         CSQCProjectile(gren, true, PROJECTILE_HOOKBOMB, true);
 186
 187         MUTATOR_CALLHOOK(EditProjectile, actor, gren);
 188 }
 189
 190 METHOD(Hook, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 191 {
 192     if (fire & 1) {
 193         if(!actor.hook)
 194         if(!(actor.hook_state & HOOK_WAITING_FOR_RELEASE))
 195         if(time > actor.hook_refire)
 196         if(weapon_prepareattack(thiswep, actor, weaponentity, false, -1))
 197         {
 198             W_DecreaseAmmo(thiswep, actor, thiswep.ammo_factor * WEP_CVAR_PRI(hook, ammo));
 199             actor.hook_state |= HOOK_FIRING;
 200             actor.hook_state |= HOOK_WAITING_FOR_RELEASE;
 201             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(hook, animtime), w_ready);
 202         }
 203     } else {
 204         actor.hook_state |= HOOK_REMOVING;
 205         actor.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 206     }
 207
 208     if(fire & 2)
 209     {
 210         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(hook, refire)))
 211         {
 212             W_Hook_Attack2(thiswep, actor, weaponentity);
 213             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(hook, animtime), w_ready);
 214         }
 215     }
 216
 217     if(actor.hook)
 218     {
 219         // if hooked, no bombs, and increase the timer
 220         actor.hook_refire = max(actor.hook_refire, time + WEP_CVAR_PRI(hook, refire) * W_WeaponRateFactor(actor));
 221
 222         // hook also inhibits health regeneration, but only for 1 second
 223         if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 224             actor.pauseregen_finished = max(actor.pauseregen_finished, time + autocvar_g_balance_pause_fuel_regen);
 225     }
 226
 227     if(actor.hook && actor.hook.state == 1)
 228     {
 229         float hooked_time_max = WEP_CVAR_PRI(hook, hooked_time_max);
 230         if(hooked_time_max > 0)
 231         {
 232             if( time > actor.hook_time_hooked + hooked_time_max )
 233                 actor.hook_state |= HOOK_REMOVING;
 234         }
 235
 236         float hooked_fuel = thiswep.ammo_factor * WEP_CVAR_PRI(hook, hooked_ammo);
 237         if(hooked_fuel > 0)
 238         {
 239             if( time > actor.hook_time_fueldecrease )
 240             {
 241                 if(!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 242                 {
 243                     if( actor.ammo_fuel >= (time - actor.hook_time_fueldecrease) * hooked_fuel )
 244                     {
 245                         W_DecreaseAmmo(thiswep, actor, (time - actor.hook_time_fueldecrease) * hooked_fuel);
 246                         actor.hook_time_fueldecrease = time;
 247                         // decrease next frame again
 248                     }
 249                     else
 250                     {
 251                         actor.ammo_fuel = 0;
 252                         actor.hook_state |= HOOK_REMOVING;
 253                         W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
 254                     }
 255                 }
 256             }
 257         }
 258     }
 259     else
 260     {
 261         actor.hook_time_hooked = time;
 262         actor.hook_time_fueldecrease = time + WEP_CVAR_PRI(hook, hooked_time_free);
 263     }
 264
 265     actor.hook_state = BITSET(actor.hook_state, HOOK_PULLING, (!PHYS_INPUT_BUTTON_CROUCH(actor) || !autocvar_g_balance_grapplehook_crouchslide));
 266
 267     if (actor.hook_state & HOOK_FIRING)
 268     {
 269         if (actor.hook)
 270             RemoveGrapplingHook(actor);
 271         FireGrapplingHook(actor);
 272         actor.hook_state &= ~HOOK_FIRING;
 273         actor.hook_refire = max(actor.hook_refire, time + autocvar_g_balance_grapplehook_refire * W_WeaponRateFactor(actor));
 274     }
 275     else if (actor.hook_state & HOOK_REMOVING)
 276     {
 277         if (actor.hook)
 278             RemoveGrapplingHook(actor);
 279         actor.hook_state &= ~HOOK_REMOVING;
 280     }
 281 }
 282 METHOD(Hook, wr_setup, void(entity thiswep, entity actor))
 283 {
 284     actor.hook_state &= ~HOOK_WAITING_FOR_RELEASE;
 285 }
 286 METHOD(Hook, wr_checkammo1, bool(Hook thiswep, entity actor))
 287 {
 288     if (!thiswep.ammo_factor) return true;
 289     if(actor.hook)
 290         return actor.ammo_fuel > 0;
 291     else
 292         return actor.ammo_fuel >= WEP_CVAR_PRI(hook, ammo);
 293 }
 294 METHOD(Hook, wr_checkammo2, bool(Hook thiswep, entity actor))
 295 {
 296     // infinite ammo for now
 297     return true; // actor.ammo_cells >= WEP_CVAR_SEC(hook, ammo); // WEAPONTODO: see above
 298 }
 299 METHOD(Hook, wr_resetplayer, void(entity thiswep, entity actor))
 300 {
 301     RemoveGrapplingHook(actor);
 302     actor.hook_time = 0;
 303     actor.hook_refire = time;
 304 }
 305 METHOD(Hook, wr_killmessage, Notification(entity thiswep))
 306 {
 307     return WEAPON_HOOK_MURDER;
 308 }
 309
 310 #endif
 311 #ifdef CSQC
 312
 313 METHOD(Hook, wr_impacteffect, void(entity thiswep, entity actor))
 314 {
 315     vector org2;
 316     org2 = w_org + w_backoff * 2;
 317     pointparticles(EFFECT_HOOK_EXPLODE, org2, '0 0 0', 1);
 318     if(!w_issilent)
 319         sound(actor, CH_SHOTS, SND_HOOKBOMB_IMPACT, VOL_BASE, ATTN_NORM);
 320 }
 321
 322 #endif
 323
 324 #ifdef CSQC
 325 #include <lib/csqcmodel/interpolate.qh>
 326 #include <lib/warpzone/common.qh>
 327
 328 float autocvar_cl_grapplehook_alpha = 1;
 329
 330 void Draw_CylindricLine(vector from, vector to, float thickness, string texture, float aspect, float shift, vector rgb, float theAlpha, float drawflag, vector vieworg);
 331
 332 entityclass(Hook);
 333 class(Hook) .entity HookType; // ENT_CLIENT_*
 334 class(Hook) .vector origin;
 335 class(Hook) .vector velocity;
 336 class(Hook) .float HookSilent;
 337 class(Hook) .float HookRange;
 338
 339 string Draw_GrapplingHook_trace_callback_tex;
 340 float Draw_GrapplingHook_trace_callback_rnd;
 341 vector Draw_GrapplingHook_trace_callback_rgb;
 342 float Draw_GrapplingHook_trace_callback_a;
 343 void Draw_GrapplingHook_trace_callback(vector start, vector hit, vector end)
 344 {
 345         float i;
 346         vector vorg;
 347         vorg = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
 348         for(i = 0; i < Draw_GrapplingHook_trace_callback_a; ++i)
 349                 Draw_CylindricLine(hit, start, 8, Draw_GrapplingHook_trace_callback_tex, 0.25, Draw_GrapplingHook_trace_callback_rnd, Draw_GrapplingHook_trace_callback_rgb, min(1, Draw_GrapplingHook_trace_callback_a - i), DRAWFLAG_NORMAL, vorg);
 350         Draw_GrapplingHook_trace_callback_rnd += 0.25 * vlen(hit - start) / 8;
 351 }
 352
 353 class(Hook) .float teleport_time;
 354 void Draw_GrapplingHook(entity this)
 355 {
 356         vector a, b, atrans;
 357         string tex;
 358         vector rgb;
 359         float t;
 360         vector vs;
 361         float intensity, offset;
 362
 363         if(this.teleport_time)
 364         if(time > this.teleport_time)
 365         {
 366                 sound (this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM); // safeguard
 367                 this.teleport_time = 0;
 368         }
 369
 370         InterpolateOrigin_Do(this);
 371
 372         int s = W_GetGunAlignment(NULL);
 373
 374         switch(this.HookType)
 375         {
 376                 default:
 377                 case NET_ENT_CLIENT_HOOK:
 378                         vs = hook_shotorigin[s];
 379                         break;
 380                 case NET_ENT_CLIENT_ARC_BEAM:
 381                         vs = lightning_shotorigin[s];
 382                         break;
 383         }
 384
 385         if((this.owner.sv_entnum == player_localentnum - 1) && autocvar_chase_active <= 0)
 386         {
 387                 switch(this.HookType)
 388                 {
 389                         default:
 390                         case NET_ENT_CLIENT_HOOK:
 391                                 a = view_origin + view_forward * vs.x + view_right * -vs.y + view_up * vs.z;
 392                                 b = this.origin;
 393                                 break;
 394                         case NET_ENT_CLIENT_ARC_BEAM:
 395                                 if(this.HookRange)
 396                                         b = view_origin + view_forward * this.HookRange;
 397                                 else
 398                                         b = view_origin + view_forward * vlen(this.velocity - this.origin); // honor original length of beam!
 399                                 WarpZone_TraceLine(view_origin, b, MOVE_NORMAL, NULL);
 400                                 b = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
 401                                 a = view_origin + view_forward * vs.x + view_right * -vs.y + view_up * vs.z;
 402                                 break;
 403                 }
 404         }
 405         else
 406         {
 407                 switch(this.HookType)
 408                 {
 409                         default:
 410                         case NET_ENT_CLIENT_HOOK:
 411                                 a = this.velocity;
 412                                 b = this.origin;
 413                                 break;
 414                         case NET_ENT_CLIENT_ARC_BEAM:
 415                                 a = this.origin;
 416                                 b = this.velocity;
 417                                 break;
 418                 }
 419         }
 420
 421         t = entcs_GetTeamColor(this.owner.sv_entnum);
 422
 423         switch(this.HookType)
 424         {
 425                 default:
 426                 case NET_ENT_CLIENT_HOOK:
 427                         intensity = autocvar_cl_grapplehook_alpha;
 428                         offset = 0;
 429                         switch(t)
 430                         {
 431                                 case NUM_TEAM_1: tex = "particles/hook_red"; rgb = '1 0.3 0.3'; break;
 432                                 case NUM_TEAM_2: tex = "particles/hook_blue"; rgb = '0.3 0.3 1'; break;
 433                                 case NUM_TEAM_3: tex = "particles/hook_yellow"; rgb = '1 1 0.3'; break;
 434                                 case NUM_TEAM_4: tex = "particles/hook_pink"; rgb = '1 0.3 1'; break;
 435                                 default: tex = "particles/hook_white"; rgb = entcs_GetColor(this.sv_entnum - 1); break;
 436                         }
 437                         break;
 438                 case NET_ENT_CLIENT_ARC_BEAM: // todo
 439                         intensity = bound(0.2, 1 + Noise_Pink(this, frametime) * 1 + Noise_Burst(this, frametime, 0.03) * 0.3, 2);
 440                         offset = Noise_Brown(this, frametime) * 10;
 441                         tex = "particles/lgbeam";
 442                         rgb = '1 1 1';
 443                         break;
 444         }
 445
 446         MUTATOR_CALLHOOK(DrawGrapplingHook, this, tex, rgb, t);
 447         tex = M_ARGV(1, string);
 448         rgb = M_ARGV(2, vector);
 449
 450         Draw_GrapplingHook_trace_callback_tex = tex;
 451         Draw_GrapplingHook_trace_callback_rnd = offset;
 452         Draw_GrapplingHook_trace_callback_rgb = rgb;
 453         Draw_GrapplingHook_trace_callback_a = intensity;
 454         WarpZone_TraceBox_ThroughZone(a, '0 0 0', '0 0 0', b, ((this.HookType == NET_ENT_CLIENT_HOOK) ? MOVE_NOTHING : MOVE_NORMAL), NULL, NULL, Draw_GrapplingHook_trace_callback);
 455         Draw_GrapplingHook_trace_callback_tex = string_null;
 456
 457         atrans = WarpZone_TransformOrigin(WarpZone_trace_transform, a);
 458
 459         switch(this.HookType)
 460         {
 461                 default:
 462                 case NET_ENT_CLIENT_HOOK:
 463                         if(vdist(trace_endpos - atrans, >, 0.5))
 464                         {
 465                                 setorigin(this, trace_endpos); // hook endpoint!
 466                                 this.angles = vectoangles(trace_endpos - atrans);
 467                                 this.drawmask = MASK_NORMAL;
 468                         }
 469                         else
 470                         {
 471                                 this.drawmask = 0;
 472                         }
 473                         break;
 474                 case NET_ENT_CLIENT_ARC_BEAM:
 475                         setorigin(this, a); // beam origin!
 476                         break;
 477         }
 478
 479         switch(this.HookType)
 480         {
 481                 default:
 482                 case NET_ENT_CLIENT_HOOK:
 483                         break;
 484                 case NET_ENT_CLIENT_ARC_BEAM:
 485                         pointparticles(EFFECT_ARC_LIGHTNING2, trace_endpos, normalize(atrans - trace_endpos), frametime * intensity); // todo: new effect
 486                         break;
 487         }
 488 }
 489
 490 void Remove_GrapplingHook(entity this)
 491 {
 492         sound (this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 493
 494         if(csqcplayer && csqcplayer.hook == this)
 495                 csqcplayer.hook = NULL;
 496 }
 497
 498 NET_HANDLE(ENT_CLIENT_HOOK, bool bIsNew)
 499 {
 500         this.HookType = NET_ENT_CLIENT_HOOK;
 501
 502         int sf = ReadByte();
 503
 504         this.HookSilent = (sf & 0x80);
 505         this.iflags = IFLAG_VELOCITY | IFLAG_ORIGIN;
 506
 507         InterpolateOrigin_Undo(this);
 508
 509         if(sf & 1)
 510         {
 511                 int myowner = ReadByte();
 512                 this.owner = playerslots[myowner - 1];
 513                 this.sv_entnum = myowner;
 514                 if(csqcplayer && myowner == player_localentnum)
 515                         csqcplayer.hook = this;
 516                 switch(this.HookType)
 517                 {
 518                         default:
 519                         case NET_ENT_CLIENT_HOOK:
 520                                 this.HookRange = 0;
 521                                 break;
 522                         case NET_ENT_CLIENT_ARC_BEAM:
 523                                 this.HookRange = ReadCoord();
 524                                 break;
 525                 }
 526         }
 527         if(sf & 2)
 528         {
 529                 this.origin_x = ReadCoord();
 530                 this.origin_y = ReadCoord();
 531                 this.origin_z = ReadCoord();
 532                 setorigin(this, this.origin);
 533         }
 534         if(sf & 4)
 535         {
 536                 this.velocity_x = ReadCoord();
 537                 this.velocity_y = ReadCoord();
 538                 this.velocity_z = ReadCoord();
 539         }
 540
 541         InterpolateOrigin_Note(this);
 542
 543         if(bIsNew || !this.teleport_time)
 544         {
 545                 this.draw = Draw_GrapplingHook;
 546                 IL_PUSH(g_drawables, this);
 547                 this.entremove = Remove_GrapplingHook;
 548
 549                 switch(this.HookType)
 550                 {
 551                         default:
 552                         case NET_ENT_CLIENT_HOOK:
 553                                 // for the model
 554                                 setmodel(this, MDL_HOOK);
 555                                 this.drawmask = MASK_NORMAL;
 556                                 break;
 557                         case NET_ENT_CLIENT_ARC_BEAM:
 558                                 sound (this, CH_SHOTS_SINGLE, SND_LGBEAM_FLY, VOL_BASE, ATTEN_NORM);
 559                                 break;
 560                 }
 561         }
 562
 563         this.teleport_time = time + 10;
 564         return true;
 565 }
 566
 567 // TODO: hook: temporarily transform this.origin for drawing the model along warpzones!
 568 #endif
 569
 570 #endif