qcsrc/menu/xonotic/util.qc

   1 float GL_CheckExtension(string ext)
   2 {
   3         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
   4 }
   5
   6 float GL_Have_TextureCompression()
   7 {
   8         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
   9 }
  10
  11 float tooltipdb;
  12 void loadTooltips()
  13 {
  14         tooltipdb = db_load(language_filename("tooltips.db"));
  15 }
  16 void unloadTooltips()
  17 {
  18         if(tooltipdb >= 0)
  19                 db_close(tooltipdb);
  20         tooltipdb = -1;
  21 }
  22 string getZonedTooltipForIdentifier(string s)
  23 {
  24         string t;
  25         if(s == "")
  26                 return string_null;
  27         if(tooltipdb >= 0)
  28         {
  29                 t = db_get(tooltipdb, s);
  30                 if(t == "-")
  31                         return string_null;
  32                 if(t != "")
  33                         return strzone(t);
  34         }
  35         if(prvm_language == "en" || prvm_language == "")
  36         {
  37                 t = cvar_description(s);
  38                 if(t != "" && t != "custom cvar")
  39                         return strzone(t);
  40         }
  41         dprint("WARNING: no tooltip set for ", s, "\n");
  42         return string_null;
  43 }
  44
  45 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  46 {
  47         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  48 }
  49
  50 .string cvarName;
  51 void SUB_Null_ee(entity e1, entity e2)
  52 {
  53 }
  54 void saveCvarsOf(entity ignore, entity e)
  55 {
  56         if(e.saveCvars)
  57                 e.saveCvars(e);
  58 }
  59 void loadCvarsOf(entity ignore, entity e)
  60 {
  61         if(e.loadCvars)
  62                 e.loadCvars(e);
  63 }
  64 void saveAllCvars(entity root)
  65 {
  66         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  67 }
  68 void loadAllCvars(entity root)
  69 {
  70         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  71 }
  72
  73 .string cvarNames_Multi;
  74 .void(entity me) saveCvars_Multi;
  75 void saveCvarsMulti(entity me)
  76 {
  77         float n, i;
  78         string s;
  79
  80         me.saveCvars_Multi(me);
  81         s = cvar_string(me.cvarName);
  82
  83         n = tokenize_console(me.cvarNames_Multi);
  84         for(i = 0; i < n; ++i)
  85                 cvar_set(argv(i), s);
  86 }
  87 void makeMulti(entity e, string otherCvars)
  88 {
  89         e.cvarNames_Multi = otherCvars;
  90         e.saveCvars_Multi = e.saveCvars;
  91         e.saveCvars = saveCvarsMulti;
  92 }
  93
  94 .void(entity me) saveCvars_Callback;
  95 .entity saveCvars_Callback_ent;
  96 .void(entity me, entity cb) saveCvars_Callback_func;
  97 void saveCvarsCallback(entity me)
  98 {
  99         me.saveCvars_Callback(me);
 100         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 101 }
 102 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 103 {
 104         e.saveCvars_Callback = e.saveCvars;
 105         e.saveCvars = saveCvarsCallback;
 106         e.saveCvars_Callback_ent = cbent;
 107         e.saveCvars_Callback_func = cbfunc;
 108 }
 109
 110 .void(entity) draw_setDependent;
 111 .string cvar_setDependent;
 112 .float cvarMin_setDependent;
 113 .float cvarMax_setDependent;
 114 .string cvar2_setDependent;
 115 .float cvar2Min_setDependent;
 116 .float cvar2Max_setDependent;
 117 .string cvar3_setDependent;
 118 .float cvar3Min_setDependent;
 119 .float cvar3Max_setDependent;
 120 .float op_setDependent;
 121 .string cvarString_setDependent;
 122 .string cvarValue_setDependent;
 123 .float(entity) func_setDependent;
 124 void setDependent_Check(entity e)
 125 {
 126         float f;
 127         string s;
 128         if(e.func_setDependent)
 129         {
 130                 e.disabled = !(e.func_setDependent(e));
 131         }
 132         else if(e.cvarString_setDependent)
 133         {
 134                 s = cvar_string(e.cvarString_setDependent);
 135                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 136         }
 137         else
 138         {
 139                 if(e.cvar_setDependent)
 140                 {
 141                         f = cvar(e.cvar_setDependent);
 142                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 143                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 144                         else
 145                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 146                 }
 147                 if(e.cvar2_setDependent)
 148                 {
 149                         f = cvar(e.cvar2_setDependent);
 150                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 151                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 152                         else
 153                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 154                 }
 155                 if(e.cvar3_setDependent)
 156                 {
 157                         f = cvar(e.cvar3_setDependent);
 158                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 159                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 160                         else
 161                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 162                 }
 163         }
 164 }
 165 void setDependent_Draw(entity e)
 166 {
 167         setDependent_Check(e);
 168         e.draw_setDependent(e);
 169 }
 170 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 171 {
 172         e.draw_setDependent = e.draw;
 173         e.cvar_setDependent = theCvarName;
 174         e.cvarMin_setDependent = theCvarMin;
 175         e.cvarMax_setDependent = theCvarMax;
 176         e.cvar2_setDependent = string_null;
 177         e.cvar3_setDependent = string_null;
 178         e.func_setDependent = func_null;
 179         e.draw = setDependent_Draw;
 180         setDependent_Check(e);
 181 }
 182 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 183 {
 184         e.draw_setDependent = e.draw;
 185         e.cvarString_setDependent = theCvarName;
 186         e.cvarValue_setDependent = theCvarValue;
 187         e.cvar_setDependent = string_null;
 188         e.cvar2_setDependent = string_null;
 189         e.cvar3_setDependent = string_null;
 190         e.func_setDependent = func_null;
 191         e.draw = setDependent_Draw;
 192         setDependent_Check(e);
 193 }
 194 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 195 {
 196         e.draw_setDependent = e.draw;
 197         e.cvar_setDependent = theCvarName;
 198         e.cvarMin_setDependent = theCvarMin;
 199         e.cvarMax_setDependent = theCvarMax;
 200         e.cvar2_setDependent = theCvar2Name;
 201         e.cvar2Min_setDependent = theCvar2Min;
 202         e.cvar2Max_setDependent = theCvar2Max;
 203         e.cvar3_setDependent = string_null;
 204         e.op_setDependent = 0;
 205         e.func_setDependent = func_null;
 206         e.draw = setDependent_Draw;
 207         setDependent_Check(e);
 208 }
 209 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 210 {
 211         e.draw_setDependent = e.draw;
 212         e.cvar_setDependent = theCvarName;
 213         e.cvarMin_setDependent = theCvarMin;
 214         e.cvarMax_setDependent = theCvarMax;
 215         e.cvar2_setDependent = theCvar2Name;
 216         e.cvar2Min_setDependent = theCvar2Min;
 217         e.cvar2Max_setDependent = theCvar2Max;
 218         e.cvar3_setDependent = string_null;
 219         e.op_setDependent = 1;
 220         e.func_setDependent = func_null;
 221         e.draw = setDependent_Draw;
 222         setDependent_Check(e);
 223 }
 224 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 225 {
 226         e.draw_setDependent = e.draw;
 227         e.cvar_setDependent = theCvarName;
 228         e.cvarMin_setDependent = theCvarMin;
 229         e.cvarMax_setDependent = theCvarMax;
 230         e.cvar2_setDependent = theCvar2Name;
 231         e.cvar2Min_setDependent = theCvar2Min;
 232         e.cvar2Max_setDependent = theCvar2Max;
 233         e.cvar3_setDependent = theCvar3Name;
 234         e.cvar3Min_setDependent = theCvar3Min;
 235         e.cvar3Max_setDependent = theCvar3Max;
 236         e.op_setDependent = 0;
 237         e.func_setDependent = func_null;
 238         e.draw = setDependent_Draw;
 239         setDependent_Check(e);
 240 }
 241 void setDependentWeird(entity e, float(entity) func)
 242 {
 243         e.draw_setDependent = e.draw;
 244         e.func_setDependent = func;
 245         e.draw = setDependent_Draw;
 246         setDependent_Check(e);
 247 }
 248
 249 // URI SYSTEM ////////////////////////////////////////////////////////
 250
 251 float _Nex_ExtResponseSystem_Queried;
 252 string _Nex_ExtResponseSystem_UpdateTo;
 253 string _Nex_ExtResponseSystem_UpdateToURL;
 254
 255 void URI_Get_Callback(float id, float status, string data)
 256 {
 257         if (id == URI_GET_DISCARD)
 258         {
 259                 // discard
 260         }
 261         else if(id == URI_GET_UPDATENOTIFICATION)
 262         {
 263                 UpdateNotification_URI_Get_Callback(id, status, data);
 264         }
 265         else if(id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 266         {
 267                 Curl_URI_Get_Callback(id, status, data);
 268         }
 269         else
 270         {
 271                 print(sprintf(_("Received HTTP request data for an invalid id %d.\n"), id));
 272         }
 273 }
 274
 275 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 276 {
 277         float n;
 278
 279         if(_Nex_ExtResponseSystem_UpdateTo)
 280         {
 281                 dprint("error: UpdateNotification_URI_Get_Callback has been called before\n");
 282                 return;
 283         }
 284         if(status != 0)
 285         {
 286                 print(sprintf(_("error receiving update notification: status is %d\n"), status));
 287                 return;
 288         }
 289         if(substring(data, 0, 1) == "<")
 290         {
 291                 print(_("error: received HTML instead of an update notification\n"));
 292                 return;
 293         }
 294         if(strstrofs(data, "\r", 0) != -1)
 295         {
 296                 print(_("error: received carriage returns from update notification server\n"));
 297                 return;
 298         }
 299
 300         if(data == "")
 301                 n = 0;
 302         else
 303                 n = tokenizebyseparator(data, "\n");
 304
 305         if(n >= 1)
 306         {
 307                 _Nex_ExtResponseSystem_UpdateTo = argv(0);
 308
 309                 if(vercmp(cvar_string("g_xonoticversion"), _Nex_ExtResponseSystem_UpdateTo) >= 0)
 310                 {
 311                         _Nex_ExtResponseSystem_UpdateTo = ""; // no update needed
 312                 }
 313                 else
 314                 {
 315                         // update needed
 316                         if(n >= 2)
 317                                 print(sprintf(_("Update can be downloaded at:\n%s\n"), argv(1)));
 318                         if(n >= 3)
 319                                 _Nex_ExtResponseSystem_UpdateToURL = strzone(argv(2));
 320                 }
 321
 322                 _Nex_ExtResponseSystem_UpdateTo = strzone(_Nex_ExtResponseSystem_UpdateTo);
 323         }
 324 }
 325
 326 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 327
 328 float preMenuInit()
 329 {
 330         vector sz;
 331         vector boxA, boxB;
 332
 333         MapInfo_Cache_Create();
 334         MapInfo_Enumerate();
 335         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 336         {
 337                 draw_reset_cropped();
 338
 339                 sz = eX * 0.025 + eY * 0.025 * (draw_scale_x / draw_scale_y);
 340                 draw_CenterText('0.5 0.5 0' - 1.25 * sz_y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 341
 342                 boxA = '0.05 0.5 0' + 0.25 * sz_y * eY;
 343                 boxB = '0.95 0.5 0' + 1.25 * sz_y * eY;
 344                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 345
 346                 boxA += sz * 0.1;
 347                 boxB -= sz * 0.1;
 348                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 349
 350                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 351                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 352
 353                 return FALSE;
 354         }
 355         return TRUE;
 356 }
 357
 358 string campaign_name_previous;
 359 float campaign_won_previous;
 360 #ifdef WATERMARK
 361 var string autocvar_menu_watermark = WATERMARK();
 362 #else
 363 var string autocvar_menu_watermark = "";
 364 #endif
 365 void postMenuDraw()
 366 {
 367         if(autocvar_menu_watermark != "")
 368         {
 369                 vector fs = '48 48 0';
 370                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 371         }
 372 }
 373 void preMenuDraw()
 374 {
 375         vector fs, sz, line, mid;
 376
 377         if(cvar("menu_updatecheck"))
 378         {
 379                 if(!_Nex_ExtResponseSystem_Queried)
 380                 {
 381                         _Nex_ExtResponseSystem_Queried = 1;
 382                         float startcnt;
 383                         string uri;
 384
 385                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 386
 387                         // for privacy, munge the start count a little
 388                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 389                         uri = sprintf("http://www.xonotic.org/dl/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 390
 391 #ifdef CVAR_POPCON
 392                         float cvar_handle, popcon_handle;
 393                         float n, i, j;
 394                         string k, s;
 395                         cvar_handle = buf_create();
 396                         buf_cvarlist(cvar_handle, "", "");
 397                         n = buf_getsize(cvar_handle);
 398                         popcon_handle = buf_create();
 399                         for(i= 0, j = 0; i < n; ++i)
 400                         {
 401                                 k = bufstr_get(cvar_handle, i);
 402                                 if(!(cvar_type(k) & CVAR_TYPEFLAG_SAVED))
 403                                         continue;
 404                                 s = sprintf("%s=%d", uri_escape(k), cvar_string(k) != cvar_defstring(k));
 405                                 bufstr_set(popcon_handle, j, s);
 406                                 ++j;
 407                         }
 408                         buf_del(cvar_handle);
 409                         uri_postbuf(
 410                                 uri, URI_GET_UPDATENOTIFICATION,
 411                                 "application/x-www-form-urlencoded",
 412                                 "&",
 413                                 popcon_handle
 414                         );
 415                         buf_del(popcon_handle);
 416 #else
 417                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 418 #endif
 419                 }
 420         }
 421
 422         if(_Nex_ExtResponseSystem_UpdateTo != "")
 423         {
 424                 // TODO rather turn this into a dialog
 425                 fs = ((1/draw_scale_x) * eX + (1/draw_scale_y) * eY) * 12;
 426                 line = eY * fs_y;
 427                 string l1, l2;
 428                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 429                 l2 = "http://www.xonotic.org/";
 430                 if(_Nex_ExtResponseSystem_UpdateToURL)
 431                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 432
 433                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 434                                 draw_TextWidth(l1, 0, fs),
 435                                 draw_TextWidth(l2, 0, fs)
 436                         );
 437                 sz_y = 3 * fs_y;
 438
 439                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 440                 mid = eX * (0.5 + 0.5 * (1 - sz_x) * cos(time * 0.071))
 441                     + eY * (0.5 + 0.5 * (1 - sz_y) * sin(time * 0.071));
 442
 443                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 444                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 445                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 446         }
 447         if not(campaign_name_previous)
 448                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 449         if(campaign_name == campaign_name_previous)
 450         {
 451                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 452                 {
 453                         if(!campaign_won_previous)
 454                         {
 455                                 m_display();
 456                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 457                         }
 458                         campaign_won_previous = 1;
 459                 }
 460                 else
 461                         campaign_won_previous = 0;
 462         }
 463         else
 464         {
 465                 strunzone(campaign_name_previous);
 466                 campaign_name_previous = strzone(campaign_name);
 467                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 468         }
 469 }
 470
 471 string resolvemod(string m)
 472 {
 473         if(m == "=")
 474                 return getcurrentmod();
 475         else
 476                 return m;
 477 }
 478
 479 float updateCompression()
 480 {
 481         float have_dds, have_jpg, have_tga;
 482         float can_dds;
 483         have_dds = (fexists("dds/particles/particlefont.dds"));
 484         have_jpg = (fexists("particles/particlefont.jpg"));
 485         have_tga = (fexists("particles/particlefont.tga"));
 486         can_dds = GL_Have_TextureCompression();
 487         if(have_dds && (have_jpg || have_tga))
 488         {
 489                 // both? Let's only use good quality precompressed files
 490                 // but ONLY if we actually support it!
 491                 if(can_dds)
 492                 {
 493                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 494                         cvar_set("gl_texturecompression", "0");
 495                         return 1;
 496
 497                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 498                         //return 2;
 499                 }
 500                 else
 501                 {
 502                         cvar_set("gl_texturecompression", "0");
 503                         cvar_set("r_texture_dds_load", "0");
 504                         return 0;
 505                 }
 506         }
 507         else if(have_dds)
 508         {
 509                 // DDS only? We probably always want texture compression
 510                 cvar_set("gl_texturecompression", "1");
 511                 cvar_set("r_texture_dds_load", "1");
 512                 if(!can_dds)
 513                         print(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 514                 return 0;
 515         }
 516         else
 517         {
 518                 // TGA only? Allow runtime compression
 519                 if(can_dds)
 520                 {
 521                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 522                         return 2;
 523                 }
 524                 else
 525                 {
 526                         cvar_set("gl_texturecompression", "0");
 527                         cvar_set("r_texture_dds_load", "0");
 528                         return 0;
 529                 }
 530         }
 531 }
 532
 533 // note: include only those that should be in the menu!
 534 #define GAMETYPES \
 535         GAMETYPE(MAPINFO_TYPE_ARENA, _("Arena")) \
 536         GAMETYPE(MAPINFO_TYPE_ASSAULT, _("Assault")) \
 537         GAMETYPE(MAPINFO_TYPE_CTF, _("Capture The Flag")) \
 538         GAMETYPE(MAPINFO_TYPE_CA, _("Clan Arena")) \
 539         GAMETYPE(MAPINFO_TYPE_DEATHMATCH, _("Deathmatch")) \
 540         GAMETYPE(MAPINFO_TYPE_DOMINATION, _("Domination")) \
 541         GAMETYPE(MAPINFO_TYPE_FREEZETAG, _("Freeze Tag")) \
 542         GAMETYPE(MAPINFO_TYPE_KEEPAWAY, _("Keepaway")) \
 543         GAMETYPE(MAPINFO_TYPE_KEYHUNT, _("Key Hunt")) \
 544         GAMETYPE(MAPINFO_TYPE_LMS, _("Last Man Standing")) \
 545         GAMETYPE(MAPINFO_TYPE_NEXBALL, _("Nexball")) \
 546         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT, _("Onslaught")) \
 547         GAMETYPE(MAPINFO_TYPE_RACE, _("Race")) \
 548         GAMETYPE(MAPINFO_TYPE_CTS, _("Race CTS")) \
 549         GAMETYPE(MAPINFO_TYPE_RUNEMATCH, _("Runematch")) \
 550         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH, _("Team Deathmatch")) \
 551         /* nothing */
 552
 553 float GameType_GetID(float cnt)
 554 {
 555         float i;
 556         i = 0;
 557 #define GAMETYPE(id,name) if(i++ == cnt) return id;
 558         GAMETYPES
 559 #undef GAMETYPE
 560         return 0;
 561 }
 562 string GameType_GetName(float cnt)
 563 {
 564         float i;
 565         i = 0;
 566 #define GAMETYPE(id,name) if(i++ == cnt) return name;
 567         GAMETYPES
 568 #undef GAMETYPE
 569         return _("@!#%'n Tuba Throwing");
 570 }
 571 float GameType_GetCount()
 572 {
 573         float i;
 574         i = 0;
 575 #define GAMETYPE(id,name) ++i;
 576         GAMETYPES
 577 #undef GAMETYPE
 578         return i;
 579 }
 580
 581 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 582 {
 583         float i;
 584         entity e;
 585
 586         me.TR(me);
 587                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 588                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 589                                 e.addValue(e, _("Default"), "");
 590                                 e.addValue(e, _("Disable"), "0");
 591                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 592                                 e.configureXonoticTextSliderValues(e);
 593         me.TR(me);
 594                 me.TDempty(me, 0.2);
 595                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 596                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 597                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 598         me.TR(me);
 599                 me.TDempty(me, 0.2);
 600                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 601         me.TR(me);
 602                 me.TDempty(me, 0.2);
 603                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 604                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 605                                 e.addValue(e, _("Default"), "");
 606                                 e.addValue(e, _("Disable"), "0");
 607                                 for(i = 1; i <= 10; ++i)
 608                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 609                                 e.configureXonoticTextSliderValues(e);
 610         me.TR(me);
 611                 me.TDempty(me, 0.2);
 612                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 613                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 614                                 e.addValue(e, _("Default"), "");
 615                                 for(i = 1; i <= 10; ++i)
 616                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 617                                 e.configureXonoticTextSliderValues(e);
 618         me.TR(me);
 619                 me.TDempty(me, 0.2);
 620                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 621                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 622                                 e.addValue(e, _("Default"), "");
 623                                 e.addValue(e, _("Disable"), "0");
 624                                 for(i = 1; i <= 10; ++i)
 625                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 626                                 e.configureXonoticTextSliderValues(e);
 627         me.TR(me);
 628                 me.TDempty(me, 0.4);
 629                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 630         me.TR(me);
 631                 me.TDempty(me, 0.2);
 632                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 633                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 634                                 e.addValue(e, _("Default"), "");
 635                                 for(i = 0; i <= 10; ++i)
 636                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 637                                 e.configureXonoticTextSliderValues(e);
 638 }