qcsrc/menu/xonotic/textslider.qc

   1 #ifndef TEXTSLIDER_H
   2 #define TEXTSLIDER_H
   3 #include "../item/textslider.qc"
   4 CLASS(XonoticTextSlider, TextSlider)
   5         METHOD(XonoticTextSlider, configureXonoticTextSlider, void(entity, string, string));
   6         METHOD(XonoticTextSlider, setValue, void(entity, float));
   7         METHOD(XonoticTextSlider, configureXonoticTextSliderValues, void(entity));
   8         ATTRIB(XonoticTextSlider, fontSize, float, SKINFONTSIZE_NORMAL)
   9         ATTRIB(XonoticTextSlider, valueSpace, float, SKINWIDTH_SLIDERTEXT)
  10         ATTRIB(XonoticTextSlider, image, string, SKINGFX_SLIDER)
  11         ATTRIB(XonoticTextSlider, tolerance, vector, SKINTOLERANCE_SLIDER)
  12         ATTRIB(XonoticTextSlider, align, float, 0.5)
  13         ATTRIB(XonoticTextSlider, color, vector, SKINCOLOR_SLIDER_N)
  14         ATTRIB(XonoticTextSlider, colorC, vector, SKINCOLOR_SLIDER_C)
  15         ATTRIB(XonoticTextSlider, colorF, vector, SKINCOLOR_SLIDER_F)
  16         ATTRIB(XonoticTextSlider, colorD, vector, SKINCOLOR_SLIDER_D)
  17         ATTRIB(XonoticTextSlider, color2, vector, SKINCOLOR_SLIDER_S)
  18
  19         ATTRIB(XonoticTextSlider, cvarName, string, string_null)
  20         METHOD(XonoticTextSlider, loadCvars, void(entity));
  21         METHOD(XonoticTextSlider, saveCvars, void(entity));
  22         ATTRIB(XonoticTextSlider, sendCvars, float, 0)
  23
  24         ATTRIB(XonoticTextSlider, alpha, float, SKINALPHA_TEXT)
  25         ATTRIB(XonoticTextSlider, disabledAlpha, float, SKINALPHA_DISABLED)
  26 ENDCLASS(XonoticTextSlider)
  27 entity makeXonoticTextSlider_T(string, string theTooltip);
  28 entity makeXonoticTextSlider(string); // note: you still need to call addValue and configureXonoticTextSliderValues!
  29 #endif
  30
  31 #ifdef IMPLEMENTATION
  32 entity makeXonoticTextSlider_T(string theCvar, string theTooltip)
  33 {
  34         entity me;
  35         me = NEW(XonoticTextSlider);
  36         me.configureXonoticTextSlider(me, theCvar, theTooltip);
  37         return me;
  38 }
  39 entity makeXonoticTextSlider(string theCvar)
  40 {
  41         return makeXonoticTextSlider_T(theCvar, string_null);
  42 }
  43 void XonoticTextSlider_configureXonoticTextSlider(entity me, string theCvar, string theTooltip)
  44 {
  45         me.configureSliderVisuals(me, me.fontSize, me.align, me.valueSpace, me.image);
  46         if(theCvar)
  47         {
  48                 me.cvarName = theCvar;
  49                 // me.loadCvars(me); // don't load it yet
  50         }
  51         setZonedTooltip(me, theTooltip, theCvar);
  52 }
  53 void XonoticTextSlider_setValue(entity me, float val)
  54 {
  55         if(val != me.value)
  56         {
  57                 SUPER(XonoticTextSlider).setValue( me, val );
  58                 me.saveCvars(me);
  59         }
  60 }
  61 void XonoticTextSlider_loadCvars(entity me)
  62 {
  63         if (!me.cvarName)
  64                 return;
  65
  66         float n = tokenize_console(me.cvarName);
  67         string s = cvar_string(argv(0));
  68         float i;
  69         for(i = 1; i < n; ++i)
  70                 s = strcat(s, " ", cvar_string(argv(i)));
  71         me.setValueFromIdentifier(me, s);
  72         if(me.value < 0 && n > 1)
  73         {
  74                 // if it failed: check if all cvars have the same value
  75                 // if yes, try its value as 1-word identifier
  76                 for(i = 1; i < n; ++i)
  77                         if(cvar_string(argv(i)) != cvar_string(argv(i-1)))
  78                                 break;
  79                 if(i >= n)
  80                         me.setValueFromIdentifier(me, cvar_string(argv(0)));
  81         }
  82 }
  83 void XonoticTextSlider_saveCvars(entity me)
  84 {
  85         if (!me.cvarName)
  86                 return;
  87
  88         if(me.value >= 0 && me.value < me.nValues)
  89         {
  90                 float n = tokenize_console(me.cvarName);
  91                 if(n == 1)
  92                 {
  93                         // this is a special case to allow spaces in the identifiers
  94                         cvar_set(argv(0), me.getIdentifier(me));
  95                         CheckSendCvars(me, argv(0));
  96                 }
  97                 else
  98                 {
  99                         float i;
 100                         float m = tokenize_console(strcat(me.cvarName, " ", me.getIdentifier(me)));
 101                         if(m == n + 1)
 102                         {
 103                                 for(i = 0; i < n; ++i)
 104                                 {
 105                                         cvar_set(argv(i), argv(n));
 106                                         CheckSendCvars(me, argv(i));
 107                                 }
 108                         }
 109                         else if(m == n * 2)
 110                         {
 111                                 for(i = 0; i < n; ++i)
 112                                 {
 113                                         cvar_set(argv(i), argv(i + n));
 114                                         CheckSendCvars(me, argv(i));
 115                                 }
 116                         }
 117                         else
 118                                 error("XonoticTextSlider: invalid identifier ", me.getIdentifier(me), " does not match cvar list ", me.cvarName);
 119                 }
 120         }
 121 }
 122 void XonoticTextSlider_configureXonoticTextSliderValues(entity me)
 123 {
 124         me.configureTextSliderValues(me, string_null);
 125         me.loadCvars(me);
 126 }
 127 #endif