qcsrc/common/weapons/weapon/seeker.qc

   1 #include "seeker.qh"
   2 #ifndef IMPLEMENTATION
   3 CLASS(Seeker, Weapon)
   4 /* ammotype  */ ATTRIB(Seeker, ammo_field, .int, ammo_rockets);
   5 /* impulse   */ ATTRIB(Seeker, impulse, int, 8);
   6 /* flags     */ ATTRIB(Seeker, spawnflags, int, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH);
   7 /* rating    */ ATTRIB(Seeker, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   8 /* color     */ ATTRIB(Seeker, wpcolor, vector, '0.5 1 0');
   9 /* modelname */ ATTRIB(Seeker, mdl, string, "seeker");
  10 #ifdef GAMEQC
  11 /* model     */ ATTRIB(Seeker, m_model, Model, MDL_SEEKER_ITEM);
  12 #endif
  13 /* crosshair */ ATTRIB(Seeker, w_crosshair, string, "gfx/crosshairseeker");
  14 /* crosshair */ ATTRIB(Seeker, w_crosshair_size, float, 0.8);
  15 /* wepimg    */ ATTRIB(Seeker, model2, string, "weaponseeker");
  16 /* refname   */ ATTRIB(Seeker, netname, string, "seeker");
  17 /* wepname   */ ATTRIB(Seeker, m_name, string, _("T.A.G. Seeker"));
  18
  19 #define X(BEGIN, P, END, class, prefix) \
  20         BEGIN(class) \
  21         P(class, prefix, flac_ammo, float, NONE) \
  22         P(class, prefix, flac_animtime, float, NONE) \
  23         P(class, prefix, flac_damage, float, NONE) \
  24         P(class, prefix, flac_edgedamage, float, NONE) \
  25         P(class, prefix, flac_force, float, NONE) \
  26         P(class, prefix, flac_lifetime, float, NONE) \
  27         P(class, prefix, flac_lifetime_rand, float, NONE) \
  28         P(class, prefix, flac_radius, float, NONE) \
  29         P(class, prefix, flac_refire, float, NONE) \
  30         P(class, prefix, flac_speed, float, NONE) \
  31         P(class, prefix, flac_speed_up, float, NONE) \
  32         P(class, prefix, flac_speed_z, float, NONE) \
  33         P(class, prefix, flac_spread, float, NONE) \
  34         P(class, prefix, missile_accel, float, NONE) \
  35         P(class, prefix, missile_ammo, float, NONE) \
  36         P(class, prefix, missile_animtime, float, NONE) \
  37         P(class, prefix, missile_count, float, NONE) \
  38         P(class, prefix, missile_damageforcescale, float, NONE) \
  39         P(class, prefix, missile_damage, float, NONE) \
  40         P(class, prefix, missile_decel, float, NONE) \
  41         P(class, prefix, missile_delay, float, NONE) \
  42         P(class, prefix, missile_edgedamage, float, NONE) \
  43         P(class, prefix, missile_force, float, NONE) \
  44         P(class, prefix, missile_health, float, NONE) \
  45         P(class, prefix, missile_lifetime, float, NONE) \
  46         P(class, prefix, missile_proxy, float, NONE) \
  47         P(class, prefix, missile_proxy_delay, float, NONE) \
  48         P(class, prefix, missile_proxy_maxrange, float, NONE) \
  49         P(class, prefix, missile_radius, float, NONE) \
  50         P(class, prefix, missile_refire, float, NONE) \
  51         P(class, prefix, missile_smart, float, NONE) \
  52         P(class, prefix, missile_smart_mindist, float, NONE) \
  53         P(class, prefix, missile_smart_trace_max, float, NONE) \
  54         P(class, prefix, missile_smart_trace_min, float, NONE) \
  55         P(class, prefix, missile_speed, float, NONE) \
  56         P(class, prefix, missile_speed_max, float, NONE) \
  57         P(class, prefix, missile_speed_up, float, NONE) \
  58         P(class, prefix, missile_speed_z, float, NONE) \
  59         P(class, prefix, missile_spread, float, NONE) \
  60         P(class, prefix, missile_turnrate, float, NONE) \
  61         P(class, prefix, reload_ammo, float, NONE) \
  62                 P(class, prefix, reload_time, float, NONE) \
  63                 P(class, prefix, switchdelay_drop, float, NONE) \
  64                 P(class, prefix, switchdelay_raise, float, NONE) \
  65         P(class, prefix, tag_ammo, float, NONE) \
  66         P(class, prefix, tag_animtime, float, NONE) \
  67         P(class, prefix, tag_damageforcescale, float, NONE) \
  68         P(class, prefix, tag_health, float, NONE) \
  69         P(class, prefix, tag_lifetime, float, NONE) \
  70         P(class, prefix, tag_refire, float, NONE) \
  71         P(class, prefix, tag_speed, float, NONE) \
  72         P(class, prefix, tag_spread, float, NONE) \
  73         P(class, prefix, tag_tracker_lifetime, float, NONE) \
  74                 P(class, prefix, type, float, NONE) \
  75                 P(class, prefix, weaponreplace, string, NONE) \
  76                 P(class, prefix, weaponstartoverride, float, NONE) \
  77                 P(class, prefix, weaponstart, float, NONE) \
  78                 P(class, prefix, weaponthrowable, float, NONE) \
  79         END()
  80         W_PROPS(X, Seeker, seeker)
  81 #undef X
  82 ENDCLASS(Seeker)
  83 REGISTER_WEAPON(SEEKER, seeker, NEW(Seeker));
  84
  85
  86 #ifdef SVQC
  87 .entity tag_target, wps_tag_tracker;
  88 .float tag_time;
  89 #endif
  90 #endif
  91 #ifdef IMPLEMENTATION
  92 #ifdef SVQC
  93 spawnfunc(weapon_seeker) { weapon_defaultspawnfunc(this, WEP_SEEKER); }
  94
  95 // ============================
  96 // Begin: Missile functions, these are general functions to be manipulated by other code
  97 // ============================
  98 void W_Seeker_Missile_Explode(entity this, entity directhitentity)
  99 {
 100         this.event_damage = func_null;
 101         RadiusDamage(this, this.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), NULL, NULL, WEP_CVAR(seeker, missile_force), this.projectiledeathtype, directhitentity);
 102
 103         delete(this);
 104 }
 105
 106 void W_Seeker_Missile_Explode_think(entity this)
 107 {
 108         W_Seeker_Missile_Explode(this, NULL);
 109 }
 110
 111 void W_Seeker_Missile_Touch(entity this, entity toucher)
 112 {
 113         PROJECTILE_TOUCH(this, toucher);
 114
 115         W_Seeker_Missile_Explode(this, toucher);
 116 }
 117
 118 void W_Seeker_Missile_Think(entity this)
 119 {
 120         entity e;
 121         vector desireddir, olddir, newdir, eorg;
 122         float turnrate;
 123         float dist;
 124         float spd;
 125
 126         if(time > this.cnt)
 127         {
 128                 this.projectiledeathtype |= HITTYPE_SPLASH;
 129                 W_Seeker_Missile_Explode(this, NULL);
 130         }
 131
 132         spd = vlen(this.velocity);
 133         spd = bound(
 134                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 135                 WEP_CVAR(seeker, missile_speed_max),
 136                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 137         );
 138
 139         if(this.enemy != NULL)
 140                 if(this.enemy.takedamage != DAMAGE_AIM || IS_DEAD(this.enemy))
 141                         this.enemy = NULL;
 142
 143         if(this.enemy != NULL)
 144         {
 145                 e               = this.enemy;
 146                 eorg            = 0.5 * (e.absmin + e.absmax);
 147                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 148                 desireddir      = normalize(eorg - this.origin);
 149                 olddir          = normalize(this.velocity); // get my current direction
 150                 dist            = vlen(eorg - this.origin);
 151
 152                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 153                 if(WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 154                 {
 155                         // Is it a better idea (shorter distance) to trace to the target itthis?
 156                         if( vdist(this.origin + olddir * this.wait, <, dist))
 157                                 traceline(this.origin, this.origin + olddir * this.wait, false, this);
 158                         else
 159                                 traceline(this.origin, eorg, false, this);
 160
 161                         // Setup adaptive tracelength
 162                         this.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(this.origin - trace_endpos), this.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 163
 164                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 165                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 166                 }
 167
 168                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 169                 this.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 170         }
 171         else
 172                 dist = 0;
 173
 174         // Proxy
 175         if(WEP_CVAR(seeker, missile_proxy))
 176         {
 177                 if(dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 178                 {
 179                         if(this.autoswitch == 0)
 180                         {
 181                                 this.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 182                         }
 183                         else
 184                         {
 185                                 if(this.autoswitch <= time)
 186                                 {
 187                                         W_Seeker_Missile_Explode(this, NULL);
 188                                         this.autoswitch = 0;
 189                                 }
 190                         }
 191                 }
 192                 else
 193                 {
 194                         if(this.autoswitch != 0)
 195                                 this.autoswitch = 0;
 196                 }
 197         }
 198         ///////////////
 199
 200         if(IS_DEAD(this.enemy))
 201         {
 202                 this.enemy = NULL;
 203                 this.cnt = time + 1 + (random() * 4);
 204                 this.nextthink = this.cnt;
 205                 return;
 206         }
 207
 208         //this.angles = vectoangles(this.velocity);                     // turn model in the new flight direction
 209         this.nextthink = time;// + 0.05; // csqc projectiles
 210         UpdateCSQCProjectile(this);
 211 }
 212
 213
 214
 215 void W_Seeker_Missile_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 216 {
 217         if(this.health <= 0)
 218                 return;
 219
 220         if(!W_CheckProjectileDamage(inflictor.realowner, this.realowner, deathtype, -1)) // no exceptions
 221                 return; // g_projectiles_damage says to halt
 222
 223         if(this.realowner == attacker)
 224                 this.health = this.health - (damage * 0.25);
 225         else
 226                 this.health = this.health - damage;
 227
 228         if(this.health <= 0)
 229                 W_PrepareExplosionByDamage(this, attacker, W_Seeker_Missile_Explode_think);
 230 }
 231
 232 /*
 233 void W_Seeker_Missile_Animate(entity this)
 234 {
 235         this.frame = this.frame +1;
 236         this.nextthink = time + 0.05;
 237
 238         if(this.enemy != NULL)
 239                 if(this.enemy.takedamage != DAMAGE_AIM || IS_DEAD(this.enemy))
 240                         this.enemy = NULL;
 241
 242         if(this.frame == 5)
 243         {
 244                 this.think           = W_Seeker_Missile_Think;
 245                 this.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 246
 247                 if(autocvar_g_balance_seeker_missile_proxy)
 248                         this.move_movetype    = MOVETYPE_BOUNCEMISSILE;
 249                 else
 250                         this.move_movetype    = MOVETYPE_FLYMISSILE;
 251         }
 252
 253         UpdateCSQCProjectile(this);
 254 }
 255 */
 256
 257 void W_Seeker_Fire_Missile(Weapon thiswep, entity actor, .entity weaponentity, vector f_diff, entity m_target)
 258 {
 259         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, missile_ammo));
 260
 261         makevectors(actor.v_angle);
 262         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_SEEKER_FIRE, CH_WEAPON_A, 0);
 263         w_shotorg += f_diff;
 264         Send_Effect(EFFECT_SEEKER_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 265
 266         //actor.detornator         = false;
 267
 268         entity missile                 = new(seeker_missile);
 269         missile.owner           = missile.realowner = actor;
 270         missile.bot_dodge       = true;
 271         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 272
 273         setthink(missile, W_Seeker_Missile_Think);
 274         settouch(missile, W_Seeker_Missile_Touch);
 275         missile.event_damage    = W_Seeker_Missile_Damage;
 276         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 277         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 278         missile.enemy           = m_target;
 279         missile.solid           = SOLID_BBOX;
 280         missile.scale           = 2;
 281         missile.takedamage      = DAMAGE_YES;
 282         missile.health          = WEP_CVAR(seeker, missile_health);
 283         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 284         missile.damagedbycontents = true;
 285         IL_PUSH(g_damagedbycontents, missile);
 286         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 287
 288         if(missile.enemy != NULL)
 289                 missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 290         else
 291                 missile.projectiledeathtype = WEP_SEEKER.m_id;
 292
 293
 294         setorigin(missile, w_shotorg);
 295         setsize(missile, '-4 -4 -4', '4 4 4');
 296         set_movetype(missile, MOVETYPE_FLYMISSILE);
 297         missile.flags = FL_PROJECTILE;
 298         IL_PUSH(g_projectiles, missile);
 299         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 300
 301         W_SetupProjVelocity_UP_PRE(missile, seeker, missile_);
 302
 303         missile.angles = vectoangles(missile.velocity);
 304
 305         CSQCProjectile(missile, false, PROJECTILE_SEEKER, true);
 306
 307         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 308 }
 309
 310 // ============================
 311 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 312 // ============================
 313 void W_Seeker_Flac_Explode(entity this, entity directhitentity)
 314 {
 315         this.event_damage = func_null;
 316
 317         RadiusDamage(this, this.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), NULL, NULL, WEP_CVAR(seeker, flac_force), this.projectiledeathtype, directhitentity);
 318
 319         delete(this);
 320 }
 321
 322 void W_Seeker_Flac_Touch(entity this, entity toucher)
 323 {
 324         W_Seeker_Flac_Explode(this, toucher);
 325 }
 326
 327 void W_Seeker_Flac_Explode_use(entity this, entity actor, entity trigger)
 328 {
 329         W_Seeker_Flac_Explode(this, trigger);
 330 }
 331
 332 void W_Seeker_Fire_Flac(Weapon thiswep, entity actor, .entity weaponentity)
 333 {
 334         entity missile;
 335         vector f_diff;
 336         float c;
 337
 338         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, flac_ammo));
 339
 340         c = actor.bulletcounter % 4;
 341         switch(c)
 342         {
 343                 case 0:
 344                         f_diff = '-1.25 -3.75 0';
 345                         break;
 346                 case 1:
 347                         f_diff = '+1.25 -3.75 0';
 348                         break;
 349                 case 2:
 350                         f_diff = '-1.25 +3.75 0';
 351                         break;
 352                 case 3:
 353                 default:
 354                         f_diff = '+1.25 +3.75 0';
 355                         break;
 356         }
 357         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_FLAC_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 358         w_shotorg += f_diff;
 359
 360         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 361
 362         missile                                 = new(missile);
 363         missile.owner                   = missile.realowner = actor;
 364         missile.bot_dodge               = true;
 365         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 366         settouch(missile, W_Seeker_Flac_Touch);
 367         missile.use                     = W_Seeker_Flac_Explode_use;
 368         setthink(missile, adaptor_think2use_hittype_splash);
 369         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 370         missile.solid                   = SOLID_BBOX;
 371         set_movetype(missile, MOVETYPE_FLY);
 372         missile.projectiledeathtype = WEP_SEEKER.m_id;
 373         missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 374         missile.flags = FL_PROJECTILE;
 375         IL_PUSH(g_projectiles, missile);
 376         missile.missile_flags       = MIF_SPLASH;
 377
 378         // csqc projectiles
 379         //missile.angles                                = vectoangles(missile.velocity);
 380         //missile.scale = 0.4; // BUG: the model is too big
 381
 382         setorigin(missile, w_shotorg);
 383         setsize(missile, '-2 -2 -2', '2 2 2');
 384
 385         W_SetupProjVelocity_UP_PRE(missile, seeker, flac_);
 386         CSQCProjectile(missile, true, PROJECTILE_FLAC, true);
 387
 388         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 389 }
 390
 391 // ============================
 392 // Begin: Tag and rocket controllers
 393 // ============================
 394 entity W_Seeker_Tagged_Info(entity isowner, entity istarget)
 395 {
 396         entity tag;
 397         for(tag = NULL; (tag = find(tag, classname, "tag_tracker")); )
 398                 if((tag.realowner == isowner) && (tag.tag_target == istarget))
 399                         return tag;
 400
 401         return NULL;
 402 }
 403
 404 void W_Seeker_Attack(entity actor, .entity weaponentity)
 405 {
 406         entity tracker, closest_target;
 407
 408         closest_target = NULL;
 409         for(tracker = NULL; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == actor)
 410         {
 411                 if(closest_target)
 412                 {
 413                         if(vlen2(actor.origin - tracker.tag_target.origin) < vlen2(actor.origin - closest_target.origin))
 414                                 closest_target = tracker.tag_target;
 415                 }
 416                 else
 417                         closest_target = tracker.tag_target;
 418         }
 419
 420         traceline(actor.origin + actor.view_ofs, closest_target.origin, MOVE_NOMONSTERS, actor);
 421         if((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 422                 closest_target = NULL;
 423
 424         W_Seeker_Fire_Missile(WEP_SEEKER, actor, weaponentity, '0 0 0', closest_target);
 425 }
 426
 427 void W_Seeker_Vollycontroller_Think(entity this) // TODO: Merge this with W_Seeker_Attack
 428 {
 429         float c;
 430         entity oldenemy;
 431         this.cnt = this.cnt - 1;
 432
 433         Weapon thiswep = WEP_SEEKER;
 434         if((!(this.realowner.items & IT_UNLIMITED_AMMO) && this.realowner.(thiswep.ammo_field) < WEP_CVAR(seeker, missile_ammo)) || (this.cnt <= -1) || (IS_DEAD(this.realowner)) || (PS(this.realowner).m_switchweapon != WEP_SEEKER))
 435         {
 436                 delete(this);
 437                 return;
 438         }
 439
 440         this.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor(this.realowner);
 441
 442         entity own = this.realowner;
 443
 444         oldenemy = own.enemy;
 445         own.enemy = this.enemy;
 446         .entity weaponentity = this.weaponentity_fld;
 447
 448         c = own.cnt % 4;
 449         switch(c)
 450         {
 451                 case 0:
 452                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '-1.25 -3.75 0', own.enemy); // TODO
 453                         break;
 454                 case 1:
 455                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '+1.25 -3.75 0', own.enemy); // TODO
 456                         break;
 457                 case 2:
 458                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '-1.25 +3.75 0', own.enemy); // TODO
 459                         break;
 460                 case 3:
 461                 default:
 462                         W_Seeker_Fire_Missile(WEP_SEEKER, own, weaponentity, '+1.25 +3.75 0', own.enemy); // TODO
 463                         break;
 464         }
 465
 466         own.enemy = oldenemy;
 467 }
 468
 469 void W_Seeker_Tracker_Think(entity this)
 470 {
 471         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 472         if((IS_DEAD(this.realowner)) || (IS_DEAD(this.tag_target)) || (PS(this.realowner).m_switchweapon != WEP_SEEKER)
 473         || (time > this.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 474         {
 475                 if(this)
 476                 {
 477                         WaypointSprite_Kill(this.tag_target.wps_tag_tracker);
 478                         delete(this);
 479                 }
 480                 return;
 481         }
 482
 483         // Update the think method information
 484         this.nextthink = time;
 485 }
 486
 487 // ============================
 488 // Begin: Tag projectile
 489 // ============================
 490 void W_Seeker_Tag_Explode(entity this)
 491 {
 492         //if(other==this.realowner)
 493         //    return;
 494         Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE, 0, this);
 495
 496         delete(this);
 497 }
 498
 499 void W_Seeker_Tag_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 500 {
 501         if(this.health <= 0)
 502                 return;
 503         this.health = this.health - damage;
 504         if(this.health <= 0)
 505                 W_Seeker_Tag_Explode(this);
 506 }
 507
 508 void W_Seeker_Tag_Touch(entity this, entity toucher)
 509 {
 510         vector dir;
 511         vector org2;
 512         entity e;
 513
 514         PROJECTILE_TOUCH(this, toucher);
 515
 516         dir     = normalize(this.realowner.origin - this.origin);
 517         org2    = findbetterlocation(this.origin, 8);
 518
 519         te_knightspike(org2);
 520
 521         this.event_damage = func_null;
 522         Damage_DamageInfo(this.origin, 0, 0, 0, this.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE | HITTYPE_SECONDARY, toucher.species, this);
 523
 524         if(toucher.takedamage == DAMAGE_AIM && !IS_DEAD(toucher))
 525         {
 526                 // check to see if this person is already tagged by me
 527                 entity tag = W_Seeker_Tagged_Info(this.realowner, toucher);
 528
 529                 if(tag != NULL)
 530                 {
 531                         if(toucher.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 532                                 WaypointSprite_Kill(toucher.wps_tag_tracker);
 533
 534                         tag.tag_time = time;
 535                 }
 536                 else
 537                 {
 538                         //sprint(this.realowner, strcat("You just tagged ^2", toucher.netname, "^7 with a tracking device!\n"));
 539                         e             = new(tag_tracker);
 540                         e.weaponentity_fld = this.weaponentity_fld;
 541                         e.cnt         = WEP_CVAR(seeker, missile_count);
 542                         e.owner       = this.owner;
 543                         e.realowner   = this.realowner;
 544
 545                         if(WEP_CVAR(seeker, type) == 1)
 546                         {
 547                                 e.tag_target  = toucher;
 548                                 e.tag_time    = time;
 549                                 setthink(e, W_Seeker_Tracker_Think);
 550                         }
 551                         else
 552                         {
 553                                 e.enemy     = toucher;
 554                                 setthink(e, W_Seeker_Vollycontroller_Think);
 555                         }
 556
 557                         e.nextthink   = time;
 558                 }
 559
 560                 if(WEP_CVAR(seeker, type) == 1)
 561                 {
 562                         WaypointSprite_Spawn(WP_Seeker, WEP_CVAR(seeker, tag_tracker_lifetime), 0, toucher, '0 0 64', this.realowner, 0, toucher, wps_tag_tracker, true, RADARICON_TAGGED);
 563                         WaypointSprite_UpdateRule(toucher.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 564                 }
 565         }
 566
 567         delete(this);
 568         return;
 569 }
 570
 571 void W_Seeker_Fire_Tag(Weapon thiswep, entity actor, .entity weaponentity)
 572 {
 573         W_DecreaseAmmo(thiswep, actor, WEP_CVAR(seeker, tag_ammo));
 574
 575         W_SetupShot_ProjectileSize(actor, weaponentity, '-2 -2 -2', '2 2 2', false, 2, SND_TAG_FIRE, CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 576
 577         entity missile          = new(seeker_tag);
 578         missile.weaponentity_fld = weaponentity;
 579         missile.owner           = missile.realowner = actor;
 580         missile.bot_dodge       = true;
 581         missile.bot_dodgerating = 50;
 582         settouch(missile, W_Seeker_Tag_Touch);
 583         setthink(missile, SUB_Remove);
 584         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 585         set_movetype(missile, MOVETYPE_FLY);
 586         missile.solid           = SOLID_BBOX;
 587
 588         missile.takedamage       = DAMAGE_YES;
 589         missile.event_damage     = W_Seeker_Tag_Damage;
 590         missile.health           = WEP_CVAR(seeker, tag_health);
 591         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 592
 593         setorigin(missile, w_shotorg);
 594         setsize(missile, '-2 -2 -2', '2 2 2');
 595
 596         missile.flags = FL_PROJECTILE;
 597         IL_PUSH(g_projectiles, missile);
 598         //missile.missile_flags = MIF_..?;
 599
 600         set_movetype(missile, MOVETYPE_FLY);
 601         W_SetupProjVelocity_PRE(missile, seeker, tag_);
 602         missile.angles = vectoangles(missile.velocity);
 603
 604         CSQCProjectile(missile, true, PROJECTILE_TAG, false); // has sound
 605
 606         MUTATOR_CALLHOOK(EditProjectile, actor, missile);
 607 }
 608
 609 // ============================
 610 // Begin: Genereal weapon functions
 611 // ============================
 612
 613 METHOD(Seeker, wr_aim, void(entity thiswep, entity actor))
 614 {
 615     if(WEP_CVAR(seeker, type) == 1)
 616         if(W_Seeker_Tagged_Info(actor, actor.enemy) != NULL)
 617             PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), false);
 618         else
 619             PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 620     else
 621         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 622 }
 623 METHOD(Seeker, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 624 {
 625     if(autocvar_g_balance_seeker_reload_ammo && actor.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) { // forced reload
 626         thiswep.wr_reload(thiswep, actor, weaponentity);
 627     } else if(fire & 1)
 628     {
 629         if(WEP_CVAR(seeker, type) == 1)
 630         {
 631             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, missile_refire)))
 632             {
 633                 W_Seeker_Attack(actor, weaponentity);
 634                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 635             }
 636         }
 637         else
 638         {
 639             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 640             {
 641                 W_Seeker_Fire_Tag(thiswep, actor, weaponentity);
 642                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 643             }
 644         }
 645     }
 646
 647     else if(fire & 2)
 648     {
 649         if(WEP_CVAR(seeker, type) == 1)
 650         {
 651             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, tag_refire)))
 652             {
 653                 W_Seeker_Fire_Tag(thiswep, actor, weaponentity);
 654                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 655             }
 656         }
 657         else
 658         {
 659             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(seeker, flac_refire)))
 660             {
 661                 W_Seeker_Fire_Flac(thiswep, actor, weaponentity);
 662                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 663             }
 664         }
 665     }
 666 }
 667 METHOD(Seeker, wr_checkammo1, bool(entity thiswep, entity actor))
 668 {
 669     float ammo_amount;
 670     if(WEP_CVAR(seeker, type) == 1)
 671     {
 672         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, missile_ammo);
 673         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, missile_ammo);
 674     }
 675     else
 676     {
 677         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, tag_ammo);
 678         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 679     }
 680     return ammo_amount;
 681 }
 682 METHOD(Seeker, wr_checkammo2, bool(entity thiswep, entity actor))
 683 {
 684     float ammo_amount;
 685     if(WEP_CVAR(seeker, type) == 1)
 686     {
 687         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, tag_ammo);
 688         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 689     }
 690     else
 691     {
 692         ammo_amount = actor.(thiswep.ammo_field) >= WEP_CVAR(seeker, flac_ammo);
 693         ammo_amount += actor.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, flac_ammo);
 694     }
 695     return ammo_amount;
 696 }
 697 METHOD(Seeker, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 698 {
 699     W_Reload(actor, weaponentity, min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), SND_RELOAD);
 700 }
 701 METHOD(Seeker, wr_suicidemessage, Notification(entity thiswep))
 702 {
 703     return WEAPON_SEEKER_SUICIDE;
 704 }
 705 METHOD(Seeker, wr_killmessage, Notification(entity thiswep))
 706 {
 707     if(w_deathtype & HITTYPE_SECONDARY)
 708         return WEAPON_SEEKER_MURDER_TAG;
 709     else
 710         return WEAPON_SEEKER_MURDER_SPRAY;
 711 }
 712
 713 #endif
 714 #ifdef CSQC
 715
 716 METHOD(Seeker, wr_impacteffect, void(entity thiswep, entity actor))
 717 {
 718     vector org2;
 719     org2 = w_org + w_backoff * 6;
 720     if(w_deathtype & HITTYPE_BOUNCE)
 721     {
 722         if(w_deathtype & HITTYPE_SECONDARY)
 723         {
 724             if(!w_issilent)
 725                 sound(actor, CH_SHOTS, SND_TAG_IMPACT, 1, ATTEN_NORM);
 726         }
 727         else
 728         {
 729             pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 730             if(!w_issilent)
 731             {
 732                 if(w_random<0.15)
 733                     sound(actor, CH_SHOTS, SND_TAGEXP1, 1, ATTEN_NORM);
 734                 else if(w_random<0.7)
 735                     sound(actor, CH_SHOTS, SND_TAGEXP2, 1, ATTEN_NORM);
 736                 else
 737                     sound(actor, CH_SHOTS, SND_TAGEXP3, 1, ATTEN_NORM);
 738             }
 739         }
 740     }
 741     else
 742     {
 743         pointparticles(EFFECT_HAGAR_EXPLODE, org2, '0 0 0', 1);
 744         if(!w_issilent)
 745         {
 746             if(w_random<0.15)
 747                 sound(actor, CH_SHOTS, SND_SEEKEREXP1, 1, ATTEN_NORM);
 748             else if(w_random<0.7)
 749                 sound(actor, CH_SHOTS, SND_SEEKEREXP2, 1, ATTEN_NORM);
 750             else
 751                 sound(actor, CH_SHOTS, SND_SEEKEREXP3, 1, ATTEN_NORM);
 752         }
 753     }
 754 }
 755
 756 #endif
 757 #endif