qcsrc/menu/xonotic/serverlist.qc

   1 #include "serverlist.qh"
   2
   3 #include "checkbox.qh"
   4 #include "inputbox.qh"
   5 #include "mainwindow.qh"
   6 #include "dialog_multiplayer_join_serverinfo.qh"
   7 #include <common/mapinfo.qh>
   8
   9 void SL_ProcessCategoryOverrides(.string override_field_string, .float override_field)
  10 {
  11         for (int i = 0; i < category_ent_count; ++i)
  12         {
  13                 string s = categories[i].override_field_string;
  14                 if (s != "" && s != categories[i].cat_name)
  15                 {
  16                         int catnum = 0;
  17                         for (int x = 0; x < category_ent_count; ++x)
  18                         {
  19                                 if(categories[x].cat_name == s)
  20                                 {
  21                                         catnum = x + 1;
  22                                         break;
  23                                 }
  24                         }
  25                         if (catnum)
  26                         {
  27                                 strfree(categories[i].override_field_string);
  28                                 categories[i].override_field = catnum;
  29                                 continue;
  30                         }
  31                         LOG_INFOF("RegisterSLCategories(): Improper override '%s' for category '%s'!", s, categories[i].cat_name);
  32                 }
  33                 strfree(categories[i].override_field_string);
  34                 categories[i].override_field = 0;
  35         }
  36 }
  37
  38 void RegisterSLCategories()
  39 {
  40         entity cat;
  41         #define SLIST_CATEGORY(name,enoverride,dioverride,str) \
  42                 SET_FIELD_COUNT(name, CATEGORY_FIRST, category_ent_count) \
  43                 CHECK_MAX_COUNT(name, MAX_CATEGORIES, category_ent_count, "SLIST_CATEGORY") \
  44                 cat = categories[name - 1] = new(slist_category); \
  45                 cat.cat_name = #name; \
  46                 cat.cat_enoverride_string = strzone(SLIST_CATEGORY_AUTOCVAR(name)); \
  47                 cat.cat_dioverride_string = strzone(dioverride); \
  48                 cat.cat_string = strzone(str);
  49         SLIST_CATEGORIES
  50         #undef SLIST_CATEGORY
  51
  52         SL_ProcessCategoryOverrides(cat_enoverride_string, cat_enoverride);
  53         SL_ProcessCategoryOverrides(cat_dioverride_string, cat_dioverride);
  54 }
  55
  56 // Supporting Functions
  57 entity RetrieveCategoryEnt(int catnum)
  58 {
  59         if((catnum > 0) && (catnum <= category_ent_count))
  60         {
  61                 return categories[catnum - 1];
  62         }
  63         else
  64         {
  65                 error(sprintf("RetrieveCategoryEnt(%d): Improper category number!\n", catnum));
  66                 return NULL;
  67         }
  68 }
  69
  70 bool IsServerInList(string list, string srv)
  71 {
  72         if(srv == "")
  73                 return false;
  74         srv = netaddress_resolve(srv, 26000);
  75         if(srv == "")
  76                 return false;
  77         string p = crypto_getidfp(srv);
  78         int n = tokenize_console(list);
  79         for(int i = 0; i < n; ++i)
  80         {
  81                 if(substring(argv(i), 0, 1) != "[" && strlen(argv(i)) == 44 && strstrofs(argv(i), ".", 0) < 0)
  82                 {
  83                         if(p && argv(i) == p)
  84                                 return true;
  85                 }
  86                 else
  87                 {
  88                         if(srv == netaddress_resolve(argv(i), 26000))
  89                                 return true;
  90                 }
  91         }
  92         return false;
  93 }
  94
  95 int CategoryOverride(int cat)
  96 {
  97         entity catent = RetrieveCategoryEnt(cat);
  98         if(catent)
  99         {
 100                 int override = (autocvar_menu_slist_categories ? catent.cat_enoverride : catent.cat_dioverride);
 101                 if(override) { return override; }
 102                 else { return cat; }
 103         }
 104         else
 105         {
 106                 error(sprintf("CategoryOverride(%d): Improper category number!\n", cat));
 107                 return cat;
 108         }
 109 }
 110
 111 int CategoryForEntry(int entry)
 112 {
 113         string s, k, v, modtype = "";
 114         int j, m, impure = 0, freeslots = 0, sflags = 0;
 115         s = gethostcachestring(SLIST_FIELD_QCSTATUS, entry);
 116         m = tokenizebyseparator(s, ":");
 117
 118         for(j = 2; j < m; ++j)
 119         {
 120                 if(argv(j) == "") { break; }
 121                 k = substring(argv(j), 0, 1);
 122                 v = substring(argv(j), 1, -1);
 123                 switch(k)
 124                 {
 125                         case "P": { impure = stof(v); break; }
 126                         case "S": { freeslots = stof(v); break; }
 127                         case "F": { sflags = stof(v); break; }
 128                         case "M": { modtype = strtolower(v); break; }
 129                 }
 130         }
 131
 132         if(modtype != "xonotic") { impure += autocvar_menu_slist_modimpurity; }
 133
 134         // check if this server is favorited
 135         if(gethostcachenumber(SLIST_FIELD_ISFAVORITE, entry)) { return CAT_FAVORITED; }
 136
 137         // now check if it's recommended
 138         if(autocvar_menu_slist_recommendations)
 139         {
 140                 string cname = gethostcachestring(SLIST_FIELD_CNAME, entry);
 141
 142                 if(IsPromoted(cname)) { return CAT_RECOMMENDED; }
 143                 else
 144                 {
 145                         float recommended = 0;
 146                         if(autocvar_menu_slist_recommendations & 1)
 147                         {
 148                                 if(IsRecommended(cname)) { ++recommended; }
 149                                 else { --recommended; }
 150                         }
 151                         if(autocvar_menu_slist_recommendations & 2)
 152                         {
 153                                 if(
 154                                         ///// check for minimum free slots
 155                                         (freeslots >= autocvar_menu_slist_recommendations_minfreeslots)
 156
 157                                         && // check for purity requirement
 158                                         (
 159                                                 (autocvar_menu_slist_recommendations_purethreshold < 0)
 160                                                 ||
 161                                                 (impure <= autocvar_menu_slist_recommendations_purethreshold)
 162                                         )
 163
 164                                         && // check for minimum amount of humans
 165                                         (
 166                                                 gethostcachenumber(SLIST_FIELD_NUMHUMANS, entry)
 167                                                 >=
 168                                                 autocvar_menu_slist_recommendations_minhumans
 169                                         )
 170
 171                                         && // check for maximum latency
 172                                         (
 173                                                 gethostcachenumber(SLIST_FIELD_PING, entry)
 174                                                 <=
 175                                                 autocvar_menu_slist_recommendations_maxping
 176                                         )
 177                                 )
 178                                         { ++recommended; }
 179                                 else
 180                                         { --recommended; }
 181                         }
 182                         if(recommended > 0) { return CAT_RECOMMENDED; }
 183                 }
 184         }
 185
 186         // if not favorited or recommended, check modname
 187         if(modtype != "xonotic")
 188         {
 189                 switch(modtype)
 190                 {
 191                         // old servers which don't report their mod name are considered modified now
 192                         case "": { return CAT_MODIFIED; }
 193
 194                         case "xpm": { return CAT_XPM; }
 195                         case "minstagib":
 196                         case "instagib": { return CAT_INSTAGIB; }
 197                         case "overkill": { return CAT_OVERKILL; }
 198
 199                         // "cts" is allowed as compat, xdf is replacement
 200                         case "cts":
 201                         case "xdf": { return CAT_DEFRAG; }
 202
 203                         default: { LOG_TRACEF("Found strange mod type: %s", modtype); return CAT_MODIFIED; }
 204                 }
 205         }
 206
 207         // must be normal or impure server
 208         return ((impure > autocvar_menu_slist_purethreshold) ? CAT_MODIFIED : CAT_NORMAL);
 209 }
 210
 211 METHOD(XonoticServerList, toggleFavorite, void(XonoticServerList this, string srv))
 212 {
 213         bool adding = true;
 214         string srv_resolved = netaddress_resolve(srv, 26000);
 215         string p = crypto_getidfp(srv_resolved);
 216         string s = cvar_string("net_slist_favorites");
 217         string ret = s;
 218         for (int i = 0, n = tokenize_console(s); i < n; ++i)
 219         {
 220                 bool match;
 221                 if (substring(argv(i), 0, 1) != "[" && strlen(argv(i)) == 44 && strstrofs(argv(i), ".", 0) < 0)
 222                 {
 223                         // it's a pubkey hash
 224                         match = (p && p == argv(i));
 225                 }
 226                 else
 227                 {
 228                         // it's an ip
 229                         match = (srv_resolved == netaddress_resolve(argv(i), 26000));
 230                 }
 231                 if (!match) continue;
 232                 // on match: remove
 233                 adding = false;
 234                 string before = (i > 0) ? substring(s, 0, argv_end_index(i - 1)) : "";
 235                 string after = (i < n - 1) ? substring(s, argv_start_index(i + 1), -1) : "";
 236                 s = strcat(before, (before != "" && after != "" ? " " : ""), after);
 237                 ret = s;
 238                 // keep searching
 239                 // TODO: why not break here?
 240                 n = tokenize_console(s);
 241                 --i; // offset the increment that is about to happen
 242         }
 243         if (adding)
 244         {
 245                 ret = strcat(s, (s != "" ? " " : ""), p ? p : srv);
 246         }
 247         cvar_set("net_slist_favorites", ret);
 248         this.refreshServerList(this, REFRESHSERVERLIST_RESORT);
 249 }
 250
 251 void ServerList_Update_favoriteButton(entity btn, entity me)
 252 {
 253         entity e = me.favoriteButton;
 254         if(IsFavorite(me.ipAddressBox.text))
 255         {
 256                 e.setText(e, ZCTX(_("SERVER^Remove favorite")));
 257                 setZonedTooltip(e, _("Remove the currently highlighted server from bookmarks"), string_null);
 258         }
 259         else
 260         {
 261                 e.setText(e, ZCTX(_("SERVER^Favorite")));
 262                 setZonedTooltip(e, _("Bookmark the currently highlighted server so that it's faster to find in the future"), string_null);
 263         }
 264 }
 265
 266 entity makeXonoticServerList()
 267 {
 268         entity me;
 269         me = NEW(XonoticServerList);
 270         me.configureXonoticServerList(me);
 271         return me;
 272 }
 273 void XonoticServerList_configureXonoticServerList(entity me)
 274 {
 275         me.configureXonoticListBox(me);
 276
 277         // update field ID's
 278         #define SLIST_FIELD(suffix,name) SLIST_FIELD_##suffix = gethostcacheindexforkey(name);
 279         SLIST_FIELDS
 280         #undef SLIST_FIELD
 281
 282         // clear list
 283         me.nItems = 0;
 284 }
 285 void XonoticServerList_setSelected(entity me, int i)
 286 {
 287         me.lockedSelectedItem = false;
 288         //int save = me.selectedItem;
 289         SUPER(XonoticServerList).setSelected(me, i);
 290         /*
 291         if(me.selectedItem == save)
 292                 return;
 293         */
 294         if(me.nItems == 0)
 295                 return;
 296         if(gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT) != me.nItems)
 297                 return; // sorry, it would be wrong
 298
 299         strcpy(me.selectedServer, gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem));
 300
 301         me.ipAddressBox.setText(me.ipAddressBox, me.selectedServer);
 302         me.ipAddressBox.cursorPos = strlen(me.selectedServer);
 303         me.ipAddressBoxFocused = -1;
 304 }
 305 void XonoticServerList_refreshServerList(entity me, int mode)
 306 {
 307         //print("refresh of type ", ftos(mode), "\n");
 308
 309         if(mode >= REFRESHSERVERLIST_REFILTER)
 310         {
 311                 string s = me.filterString;
 312
 313                 string typestr;
 314                 int m = strstrofs(s, ":", 0);
 315                 if(m >= 0)
 316                 {
 317                         typestr = substring(s, 0, m);
 318                         s = substring(s, m + 1, strlen(s) - m - 1);
 319                         while(substring(s, 0, 1) == " ")
 320                                 s = substring(s, 1, strlen(s) - 1);
 321                 }
 322                 else
 323                         typestr = "";
 324
 325                 string modstr = cvar_string("menu_slist_modfilter");
 326
 327                 m = SLIST_MASK_AND - 1;
 328                 resethostcachemasks();
 329
 330                 // ping: reject negative ping (no idea why this happens in the first place, engine bug)
 331                 sethostcachemasknumber(++m, SLIST_FIELD_PING, 0, SLIST_TEST_GREATEREQUAL);
 332
 333                 // show full button
 334                 if(!me.filterShowFull)
 335                 {
 336                         sethostcachemasknumber(++m, SLIST_FIELD_FREESLOTS, 1, SLIST_TEST_GREATEREQUAL); // legacy
 337                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, ":S0:", SLIST_TEST_NOTCONTAIN); // g_maxplayers support
 338                 }
 339
 340                 // show empty button
 341                 if(!me.filterShowEmpty)
 342                         sethostcachemasknumber(++m, SLIST_FIELD_NUMHUMANS, 1, SLIST_TEST_GREATEREQUAL);
 343
 344                 // show laggy button
 345                 if(!me.filterShowLaggy && autocvar_menu_slist_maxping > 0)
 346                         sethostcachemasknumber(++m, SLIST_FIELD_PING, autocvar_menu_slist_maxping, SLIST_TEST_LESSEQUAL);
 347
 348                 // gametype filtering
 349                 if(typestr != "")
 350                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, strcat(typestr, ":"), SLIST_TEST_STARTSWITH);
 351
 352                 // mod filtering
 353                 if(modstr != "")
 354                 {
 355                         if(substring(modstr, 0, 1) == "!")
 356                                 sethostcachemaskstring(++m, SLIST_FIELD_MOD, resolvemod(substring(modstr, 1, strlen(modstr) - 1)), SLIST_TEST_NOTEQUAL);
 357                         else
 358                                 sethostcachemaskstring(++m, SLIST_FIELD_MOD, resolvemod(modstr), SLIST_TEST_EQUAL);
 359                 }
 360
 361                 // server banning
 362                 int n = tokenizebyseparator(_Nex_ExtResponseSystem_BannedServers, " ");
 363                 for(int i = 0; i < n; ++i)
 364                         if(argv(i) != "")
 365                                 sethostcachemaskstring(++m, SLIST_FIELD_CNAME, argv(i), SLIST_TEST_NOTSTARTSWITH);
 366
 367                 m = SLIST_MASK_OR - 1;
 368                 if(s != "")
 369                 {
 370                         sethostcachemaskstring(++m, SLIST_FIELD_NAME, s, SLIST_TEST_CONTAINS);
 371                         sethostcachemaskstring(++m, SLIST_FIELD_MAP, s, SLIST_TEST_CONTAINS);
 372                         sethostcachemaskstring(++m, SLIST_FIELD_PLAYERS, s, SLIST_TEST_CONTAINS);
 373                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, strcat(s, ":"), SLIST_TEST_STARTSWITH);
 374                 }
 375
 376                 int sorting_flags = 0;
 377                 //sorting_flags |= SLSF_FAVORITES;
 378                 sorting_flags |= SLSF_CATEGORIES;
 379                 if(me.currentSortOrder < 0) { sorting_flags |= SLSF_DESCENDING; }
 380                 sethostcachesort(me.currentSortField, sorting_flags);
 381         }
 382
 383         resorthostcache();
 384         if(mode >= REFRESHSERVERLIST_ASK)
 385                 refreshhostcache(mode >= REFRESHSERVERLIST_RESET);
 386 }
 387 void XonoticServerList_focusEnter(entity me)
 388 {
 389         SUPER(XonoticServerList).focusEnter(me);
 390         if(time < me.nextRefreshTime)
 391         {
 392                 //print("sorry, no refresh yet\n");
 393                 return;
 394         }
 395         me.nextRefreshTime = time + 10;
 396         me.refreshServerList(me, REFRESHSERVERLIST_ASK);
 397 }
 398
 399 void XonoticServerList_draw(entity me)
 400 {
 401         if(_Nex_ExtResponseSystem_BannedServersNeedsRefresh)
 402         {
 403                 if(!me.needsRefresh)
 404                         me.needsRefresh = 2;
 405                 _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 0;
 406         }
 407
 408         if(_Nex_ExtResponseSystem_PromotedServersNeedsRefresh)
 409         {
 410                 if(!me.needsRefresh)
 411                         me.needsRefresh = 3;
 412                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 0;
 413         }
 414
 415         if(_Nex_ExtResponseSystem_RecommendedServersNeedsRefresh)
 416         {
 417                 if(!me.needsRefresh)
 418                         me.needsRefresh = 3;
 419                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 0;
 420         }
 421
 422         if(me.currentSortField == -1)
 423         {
 424                 me.setSortOrder(me, SLIST_FIELD_PING, +1);
 425                 me.refreshServerList(me, REFRESHSERVERLIST_RESET);
 426         }
 427         else if(me.needsRefresh == 1)
 428         {
 429                 me.needsRefresh = 2; // delay by one frame to make sure "slist" has been executed
 430         }
 431         else if(me.needsRefresh == 2)
 432         {
 433                 me.needsRefresh = 0;
 434                 me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 435         }
 436         else if(me.needsRefresh == 3)
 437         {
 438                 me.needsRefresh = 0;
 439                 me.refreshServerList(me, REFRESHSERVERLIST_RESORT);
 440         }
 441
 442         bool owned = ((me.selectedServer == me.ipAddressBox.text) && (me.ipAddressBox.text != ""));
 443
 444         for(int i = 0; i < category_draw_count; ++i) { category_name[i] = -1; category_item[i] = -1; }
 445         category_draw_count = 0;
 446
 447         if(autocvar_menu_slist_categories >= 0) // if less than 0, don't even draw a category heading for favorites
 448         {
 449                 float itemcount = gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT);
 450                 me.nItems = itemcount;
 451
 452                 //float visible = floor(me.scrollPos / me.itemHeight);
 453                 // ^ unfortunately no such optimization can be made-- we must process through the
 454                 // entire list, otherwise there is no way to know which item is first in its category.
 455
 456                 // binary search method suggested by div
 457                 float begin = 0;
 458                 for(int j = 1; j <= category_ent_count; ++j) {
 459                         float first = begin;
 460                         float last = (itemcount - 1);
 461                         if (first > last) {
 462                                 // List is empty.
 463                                 break;
 464                         }
 465                         float catf = gethostcachenumber(SLIST_FIELD_CATEGORY, first);
 466                         float catl = gethostcachenumber(SLIST_FIELD_CATEGORY, last);
 467                         if (catf > j) {
 468                                 // The first one is already > j.
 469                                 // Therefore, category j does not exist.
 470                                 // Higher numbered categories do exist though.
 471                         } else if (catl < j) {
 472                                 // The last one is < j.
 473                                 // Thus this category - and any following -
 474                                 // don't exist.
 475                                 break;
 476                         } else if (catf == j) {
 477                                 // Starts at first. This breaks the loop
 478                                 // invariant in the binary search and thus has
 479                                 // to be handled separately.
 480                                 if(gethostcachenumber(SLIST_FIELD_CATEGORY, first) != j)
 481                                         error("Category mismatch I");
 482                                 if(first > 0)
 483                                         if(gethostcachenumber(SLIST_FIELD_CATEGORY, first - 1) == j)
 484                                                 error("Category mismatch II");
 485                                 category_name[category_draw_count] = j;
 486                                 category_item[category_draw_count] = first;
 487                                 ++category_draw_count;
 488                                 begin = first + 1;
 489                         } else {
 490                                 // At this point, catf <= j < catl, thus
 491                                 // catf < catl, thus first < last.
 492                                 // INVARIANTS:
 493                                 // last - first >= 1
 494                                 // catf == gethostcachenumber(SLIST_FIELD_CATEGORY(first)
 495                                 // catl == gethostcachenumber(SLIST_FIELD_CATEGORY(last)
 496                                 // catf < j
 497                                 // catl >= j
 498                                 while (last - first > 1) {
 499                                         float middle = floor((first + last) / 2);
 500                                         // By loop condition, middle != first && middle != last.
 501                                         float cat = gethostcachenumber(SLIST_FIELD_CATEGORY, middle);
 502                                         if (cat >= j) {
 503                                                 last = middle;
 504                                                 catl = cat;
 505                                         } else {
 506                                                 first = middle;
 507                                                 catf = cat;
 508                                         }
 509                                 }
 510                                 if (catl == j) {
 511                                         if(gethostcachenumber(SLIST_FIELD_CATEGORY, last) != j)
 512                                                 error("Category mismatch III");
 513                                         if(last > 0)
 514                                                 if(gethostcachenumber(SLIST_FIELD_CATEGORY, last - 1) == j)
 515                                                         error("Category mismatch IV");
 516                                         category_name[category_draw_count] = j;
 517                                         category_item[category_draw_count] = last;
 518                                         ++category_draw_count;
 519                                         begin = last + 1; // already scanned through these, skip 'em
 520                                 }
 521                                 else
 522                                         begin = last; // already scanned through these, skip 'em
 523                         }
 524                 }
 525                 if(autocvar_menu_slist_categories_onlyifmultiple && (category_draw_count == 1))
 526                 {
 527                         category_name[0] = -1;
 528                         category_item[0] = -1;
 529                         category_draw_count = 0;
 530                         me.nItems = itemcount;
 531                 }
 532         }
 533         else { me.nItems = gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT); }
 534
 535         me.connectButton.disabled = (me.ipAddressBox.text == "");
 536         //me.disconnectButton.disabled = (!(gamestatus & (GAME_ISSERVER | GAME_CONNECTED)));
 537         me.infoButton.disabled = !owned;
 538         me.favoriteButton.disabled = (me.ipAddressBox.text == "");
 539
 540         bool found = false;
 541         if(me.lockedSelectedItem)
 542         {
 543                 if(me.nItems > 0)
 544                 {
 545                         if(gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem) != me.selectedServer)
 546                         {
 547                                 strcpy(me.selectedServer, gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem));
 548                         }
 549                         found = true;
 550                 }
 551         }
 552         else if(me.selectedServer)
 553         {
 554                 for(int i = 0; i < me.nItems; ++i)
 555                 {
 556                         if(gethostcachestring(SLIST_FIELD_CNAME, i) == me.selectedServer)
 557                         {
 558                                 // don't follow the selected item with SUPER(XonoticServerList).setSelected(me, i);
 559                                 me.selectedItem = i;
 560                                 found = true;
 561                                 break;
 562                         }
 563                 }
 564         }
 565         if(!found)
 566         {
 567                 if(me.nItems > 0)
 568                 {
 569                         // selected server disappeared, select the last server (scrolling to it)
 570                         if(me.selectedItem >= me.nItems)
 571                                 SUPER(XonoticServerList).setSelected(me, me.nItems - 1);
 572                         strcpy(me.selectedServer, gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem));
 573                 }
 574         }
 575
 576         if(owned)
 577         {
 578                 if(me.selectedServer != me.ipAddressBox.text)
 579                 {
 580                         me.ipAddressBox.setText(me.ipAddressBox, me.selectedServer);
 581                         me.ipAddressBox.cursorPos = strlen(me.selectedServer);
 582                         me.ipAddressBoxFocused = -1;
 583                 }
 584         }
 585
 586         if(me.ipAddressBoxFocused != me.ipAddressBox.focused)
 587         {
 588                 if(me.ipAddressBox.focused || me.ipAddressBoxFocused < 0)
 589                         ServerList_Update_favoriteButton(NULL, me);
 590                 me.ipAddressBoxFocused = me.ipAddressBox.focused;
 591         }
 592
 593         SUPER(XonoticServerList).draw(me);
 594 }
 595 void ServerList_PingSort_Click(entity btn, entity me)
 596 {
 597         me.setSortOrder(me, SLIST_FIELD_PING, +1);
 598 }
 599 void ServerList_NameSort_Click(entity btn, entity me)
 600 {
 601         me.setSortOrder(me, SLIST_FIELD_NAME, -1); // why?
 602 }
 603 void ServerList_MapSort_Click(entity btn, entity me)
 604 {
 605         me.setSortOrder(me, SLIST_FIELD_MAP, -1); // why?
 606 }
 607 void ServerList_PlayerSort_Click(entity btn, entity me)
 608 {
 609         me.setSortOrder(me, SLIST_FIELD_NUMHUMANS, -1);
 610 }
 611 void ServerList_TypeSort_Click(entity btn, entity me)
 612 {
 613         string s = me.filterString;
 614         int m = strstrofs(s, ":", 0);
 615         if(m >= 0)
 616         {
 617                 s = substring(s, 0, m);
 618                 while(substring(s, m+1, 1) == " ") // skip spaces
 619                         ++m;
 620         }
 621         else
 622                 s = "";
 623
 624         Gametype first = NULL; FOREACH(Gametypes, !first, first = it; break);
 625         bool flag = false;
 626         FOREACH(Gametypes, s == MapInfo_Type_ToString(it), {
 627                 // the type was found
 628                 // choose the next one
 629                 flag = true;
 630                 s = MapInfo_Type_ToString(REGISTRY_GET(Gametypes, it.m_id + 1));
 631                 if (s == "") s = MapInfo_Type_ToString(first);
 632                 break;
 633         });
 634         if (!flag) {
 635                 // no type was found
 636                 // choose the first one
 637                 s = MapInfo_Type_ToString(first);
 638         }
 639
 640         if(s != "") s = strcat(s, ":");
 641         s = strcat(s, substring(me.filterString, m+1, strlen(me.filterString) - m - 1));
 642
 643         me.controlledTextbox.setText(me.controlledTextbox, s);
 644         me.controlledTextbox.keyDown(me.controlledTextbox, K_END, 0, 0);
 645         me.controlledTextbox.keyUp(me.controlledTextbox, K_END, 0, 0);
 646         //ServerList_Filter_Change(me.controlledTextbox, me);
 647 }
 648 void ServerList_Filter_Change(entity box, entity me)
 649 {
 650         strfree(me.filterString);
 651         if(box.text != "")
 652                 me.filterString = strzone(box.text);
 653         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 654
 655         me.ipAddressBox.setText(me.ipAddressBox, "");
 656         me.ipAddressBox.cursorPos = 0;
 657         me.ipAddressBoxFocused = -1;
 658 }
 659 void ServerList_Categories_Click(entity box, entity me)
 660 {
 661         box.setChecked(box, autocvar_menu_slist_categories = !autocvar_menu_slist_categories);
 662         me.refreshServerList(me, REFRESHSERVERLIST_RESORT);
 663
 664         me.ipAddressBox.setText(me.ipAddressBox, "");
 665         me.ipAddressBox.cursorPos = 0;
 666         me.ipAddressBoxFocused = -1;
 667 }
 668 void ServerList_ShowEmpty_Click(entity box, entity me)
 669 {
 670         box.setChecked(box, me.filterShowEmpty = !me.filterShowEmpty);
 671         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 672
 673         me.ipAddressBox.setText(me.ipAddressBox, "");
 674         me.ipAddressBox.cursorPos = 0;
 675         me.ipAddressBoxFocused = -1;
 676 }
 677 void ServerList_ShowFull_Click(entity box, entity me)
 678 {
 679         box.setChecked(box, me.filterShowFull = !me.filterShowFull);
 680         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 681
 682         me.ipAddressBox.setText(me.ipAddressBox, "");
 683         me.ipAddressBox.cursorPos = 0;
 684         me.ipAddressBoxFocused = -1;
 685 }
 686 void ServerList_ShowLaggy_Click(entity box, entity me)
 687 {
 688         box.setChecked(box, me.filterShowLaggy = !me.filterShowLaggy);
 689         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 690
 691         me.ipAddressBox.setText(me.ipAddressBox, "");
 692         me.ipAddressBox.cursorPos = 0;
 693         me.ipAddressBoxFocused = -1;
 694 }
 695 void XonoticServerList_setSortOrder(entity me, int fld, int direction)
 696 {
 697         if(me.currentSortField == fld)
 698                 direction = -me.currentSortOrder;
 699         me.currentSortOrder = direction;
 700         me.currentSortField = fld;
 701         me.sortButton1.forcePressed = (fld == SLIST_FIELD_PING);
 702         me.sortButton2.forcePressed = (fld == SLIST_FIELD_NAME);
 703         me.sortButton3.forcePressed = (fld == SLIST_FIELD_MAP);
 704         me.sortButton4.forcePressed = 0;
 705         me.sortButton5.forcePressed = (fld == SLIST_FIELD_NUMHUMANS);
 706         me.selectedItem = 0;
 707         strfree(me.selectedServer);
 708         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 709 }
 710 void XonoticServerList_positionSortButton(entity me, entity btn, float theOrigin, float theSize, string theTitle, void(entity, entity) theFunc)
 711 {
 712         vector originInLBSpace = eY * (-me.itemHeight);
 713         vector sizeInLBSpace = eY * me.itemHeight + eX * (1 - me.controlWidth);
 714
 715         vector originInDialogSpace = boxToGlobal(originInLBSpace, me.Container_origin, me.Container_size);
 716         vector sizeInDialogSpace = boxToGlobalSize(sizeInLBSpace, me.Container_size);
 717
 718         btn.Container_origin_x = originInDialogSpace.x + sizeInDialogSpace.x * theOrigin;
 719         btn.Container_size_x   =                         sizeInDialogSpace.x * theSize;
 720         btn.setText(btn, theTitle);
 721         btn.onClick = theFunc;
 722         btn.onClickEntity = me;
 723         btn.resized = 1;
 724 }
 725 void XonoticServerList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 726 {
 727         SUPER(XonoticServerList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 728
 729         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
 730         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
 731         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 732
 733         me.columnIconsOrigin = 0;
 734         me.columnIconsSize = me.realFontSize.x * 4 * me.iconsSizeFactor;
 735         me.columnPingSize = me.realFontSize.x * 3;
 736         me.columnMapSize = me.realFontSize.x * 10;
 737         me.columnTypeSize = me.realFontSize.x * 4;
 738         me.columnPlayersSize = me.realFontSize.x * 5;
 739         me.columnNameSize = 1 - me.columnPlayersSize - me.columnMapSize - me.columnPingSize - me.columnIconsSize - me.columnTypeSize - 5 * me.realFontSize.x;
 740         me.columnPingOrigin = me.columnIconsOrigin + me.columnIconsSize + me.realFontSize.x;
 741         me.columnNameOrigin = me.columnPingOrigin + me.columnPingSize + me.realFontSize.x;
 742         me.columnMapOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x;
 743         me.columnTypeOrigin = me.columnMapOrigin + me.columnMapSize + me.realFontSize.x;
 744         me.columnPlayersOrigin = me.columnTypeOrigin + me.columnTypeSize + me.realFontSize.x;
 745
 746         me.positionSortButton(me, me.sortButton1, me.columnPingOrigin, me.columnPingSize, _("Ping"), ServerList_PingSort_Click);
 747         me.positionSortButton(me, me.sortButton2, me.columnNameOrigin, me.columnNameSize, _("Hostname"), ServerList_NameSort_Click);
 748         me.positionSortButton(me, me.sortButton3, me.columnMapOrigin, me.columnMapSize, _("Map"), ServerList_MapSort_Click);
 749         me.positionSortButton(me, me.sortButton4, me.columnTypeOrigin, me.columnTypeSize, _("Type"), ServerList_TypeSort_Click);
 750         me.positionSortButton(me, me.sortButton5, me.columnPlayersOrigin, me.columnPlayersSize, _("Players"), ServerList_PlayerSort_Click);
 751
 752         int f = me.currentSortField;
 753         if(f >= 0)
 754         {
 755                 me.currentSortField = -1;
 756                 me.setSortOrder(me, f, me.currentSortOrder); // force resetting the sort order
 757         }
 758 }
 759 void ServerList_Connect_Click(entity btn, entity me)
 760 {
 761         if (me.ipAddressBox.text != "")
 762                 localcmd(sprintf("connect %s\n", me.ipAddressBox.text));
 763 }
 764 void ServerList_Favorite_Click(entity btn, entity this)
 765 {
 766         string addr = this.ipAddressBox.text;
 767         string ipstr = netaddress_resolve(addr, 26000);
 768         if (ipstr == "") return;
 769         m_play_click_sound(MENU_SOUND_SELECT);
 770         this.toggleFavorite(this, addr);
 771         this.ipAddressBoxFocused = -1;
 772 }
 773 void ServerList_Info_Click(entity btn, entity me)
 774 {
 775         if (me.nItems != 0)
 776                 main.serverInfoDialog.loadServerInfo(main.serverInfoDialog, me.selectedItem);
 777
 778         vector org = boxToGlobal(eY * (me.selectedItem * me.itemHeight - me.scrollPos), me.origin, me.size);
 779         vector sz = boxToGlobalSize(eY * me.itemHeight + eX * (1 - me.controlWidth), me.size);
 780         DialogOpenButton_Click_withCoords(me, main.serverInfoDialog, org, sz);
 781 }
 782 void XonoticServerList_doubleClickListBoxItem(entity me, int i, vector where)
 783 {
 784         ServerList_Connect_Click(NULL, me);
 785 }
 786 void XonoticServerList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 787 {
 788         vector oldscale = draw_scale;
 789         vector oldshift = draw_shift;
 790 #define SET_YRANGE(start,end) \
 791         draw_scale = boxToGlobalSize(eX + eY * (end - start), oldscale); \
 792         draw_shift = boxToGlobal(eY * start, oldshift, oldscale);
 793
 794         int c;
 795         for (c = 0; c < category_draw_count; ++c) {
 796                 // Matches exactly the headings with increased height.
 797                 if (i == category_item[c])
 798                         break;
 799         }
 800
 801         if (c < category_draw_count)
 802         {
 803                 entity catent = RetrieveCategoryEnt(category_name[c]);
 804                 if(catent)
 805                 {
 806                         SET_YRANGE(
 807                                 (me.categoriesHeight - 1) / (me.categoriesHeight + 1),
 808                                 me.categoriesHeight / (me.categoriesHeight + 1)
 809                         );
 810                         draw_Text(
 811                                 eY * me.realUpperMargin
 812                                 +
 813 #if 0
 814                                 eX * (me.columnNameOrigin + (me.columnNameSize - draw_TextWidth(catent.cat_string, 0, me.realFontSize)) * 0.5),
 815                                 catent.cat_string,
 816 #else
 817                                 eX * (me.columnNameOrigin),
 818                                 strcat(catent.cat_string, ":"),
 819 #endif
 820                                 me.realFontSize,
 821                                 SKINCOLOR_SERVERLIST_CATEGORY,
 822                                 SKINALPHA_SERVERLIST_CATEGORY,
 823                                 0
 824                         );
 825                         SET_YRANGE(me.categoriesHeight / (me.categoriesHeight + 1), 1);
 826                 }
 827         }
 828
 829         if(isSelected && !me.lockedSelectedItem)
 830                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 831         else if(isFocused)
 832         {
 833                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 834                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 835         }
 836
 837         string s = gethostcachestring(SLIST_FIELD_QCSTATUS, i);
 838         int m = tokenizebyseparator(s, ":");
 839         string typestr = "", versionstr = "";
 840         if(m >= 2)
 841         {
 842                 typestr = argv(0);
 843                 versionstr = argv(1);
 844         }
 845         bool pure = false, pure_available = false;
 846         int freeslots = -1, sflags = -1;
 847         string modname = "";
 848         for(int j = 2; j < m; ++j)
 849         {
 850                 if(argv(j) == "")
 851                         break;
 852                 string key = substring(argv(j), 0, 1);
 853                 string value = substring(argv(j), 1, -1);
 854                 if(key == "P")
 855                 {
 856                         pure = (stof(value) == 0);
 857                         pure_available = true;
 858                 }
 859                 else if(key == "S")
 860                         freeslots = stof(value);
 861                 else if(key == "F")
 862                         sflags = stoi(value);
 863                 else if(key == "M")
 864                         modname = value;
 865         }
 866
 867 #ifdef COMPAT_NO_MOD_IS_XONOTIC
 868         if(modname == "")
 869                 modname = "Xonotic";
 870 #endif
 871
 872         string original_modname = modname;
 873         modname = strtolower(modname);
 874
 875         /*
 876         SLIST_FIELD_MOD = gethostcacheindexforkey("mod");
 877         s = gethostcachestring(SLIST_FIELD_MOD, i);
 878         if(s != "data")
 879                 if(modname == "xonotic")
 880                         modname = s;
 881         */
 882
 883         // list the mods here on which the pure server check actually works
 884         if(modname != "xonotic")
 885         if(modname != "instagib" || modname != "minstagib")
 886         if(modname != "cts")
 887         if(modname != "nix")
 888         if(modname != "newtoys")
 889                 pure_available = false;
 890
 891         float theAlpha;
 892         if(gethostcachenumber(SLIST_FIELD_FREESLOTS, i) <= 0)
 893                 theAlpha = SKINALPHA_SERVERLIST_FULL;
 894         else if(freeslots == 0)
 895                 theAlpha = SKINALPHA_SERVERLIST_FULL; // g_maxplayers support
 896         else if (!gethostcachenumber(SLIST_FIELD_NUMHUMANS, i))
 897                 theAlpha = SKINALPHA_SERVERLIST_EMPTY;
 898         else
 899                 theAlpha = 1;
 900
 901         float ping = gethostcachenumber(SLIST_FIELD_PING, i);
 902         const int PING_LOW = 75;
 903         const int PING_MED = 200;
 904         const int PING_HIGH = 500;
 905         vector theColor;
 906         if(ping < PING_LOW)
 907                 theColor = SKINCOLOR_SERVERLIST_LOWPING + (SKINCOLOR_SERVERLIST_MEDPING - SKINCOLOR_SERVERLIST_LOWPING) * (ping / PING_LOW);
 908         else if(ping < PING_MED)
 909                 theColor = SKINCOLOR_SERVERLIST_MEDPING + (SKINCOLOR_SERVERLIST_HIGHPING - SKINCOLOR_SERVERLIST_MEDPING) * ((ping - PING_LOW) / (PING_MED - PING_LOW));
 910         else if(ping < PING_HIGH)
 911         {
 912                 theColor = SKINCOLOR_SERVERLIST_HIGHPING;
 913                 theAlpha *= 1 + (SKINALPHA_SERVERLIST_HIGHPING - 1) * ((ping - PING_MED) / (PING_HIGH - PING_MED));
 914         }
 915         else
 916         {
 917                 theColor = eX;
 918                 theAlpha *= SKINALPHA_SERVERLIST_HIGHPING;
 919         }
 920
 921         if(gethostcachenumber(SLIST_FIELD_ISFAVORITE, i))
 922         {
 923                 theColor = theColor * (1 - SKINALPHA_SERVERLIST_FAVORITE) + SKINCOLOR_SERVERLIST_FAVORITE * SKINALPHA_SERVERLIST_FAVORITE;
 924                 theAlpha = theAlpha * (1 - SKINALPHA_SERVERLIST_FAVORITE) + SKINALPHA_SERVERLIST_FAVORITE;
 925         }
 926
 927         s = gethostcachestring(SLIST_FIELD_CNAME, i);
 928
 929         bool isv4 = false, isv6 = false;
 930         if(substring(s, 0, 1) == "[")
 931         {
 932                 isv6 = true;
 933                 me.seenIPv6 += 1;
 934         }
 935         else if(IS_DIGIT(substring(s, 0, 1)))
 936         {
 937                 isv4 = true;
 938                 me.seenIPv4 += 1;
 939         }
 940
 941         int crypto = stof(substring(crypto_getencryptlevel(s), 0, 1));
 942         if((crypto <= 0 && cvar("crypto_aeslevel") >= 3) || (crypto >= 3 && cvar("crypto_aeslevel") <= 0))
 943         {
 944                 theColor = SKINCOLOR_SERVERLIST_IMPOSSIBLE;
 945                 theAlpha = SKINALPHA_SERVERLIST_IMPOSSIBLE;
 946         }
 947
 948         if(crypto == 1)
 949         {
 950                 if(cvar("crypto_aeslevel") >= 2)
 951                         crypto |= 4;
 952         }
 953         if(crypto == 2)
 954         {
 955                 if(cvar("crypto_aeslevel") >= 1)
 956                         crypto |= 4;
 957         }
 958         if(crypto == 3)
 959                 crypto = 5;
 960         else if(crypto >= 3)
 961                 crypto -= 2;
 962         // possible status:
 963         // 0: crypto off
 964         // 1: AES possible
 965         // 2: AES recommended but not available
 966         // 3: AES possible and will be used
 967         // 4: AES recommended and will be used
 968         // 5: AES required
 969
 970         // --------------
 971         //  RENDER ICONS
 972         // --------------
 973         vector iconSize = '0 0 0';
 974         iconSize_y = me.realFontSize.y * me.iconsSizeFactor;
 975         iconSize_x = me.realFontSize.x * me.iconsSizeFactor;
 976
 977         vector iconPos = '0 0 0';
 978         iconPos_x = (me.columnIconsSize - 3 * iconSize.x) * 0.5;
 979         iconPos_y = (1 - iconSize.y) * 0.5;
 980
 981         // IP
 982         if(me.seenIPv4 && me.seenIPv6)
 983         {
 984                 if(isv6)
 985                         draw_Picture(iconPos, "icon_ipv6", iconSize, '1 1 1', 1);
 986                 else if(isv4)
 987                         draw_Picture(iconPos, "icon_ipv4", iconSize, '1 1 1', 1);
 988         }
 989
 990         iconPos.x += iconSize.x;
 991
 992         // AES
 993         if(crypto > 0)
 994                 draw_Picture(iconPos, strcat("icon_aeslevel", ftos(crypto)), iconSize, '1 1 1', 1);
 995
 996         iconPos.x += iconSize.x;
 997
 998         // Mod
 999         if(modname == "xonotic")
1000         {
1001                 // Here, pure_available should always be set. If not, consider
1002                 // it an impurity.
1003                 if(pure_available && pure)
1004                         draw_Picture(iconPos, "icon_pure1", iconSize, '1 1 1', 1);
1005         }
1006         else
1007         {
1008                 string icon = strcat("icon_mod_", modname);
1009                 if(draw_PictureSize(icon) == '0 0 0')
1010                         icon = "icon_mod_";
1011
1012                 // In mods, pure_available not being present indicates
1013                 // non-support of the feature. Just show the mod icon as is
1014                 // then.
1015                 if(pure_available && !pure)
1016                         draw_Picture(iconPos, icon, iconSize, '1 1 1', SKINALPHA_SERVERLIST_ICON_NONPURE);
1017                 else
1018                         draw_Picture(iconPos, icon, iconSize, '1 1 1', 1);
1019         }
1020
1021         iconPos.x += iconSize.x;
1022
1023         // Stats
1024         if(sflags >= 0 && (sflags & SERVERFLAG_PLAYERSTATS))
1025                 draw_Picture(iconPos, "icon_stats1", iconSize, '1 1 1', 1);
1026
1027         if(isFocused && me.mouseOverIcons && !me.tooltip)
1028         {
1029                 string t = "";
1030                 if(me.seenIPv4 && me.seenIPv6)
1031                         t = strcat(t, (isv6) ? "IPv6, " : "IPv4, ");
1032                 t = strcat(t, _("encryption:"), " ", (crypto ? sprintf(_("AES level %d"), crypto) : ZCTX(_("ENC^none"))), ", ");
1033                 t = strcat(t, sprintf(_("mod: %s"), ((modname == "xonotic") ? ZCTX(_("MOD^Default")) : original_modname)));
1034                 if(pure_available)
1035                         t = strcat(t, sprintf(" (%s)", (pure) ? _("official settings") : _("modified settings")));
1036                 t = strcat(t, ", ");
1037                 t = strcat(t, ((sflags >= 0 && (sflags & SERVERFLAG_PLAYERSTATS)) ? _("stats enabled") : _("stats disabled")));
1038                 setZonedTooltip(me, t, string_null);
1039         }
1040         // --------------
1041         //  RENDER TEXT
1042         // --------------
1043
1044         // ping
1045         s = ftos(ping);
1046         draw_Text(me.realUpperMargin * eY + (me.columnPingOrigin + me.columnPingSize - draw_TextWidth(s, 0, me.realFontSize)) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1047
1048         // server name
1049         s = draw_TextShortenToWidth(gethostcachestring(SLIST_FIELD_NAME, i), me.columnNameSize, 0, me.realFontSize);
1050         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
1051
1052         // server map
1053         s = draw_TextShortenToWidth(gethostcachestring(SLIST_FIELD_MAP, i), me.columnMapSize, 0, me.realFontSize);
1054         draw_Text(me.realUpperMargin * eY + (me.columnMapOrigin + (me.columnMapSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1055
1056         // server gametype
1057         s = draw_TextShortenToWidth(typestr, me.columnTypeSize, 0, me.realFontSize);
1058         draw_Text(me.realUpperMargin * eY + (me.columnTypeOrigin + (me.columnTypeSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1059
1060         // server playercount
1061         s = strcat(ftos(gethostcachenumber(SLIST_FIELD_NUMHUMANS, i)), "/", ftos(gethostcachenumber(SLIST_FIELD_MAXPLAYERS, i)));
1062         draw_Text(me.realUpperMargin * eY + (me.columnPlayersOrigin + (me.columnPlayersSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1063 }
1064
1065 void XonoticServerList_focusedItemChangeNotify(entity me)
1066 {
1067         clearTooltip(me);
1068 }
1069
1070 float XonoticServerList_mouseMove(entity me, vector pos)
1071 {
1072         if(!SUPER(XonoticServerList).mouseMove(me, pos))
1073         {
1074                 me.mouseOverIcons = false;
1075                 clearTooltip(me);
1076                 return 1;
1077         }
1078
1079         me.mouseOverIcons = (pos_x <= me.columnIconsSize);
1080         if(!me.mouseOverIcons)
1081                 clearTooltip(me);
1082         return 1;
1083 }
1084
1085 bool XonoticServerList_keyDown(entity me, int scan, bool ascii, bool shift)
1086 {
1087         if(scan == K_ENTER || scan == K_KP_ENTER)
1088         {
1089                 ServerList_Connect_Click(NULL, me);
1090                 return true;
1091         }
1092         else if(scan == K_MOUSE2 || scan == K_SPACE)
1093         {
1094                 if(me.nItems != 0)
1095                 {
1096                         vector org = boxToGlobal(eY * (me.selectedItem * me.itemHeight - me.scrollPos), me.origin, me.size);
1097                         vector sz = boxToGlobalSize(eY * me.itemHeight + eX * (1 - me.controlWidth), me.size);
1098                         m_play_click_sound(MENU_SOUND_OPEN);
1099                         main.serverInfoDialog.loadServerInfo(main.serverInfoDialog, me.selectedItem);
1100                         DialogOpenButton_Click_withCoords(me, main.serverInfoDialog, org, sz);
1101                         return true;
1102                 }
1103                 return false;
1104         }
1105         else if(scan == K_INS || scan == K_MOUSE3 || scan == K_KP_INS)
1106         {
1107                 if(me.nItems != 0)
1108                 {
1109                         me.toggleFavorite(me, me.selectedServer);
1110                         me.ipAddressBoxFocused = -1;
1111                         return true;
1112                 }
1113                 return false;
1114         }
1115         else if(SUPER(XonoticServerList).keyDown(me, scan, ascii, shift))
1116                 return true;
1117         else if(!me.controlledTextbox)
1118                 return false;
1119         else
1120                 return me.controlledTextbox.keyDown(me.controlledTextbox, scan, ascii, shift);
1121 }
1122
1123 float XonoticServerList_getTotalHeight(entity me)
1124 {
1125         float num_normal_rows = me.nItems;
1126         int num_headers = category_draw_count;
1127         return me.itemHeight * (num_normal_rows + me.categoriesHeight * num_headers);
1128 }
1129 int XonoticServerList_getItemAtPos(entity me, float pos)
1130 {
1131         pos = pos / me.itemHeight;
1132         for (int i = category_draw_count - 1; i >= 0; --i) {
1133                 int itemidx = category_item[i];
1134                 float itempos = i * me.categoriesHeight + category_item[i];
1135                 if (pos >= itempos + me.categoriesHeight + 1)
1136                         return itemidx + 1 + floor(pos - (itempos + me.categoriesHeight + 1));
1137                 if (pos >= itempos)
1138                         return itemidx;
1139         }
1140         // No category matches? Note that category 0 is... 0. Therefore no headings exist at all.
1141         return floor(pos);
1142 }
1143 float XonoticServerList_getItemStart(entity me, int item)
1144 {
1145         for (int i = category_draw_count - 1; i >= 0; --i) {
1146                 int itemidx = category_item[i];
1147                 float itempos = i * me.categoriesHeight + category_item[i];
1148                 if (item >= itemidx + 1)
1149                         return (itempos + me.categoriesHeight + 1 + item - (itemidx + 1)) * me.itemHeight;
1150                 if (item >= itemidx)
1151                         return itempos * me.itemHeight;
1152         }
1153         // No category matches? Note that category 0 is... 0. Therefore no headings exist at all.
1154         return item * me.itemHeight;
1155 }
1156 float XonoticServerList_getItemHeight(entity me, int item)
1157 {
1158         for (int i = 0; i < category_draw_count; ++i) {
1159                 // Matches exactly the headings with increased height.
1160                 if (item == category_item[i])
1161                         return me.itemHeight * (me.categoriesHeight + 1);
1162         }
1163         return me.itemHeight;
1164 }