qcsrc/menu/gamecommand.qc

   1 void GameCommand_Init()
   2 {
   3         // make gg call menu QC theCommands
   4         localcmd("alias qc_cmd \"menu_cmd $*\"\n");
   5 }
   6
   7 string _dumptree_space;
   8 void _dumptree_open(entity pass, entity me)
   9 {
  10         string s;
  11         s = me.toString(me);
  12         if(s == "")
  13                 s = me.classname;
  14         else
  15                 s = strcat(me.classname, ": ", s);
  16         print(_dumptree_space, etos(me), " (", s, ")");
  17         if(me.firstChild)
  18         {
  19                 print(" {\n");
  20                 _dumptree_space = strcat(_dumptree_space, "  ");
  21         }
  22         else
  23                 print("\n");
  24 }
  25 void _dumptree_close(entity pass, entity me)
  26 {
  27         if(me.firstChild)
  28         {
  29                 _dumptree_space = substring(_dumptree_space, 0, strlen(_dumptree_space) - 2);
  30                 print(_dumptree_space, "}\n");
  31         }
  32 }
  33
  34 float curl_uri_get_pos;
  35 float curl_uri_get_exec[URI_GET_CURL_END - URI_GET_CURL + 1];
  36 string curl_uri_get_cvar[URI_GET_CURL_END - URI_GET_CURL + 1];
  37 void Curl_URI_Get_Callback(float id, float status, string data)
  38 {
  39         float i;
  40         float do_exec;
  41         string do_cvar;
  42         i = id - URI_GET_CURL;
  43         do_exec = curl_uri_get_exec[i];
  44         do_cvar = curl_uri_get_cvar[i];
  45         if(status != 0)
  46         {
  47                 print(sprintf(_("error: status is %d\n"), status));
  48                 return;
  49         }
  50         if(do_exec)
  51                 localcmd(data);
  52         if(do_cvar)
  53                 cvar_set(do_cvar, data);
  54         if(!do_exec && !do_cvar)
  55                 print(data);
  56 }
  57
  58 void GameCommand(string theCommand)
  59 {
  60         float argc;
  61         argc = tokenize_console(theCommand);
  62
  63         if(argv(0) == "help" || argc == 0)
  64         {
  65                 print(_("Usage: menu_cmd theCommand..., where possible theCommands are:\n"));
  66                 print(_("  sync - reloads all cvars on the current menu page\n"));
  67                 print(_("  directmenu ITEM - select a menu item as main item\n"));
  68                 GameCommand_Generic("help");
  69                 return;
  70         }
  71
  72         if(GameCommand_Generic(theCommand))
  73                 return;
  74
  75         if(argv(0) == "sync")
  76         {
  77                 loadAllCvars(main);
  78                 updateCompression();
  79                 return;
  80         }
  81
  82         if(argv(0) == "directmenu") if(argc == 2)
  83         {
  84                 // switch to a menu item
  85                 if(!isdemo()) // don't allow this command in demos
  86                         m_goto(argv(1));
  87                 return;
  88         }
  89
  90         if(argv(0) == "directpanelhudmenu")
  91         {
  92                 // switch to a menu item
  93                 m_goto(strcat("HUD", argv(1)));
  94                 return;
  95         }
  96
  97         if(argv(0) == "skinselect")
  98         {
  99                 m_goto_skin_selector();
 100                 return;
 101         }
 102
 103         if(argv(0) == "videosettings")
 104         {
 105                 m_goto_video_settings();
 106                 return;
 107         }
 108
 109         if(argv(0) == "dumptree")
 110         {
 111                 _dumptree_space = "";
 112                 depthfirst(main, parent, firstChild, nextSibling, _dumptree_open, _dumptree_close, NULL);
 113                 return;
 114         }
 115
 116         if(argv(0) == "setresolution")
 117         {
 118                 updateConwidths();
 119                 return;
 120         }
 121
 122         if(argv(0) == "setcompression")
 123         {
 124                 updateCompression();
 125                 return;
 126         }
 127
 128         if(argv(0) == "curl")
 129         {
 130                 float do_exec;
 131                 string do_cvar;
 132                 float key;
 133                 float i, j;
 134                 string url;
 135                 float buf;
 136                 float r;
 137
 138                 do_exec = FALSE;
 139                 do_cvar = string_null;
 140                 key = -1;
 141
 142                 for(i = 1; i+1 < argc; ++i)
 143                 {
 144                         if(argv(i) == "--cvar" && i+2 < argc)
 145                         {
 146                                 ++i;
 147                                 do_cvar = argv(i);
 148                                 continue;
 149                         }
 150                         if(argv(i) == "--exec")
 151                         {
 152                                 do_exec = TRUE;
 153                                 continue;
 154                         }
 155                         if(argv(i) == "--key" && i+2 < argc)
 156                         {
 157                                 ++i;
 158                                 key = stof(argv(i));
 159                                 continue;
 160                         }
 161                         break;
 162                 }
 163
 164                 // now, argv(i) is the URL
 165                 // following args may be POST parameters
 166                 url = argv(i);
 167                 ++i;
 168                 buf = buf_create();
 169                 j = 0;
 170                 for(; i+1 < argc; i += 2)
 171                         bufstr_set(buf, ++j, sprintf("%s=%s", uri_escape(argv(i)), uri_escape(argv(i+1))));
 172                 if(i < argc)
 173                         bufstr_set(buf, ++j, sprintf("submit=%s", uri_escape(argv(i))));
 174
 175                 if(j == 0) // no args: GET
 176                         r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, string_null, string_null, -1, key);
 177                 else // with args: POST
 178                         r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, "application/x-www-form-urlencoded", "&", buf, key);
 179
 180                 if(r)
 181                 {
 182                         curl_uri_get_exec[curl_uri_get_pos] = do_exec;
 183                         curl_uri_get_cvar[curl_uri_get_pos] = do_cvar;
 184                         curl_uri_get_pos = mod(curl_uri_get_pos + 1, URI_GET_CURL_END - URI_GET_CURL + 1);
 185                 }
 186                 else
 187                         print(_("error creating curl handle\n"));
 188
 189                 buf_del(buf);
 190
 191                 return;
 192         }
 193
 194 #if 0
 195         if(argv(0) == "tokentest")
 196         {
 197                 string s;
 198                 float i, n;
 199
 200                 print("SANE tokenizer:\n");
 201                 s = cvar_string("tokentest");
 202                 n = tokenize_console_force_builtin(s);
 203                 for(i = -n; i < n; ++i)
 204                 {
 205                         print("token ", ftos(i), ": '", argv(i), "' = ");
 206                         print(ftos(argv_start_index(i)), " to ", ftos(argv_end_index(i)), "\n");
 207                 }
 208                 print(".\n");
 209
 210                 print("INSANE tokenizer:\n");
 211                 s = cvar_string("tokentest");
 212                 n = tokenize(s);
 213                 for(i = -n; i < n; ++i)
 214                 {
 215                         print("token ", ftos(i), ": '", argv(i), "' = ");
 216                         print(ftos(argv_start_index(i)), " to ", ftos(argv_end_index(i)), "\n");
 217                 }
 218                 print(".\n");
 219
 220                 print("EMULATED tokenizer:\n");
 221                 s = cvar_string("tokentest");
 222                 n = tokenize_console_force_emulation(s);
 223                 for(i = -n; i < n; ++i)
 224                 {
 225                         print("token ", ftos(i), ": '", argv(i), "' = ");
 226                         print(ftos(argv_start_index(i)), " to ", ftos(argv_end_index(i)), "\n");
 227                 }
 228                 print(".\n");
 229                 return;
 230         }
 231 #endif
 232
 233         print(_("Invalid command. For a list of supported commands, try menu_cmd help.\n"));
 234 }