qcsrc/common/weapons/weapon/seeker.qc

   1 #include "seeker.qh"
   2
   3 #ifdef SVQC
   4
   5 // ============================
   6 // Begin: Missile functions, these are general functions to be manipulated by other code
   7 // ============================
   8 void W_Seeker_Missile_Explode(entity this, entity directhitentity)
   9 {
  10         this.event_damage = func_null;
  11         RadiusDamage(this, this.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), NULL, NULL, WEP_CVAR(seeker, missile_force), this.projectiledeathtype, directhitentity);
  12
  13         delete(this);
  14 }
  15
  16 void W_Seeker_Missile_Explode_think(entity this)
  17 {
  18         W_Seeker_Missile_Explode(this, NULL);
  19 }
  20
  21 void W_Seeker_Missile_Touch(entity this, entity toucher)
  22 {
  23         PROJECTILE_TOUCH(this, toucher);
  24
  25         W_Seeker_Missile_Explode(this, toucher);
  26 }
  27
  28 void W_Seeker_Missile_Think(entity this)
  29 {
  30         entity e;
  31         vector desireddir, olddir, newdir, eorg;
  32         float turnrate;
  33         float dist;
  34         float spd;
  35
  36         if(time > this.cnt)
  37         {
  38                 this.projectiledeathtype |= HITTYPE_SPLASH;
  39                 W_Seeker_Missile_Explode(this, NULL);
  40         }
  41
  42         spd = vlen(this.velocity);
  43         spd = bound(
  44                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
  45                 WEP_CVAR(seeker, missile_speed_max),
  46                 spd + WEP_CVAR(seeker, missile_accel) * frametime
  47         );
  48
  49         if(this.enemy != NULL)
  50                 if(this.enemy.takedamage != DAMAGE_AIM || IS_DEAD(this.enemy))
  51                         this.enemy = NULL;
  52
  53         if(this.enemy != NULL)
  54         {
  55                 e               = this.enemy;
  56                 eorg            = 0.5 * (e.absmin + e.absmax);
  57                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
  58                 desireddir      = normalize(eorg - this.origin);
  59                 olddir          = normalize(this.velocity); // get my current direction
  60                 dist            = vlen(eorg - this.origin);
  61
  62                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
  63                 if(WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
  64                 {
  65                         // Is it a better idea (shorter distance) to trace to the target itself?
  66                         if( vdist(this.origin + olddir * this.wait, <, dist))
  67                                 traceline(this.origin, this.origin + olddir * this.wait, false, this);
  68                         else
  69                                 traceline(this.origin, eorg, false, this);
  70
  71                         // Setup adaptive tracelength
  72                         this.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(this.origin - trace_endpos), this.wait = WEP_CVAR(seeker, missile_smart_trace_max));
  73
  74                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
  75                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
  76                 }
  77
  78                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
  79                 this.velocity = newdir * spd; // make me fly in the new direction at my flight speed
  80         }
  81         else
  82                 dist = 0;
  83
  84         // Proxy
  85         if(WEP_CVAR(seeker, missile_proxy))
  86         {
  87                 if(dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
  88                 {
  89                         if(this.autoswitch == 0)
  90                         {
  91                                 this.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
  92                         }
  93                         else
  94                         {
  95                                 if(this.autoswitch <= time)
  96                                 {
  97                                         W_Seeker_Missile_Explode(this, NULL);
  98                                         this.autoswitch = 0;
  99                                 }
 100                         }
 101                 }
 102                 else
 103                 {
 104                         if(this.autoswitch != 0)
 105                                 this.autoswitch = 0;
 106                 }
 107         }
 108         ///////////////
 109
 110         if(IS_DEAD(this.enemy))
 111         {
 112                 this.enemy = NULL;
 113                 this.cnt = time + 1 + (random() * 4);
 114                 this.nextthink = this.cnt;
 115                 return;
 116         }
 117
 118         //this.angles = vectoangles(this.velocity);                     // turn model in the new flight direction
 119         this.nextthink = time;// + 0.05; // csqc projectiles
 120         UpdateCSQCProjectile(this);
 121 }
 122
 123
 124
 125 void W_Seeker_Missile_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 126 {
 127         if(this.health <= 0)
 128                 return;
 129
 130         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 131                 return; // g_projectiles_damage says to halt
 132
 133         if(this.realowner == attacker)
 134                 this.health = this.health - (damage * 0.25);
 135         else
 136                 this.health = this.health - damage;
 137
 138         if(this.health <= 0)
 139                 W_PrepareExplosionByDamage(this, attacker, W_Seeker_Missile_Explode_think);
 140 }
 141
 142 /*
 143 void W_Seeker_Missile_Animate(entity this)
 144 {
 145         this.frame = this.frame +1;
 146         this.nextthink = time + 0.05;
 147
 148         if(this.enemy != NULL)
 149                 if(this.enemy.takedamage != DAMAGE_AIM || IS_DEAD(this.enemy))
 150                         this.enemy = NULL;
 151
 152         if(this.frame == 5)
 153         {
 154                 this.think           = W_Seeker_Missile_Think;
 155                 this.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 156
 157                 if(autocvar_g_balance_seeker_missile_proxy)
 158                         this.move_movetype    = MOVETYPE_BOUNCEMISSILE;
 159                 else
 160                         this.move_movetype    = MOVETYPE_FLYMISSILE;
 161         }
 162
 163         UpdateCSQCProjectile(this);
 164 }
 165 */
 166
 167 void W_Seeker_Fire_Missile(Weapon thiswep, entity actor, .entity weaponentity, vector f_diff, entity m_target)
 168 {
 169         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, missile_ammo), weaponentity);
 170
 171         makevectors(actor.v_angle);
 172         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_SEEKER_FIRE, CH_WEAPON_A, 0);
 173         w_shotorg += f_diff;
 174         Send_Effect(EFFECT_SEEKER_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 175
 176         //actor.detornator         = false;
 177
 178         entity missile                 = new(seeker_missile);
 179         missile.owner           = missile.realowner = actor;
 180         missile.bot_dodge       = true;
 181         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 182
 183         setthink(missile, W_Seeker_Missile_Think);
 184         settouch(missile, W_Seeker_Missile_Touch);
 185         missile.event_damage    = W_Seeker_Missile_Damage;
 186         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 187         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 188         missile.enemy           = m_target;
 189         missile.solid           = SOLID_BBOX;
 190         missile.scale           = 2;
 191         missile.takedamage      = DAMAGE_YES;
 192         missile.health          = WEP_CVAR(seeker, missile_health);
 193         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 194         missile.damagedbycontents = true;
 195         IL_PUSH(g_damagedbycontents, missile);
 196         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 197
 198         if(missile.enemy != NULL)
 199                 missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 200         else
 201                 missile.projectiledeathtype = WEP_SEEKER.m_id;
 202
 203
 204         setorigin(missile, w_shotorg);
 205         setsize(missile, '-4 -4 -4', '4 4 4');
 206         set_movetype(missile, MOVETYPE_FLYMISSILE);
 207         missile.flags = FL_PROJECTILE;
 208         IL_PUSH(g_projectiles, missile);
 209         IL_PUSH(g_bot_dodge, missile);
 210         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 211
 212         W_SetupProjVelocity_UP_PRE(missile, seeker, missile_);
 213
 214         missile.angles = vectoangles(missile.velocity);
 215
 216         CSQCProjectile(missile, false, PROJECTILE_SEEKER, true);
 217
 218         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 219 }
 220
 221 // ============================
 222 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 223 // ============================
 224 void W_Seeker_Flac_Explode(entity this, entity directhitentity)
 225 {
 226         this.event_damage = func_null;
 227
 228         RadiusDamage(this, this.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), NULL, NULL, WEP_CVAR(seeker, flac_force), this.projectiledeathtype, directhitentity);
 229
 230         delete(this);
 231 }
 232
 233 void W_Seeker_Flac_Touch(entity this, entity toucher)
 234 {
 235         W_Seeker_Flac_Explode(this, toucher);
 236 }
 237
 238 void W_Seeker_Flac_Explode_use(entity this, entity actor, entity trigger)
 239 {
 240         W_Seeker_Flac_Explode(this, trigger);
 241 }
 242
 243 void W_Seeker_Fire_Flac(Weapon thiswep, entity actor, .entity weaponentity)
 244 {
 245         entity missile;
 246         vector f_diff;
 247         float c;
 248
 249         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, flac_ammo), weaponentity);
 250
 251         c = actor.(weaponentity).bulletcounter % 4;
 252         switch(c)
 253         {
 254                 case 0:
 255                         f_diff = '-1.25 -3.75 0';
 256                         break;
 257                 case 1:
 258                         f_diff = '+1.25 -3.75 0';
 259                         break;
 260                 case 2:
 261                         f_diff = '-1.25 +3.75 0';
 262                         break;
 263                 case 3:
 264                 default:
 265                         f_diff = '+1.25 +3.75 0';
 266                         break;
 267         }
 268         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_FLAC_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 269         w_shotorg += f_diff;
 270
 271         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 272
 273         missile                                 = new(missile);
 274         missile.owner                   = missile.realowner = actor;
 275         missile.bot_dodge               = true;
 276         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 277         settouch(missile, W_Seeker_Flac_Touch);
 278         missile.use                     = W_Seeker_Flac_Explode_use;
 279         setthink(missile, adaptor_think2use_hittype_splash);
 280         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 281         missile.solid                   = SOLID_BBOX;
 282         set_movetype(missile, MOVETYPE_FLY);
 283         missile.projectiledeathtype = WEP_SEEKER.m_id;
 284         missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 285         missile.flags = FL_PROJECTILE;
 286         IL_PUSH(g_projectiles, missile);
 287         IL_PUSH(g_bot_dodge, missile);
 288         missile.missile_flags       = MIF_SPLASH;
 289
 290         // csqc projectiles
 291         //missile.angles                                = vectoangles(missile.velocity);
 292         //missile.scale = 0.4; // BUG: the model is too big
 293
 294         setorigin(missile, w_shotorg);
 295         setsize(missile, '-2 -2 -2', '2 2 2');
 296
 297         W_SetupProjVelocity_UP_PRE(missile, seeker, flac_);
 298         CSQCProjectile(missile, true, PROJECTILE_FLAC, true);
 299
 300         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 301 }
 302
 303 // ============================
 304 // Begin: Tag and rocket controllers
 305 // ============================
 306 entity W_Seeker_Tagged_Info(entity isowner, .entity weaponentity, entity istarget)
 307 {
 308         IL_EACH(g_seeker_trackers, it.classname == "tag_tracker" && it.realowner == isowner,
 309         {
 310                 if(it.tag_target == istarget && it.weaponentity_fld == weaponentity)
 311                         return it;
 312         });
 313
 314         return NULL;
 315 }
 316
 317 void W_Seeker_Attack(entity actor, .entity weaponentity)
 318 {
 319         entity closest_target = NULL;
 320
 321         IL_EACH(g_seeker_trackers, it.classname == "tag_tracker" && it.realowner == actor,
 322         {
 323                 if(closest_target)
 324                 {
 325                         if(vlen2(actor.origin - it.tag_target.origin) < vlen2(actor.origin - closest_target.origin))
 326                                 closest_target = it.tag_target;
 327                 }
 328                 else
 329                         closest_target = it.tag_target;
 330         });
 331
 332         if(closest_target)
 333         {
 334                 traceline(actor.origin + actor.view_ofs, closest_target.origin, MOVE_NOMONSTERS, actor);
 335                 if(!closest_target || (trace_fraction < 1 && trace_ent != closest_target))
 336                         closest_target = NULL;
 337         }
 338
 339         W_Seeker_Fire_Missile(WEP_SEEKER, actor, weaponentity, '0 0 0', closest_target);
 340 }
 341
 342 void W_Seeker_Vollycontroller_Think(entity this) // TODO: Merge this with W_Seeker_Attack
 343 {
 344         float c;
 345         entity oldenemy;
 346         this.cnt = this.cnt - 1;
 347
 348         Weapon thiswep = WEP_SEEKER;
 349         .entity weaponentity = this.weaponentity_fld;
 350         if((!(this.realowner.items & IT_UNLIMITED_AMMO) && GetResourceAmount(this.realowner, thiswep.ammo_type) < WEP_CVAR(seeker, missile_ammo)) || (this.cnt <= -1) || (IS_DEAD(this.realowner)) || (this.realowner.(weaponentity).m_switchweapon != WEP_SEEKER))
 351         {
 352                 delete(this);
 353                 return;
 354         }
 355
 356         this.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor(this.realowner);
 357
 358         entity own = this.realowner;
 359
 360         oldenemy = own.enemy;
 361         own.enemy = this.enemy;
 362
 363         c = own.cnt % 4;
 364         switch(c)
 365         {
 366                 case 0:
 367                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '-1.25 -3.75 0', own.enemy); // TODO
 368                         break;
 369                 case 1:
 370                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '+1.25 -3.75 0', own.enemy); // TODO
 371                         break;
 372                 case 2:
 373                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '-1.25 +3.75 0', own.enemy); // TODO
 374                         break;
 375                 case 3:
 376                 default:
 377                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '+1.25 +3.75 0', own.enemy); // TODO
 378                         break;
 379         }
 380
 381         own.enemy = oldenemy;
 382 }
 383
 384 void W_Seeker_Tracker_Think(entity this)
 385 {
 386         .entity weaponentity = this.weaponentity_fld;
 387         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 388         if((IS_DEAD(this.realowner)) || (IS_DEAD(this.tag_target)) || (this.realowner.(weaponentity).m_switchweapon != WEP_SEEKER)
 389         || (time > this.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 390         {
 391                 if(this)
 392                 {
 393                         WaypointSprite_Kill(this.tag_target.wps_tag_tracker);
 394                         delete(this);
 395                 }
 396                 return;
 397         }
 398
 399         // Update the think method information
 400         this.nextthink = time;
 401 }
 402
 403 // ============================
 404 // Begin: Tag projectile
 405 // ============================
 406 void W_Seeker_Tag_Explode(entity this)
 407 {
 408         //if(other==this.realowner)
 409         //    return;
 410         Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE, 0, this);
 411
 412         delete(this);
 413 }
 414
 415 void W_Seeker_Tag_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 416 {
 417         if(this.health <= 0)
 418                 return;
 419         this.health = this.health - damage;
 420         if(this.health <= 0)
 421                 W_Seeker_Tag_Explode(this);
 422 }
 423
 424 void W_Seeker_Tag_Touch(entity this, entity toucher)
 425 {
 426         vector dir;
 427         vector org2;
 428         entity e;
 429
 430         PROJECTILE_TOUCH(this, toucher);
 431
 432         dir     = normalize(this.realowner.origin - this.origin);
 433         org2    = findbetterlocation(this.origin, 8);
 434
 435         te_knightspike(org2);
 436
 437         this.event_damage = func_null;
 438         Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE | HITTYPE_SECONDARY, toucher.species, this);
 439
 440         if(toucher.takedamage == DAMAGE_AIM && !IS_DEAD(toucher))
 441         {
 442                 // check to see if this person is already tagged by me
 443                 .entity weaponentity = this.weaponentity_fld;
 444                 entity tag = W_Seeker_Tagged_Info(this.realowner, weaponentity, toucher);
 445
 446                 if(tag != NULL)
 447                 {
 448                         if(toucher.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 449                                 WaypointSprite_Kill(toucher.wps_tag_tracker);
 450
 451                         tag.tag_time = time;
 452                 }
 453                 else
 454                 {
 455                         //sprint(this.realowner, strcat("You just tagged ^2", toucher.netname, "^7 with a tracking device!\n"));
 456                         e             = new(tag_tracker);
 457                         e.weaponentity_fld = this.weaponentity_fld;
 458                         e.cnt         = WEP_CVAR(seeker, missile_count);
 459                         e.owner       = this.owner;
 460                         e.realowner   = this.realowner;
 461                         IL_PUSH(g_seeker_trackers, e);
 462
 463                         if(WEP_CVAR(seeker, type) == 1)
 464                         {
 465                                 e.tag_target  = toucher;
 466                                 e.tag_time    = time;
 467                                 setthink(e, W_Seeker_Tracker_Think);
 468                         }
 469                         else
 470                         {
 471                                 e.enemy     = toucher;
 472                                 setthink(e, W_Seeker_Vollycontroller_Think);
 473                         }
 474
 475                         e.nextthink   = time;
 476                 }
 477
 478                 if(WEP_CVAR(seeker, type) == 1)
 479                 {
 480                         WaypointSprite_Spawn(WP_Seeker, WEP_CVAR(seeker, tag_tracker_lifetime), 0, toucher, '0 0 64', this.realowner, 0, toucher, wps_tag_tracker, true, RADARICON_TAGGED);
 481                         WaypointSprite_UpdateRule(toucher.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 482                 }
 483         }
 484
 485         delete(this);
 486         return;
 487 }
 488
 489 void W_Seeker_Fire_Tag(Weapon thiswep, entity actor, .entity weaponentity)
 490 {
 491         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, tag_ammo), weaponentity);
 492
 493         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_TAG_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 494
 495         entity missile          = new(seeker_tag);
 496         missile.weaponentity_fld = weaponentity;
 497         missile.owner           = missile.realowner = actor;
 498         missile.bot_dodge       = true;
 499         missile.bot_dodgerating = 50;
 500         settouch(missile, W_Seeker_Tag_Touch);
 501         setthink(missile, SUB_Remove);
 502         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 503         set_movetype(missile, MOVETYPE_FLY);
 504         missile.solid           = SOLID_BBOX;
 505
 506         missile.takedamage       = DAMAGE_YES;
 507         missile.event_damage     = W_Seeker_Tag_Damage;
 508         missile.health           = WEP_CVAR(seeker, tag_health);
 509         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 510
 511         setorigin(missile, w_shotorg);
 512         setsize(missile, '-2 -2 -2', '2 2 2');
 513
 514         missile.flags = FL_PROJECTILE;
 515         IL_PUSH(g_projectiles, missile);
 516         IL_PUSH(g_bot_dodge, missile);
 517         //missile.missile_flags = MIF_..?;
 518
 519         set_movetype(missile, MOVETYPE_FLY);
 520         W_SetupProjVelocity_PRE(missile, seeker, tag_);
 521         missile.angles = vectoangles(missile.velocity);
 522
 523         CSQCProjectile(missile, true, PROJECTILE_TAG, false); // has sound
 524
 525         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 526 }
 527
 528 // ============================
 529 // Begin: Genereal weapon functions
 530 // ============================
 531
 532 METHOD(Seeker, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 533 {
 534     if(WEP_CVAR(seeker, type) == 1)
 535         if(W_Seeker_Tagged_Info(actor, weaponentity, actor.enemy) != NULL)
 536             PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), false);
 537         else
 538             PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 539     else
 540         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 541 }
 542 METHOD(Seeker, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 543 {
 544     if(autocvar_g_balance_seeker_reload_ammo && actor.(weaponentity).clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) { // forced reload
 545         thiswep.wr_reload(thiswep, actor, weaponentity);
 546     } else if(fire & 1)
 547     {
 548         if(WEP_CVAR(seeker, type) == 1)
 549         {
 550             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, missile_refire)))
 551             {
 552                 W_Seeker_Attack(actor, weaponentity);
 553                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 554             }
 555         }
 556         else
 557         {
 558             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 559             {
 560                 W_Seeker_Fire_Tag(thiswep, actor, weaponentity);
 561                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 562             }
 563         }
 564     }
 565
 566     else if(fire & 2)
 567     {
 568         if(WEP_CVAR(seeker, type) == 1)
 569         {
 570             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 571             {
 572                 W_Seeker_Fire_Tag(thiswep, actor, weaponentity);
 573                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 574             }
 575         }
 576         else
 577         {
 578             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, flac_refire)))
 579             {
 580                 W_Seeker_Fire_Flac(thiswep, actor, weaponentity);
 581                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 582             }
 583         }
 584     }
 585 }
 586 METHOD(Seeker, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 587 {
 588     float ammo_amount;
 589     if(WEP_CVAR(seeker, type) == 1)
 590     {
 591         ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(seeker, missile_ammo);
 592         ammo_amount += actor.(weaponentity).(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, missile_ammo);
 593     }
 594     else
 595     {
 596         ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(seeker, tag_ammo);
 597         ammo_amount += actor.(weaponentity).(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 598     }
 599     return ammo_amount;
 600 }
 601 METHOD(Seeker, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 602 {
 603     float ammo_amount;
 604     if(WEP_CVAR(seeker, type) == 1)
 605     {
 606         ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(seeker, tag_ammo);
 607         ammo_amount += actor.(weaponentity).(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 608     }
 609     else
 610     {
 611         ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(seeker, flac_ammo);
 612         ammo_amount += actor.(weaponentity).(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, flac_ammo);
 613     }
 614     return ammo_amount;
 615 }
 616 METHOD(Seeker, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 617 {
 618     W_Reload(actor, weaponentity, min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), SND_RELOAD);
 619 }
 620 METHOD(Seeker, wr_suicidemessage, Notification(entity thiswep))
 621 {
 622     return WEAPON_SEEKER_SUICIDE;
 623 }
 624 METHOD(Seeker, wr_killmessage, Notification(entity thiswep))
 625 {
 626     if(w_deathtype & HITTYPE_SECONDARY)
 627         return WEAPON_SEEKER_MURDER_TAG;
 628     else
 629         return WEAPON_SEEKER_MURDER_SPRAY;
 630 }
 631
 632 #endif
 633 #ifdef CSQC
 634
 635 METHOD(Seeker, wr_impacteffect, void(entity thiswep, entity actor))
 636 {
 637     vector org2;
 638     org2 = w_org + w_backoff * 6;
 639     if(w_deathtype & HITTYPE_BOUNCE)
 640     {
 641         if(w_deathtype & HITTYPE_SECONDARY)
 642         {
 643             if(!w_issilent)
 644                 sound(actor, CH_SHOTS, SND_TAG_IMPACT, 1, ATTEN_NORM);
 645         }
 646         else
 647         {
 648             pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 649             if(!w_issilent)
 650             {
 651                 if(w_random<0.15)
 652                     sound(actor, CH_SHOTS, SND_TAGEXP1, 1, ATTEN_NORM);
 653                 else if(w_random<0.7)
 654                     sound(actor, CH_SHOTS, SND_TAGEXP2, 1, ATTEN_NORM);
 655                 else
 656                     sound(actor, CH_SHOTS, SND_TAGEXP3, 1, ATTEN_NORM);
 657             }
 658         }
 659     }
 660     else
 661     {
 662         pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 663         if(!w_issilent)
 664         {
 665             if(w_random<0.15)
 666                 sound(actor, CH_SHOTS, SND_SEEKEREXP1, 1, ATTEN_NORM);
 667             else if(w_random<0.7)
 668                 sound(actor, CH_SHOTS, SND_SEEKEREXP2, 1, ATTEN_NORM);
 669             else
 670                 sound(actor, CH_SHOTS, SND_SEEKEREXP3, 1, ATTEN_NORM);
 671         }
 672     }
 673 }
 674
 675 #endif