qcsrc/lib/net.qh

   1 #pragma once
   2
   3 #include "registry.qh"
   4 #include "sort.qh"
   5 #include "yenc.qh"
   6
   7 .string netname;
   8 .int m_id;
   9 .bool(entity this, entity sender, bool isNew) m_read;
  10 #define NET_HANDLE(id, param) bool Net_Handle_##id(entity this, entity sender, param)
  11
  12
  13 #ifdef CSQC
  14         #define REGISTER_NET_TEMP(id) \
  15                 NET_HANDLE(id, bool); \
  16                 REGISTER(TempEntities, NET, id, m_id, new_pure(net_temp_packet)) \
  17                 { \
  18                         this.netname = #id; \
  19                         this.m_read = Net_Handle_##id; \
  20                 }
  21 #else
  22         #define REGISTER_NET_TEMP(id) \
  23                 const bool NET_##id##_istemp = true; \
  24                 REGISTER(TempEntities, NET, id, m_id, new_pure(net_temp_packet)) \
  25                 { \
  26                         this.netname = #id; \
  27                 }
  28 #endif
  29 #define REGISTER_NET_S2C(id) REGISTER_NET_TEMP(id)
  30
  31 REGISTRY(TempEntities, BITS(8) - 80)
  32 #define TempEntities_from(i) _TempEntities_from(i, NULL)
  33 REGISTER_REGISTRY(TempEntities)
  34 REGISTRY_SORT(TempEntities)
  35 REGISTRY_CHECK(TempEntities)
  36 STATIC_INIT(RegisterTempEntities_renumber) { FOREACH(TempEntities, true, it.m_id = 80 + i); }
  37
  38
  39
  40 #ifdef CSQC
  41         #define REGISTER_NET_LINKED(id) \
  42                 [[accumulate]] NET_HANDLE(id, bool isnew) \
  43                 { \
  44                         this = __self; \
  45                         this.sourceLoc = __FILE__ ":" STR(__LINE__); \
  46                         if (!this) isnew = true; \
  47                 } \
  48                 REGISTER(LinkedEntities, NET, id, m_id, new_pure(net_linked_packet)) \
  49                 { \
  50                         this.netname = #id; \
  51                         this.m_read = Net_Handle_##id; \
  52                 }
  53 #else
  54         #define REGISTER_NET_LINKED(id) \
  55                 const bool NET_##id##_istemp = false; \
  56                 REGISTER(LinkedEntities, NET, id, m_id, new_pure(net_linked_packet)) \
  57                 { \
  58                         this.netname = #id; \
  59                 }
  60 #endif
  61
  62 REGISTRY(LinkedEntities, BITS(8) - 1)
  63 #define LinkedEntities_from(i) _LinkedEntities_from(i, NULL)
  64 REGISTER_REGISTRY(LinkedEntities)
  65 REGISTRY_SORT(LinkedEntities)
  66 REGISTRY_CHECK(LinkedEntities)
  67 STATIC_INIT(RegisterLinkedEntities_renumber) { FOREACH(LinkedEntities, true, it.m_id = 1 + i); }
  68
  69
  70
  71 #ifdef SVQC
  72         #define REGISTER_NET_C2S(id) \
  73                 NET_HANDLE(id, bool); \
  74                 REGISTER(C2S_Protocol, NET, id, m_id, new_pure(net_c2s_packet)) \
  75                 { \
  76                         this.netname = #id; \
  77                         this.m_read = Net_Handle_##id; \
  78                 }
  79 #else
  80         #define REGISTER_NET_C2S(id) \
  81                 const bool NET_##id##_istemp = true; \
  82                 REGISTER(C2S_Protocol, NET, id, m_id, new_pure(net_c2s_packet)) \
  83                 { \
  84                         this.netname = #id; \
  85                 }
  86 #endif
  87
  88 REGISTRY(C2S_Protocol, BITS(8) - 1)
  89 #define C2S_Protocol_from(i) _C2S_Protocol_from(i, NULL)
  90 REGISTER_REGISTRY(C2S_Protocol)
  91 REGISTRY_SORT(C2S_Protocol)
  92 REGISTRY_CHECK(C2S_Protocol)
  93 STATIC_INIT(C2S_Protocol_renumber) { FOREACH(C2S_Protocol, true, it.m_id = i); }
  94
  95 #ifdef SVQC
  96         const int MSG_ENTITY = 5;
  97
  98         .int Version;  // deprecated, use SendFlags
  99         .int SendFlags;
 100
 101         void Net_LinkEntity(entity e, bool docull, float dt, bool(entity this, entity to, int sendflags) sendfunc)
 102         {
 103                 if (e.classname == "") e.classname = "net_linked";
 104
 105                 if (e.model == "" || e.modelindex == 0)
 106                 {
 107                         vector mi = e.mins;
 108                         vector ma = e.maxs;
 109                         _setmodel(e, "null");
 110                         setsize(e, mi, ma);
 111                 }
 112
 113                 setSendEntity(e, sendfunc);
 114                 e.SendFlags = 0xFFFFFF;
 115
 116                 if (!docull) e.effects |= EF_NODEPTHTEST;
 117
 118                 if (dt)
 119                 {
 120                         e.nextthink = time + dt;
 121                         setthink(e, SUB_Remove);
 122                 }
 123         }
 124
 125         void Net_UnlinkEntity(entity e)
 126         {
 127                 setSendEntity(e, func_null);
 128         }
 129
 130         .void(entity this) uncustomizeentityforclient;
 131         .float uncustomizeentityforclient_set;
 132
 133         void SetCustomizer(entity e, bool(entity this) customizer, void(entity this) uncustomizer)
 134         {
 135                 setcefc(e, customizer);
 136                 e.uncustomizeentityforclient = uncustomizer;
 137                 e.uncustomizeentityforclient_set = !!uncustomizer;
 138         }
 139
 140         void UncustomizeEntitiesRun()
 141         {
 142                 FOREACH_ENTITY_FLOAT(uncustomizeentityforclient_set, true, it.uncustomizeentityforclient(it));
 143         }
 144
 145         STRING_ITERATOR(g_buf, string_null, 0);
 146
 147         int ReadByte();
 148
 149         void Net_ClientCommand(entity sender, string command)
 150         {
 151                 // command matches `c2s "(.+)"`
 152                 string buf = substring(command, argv_start_index(1) + 1, -2);
 153                 if (buf == "") return;
 154                 STRING_ITERATOR_SET(g_buf, buf, 0);
 155                 for (int C2S; (C2S = ReadByte()) >= 0; )
 156                 {
 157                         entity reader = C2S_Protocol_from(C2S);
 158                         if (reader && reader.m_read && reader.m_read(NULL, sender, true)) continue;
 159                         LOG_SEVEREF("Net_ClientCommand() with malformed C2S=%d\n", C2S);
 160                         return;
 161                 }
 162                 g_buf_i--;
 163                 int expected = strlen(buf);
 164                 if (g_buf_i > expected) LOG_WARNINGF("Underflow: %d", g_buf_i - expected);
 165                 if (g_buf_i < expected) LOG_WARNINGF("Overrflow: %d", expected - g_buf_i);
 166         }
 167
 168 #endif
 169
 170 #ifdef CSQC
 171         const int MSG_C2S = 0;
 172
 173         #define Net_Accept(classname) \
 174                 MACRO_BEGIN { \
 175                         if (!this)    this = new(classname); \
 176                 } MACRO_END
 177         #define Net_Reject() \
 178                 MACRO_BEGIN { \
 179                         if (this)     remove(this); \
 180                 } MACRO_END
 181
 182         string g_buf;
 183
 184         void Net_Flush()
 185         {
 186                 if (g_buf == "") return;
 187                 localcmd("\ncmd c2s \"", strreplace("$", "$$", g_buf), "\"\n");
 188                 strunzone(g_buf);
 189                 g_buf = string_null;
 190         }
 191 #endif
 192
 193 #if defined(CSQC)
 194         #define WriteHeader(to, id) \
 195                 MACRO_BEGIN { \
 196                         WriteByte(to, NET_##id.m_id); \
 197                 } MACRO_END
 198 #elif defined(SVQC)
 199         #define WriteHeader(to, id) \
 200                 MACRO_BEGIN { \
 201                         if (NET_##id##_istemp) WriteByte(to, SVC_TEMPENTITY); \
 202                         WriteByte(to, NET_##id.m_id); \
 203                 } MACRO_END
 204 #endif
 205
 206 #define ReadRegistered(r) r##_from(Read_byte())
 207 #define WriteRegistered(r, to, it) Write_byte(to, it.m_id)
 208
 209 #define Read_byte() ReadByte()
 210 #define Write_byte(to, f) WriteByte(to, f)
 211
 212 #if defined(CSQC)
 213         int ReadByte();
 214         void WriteByte(int to, int b)
 215         {
 216                 assert(to == MSG_C2S);
 217                 string s = string_null;
 218                 yenc_single(b, s);
 219                 string tmp = strcat(g_buf, s);
 220                 if (g_buf) strunzone(g_buf);
 221                 g_buf = strzone(tmp);
 222         }
 223 #elif defined(SVQC)
 224         int ReadByte()
 225         {
 226                 int ret = -1;
 227                 ydec_single(g_buf, ret);
 228                 return ret;
 229         }
 230         void WriteByte(int to, int b);
 231 #endif
 232
 233 #define Read_int() ReadInt24_t()
 234 #define Write_int(to, f) WriteInt24_t(to, f)
 235
 236 #define Read_float() ReadFloat()
 237 #define Write_float(to, f) WriteFloat(to, f)
 238
 239 #define Read_string() ReadString()
 240 #define Write_string(to, f) WriteString(to, f)
 241
 242 #ifndef MENUQC
 243         const float APPROXPASTTIME_ACCURACY_REQUIREMENT = 0.05;
 244         #define APPROXPASTTIME_MAX (16384 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 245         #define APPROXPASTTIME_RANGE (64 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 246
 247         #ifdef CSQC
 248                 entity ReadCSQCEntity()
 249                 {
 250                         int f = ReadShort();
 251                         if (f == 0) return NULL;
 252                         return findfloat(NULL, entnum, f);
 253                 }
 254                 int ReadInt24_t()
 255                 {
 256                         int v = ReadShort() << 8; // note: this is signed
 257                         v += ReadByte();          // note: this is unsigned
 258                         return v;
 259                 }
 260                 #define ReadInt48_t() vec3(ReadInt24_t(), ReadInt24_t(), 0)
 261                 #define ReadInt72_t() vec3(ReadInt24_t(), ReadInt24_t(), ReadInt24_t())
 262
 263                 int _ReadSByte;
 264                 #define ReadSByte() (_ReadSByte = ReadByte(), (_ReadSByte & BIT(7) ? -128 : 0) + (_ReadSByte & BITS(7)))
 265                 #define ReadFloat() ReadCoord()
 266                 #define ReadVector() vec3(ReadFloat(), ReadFloat(), ReadFloat())
 267                 #define ReadVector2D() vec3(ReadFloat(), ReadFloat(), 0)
 268
 269                 float ReadApproxPastTime()
 270                 {
 271                         float dt = ReadByte();
 272
 273                         // map from range...PPROXPASTTIME_MAX / 256
 274                         dt = (APPROXPASTTIME_MAX / 256) * (dt / (256 - dt));
 275
 276                         return servertime - dt;
 277                 }
 278
 279         #else
 280                 void WriteInt24_t(float dst, float val)
 281                 {
 282                         float v;
 283                         WriteShort(dst, (v = floor(val >> 8)));
 284                         WriteByte(dst, val - (v << 8));  // 0..255
 285                 }
 286                 void WriteInt48_t(float dst, vector val)
 287                 {
 288                         WriteInt24_t(dst, val.x);
 289                         WriteInt24_t(dst, val.y);
 290                 }
 291                 void WriteInt72_t(float dst, vector val)
 292                 {
 293                         WriteInt24_t(dst, val.x);
 294                         WriteInt24_t(dst, val.y);
 295                         WriteInt24_t(dst, val.z);
 296                 }
 297
 298         #define WriteFloat(to, f) WriteCoord(to, f)
 299                 #define WriteVector(to, v) MACRO_BEGIN { WriteFloat(to, v.x); WriteFloat(to, v.y); WriteFloat(to, v.z); } MACRO_END
 300         #define WriteVector2D(to, v) MACRO_BEGIN { WriteFloat(to, v.x); WriteFloat(to, v.y); } MACRO_END
 301
 302                 // this will use the value:
 303                 //   128
 304                 // accuracy near zero is APPROXPASTTIME_MAX/(256*255)
 305                 // accuracy at x is 1/derivative, i.e.
 306                 //   APPROXPASTTIME_MAX * (1 + 256 * (dt / APPROXPASTTIME_MAX))^2 / 65536
 307                 void WriteApproxPastTime(float dst, float t)
 308                 {
 309                         float dt = time - t;
 310
 311                         // warning: this is approximate; do not resend when you don't have to!
 312                         // be careful with sendflags here!
 313                         // we want: 0 -> 0.05, 1 -> 0.1, ..., 255 -> 12.75
 314
 315                         // map to range...
 316                         dt = 256 * (dt / ((APPROXPASTTIME_MAX / 256) + dt));
 317
 318                         // round...
 319                         dt = rint(bound(0, dt, 255));
 320
 321                         WriteByte(dst, dt);
 322                 }
 323
 324                 // allow writing to also pass through to spectators (like so spectators see the same centerprints as players for example)
 325                 #define WRITESPECTATABLE_MSG_ONE(to, statement) MACRO_BEGIN { \
 326                         entity prev = msg_entity; \
 327                         entity dst = to; \
 328                         FOREACH_CLIENT(IS_REAL_CLIENT(it), { \
 329                                 if (it == dst || (it.classname == STR_SPECTATOR && it.enemy == dst)) \
 330                                 { \
 331                                         msg_entity = it; \
 332                                         LAMBDA(statement); \
 333                                 } \
 334                         }); \
 335                         msg_entity = prev; \
 336                 } MACRO_END
 337         #endif
 338 #endif