qcsrc/common/weapons/weapon/shotgun.qc

   1 #include "shotgun.qh"
   2
   3 #ifdef SVQC
   4
   5 // enable to debug melee range
   6 //#define SHOTGUN_MELEEDEBUG
   7
   8 METHOD(Shotgun, m_spawnfunc_hookreplace, Weapon(Shotgun this, entity e))
   9 {
  10         if (autocvar_sv_q3acompat_machineshotgunswap && !Item_IsLoot(e))
  11         {
  12                 return WEP_MACHINEGUN;
  13         }
  14         return this;
  15 }
  16
  17 void W_Shotgun_Attack(Weapon thiswep, entity actor, .entity weaponentity, float isprimary, float ammocount, float damage, float bullets, float spread, float solidpenetration, float force, entity bullet_trail_effect)
  18 {
  19         W_DecreaseAmmo(thiswep, actor, ammocount, weaponentity);
  20
  21         W_SetupShot(actor, weaponentity, true, 5, SND_SHOTGUN_FIRE, ((isprimary) ? CH_WEAPON_A : CH_WEAPON_SINGLE), damage * bullets, thiswep.m_id);
  22
  23         // TRICK: do the antilag outside the regular fireBullet function, so it isn't performed unnecessarily on every single bullet!
  24         float lag = antilag_getlag(actor);
  25         if(lag && bullets > 0)
  26                 antilag_takeback_all(actor, lag);
  27
  28         for(int sc = 0;sc < bullets;sc = sc + 1)
  29                 fireBullet_antilag(actor, weaponentity, w_shotorg, w_shotdir, spread, solidpenetration, damage, force, thiswep.m_id, bullet_trail_effect, false);
  30
  31         if(lag && bullets > 0)
  32                 antilag_restore_all(actor);
  33
  34         W_MuzzleFlash(actor, weaponentity, EFFECT_SHOTGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000);
  35
  36         // casing code
  37         if(autocvar_g_casings >= 1)
  38         {
  39                 makevectors(actor.v_angle); // for some reason, this is lost
  40                 //for(int sc = 0;sc < WEP_CVAR_PRI(shotgun, ammo);sc = sc + 1)
  41                         SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, actor, weaponentity);
  42         }
  43
  44         // muzzle flash for 1st person view
  45         // TODO: handle on the client
  46         entity flash = spawn();
  47         setmodel(flash, MDL_SHOTGUN_MUZZLEFLASH); // precision set below
  48         setthink(flash, SUB_Remove);
  49         flash.nextthink = time + 0.06;
  50         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  51         W_AttachToShotorg(actor, weaponentity, flash, '5 0 0');
  52 }
  53
  54 .float swing_prev;
  55 .entity swing_alreadyhit;
  56 void W_Shotgun_Melee_Think(entity this)
  57 {
  58         // declarations
  59         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  60         entity target_victim;
  61         vector targpos;
  62
  63         if(!this.cnt) // set start time of melee
  64         {
  65                 this.cnt = time;
  66                 W_PlayStrengthSound(this.realowner);
  67         }
  68
  69         makevectors(this.realowner.v_angle); // update values for v_* vectors
  70
  71         // calculate swing percentage based on time
  72         meleetime = WEP_CVAR_SEC(shotgun, melee_time) * W_WeaponRateFactor(this.realowner);
  73         swing = bound(0, (this.cnt + meleetime - time) / meleetime, 10);
  74         f = ((1 - swing) * WEP_CVAR_SEC(shotgun, melee_traces));
  75
  76         // check to see if we can still continue, otherwise give up now
  77         if(IS_DEAD(this.realowner) && WEP_CVAR_SEC(shotgun, melee_no_doubleslap))
  78         {
  79                 delete(this);
  80                 return;
  81         }
  82
  83         // if okay, perform the traces needed for this frame
  84         for(i=this.swing_prev; i < f; ++i)
  85         {
  86                 swing_factor = ((1 - (i / WEP_CVAR_SEC(shotgun, melee_traces))) * 2 - 1);
  87
  88                 targpos = (this.realowner.origin + this.realowner.view_ofs
  89                         + (v_forward * WEP_CVAR_SEC(shotgun, melee_range))
  90                         + (v_up * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_up))
  91                         + (v_right * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_side)));
  92
  93                 WarpZone_traceline_antilag(this.realowner, this.realowner.origin + this.realowner.view_ofs, targpos, false, this.realowner, ((IS_CLIENT(this.realowner)) ? ANTILAG_LATENCY(this.realowner) : 0));
  94
  95                 // draw lightning beams for debugging
  96         #ifdef SHOTGUN_MELEEDEBUG
  97                 te_lightning2(NULL, targpos, this.realowner.origin + this.realowner.view_ofs + v_forward * 5 - v_up * 5);
  98                 te_customflash(targpos, 40,  2, '1 1 1');
  99         #endif
 100
 101                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
 102
 103                 if((trace_fraction < 1) // if trace is good, apply the damage and remove this
 104                         && (trace_ent.takedamage != DAMAGE_NO)
 105                         && (trace_ent != this.swing_alreadyhit)
 106                         && (is_player || WEP_CVAR_SEC(shotgun, melee_nonplayerdamage)))
 107                 {
 108                         target_victim = trace_ent; // so it persists through other calls
 109
 110                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 111                                 swing_damage = (WEP_CVAR_SEC(shotgun, damage) * min(1, swing_factor + 1));
 112                         else
 113                                 swing_damage = (WEP_CVAR_SEC(shotgun, melee_nonplayerdamage) * min(1, swing_factor + 1));
 114
 115                         //print(strcat(this.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
 116
 117                         Damage(target_victim, this.realowner, this.realowner,
 118                                 swing_damage, WEP_SHOTGUN.m_id | HITTYPE_SECONDARY, this.weaponentity_fld,
 119                                 this.realowner.origin + this.realowner.view_ofs,
 120                                 v_forward * WEP_CVAR_SEC(shotgun, force));
 121
 122                         if(accuracy_isgooddamage(this.realowner, target_victim)) { accuracy_add(this.realowner, WEP_SHOTGUN, 0, swing_damage); }
 123
 124                         // draw large red flash for debugging
 125                 #ifdef SHOTGUN_MELEEDEBUG
 126                         te_customflash(targpos, 200, 2, '15 0 0');
 127                 #endif
 128
 129                         if(WEP_CVAR_SEC(shotgun, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
 130                         {
 131                                 this.swing_alreadyhit = target_victim;
 132                                 continue; // move along to next trace
 133                         }
 134                         else
 135                         {
 136                                 delete(this);
 137                                 return;
 138                         }
 139                 }
 140         }
 141
 142         if(time >= this.cnt + meleetime)
 143         {
 144                 // melee is finished
 145                 delete(this);
 146                 return;
 147         }
 148         else
 149         {
 150                 // set up next frame
 151                 this.swing_prev = i;
 152                 this.nextthink = time;
 153         }
 154 }
 155
 156 void W_Shotgun_Attack2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 157 {
 158         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTEN_NORM);
 159         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(shotgun, animtime), w_ready);
 160
 161         entity meleetemp = new_pure(meleetemp);
 162         meleetemp.realowner = actor;
 163         setthink(meleetemp, W_Shotgun_Melee_Think);
 164         meleetemp.nextthink = time + WEP_CVAR_SEC(shotgun, melee_delay) * W_WeaponRateFactor(actor);
 165         meleetemp.weaponentity_fld = weaponentity;
 166         W_SetupShot_Range(actor, weaponentity, true, 0, SND_Null, 0, WEP_CVAR_SEC(shotgun, damage), WEP_CVAR_SEC(shotgun, melee_range), WEP_SHOTGUN.m_id | HITTYPE_SECONDARY);
 167 }
 168
 169 // alternate secondary weapon frames
 170 void W_Shotgun_Attack3_Frame2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 171 {
 172         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 173         if (!(actor.items & IT_UNLIMITED_AMMO))
 174         {
 175                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 176                 w_ready(thiswep, actor, weaponentity, fire);
 177                 return;
 178         }
 179
 180         sound(actor, CH_WEAPON_SINGLE, SND_Null, VOL_BASE, ATTN_NORM); // kill previous sound
 181         W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 182                 WEP_CVAR_PRI(shotgun, ammo),
 183                 WEP_CVAR_PRI(shotgun, damage),
 184                 WEP_CVAR_PRI(shotgun, bullets),
 185                 WEP_CVAR_PRI(shotgun, spread),
 186                 WEP_CVAR_PRI(shotgun, solidpenetration),
 187                 WEP_CVAR_PRI(shotgun, force),
 188                 EFFECT_BULLET_WEAK); // actually is secondary, but we trick the last shot into playing full reload sound
 189         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), w_ready);
 190 }
 191 void W_Shotgun_Attack3_Frame1(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 192 {
 193         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 194         if (!(actor.items & IT_UNLIMITED_AMMO))
 195         {
 196                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 197                 w_ready(thiswep, actor, weaponentity, fire);
 198                 return;
 199         }
 200
 201         W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 202                 WEP_CVAR_PRI(shotgun, ammo),
 203                 WEP_CVAR_PRI(shotgun, damage),
 204                 WEP_CVAR_PRI(shotgun, bullets),
 205                 WEP_CVAR_PRI(shotgun, spread),
 206                 WEP_CVAR_PRI(shotgun, solidpenetration),
 207                 WEP_CVAR_PRI(shotgun, force),
 208                 EFFECT_BULLET_WEAK);
 209         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame2);
 210 }
 211
 212 .float shotgun_primarytime;
 213
 214 METHOD(Shotgun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 215 {
 216     if(vdist(actor.origin - actor.enemy.origin, <=, WEP_CVAR_SEC(shotgun, melee_range)))
 217         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 218     else
 219         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 220 }
 221
 222 METHOD(Shotgun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 223 {
 224     if(WEP_CVAR(shotgun, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(shotgun, ammo)) // forced reload
 225     {
 226         // don't force reload an empty shotgun if its melee attack is active
 227         if(WEP_CVAR(shotgun, secondary) < 2) {
 228             thiswep.wr_reload(thiswep, actor, weaponentity);
 229         }
 230     }
 231     else
 232     {
 233         if(fire & 1)
 234         {
 235             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 236             {
 237                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(shotgun, animtime)))
 238                 {
 239                     W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 240                                                 WEP_CVAR_PRI(shotgun, ammo),
 241                                                 WEP_CVAR_PRI(shotgun, damage),
 242                                                 WEP_CVAR_PRI(shotgun, bullets),
 243                                                 WEP_CVAR_PRI(shotgun, spread),
 244                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 245                                                 WEP_CVAR_PRI(shotgun, force),
 246                                                 EFFECT_BULLET_WEAK);
 247                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_PRI(shotgun, refire) * W_WeaponRateFactor(actor);
 248                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(shotgun, animtime), w_ready);
 249                 }
 250             }
 251         }
 252         else if((fire & 2) && WEP_CVAR(shotgun, secondary) == 2)
 253         {
 254             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 255             {
 256                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(shotgun, alt_animtime)))
 257                 {
 258                     W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 259                                                 WEP_CVAR_PRI(shotgun, ammo),
 260                                                 WEP_CVAR_PRI(shotgun, damage),
 261                                                 WEP_CVAR_PRI(shotgun, bullets),
 262                                                 WEP_CVAR_PRI(shotgun, spread),
 263                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 264                                                 WEP_CVAR_PRI(shotgun, force),
 265                                                 EFFECT_BULLET_WEAK);
 266                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_SEC(shotgun, alt_refire) * W_WeaponRateFactor(actor);
 267                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame1);
 268                 }
 269             }
 270         }
 271     }
 272     if(actor.(weaponentity).clip_load >= 0) // we are not currently reloading
 273     if(WEP_CVAR(shotgun, secondary) == 1)
 274     if(((fire & 1) && GetResource(actor, thiswep.ammo_type) <= 0 && !(actor.items & IT_UNLIMITED_AMMO)) || (fire & 2))
 275     if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(shotgun, refire)))
 276     {
 277         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 278         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 279     }
 280 }
 281 METHOD(Shotgun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 282 {
 283     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 284     ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 285     return ammo_amount;
 286 }
 287 METHOD(Shotgun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 288 {
 289     if(IS_BOT_CLIENT(actor))
 290     if(vdist(actor.origin - actor.enemy.origin, >, WEP_CVAR_SEC(shotgun, melee_range)))
 291         return false; // bots cannot use secondary out of range (fixes constant melee when out of ammo)
 292     switch(WEP_CVAR(shotgun, secondary))
 293     {
 294         case 1: return true; // melee does not use ammo
 295         case 2: // secondary triple shot
 296         {
 297             float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 298             ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 299             return ammo_amount;
 300         }
 301         default: return false; // secondary unavailable
 302     }
 303 }
 304 METHOD(Shotgun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 305 {
 306     W_Reload(actor, weaponentity, WEP_CVAR_PRI(shotgun, ammo), SND_RELOAD); // WEAPONTODO
 307 }
 308 METHOD(Shotgun, wr_suicidemessage, Notification(entity thiswep))
 309 {
 310     return WEAPON_THINKING_WITH_PORTALS;
 311 }
 312 METHOD(Shotgun, wr_killmessage, Notification(entity thiswep))
 313 {
 314     if(w_deathtype & HITTYPE_SECONDARY)
 315         return WEAPON_SHOTGUN_MURDER_SLAP;
 316     else
 317         return WEAPON_SHOTGUN_MURDER;
 318 }
 319
 320 #endif
 321 #ifdef CSQC
 322 .float prevric;
 323
 324 METHOD(Shotgun, wr_impacteffect, void(entity thiswep, entity actor))
 325 {
 326     vector org2 = w_org + w_backoff * 2;
 327     pointparticles(EFFECT_SHOTGUN_IMPACT, org2, w_backoff * 1000, 1);
 328     if(!w_issilent && time - actor.prevric > 0.25)
 329     {
 330         if(w_random < 0.05)
 331             sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 332         actor.prevric = time;
 333     }
 334 }
 335
 336 #endif