qcsrc/menu/xonotic/util.qc

   1 #include "util.qh"
   2 #include "dialog.qh"
   3
   4 #include "../item.qh"
   5
   6 #include "../menu.qh"
   7 #include <common/campaign_common.qh>
   8 #include <common/constants.qh>
   9 #include <common/gamemodes/_mod.qh>
  10 #include <common/util.qh>
  11 #include <common/command/_mod.qh>
  12
  13 float GL_CheckExtension(string ext)
  14 {
  15         return strhasword(cvar_string("gl_info_extensions"), ext);
  16 }
  17
  18 float GL_Have_TextureCompression()
  19 {
  20         return GL_CheckExtension("GL_EXT_texture_compression_s3tc");
  21 }
  22
  23 .entity parent, firstChild, nextSibling;
  24 void forAllDescendants(entity root, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
  25 {
  26         depthfirst(root, parent, firstChild, nextSibling, funcPre, funcPost, pass);
  27 }
  28
  29 .string controlledCvar;
  30 void SUB_Null_ee(entity e1, entity e2)
  31 {
  32 }
  33
  34 .void(entity) saveCvars;
  35 void saveCvarsOf(entity ignore, entity e)
  36 {
  37         if(e.saveCvars)
  38                 e.saveCvars(e);
  39 }
  40
  41 .void(entity) loadCvars;
  42 void loadCvarsOf(entity ignore, entity e)
  43 {
  44         if(e.loadCvars)
  45                 e.loadCvars(e);
  46 }
  47 void saveAllCvars(entity root)
  48 {
  49         forAllDescendants(root, saveCvarsOf, SUB_Null_ee, NULL);
  50 }
  51 void loadAllCvars(entity root)
  52 {
  53         forAllDescendants(root, loadCvarsOf, SUB_Null_ee, NULL);
  54 }
  55
  56 .string controlledCvars_Multi;
  57 .void(entity me) saveCvars_Multi;
  58 string getCvarsMulti(entity me)
  59 {
  60         if (me.controlledCvars_Multi)
  61                 return me.controlledCvars_Multi;
  62         return string_null;
  63 }
  64 void saveCvarsMulti(entity me)
  65 {
  66         float n, i;
  67         string s, cvarname;
  68
  69         me.saveCvars_Multi(me);
  70         s = cvar_string(me.controlledCvar);
  71
  72         n = tokenize_console(me.controlledCvars_Multi);
  73         for(i = 0; i < n; ++i)
  74         {
  75                 // cvars prefixed with ! get saved with the inverted value
  76                 if(substring(argv(i), 0, 1) == "!")
  77                 {
  78                         cvarname = substring(argv(i), 1, strlen(argv(i)));
  79                         cvar_set(cvarname, ((s == "0") ? "1" : "0"));
  80                 }
  81                 else
  82                 {
  83                         cvarname = argv(i);
  84                         cvar_set(cvarname, s);
  85                 }
  86
  87                 CheckSendCvars(me, cvarname);
  88         }
  89 }
  90 void makeMulti(entity e, string otherCvars)
  91 {
  92         e.controlledCvars_Multi = otherCvars;
  93         e.saveCvars_Multi = e.saveCvars;
  94         e.saveCvars = saveCvarsMulti;
  95 }
  96
  97 .void(entity me) saveCvars_Callback;
  98 .entity saveCvars_Callback_ent;
  99 .void(entity me, entity cb) saveCvars_Callback_func;
 100 void saveCvarsCallback(entity me)
 101 {
 102         me.saveCvars_Callback(me);
 103         me.saveCvars_Callback_func(me.saveCvars_Callback_ent, me);
 104 }
 105 void makeCallback(entity e, entity cbent, void(entity, entity) cbfunc)
 106 {
 107         e.saveCvars_Callback = e.saveCvars;
 108         e.saveCvars = saveCvarsCallback;
 109         e.saveCvars_Callback_ent = cbent;
 110         e.saveCvars_Callback_func = cbfunc;
 111 }
 112
 113 .void(entity) draw_setDependent;
 114 .string cvar_setDependent;
 115 .float cvarMin_setDependent;
 116 .float cvarMax_setDependent;
 117 .string cvar2_setDependent;
 118 .float cvar2Min_setDependent;
 119 .float cvar2Max_setDependent;
 120 .string cvar3_setDependent;
 121 .float cvar3Min_setDependent;
 122 .float cvar3Max_setDependent;
 123 .float op_setDependent;
 124 .string cvarString_setDependent;
 125 .string cvarValue_setDependent;
 126 .float(entity) func_setDependent;
 127 .bool disabled;
 128 void setDependent_Check(entity e)
 129 {
 130         bool disabled_prev = e.disabled;
 131         float f;
 132         string s;
 133         if(e.func_setDependent)
 134         {
 135                 e.disabled = !(e.func_setDependent(e));
 136         }
 137         else if(e.cvarString_setDependent)
 138         {
 139                 s = cvar_string(e.cvarString_setDependent);
 140                 e.disabled = (cvar_string(e.cvarString_setDependent) == e.cvarValue_setDependent);
 141         }
 142         else
 143         {
 144                 if(e.cvar_setDependent)
 145                 {
 146                         f = cvar(e.cvar_setDependent);
 147                         if(e.cvarMin_setDependent <= e.cvarMax_setDependent)
 148                                 e.disabled = ((f < e.cvarMin_setDependent) || (f > e.cvarMax_setDependent));
 149                         else
 150                                 e.disabled = ((f >= e.cvarMax_setDependent) && (f <= e.cvarMin_setDependent));
 151                 }
 152                 if(e.cvar2_setDependent)
 153                 {
 154                         f = cvar(e.cvar2_setDependent);
 155                         if(e.cvar2Min_setDependent <= e.cvar2Max_setDependent)
 156                                 e.disabled = (e.disabled + ((f < e.cvar2Min_setDependent) || (f > e.cvar2Max_setDependent)) > e.op_setDependent);
 157                         else
 158                                 e.disabled = (e.disabled + ((f >= e.cvar2Max_setDependent) && (f <= e.cvar2Min_setDependent)) > e.op_setDependent);
 159                 }
 160                 if(e.cvar3_setDependent)
 161                 {
 162                         f = cvar(e.cvar3_setDependent);
 163                         if(e.cvar3Min_setDependent <= e.cvar3Max_setDependent)
 164                                 e.disabled = (e.disabled + ((f < e.cvar3Min_setDependent) || (f > e.cvar3Max_setDependent)) > e.op_setDependent);
 165                         else
 166                                 e.disabled = (e.disabled + ((f >= e.cvar3Max_setDependent) && (f <= e.cvar3Min_setDependent)) > e.op_setDependent);
 167                 }
 168         }
 169         if (disabled_prev != e.disabled && e.loadCvars)
 170                 e.loadCvars(e);
 171 }
 172 void setDependent_Draw(entity e)
 173 {
 174         setDependent_Check(e);
 175         e.draw_setDependent(e);
 176 }
 177 .void(entity) draw;
 178 void setDependent(entity e, string theCvarName, float theCvarMin, float theCvarMax)
 179 {
 180         e.draw_setDependent = e.draw;
 181         e.cvar_setDependent = theCvarName;
 182         e.cvarMin_setDependent = theCvarMin;
 183         e.cvarMax_setDependent = theCvarMax;
 184         e.cvar2_setDependent = string_null;
 185         e.cvar3_setDependent = string_null;
 186         e.func_setDependent = func_null;
 187         e.draw = setDependent_Draw;
 188         setDependent_Check(e);
 189 }
 190 void setDependentStringNotEqual(entity e, string theCvarName, string theCvarValue)
 191 {
 192         e.draw_setDependent = e.draw;
 193         e.cvarString_setDependent = theCvarName;
 194         e.cvarValue_setDependent = theCvarValue;
 195         e.cvar_setDependent = string_null;
 196         e.cvar2_setDependent = string_null;
 197         e.cvar3_setDependent = string_null;
 198         e.func_setDependent = func_null;
 199         e.draw = setDependent_Draw;
 200         setDependent_Check(e);
 201 }
 202 void setDependentAND(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 203 {
 204         e.draw_setDependent = e.draw;
 205         e.cvar_setDependent = theCvarName;
 206         e.cvarMin_setDependent = theCvarMin;
 207         e.cvarMax_setDependent = theCvarMax;
 208         e.cvar2_setDependent = theCvar2Name;
 209         e.cvar2Min_setDependent = theCvar2Min;
 210         e.cvar2Max_setDependent = theCvar2Max;
 211         e.cvar3_setDependent = string_null;
 212         e.op_setDependent = 0;
 213         e.func_setDependent = func_null;
 214         e.draw = setDependent_Draw;
 215         setDependent_Check(e);
 216 }
 217 void setDependentOR(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max)
 218 {
 219         e.draw_setDependent = e.draw;
 220         e.cvar_setDependent = theCvarName;
 221         e.cvarMin_setDependent = theCvarMin;
 222         e.cvarMax_setDependent = theCvarMax;
 223         e.cvar2_setDependent = theCvar2Name;
 224         e.cvar2Min_setDependent = theCvar2Min;
 225         e.cvar2Max_setDependent = theCvar2Max;
 226         e.cvar3_setDependent = string_null;
 227         e.op_setDependent = 1;
 228         e.func_setDependent = func_null;
 229         e.draw = setDependent_Draw;
 230         setDependent_Check(e);
 231 }
 232 void setDependentAND3(entity e, string theCvarName, float theCvarMin, float theCvarMax, string theCvar2Name, float theCvar2Min, float theCvar2Max, string theCvar3Name, float theCvar3Min, float theCvar3Max)
 233 {
 234         e.draw_setDependent = e.draw;
 235         e.cvar_setDependent = theCvarName;
 236         e.cvarMin_setDependent = theCvarMin;
 237         e.cvarMax_setDependent = theCvarMax;
 238         e.cvar2_setDependent = theCvar2Name;
 239         e.cvar2Min_setDependent = theCvar2Min;
 240         e.cvar2Max_setDependent = theCvar2Max;
 241         e.cvar3_setDependent = theCvar3Name;
 242         e.cvar3Min_setDependent = theCvar3Min;
 243         e.cvar3Max_setDependent = theCvar3Max;
 244         e.op_setDependent = 0;
 245         e.func_setDependent = func_null;
 246         e.draw = setDependent_Draw;
 247         setDependent_Check(e);
 248 }
 249 void setDependentWeird(entity e, float(entity) func)
 250 {
 251         e.draw_setDependent = e.draw;
 252         e.func_setDependent = func;
 253         e.draw = setDependent_Draw;
 254         setDependent_Check(e);
 255 }
 256
 257 void setZonedTooltip(entity e, string theTooltip, string theCvar)
 258 {
 259         if(theTooltip == "") // no tooltip, use cvar description then
 260         {
 261                 if(theCvar != "" && prvm_language == "en")
 262                 {
 263                         string t = cvar_description(theCvar);
 264                         if(t != "" && t != "custom cvar")
 265                                 theTooltip = t;
 266                 }
 267         }
 268         else if(theTooltip == "-") // no cvar description as tooltip
 269         {
 270                 theTooltip = string_null;
 271         }
 272
 273         strfree(e.tooltip);
 274         e.tooltip = (theTooltip != "") ? strzone(theTooltip) : string_null;
 275 }
 276
 277 void clearTooltip(entity e)
 278 {
 279         setZonedTooltip(e, string_null, string_null);
 280 }
 281
 282 // URI SYSTEM ////////////////////////////////////////////////////////
 283
 284 float _Nex_ExtResponseSystem_Queried;
 285 string _Nex_ExtResponseSystem_UpdateTo;
 286 string _Nex_ExtResponseSystem_UpdateToURL;
 287 string _Nex_ExtResponseSystem_Packs;
 288 float _Nex_ExtResponseSystem_PacksStep;
 289
 290 /** engine callback */
 291 void URI_Get_Callback(float id, float status, string data)
 292 {
 293         if(url_URI_Get_Callback(id, status, data))
 294         {
 295                 // handled
 296         }
 297         else if (id == URI_GET_DISCARD)
 298         {
 299                 // discard
 300         }
 301         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
 302         {
 303                 // sv_cmd curl
 304                 Curl_URI_Get_Callback(id, status, data);
 305         }
 306         else if (id == URI_GET_UPDATENOTIFICATION)
 307         {
 308                 UpdateNotification_URI_Get_Callback(id, status, data);
 309         }
 310         else
 311         {
 312                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
 313         }
 314 }
 315
 316 void UpdateNotification_URI_Get_Callback(float id, float status, string data)
 317 {
 318         float n;
 319
 320         if(_Nex_ExtResponseSystem_UpdateTo)
 321         {
 322                 LOG_TRACE("error: UpdateNotification_URI_Get_Callback has been called before");
 323                 return;
 324         }
 325         if(status != 0)
 326         {
 327                 LOG_TRACEF("error receiving update notification: status is %d", status);
 328                 return;
 329         }
 330         if(substring(data, 0, 1) == "<")
 331         {
 332                 LOG_TRACE("error: received HTML instead of an update notification");
 333                 return;
 334         }
 335         if(strstrofs(data, "\r", 0) != -1)
 336         {
 337                 LOG_TRACE("error: received carriage returns from update notification server");
 338                 return;
 339         }
 340
 341         if(data == "")
 342                 n = 0;
 343         else
 344                 n = tokenizebyseparator(data, "\n");
 345
 346         float i;
 347         string s;
 348
 349         string un_version = "";
 350         string un_tosversion = "";
 351         string un_download = "";
 352         string un_url = "";
 353         string un_bannedservers = "";
 354         string un_emergency_pk3s = "";
 355         string un_promoted = "";
 356         string un_recommended = "";
 357         string un_compatexpire = "";
 358
 359         for(i = 0; i < n; ++i)
 360         {
 361                 s = substring(argv(i), 2, -1);
 362                 if(s == "") { continue; } // ignore empty lines
 363
 364                 switch(substring(argv(i), 0, 1))
 365                 {
 366                         case "V":
 367                         {
 368                                 un_version = s;
 369                                 break;
 370                         }
 371                         case "T":
 372                         {
 373                                 un_tosversion = s;
 374                                 break;
 375                         }
 376                         case "C":
 377                         {
 378                                 un_compatexpire = s;
 379                                 break;
 380                         }
 381                         case "D":
 382                         {
 383                                 un_download = s;
 384                                 break;
 385                         }
 386                         case "U":
 387                         {
 388                                 un_url = s;
 389                                 break;
 390                         }
 391                         case "B":
 392                         {
 393                                 APPEND_TO_STRING(un_bannedservers, " ", s);
 394                                 break;
 395                         }
 396                         case "E":
 397                         {
 398                                 if(cvar("menu_updatecheck_getpacks"))
 399                                         APPEND_TO_STRING(un_emergency_pk3s, " ", s);
 400                                 break;
 401                         }
 402                         case "P":
 403                         {
 404                                 APPEND_TO_STRING(un_promoted, " ", s);
 405                                 break;
 406                         }
 407                         case "R":
 408                         {
 409                                 APPEND_TO_STRING(un_recommended, " ", s);
 410                                 break;
 411                         }
 412                 }
 413         }
 414
 415         if(un_version != "" && vercmp(cvar_string("g_xonoticversion"), un_version) < 0)
 416         {
 417                 // update needed
 418                 _Nex_ExtResponseSystem_UpdateTo = strzone(un_version);
 419                 if(un_download) { LOG_INFO(_("Update can be downloaded at:"), "\n", un_download); }
 420                 if(un_url) { _Nex_ExtResponseSystem_UpdateToURL = strzone(un_url); }
 421         }
 422
 423         if(un_tosversion != "")
 424         {
 425                 _Nex_ExtResponseSystem_NewToS = stof(un_tosversion);
 426         }
 427
 428         if(un_bannedservers != "")
 429         {
 430                 _Nex_ExtResponseSystem_BannedServers = strzone(un_bannedservers);
 431                 _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 1;
 432         }
 433
 434         if(un_emergency_pk3s != "")
 435         {
 436                 _Nex_ExtResponseSystem_Packs = strzone(un_emergency_pk3s);
 437                 _Nex_ExtResponseSystem_PacksStep = 1;
 438         }
 439
 440         if(un_promoted != "")
 441         {
 442                 _Nex_ExtResponseSystem_PromotedServers = strzone(un_promoted);
 443                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 1;
 444         }
 445
 446         if(un_recommended != "")
 447         {
 448                 _Nex_ExtResponseSystem_RecommendedServers = strzone(un_recommended);
 449                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 1;
 450         }
 451 }
 452
 453 // END OF URI SYSTEM ////////////////////////////////////////////////////////
 454
 455 void updateCheck()
 456 {
 457         if(!_Nex_ExtResponseSystem_Queried)
 458         {
 459                 _Nex_ExtResponseSystem_Queried = 1;
 460                 cvar_set("cl_startcount", ftos(cvar("cl_startcount") + 1));
 461                 uri_get("https://update.xonotic.org/checkupdate.txt", URI_GET_UPDATENOTIFICATION);
 462         }
 463
 464         if(_Nex_ExtResponseSystem_PacksStep > 0)
 465         {
 466                 float n, i;
 467                 float allgood;
 468                 n = tokenize_console(_Nex_ExtResponseSystem_Packs);
 469                 allgood = true;
 470                 for(i = 0; i+1 < n; i += 2)
 471                 {
 472                         if(fexists(argv(i+1)))
 473                                 continue;
 474                         allgood = false;
 475                         if(_Nex_ExtResponseSystem_PacksStep == 1) // first run
 476                                 localcmd("\ncurl --pak \"", argv(i), "\"\n");
 477                 }
 478                 if(allgood)
 479                 {
 480                         if(_Nex_ExtResponseSystem_PacksStep == 2)
 481                         {
 482                                 if(!Menu_Active)
 483                                         cvar_set("_menu_initialized", "0");
 484                                         // HACK: cause m_hide call on next start
 485                                 localcmd("\nmenu_restart\n");
 486                         }
 487                         _Nex_ExtResponseSystem_PacksStep = 0;
 488                 }
 489                 else
 490                         _Nex_ExtResponseSystem_PacksStep = 2;
 491         }
 492
 493 }
 494
 495 bool show_propermenu = false;
 496
 497 float preMenuInit()
 498 {
 499         vector sz;
 500         vector boxA, boxB;
 501
 502         if(random() < 0.1)
 503                 show_propermenu = true;
 504
 505         updateCheck();
 506
 507         MapInfo_Cache_Create();
 508         MapInfo_Enumerate();
 509         if(!_MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 510         {
 511                 draw_reset_cropped();
 512
 513                 sz = eX * 0.025 + eY * 0.025 * (draw_scale.x / draw_scale.y);
 514                 draw_CenterText('0.5 0.5 0' - 1.25 * sz.y * eY, _("Autogenerating mapinfo for newly added maps..."), sz, '1 1 1', 1, 0);
 515
 516                 boxA = '0.05 0.5 0' + 0.25 * sz.y * eY;
 517                 boxB = '0.95 0.5 0' + 1.25 * sz.y * eY;
 518                 draw_Fill(boxA, boxB - boxA, '1 1 1', 1);
 519
 520                 boxA += sz * 0.1;
 521                 boxB -= sz * 0.1;
 522                 draw_Fill(boxA, boxB - boxA, '0.1 0.1 0.1', 1);
 523
 524                 boxB_x = boxA_x * (1 - MapInfo_progress) + boxB_x * MapInfo_progress;
 525                 draw_Fill(boxA, boxB - boxA, '0 0 1', 1);
 526
 527                 return false;
 528         }
 529         return true;
 530 }
 531
 532 string campaign_name_previous;
 533 float campaign_won_previous;
 534 void postMenuDraw() {}
 535 void DialogOpenButton_Click_withCoords(entity button, entity tab, vector theOrigin, vector theSize);
 536 .entity winnerDialog;
 537 void preMenuDraw()
 538 {
 539         vector fs, sz = '0 0 0', line, mid;
 540
 541         updateCheck();
 542
 543         if(_Nex_ExtResponseSystem_UpdateTo != "" && !(gamestatus & (GAME_CONNECTED | GAME_ISSERVER)))
 544         {
 545                 // TODO rather turn this into a dialog
 546                 fs = ((1/draw_scale.x) * eX + (1/draw_scale.y) * eY) * 12;
 547                 line = eY * fs.y;
 548                 string l1, l2;
 549                 if(show_propermenu)
 550                         l1 = sprintf("Jeff pay 4 new weapons for %s", _Nex_ExtResponseSystem_UpdateTo);
 551                 else
 552                         l1 = sprintf(_("Update to %s now!"), _Nex_ExtResponseSystem_UpdateTo);
 553                 l2 = "http://www.xonotic.org/";
 554                 if(_Nex_ExtResponseSystem_UpdateToURL)
 555                         l2 = _Nex_ExtResponseSystem_UpdateToURL;
 556
 557                 sz_x = draw_TextWidth("    ", 0, fs) + max(
 558                                 draw_TextWidth(l1, 0, fs),
 559                                 draw_TextWidth(l2, 0, fs)
 560                         );
 561                 sz_y = 3 * fs.y;
 562
 563                 draw_alpha = bound(0, sin(time * 0.112 - 0.3) * 10, 1);
 564                 mid = eX * (0.5 + 0.5 * (1 - sz.x) * cos(time * 0.071))
 565                     + eY * (0.5 + 0.5 * (1 - sz.y) * sin(time * 0.071));
 566
 567                 draw_Fill(mid - 0.5 * sz, sz, '1 1 0', 1);
 568                 draw_CenterText(mid - 1 * line, l1, fs, '1 0 0', 1, 0);
 569                 draw_CenterText(mid - 0 * line, l2, fs, '0 0 1', 1, 0);
 570         }
 571
 572         if (!campaign_name_previous)
 573                 campaign_name_previous = strzone(strcat(campaign_name, "x")); // force unequal
 574         if(campaign_name == campaign_name_previous)
 575         {
 576                 if(cvar(strcat("g_campaign", campaign_name, "_won")))
 577                 {
 578                         if(!campaign_won_previous)
 579                         {
 580                                 m_display();
 581                                 DialogOpenButton_Click_withCoords(NULL, main.winnerDialog, '0 0 0', eX * conwidth + eY * conheight);
 582                         }
 583                         campaign_won_previous = 1;
 584                 }
 585                 else
 586                         campaign_won_previous = 0;
 587         }
 588         else
 589         {
 590                 strcpy(campaign_name_previous, campaign_name);
 591                 campaign_won_previous = cvar(strcat("g_campaign", campaign_name, "_won"));
 592         }
 593 }
 594
 595 string resolvemod(string m)
 596 {
 597         if(m == "=")
 598                 return getcurrentmod();
 599         else
 600                 return m;
 601 }
 602
 603 float updateCompression()
 604 {
 605         float have_dds, have_jpg, have_tga;
 606         float can_dds;
 607         have_dds = (fexists("dds/particles/particlefont.dds"));
 608         have_jpg = (fexists("particles/particlefont.jpg"));
 609         have_tga = (fexists("particles/particlefont.tga"));
 610         can_dds = GL_Have_TextureCompression();
 611         if(have_dds && (have_jpg || have_tga))
 612         {
 613                 // both? Let's only use good quality precompressed files
 614                 // but ONLY if we actually support it!
 615                 if(can_dds)
 616                 {
 617                         // these builds are meant to have GOOD quality, so let's not compress non-skinframes
 618                         cvar_set("gl_texturecompression", "0");
 619                         return 1;
 620
 621                         //cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 622                         //return 2;
 623                 }
 624                 else
 625                 {
 626                         cvar_set("gl_texturecompression", "0");
 627                         cvar_set("r_texture_dds_load", "0");
 628                         return 0;
 629                 }
 630         }
 631         else if(have_dds)
 632         {
 633                 // DDS only? We probably always want texture compression
 634                 cvar_set("gl_texturecompression", "1");
 635                 cvar_set("r_texture_dds_load", "1");
 636                 if(!can_dds)
 637                         LOG_INFO(_("^1ERROR: Texture compression is required but not supported.\n^1Expect visual problems."));
 638                 return 0;
 639         }
 640         else
 641         {
 642                 // TGA only? Allow runtime compression
 643                 if(can_dds)
 644                 {
 645                         cvar_set("gl_texturecompression", cvar_string("r_texture_dds_load"));
 646                         return 2;
 647                 }
 648                 else
 649                 {
 650                         cvar_set("gl_texturecompression", "0");
 651                         cvar_set("r_texture_dds_load", "0");
 652                         return 0;
 653                 }
 654         }
 655 }
 656
 657 // note: include only those that should be in the menu!
 658 #define GAMETYPES \
 659         GAMETYPE(MAPINFO_TYPE_DEATHMATCH) \
 660         GAMETYPE(MAPINFO_TYPE_TEAM_DEATHMATCH) \
 661         GAMETYPE(MAPINFO_TYPE_CTF) \
 662         GAMETYPE(MAPINFO_TYPE_CA) \
 663         GAMETYPE(MAPINFO_TYPE_FREEZETAG) \
 664         GAMETYPE(MAPINFO_TYPE_KEEPAWAY) \
 665         GAMETYPE(MAPINFO_TYPE_KEYHUNT) \
 666         GAMETYPE(MAPINFO_TYPE_LMS) \
 667         GAMETYPE(MAPINFO_TYPE_DOMINATION) \
 668         GAMETYPE(MAPINFO_TYPE_NEXBALL) \
 669         GAMETYPE(MAPINFO_TYPE_ONSLAUGHT) \
 670         GAMETYPE(MAPINFO_TYPE_ASSAULT) \
 671         /* GAMETYPE(MAPINFO_TYPE_DUEL) */ \
 672         /**/
 673
 674 // hidden gametypes come last so indexing always works correctly
 675 #define HIDDEN_GAMETYPES \
 676         GAMETYPE(MAPINFO_TYPE_RACE) \
 677         GAMETYPE(MAPINFO_TYPE_CTS) \
 678         GAMETYPE(MAPINFO_TYPE_INVASION) \
 679         /**/
 680
 681 Gametype GameType_GetID(int cnt)
 682 {
 683         int i = 0;
 684         #define GAMETYPE(it) { if (i++ == cnt) return it; }
 685         GAMETYPES
 686         HIDDEN_GAMETYPES
 687         #undef GAMETYPE
 688         return NULL;
 689 }
 690
 691 int GameType_GetCount()
 692 {
 693         int i = 0;
 694         int dev = cvar("developer");
 695         #define GAMETYPE(id) ++i;
 696         GAMETYPES
 697         #undef GAMETYPE
 698         #define GAMETYPE(it) { if (dev > 0) ++i; }
 699         HIDDEN_GAMETYPES
 700         #undef GAMETYPE
 701         return i;
 702 }
 703
 704 int GameType_GetTotalCount()
 705 {
 706         int i = 0;
 707         #define GAMETYPE(id) ++i;
 708         GAMETYPES
 709         HIDDEN_GAMETYPES
 710         #undef GAMETYPE
 711         return i;
 712 }
 713
 714 string GameType_GetName(int cnt)
 715 {
 716         Gametype i = GameType_GetID(cnt);
 717         return i ? MapInfo_Type_ToText(i) : "";
 718 }
 719
 720 string GameType_GetIcon(int cnt)
 721 {
 722         Gametype i = GameType_GetID(cnt);
 723         return i ? strcat("gametype_", MapInfo_Type_ToString(i)) : "";
 724 }
 725
 726 .void(entity) TR;
 727 .void(entity, float, float, entity) TD;
 728 .void(entity, float) TDempty;
 729 .void(entity, float, float) gotoRC;
 730 entity makeXonoticTextLabel(float theAlign, string theText);
 731 entity makeXonoticTextSlider(string);
 732 .void(entity, string, string) addValue;
 733 .void(entity) configureXonoticTextSliderValues;
 734 entity makeXonoticColorpickerString(string theCvar, string theDefaultCvar);
 735 entity makeXonoticCheckBoxString(string, string, string, string);
 736 entity makeXonoticCheckBox(float, string, string);
 737 .bool sendCvars;
 738
 739 void dialog_hudpanel_main_checkbox(entity me, string panelname)
 740 {
 741         entity e;
 742
 743         me.TR(me);
 744                 me.TDempty(me, 1.5);
 745                 me.TD(me, 1, 2.5, e = makeXonoticCheckBox(0, strzone(strcat("hud_panel_", panelname)), _("Enable")));
 746 }
 747
 748 void dialog_hudpanel_main_settings(entity me, string panelname)
 749 {
 750         float i;
 751         entity e;
 752
 753         me.gotoRC(me, me.currentRow + 1.5, 0);
 754                 me.TD(me, 1, 1.4, e = makeXonoticTextLabel(0, _("Background:")));
 755                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg"))));
 756                                 e.addValue(e, _("Default"), "");
 757                                 e.addValue(e, _("Disable"), "0");
 758                                 e.addValue(e, strzone(strcat("border_", panelname)), strzone(strcat("border_", panelname)));
 759                                 e.configureXonoticTextSliderValues(e);
 760         me.TR(me);
 761                 me.TDempty(me, 0.2);
 762                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Color:")));
 763                 me.TD(me, 2, 2.6, e = makeXonoticColorpickerString(strzone(strcat("hud_panel_", panelname, "_bg_color")), "hud_panel_bg_color"));
 764                         setDependentStringNotEqual(e, strzone(strcat("hud_panel_", panelname, "_bg_color")), "");
 765         me.TR(me);
 766                 me.TDempty(me, 0.2);
 767                 me.TD(me, 1, 1.0, e = makeXonoticCheckBoxString("", "1 1 1", strzone(strcat("hud_panel_", panelname, "_bg_color")), _("Use default")));
 768         me.TR(me);
 769                 me.TDempty(me, 0.2);
 770                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Border size:")));
 771                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_border"))));
 772                                 e.addValue(e, _("Default"), "");
 773                                 e.addValue(e, _("Disable"), "0");
 774                                 for(i = 1; i <= 10; ++i)
 775                                         e.addValue(e, strzone(ftos_decimals(i * 2, 0)), strzone(ftos(i * 2)));
 776                                 e.configureXonoticTextSliderValues(e);
 777         me.TR(me);
 778                 me.TDempty(me, 0.2);
 779                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Alpha:")));
 780                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_alpha"))));
 781                                 e.addValue(e, _("Default"), "");
 782                                 for(i = 1; i <= 10; ++i)
 783                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 784                                 e.configureXonoticTextSliderValues(e);
 785         me.TR(me);
 786                 me.TDempty(me, 0.2);
 787                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Team Color:")));
 788                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_color_team"))));
 789                                 e.addValue(e, _("Default"), "");
 790                                 e.addValue(e, _("Disable"), "0");
 791                                 for(i = 1; i <= 10; ++i)
 792                                         e.addValue(e, strzone(ftos_decimals(i/10, 1)), strzone(ftos(i/10)));
 793                                 e.configureXonoticTextSliderValues(e);
 794         me.TR(me);
 795                 me.TDempty(me, 0.4);
 796                 me.TD(me, 1, 3.6, e = makeXonoticCheckBox(0, "hud_configure_teamcolorforced", _("Test team color in configure mode")));
 797         me.TR(me);
 798                 me.TDempty(me, 0.2);
 799                 me.TD(me, 1, 1.2, e = makeXonoticTextLabel(0, _("Padding:")));
 800                         me.TD(me, 1, 2.6, e = makeXonoticTextSlider(strzone(strcat("hud_panel_", panelname, "_bg_padding"))));
 801                                 e.addValue(e, _("Default"), "");
 802                                 for(i = 0; i <= 10; ++i)
 803                                         e.addValue(e, strzone(ftos_decimals(i - 5, 0)), strzone(ftos(i - 5)));
 804                                 e.configureXonoticTextSliderValues(e);
 805 }
 806
 807 bool isServerSingleplayer()
 808 {
 809         return (cvar_string("net_address") == "127.0.0.1" && cvar_string("net_address_ipv6") == "::1");
 810 }
 811
 812 void makeServerSingleplayer()
 813 {
 814         // it doesn't allow clients to connect from different machines
 815         localcmd("defer 0.1 \"sv_cmd settemp net_address 127.0.0.1\"\n");
 816         localcmd("defer 0.1 \"sv_cmd settemp net_address_ipv6 ::1\"\n");
 817 }
 818
 819 float getFadedAlpha(float currentAlpha, float startAlpha, float targetAlpha)
 820 {
 821         if(startAlpha < targetAlpha)
 822                 currentAlpha = min(currentAlpha + frametime * 0.5, targetAlpha);
 823         else
 824                 currentAlpha = max(currentAlpha - frametime * 0.5, targetAlpha);
 825         return currentAlpha;
 826 }
 827
 828 void CheckSendCvars(entity me, string cvarnamestring)
 829 {
 830         if(me.sendCvars)
 831         {
 832                 if(gamestatus & (GAME_CONNECTED | GAME_ISSERVER))
 833                 {
 834                         LOG_INFOF("Sending cvar: %s -> %s", cvarnamestring, cvar_string(cvarnamestring));
 835                         cmd(sprintf("\nsendcvar %s\n", cvarnamestring));
 836                 }
 837         }
 838 }