qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/triggers/teleporters.qh>
  22 #include <common/triggers/trigger/jumppads.qh>
  23
  24 #include <lib/warpzone/common.qh>
  25
  26 .float speed;
  27
  28 void havocbot_ai(entity this)
  29 {
  30         if(this.draggedby)
  31                 return;
  32
  33         if(bot_execute_commands(this))
  34                 return;
  35
  36         if (bot_strategytoken == this)
  37         if (!bot_strategytoken_taken)
  38         {
  39                 if(this.havocbot_blockhead)
  40                 {
  41                         this.havocbot_blockhead = false;
  42                 }
  43                 else
  44                 {
  45                         if (!this.jumppadcount && !STAT(FROZEN, this))
  46                                 this.havocbot_role(this); // little too far down the rabbit hole
  47                 }
  48
  49                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  50                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  51                 if(!this.goalcurrent)
  52                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  53                 {
  54                         // Look for the closest waypoint out of water
  55                         entity newgoal = NULL;
  56                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  57                         {
  58                                 if(it.origin.z < this.origin.z)
  59                                         continue;
  60
  61                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  62                                         continue;
  63
  64                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  65                                         continue;
  66
  67                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  68
  69                                 if(trace_fraction < 1)
  70                                         continue;
  71
  72                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  73                                         newgoal = it;
  74                         });
  75
  76                         if(newgoal)
  77                         {
  78                         //      te_wizspike(newgoal.origin);
  79                                 navigation_pushroute(this, newgoal);
  80                         }
  81                 }
  82
  83                 // token has been used this frame
  84                 bot_strategytoken_taken = true;
  85         }
  86
  87         if(IS_DEAD(this) || STAT(FROZEN, this))
  88                 return;
  89
  90         havocbot_chooseenemy(this);
  91
  92         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  93         {
  94                 .entity weaponentity = weaponentities[slot];
  95                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  96                 if(this.(weaponentity).bot_chooseweapontime < time)
  97                 {
  98                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
  99                         havocbot_chooseweapon(this, weaponentity);
 100                 }
 101         }
 102         havocbot_aim(this);
 103         lag_update(this);
 104         if (this.bot_aimtarg)
 105         {
 106                 this.aistatus |= AI_STATUS_ATTACKING;
 107                 this.aistatus &= ~AI_STATUS_ROAMING;
 108
 109                 if(this.weapons)
 110                 {
 111                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 112                         {
 113                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 114                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 115                         }
 116                         else
 117                         {
 118                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 119                                 {
 120                                         .entity weaponentity = weaponentities[slot];
 121                                         Weapon w = this.(weaponentity).m_weapon;
 122                                         if(w == WEP_Null && slot != 0)
 123                                                 continue;
 124                                         w.wr_aim(w, this, weaponentity);
 125                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 126                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 127                                 }
 128                         }
 129                 }
 130                 else
 131                 {
 132                         if(IS_PLAYER(this.bot_aimtarg))
 133                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 134                 }
 135         }
 136         else if (this.goalcurrent)
 137         {
 138                 this.aistatus |= AI_STATUS_ROAMING;
 139                 this.aistatus &= ~AI_STATUS_ATTACKING;
 140
 141                 vector v = '0 0 0', now, next;
 142                 float aimdistance,skillblend,distanceblend,blend;
 143
 144                 SET_DESTCOORDS(this.goalcurrent, this.origin, v);
 145                 if(this.goalcurrent.wpisbox)
 146                 {
 147                         // avoid a glitch when bot is teleported but teleport waypoint isn't removed yet
 148                         if(this.goalstack02 && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT
 149                         && this.lastteleporttime > 0 && time - this.lastteleporttime < 0.15)
 150                                 v = (this.goalstack02.absmin + this.goalstack02.absmax) * 0.5;
 151                         // aim to teleport origin if bot is inside teleport waypoint but hasn't touched the real teleport yet
 152                         else if(boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
 153                                 v = this.goalcurrent.origin;
 154                 }
 155                 next = now = v - (this.origin + this.view_ofs);
 156                 aimdistance = vlen(now);
 157
 158                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 159                 if(
 160                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 161                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 162                 )
 163                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 164
 165                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 166                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 167                 blend = skillblend * (1-distanceblend);
 168                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 169                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 170                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 171                 v = now + blend * (next - now);
 172                 //dprint(etos(this), " ");
 173                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 174                 //v = now * (distanceblend) + next * (1-distanceblend);
 175                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 176                         v.z = 0;
 177                 //dprint("walk at:", vtos(v), "\n");
 178                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 179                 bot_aimdir(this, v, -1);
 180         }
 181         havocbot_movetogoal(this);
 182
 183         // if the bot is not attacking, consider reloading weapons
 184         if (!(this.aistatus & AI_STATUS_ATTACKING))
 185         {
 186                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 187                 {
 188                         .entity weaponentity = weaponentities[slot];
 189
 190                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 191                                 continue;
 192
 193                         // we are currently holding a weapon that's not fully loaded, reload it
 194                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 195                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 196                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 197
 198                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 199                         // the code above executes next frame, starting the reloading then
 200                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 201                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 202                         {
 203                                 FOREACH(Weapons, it != WEP_Null, {
 204                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 205                                         {
 206                                                 this.(weaponentity).m_switchweapon = it;
 207                                                 break;
 208                                         }
 209                                 });
 210                         }
 211                 }
 212         }
 213 }
 214
 215 void havocbot_keyboard_movement(entity this, vector destorg)
 216 {
 217         vector keyboard;
 218
 219         if (time > this.havocbot_keyboardtime)
 220         {
 221                 float sk = skill + this.bot_moveskill;
 222                 this.havocbot_keyboardtime =
 223                         max(
 224                                 this.havocbot_keyboardtime
 225                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 226                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 227                         , time);
 228                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 229
 230                 float trigger = autocvar_bot_ai_keyboard_threshold;
 231                 float trigger1 = -trigger;
 232
 233                 // categorize forward movement
 234                 // at skill < 1.5 only forward
 235                 // at skill < 2.5 only individual directions
 236                 // at skill < 4.5 only individual directions, and forward diagonals
 237                 // at skill >= 4.5, all cases allowed
 238                 if (keyboard.x > trigger)
 239                 {
 240                         keyboard.x = 1;
 241                         if (sk < 2.5)
 242                                 keyboard.y = 0;
 243                 }
 244                 else if (keyboard.x < trigger1 && sk > 1.5)
 245                 {
 246                         keyboard.x = -1;
 247                         if (sk < 4.5)
 248                                 keyboard.y = 0;
 249                 }
 250                 else
 251                 {
 252                         keyboard.x = 0;
 253                         if (sk < 1.5)
 254                                 keyboard.y = 0;
 255                 }
 256                 if (sk < 4.5)
 257                         keyboard.z = 0;
 258
 259                 if (keyboard.y > trigger)
 260                         keyboard.y = 1;
 261                 else if (keyboard.y < trigger1)
 262                         keyboard.y = -1;
 263                 else
 264                         keyboard.y = 0;
 265
 266                 if (keyboard.z > trigger)
 267                         keyboard.z = 1;
 268                 else if (keyboard.z < trigger1)
 269                         keyboard.z = -1;
 270                 else
 271                         keyboard.z = 0;
 272
 273                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 274                 if (this.havocbot_ducktime > time)
 275                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 276         }
 277
 278         keyboard = this.havocbot_keyboard;
 279         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 280         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 281         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 282 }
 283
 284 void havocbot_bunnyhop(entity this, vector dir)
 285 {
 286         float bunnyhopdistance;
 287         vector deviation;
 288         float maxspeed;
 289         vector gco = '0 0 0', gno;
 290
 291         // Don't jump when attacking
 292         if(this.aistatus & AI_STATUS_ATTACKING)
 293                 return;
 294
 295         if(IS_PLAYER(this.goalcurrent))
 296                 return;
 297
 298         maxspeed = autocvar_sv_maxspeed;
 299
 300         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 301                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 302         {
 303                 this.aistatus &= ~AI_STATUS_RUNNING;
 304                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 305                 this.bot_canruntogoal = 0;
 306                 this.bot_timelastseengoal = 0;
 307                 return;
 308         }
 309
 310         if(this.waterlevel > WATERLEVEL_WETFEET)
 311         {
 312                 this.aistatus &= ~AI_STATUS_RUNNING;
 313                 return;
 314         }
 315
 316         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 317         {
 318                 this.bot_canruntogoal = 0;
 319                 this.bot_timelastseengoal = 0;
 320         }
 321
 322         SET_DESTCOORDS(this.goalcurrent, this.origin, gco);
 323         bunnyhopdistance = vlen(this.origin - gco);
 324
 325         // Run only to visible goals
 326         if(IS_ONGROUND(this))
 327         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 328         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 329         {
 330                         this.bot_lastseengoal = this.goalcurrent;
 331
 332                         // seen it before
 333                         if(this.bot_timelastseengoal)
 334                         {
 335                                 // for a period of time
 336                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 337                                 {
 338                                         float checkdistance;
 339                                         checkdistance = true;
 340
 341                                         // don't run if it is too close
 342                                         if(this.bot_canruntogoal==0)
 343                                         {
 344                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 345                                                         this.bot_canruntogoal = 1;
 346                                                 else
 347                                                         this.bot_canruntogoal = -1;
 348                                         }
 349
 350                                         if(this.bot_canruntogoal != 1)
 351                                                 return;
 352
 353                                         if(this.aistatus & AI_STATUS_ROAMING)
 354                                         if(this.goalcurrent.classname=="waypoint")
 355                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 356                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 357                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 358                                         {
 359                                                 gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 360                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 361                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 362                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 363
 364                                                 if(fabs(deviation.y) < 20)
 365                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 366                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 367                                                 {
 368                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 369                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 370                                                         {
 371                                                                 checkdistance = false;
 372                                                         }
 373                                                 }
 374                                         }
 375
 376                                         if(checkdistance)
 377                                         {
 378                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 379                                                 // increase stop distance in case the goal is on a slope or a lower platform
 380                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 381                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 382                                         }
 383                                         else
 384                                         {
 385                                                 this.aistatus |= AI_STATUS_RUNNING;
 386                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 387                                         }
 388                                 }
 389                         }
 390                         else
 391                         {
 392                                 this.bot_timelastseengoal = time;
 393                         }
 394         }
 395         else
 396         {
 397                 this.bot_timelastseengoal = 0;
 398         }
 399
 400 #if 0
 401         // Release jump button
 402         if(!cvar("sv_pogostick"))
 403         if((IS_ONGROUND(this)) == 0)
 404         {
 405                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 406                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 407
 408                 // Strafe
 409                 if(this.aistatus & AI_STATUS_RUNNING)
 410                 if(vlen(this.velocity)>maxspeed)
 411                 {
 412                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 413                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 414                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 415
 416                         if(fabs(deviation.y)>10)
 417                                 CS(this).movement_x = 0;
 418
 419                         if(deviation.y>10)
 420                                 CS(this).movement_y = maxspeed * -1;
 421                         else if(deviation.y<10)
 422                                 CS(this).movement_y = maxspeed;
 423
 424                 }
 425         }
 426 #endif
 427 }
 428
 429 // return true when bot isn't getting closer to the current goal
 430 bool havocbot_checkgoaldistance(entity this, vector gco)
 431 {
 432         float curr_dist = vlen(this.origin - gco);
 433         float curr_dist_2d = vlen(vec2(this.origin - gco));
 434         float distance_time = this.goalcurrent_distance_time;
 435         if(distance_time < 0)
 436                 distance_time = -distance_time;
 437         if(curr_dist > this.goalcurrent_distance && curr_dist_2d > this.goalcurrent_distance_2d)
 438         {
 439                 if(!distance_time)
 440                         this.goalcurrent_distance_time = time;
 441                 else if (time - distance_time > 0.5)
 442                         return true;
 443         }
 444         else
 445         {
 446                 // reduce it a little bit so it works even with very small approaches to the goal
 447                 this.goalcurrent_distance = max(20, curr_dist - 10);
 448                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 449                 this.goalcurrent_distance_time = 0;
 450         }
 451         return false;
 452 }
 453
 454 void havocbot_movetogoal(entity this)
 455 {
 456         vector destorg = '0 0 0';
 457         vector diff;
 458         vector dir;
 459         vector flatdir;
 460         vector evadeobstacle;
 461         vector evadelava;
 462         float maxspeed;
 463         vector gco;
 464         //float dist;
 465         vector dodge;
 466         //if (this.goalentity)
 467         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 468         CS(this).movement = '0 0 0';
 469         maxspeed = autocvar_sv_maxspeed;
 470
 471         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 472         // Jetpack navigation
 473         if(this.navigation_jetpack_goal)
 474         if(this.goalcurrent==this.navigation_jetpack_goal)
 475         if(this.ammo_fuel)
 476         {
 477                 if(autocvar_bot_debug_goalstack)
 478                 {
 479                         debuggoalstack(this);
 480                         te_wizspike(this.navigation_jetpack_point);
 481                 }
 482
 483                 // Take off
 484                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 485                 {
 486                         // Brake almost completely so it can get a good direction
 487                         if(vdist(this.velocity, >, 10))
 488                                 return;
 489                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 490                 }
 491
 492                 makevectors(this.v_angle.y * '0 1 0');
 493                 dir = normalize(this.navigation_jetpack_point - this.origin);
 494
 495                 // Landing
 496                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 497                 {
 498                         // Calculate brake distance in xy
 499                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 500                         float v = vlen(vec2(this.velocity));
 501                         float db = ((v ** 2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 502                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 503                         if(d < db || d < 500)
 504                         {
 505                                 // Brake
 506                                 if(v > maxspeed * 0.3)
 507                                 {
 508                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 509                                         return;
 510                                 }
 511                                 // Switch to normal mode
 512                                 this.navigation_jetpack_goal = NULL;
 513                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 514                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 515                                 return;
 516                         }
 517                 }
 518                 else if(checkpvs(this.origin,this.goalcurrent))
 519                 {
 520                         // If I can see the goal switch to landing code
 521                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 522                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 523                         return;
 524                 }
 525
 526                 // Flying
 527                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 528                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 529                 {
 530                         CS(this).movement_x = dir * v_forward * maxspeed;
 531                         CS(this).movement_y = dir * v_right * maxspeed;
 532                 }
 533                 return;
 534         }
 535
 536         // Handling of jump pads
 537         if(this.jumppadcount)
 538         {
 539                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 540                 {
 541                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 542                         navigation_poptouchedgoals(this);
 543                         return;
 544                 }
 545                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 546                 {
 547                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 548                         // but with some randomness so it can try out different paths
 549                         if(!this.goalcurrent)
 550                         {
 551                                 entity newgoal = NULL;
 552                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 553                                 {
 554                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 555                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 556                                                 continue;
 557
 558                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 559
 560                                         if(trace_fraction < 1)
 561                                                 continue;
 562
 563                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 564                                                 newgoal = it;
 565                                 });
 566
 567                                 if(newgoal)
 568                                 {
 569                                         this.ignoregoal = this.goalcurrent;
 570                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 571                                         navigation_clearroute(this);
 572                                         navigation_routetogoal(this, newgoal, this.origin);
 573                                         if(autocvar_bot_debug_goalstack)
 574                                                 debuggoalstack(this);
 575                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 576                                 }
 577                         }
 578                         else
 579                         {
 580                                 gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 581                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 582                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 583                                 else if(havocbot_checkgoaldistance(this, gco))
 584                                 {
 585                                         navigation_clearroute(this);
 586                                         navigation_goalrating_timeout_force(this);
 587                                 }
 588                                 else
 589                                         return;
 590                         }
 591                 }
 592                 else
 593                 {
 594                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 595                         {
 596                                 vector velxy = this.velocity; velxy_z = 0;
 597                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 598                                 {
 599                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 600                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 601                                 }
 602                                 return;
 603                         }
 604
 605                         // Don't chase players while using a jump pad
 606                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 607                                 return;
 608                 }
 609         }
 610         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 611                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 612
 613         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 614         if (skill > 6 && !(IS_ONGROUND(this)))
 615         {
 616                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 617                         * ((this.strength_finished < time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 618                         * ((this.invincible_finished < time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 619
 620                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 621                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 622                 if(this.items & IT_JETPACK)
 623                 {
 624                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 625                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 626                         {
 627                                 if(this.velocity.z<0)
 628                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 629                         }
 630                         else
 631                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 632
 633                         // If there is no goal try to move forward
 634
 635                         if(this.goalcurrent==NULL)
 636                                 dir = v_forward;
 637                         else
 638                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 639
 640                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 641                         float xyspeed = xyvelocity * dir;
 642
 643                         if(xyspeed < (maxspeed / 2))
 644                         {
 645                                 makevectors(this.v_angle.y * '0 1 0');
 646                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 647                                 if(trace_fraction==1)
 648                                 {
 649                                         CS(this).movement_x = dir * v_forward * maxspeed;
 650                                         CS(this).movement_y = dir * v_right * maxspeed;
 651                                         if (skill < 10)
 652                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 653                                 }
 654                         }
 655
 656                         this.havocbot_blockhead = true;
 657
 658                         return;
 659                 }
 660                 else if(this.health + this.armorvalue > ROCKETJUMP_DAMAGE())
 661                 {
 662                         if(this.velocity.z < 0)
 663                         {
 664                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 665                                 {
 666                                         .entity weaponentity = weaponentities[slot];
 667
 668                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 669                                                 continue;
 670
 671                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 672                                         {
 673                                                 CS(this).movement_x = maxspeed;
 674
 675                                                 if(this.rocketjumptime)
 676                                                 {
 677                                                         if(time > this.rocketjumptime)
 678                                                         {
 679                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 680                                                                 this.rocketjumptime = 0;
 681                                                         }
 682                                                         return;
 683                                                 }
 684
 685                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 686                                                 this.v_angle_x = 90;
 687                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 688                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 689                                                 return;
 690                                         }
 691                                 }
 692                         }
 693                 }
 694                 else
 695                 {
 696                         // If there is no goal try to move forward
 697                         if(this.goalcurrent==NULL)
 698                                 CS(this).movement_x = maxspeed;
 699                 }
 700         }
 701
 702         // If we are under water with no goals, swim up
 703         if(this.waterlevel)
 704         if(this.goalcurrent==NULL)
 705         {
 706                 dir = '0 0 0';
 707                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 708                         dir.z = 1;
 709                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 710                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 711                 else
 712                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 713                 makevectors(this.v_angle.y * '0 1 0');
 714                 CS(this).movement_x = dir * v_forward * maxspeed;
 715                 CS(this).movement_y = dir * v_right * maxspeed;
 716                 CS(this).movement_z = dir * v_up * maxspeed;
 717         }
 718
 719         // if there is nowhere to go, exit
 720         if (this.goalcurrent == NULL)
 721                 return;
 722
 723
 724         bool locked_goal = false;
 725         if(this.goalentity && wasfreed(this.goalentity))
 726         {
 727                 navigation_clearroute(this);
 728                 navigation_goalrating_timeout_force(this);
 729                 return;
 730         }
 731         else if(this.goalentity.bot_pickup)
 732         {
 733                 if(this.goalentity.bot_pickup_respawning)
 734                 {
 735                         if(this.goalentity.solid) // item respawned
 736                                 this.goalentity.bot_pickup_respawning = false;
 737                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 738                         {
 739                                 if(checkpvs(this.origin, this.goalentity))
 740                                 {
 741                                         this.goalentity.bot_pickup_respawning = false;
 742                                         navigation_clearroute(this);
 743                                         navigation_goalrating_timeout_force(this);
 744                                         return;
 745                                 }
 746                         }
 747                         else if(this.goalentity == this.goalcurrent)
 748                                 locked_goal = true; // wait for item to respawn
 749                 }
 750                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 751                 {
 752                         if(checkpvs(this.origin, this.goalentity))
 753                         {
 754                                 navigation_clearroute(this);
 755                                 navigation_goalrating_timeout_force(this);
 756                                 return;
 757                         }
 758                 }
 759         }
 760         if(!locked_goal)
 761         {
 762                 if(navigation_poptouchedgoals(this) && time > this.bot_strategytime - (IS_MOVABLE(this.goalentity) ? 3 : 2))
 763                         navigation_goalrating_timeout_force(this);
 764         }
 765
 766         // if ran out of goals try to use an alternative goal or get a new strategy asap
 767         if(this.goalcurrent == NULL)
 768         {
 769                 navigation_goalrating_timeout_force(this);
 770                 return;
 771         }
 772
 773
 774         if(autocvar_bot_debug_goalstack)
 775                 debuggoalstack(this);
 776
 777         bool bunnyhop_forbidden = false;;
 778         SET_DESTCOORDS(this.goalcurrent, this.origin, destorg);
 779
 780         // in case bot ends up inside the teleport waypoint without touching
 781         // the teleport itself, head to the teleport origin
 782         if(this.goalcurrent.wpisbox && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z))
 783         {
 784                 bunnyhop_forbidden = true;
 785                 destorg = this.goalcurrent.origin;
 786                 if(destorg.z > this.origin.z)
 787                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 788         }
 789
 790         diff = destorg - this.origin;
 791         //dist = vlen(diff);
 792         dir = normalize(diff);
 793         flatdir = diff;flatdir.z = 0;
 794         flatdir = normalize(flatdir);
 795         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 796
 797         //if (this.bot_dodgevector_time < time)
 798         {
 799                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 800                 //this.bot_dodgevector_jumpbutton = 1;
 801                 evadeobstacle = '0 0 0';
 802                 evadelava = '0 0 0';
 803
 804                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 805                 makevectors(this.v_angle.y * '0 1 0');
 806                 if (this.waterlevel)
 807                 {
 808                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 809                         {
 810                                 if(!this.goalcurrent)
 811                                         this.aistatus |= AI_STATUS_OUT_WATER;
 812                                 else if(gco.z > this.origin.z)
 813                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 814                         }
 815                         else
 816                         {
 817                                 dir = flatdir;
 818                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && gco.z < this.origin.z) &&
 819                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 820                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 821                                 else
 822                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 823                         }
 824                 }
 825                 else
 826                 {
 827                         float s;
 828                         vector offset;
 829                         if(this.aistatus & AI_STATUS_OUT_WATER)
 830                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 831
 832                         // jump if going toward an obstacle that doesn't look like stairs we
 833                         // can walk up directly
 834                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
 835                         tracebox(this.origin, this.mins, this.maxs, this.origin + offset, false, this);
 836                         if (trace_fraction < 1)
 837                         if (trace_plane_normal.z < 0.7)
 838                         {
 839                                 s = trace_fraction;
 840                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, this.origin + offset + stepheightvec, false, this);
 841                                 if (trace_fraction < s + 0.01)
 842                                 if (trace_plane_normal.z < 0.7)
 843                                 {
 844                                         s = trace_fraction;
 845                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, this.origin + offset + jumpstepheightvec, false, this);
 846                                         if (trace_fraction > s)
 847                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 848                                 }
 849                         }
 850
 851                         // if bot for some reason doesn't get close to the current goal find another one
 852                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent) && !(this.goalcurrent.bot_pickup_respawning && this.goalcurrent_distance < 50))
 853                         if(havocbot_checkgoaldistance(this, gco))
 854                         {
 855                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
 856                                 {
 857                                         navigation_clearroute(this);
 858                                         navigation_goalrating_timeout_force(this);
 859                                         return;
 860                                 }
 861
 862                                 vector dest = '0 0 0';
 863                                 float dest_height = 0;
 864                                 SET_TRACEWALK_DESTCOORDS(this.goalcurrent, this.origin, dest, dest_height);
 865                                 if (!tracewalk(this, this.origin, this.mins, this.maxs, dest, dest_height, bot_navigation_movemode))
 866                                 {
 867                                         navigation_clearroute(this);
 868                                         navigation_goalrating_timeout_force(this);
 869                                         return;
 870                                 }
 871
 872                                 // give bot only another chance to prevent bot getting stuck
 873                                 // in case it thinks it can walk but actually can't
 874                                 this.goalcurrent_distance = FLOAT_MAX;
 875                                 this.goalcurrent_distance_2d = FLOAT_MAX;
 876                                 this.goalcurrent_distance_time = -time; // mark second try
 877                         }
 878
 879                         // Check for water/slime/lava and dangerous edges
 880                         // (only when the bot is on the ground or jumping intentionally)
 881
 882                         vector dst_ahead = this.origin + this.view_ofs + offset;
 883                         vector dst_down = dst_ahead - '0 0 3000';
 884                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 885
 886                         bool unreachable = false;
 887                         s = CONTENT_SOLID;
 888                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 889                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
 890                         {
 891                                 // Look downwards
 892                                 traceline(dst_ahead , dst_down, true, NULL);
 893                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
 894                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
 895                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 896                                 {
 897                                         s = pointcontents(trace_endpos + '0 0 1');
 898                                         if (s != CONTENT_SOLID)
 899                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 900                                                 evadelava = normalize(this.velocity) * -1;
 901                                         else if (s == CONTENT_SKY)
 902                                                 evadeobstacle = normalize(this.velocity) * -1;
 903                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 904                                         {
 905                                                 // the traceline check isn't enough but is good as optimization,
 906                                                 // when not true (most of the time) this tracebox call is avoided
 907                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
 908                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 909                                                 {
 910                                                         if (gco.z > this.origin.z + jumpstepheightvec.z)
 911                                                         {
 912                                                                 // the goal is probably on an upper platform, assume bot can't get there
 913                                                                 unreachable = true;
 914                                                         }
 915                                                         else
 916                                                                 evadelava = normalize(this.velocity) * -1;
 917                                                 }
 918                                         }
 919                                 }
 920                         }
 921
 922                         dir = flatdir;
 923                         evadeobstacle.z = 0;
 924                         evadelava.z = 0;
 925                         makevectors(this.v_angle.y * '0 1 0');
 926
 927                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
 928                         {
 929                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
 930                                 if(IS_PLAYER(this.goalcurrent))
 931                                         unreachable = true;
 932                         }
 933                         if(unreachable)
 934                         {
 935                                 navigation_clearroute(this);
 936                                 navigation_goalrating_timeout_force(this);
 937                         }
 938                 }
 939
 940                 dodge = havocbot_dodge(this);
 941                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
 942                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 943                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
 944                 if(IS_PLAYER(trace_ent))
 945                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
 946
 947                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 948         //      this.bot_dodgevector = dir;
 949         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
 950         }
 951
 952         if(time < this.ladder_time)
 953         {
 954                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
 955                 {
 956                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
 957                                 dir.z = 1;
 958                 }
 959                 else
 960                 {
 961                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
 962                                 dir.z = -1;
 963                 }
 964         }
 965
 966         //dir = this.bot_dodgevector;
 967         //if (this.bot_dodgevector_jumpbutton)
 968         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
 969         CS(this).movement_x = dir * v_forward * maxspeed;
 970         CS(this).movement_y = dir * v_right * maxspeed;
 971         CS(this).movement_z = dir * v_up * maxspeed;
 972
 973         // Emulate keyboard interface
 974         if (skill < 10)
 975                 havocbot_keyboard_movement(this, destorg);
 976
 977         // Bunnyhop!
 978         //if(this.aistatus & AI_STATUS_ROAMING)
 979         if(!bunnyhop_forbidden && this.goalcurrent)
 980         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
 981                 havocbot_bunnyhop(this, dir);
 982
 983         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
 984         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
 985         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
 986 }
 987
 988 entity havocbot_gettarget(entity this, bool secondary)
 989 {
 990         entity best = NULL;
 991         vector eye = CENTER_OR_VIEWOFS(this);
 992         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
 993         {
 994                 vector v = CENTER_OR_VIEWOFS(it);
 995                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
 996                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
 997                 if(bot_shouldattack(this, it))
 998                 {
 999                         traceline(eye, v, true, this);
1000                         if (trace_ent == it || trace_fraction >= 1)
1001                                 best = it;
1002                 }
1003         });
1004
1005         return best;
1006 }
1007
1008 void havocbot_chooseenemy(entity this)
1009 {
1010         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1011         {
1012                 this.enemy = NULL;
1013                 return;
1014         }
1015         if (this.enemy)
1016         {
1017                 if (!bot_shouldattack(this, this.enemy))
1018                 {
1019                         // enemy died or something, find a new target
1020                         this.enemy = NULL;
1021                         this.havocbot_chooseenemy_finished = time;
1022                 }
1023                 else if (this.havocbot_stickenemy)
1024                 {
1025                         // tracking last chosen enemy
1026                         // if enemy is visible
1027                         // and not really really far away
1028                         // and we're not severely injured
1029                         // then keep tracking for a half second into the future
1030                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1031                         if (trace_ent == this.enemy || trace_fraction == 1)
1032                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1033                         if (this.health > 30)
1034                         {
1035                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1036                                 this.havocbot_chooseenemy_finished = time + 0.5;
1037                                 return;
1038                         }
1039                         // enemy isn't visible, or is far away, or we're injured severely
1040                         // so stop preferring this enemy
1041                         // (it will still take a half second until a new one is chosen)
1042                         this.havocbot_stickenemy = 0;
1043                 }
1044         }
1045         if (time < this.havocbot_chooseenemy_finished)
1046                 return;
1047         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1048         vector eye = this.origin + this.view_ofs;
1049         entity best = NULL;
1050         float bestrating = 100000000;
1051
1052         // Backup hit flags
1053         int hf = this.dphitcontentsmask;
1054
1055         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1056
1057         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1058
1059         bool scan_transparent = false;
1060         bool scan_secondary_targets = false;
1061         bool have_secondary_targets = false;
1062         while(true)
1063         {
1064                 scan_secondary_targets = false;
1065 LABEL(scan_targets)
1066                 IL_EACH(g_bot_targets, it.bot_attack,
1067                 {
1068                         if(!scan_secondary_targets)
1069                         {
1070                                 if(it.classname == "misc_breakablemodel")
1071                                 {
1072                                         have_secondary_targets = true;
1073                                         continue;
1074                                 }
1075                         }
1076                         else if(it.classname != "misc_breakablemodel")
1077                                 continue;
1078
1079                         vector v = (it.absmin + it.absmax) * 0.5;
1080                         float rating = vlen2(v - eye);
1081                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1082                         if (bestrating > rating)
1083                         if (bot_shouldattack(this, it))
1084                         {
1085                                 traceline(eye, v, true, this);
1086                                 if (trace_ent == it || trace_fraction >= 1)
1087                                 {
1088                                         best = it;
1089                                         bestrating = rating;
1090                                 }
1091                         }
1092                 });
1093
1094                 if(!best && have_secondary_targets && !scan_secondary_targets)
1095                 {
1096                         scan_secondary_targets = true;
1097                         // restart the loop
1098                         bestrating = 100000000;
1099                         goto scan_targets;
1100                 }
1101
1102                 // I want to do a second scan if no enemy was found or I don't have weapons
1103                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1104                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
1105                         break;
1106                 if(scan_transparent)
1107                         break;
1108
1109                 // Set flags to see through transparent objects
1110                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1111
1112                 scan_transparent = true;
1113         }
1114
1115         // Restore hit flags
1116         this.dphitcontentsmask = hf;
1117
1118         this.enemy = best;
1119         this.havocbot_stickenemy = true;
1120         if(best && best.classname == "misc_breakablemodel")
1121                 this.havocbot_stickenemy = false;
1122 }
1123
1124 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1125 {
1126         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1127         // so skip this for them, or they'll never get to reload their weapons at all.
1128         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1129         if(skill < 5)
1130                 return false;
1131
1132         // if this weapon is scheduled for reloading, don't switch to it during combat
1133         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1134         {
1135                 FOREACH(Weapons, it != WEP_Null, {
1136                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1137                                 return true; // other weapon available
1138                 });
1139         }
1140
1141         return false;
1142 }
1143
1144 void havocbot_chooseweapon(entity this, .entity weaponentity)
1145 {
1146         int i;
1147
1148         // ;)
1149         if(g_weaponarena_weapons == WEPSET(TUBA))
1150         {
1151                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1152                 return;
1153         }
1154
1155         // TODO: clean this up by moving it to weapon code
1156         if(this.enemy==NULL)
1157         {
1158                 // If no weapon was chosen get the first available weapon
1159                 if(this.(weaponentity).m_weapon==WEP_Null)
1160                 FOREACH(Weapons, it != WEP_Null, {
1161                         if(client_hasweapon(this, it, weaponentity, true, false))
1162                         {
1163                                 this.(weaponentity).m_switchweapon = it;
1164                                 return;
1165                         }
1166                 });
1167                 return;
1168         }
1169
1170         // Do not change weapon during the next second after a combo
1171         float f = time - this.lastcombotime;
1172         if(f < 1)
1173                 return;
1174
1175         float w;
1176         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1177
1178         // Should it do a weapon combo?
1179         float af, ct, combo_time, combo;
1180
1181         af = ATTACK_FINISHED(this, 0);
1182         ct = autocvar_bot_ai_weapon_combo_threshold;
1183
1184         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1185         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1186         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1187
1188         combo = false;
1189
1190         if(autocvar_bot_ai_weapon_combo)
1191         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1192         if(af > combo_time)
1193         {
1194                 combo = true;
1195                 this.lastcombotime = time;
1196         }
1197
1198         distance *= (2 ** this.bot_rangepreference);
1199
1200         // Custom weapon list based on distance to the enemy
1201         if(bot_custom_weapon){
1202
1203                 // Choose weapons for far distance
1204                 if ( distance > bot_distance_far ) {
1205                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1206                                 w = bot_weapons_far[i];
1207                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1208                                 {
1209                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1210                                                 continue;
1211                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1212                                         return;
1213                                 }
1214                         }
1215                 }
1216
1217                 // Choose weapons for mid distance
1218                 if ( distance > bot_distance_close) {
1219                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1220                                 w = bot_weapons_mid[i];
1221                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1222                                 {
1223                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1224                                                 continue;
1225                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1226                                         return;
1227                                 }
1228                         }
1229                 }
1230
1231                 // Choose weapons for close distance
1232                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1233                         w = bot_weapons_close[i];
1234                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1235                         {
1236                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1237                                         continue;
1238                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1239                                 return;
1240                         }
1241                 }
1242         }
1243 }
1244
1245 void havocbot_aim(entity this)
1246 {
1247         if (time < this.nextaim)
1248                 return;
1249         this.nextaim = time + 0.1;
1250         vector myvel = this.velocity;
1251         if (!this.waterlevel)
1252                 myvel.z = 0;
1253         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1254         else if (this.enemy)
1255         {
1256                 vector enemyvel = this.enemy.velocity;
1257                 if (!this.enemy.waterlevel)
1258                         enemyvel.z = 0;
1259                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1260         }
1261         else
1262                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1263 }
1264
1265 bool havocbot_moveto_refresh_route(entity this)
1266 {
1267         // Refresh path to goal if necessary
1268         entity wp;
1269         wp = this.havocbot_personal_waypoint;
1270         navigation_goalrating_start(this);
1271         navigation_routerating(this, wp, 10000, 10000);
1272         navigation_goalrating_end(this);
1273         return (this.goalentity != NULL);
1274 }
1275
1276 float havocbot_moveto(entity this, vector pos)
1277 {
1278         entity wp;
1279
1280         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1281         {
1282                 // Step 4: Move to waypoint
1283                 if(this.havocbot_personal_waypoint==NULL)
1284                 {
1285                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1286                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1287                         return CMD_STATUS_ERROR;
1288                 }
1289
1290                 if (!bot_strategytoken_taken)
1291                 if(this.havocbot_personal_waypoint_searchtime<time)
1292                 {
1293                         bot_strategytoken_taken = true;
1294                         if(havocbot_moveto_refresh_route(this))
1295                         {
1296                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1297                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1298                                 this.havocbot_personal_waypoint_failcounter = 0;
1299                         }
1300                         else
1301                         {
1302                                 this.havocbot_personal_waypoint_failcounter += 1;
1303                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1304                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1305                                 {
1306                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1307                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1308                                         delete(this.havocbot_personal_waypoint);
1309                                         return CMD_STATUS_ERROR;
1310                                 }
1311                                 else
1312                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1313                         }
1314                 }
1315
1316                 if(autocvar_bot_debug_goalstack)
1317                         debuggoalstack(this);
1318
1319                 // Heading
1320                 vector dir = '0 0 0';
1321                 SET_DESTCOORDS(this.goalcurrent, this.origin, dir);
1322                 dir = dir - (this.origin + this.view_ofs);
1323                 dir.z = 0;
1324                 bot_aimdir(this, dir, -1);
1325
1326                 // Go!
1327                 havocbot_movetogoal(this);
1328
1329                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1330                 {
1331                         // Step 5: Waypoint reached
1332                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1333                         delete(this.havocbot_personal_waypoint);
1334                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1335                         return CMD_STATUS_FINISHED;
1336                 }
1337
1338                 return CMD_STATUS_EXECUTING;
1339         }
1340
1341         // Step 2: Linking waypoint
1342         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1343         {
1344                 // Wait until it is linked
1345                 if(!this.havocbot_personal_waypoint.wplinked)
1346                 {
1347                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1348                         return CMD_STATUS_EXECUTING;
1349                 }
1350
1351                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1352                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1353                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1354
1355                 // Step 3: Route to waypoint
1356                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1357
1358                 return CMD_STATUS_EXECUTING;
1359         }
1360
1361         // Step 1: Spawning waypoint
1362         wp = waypoint_spawnpersonal(this, pos);
1363         if(wp==NULL)
1364         {
1365                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1366                 return CMD_STATUS_ERROR;
1367         }
1368
1369         this.havocbot_personal_waypoint = wp;
1370         this.havocbot_personal_waypoint_failcounter = 0;
1371         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1372
1373         // if pos is inside a teleport, then let's mark it as teleport waypoint
1374         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1375         {
1376                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1377                 this.lastteleporttime = 0;
1378         });
1379
1380 /*
1381         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1382                 print("routing to a teleporter\n");
1383         else
1384                 print("routing to a non-teleporter\n");
1385 */
1386
1387         return CMD_STATUS_EXECUTING;
1388 }
1389
1390 float havocbot_resetgoal(entity this)
1391 {
1392         navigation_clearroute(this);
1393         return CMD_STATUS_FINISHED;
1394 }
1395
1396 void havocbot_setupbot(entity this)
1397 {
1398         this.bot_ai = havocbot_ai;
1399         this.cmd_moveto = havocbot_moveto;
1400         this.cmd_resetgoal = havocbot_resetgoal;
1401
1402         havocbot_chooserole(this);
1403 }
1404
1405 vector havocbot_dodge(entity this)
1406 {
1407         // LordHavoc: disabled because this is too expensive
1408         return '0 0 0';
1409 #if 0
1410         entity head;
1411         vector dodge, v, n;
1412         float danger, bestdanger, vl, d;
1413         dodge = '0 0 0';
1414         bestdanger = -20;
1415         // check for dangerous objects near bot or approaching bot
1416         head = findchainfloat(bot_dodge, true);
1417         while(head)
1418         {
1419                 if (head.owner != this)
1420                 {
1421                         vl = vlen(head.velocity);
1422                         if (vl > autocvar_sv_maxspeed * 0.3)
1423                         {
1424                                 n = normalize(head.velocity);
1425                                 v = this.origin - head.origin;
1426                                 d = v * n;
1427                                 if (d > (0 - head.bot_dodgerating))
1428                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1429                                 {
1430                                         // calculate direction and distance from the flight path, by removing the forward axis
1431                                         v = v - (n * (v * n));
1432                                         danger = head.bot_dodgerating - vlen(v);
1433                                         if (bestdanger < danger)
1434                                         {
1435                                                 bestdanger = danger;
1436                                                 // dodge to the side of the object
1437                                                 dodge = normalize(v);
1438                                         }
1439                                 }
1440                         }
1441                         else
1442                         {
1443                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1444                                 if (bestdanger < danger)
1445                                 {
1446                                         bestdanger = danger;
1447                                         dodge = normalize(this.origin - head.origin);
1448                                 }
1449                         }
1450                 }
1451                 head = head.chain;
1452         }
1453         return dodge;
1454 #endif
1455 }