qcsrc/menu/xonotic/playlist.qc

   1 #include "playlist.qh"
   2
   3 entity makeXonoticPlayList()
   4 {
   5         entity me;
   6         me = NEW(XonoticPlayList);
   7         me.configureXonoticPlayList(me);
   8         return me;
   9 }
  10
  11 void XonoticPlayList_configureXonoticPlayList(entity me)
  12 {
  13         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  14         me.configureXonoticListBox(me);
  15 }
  16
  17 void XonoticPlayList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  18 {
  19         me.itemAbsSize = '0 0 0';
  20         SUPER(XonoticPlayList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  21
  22         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
  23         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
  24         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
  25
  26         me.columnNumberOrigin = 0;
  27         me.columnNumberSize = 3 * me.realFontSize.x;
  28
  29         me.columnNameOrigin = me.columnNumberSize + me.realFontSize.x;
  30         me.columnNameSize = 1 - me.columnNameOrigin - me.realFontSize.x;
  31 }
  32
  33 void XonoticPlayList_addToPlayList(entity me, string track)
  34 {
  35         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  36         if(me.nItems == 0)
  37         {
  38                 cvar_set("music_playlist_list0", track);
  39                 return;
  40         }
  41         float i;
  42         for(i = 0; i < me.nItems; ++i)
  43         {
  44                 if(argv(i) == track)
  45                         return; // track is already in playlist
  46         }
  47         cvar_set("music_playlist_list0", strcat(cvar_string("music_playlist_list0"), " ", track));
  48 }
  49
  50 void XonoticPlayList_removeSelectedFromPlayList(entity me)
  51 {
  52         float i, cpt = false;
  53         string s = "";
  54         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
  55         if(me.nItems == 0)
  56                 return;
  57         for(i = 0; i < me.nItems; ++i)
  58         {
  59                 if(i == me.selectedItem)
  60                 {
  61                         if(i == me.nItems - 1)
  62                                 me.setSelected(me, me.selectedItem - 1);
  63                         if(cvar("music_playlist_index") == 0 || cvar("music_playlist_index") == 999)
  64                         {
  65                                 if(cvar("music_playlist_current0") == i)
  66                                         cpt = true; // current playing track (we can't start next track here because startSound calls tokenize_console)
  67                                 else if(cvar("music_playlist_current0") > i)
  68                                         cvar_set("music_playlist_current0", ftos(cvar("music_playlist_current0") - 1));
  69                         }
  70                         continue;
  71                 }
  72                 s = strcat(s, " ", argv(i));
  73         }
  74         // we must stop the current playing track if it has been removed
  75         // otherwise pause/play button will resume from another track
  76         if(s == "")
  77         {
  78                 cvar_set("music_playlist_list0", "");
  79                 if(cpt)
  80                         me.stopSound(me);
  81         }
  82         else
  83         {
  84                 cvar_set("music_playlist_list0", substring(s, 1, strlen(s))); // remove initial space
  85                 if(cpt)
  86                         me.startSound(me, 0);
  87         }
  88 }
  89
  90 void PlayList_Remove(entity btn, entity me)
  91 {
  92         me.removeSelectedFromPlayList(me);
  93 }
  94
  95 void PlayList_Remove_All(entity btn, entity me)
  96 {
  97         cvar_set("music_playlist_list0", "");
  98         me.stopSound(me);
  99         me.selectedItem = 0;
 100 }
 101
 102 float XonoticPlayList_mouseDrag(entity me, vector pos)
 103 {
 104         float f, i;
 105         i = me.selectedItem;
 106         f = SUPER(XonoticPlayList).mouseDrag(me, pos);
 107
 108         if(me.pressed != 1) // don't change priority if the person is just scrolling
 109         {
 110                 if(me.selectedItem != i)
 111                 {
 112                         cvar_set("music_playlist_list0", swapInPriorityList(cvar_string("music_playlist_list0"), me.selectedItem, i));
 113                         float c = cvar("music_playlist_current0");
 114                         if(c == i)
 115                                 cvar_set("music_playlist_current0", ftos(me.selectedItem));
 116                         else if(c == me.selectedItem)
 117                                 cvar_set("music_playlist_current0", ftos(i));
 118                 }
 119         }
 120
 121         return f;
 122 }
 123
 124 void XonoticPlayList_draw(entity me)
 125 {
 126         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 127         if(cvar("music_playlist_index") == 0 || cvar("music_playlist_index") == 999)
 128                 me.playingTrack = cvar("music_playlist_current0");
 129         else
 130                 me.playingTrack = -1;
 131         SUPER(XonoticPlayList).draw(me);
 132 }
 133
 134 void XonoticPlayList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 135 {
 136         string s;
 137         if(isSelected)
 138                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 139         else if(isFocused)
 140         {
 141                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 142                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 143         }
 144
 145         if(i == me.playingTrack)
 146         {
 147                 float f = cvar("music_playlist_sampleposition0");
 148                 if(f <= 0 || (((time * 2) & 1) && f > 0))
 149                         draw_Text(me.realUpperMargin * eY + (me.columnNumberOrigin + me.columnNumberSize) * eX, "\xE2\x96\xB6", me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 150         }
 151
 152         s = ftos(i+1);
 153         draw_CenterText(me.realUpperMargin * eY + (me.columnNumberOrigin + 0.5 * me.columnNumberSize) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 154
 155         s = draw_TextShortenToWidth(argv(i), me.columnNameSize, 0, me.realFontSize);
 156         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 157 }
 158
 159 void XonoticPlayList_stopSound(entity me)
 160 {
 161         // STOP: list 0 is disabled by setting the index to -1
 162         // we set sampleposition0 to 0 to forget the position that the engine saves in this frame (for this reason we need to wait a frame)
 163         if(cvar("music_playlist_index") == 0 || cvar("music_playlist_index") == 999)
 164         {
 165                 cvar_set("music_playlist_index", "-1");
 166                 localcmd("\nwait; music_playlist_sampleposition0 0\n");
 167                 localcmd("\ndefer 3 \"cd play $menu_cdtrack\"\n");
 168         }
 169 }
 170
 171 void StopSound_Click(entity btn, entity me)
 172 {
 173         me.stopSound(me);
 174 }
 175
 176 void XonoticPlayList_startSound(entity me, float offset)
 177 {
 178         float f;
 179         me.nItems = tokenize_console(cvar_string("music_playlist_list0"));
 180         if(offset)
 181         {
 182                 if(cvar("music_playlist_index") == -1)
 183                         return;
 184                 f = bound(0, cvar("music_playlist_current0") + offset, me.nItems - 1);
 185                 if(f == cvar("music_playlist_current0"))
 186                         return;
 187         }
 188         else
 189         {
 190                 f = me.selectedItem;
 191                 // if it was paused then resume
 192                 if(f == cvar("music_playlist_current0"))
 193                 if(cvar("music_playlist_index") == 999)
 194                 {
 195                         me.resumeSound(me);
 196                         return;
 197                 }
 198                 // if it was not paused then proceed with restart
 199         }
 200
 201         // START: list 0 is disabled by setting the index to 999
 202         // we set current0 to the selected track and sampleposition0 to 0 to forget the position that the engine saves in this frame (for this reason we need to wait a frame)
 203         // then we switch back to list 0
 204         cvar_set("music_playlist_index", "999");
 205         cvar_set("music_playlist_current0", ftos(f));
 206         localcmd("\nwait; music_playlist_sampleposition0 0; wait; music_playlist_index 0\n");
 207 }
 208
 209 void StartSound_Click(entity btn, entity me)
 210 {
 211         me.startSound(me, 0);
 212 }
 213
 214 void PrevSound_Click(entity btn, entity me)
 215 {
 216         me.startSound(me, -1);
 217 }
 218
 219 void NextSound_Click(entity btn, entity me)
 220 {
 221         me.startSound(me, +1);
 222 }
 223
 224 void XonoticPlayList_resumeSound(entity me)
 225 {
 226         // RESUME: list 0 is enabled by setting the index to 0
 227         // (we reset sampleposition0 to 0 to mark the track as in playing back state)
 228         if(cvar("music_playlist_index") == 999)
 229                 localcmd("\nmusic_playlist_index 0; wait; music_playlist_sampleposition0 0\n");
 230 }
 231 void XonoticPlayList_pauseSound(entity me)
 232 {
 233         // PAUSE: list 0 is disabled by setting the index to 999
 234         // (we know the track is paused because the engine sets sampleposition0 to remember current position)
 235         if(cvar("music_playlist_index") == 0)
 236                 localcmd("\nmusic_playlist_index 999\n");
 237         else me.resumeSound(me);
 238 }
 239
 240 void PauseSound_Click(entity btn, entity me)
 241 {
 242         me.pauseSound(me);
 243 }
 244
 245 void XonoticPlayList_doubleClickListBoxItem(entity me, float i, vector where)
 246 {
 247         me.startSound(me, 0);
 248 }
 249
 250 float XonoticPlayList_keyDown(entity me, float scan, float ascii, float shift)
 251 {
 252         if(scan == K_ENTER || scan == K_KP_ENTER) {
 253                 me.startSound(me, 0);
 254                 return 1;
 255         }
 256         else if(scan == K_SPACE) {
 257                 me.pauseSound(me);
 258                 return 1;
 259         }
 260         else if(scan == K_DEL || scan == K_KP_DEL || scan == K_BACKSPACE || scan == K_MOUSE3) {
 261                 me.removeSelectedFromPlayList(me);
 262                 return 1;
 263         }
 264         else
 265                 return SUPER(XonoticPlayList).keyDown(me, scan, ascii, shift);
 266 }