qcsrc/lib/string.qh

   1 #pragma once
   2
   3 #include "nil.qh"
   4 #include "sort.qh"
   5 #include "oo.qh"
   6
   7 #ifndef SVQC
   8         float stringwidth_colors(string s, vector theSize)
   9         {
  10                 return stringwidth(s, true, theSize);
  11         }
  12
  13         float stringwidth_nocolors(string s, vector theSize)
  14         {
  15                 return stringwidth(s, false, theSize);
  16         }
  17 #endif
  18
  19 // TODO: macro
  20 string seconds_tostring(float sec)
  21 {
  22         float minutes = floor(sec / 60);
  23         sec -= minutes * 60;
  24         return sprintf("%d:%02d", minutes, sec);
  25 }
  26
  27 string format_time(float seconds)
  28 {
  29         seconds = floor(seconds + 0.5);
  30         float days = floor(seconds / 864000);
  31         seconds -= days * 864000;
  32         float hours = floor(seconds / 36000);
  33         seconds -= hours * 36000;
  34         float minutes = floor(seconds / 600);
  35         seconds -= minutes * 600;
  36         if (days > 0) return sprintf(_("%d days, %02d:%02d:%02d"), days, hours, minutes, seconds);
  37         else return sprintf(_("%02d:%02d:%02d"), hours, minutes, seconds);
  38 }
  39
  40 string mmsss(float tenths)
  41 {
  42         tenths = floor(tenths + 0.5);
  43         float minutes = floor(tenths / 600);
  44         tenths -= minutes * 600;
  45         string s = ftos(1000 + tenths);
  46         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 1));
  47 }
  48
  49 string mmssss(float hundredths)
  50 {
  51         hundredths = floor(hundredths + 0.5);
  52         float minutes = floor(hundredths / 6000);
  53         hundredths -= minutes * 6000;
  54         string s = ftos(10000 + hundredths);
  55         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 2));
  56 }
  57
  58 int ColorTranslateMode;
  59
  60 string ColorTranslateRGB(string s)
  61 {
  62         return (ColorTranslateMode & 1) ? strdecolorize(s) : s;
  63 }
  64
  65 // color code replace, place inside of sprintf and parse the string... defaults described as constants
  66 // foreground/normal colors
  67 string autocvar_hud_colorset_foreground_1 = "2"; // F1 - Green  // primary priority (important names, etc)
  68 string autocvar_hud_colorset_foreground_2 = "3"; // F2 - Yellow // secondary priority (items, locations, numbers, etc)
  69 string autocvar_hud_colorset_foreground_3 = "4"; // F3 - Blue   // tertiary priority or relatively inconsequential text
  70 string autocvar_hud_colorset_foreground_4 = "1"; // F4 - Red    // notice/attention grabbing texting
  71 // "kill" colors
  72 string autocvar_hud_colorset_kill_1 = "1";       // K1 - Red    // "bad" or "dangerous" text (death messages against you, kill notifications, etc)
  73 string autocvar_hud_colorset_kill_2 = "3";       // K2 - Yellow // similar to above, but less important... OR, a highlight out of above message type
  74 string autocvar_hud_colorset_kill_3 = "4";       // K3 - Blue   // "good" or "beneficial" text (you fragging someone, etc)
  75 // background color
  76 string autocvar_hud_colorset_background = "7";   // BG - White // neutral/unimportant text
  77
  78 /** color code replace, place inside of sprintf and parse the string */
  79 string CCR(string input)
  80 {
  81         // See the autocvar declarations in util.qh for default values
  82
  83         // foreground/normal colors
  84         input = strreplace("^F1", strcat("^", autocvar_hud_colorset_foreground_1), input);
  85         input = strreplace("^F2", strcat("^", autocvar_hud_colorset_foreground_2), input);
  86         input = strreplace("^F3", strcat("^", autocvar_hud_colorset_foreground_3), input);
  87         input = strreplace("^F4", strcat("^", autocvar_hud_colorset_foreground_4), input);
  88
  89         // "kill" colors
  90         input = strreplace("^K1", strcat("^", autocvar_hud_colorset_kill_1), input);
  91         input = strreplace("^K2", strcat("^", autocvar_hud_colorset_kill_2), input);
  92         input = strreplace("^K3", strcat("^", autocvar_hud_colorset_kill_3), input);
  93
  94         // background colors
  95         input = strreplace("^BG", strcat("^", autocvar_hud_colorset_background), input);
  96         input = strreplace("^N", "^7", input);  // "none"-- reset to white...
  97         return input;
  98 }
  99
 100 #define startsWith(haystack, needle) (strstrofs(haystack, needle, 0) == 0)
 101
 102 bool startsWithNocase(string haystack, string needle)
 103 {
 104         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
 105 }
 106
 107 /** unzone the string, and return it as tempstring. Safe to be called on string_null */
 108 string fstrunzone(string s)
 109 {
 110         if (!s) return s;
 111         string sc = strcat(s, "");
 112         strunzone(s);
 113         return sc;
 114 }
 115
 116 /** returns first word */
 117 string car(string s)
 118 {
 119         int o = strstrofs(s, " ", 0);
 120         if (o < 0) return s;
 121         return substring(s, 0, o);
 122 }
 123
 124 /** returns all but first word */
 125 string cdr(string s)
 126 {
 127         int o = strstrofs(s, " ", 0);
 128         if (o < 0) return string_null;
 129         return substring(s, o + 1, strlen(s) - (o + 1));
 130 }
 131
 132 string cons(string a, string b)
 133 {
 134         if (a == "") return b;
 135         if (b == "") return a;
 136         return strcat(a, " ", b);
 137 }
 138
 139 string substring_range(string s, float b, float e)
 140 {
 141         return substring(s, b, e - b);
 142 }
 143
 144 string swapwords(string str, float i, float j)
 145 {
 146         float n;
 147         string s1, s2, s3, s4, s5;
 148         float si, ei, sj, ej, s0, en;
 149         n = tokenizebyseparator(str, " ");  // must match g_maplist processing in ShuffleMaplist and "shuffle"
 150         si = argv_start_index(i);
 151         sj = argv_start_index(j);
 152         ei = argv_end_index(i);
 153         ej = argv_end_index(j);
 154         s0 = argv_start_index(0);
 155         en = argv_end_index(n - 1);
 156         s1 = substring_range(str, s0, si);
 157         s2 = substring_range(str, si, ei);
 158         s3 = substring_range(str, ei, sj);
 159         s4 = substring_range(str, sj, ej);
 160         s5 = substring_range(str, ej, en);
 161         return strcat(s1, s4, s3, s2, s5);
 162 }
 163
 164 string _shufflewords_str;
 165 void _shufflewords_swapfunc(float i, float j, entity pass)
 166 {
 167         _shufflewords_str = swapwords(_shufflewords_str, i, j);
 168 }
 169 string shufflewords(string str)
 170 {
 171         _shufflewords_str = str;
 172         int n = tokenizebyseparator(str, " ");
 173         shuffle(n, _shufflewords_swapfunc, NULL);
 174         str = _shufflewords_str;
 175         _shufflewords_str = string_null;
 176         return str;
 177 }
 178
 179 string unescape(string in)
 180 {
 181         in = strzone(in);  // but it doesn't seem to be necessary in my tests at least
 182
 183         int len = strlen(in);
 184         string str = "";
 185         for (int i = 0; i < len; ++i)
 186         {
 187                 string s = substring(in, i, 1);
 188                 if (s == "\\")
 189                 {
 190                         s = substring(in, i + 1, 1);
 191                         if (s == "n") str = strcat(str, "\n");
 192                         else if (s == "\\") str = strcat(str, "\\");
 193                         else str = strcat(str, substring(in, i, 2));
 194                         ++i;
 195                         continue;
 196                 }
 197                 str = strcat(str, s);
 198         }
 199         strunzone(in);
 200         return str;
 201 }
 202
 203 string strwords(string s, int w)
 204 {
 205         int endpos = 0;
 206         for ( ; w && endpos >= 0; --w)
 207                 endpos = strstrofs(s, " ", endpos + 1);
 208         if (endpos < 0) return s;
 209         return substring(s, 0, endpos);
 210 }
 211
 212 #define strhasword(s, w) (strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0)
 213
 214 int u8_strsize(string s)
 215 {
 216         int l = 0;
 217         for (int i = 0, c; (c = str2chr(s, i)) > 0; ++i, ++l)
 218         {
 219                 l += (c >= 0x80);
 220                 l += (c >= 0x800);
 221                 l += (c >= 0x10000);
 222         }
 223         return l;
 224 }
 225
 226 bool isInvisibleString(string s)
 227 {
 228         s = strdecolorize(s);
 229         bool utf8 = cvar("utf8_enable");
 230         for (int i = 0, n = strlen(s); i < n; ++i)
 231         {
 232                 int c = str2chr(s, i);
 233                 switch (c)
 234                 {
 235                         case 0:
 236                         case 32:           // space
 237                                 break;
 238                         case 192:          // charmap space
 239                                 if (!utf8) break;
 240                                 return false;
 241                         case 160:          // space in unicode fonts
 242                         case 0xE000 + 192: // utf8 charmap space
 243                                 if (utf8) break;
 244                         default:
 245                                 return false;
 246                 }
 247         }
 248         return true;
 249 }
 250
 251 // Multiline text file buffers
 252
 253 int buf_load(string pFilename)
 254 {
 255         int buf = buf_create();
 256         if (buf < 0) return -1;
 257         int fh = fopen(pFilename, FILE_READ);
 258         if (fh < 0)
 259         {
 260                 buf_del(buf);
 261                 return -1;
 262         }
 263         string l;
 264         for (int i = 0; (l = fgets(fh)); ++i)
 265                 bufstr_set(buf, i, l);
 266         fclose(fh);
 267         return buf;
 268 }
 269
 270 void buf_save(float buf, string pFilename)
 271 {
 272         int fh = fopen(pFilename, FILE_WRITE);
 273         if (fh < 0) error(strcat("Can't write buf to ", pFilename));
 274         int n = buf_getsize(buf);
 275         for (int i = 0; i < n; ++i)
 276                 fputs(fh, strcat(bufstr_get(buf, i), "\n"));
 277         fclose(fh);
 278 }
 279
 280 /**
 281  * converts a number to a string with the indicated number of decimals
 282  * works for up to 10 decimals!
 283  */
 284 string ftos_decimals(float number, int decimals)
 285 {
 286         // inhibit stupid negative zero
 287         if (number == 0) number = 0;
 288         // we have sprintf...
 289         return sprintf("%.*f", decimals, number);
 290 }
 291
 292 int vercmp_recursive(string v1, string v2)
 293 {
 294         int dot1 = strstrofs(v1, ".", 0);
 295         int dot2 = strstrofs(v2, ".", 0);
 296         string s1 = (dot1 == -1) ? v1 : substring(v1, 0, dot1);
 297         string s2 = (dot2 == -1) ? v2 : substring(v2, 0, dot2);
 298
 299         float r;
 300         r = stof(s1) - stof(s2);
 301         if (r != 0) return r;
 302
 303         r = strcasecmp(s1, s2);
 304         if (r != 0) return r;
 305
 306         if (dot1 == -1) return (dot2 == -1) ? 0 : -1;
 307         else return (dot2 == -1) ? 1 : vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
 308 }
 309
 310 int vercmp(string v1, string v2)
 311 {
 312         if (strcasecmp(v1, v2) == 0) return 0;  // early out check
 313
 314         // "git" beats all
 315         if (v1 == "git") return 1;
 316         if (v2 == "git") return -1;
 317
 318         return vercmp_recursive(v1, v2);
 319 }
 320
 321 const string HEXDIGITS = "0123456789ABCDEF0123456789abcdef";
 322 #define HEXDIGIT_TO_DEC_RAW(d) (strstrofs(HEXDIGITS, (d), 0))
 323 #define HEXDIGIT_TO_DEC(d) ((HEXDIGIT_TO_DEC_RAW(d) | 0x10) - 0x10)
 324 #define DEC_TO_HEXDIGIT(d) (substring(HEXDIGITS, (d), 1))