qcsrc/common/weapons/weapon/shotgun.qc

   1 #include "shotgun.qh"
   2
   3 #ifdef SVQC
   4
   5 METHOD(Shotgun, m_spawnfunc_hookreplace, Weapon(Shotgun this, entity e))
   6 {
   7         if (autocvar_sv_q3acompat_machineshotgunswap && !Item_IsLoot(e))
   8         {
   9                 return WEP_MACHINEGUN;
  10         }
  11         return this;
  12 }
  13
  14 void W_Shotgun_Attack(Weapon thiswep, entity actor, .entity weaponentity, float isprimary, float ammocount, float damage, float bullets, float spread, float solidpenetration, float force, entity bullet_trail_effect)
  15 {
  16         W_DecreaseAmmo(thiswep, actor, ammocount, weaponentity);
  17
  18         W_SetupShot(actor, weaponentity, true, 5, SND_SHOTGUN_FIRE, ((isprimary) ? CH_WEAPON_A : CH_WEAPON_SINGLE), damage * bullets, thiswep.m_id);
  19
  20         // TRICK: do the antilag outside the regular fireBullet function, so it isn't performed unnecessarily on every single bullet!
  21         float lag = antilag_getlag(actor);
  22         if(lag && bullets > 0)
  23                 antilag_takeback_all(actor, lag);
  24
  25         for(int sc = 0;sc < bullets;sc = sc + 1)
  26                 fireBullet_antilag(actor, weaponentity, w_shotorg, w_shotdir, spread, solidpenetration, damage, force, thiswep.m_id, bullet_trail_effect, false);
  27
  28         if(lag && bullets > 0)
  29                 antilag_restore_all(actor);
  30
  31         Send_Effect(EFFECT_SHOTGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, ammocount);
  32
  33         // casing code
  34         if(autocvar_g_casings >= 1)
  35         {
  36                 makevectors(actor.v_angle); // for some reason, this is lost
  37                 //for(int sc = 0;sc < WEP_CVAR_PRI(shotgun, ammo);sc = sc + 1)
  38                         SpawnCasing(((random() * 50 + 50) * v_right) - (v_forward * (random() * 25 + 25)) - ((random() * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, actor, weaponentity);
  39         }
  40
  41         // muzzle flash for 1st person view
  42         entity flash = spawn();
  43         setmodel(flash, MDL_SHOTGUN_MUZZLEFLASH); // precision set below
  44         setthink(flash, SUB_Remove);
  45         flash.nextthink = time + 0.06;
  46         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  47         W_AttachToShotorg(actor, weaponentity, flash, '5 0 0');
  48 }
  49
  50 .float swing_prev;
  51 .entity swing_alreadyhit;
  52 void W_Shotgun_Melee_Think(entity this)
  53 {
  54         // declarations
  55         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  56         entity target_victim;
  57         vector targpos;
  58
  59         if(!this.cnt) // set start time of melee
  60         {
  61                 this.cnt = time;
  62                 W_PlayStrengthSound(this.realowner);
  63         }
  64
  65         makevectors(this.realowner.v_angle); // update values for v_* vectors
  66
  67         // calculate swing percentage based on time
  68         meleetime = WEP_CVAR_SEC(shotgun, melee_time) * W_WeaponRateFactor(this.realowner);
  69         swing = bound(0, (this.cnt + meleetime - time) / meleetime, 10);
  70         f = ((1 - swing) * WEP_CVAR_SEC(shotgun, melee_traces));
  71
  72         // check to see if we can still continue, otherwise give up now
  73         if(IS_DEAD(this.realowner) && WEP_CVAR_SEC(shotgun, melee_no_doubleslap))
  74         {
  75                 delete(this);
  76                 return;
  77         }
  78
  79         // if okay, perform the traces needed for this frame
  80         for(i=this.swing_prev; i < f; ++i)
  81         {
  82                 swing_factor = ((1 - (i / WEP_CVAR_SEC(shotgun, melee_traces))) * 2 - 1);
  83
  84                 targpos = (this.realowner.origin + this.realowner.view_ofs
  85                         + (v_forward * WEP_CVAR_SEC(shotgun, melee_range))
  86                         + (v_up * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_up))
  87                         + (v_right * swing_factor * WEP_CVAR_SEC(shotgun, melee_swing_side)));
  88
  89                 WarpZone_traceline_antilag(this.realowner, this.realowner.origin + this.realowner.view_ofs, targpos, false, this.realowner, ((IS_CLIENT(this.realowner)) ? ANTILAG_LATENCY(this.realowner) : 0));
  90
  91                 // draw lightning beams for debugging
  92                 //te_lightning2(NULL, targpos, this.realowner.origin + this.realowner.view_ofs + v_forward * 5 - v_up * 5);
  93                 //te_customflash(targpos, 40,  2, '1 1 1');
  94
  95                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
  96
  97                 if((trace_fraction < 1) // if trace is good, apply the damage and remove this
  98                         && (trace_ent.takedamage != DAMAGE_NO)
  99                         && (trace_ent != this.swing_alreadyhit)
 100                         && (is_player || WEP_CVAR_SEC(shotgun, melee_nonplayerdamage)))
 101                 {
 102                         target_victim = trace_ent; // so it persists through other calls
 103
 104                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
 105                                 swing_damage = (WEP_CVAR_SEC(shotgun, damage) * min(1, swing_factor + 1));
 106                         else
 107                                 swing_damage = (WEP_CVAR_SEC(shotgun, melee_nonplayerdamage) * min(1, swing_factor + 1));
 108
 109                         //print(strcat(this.realowner.netname, " hitting ", target_victim.netname, " with ", strcat(ftos(swing_damage), " damage (factor: ", ftos(swing_factor), ") at "), ftos(time), " seconds.\n"));
 110
 111                         Damage(target_victim, this.realowner, this.realowner,
 112                                 swing_damage, WEP_SHOTGUN.m_id | HITTYPE_SECONDARY, this.weaponentity_fld,
 113                                 this.realowner.origin + this.realowner.view_ofs,
 114                                 v_forward * WEP_CVAR_SEC(shotgun, force));
 115
 116                         if(accuracy_isgooddamage(this.realowner, target_victim)) { accuracy_add(this.realowner, WEP_SHOTGUN, 0, swing_damage); }
 117
 118                         // draw large red flash for debugging
 119                         //te_customflash(targpos, 200, 2, '15 0 0');
 120
 121                         if(WEP_CVAR_SEC(shotgun, melee_multihit)) // allow multiple hits with one swing, but not against the same player twice.
 122                         {
 123                                 this.swing_alreadyhit = target_victim;
 124                                 continue; // move along to next trace
 125                         }
 126                         else
 127                         {
 128                                 delete(this);
 129                                 return;
 130                         }
 131                 }
 132         }
 133
 134         if(time >= this.cnt + meleetime)
 135         {
 136                 // melee is finished
 137                 delete(this);
 138                 return;
 139         }
 140         else
 141         {
 142                 // set up next frame
 143                 this.swing_prev = i;
 144                 this.nextthink = time;
 145         }
 146 }
 147
 148 void W_Shotgun_Attack2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 149 {
 150         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTEN_NORM);
 151         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(shotgun, animtime), w_ready);
 152
 153         entity meleetemp = new_pure(meleetemp);
 154         meleetemp.realowner = actor;
 155         setthink(meleetemp, W_Shotgun_Melee_Think);
 156         meleetemp.nextthink = time + WEP_CVAR_SEC(shotgun, melee_delay) * W_WeaponRateFactor(actor);
 157         meleetemp.weaponentity_fld = weaponentity;
 158         W_SetupShot_Range(actor, weaponentity, true, 0, SND_Null, 0, WEP_CVAR_SEC(shotgun, damage), WEP_CVAR_SEC(shotgun, melee_range), WEP_SHOTGUN.m_id | HITTYPE_SECONDARY);
 159 }
 160
 161 // alternate secondary weapon frames
 162 void W_Shotgun_Attack3_Frame2(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 163 {
 164         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 165         if (!(actor.items & IT_UNLIMITED_AMMO))
 166         {
 167                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 168                 w_ready(thiswep, actor, weaponentity, fire);
 169                 return;
 170         }
 171
 172         sound(actor, CH_WEAPON_SINGLE, SND_Null, VOL_BASE, ATTN_NORM); // kill previous sound
 173         W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 174                 WEP_CVAR_PRI(shotgun, ammo),
 175                 WEP_CVAR_PRI(shotgun, damage),
 176                 WEP_CVAR_PRI(shotgun, bullets),
 177                 WEP_CVAR_PRI(shotgun, spread),
 178                 WEP_CVAR_PRI(shotgun, solidpenetration),
 179                 WEP_CVAR_PRI(shotgun, force),
 180                 EFFECT_BULLET_WEAK); // actually is secondary, but we trick the last shot into playing full reload sound
 181         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), w_ready);
 182 }
 183 void W_Shotgun_Attack3_Frame1(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 184 {
 185         if (!thiswep.wr_checkammo2(thiswep, actor, weaponentity))
 186         if (!(actor.items & IT_UNLIMITED_AMMO))
 187         {
 188                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 189                 w_ready(thiswep, actor, weaponentity, fire);
 190                 return;
 191         }
 192
 193         W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 194                 WEP_CVAR_PRI(shotgun, ammo),
 195                 WEP_CVAR_PRI(shotgun, damage),
 196                 WEP_CVAR_PRI(shotgun, bullets),
 197                 WEP_CVAR_PRI(shotgun, spread),
 198                 WEP_CVAR_PRI(shotgun, solidpenetration),
 199                 WEP_CVAR_PRI(shotgun, force),
 200                 EFFECT_BULLET_WEAK);
 201         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame2);
 202 }
 203
 204 .float shotgun_primarytime;
 205
 206 METHOD(Shotgun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
 207 {
 208     if(vdist(actor.origin - actor.enemy.origin, <=, WEP_CVAR_SEC(shotgun, melee_range)))
 209         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 210     else
 211         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
 212 }
 213
 214 METHOD(Shotgun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 215 {
 216     if(WEP_CVAR(shotgun, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(shotgun, ammo)) // forced reload
 217     {
 218         // don't force reload an empty shotgun if its melee attack is active
 219         if(WEP_CVAR(shotgun, secondary) < 2) {
 220             thiswep.wr_reload(thiswep, actor, weaponentity);
 221         }
 222     }
 223     else
 224     {
 225         if(fire & 1)
 226         {
 227             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 228             {
 229                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(shotgun, animtime)))
 230                 {
 231                     W_Shotgun_Attack(thiswep, actor, weaponentity, true,
 232                                                 WEP_CVAR_PRI(shotgun, ammo),
 233                                                 WEP_CVAR_PRI(shotgun, damage),
 234                                                 WEP_CVAR_PRI(shotgun, bullets),
 235                                                 WEP_CVAR_PRI(shotgun, spread),
 236                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 237                                                 WEP_CVAR_PRI(shotgun, force),
 238                                                 EFFECT_BULLET_WEAK);
 239                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_PRI(shotgun, refire) * W_WeaponRateFactor(actor);
 240                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(shotgun, animtime), w_ready);
 241                 }
 242             }
 243         }
 244         else if((fire & 2) && WEP_CVAR(shotgun, secondary) == 2)
 245         {
 246             if(time >= actor.(weaponentity).shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 247             {
 248                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(shotgun, alt_animtime)))
 249                 {
 250                     W_Shotgun_Attack(thiswep, actor, weaponentity, false,
 251                                                 WEP_CVAR_PRI(shotgun, ammo),
 252                                                 WEP_CVAR_PRI(shotgun, damage),
 253                                                 WEP_CVAR_PRI(shotgun, bullets),
 254                                                 WEP_CVAR_PRI(shotgun, spread),
 255                                                 WEP_CVAR_PRI(shotgun, solidpenetration),
 256                                                 WEP_CVAR_PRI(shotgun, force),
 257                                                 EFFECT_BULLET_WEAK);
 258                     actor.(weaponentity).shotgun_primarytime = time + WEP_CVAR_SEC(shotgun, alt_refire) * W_WeaponRateFactor(actor);
 259                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_SEC(shotgun, alt_animtime), W_Shotgun_Attack3_Frame1);
 260                 }
 261             }
 262         }
 263     }
 264     if(actor.(weaponentity).clip_load >= 0) // we are not currently reloading
 265     if(WEP_CVAR(shotgun, secondary) == 1)
 266     if(((fire & 1) && GetResource(actor, thiswep.ammo_type) <= 0 && !(actor.items & IT_UNLIMITED_AMMO)) || (fire & 2))
 267     if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR_SEC(shotgun, refire)))
 268     {
 269         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 270         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 271     }
 272 }
 273 METHOD(Shotgun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 274 {
 275     float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 276     ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 277     return ammo_amount;
 278 }
 279 METHOD(Shotgun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 280 {
 281     if(IS_BOT_CLIENT(actor))
 282     if(vdist(actor.origin - actor.enemy.origin, >, WEP_CVAR_SEC(shotgun, melee_range)))
 283         return false; // bots cannot use secondary out of range (fixes constant melee when out of ammo)
 284     switch(WEP_CVAR(shotgun, secondary))
 285     {
 286         case 1: return true; // melee does not use ammo
 287         case 2: // secondary triple shot
 288         {
 289             float ammo_amount = GetResource(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(shotgun, ammo);
 290             ammo_amount += actor.(weaponentity).(weapon_load[thiswep.m_id]) >= WEP_CVAR_PRI(shotgun, ammo);
 291             return ammo_amount;
 292         }
 293         default: return false; // secondary unavailable
 294     }
 295 }
 296 METHOD(Shotgun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 297 {
 298     W_Reload(actor, weaponentity, WEP_CVAR_PRI(shotgun, ammo), SND_RELOAD); // WEAPONTODO
 299 }
 300 METHOD(Shotgun, wr_suicidemessage, Notification(entity thiswep))
 301 {
 302     return WEAPON_THINKING_WITH_PORTALS;
 303 }
 304 METHOD(Shotgun, wr_killmessage, Notification(entity thiswep))
 305 {
 306     if(w_deathtype & HITTYPE_SECONDARY)
 307         return WEAPON_SHOTGUN_MURDER_SLAP;
 308     else
 309         return WEAPON_SHOTGUN_MURDER;
 310 }
 311
 312 #endif
 313 #ifdef CSQC
 314 .float prevric;
 315
 316 METHOD(Shotgun, wr_impacteffect, void(entity thiswep, entity actor))
 317 {
 318     vector org2 = w_org + w_backoff * 2;
 319     pointparticles(EFFECT_SHOTGUN_IMPACT, org2, w_backoff * 1000, 1);
 320     if(!w_issilent && time - actor.prevric > 0.25)
 321     {
 322         if(w_random < 0.05)
 323             sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 324         actor.prevric = time;
 325     }
 326 }
 327
 328 #endif