qcsrc/lib/warpzone/common.qc

   1 #include "common.qh"
   2
   3 #if defined(CSQC)
   4     #include <common/t_items.qh>
   5 #elif defined(MENUQC)
   6 #elif defined(SVQC)
   7     #include <common/weapons/_all.qh>
   8 #endif
   9
  10 void WarpZone_Accumulator_Clear(entity acc)
  11 {
  12         acc.warpzone_transform = '0 0 0';
  13         acc.warpzone_shift = '0 0 0';
  14 }
  15 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  16 {
  17         vector tr, st;
  18         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  19         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  20         acc.warpzone_transform = tr;
  21         acc.warpzone_shift = st;
  22 }
  23 void WarpZone_Accumulator_Add(entity acc, entity wz)
  24 {
  25         WarpZone_Accumulator_AddTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  26 }
  27 void WarpZone_Accumulator_AddInverseTransform(entity acc, vector t, vector s)
  28 {
  29         vector tt, ss;
  30         tt = AnglesTransform_Invert(t);
  31         ss = AnglesTransform_PrePostShift_GetPostShift(s, tt, '0 0 0');
  32         WarpZone_Accumulator_AddTransform(acc, tt, ss);
  33         // yes, this probably can be done simpler... but this way is "obvious" :)
  34 }
  35 void WarpZone_Accumulator_AddInverse(entity acc, entity wz)
  36 {
  37         WarpZone_Accumulator_AddInverseTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  38 }
  39
  40 float autocvar_cl_warpzone_usetrace = 1;
  41 vector WarpZone_camera_transform(entity this, vector org, vector ang)
  42 {
  43         vector vf, vr, vu;
  44         if(this.warpzone_fadestart)
  45                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  46                         return org;
  47                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  48                         // unneeded on client, on server this helps a lot
  49         vf = v_forward;
  50         vr = v_right;
  51         vu = v_up;
  52         org = WarpZone_TransformOrigin(this, org);
  53         vf = WarpZone_TransformVelocity(this, vf);
  54         vr = WarpZone_TransformVelocity(this, vr);
  55         vu = WarpZone_TransformVelocity(this, vu);
  56         if(autocvar_cl_warpzone_usetrace)
  57                 traceline(this.warpzone_targetorigin, org, MOVE_NOMONSTERS, NULL);
  58         else
  59                 trace_endpos = this.warpzone_targetorigin;
  60         v_forward = vf;
  61         v_right = vr;
  62         v_up = vu;
  63         return org;
  64 }
  65
  66 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  67 {
  68         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  69         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  70         e.warpzone_origin = my_org;
  71         e.warpzone_targetorigin = other_org;
  72         e.warpzone_angles = my_ang;
  73         e.warpzone_targetangles = other_ang;
  74         FIXED_MAKE_VECTORS_NEW(my_ang, forward, right, up);
  75         e.warpzone_forward = forward;
  76         FIXED_MAKE_VECTORS(other_ang, forward, right, up);
  77         e.warpzone_targetforward = forward;
  78         setcamera_transform(e, WarpZone_camera_transform);
  79 }
  80
  81 vector WarpZone_Camera_camera_transform(entity this, vector org, vector ang)
  82 {
  83         // a fixed camera view
  84         if(this.warpzone_fadestart)
  85                 if(vdist(org - this.origin - 0.5 * (this.mins + this.maxs), >, this.warpzone_fadeend + 400))
  86                         return org;
  87                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  88                         // unneeded on client, on server this helps a lot
  89         trace_endpos = this.warpzone_origin;
  90         makevectors(this.warpzone_angles);
  91         return this.warpzone_origin;
  92 }
  93
  94 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  95 {
  96         e.warpzone_origin = my_org;
  97         e.warpzone_angles = my_ang;
  98         setcamera_transform(e, WarpZone_Camera_camera_transform);
  99 }
 100
 101 .entity enemy;
 102
 103 vector WarpZoneLib_BoxTouchesBrush_mins;
 104 vector WarpZoneLib_BoxTouchesBrush_maxs;
 105 entity WarpZoneLib_BoxTouchesBrush_ent;
 106 entity WarpZoneLib_BoxTouchesBrush_ignore;
 107 float WarpZoneLib_BoxTouchesBrush_Recurse()
 108 {
 109         float s;
 110         entity se;
 111         float f;
 112
 113         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
 114 #ifdef CSQC
 115         if (trace_networkentity)
 116         {
 117                 LOG_TRACE("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush");
 118                 // we cannot continue, as a player blocks us...
 119                 // so, abort
 120                 return 0;
 121         }
 122 #endif
 123         if (!trace_ent)
 124                 return 0;
 125         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
 126                 return 1;
 127
 128         se = trace_ent;
 129         s = se.solid;
 130         se.solid = SOLID_NOT;
 131         f = WarpZoneLib_BoxTouchesBrush_Recurse();
 132         se.solid = s;
 133
 134         return f;
 135 }
 136
 137 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 138 {
 139     float f, s;
 140
 141     if(!e.modelindex || e.warpzone_isboxy)
 142         return 1;
 143
 144     s = e.solid;
 145     e.solid = SOLID_BSP;
 146     WarpZoneLib_BoxTouchesBrush_mins = mi;
 147     WarpZoneLib_BoxTouchesBrush_maxs = ma;
 148     WarpZoneLib_BoxTouchesBrush_ent = e;
 149     WarpZoneLib_BoxTouchesBrush_ignore = ig;
 150     f = WarpZoneLib_BoxTouchesBrush_Recurse();
 151     e.solid = s;
 152
 153     return f;
 154 }
 155
 156 entity WarpZone_Find(vector mi, vector ma)
 157 {
 158         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 159         if(!warpzone_warpzones_exist)
 160                 return NULL;
 161         IL_EACH(g_warpzones, WarpZoneLib_BoxTouchesBrush(mi, ma, it, NULL),
 162         {
 163                 return it;
 164         });
 165         return NULL;
 166 }
 167
 168 void WarpZone_MakeAllSolid()
 169 {
 170         if(!warpzone_warpzones_exist)
 171                 return;
 172         IL_EACH(g_warpzones, true,
 173         {
 174                 it.solid = SOLID_BSP;
 175         });
 176 }
 177
 178 void WarpZone_MakeAllOther()
 179 {
 180         if(!warpzone_warpzones_exist)
 181                 return;
 182         IL_EACH(g_warpzones, true,
 183         {
 184                 it.solid = SOLID_TRIGGER;
 185         });
 186 }
 187
 188 void WarpZone_Trace_InitTransform()
 189 {
 190         if(!WarpZone_trace_transform)
 191         {
 192                 WarpZone_trace_transform = new_pure(warpzone_trace_transform);
 193         }
 194         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 195 }
 196 void WarpZone_Trace_AddTransform(entity wz)
 197 {
 198         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 199 }
 200
 201 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 202 {
 203         float nomonsters_adjusted;
 204         float frac, sol, i;
 205         float contentshack;
 206         entity wz;
 207
 208         WarpZone_trace_forent = forent;
 209         WarpZone_trace_firstzone = NULL;
 210         WarpZone_trace_lastzone = NULL;
 211         WarpZone_Trace_InitTransform();
 212         if(!warpzone_warpzones_exist)
 213         {
 214                 if(nomonsters == MOVE_NOTHING)
 215                 {
 216                         trace_endpos = end;
 217                         trace_fraction = 1;
 218                         if(cb)
 219                                 cb(org, trace_endpos, end);
 220                         return;
 221                 }
 222                 else
 223                 {
 224                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
 225                         if(cb)
 226                                 cb(org, trace_endpos, end);
 227                         return;
 228                 }
 229         }
 230
 231         switch(nomonsters)
 232         {
 233                 case MOVE_WORLDONLY:
 234                 case MOVE_NOTHING:
 235                         nomonsters_adjusted = MOVE_NOMONSTERS;
 236                         break;
 237                 default:
 238                         nomonsters_adjusted = nomonsters;
 239                         break;
 240         }
 241         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 242                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 243
 244         // if starting in warpzone, first transform
 245         wz = WarpZone_Find(org + mi, org + ma);
 246         if(wz)
 247         {
 248                 WarpZone_trace_firstzone = wz;
 249                 WarpZone_trace_lastzone = wz;
 250                 if(zone && wz != zone)
 251                 {
 252                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 253                         sol = 1;
 254                         trace_fraction = 0;
 255                         trace_endpos = org;
 256                         goto fail;
 257                 }
 258                 WarpZone_Trace_AddTransform(wz);
 259                 org = WarpZone_TransformOrigin(wz, org);
 260                 end = WarpZone_TransformOrigin(wz, end);
 261         }
 262         WarpZone_MakeAllSolid();
 263         sol = -1;
 264         frac = 0;
 265         i = 16;
 266         for (;;)
 267         {
 268                 if(--i < 1)
 269                 {
 270                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 271                         trace_ent = NULL;
 272                         break;
 273                 }
 274                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
 275                 if(cb)
 276                         cb(org, trace_endpos, end);
 277                 if(sol < 0)
 278                         sol = trace_startsolid;
 279
 280                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 281                 if(trace_fraction >= 1)
 282                         break;
 283                 if(trace_ent.classname != "trigger_warpzone")
 284                 {
 285                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 286                         {
 287                                 // continue the trace, ignoring this hit (we only care for warpzones)
 288                                 org = trace_endpos + normalize(end - org);
 289                                 continue;
 290                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 291                                 // otherwise, players could block entrances that way
 292                         }
 293                         break;
 294                 }
 295                 /*if(trace_ent == wz)
 296                 {
 297                         // FIXME can this check be removed? Do we really need it?
 298                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 299                         trace_ent = NULL;
 300                         break;
 301                 }*/
 302                 wz = trace_ent;
 303                 if(!WarpZone_trace_firstzone)
 304                         WarpZone_trace_firstzone = wz;
 305                 WarpZone_trace_lastzone = wz;
 306                 if(zone && wz != zone)
 307                         break;
 308                 WarpZone_Trace_AddTransform(wz);
 309                 // we hit a warpzone... so, let's perform the trace after the warp again
 310                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 311                 end = WarpZone_TransformOrigin(wz, end);
 312
 313                 // we got warped, so let's step back a bit
 314                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
 315                 org = trace_endpos;
 316         }
 317         WarpZone_MakeAllOther();
 318 LABEL(fail)
 319         if(contentshack)
 320                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 321         trace_startsolid = sol;
 322 }
 323
 324 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 325 {
 326         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, NULL, WarpZone_trace_callback_t_null);
 327 }
 328
 329 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 330 {
 331         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 332 }
 333
 334 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 335 {
 336         float g, dt, i;
 337         vector v0, o0;
 338         entity wz;
 339
 340         o0 = e.origin;
 341         v0 = e.velocity;
 342         g = cvar("sv_gravity") * e.gravity;
 343
 344         WarpZone_trace_forent = forent;
 345         WarpZone_trace_firstzone = NULL;
 346         WarpZone_trace_lastzone = NULL;
 347         WarpZone_Trace_InitTransform();
 348         WarpZone_tracetoss_time = 0;
 349         if(!warpzone_warpzones_exist)
 350         {
 351                 tracetoss(e, WarpZone_trace_forent);
 352                 if(cb)
 353                         cb(e.origin, trace_endpos, trace_endpos);
 354                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 355                 WarpZone_tracetoss_time += dt;
 356                 e.velocity_z -= dt * g;
 357                 WarpZone_tracetoss_velocity = e.velocity;
 358                 e.velocity = v0;
 359                 return;
 360         }
 361
 362         // if starting in warpzone, first transform
 363         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 364         if(wz)
 365         {
 366                 WarpZone_trace_firstzone = wz;
 367                 WarpZone_trace_lastzone = wz;
 368                 if(zone && wz != zone)
 369                 {
 370                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 371
 372                         WarpZone_tracetoss_time = 0;
 373                         trace_endpos = o0;
 374                         goto fail;
 375                 }
 376                 WarpZone_Trace_AddTransform(wz);
 377                 vector org = WarpZone_TransformOrigin(wz, e.origin);
 378                 setorigin(e, org);
 379                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 380         }
 381         WarpZone_MakeAllSolid();
 382         i = 16;
 383         for (;;)
 384         {
 385                 if(--i < 1)
 386                 {
 387                         LOG_TRACE("Too many warpzones in sequence, aborting trace.");
 388                         trace_ent = NULL;
 389                         break;
 390                 }
 391                 tracetoss(e, WarpZone_trace_forent);
 392                 if(cb)
 393                         cb(e.origin, trace_endpos, trace_endpos);
 394                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 395                 WarpZone_tracetoss_time += dt;
 396                 e.origin = trace_endpos;
 397                 e.velocity_z -= dt * g;
 398                 if(trace_fraction >= 1)
 399                         break;
 400                 if(trace_ent.classname != "trigger_warpzone")
 401                         break;
 402                 if(trace_ent == wz)
 403                 {
 404                         // FIXME can this check be removed? Do we really need it?
 405                         LOG_TRACE("I transformed into the same zone again, wtf, aborting the trace");
 406                         trace_ent = NULL;
 407                         break;
 408                 }
 409                 wz = trace_ent;
 410                 if(!WarpZone_trace_firstzone)
 411                         WarpZone_trace_firstzone = wz;
 412                 WarpZone_trace_lastzone = wz;
 413                 if(zone && wz != zone)
 414                         break;
 415                 WarpZone_Trace_AddTransform(wz);
 416                 // we hit a warpzone... so, let's perform the trace after the warp again
 417                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 418                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 419
 420                 // we got warped, so let's step back a bit
 421                 e.velocity = -e.velocity;
 422                 tracetoss(e, WarpZone_trace_forent);
 423                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 424                 WarpZone_tracetoss_time -= dt;
 425                 e.origin = trace_endpos;
 426                 e.velocity = -e.velocity;
 427         }
 428         WarpZone_MakeAllOther();
 429 LABEL(fail)
 430         WarpZone_tracetoss_velocity = e.velocity;
 431         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 432         e.velocity = v0;
 433         e.origin = o0;
 434 }
 435
 436 void WarpZone_TraceToss(entity e, entity forent)
 437 {
 438         WarpZone_TraceToss_ThroughZone(e, forent, NULL, WarpZone_trace_callback_t_null);
 439 }
 440
 441 entity WarpZone_TrailParticles_trace_callback_own;
 442 float WarpZone_TrailParticles_trace_callback_eff;
 443 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 444 {
 445         __trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 446 }
 447
 448 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 449 {
 450         WarpZone_TrailParticles_trace_callback_own = own;
 451         WarpZone_TrailParticles_trace_callback_eff = eff;
 452         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_trace_callback);
 453 }
 454
 455 #ifdef CSQC
 456 float WarpZone_TrailParticles_trace_callback_f;
 457 float WarpZone_TrailParticles_trace_callback_flags;
 458 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
 459 {
 460         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
 461 }
 462
 463 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, int boxflags)
 464 {
 465         WarpZone_TrailParticles_trace_callback_own = own;
 466         WarpZone_TrailParticles_trace_callback_eff = eff;
 467         WarpZone_TrailParticles_trace_callback_f = f;
 468         WarpZone_TrailParticles_trace_callback_flags = boxflags | PARTICLES_DRAWASTRAIL;
 469         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, NULL, NULL, WarpZone_TrailParticles_WithMultiplier_trace_callback);
 470 }
 471 #endif
 472
 473 float WarpZone_PlaneDist(entity wz, vector v)
 474 {
 475         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 476 }
 477
 478 float WarpZone_TargetPlaneDist(entity wz, vector v)
 479 {
 480         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 481 }
 482
 483 vector WarpZone_TransformOrigin(entity wz, vector v)
 484 {
 485         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 486 }
 487
 488 vector WarpZone_TransformVelocity(entity wz, vector v)
 489 {
 490         return AnglesTransform_Apply(wz.warpzone_transform, v);
 491 }
 492
 493 vector WarpZone_TransformAngles(entity wz, vector v)
 494 {
 495         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 496 }
 497
 498 vector WarpZone_TransformVAngles(entity wz, vector ang)
 499 {
 500 #ifdef KEEP_ROLL
 501         float roll;
 502         roll = ang.z;
 503         ang.z = 0;
 504 #endif
 505
 506         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 507
 508 #ifdef KEEP_ROLL
 509         ang = AnglesTransform_Normalize(ang, true);
 510         ang = AnglesTransform_CancelRoll(ang);
 511         ang.z = roll;
 512 #else
 513         ang = AnglesTransform_Normalize(ang, false);
 514 #endif
 515
 516         return ang;
 517 }
 518
 519 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 520 {
 521         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 522 }
 523
 524 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 525 {
 526         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 527 }
 528
 529 vector WarpZone_UnTransformAngles(entity wz, vector v)
 530 {
 531         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 532 }
 533
 534 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 535 {
 536         float roll;
 537
 538         roll = ang.z;
 539         ang.z = 0;
 540
 541         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 542         ang = AnglesTransform_Normalize(ang, true);
 543         ang = AnglesTransform_CancelRoll(ang);
 544
 545         ang.z = roll;
 546         return ang;
 547 }
 548
 549 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 550 {
 551         vector nearest;
 552         nearest.x = bound(mi.x, org.x, ma.x);
 553         nearest.y = bound(mi.y, org.y, ma.y);
 554         nearest.z = bound(mi.z, org.z, ma.z);
 555         return nearest;
 556 }
 557
 558 bool WarpZoneLib_BadEntity(entity e)
 559 {
 560         if (is_pure(e)) return true;
 561         string s = e.classname;
 562
 563         //if (s == "net_linked") return true; // actually some real entities are linked without classname, fail
 564         if (s == "") return true;
 565
 566         if (startsWith(s, "target_")) return true;
 567
 568         if (startsWith(s, "info_")) return true;
 569
 570         return false;
 571 }
 572
 573 .float WarpZone_findradius_hit;
 574 .entity WarpZone_findradius_next;
 575 void WarpZone_FindRadius_Recurse(
 576     /** blast origin of current search */
 577     vector org,
 578     float rad,
 579     /** original blast origin */
 580     vector org0,
 581     /** how to untransform (victim to blast system) */
 582     vector transform,
 583     vector shift,
 584     bool needlineofsight)
 585 {
 586         if (rad <= 0) return;
 587         entity wz = NULL;
 588         FOREACH_ENTITY_RADIUS(org, rad, !WarpZoneLib_BadEntity(it), {
 589                 vector p = WarpZoneLib_NearestPointOnBox(it.origin + it.mins, it.origin + it.maxs, org0);
 590                 if (needlineofsight)
 591                 {
 592                         traceline(org, p, MOVE_NOMONSTERS, it);
 593                         if (trace_fraction < 1) continue;
 594                 }
 595                 if (!it.WarpZone_findradius_hit || vlen2(it.WarpZone_findradius_dist) > vlen2(org0 - p))
 596                 {
 597                         it.WarpZone_findradius_nearest = p;
 598                         it.WarpZone_findradius_dist = org0 - p;
 599                         it.WarpZone_findradius_findorigin = org;
 600                         it.WarpZone_findradius_findradius = rad;
 601                         if (it.classname == "warpzone_refsys")
 602                         {
 603                                 // ignore, especially: do not overwrite the refsys parameters
 604                         }
 605                         else if (it.classname == "trigger_warpzone")
 606                         {
 607                                 it.WarpZone_findradius_next = wz;
 608                                 wz = it;
 609                                 it.WarpZone_findradius_hit = 1;
 610                                 it.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 611                                 it.enemy.WarpZone_findradius_hit = 1;
 612                         }
 613                         else
 614                         {
 615                                 it.warpzone_transform = transform;
 616                                 it.warpzone_shift = shift;
 617                                 it.WarpZone_findradius_hit = 1;
 618                         }
 619                 }
 620     });
 621         for(entity e = wz; e; e = e.WarpZone_findradius_next)
 622         {
 623                 if (WarpZoneLib_BadEntity(e)) continue;
 624
 625                 vector org0_new = WarpZone_TransformOrigin(e, org);
 626                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 627                 vector org_new = trace_endpos;
 628
 629                 vector transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 630                 vector shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 631                 WarpZone_FindRadius_Recurse(
 632                         org_new,
 633                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 634                         org0_new,
 635                         transform_new, shift_new,
 636                         needlineofsight);
 637                 e.WarpZone_findradius_hit = 0;
 638                 e.enemy.WarpZone_findradius_hit = 0;
 639         }
 640 }
 641 entity WarpZone_FindRadius(vector org, float rad, bool needlineofsight)
 642 {
 643     // FIXME: why can't we do this? (sometimes finds nothing, breaking explosions)
 644     // if (!warpzone_warpzones_exist && !needlineofsight) return findradius(org, rad);
 645         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 646         entity list_first = findchainfloat(WarpZone_findradius_hit, 1);
 647         FOREACH_LIST(list, chain, true, it.WarpZone_findradius_hit = 0);
 648         return list_first;
 649 }
 650
 651 .entity WarpZone_refsys;
 652 void WarpZone_RefSys_GC(entity this)
 653 {
 654         // garbage collect unused reference systems
 655         this.nextthink = time + 1;
 656         if(this.owner.WarpZone_refsys != this)
 657                 delete(this);
 658 }
 659 void WarpZone_RefSys_CheckCreate(entity me)
 660 {
 661         if(me.WarpZone_refsys.owner != me)
 662         {
 663                 me.WarpZone_refsys = new(warpzone_refsys);
 664                 me.WarpZone_refsys.owner = me;
 665                 setthink(me.WarpZone_refsys, WarpZone_RefSys_GC);
 666                 me.WarpZone_refsys.nextthink = time + 1;
 667                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 668         }
 669 }
 670 void WarpZone_RefSys_Clear(entity me)
 671 {
 672         if(me.WarpZone_refsys)
 673         {
 674                 delete(me.WarpZone_refsys);
 675                 me.WarpZone_refsys = NULL;
 676         }
 677 }
 678 void WarpZone_RefSys_AddTransform(entity me, vector t, vector s)
 679 {
 680         if(t != '0 0 0' || s != '0 0 0')
 681         {
 682                 WarpZone_RefSys_CheckCreate(me);
 683                 WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 684         }
 685 }
 686 void WarpZone_RefSys_Add(entity me, entity wz)
 687 {
 688         WarpZone_RefSys_AddTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 689 }
 690 void WarpZone_RefSys_AddInverseTransform(entity me, vector t, vector s)
 691 {
 692         if(t != '0 0 0' || s != '0 0 0')
 693         {
 694                 WarpZone_RefSys_CheckCreate(me);
 695                 WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, t, s);
 696         }
 697 }
 698 void WarpZone_RefSys_AddInverse(entity me, entity wz)
 699 {
 700         WarpZone_RefSys_AddInverseTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 701 }
 702 .vector WarpZone_refsys_incremental_shift;
 703 .vector WarpZone_refsys_incremental_transform;
 704 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 705 {
 706         //vector t, s;
 707         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 708         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 709                 return;
 710         WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, me.WarpZone_refsys_incremental_transform, me.WarpZone_refsys_incremental_shift);
 711         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
 712         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 713         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 714 }
 715 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 716 {
 717         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 718         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 719 }
 720 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 721 {
 722         if(from.WarpZone_refsys)
 723                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 724         if(to.WarpZone_refsys)
 725                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 726         return org;
 727 }
 728 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 729 {
 730         if(from.WarpZone_refsys)
 731                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 732         if(to.WarpZone_refsys)
 733                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 734         return vel;
 735 }
 736 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 737 {
 738         if(from.WarpZone_refsys)
 739                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 740         if(to.WarpZone_refsys)
 741                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 742         return ang;
 743 }
 744 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 745 {
 746         if(from.WarpZone_refsys)
 747                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 748         if(to.WarpZone_refsys)
 749                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 750         return ang;
 751 }
 752 void WarpZone_RefSys_Copy(entity me, entity from)
 753 {
 754         if(from.WarpZone_refsys)
 755         {
 756                 WarpZone_RefSys_CheckCreate(me);
 757                 me.WarpZone_refsys.warpzone_shift = from.WarpZone_refsys.warpzone_shift;
 758                 me.WarpZone_refsys.warpzone_transform = from.WarpZone_refsys.warpzone_transform;
 759         }
 760         else
 761                 WarpZone_RefSys_Clear(me);
 762 }
 763 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 764 {
 765         entity e;
 766         e = spawn();
 767         WarpZone_RefSys_Copy(e, me);
 768         return e;
 769 }
 770
 771 bool WarpZoneLib_ExactTrigger_Touch(entity this, entity toucher)
 772 {
 773         return !WarpZoneLib_BoxTouchesBrush(toucher.absmin, toucher.absmax, this, toucher);
 774 }
 775
 776
 777 void WarpZoneLib_MoveOutOfSolid_Expand(entity e, vector by)
 778 {
 779         float eps = 0.0625;
 780         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
 781         if (trace_startsolid)
 782                 return;
 783         if (trace_fraction < 1)
 784         {
 785                 // hit something
 786                 // adjust origin in the other direction...
 787                 setorigin(e, e.origin - by * (1 - trace_fraction));
 788         }
 789 }
 790
 791 bool WarpZoneLib_MoveOutOfSolid(entity e)
 792 {
 793         vector o = e.origin;
 794         traceline(o, o, MOVE_WORLDONLY, e);
 795         if (trace_startsolid)
 796                 return false;
 797
 798         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
 799         if (!trace_startsolid)
 800                 return true;
 801
 802         vector m0 = e.mins;
 803         vector m1 = e.maxs;
 804         e.mins = '0 0 0';
 805         e.maxs = '0 0 0';
 806         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m0.x); e.mins_x = m0.x;
 807         WarpZoneLib_MoveOutOfSolid_Expand(e, eX * m1.x); e.maxs_x = m1.x;
 808         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m0.y); e.mins_y = m0.y;
 809         WarpZoneLib_MoveOutOfSolid_Expand(e, eY * m1.y); e.maxs_y = m1.y;
 810         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m0.z); e.mins_z = m0.z;
 811         WarpZoneLib_MoveOutOfSolid_Expand(e, eZ * m1.z); e.maxs_z = m1.z;
 812         setorigin(e, e.origin);
 813
 814         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 815         if (trace_startsolid)
 816         {
 817                 setorigin(e, o);
 818                 return false;
 819         }
 820
 821         return true;
 822 }