qcsrc/menu/xonotic/campaign.qc

   1 #include "campaign.qh"
   2
   3 #include <common/campaign_common.qh>
   4 #include "inputbox.qh"
   5
   6 string campaign_longdesc_wrapped[CAMPAIGN_MAX_ENTRIES];
   7
   8 void rewrapCampaign(float w, float l0, float emptyheight, vector theFontSize)
   9 {
  10         int i, j;
  11         int n;
  12         float l;
  13         string r, s;
  14         for(i = 0; i < campaign_entries; ++i)
  15         {
  16                 l = l0;
  17                 strfree(campaign_longdesc_wrapped[i]);
  18                 n = tokenizebyseparator(campaign_longdesc[i], "\n");
  19                 r = "";
  20                 for(j = 0; j < n; ++j)
  21                 {
  22                         s = argv(j);
  23                         if(s == "")
  24                         {
  25                                 l -= emptyheight;
  26                                 r = strcat(r, "\n");
  27                                 continue;
  28                         }
  29
  30                         getWrappedLine_remaining = s;
  31                         while(getWrappedLine_remaining)
  32                         {
  33                                 s = getWrappedLine(w, theFontSize, draw_TextWidth_WithoutColors);
  34                                 if(--l < 0) goto toolong;
  35                                 r = strcat(r, s, "\n");
  36                         }
  37                 }
  38                 goto nottoolong;
  39 LABEL(toolong)
  40                 while(substring(r, strlen(r) - 1, 1) == "\n")
  41                         r = substring(r, 0, strlen(r) - 1);
  42                 r = strcat(r, "...\n");
  43 LABEL(nottoolong)
  44                 campaign_longdesc_wrapped[i] = strzone(substring(r, 0, strlen(r) - 1));
  45         }
  46 }
  47
  48 entity makeXonoticCampaignList()
  49 {
  50         entity me;
  51         me = NEW(XonoticCampaignList);
  52         me.configureXonoticCampaignList(me);
  53         return me;
  54 }
  55 void XonoticCampaignList_configureXonoticCampaignList(entity me)
  56 {
  57         me.configureXonoticListBox(me);
  58         me.campaignGlob = search_begin("maps/campaign*.txt", true, true);
  59         me.loadCvars(me);
  60         me.campaignGo(me, 0); // takes care of enabling/disabling buttons too
  61 }
  62
  63 void XonoticCampaignList_destroy(entity me)
  64 {
  65         if(me.campaignGlob >= 0)
  66                 search_end(me.campaignGlob);
  67 }
  68
  69 void XonoticCampaignList_loadCvars(entity me)
  70 {
  71         // read campaign cvars
  72         strcpy(campaign_name, cvar_string("g_campaign_name"));
  73         strcpy(me.cvarName, strcat("g_campaign", campaign_name, "_index"));
  74         registercvar(me.cvarName, "", 0); // saved by server QC anyway
  75         CampaignFile_Unload();
  76         CampaignFile_Load(0, CAMPAIGN_MAX_ENTRIES);
  77         me.campaignIndex = bound(0, cvar(me.cvarName), campaign_entries);
  78         cvar_set(me.cvarName, ftos(me.campaignIndex));
  79         if(me.columnNameSize)
  80                 rewrapCampaign(me.columnNameSize, me.rowsPerItem - 3, me.emptyLineHeight, me.realFontSize);
  81         me.nItems = min(me.campaignIndex + 2, campaign_entries);
  82         me.setSelected(me, min(me.campaignIndex, me.nItems - 1));
  83         if(me.nItems - 1 > me.campaignIndex)
  84                 me.scrollToItem(me, me.nItems - 1);
  85         if(me.labelTitle)
  86                 me.labelTitle.setText(me.labelTitle, campaign_title);
  87 }
  88
  89 void XonoticCampaignList_saveCvars(entity me)
  90 {
  91         // write campaign cvars
  92         // no reason to do this!
  93         // cvar_set("g_campaign_name", campaign_name);
  94         // cvar_set(me.cvarName, ftos(me.campaignIndex)); // NOTE: only server QC does that!
  95 }
  96
  97 void XonoticCampaignList_campaignGo(entity me, float step)
  98 {
  99         float canNext, canPrev;
 100         string s;
 101         float i, j, n;
 102
 103         canNext = canPrev = 0;
 104
 105         if(me.campaignGlob >= 0)
 106         {
 107                 n = search_getsize(me.campaignGlob);
 108                 if(n > 0)
 109                 {
 110                         j = -1;
 111                         s = strcat("maps/campaign", campaign_name, ".txt");
 112                         for(i = 0; i < n; ++i)
 113                         {
 114                                 if(search_getfilename(me.campaignGlob, i) == s)
 115                                         j = i;
 116                         }
 117                         if(j < 0)
 118                         {
 119                                 s = strcat("maps/campaign", cvar_defstring("g_campaign_name"), ".txt");
 120                                 for(i = 0; i < n; ++i)
 121                                 {
 122                                         if(search_getfilename(me.campaignGlob, i) == s)
 123                                                 j = i;
 124                                 }
 125                         }
 126                         if(j < 0)
 127                         {
 128                                 if(step >= 0)
 129                                         j = 0;
 130                                 else
 131                                         j = n - 1;
 132                         }
 133                         else
 134                                 j = mod(j + step, n);
 135                         s = search_getfilename(me.campaignGlob, j);
 136                         s = substring(s, 13, strlen(s) - 17);
 137                         cvar_set("g_campaign_name", s);
 138                         me.loadCvars(me);
 139                         canNext = (j != n - 1);
 140                         canPrev = (j != 0);
 141                 }
 142         }
 143
 144         if(me.buttonNext)
 145                 me.buttonNext.disabled = !canNext;
 146         if(me.buttonPrev)
 147                 me.buttonPrev.disabled = !canPrev;
 148 }
 149
 150 void MultiCampaign_Next(entity btn, entity me)
 151 {
 152         me.campaignGo(me, +1);
 153 }
 154 void MultiCampaign_Prev(entity btn, entity me)
 155 {
 156         me.campaignGo(me, -1);
 157 }
 158
 159 void XonoticCampaignList_draw(entity me)
 160 {
 161         if(cvar(me.cvarName) != me.campaignIndex || cvar_string("g_campaign_name") != campaign_name)
 162                 me.loadCvars(me);
 163         SUPER(XonoticCampaignList).draw(me);
 164 }
 165
 166 void XonoticCampaignList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 167 {
 168         me.itemAbsSize = '0 0 0';
 169         SUPER(XonoticCampaignList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 170
 171         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 172         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 173         me.realUpperMargin1 = 0.5 * me.realFontSize.y;
 174         me.realUpperMargin2 = me.realUpperMargin1 + 2 * me.realFontSize.y;
 175
 176         me.checkMarkSize = (eX * (me.itemAbsSize.y / me.itemAbsSize.x) + eY) * 0.5;
 177
 178         me.columnPreviewOrigin = 0;
 179         me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
 180         me.columnCheckMarkSize = me.checkMarkSize.x;
 181         me.columnNameSize = 1 - me.columnPreviewSize - me.columnCheckMarkSize - 4 * me.realFontSize.x;
 182         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
 183         me.columnCheckMarkOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x * 2;
 184
 185         me.checkMarkOrigin = eY + eX * (me.columnCheckMarkOrigin + me.columnCheckMarkSize) - me.checkMarkSize;
 186
 187         rewrapCampaign(me.columnNameSize, me.rowsPerItem - 3, me.emptyLineHeight, me.realFontSize);
 188 }
 189 void XonoticCampaignList_doubleClickListBoxItem(entity me, float i, vector where)
 190 {
 191         CampaignList_LoadMap(me, me);
 192 }
 193 void XonoticCampaignList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 194 {
 195         string s;
 196         vector theColor;
 197         float theAlpha;
 198         float j, n;
 199         vector o;
 200
 201         if(i < me.campaignIndex)
 202         {
 203                 theAlpha = SKINALPHA_CAMPAIGN_SELECTABLE;
 204                 theColor = SKINCOLOR_CAMPAIGN_SELECTABLE;
 205         }
 206         else if(i == me.campaignIndex)
 207         {
 208                 theAlpha = SKINALPHA_CAMPAIGN_CURRENT;
 209                 theColor = SKINCOLOR_CAMPAIGN_CURRENT;
 210         }
 211         else
 212         {
 213                 theAlpha = SKINALPHA_CAMPAIGN_FUTURE;
 214                 theColor = SKINCOLOR_CAMPAIGN_FUTURE;
 215         }
 216
 217         if(isSelected)
 218                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 219         else if(isFocused)
 220         {
 221                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 222                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 223         }
 224
 225         if(draw_PictureSize(strcat("/maps/", campaign_mapname[i])) == '0 0 0')
 226                 draw_Picture(me.columnPreviewOrigin * eX, "nopreview_map", me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 227         else
 228                 draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", campaign_mapname[i]), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 229
 230         if(i < me.campaignIndex)
 231                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 232         if(i <= me.campaignIndex)
 233                 s = campaign_shortdesc[i]; // fteqcc sucks
 234         else
 235                 s = "???";
 236         s = draw_TextShortenToWidth(sprintf(_("Level %d: %s"), i+1, s), me.columnNameSize, 0, me.realFontSize);
 237         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, theColor, theAlpha, 0);
 238
 239         if(i <= me.campaignIndex)
 240         {
 241                 s = campaign_longdesc_wrapped[i];
 242                 n = tokenizebyseparator(s, "\n");
 243                 o = me.realUpperMargin2 * eY + me.columnNameOrigin * eX;
 244                 for(j = 0; j < n; ++j)
 245                         if(argv(j) != "")
 246                         {
 247                                 draw_Text(o, argv(j), me.realFontSize, theColor, theAlpha * SKINALPHA_CAMPAIGN_DESCRIPTION, 0);
 248                                 o.y += me.realFontSize.y;
 249                         }
 250                         else
 251                                 o.y += me.realFontSize.y * me.emptyLineHeight;
 252         }
 253 }
 254 void CampaignList_LoadMap(entity btn, entity me)
 255 {
 256         if(me.selectedItem >= me.nItems || me.selectedItem < 0)
 257                 return;
 258         CampaignSetup(me.selectedItem);
 259 }
 260
 261 void XonoticCampaignList_setSelected(entity me, float i)
 262 {
 263         // prevent too late items from being played
 264         SUPER(XonoticCampaignList).setSelected(me, min(i, me.campaignIndex));
 265 }
 266
 267 float XonoticCampaignList_keyDown(entity me, float scan, float ascii, float shift)
 268 {
 269         if(scan == K_ENTER || scan == K_SPACE || scan == K_KP_ENTER)
 270                 CampaignList_LoadMap(me, me);
 271         else
 272                 return SUPER(XonoticCampaignList).keyDown(me, scan, ascii, shift);
 273         return 1;
 274 }