qcsrc/csqcmodellib/cl_player.qc

   1 /*
   2  * Copyright (c) 2011 Rudolf Polzer
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to
   6  * deal in the Software without restriction, including without limitation the
   7  * rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   8  * sell copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  19  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  20  * IN THE SOFTWARE.
  21  */
  22
  23 var float autocvar_cl_predictionerrorcompensation = 0;
  24
  25 // engine stuff
  26 .float pmove_flags;
  27 float pmove_onground; // weird engine flag we shouldn't really use but have to for now
  28 #define PMF_JUMP_HELD 1
  29 #define PMF_DUCKED 4
  30 #define PMF_ONGROUND 8
  31 #define REFDEFFLAG_TELEPORTED 1
  32 #define REFDEFFLAG_JUMPING 2
  33
  34 entity csqcplayer;
  35 vector csqcplayer_origin, csqcplayer_velocity;
  36 float csqcplayer_sequence, player_pmflags;
  37 float csqcplayer_moveframe;
  38 vector csqcplayer_predictionerror;
  39 float csqcplayer_predictionerrortime;
  40
  41 vector CSQCPlayer_GetPredictionError()
  42 {
  43         if(!autocvar_cl_predictionerrorcompensation)
  44                 return '0 0 0';
  45         if(time < csqcplayer_predictionerrortime)
  46                 return csqcplayer_predictionerror * (csqcplayer_predictionerrortime - time) * autocvar_cl_predictionerrorcompensation;
  47         return '0 0 0';
  48 }
  49
  50 void CSQCPlayer_SetPredictionError(vector v)
  51 {
  52         if(!autocvar_cl_predictionerrorcompensation)
  53                 return;
  54         csqcplayer_predictionerror = (csqcplayer_predictionerrortime - time) * autocvar_cl_predictionerrorcompensation * csqcplayer_predictionerror + v;
  55         csqcplayer_predictionerrortime = time + 1.0 / autocvar_cl_predictionerrorcompensation;
  56 }
  57
  58 void CSQCPlayer_Unpredict()
  59 {
  60         if(csqcplayer_status == CSQCPLAYERSTATUS_UNPREDICTED)
  61                 return;
  62         if(csqcplayer_status != CSQCPLAYERSTATUS_PREDICTED)
  63                 error("Cannot unpredict in current status");
  64         self.origin = csqcplayer_origin;
  65         self.velocity = csqcplayer_velocity;
  66         csqcplayer_moveframe = csqcplayer_sequence+1; //+1 because the recieved frame has the move already done (server side)
  67         self.pmove_flags = player_pmflags;
  68 }
  69
  70 void CSQCPlayer_SetMinsMaxs()
  71 {
  72         if(self.pmove_flags & PMF_DUCKED)
  73         {
  74                 self.mins = PL_CROUCH_MIN;
  75                 self.maxs = PL_CROUCH_MAX;
  76                 self.view_ofs = PL_CROUCH_VIEW_OFS;
  77         }
  78         else
  79         {
  80                 self.mins = PL_MIN;
  81                 self.maxs = PL_MAX;
  82                 self.view_ofs = PL_VIEW_OFS;
  83         }
  84 }
  85
  86 void CSQCPlayer_SavePrediction()
  87 {
  88         player_pmflags = self.pmove_flags;
  89         csqcplayer_origin = self.origin;
  90         csqcplayer_velocity = self.velocity;
  91         csqcplayer_sequence = servercommandframe;
  92         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
  93 }
  94
  95 void CSQCPlayer_PredictTo(float endframe)
  96 {
  97         CSQCPlayer_Unpredict();
  98         CSQCPlayer_SetMinsMaxs();
  99
 100         csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 101
 102         // FIXME do we really NEED this? dead players have servercommandframe
 103         // == 0 and thus won't predict
 104         if (getstatf(STAT_HEALTH) <= 0)
 105         {
 106                 csqcplayer_moveframe = clientcommandframe;
 107                 getinputstate(csqcplayer_moveframe-1);
 108                 return;
 109         }
 110
 111         if(csqcplayer_moveframe >= endframe)
 112         {
 113                 getinputstate(csqcplayer_moveframe - 1);
 114         }
 115         else
 116         {
 117                 do
 118                 {
 119                         if (!getinputstate(csqcplayer_moveframe))
 120                                 break;
 121                         runstandardplayerphysics(self);
 122                         CSQCPlayer_SetMinsMaxs();
 123                         csqcplayer_moveframe++;
 124                 }
 125                 while(csqcplayer_moveframe < endframe);
 126         }
 127
 128         //add in anything that was applied after (for low packet rate protocols)
 129         input_angles = view_angles;
 130 }
 131
 132 float CSQCPlayer_IsLocalPlayer()
 133 {
 134         return (self == csqcplayer);
 135 }
 136
 137 void(entity e, float fl) V_CalcRefdef = #640; // DP_CSQC_V_CALCREFDEF
 138
 139 void CSQCPlayer_SetCamera()
 140 {
 141         if(csqcplayer)
 142         {
 143                 entity oldself;
 144                 oldself = self;
 145                 self = csqcplayer;
 146
 147 #ifdef COMPAT_XON050_ENGINE
 148                 if(servercommandframe == 0 || clientcommandframe == 0 || !(checkextension("DP_CSQC_V_CALCREFDEF") || checkextension("DP_CSQC_V_CALCREFDEF_WIP1")))
 149 #else
 150                 if(servercommandframe == 0 || clientcommandframe == 0)
 151 #endif
 152                 {
 153                         InterpolateOrigin_Do();
 154                         self.view_ofs = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 155
 156                         // get crouch state from the server
 157                         if(getstati(STAT_VIEWHEIGHT) == PL_VIEW_OFS_z)
 158                                 self.pmove_flags &~= PMF_DUCKED;
 159                         else if(getstati(STAT_VIEWHEIGHT) == PL_CROUCH_VIEW_OFS_z)
 160                                 self.pmove_flags |= PMF_DUCKED;
 161
 162                         // get onground state from the server
 163                         if(pmove_onground)
 164                                 self.pmove_flags |= PMF_ONGROUND;
 165                         else
 166                                 self.pmove_flags &~= PMF_ONGROUND;
 167
 168                         CSQCPlayer_SetMinsMaxs();
 169
 170                         // override it back just in case
 171                         self.view_ofs = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 172                 }
 173                 else
 174                 {
 175                         if(csqcplayer_status == CSQCPLAYERSTATUS_FROMSERVER)
 176                         {
 177                                 vector o, v;
 178                                 o = self.origin;
 179                                 v = pmove_vel; // TRICK: pmove_vel is set by the engine when we get here. No need to network velocity
 180                                 csqcplayer_status = CSQCPLAYERSTATUS_PREDICTED;
 181                                 CSQCPlayer_PredictTo(servercommandframe + 1);
 182                                 CSQCPlayer_SetPredictionError(o - self.origin);
 183                                 self.origin = o;
 184                                 self.velocity = v;
 185
 186                                 // get crouch state from the server
 187                                 if(getstati(STAT_VIEWHEIGHT) == PL_VIEW_OFS_z)
 188                                         self.pmove_flags &~= PMF_DUCKED;
 189                                 else if(getstati(STAT_VIEWHEIGHT) == PL_CROUCH_VIEW_OFS_z)
 190                                         self.pmove_flags |= PMF_DUCKED;
 191
 192                                 // get onground state from the server
 193                                 if(pmove_onground)
 194                                         self.pmove_flags |= PMF_ONGROUND;
 195                                 else
 196                                         self.pmove_flags &~= PMF_ONGROUND;
 197
 198                                 CSQCPlayer_SavePrediction();
 199                         }
 200                         CSQCPlayer_PredictTo(clientcommandframe + 1);
 201
 202                         CSQCPlayer_SetMinsMaxs();
 203
 204                         self.angles_y = input_angles_y;
 205                 }
 206
 207                 // relink
 208                 setorigin(self, self.origin);
 209
 210                 self = oldself;
 211         }
 212
 213         entity view;
 214 #ifdef COMPAT_XON050_ENGINE
 215         view = CSQCModel_server2csqc((spectatee_status > 0) ? spectatee_status : player_localentnum);
 216 #else
 217         view = CSQCModel_server2csqc(player_localentnum);
 218 #endif
 219
 220         if(view && view != csqcplayer)
 221         {
 222                 entity oldself = self;
 223                 self = view;
 224                 InterpolateOrigin_Do();
 225                 self.view_ofs = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 226                 self = oldself;
 227         }
 228
 229 #ifdef COMPAT_XON050_ENGINE
 230         if(view && !(checkextension("DP_CSQC_V_CALCREFDEF") || checkextension("DP_CSQC_V_CALCREFDEF_WIP1")))
 231         {
 232                 // legacy code, not totally correct, but good enough for not having V_CalcRefdef
 233                 setproperty(VF_ORIGIN, view.origin + '0 0 1' * getstati(STAT_VIEWHEIGHT));
 234                 setproperty(VF_ANGLES, view_angles);
 235         }
 236         else
 237 #endif
 238         if(view)
 239         {
 240                 var float refdefflags = 0;
 241
 242                 if(view.csqcmodel_teleported)
 243                         refdefflags |= REFDEFFLAG_TELEPORTED;
 244
 245                 if(input_buttons & 4)
 246                         refdefflags |= REFDEFFLAG_JUMPING;
 247
 248                 V_CalcRefdef(view, refdefflags);
 249         }
 250         else
 251         {
 252                 // FIXME by CSQC spec we have to do this:
 253                 // but it breaks chase cam
 254                 /*
 255                 setproperty(VF_ORIGIN, pmove_org + '0 0 1' * getstati(STAT_VIEWHEIGHT));
 256                 setproperty(VF_ANGLES, view_angles);
 257                 */
 258         }
 259
 260         { CSQCPLAYER_HOOK_POSTCAMERASETUP }
 261 }
 262
 263 void CSQCPlayer_Remove()
 264 {
 265         csqcplayer = world;
 266         cvar_settemp("cl_movement_replay", "1");
 267 }
 268
 269 float CSQCPlayer_PreUpdate()
 270 {
 271         if(self != csqcplayer)
 272                 return 0;
 273         if(csqcplayer_status != CSQCPLAYERSTATUS_FROMSERVER)
 274                 CSQCPlayer_Unpredict();
 275         return 1;
 276 }
 277
 278 float CSQCPlayer_PostUpdate()
 279 {
 280         if(self.entnum != player_localnum + 1)
 281                 return 0;
 282         csqcplayer = self;
 283         csqcplayer_status = CSQCPLAYERSTATUS_FROMSERVER;
 284         cvar_settemp("cl_movement_replay", "0");
 285         self.entremove = CSQCPlayer_Remove;
 286         return 1;
 287 }