qcsrc/menu/xonotic/colorpicker.qc

   1 #include "colorpicker.qh"
   2
   3 #include "inputbox.qh"
   4
   5 entity makeXonoticColorpicker(entity theTextbox)
   6 {
   7         entity me;
   8         me = NEW(XonoticColorpicker);
   9         me.configureXonoticColorpicker(me, theTextbox);
  10         return me;
  11 }
  12
  13 void XonoticColorpicker_configureXonoticColorpicker(entity me, entity theTextbox)
  14 {
  15         me.controlledTextbox = theTextbox;
  16         me.configureImage(me, me.image);
  17 }
  18
  19 METHOD(XonoticColorpicker, mousePress, bool(XonoticColorpicker this, vector pos))
  20 {
  21         this.mouseDrag(this, pos);
  22         return true;
  23 }
  24
  25 // must match hslimage.c
  26 vector hslimage_color(vector v, vector margin)
  27 {
  28     v_x = (v.x - margin.x) / (1 - 2 * margin.x);
  29     v_y = (v.y - margin.y) / (1 - 2 * margin.y);
  30     if(v.x < 0) v_x = 0;
  31     if(v.y < 0) v_y = 0;
  32     if(v.x > 1) v_x = 1;
  33     if(v.y > 1) v_y = 1;
  34     if(v.y > 0.875) // grey bar
  35         return hsl_to_rgb(eZ * v.x);
  36     else
  37         return hsl_to_rgb(v.x * 6 * eX + eY + v.y / 0.875 * eZ);
  38 }
  39
  40 vector color_hslimage(vector v, vector margin)
  41 {
  42         vector pos = '0 0 0';
  43         v = rgb_to_hsl(v);
  44         if (v.y)
  45         {
  46                 pos_x = v.x / 6;
  47                 pos_y = v.z * 0.875;
  48         }
  49         else // grey scale
  50         {
  51                 pos_x = v.z;
  52                 pos_y = 0.875 + 0.07;
  53         }
  54         pos_x = margin.x + pos.x * (1 - 2 * margin.x);
  55         pos_y = margin.y + pos.y * (1 - 2 * margin.y);
  56         return pos;
  57 }
  58
  59 float XonoticColorpicker_mouseDrag(entity me, vector coords)
  60 {
  61         int i;
  62         for (;;)
  63         {
  64                 i = me.controlledTextbox.cursorPos;
  65                 string theText = me.controlledTextbox.text;
  66                 vector res = checkColorCode(theText, strlen(theText), i, true);
  67                 if (!res.x)
  68                         break;
  69
  70                 int cc_len = res.x;
  71                 int ofs = res.y;
  72                 for (int j = cc_len - ofs; j > 0; j--)
  73                         me.controlledTextbox.keyDown(me.controlledTextbox, K_RIGHTARROW, 8, 0);
  74                 for (int j = cc_len; j > 0; j--)
  75                         me.controlledTextbox.keyDown(me.controlledTextbox, K_BACKSPACE, 8, 0);
  76         }
  77
  78         if(substring(me.controlledTextbox.text, i-1, 1) == "^")
  79         {
  80                 if(!isCaretEscaped(me.controlledTextbox.text, i-1))
  81                         me.controlledTextbox.enterText(me.controlledTextbox, "^"); // escape previous caret
  82         }
  83
  84         vector margin;
  85         margin = me.imagemargin;
  86         if(coords.x >= margin.x)
  87         if(coords.y >= margin.y)
  88         if(coords.x <= 1 - margin.x)
  89         if(coords.y <= 1 - margin.y)
  90                 me.controlledTextbox.enterText(me.controlledTextbox, rgb_to_hexcolor(hslimage_color(coords, margin)));
  91
  92         return 1;
  93 }
  94
  95 float XonoticColorpicker_mouseRelease(entity me, vector coords)
  96 {
  97         m_play_click_sound(MENU_SOUND_SLIDE);
  98         me.mouseDrag(me, coords);
  99         return 1;
 100 }
 101
 102 void XonoticColorpicker_focusLeave(entity me)
 103 {
 104         me.controlledTextbox.saveCvars(me.controlledTextbox);
 105 }
 106 float XonoticColorpicker_keyDown(entity me, float key, float ascii, float shift)
 107 {
 108         return me.controlledTextbox.keyDown(me.controlledTextbox, key, ascii, shift);
 109 }
 110 void XonoticColorpicker_draw(entity me)
 111 {
 112         SUPER(XonoticColorpicker).draw(me);
 113
 114         float B, C, aC;
 115         C = cvar("r_textcontrast");
 116         B = cvar("r_textbrightness");
 117
 118         // for this to work, C/(1-B) must be in 0..1
 119         // B must be < 1
 120         // C must be < 1-B
 121
 122         B = bound(0, B, 1);
 123         C = bound(0, C, 1-B);
 124
 125         aC = 1 - C / (1 - B);
 126
 127         draw_Picture(me.imgOrigin, strcat(me.src, "_m"), me.imgSize, '0 0 0', aC);
 128         draw_Picture(me.imgOrigin, strcat(me.src, "_m"), me.imgSize, me.color, B);
 129 }