qcsrc/menu/xonotic/util.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4 #endif
   5
   6 float GL_CheckExtension(string ext)
   7 {
   8         return (strstrofs(strcat(" ", cvar_string("gl_info_extensions"), " "), strcat(" ", ext, " "), 0) >= 0);
   9 }
  10
  11 float GL_Have_TextureCompression()
  12 {
  13         return (GL_CheckExtension("GL_EXT_texture_compression_s3tc") && GL_CheckExtension("GL_ARB_texture_compression"));
  14 }
  15
  16 void loadTooltips()
  17 {
  18         tooltipdb = db_load(language_filename("tooltips.db"));
  19 }
  20 void unloadTooltips()
  21 {
  22         if(tooltipdb >= 0)
  23                 db_close(tooltipdb);
  24         tooltipdb = -1;
  25 }
  26 string getZonedTooltipForIdentifier(string s)
  27 {
  28         string t;
  29         if(s == "")
  30                 return string_null;
  31         if(tooltipdb >= 0)
  32         {
  33                 t = db_get(tooltipdb, s);
  34                 if(t == "-")
  35                         return string_null;
  36                 if(t != "")
  37                         return strzone(t);
  38         }
  39         if(prvm_language == "en")
  40         {
  41                 t = cvar_description(s);
  42                 if(t != "" && t != "custom cvar")
  43                         return strzone(t);
  44         }
  45         dprint("WARNING: no tooltip set for ", s, "\n");
  46         return string_null;
  47 }
  48
  49 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  50 {
  51         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  52 }
  53
  54 .string cvarName;
  55 void SUB_Null_ee(entity e1, entity e2)
  56 {
  57 }
  58 void saveCvarsOf(entity ignore, entity e)
  59 {
  60         if(e.saveCvars)
  61                 e.saveCvars(e);
  62 }
  63 void loadCvarsOf(entity ignore, entity e)
  64 {
  65         if(e.loadCvars)
  66                 e.loadCvars(e);
  67 }
  68 void saveAllCvars(entity root)
  69 {
  70         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  71 }
  72 void loadAllCvars(entity root)
  73 {
  74         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  75 }
  76
  77 .string cvarNames_Multi;
  78 .void(entity me) saveCvars_Multi;
  79 string getCvarsMulti(entity me)
  80 {
  81         if (me.cvarNames_Multi)
  82                 return me.cvarNames_Multi;
  83         return string_null;
  84 }
  85 void saveCvarsMulti(entity me)
  86 {
  87         float n, i;
  88         string s;
  89
  90         me.saveCvars_Multi(me);
  91         s = cvar_string(me.cvarName);
  92
  93         n = tokenize_console(me.cvarNames_Multi);
  94         for(i = 0; i < n; ++i)
  95         {
  96                 if(substring(argv(i), 0, 1) == "!")
  97                         cvar_set(substring(argv(i), 1, strlen(argv(i))), ((s == "0") ? "1" : "0"));
  98                 else
  99                         cvar_set(argv(i), s);
 100
 101                 CheckSendCvars(me, argv(i));
 102         }
 103 }
 104 void makeMulti(entity e, string otherCvars)
 105 {
 106         e.cvarNames_Multi = otherCvars;
 107         e.saveCvars_Multi = e.saveCvars;
 108         e.saveCvars = saveCvarsMulti;
 109 }
 110
 111 .void(entity me) saveCvars_Callback;
 112 .entity saveCvars_Callback_ent;
 113 .void(entity me, entity cb) saveCvars_Callback_func;
 114 void saveCvarsCallback(entity me)
 115 {
 116         me.saveCvars_Callback(me);
 117         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 118 }
 119 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 120 {
 121         e.saveCvars_Callback = e.saveCvars;
 122         e.saveCvars = saveCvarsCallback;
 123         e.saveCvars_Callback_ent = cbent;
 124         e.saveCvars_Callback_func = cbfunc;
 125 }
 126
 127 .void(entity) draw_setDependent;
 128 .string cvar_setDependent;
 129 .float cvarMin_setDependent;
 130 .float cvarMax_setDependent;
 131 .string cvar2_setDependent;
 132 .float cvar2Min_setDependent;
 133 .float cvar2Max_setDependent;
 134 .string cvar3_setDependent;
 135 .float cvar3Min_setDependent;
 136 .float cvar3Max_setDependent;
 137 .float op_setDependent;
 138 .string cvarString_setDependent;
 139 .string cvarValue_setDependent;
 140 .float(entity) func_setDependent;
 141 void setDependent_Check(entity e)
 142 {
 143         float f;
 144         string s;
 145         if(e.func_setDependent)
 146         {
 147                 e.disabled = !(e.func_setDependent(e));
 148         }
 149         else if(e.cvarString_setDependent)
 150         {
 151                 s = cvar_string(e.cvarString_setDependent);
 152                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 153         }
 154         else
 155         {
 156                 if(e.cvar_setDependent)
 157                 {
 158                         f = cvar(e.cvar_setDependent);
 159                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 160                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 161                         else
 162                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 163                 }
 164                 if(e.cvar2_setDependent)
 165                 {
 166                         f = cvar(e.cvar2_setDependent);
 167                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 168                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 169                         else
 170                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 171                 }
 172                 if(e.cvar3_setDependent)
 173                 {
 174                         f = cvar(e.cvar3_setDependent);
 175                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 176                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 177                         else
 178                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 179                 }
 180         }
 181 }
 182 void setDependent_Draw(entity e)
 183 {
 184         setDependent_Check(e);
 185         e.draw_setDependent(e);
 186 }
 187 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 188 {
 189         e.draw_setDependent = e.draw;
 190         e.cvar_setDependent = theCvarName;
 191         e.cvarMin_setDependent = theCvarMin;
 192         e.cvarMax_setDependent = theCvarMax;
 193         e.cvar2_setDependent = string_null;
 194         e.cvar3_setDependent = string_null;
 195         e.func_setDependent = func_null;
 196         e.draw = setDependent_Draw;
 197         setDependent_Check(e);
 198 }
 199 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 200 {
 201         e.draw_setDependent = e.draw;
 202         e.cvarString_setDependent = theCvarName;
 203         e.cvarValue_setDependent = theCvarValue;
 204         e.cvar_setDependent = string_null;
 205         e.cvar2_setDependent = string_null;
 206         e.cvar3_setDependent = string_null;
 207         e.func_setDependent = func_null;
 208         e.draw = setDependent_Draw;
 209         setDependent_Check(e);
 210 }
 211 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 212 {
 213         e.draw_setDependent = e.draw;
 214         e.cvar_setDependent = theCvarName;
 215         e.cvarMin_setDependent = theCvarMin;
 216         e.cvarMax_setDependent = theCvarMax;
 217         e.cvar2_setDependent = theCvar2Name;
 218         e.cvar2Min_setDependent = theCvar2Min;
 219         e.cvar2Max_setDependent = theCvar2Max;
 220         e.cvar3_setDependent = string_null;
 221         e.op_setDependent = 0;
 222         e.func_setDependent = func_null;
 223         e.draw = setDependent_Draw;
 224         setDependent_Check(e);
 225 }
 226 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 227 {
 228         e.draw_setDependent = e.draw;
 229         e.cvar_setDependent = theCvarName;
 230         e.cvarMin_setDependent = theCvarMin;
 231         e.cvarMax_setDependent = theCvarMax;
 232         e.cvar2_setDependent = theCvar2Name;
 233         e.cvar2Min_setDependent = theCvar2Min;
 234         e.cvar2Max_setDependent = theCvar2Max;
 235         e.cvar3_setDependent = string_null;
 236         e.op_setDependent = 1;
 237         e.func_setDependent = func_null;
 238         e.draw = setDependent_Draw;
 239         setDependent_Check(e);
 240 }
 241 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 242 {
 243         e.draw_setDependent = e.draw;
 244         e.cvar_setDependent = theCvarName;
 245         e.cvarMin_setDependent = theCvarMin;
 246         e.cvarMax_setDependent = theCvarMax;
 247         e.cvar2_setDependent = theCvar2Name;
 248         e.cvar2Min_setDependent = theCvar2Min;
 249         e.cvar2Max_setDependent = theCvar2Max;
 250         e.cvar3_setDependent = theCvar3Name;
 251         e.cvar3Min_setDependent = theCvar3Min;
 252         e.cvar3Max_setDependent = theCvar3Max;
 253         e.op_setDependent = 0;
 254         e.func_setDependent = func_null;
 255         e.draw = setDependent_Draw;
 256         setDependent_Check(e);
 257 }
 258 void setDependentWeird(entity e, float(entity) func)
 259 {
 260         e.draw_setDependent = e.draw;
 261         e.func_setDependent = func;
 262         e.draw = setDependent_Draw;
 263         setDependent_Check(e);
 264 }
 265
 266 // URI SYSTEM ////////////////////////////////////////////////////////
 267
 268 float _Nex_ExtResponseSystem_Queried;
 269 string _Nex_ExtResponseSystem_UpdateTo;
 270 string _Nex_ExtResponseSystem_UpdateToURL;
 271 string _Nex_ExtResponseSystem_Packs;
 272 float _Nex_ExtResponseSystem_PacksStep;
 273
 274 void URI_Get_Callback(float id, float status, string data)
 275 {
 276         if(url_URI_Get_Callback(id, status, data))
 277         {
 278                 // handled
 279         }
 280         else if (id == URI_GET_DISCARD)
 281         {
 282                 // discard
 283         }
 284         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 285         {
 286                 // sv_cmd curl
 287                 Curl_URI_Get_Callback(id, status, data);
 288         }
 289         else if (id == URI_GET_UPDATENOTIFICATION)
 290         {
 291                 UpdateNotification_URI_Get_Callback(id, status, data);
 292         }
 293         else
 294         {
 295                 printf("Received HTTP request data for an invalid id %d.\n", id);
 296         }
 297 }
 298
 299 void DisableServerBackwardsCompatibility()
 300 {
 301         cvar_set("gameversion_min", ftos(100 * floor(cvar("gameversion") / 100)));
 302 }
 303
 304 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 305 {
 306         float n;
 307
 308         if(_Nex_ExtResponseSystem_UpdateTo)
 309         {
 310                 dprint("error: UpdateNotification_URI_Get_Callback has been called before\n");
 311                 return;
 312         }
 313         if(status != 0)
 314         {
 315                 dprintf("error receiving update notification: status is %d\n", status);
 316                 return;
 317         }
 318         if(substring(data, 0, 1) == "<")
 319         {
 320                 dprint("error: received HTML instead of an update notification\n");
 321                 return;
 322         }
 323         if(strstrofs(data, "\r", 0) != -1)
 324         {
 325                 dprint("error: received carriage returns from update notification server\n");
 326                 return;
 327         }
 328
 329         if(data == "")
 330                 n = 0;
 331         else
 332                 n = tokenizebyseparator(data, "\n");
 333
 334         float i;
 335         string s;
 336
 337         string un_version = "";
 338         string un_download = "";
 339         string un_url = "";
 340         string un_bannedservers = "";
 341         string un_emergency_pk3s = "";
 342         string un_promoted = "";
 343         string un_recommended = "";
 344         string un_compatexpire = "";
 345
 346         for(i = 0; i < n; ++i)
 347         {
 348                 s = substring(argv(i), 2, -1);
 349                 if(s == "") { continue; } // ignore empty lines
 350
 351                 switch(substring(argv(i), 0, 1))
 352                 {
 353                         case "V":
 354                         {
 355                                 un_version = s;
 356                                 break;
 357                         }
 358                         case "C":
 359                         {
 360                                 un_compatexpire = s;
 361                                 break;
 362                         }
 363                         case "D":
 364                         {
 365                                 un_download = s;
 366                                 break;
 367                         }
 368                         case "U":
 369                         {
 370                                 un_url = s;
 371                                 break;
 372                         }
 373                         case "B":
 374                         {
 375                                 APPEND_TO_STRING(un_bannedservers, " ", s);
 376                                 break;
 377                         }
 378                         case "E":
 379                         {
 380                                 if(cvar("menu_updatecheck_getpacks"))
 381                                         APPEND_TO_STRING(un_emergency_pk3s, " ", s);
 382                                 break;
 383                         }
 384                         case "P":
 385                         {
 386                                 APPEND_TO_STRING(un_promoted, " ", s);
 387                                 break;
 388                         }
 389                         case "R":
 390                         {
 391                                 APPEND_TO_STRING(un_recommended, " ", s);
 392                                 break;
 393                         }
 394                 }
 395         }
 396
 397         if(un_version != "")
 398         {
 399                 if(vercmp(cvar_string("g_xonoticversion"), un_version) < 0)
 400                 {
 401                         // update needed
 402                         _Nex_ExtResponseSystem_UpdateTo = strzone(un_version);
 403                         if(un_download) { printf(_("Update can be downloaded at:\n%s\n"), un_download); }
 404                         if(un_url) { _Nex_ExtResponseSystem_UpdateToURL = strzone(un_url); }
 405                         DisableServerBackwardsCompatibility();
 406                 }
 407                 else if(cvar_string("g_xonoticversion") == un_version)
 408                 {
 409                         if(un_compatexpire != "")
 410                         {
 411                                 string curdate = strftime(false, "%Y%m%d%H%M%S");
 412                                 if (strcmp(curdate, un_compatexpire) >= 0)
 413                                         DisableServerBackwardsCompatibility();
 414                         }
 415                 }
 416         }
 417
 418         if(un_emergency_pk3s != "")
 419         {
 420                 _Nex_ExtResponseSystem_Packs = strzone(un_emergency_pk3s);
 421                 _Nex_ExtResponseSystem_PacksStep = 1;
 422         }
 423
 424         if(un_promoted != "")
 425         {
 426                 _Nex_ExtResponseSystem_PromotedServers = strzone(un_promoted);
 427                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 1;
 428         }
 429
 430         if(un_recommended != "")
 431         {
 432                 _Nex_ExtResponseSystem_RecommendedServers = strzone(un_recommended);
 433                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 434         }
 435 }
 436
 437 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 438
 439 void updateCheck()
 440 {
 441         if(cvar("menu_updatecheck"))
 442         {
 443                 if(!_Nex_ExtResponseSystem_Queried)
 444                 {
 445                         _Nex_ExtResponseSystem_Queried = 1;
 446                         float startcnt;
 447                         string uri;
 448
 449                         cvar_set("cl_startcount", ftos(startcnt = cvar("cl_startcount") + 1));
 450
 451                         // for privacy, munge the start count a little
 452                         startcnt = floor((floor(startcnt / 10) + random()) * 10);
 453                         uri = sprintf("http://update.xonotic.org/checkupdate.txt?version=%s&cnt=%d", uri_escape(cvar_string("g_xonoticversion")), startcnt);
 454                         uri_get(uri, URI_GET_UPDATENOTIFICATION);
 455                 }
 456         }
 457
 458         if(_Nex_ExtResponseSystem_PacksStep > 0)
 459         {
 460                 float n, i;
 461                 float allgood;
 462                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 463                 allgood = true;
 464                 for(i = 0; i+1 < n; i += 2)
 465                 {
 466                         if(fexists(argv(i+1)))
 467                                 continue;
 468                         allgood = false;
 469                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 470                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 471                 }
 472                 if(allgood)
 473                 {
 474                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 475                         {
 476                                 if(!Menu_Active)
 477                                         cvar_set("_menu_initialized", "0");
 478                                         // HACK: cause m_hide call on next start
 479                                 localcmd("\nmenu_restart\n");
 480                         }
 481                         _Nex_ExtResponseSystem_PacksStep = 0;
 482                 }
 483                 else
 484                         _Nex_ExtResponseSystem_PacksStep = 2;
 485         }
 486
 487 }
 488
 489 float preMenuInit()
 490 {
 491         vector sz;
 492         vector boxA, boxB;
 493
 494         updateCheck();
 495
 496         MapInfo_Cache_Create();
 497         MapInfo_Enumerate();
 498         if(!MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 499         {
 500                 draw_reset_cropped();
 501
 502                 sz = eX * 0.025 + eY * 0.025 * (draw_scale.x / draw_scale.y);
 503                 draw_CenterText('0.5 0.5 0' - 1.25 * sz.y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 504
 505                 boxA = '0.05 0.5 0' + 0.25 * sz.y * eY;
 506                 boxB = '0.95 0.5 0' + 1.25 * sz.y * eY;
 507                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 508
 509                 boxA += sz * 0.1;
 510                 boxB -= sz * 0.1;
 511                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 512
 513                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 514                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 515
 516                 return false;
 517         }
 518         return true;
 519 }
 520
 521 string campaign_name_previous;
 522 float campaign_won_previous;
 523 #ifdef WATERMARK
 524 string autocvar_menu_watermark = WATERMARK;
 525 #else
 526 string autocvar_menu_watermark = "";
 527 #endif
 528 void postMenuDraw()
 529 {
 530         if(autocvar_menu_watermark != "")
 531         {
 532                 draw_CenterText('0.5 0.1 0', sprintf(_("^1%s TEST BUILD"), autocvar_menu_watermark), globalToBoxSize('32 32 0', draw_scale), '1 1 1', 0.05, 1);
 533         }
 534 }
 535 void preMenuDraw()
 536 {
 537         vector fs, sz = '0 0 0', line, mid;
 538
 539         updateCheck();
 540
 541         if(_Nex_ExtResponseSystem_UpdateTo != "")
 542         {
 543                 // TODO rather turn this into a dialog
 544                 fs = ((1/draw_scale.x) * eX + (1/draw_scale.y) * eY) * 12;
 545                 line = eY * fs.y;
 546                 string l1, l2;
 547                 l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 548                 l2 = "http://www.xonotic.org/";
 549                 if(_Nex_ExtResponseSystem_UpdateToURL)
 550                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 551
 552                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 553                                 draw_TextWidth(l1, 0, fs),
 554                                 draw_TextWidth(l2, 0, fs)
 555                         );
 556                 sz_y = 3 * fs.y;
 557
 558                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 559                 mid = eX * (0.5 + 0.5 * (1 - sz.x) * cos(time * 0.071))
 560                     + eY * (0.5 + 0.5 * (1 - sz.y) * sin(time * 0.071));
 561
 562                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 563                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 564                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 565         }
 566         if (!campaign_name_previous)
 567                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 568         if(campaign_name == campaign_name_previous)
 569         {
 570                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 571                 {
 572                         if(!campaign_won_previous)
 573                         {
 574                                 m_display();
 575                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 576                         }
 577                         campaign_won_previous = 1;
 578                 }
 579                 else
 580                         campaign_won_previous = 0;
 581         }
 582         else
 583         {
 584                 strunzone(campaign_name_previous);
 585                 campaign_name_previous = strzone(campaign_name);
 586                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 587         }
 588 }
 589
 590 string resolvemod(string m)
 591 {
 592         if(m == "=")
 593                 return getcurrentmod();
 594         else
 595                 return m;
 596 }
 597
 598 float updateCompression()
 599 {
 600         float have_dds, have_jpg, have_tga;
 601         float can_dds;
 602         have_dds = (fexists("dds/particles/particlefont.dds"));
 603         have_jpg = (fexists("particles/particlefont.jpg"));
 604         have_tga = (fexists("particles/particlefont.tga"));
 605         can_dds = GL_Have_TextureCompression();
 606         if(have_dds && (have_jpg || have_tga))
 607         {
 608                 // both? Let's only use good quality precompressed files
 609                 // but ONLY if we actually support it!
 610                 if(can_dds)
 611                 {
 612                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 613                         cvar_set("gl_texturecompression", "0");
 614                         return 1;
 615
 616                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 617                         //return 2;
 618                 }
 619                 else
 620                 {
 621                         cvar_set("gl_texturecompression", "0");
 622                         cvar_set("r_texture_dds_load", "0");
 623                         return 0;
 624                 }
 625         }
 626         else if(have_dds)
 627         {
 628                 // DDS only? We probably always want texture compression
 629                 cvar_set("gl_texturecompression", "1");
 630                 cvar_set("r_texture_dds_load", "1");
 631                 if(!can_dds)
 632                         print(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems.\n"));
 633                 return 0;
 634         }
 635         else
 636         {
 637                 // TGA only? Allow runtime compression
 638                 if(can_dds)
 639                 {
 640                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 641                         return 2;
 642                 }
 643                 else
 644                 {
 645                         cvar_set("gl_texturecompression", "0");
 646                         cvar_set("r_texture_dds_load", "0");
 647                         return 0;
 648                 }
 649         }
 650 }
 651
 652 // note: include only those that should be in the menu!
 653 #define GAMETYPES \
 654         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 655         GAMETYPE(MAPINFO_TYPE_CTF) \
 656         GAMETYPE(MAPINFO_TYPE_CA) \
 657         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 658         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 659         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 660         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 661         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 662         GAMETYPE(MAPINFO_TYPE_LMS) \
 663         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 664         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 665         if (cvar("developer")) GAMETYPE(MAPINFO_TYPE_RACE) \
 666         GAMETYPE(MAPINFO_TYPE_CTS) \
 667         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 668         //GAMETYPE(MAPINFO_TYPE_INVASION) \
 669         /* nothing */
 670
 671 float GameType_GetID(float cnt)
 672 {
 673         float i;
 674         i = 0;
 675
 676         #define GAMETYPE(id) { if(i++ == cnt) return id; }
 677         GAMETYPES
 678         #undef GAMETYPE
 679
 680         unused_float = i;
 681
 682         return 0;
 683 }
 684
 685 float GameType_GetCount()
 686 {
 687         float i;
 688         i = 0;
 689
 690         #define GAMETYPE(id) ++i;
 691         GAMETYPES
 692         #undef GAMETYPE
 693
 694         return i;
 695 }
 696
 697 string GameType_GetName(float cnt)
 698 {
 699         float i = GameType_GetID(cnt);
 700
 701         if(i)
 702                 return MapInfo_Type_ToText(i);
 703
 704         return "";
 705 }
 706
 707 string GameType_GetIcon(float cnt)
 708 {
 709         float i = GameType_GetID(cnt);
 710
 711         if(i)
 712                 return strcat("gametype_", MapInfo_Type_ToString(i));
 713
 714         return "";
 715 }
 716
 717 void dialog_hudpanel_common_notoggle(entity me, string panelname)
 718 {
 719         float i;
 720         entity e;
 721
 722         me.TR(me);
 723                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 724                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 725                                 e.addValue(e, _("Default"), "");
 726                                 e.addValue(e, _("Disable"), "0");
 727                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 728                                 e.configureXonoticTextSliderValues(e);
 729         me.TR(me);
 730                 me.TDempty(me, 0.2);
 731                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 732                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 733                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 734         me.TR(me);
 735                 me.TDempty(me, 0.2);
 736                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 737         me.TR(me);
 738                 me.TDempty(me, 0.2);
 739                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 740                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 741                                 e.addValue(e, _("Default"), "");
 742                                 e.addValue(e, _("Disable"), "0");
 743                                 for(i = 1; i <= 10; ++i)
 744                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 745                                 e.configureXonoticTextSliderValues(e);
 746         me.TR(me);
 747                 me.TDempty(me, 0.2);
 748                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 749                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 750                                 e.addValue(e, _("Default"), "");
 751                                 for(i = 1; i <= 10; ++i)
 752                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 753                                 e.configureXonoticTextSliderValues(e);
 754         me.TR(me);
 755                 me.TDempty(me, 0.2);
 756                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 757                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 758                                 e.addValue(e, _("Default"), "");
 759                                 e.addValue(e, _("Disable"), "0");
 760                                 for(i = 1; i <= 10; ++i)
 761                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 762                                 e.configureXonoticTextSliderValues(e);
 763         me.TR(me);
 764                 me.TDempty(me, 0.4);
 765                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 766         me.TR(me);
 767                 me.TDempty(me, 0.2);
 768                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 769                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 770                                 e.addValue(e, _("Default"), "");
 771                                 for(i = 0; i <= 10; ++i)
 772                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 773                                 e.configureXonoticTextSliderValues(e);
 774 }
 775
 776 void CheckSendCvars(entity me, string cvarnamestring)
 777 {
 778         if(me.sendCvars)
 779         {
 780                 printf("Sending cvar: %s -> %s\n", cvarnamestring, cvar_string(cvarnamestring));
 781                 if(gamestatus & (GAME_CONNECTED | GAME_ISSERVER))
 782                 {
 783                         cmd(sprintf("\nsendcvar %s\n", cvarnamestring));
 784                 }
 785         }
 786 }