qcsrc/lib/warpzone/common.qc

   1 #include "common.qh"
   2
   3 #if defined(CSQC)
   4     #include <common/t_items.qh>
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7     #include <common/weapons/_all.qh>
   8 #endif
   9
  10 void WarpZone_Accumulator_Clear(entity acc)
  11 {
  12         acc.warpzone_transform = '0 0 0';
  13         acc.warpzone_shift = '0 0 0';
  14 }
  15 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  16 {
  17         vector tr, st;
  18         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  19         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  20         acc.warpzone_transform = tr;
  21         acc.warpzone_shift = st;
  22 }
  23 void WarpZone_Accumulator_Add(entity acc, entity wz)
  24 {
  25         WarpZone_Accumulator_AddTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  26 }
  27 void WarpZone_Accumulator_AddInverseTransform(entity acc, vector t, vector s)
  28 {
  29         vector tt, ss;
  30         tt = AnglesTransform_Invert(t);
  31         ss = AnglesTransform_PrePostShift_GetPostShift(s, tt, '0 0 0');
  32         WarpZone_Accumulator_AddTransform(acc, tt, ss);
  33         // yes, this probably can be done simpler... but this way is "obvious" :)
  34 }
  35 void WarpZone_Accumulator_AddInverse(entity acc, entity wz)
  36 {
  37         WarpZone_Accumulator_AddInverseTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  38 }
  39
  40 float autocvar_cl_warpzone_usetrace = 1;
  41 vector WarpZone_camera_transform(entity this, vector org, vector ang)
  42 {
  43         vector vf, vr, vu;
  44         if(this.warpzone_fadestart)
  45                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  46                         return org;
  47                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  48                         // unneeded on client, on server this helps a lot
  49         vf = v_forward;
  50         vr = v_right;
  51         vu = v_up;
  52         org = WarpZone_TransformOrigin(this, org);
  53         vf = WarpZone_TransformVelocity(this, vf);
  54         vr = WarpZone_TransformVelocity(this, vr);
  55         vu = WarpZone_TransformVelocity(this, vu);
  56         if(autocvar_cl_warpzone_usetrace)
  57                 traceline(this.warpzone_targetorigin, org, MOVE_NOMONSTERS, NULL);
  58         else
  59                 trace_endpos = this.warpzone_targetorigin;
  60         v_forward = vf;
  61         v_right = vr;
  62         v_up = vu;
  63         return org;
  64 }
  65
  66 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  67 {
  68         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  69         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  70         e.warpzone_origin = my_org;
  71         e.warpzone_targetorigin = other_org;
  72         e.warpzone_angles = my_ang;
  73         e.warpzone_targetangles = other_ang;
  74         FIXED_MAKE_VECTORS_NEW(my_ang, forward, right, up);
  75         e.warpzone_forward = forward;
  76         FIXED_MAKE_VECTORS(other_ang, forward, right, up);
  77         e.warpzone_targetforward = forward;
  78         setcamera_transform(e, WarpZone_camera_transform);
  79 }
  80
  81 vector WarpZone_Camera_camera_transform(entity this, vector org, vector ang)
  82 {
  83         // a fixed camera view
  84         if(this.warpzone_fadestart)
  85                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  86                         return org;
  87                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  88                         // unneeded on client, on server this helps a lot
  89         trace_endpos = this.warpzone_origin;
  90         makevectors(this.warpzone_angles);
  91         return this.warpzone_origin;
  92 }
  93
  94 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  95 {
  96         e.warpzone_origin = my_org;
  97         e.warpzone_angles = my_ang;
  98         setcamera_transform(e, WarpZone_Camera_camera_transform);
  99 }
 100
 101 .entity enemy;
 102
 103 vector WarpZoneLib_BoxTouchesBrush_mins;
 104 vector WarpZoneLib_BoxTouchesBrush_maxs;
 105 entity WarpZoneLib_BoxTouchesBrush_ent;
 106 entity WarpZoneLib_BoxTouchesBrush_ignore;
 107 float WarpZoneLib_BoxTouchesBrush_Recurse()
 108 {
 109         float s;
 110         entity se;
 111         float f;
 112
 113         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
 114 #ifdef CSQC
 115         if (trace_networkentity)
 116         {
 117                 LOG_TRACE("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush");
 118                 // we cannot continue, as a player blocks us...
 119                 // so, abort
 120                 return 0;
 121         }
 122 #endif
 123         if (!trace_ent)
 124                 return 0;
 125         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
 126                 return 1;
 127
 128         se = trace_ent;
 129         s = se.solid;
 130         se.solid = SOLID_NOT;
 131         f = WarpZoneLib_BoxTouchesBrush_Recurse();
 132         se.solid = s;
 133
 134         return f;
 135 }
 136
 137 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 138 {
 139     float f, s;
 140
 141     if(!e.modelindex || e.warpzone_isboxy)
 142         return 1;
 143
 144     s = e.solid;
 145     e.solid = SOLID_BSP;
 146     WarpZoneLib_BoxTouchesBrush_mins = mi;
 147     WarpZoneLib_BoxTouchesBrush_maxs = ma;
 148     WarpZoneLib_BoxTouchesBrush_ent = e;
 149     WarpZoneLib_BoxTouchesBrush_ignore = ig;
 150     f = WarpZoneLib_BoxTouchesBrush_Recurse();
 151     e.solid = s;
 152
 153     return f;
 154 }
 155
 156 entity WarpZone_Find(vector mi, vector ma)
 157 {
 158         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 159         if(!warpzone_warpzones_exist)
 160                 return NULL;
 161         IL_EACH(g_warpzones, WarpZoneLib_BoxTouchesBrush(mi, ma, it, NULL),
 162         {
 163                 return it;
 164         });
 165         return NULL;
 166 }
 167
 168 void WarpZone_MakeAllSolid()
 169 {
 170         if(!warpzone_warpzones_exist)
 171                 return;
 172         IL_EACH(g_warpzones, true,
 173         {
 174                 it.solid = SOLID_BSP;
 175         });
 176 }
 177
 178 void WarpZone_MakeAllOther()
 179 {
 180         if(!warpzone_warpzones_exist)
 181                 return;
 182         IL_EACH(g_warpzones, true,
 183         {
 184                 it.solid = SOLID_TRIGGER;
 185         });
 186 }
 187
 188 void WarpZone_Trace_InitTransform()
 189 {
 190         if(!WarpZone_trace_transform)
 191         {
 192                 WarpZone_trace_transform = new_pure(warpzone_trace_transform);
 193         }
 194         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 195 }
 196 void WarpZone_Trace_AddTransform(entity wz)
 197 {
 198         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 199 }
 200
 201 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 202 {
 203         float nomonsters_adjusted;
 204         float frac, sol, i;
 205         float contentshack;
 206         vector o0, e0;
 207         entity wz;
 208         vector vf, vr, vu;
 209
 210         WarpZone_trace_forent = forent;
 211         WarpZone_trace_firstzone = NULL;
 212         WarpZone_trace_lastzone = NULL;
 213         WarpZone_Trace_InitTransform();
 214         if(!warpzone_warpzones_exist)
 215         {
 216                 if(nomonsters == MOVE_NOTHING)
 217                 {
 218                         trace_endpos = end;
 219                         trace_fraction = 1;
 220                         if(cb)
 221                                 cb(org, trace_endpos, end);
 222                         return;
 223                 }
 224                 else
 225                 {
 226                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
 227                         if(cb)
 228                                 cb(org, trace_endpos, end);
 229                         return;
 230                 }
 231         }
 232
 233         vf = v_forward;
 234         vr = v_right;
 235         vu = v_up;
 236         o0 = org;
 237         e0 = end;
 238
 239         switch(nomonsters)
 240         {
 241                 case MOVE_WORLDONLY:
 242                 case MOVE_NOTHING:
 243                         nomonsters_adjusted = MOVE_NOMONSTERS;
 244                         break;
 245                 default:
 246                         nomonsters_adjusted = nomonsters;
 247                         break;
 248         }
 249         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 250                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 251
 252         // if starting in warpzone, first transform
 253         wz = WarpZone_Find(org + mi, org + ma);
 254         if(wz)
 255         {
 256                 WarpZone_trace_firstzone = wz;
 257                 WarpZone_trace_lastzone = wz;
 258                 if(zone && wz != zone)
 259                 {
 260                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 261                         sol = 1;
 262                         trace_fraction = 0;
 263                         trace_endpos = org;
 264                         goto fail;
 265                 }
 266                 WarpZone_Trace_AddTransform(wz);
 267                 org = WarpZone_TransformOrigin(wz, org);
 268                 end = WarpZone_TransformOrigin(wz, end);
 269         }
 270         WarpZone_MakeAllSolid();
 271         sol = -1;
 272         frac = 0;
 273         i = 16;
 274         for (;;)
 275         {
 276                 if(--i < 1)
 277                 {
 278                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 279                         trace_ent = NULL;
 280                         break;
 281                 }
 282                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
 283                 if(cb)
 284                         cb(org, trace_endpos, end);
 285                 if(sol < 0)
 286                         sol = trace_startsolid;
 287
 288                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 289                 if(trace_fraction >= 1)
 290                         break;
 291                 if(trace_ent.classname != "trigger_warpzone")
 292                 {
 293                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 294                         {
 295                                 // continue the trace, ignoring this hit (we only care for warpzones)
 296                                 org = trace_endpos + normalize(end - org);
 297                                 continue;
 298                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 299                                 // otherwise, players could block entrances that way
 300                         }
 301                         break;
 302                 }
 303                 /*if(trace_ent == wz)
 304                 {
 305                         // FIXME can this check be removed? Do we really need it?
 306                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 307                         trace_ent = NULL;
 308                         break;
 309                 }*/
 310                 wz = trace_ent;
 311                 if(!WarpZone_trace_firstzone)
 312                         WarpZone_trace_firstzone = wz;
 313                 WarpZone_trace_lastzone = wz;
 314                 if(zone && wz != zone)
 315                         break;
 316                 WarpZone_Trace_AddTransform(wz);
 317                 // we hit a warpzone... so, let's perform the trace after the warp again
 318                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 319                 end = WarpZone_TransformOrigin(wz, end);
 320
 321                 // we got warped, so let's step back a bit
 322                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
 323                 org = trace_endpos;
 324         }
 325         WarpZone_MakeAllOther();
 326 LABEL(fail)
 327         if(contentshack)
 328                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 329         trace_startsolid = sol;
 330         v_forward = vf;
 331         v_right = vr;
 332         v_up = vu;
 333 }
 334
 335 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 336 {
 337         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, NULL, WarpZone_trace_callback_t_null);
 338 }
 339
 340 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 341 {
 342         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 343 }
 344
 345 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 346 {
 347         float g, dt, i;
 348         vector vf, vr, vu, v0, o0;
 349         entity wz;
 350
 351         o0 = e.origin;
 352         v0 = e.velocity;
 353         g = cvar("sv_gravity") * e.gravity;
 354
 355         WarpZone_trace_forent = forent;
 356         WarpZone_trace_firstzone = NULL;
 357         WarpZone_trace_lastzone = NULL;
 358         WarpZone_Trace_InitTransform();
 359         WarpZone_tracetoss_time = 0;
 360         if(!warpzone_warpzones_exist)
 361         {
 362                 tracetoss(e, WarpZone_trace_forent);
 363                 if(cb)
 364                         cb(e.origin, trace_endpos, trace_endpos);
 365                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 366                 WarpZone_tracetoss_time += dt;
 367                 e.velocity_z -= dt * g;
 368                 WarpZone_tracetoss_velocity = e.velocity;
 369                 e.velocity = v0;
 370                 return;
 371         }
 372
 373         vf = v_forward;
 374         vr = v_right;
 375         vu = v_up;
 376
 377         // if starting in warpzone, first transform
 378         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 379         if(wz)
 380         {
 381                 WarpZone_trace_firstzone = wz;
 382                 WarpZone_trace_lastzone = wz;
 383                 if(zone && wz != zone)
 384                 {
 385                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 386
 387                         WarpZone_tracetoss_time = 0;
 388                         trace_endpos = o0;
 389                         goto fail;
 390                 }
 391                 WarpZone_Trace_AddTransform(wz);
 392                 vector org = WarpZone_TransformOrigin(wz, e.origin);
 393                 setorigin(e, org);
 394                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 395         }
 396         WarpZone_MakeAllSolid();
 397         i = 16;
 398         for (;;)
 399         {
 400                 if(--i < 1)
 401                 {
 402                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 403                         trace_ent = NULL;
 404                         break;
 405                 }
 406                 tracetoss(e, WarpZone_trace_forent);
 407                 if(cb)
 408                         cb(e.origin, trace_endpos, trace_endpos);
 409                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 410                 WarpZone_tracetoss_time += dt;
 411                 e.origin = trace_endpos;
 412                 e.velocity_z -= dt * g;
 413                 if(trace_fraction >= 1)
 414                         break;
 415                 if(trace_ent.classname != "trigger_warpzone")
 416                         break;
 417                 if(trace_ent == wz)
 418                 {
 419                         // FIXME can this check be removed? Do we really need it?
 420                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 421                         trace_ent = NULL;
 422                         break;
 423                 }
 424                 wz = trace_ent;
 425                 if(!WarpZone_trace_firstzone)
 426                         WarpZone_trace_firstzone = wz;
 427                 WarpZone_trace_lastzone = wz;
 428                 if(zone && wz != zone)
 429                         break;
 430                 WarpZone_Trace_AddTransform(wz);
 431                 // we hit a warpzone... so, let's perform the trace after the warp again
 432                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 433                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 434
 435                 // we got warped, so let's step back a bit
 436                 e.velocity = -e.velocity;
 437                 tracetoss(e, WarpZone_trace_forent);
 438                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 439                 WarpZone_tracetoss_time -= dt;
 440                 e.origin = trace_endpos;
 441                 e.velocity = -e.velocity;
 442         }
 443         WarpZone_MakeAllOther();
 444 LABEL(fail)
 445         WarpZone_tracetoss_velocity = e.velocity;
 446         v_forward = vf;
 447         v_right = vr;
 448         v_up = vu;
 449         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 450         e.velocity = v0;
 451         e.origin = o0;
 452 }
 453
 454 void WarpZone_TraceToss(entity e, entity forent)
 455 {
 456         WarpZone_TraceToss_ThroughZone(e, forent, NULL, WarpZone_trace_callback_t_null);
 457 }
 458
 459 entity WarpZone_TrailParticles_trace_callback_own;
 460 float WarpZone_TrailParticles_trace_callback_eff;
 461 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 462 {
 463         __trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 464 }
 465
 466 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 467 {
 468         WarpZone_TrailParticles_trace_callback_own = own;
 469         WarpZone_TrailParticles_trace_callback_eff = eff;
 470         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_trace_callback);
 471 }
 472
 473 #ifdef CSQC
 474 float WarpZone_TrailParticles_trace_callback_f;
 475 float WarpZone_TrailParticles_trace_callback_flags;
 476 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
 477 {
 478         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
 479 }
 480
 481 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, int boxflags)
 482 {
 483         WarpZone_TrailParticles_trace_callback_own = own;
 484         WarpZone_TrailParticles_trace_callback_eff = eff;
 485         WarpZone_TrailParticles_trace_callback_f = f;
 486         WarpZone_TrailParticles_trace_callback_flags = boxflags | PARTICLES_DRAWASTRAIL;
 487         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_WithMultiplier_trace_callback);
 488 }
 489 #endif
 490
 491 float WarpZone_PlaneDist(entity wz, vector v)
 492 {
 493         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 494 }
 495
 496 float WarpZone_TargetPlaneDist(entity wz, vector v)
 497 {
 498         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 499 }
 500
 501 vector WarpZone_TransformOrigin(entity wz, vector v)
 502 {
 503         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 504 }
 505
 506 vector WarpZone_TransformVelocity(entity wz, vector v)
 507 {
 508         return AnglesTransform_Apply(wz.warpzone_transform, v);
 509 }
 510
 511 vector WarpZone_TransformAngles(entity wz, vector v)
 512 {
 513         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 514 }
 515
 516 vector WarpZone_TransformVAngles(entity wz, vector ang)
 517 {
 518 #ifdef KEEP_ROLL
 519         float roll;
 520         roll = ang.z;
 521         ang.z = 0;
 522 #endif
 523
 524         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 525
 526 #ifdef KEEP_ROLL
 527         ang = AnglesTransform_Normalize(ang, true);
 528         ang = AnglesTransform_CancelRoll(ang);
 529         ang.z = roll;
 530 #else
 531         ang = AnglesTransform_Normalize(ang, false);
 532 #endif
 533
 534         return ang;
 535 }
 536
 537 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 538 {
 539         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 540 }
 541
 542 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 543 {
 544         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 545 }
 546
 547 vector WarpZone_UnTransformAngles(entity wz, vector v)
 548 {
 549         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 550 }
 551
 552 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 553 {
 554         float roll;
 555
 556         roll = ang.z;
 557         ang.z = 0;
 558
 559         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 560         ang = AnglesTransform_Normalize(ang, true);
 561         ang = AnglesTransform_CancelRoll(ang);
 562
 563         ang.z = roll;
 564         return ang;
 565 }
 566
 567 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 568 {
 569         vector nearest;
 570         nearest.x = bound(mi.x, org.x, ma.x);
 571         nearest.y = bound(mi.y, org.y, ma.y);
 572         nearest.z = bound(mi.z, org.z, ma.z);
 573         return nearest;
 574 }
 575
 576 bool WarpZoneLib_BadEntity(entity e)
 577 {
 578         if (is_pure(e)) return true;
 579         string s = e.classname;
 580
 581         //if (s == "net_linked") return true; // actually some real entities are linked without classname, fail
 582         if (s == "") return true;
 583
 584         if (startsWith(s, "target_")) return true;
 585
 586         if (startsWith(s, "info_")) return true;
 587
 588         return false;
 589 }
 590
 591 .float WarpZone_findradius_hit;
 592 .entity WarpZone_findradius_next;
 593 void WarpZone_FindRadius_Recurse(
 594     /** blast origin of current search */
 595     vector org,
 596     float rad,
 597     /** original blast origin */
 598     vector org0,
 599     /** how to untransform (victim to blast system) */
 600     vector transform,
 601     vector shift,
 602     bool needlineofsight)
 603 {
 604         if (rad <= 0) return;
 605         entity wz = NULL;
 606         FOREACH_ENTITY_RADIUS(org, rad, !WarpZoneLib_BadEntity(it), {
 607                 vector p = WarpZoneLib_NearestPointOnBox(it.origin + it.mins, it.origin + it.maxs, org0);
 608                 if (needlineofsight)
 609                 {
 610                         traceline(org, p, MOVE_NOMONSTERS, it);
 611                         if (trace_fraction < 1) continue;
 612                 }
 613                 if (!it.WarpZone_findradius_hit || vlen2(it.WarpZone_findradius_dist) > vlen2(org0 - p))
 614                 {
 615                         it.WarpZone_findradius_nearest = p;
 616                         it.WarpZone_findradius_dist = org0 - p;
 617                         it.WarpZone_findradius_findorigin = org;
 618                         it.WarpZone_findradius_findradius = rad;
 619                         if (it.classname == "warpzone_refsys")
 620                         {
 621                                 // ignore, especially: do not overwrite the refsys parameters
 622                         }
 623                         else if (it.classname == "trigger_warpzone")
 624                         {
 625                                 it.WarpZone_findradius_next = wz;
 626                                 wz = it;
 627                                 it.WarpZone_findradius_hit = 1;
 628                                 it.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 629                                 it.enemy.WarpZone_findradius_hit = 1;
 630                         }
 631                         else
 632                         {
 633                                 it.warpzone_transform = transform;
 634                                 it.warpzone_shift = shift;
 635                                 it.WarpZone_findradius_hit = 1;
 636                         }
 637                 }
 638     });
 639         for(entity e = wz; e; e = e.WarpZone_findradius_next)
 640         {
 641                 if (WarpZoneLib_BadEntity(e)) continue;
 642
 643                 vector org0_new = WarpZone_TransformOrigin(e, org);
 644                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 645                 vector org_new = trace_endpos;
 646
 647                 vector transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 648                 vector shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 649                 WarpZone_FindRadius_Recurse(
 650                         org_new,
 651                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 652                         org0_new,
 653                         transform_new, shift_new,
 654                         needlineofsight);
 655                 e.WarpZone_findradius_hit = 0;
 656                 e.enemy.WarpZone_findradius_hit = 0;
 657         }
 658 }
 659 entity WarpZone_FindRadius(vector org, float rad, bool needlineofsight)
 660 {
 661     // FIXME: why can't we do this? (sometimes finds nothing, breaking explosions)
 662     // if (!warpzone_warpzones_exist && !needlineofsight) return findradius(org, rad);
 663         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 664         entity list_first = findchainfloat(WarpZone_findradius_hit, 1);
 665         FOREACH_LIST(list, chain, true, it.WarpZone_findradius_hit = 0);
 666         return list_first;
 667 }
 668
 669 .entity WarpZone_refsys;
 670 void WarpZone_RefSys_GC(entity this)
 671 {
 672         // garbage collect unused reference systems
 673         this.nextthink = time + 1;
 674         if(this.owner.WarpZone_refsys != this)
 675                 delete(this);
 676 }
 677 void WarpZone_RefSys_CheckCreate(entity me)
 678 {
 679         if(me.WarpZone_refsys.owner != me)
 680         {
 681                 me.WarpZone_refsys = new(warpzone_refsys);
 682                 me.WarpZone_refsys.owner = me;
 683                 setthink(me.WarpZone_refsys, WarpZone_RefSys_GC);
 684                 me.WarpZone_refsys.nextthink = time + 1;
 685                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 686         }
 687 }
 688 void WarpZone_RefSys_Clear(entity me)
 689 {
 690         if(me.WarpZone_refsys)
 691         {
 692                 delete(me.WarpZone_refsys);
 693                 me.WarpZone_refsys = NULL;
 694         }
 695 }
 696 void WarpZone_RefSys_AddTransform(entity me, vector t, vector s)
 697 {
 698         if(t != '0 0 0' || s != '0 0 0')
 699         {
 700                 WarpZone_RefSys_CheckCreate(me);
 701                 WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 702         }
 703 }
 704 void WarpZone_RefSys_Add(entity me, entity wz)
 705 {
 706         WarpZone_RefSys_AddTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 707 }
 708 void WarpZone_RefSys_AddInverseTransform(entity me, vector t, vector s)
 709 {
 710         if(t != '0 0 0' || s != '0 0 0')
 711         {
 712                 WarpZone_RefSys_CheckCreate(me);
 713                 WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, t, s);
 714         }
 715 }
 716 void WarpZone_RefSys_AddInverse(entity me, entity wz)
 717 {
 718         WarpZone_RefSys_AddInverseTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 719 }
 720 .vector WarpZone_refsys_incremental_shift;
 721 .vector WarpZone_refsys_incremental_transform;
 722 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 723 {
 724         //vector t, s;
 725         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 726         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 727                 return;
 728         WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, me.WarpZone_refsys_incremental_transform, me.WarpZone_refsys_incremental_shift);
 729         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
 730         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 731         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 732 }
 733 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 734 {
 735         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 736         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 737 }
 738 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 739 {
 740         if(from.WarpZone_refsys)
 741                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 742         if(to.WarpZone_refsys)
 743                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 744         return org;
 745 }
 746 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 747 {
 748         if(from.WarpZone_refsys)
 749                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 750         if(to.WarpZone_refsys)
 751                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 752         return vel;
 753 }
 754 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 755 {
 756         if(from.WarpZone_refsys)
 757                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 758         if(to.WarpZone_refsys)
 759                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 760         return ang;
 761 }
 762 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 763 {
 764         if(from.WarpZone_refsys)
 765                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 766         if(to.WarpZone_refsys)
 767                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 768         return ang;
 769 }
 770 void WarpZone_RefSys_Copy(entity me, entity from)
 771 {
 772         if(from.WarpZone_refsys)
 773         {
 774                 WarpZone_RefSys_CheckCreate(me);
 775                 me.WarpZone_refsys.warpzone_shift = from.WarpZone_refsys.warpzone_shift;
 776                 me.WarpZone_refsys.warpzone_transform = from.WarpZone_refsys.warpzone_transform;
 777         }
 778         else
 779                 WarpZone_RefSys_Clear(me);
 780 }
 781 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 782 {
 783         entity e;
 784         e = spawn();
 785         WarpZone_RefSys_Copy(e, me);
 786         return e;
 787 }
 788
 789 bool WarpZoneLib_ExactTrigger_Touch(entity this, entity toucher)
 790 {
 791         return !WarpZoneLib_BoxTouchesBrush(toucher.absmin, toucher.absmax, this, toucher);
 792 }
 793
 794
 795 void WarpZoneLib_MoveOutOfSolid_Expand(entity e, vector by)
 796 {
 797         float eps = 0.0625;
 798         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
 799         if (trace_startsolid)
 800                 return;
 801         if (trace_fraction < 1)
 802         {
 803                 // hit something
 804                 // adjust origin in the other direction...
 805                 setorigin(e, e.origin - by * (1 - trace_fraction));
 806         }
 807 }
 808
 809 bool WarpZoneLib_MoveOutOfSolid(entity e)
 810 {
 811         vector o = e.origin;
 812         traceline(o, o, MOVE_WORLDONLY, e);
 813         if (trace_startsolid)
 814                 return false;
 815
 816         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
 817         if (!trace_startsolid)
 818                 return true;
 819
 820         vector m0 = e.mins;
 821         vector m1 = e.maxs;
 822         e.mins = '0 0 0';
 823         e.maxs = '0 0 0';
 824         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m0.x); e.mins_x = m0.x;
 825         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m1.x); e.maxs_x = m1.x;
 826         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m0.y); e.mins_y = m0.y;
 827         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m1.y); e.maxs_y = m1.y;
 828         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m0.z); e.mins_z = m0.z;
 829         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m1.z); e.maxs_z = m1.z;
 830         setorigin(e, e.origin);
 831
 832         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 833         if (trace_startsolid)
 834         {
 835                 setorigin(e, o);
 836                 return false;
 837         }
 838
 839         return true;
 840 }