qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/triggers/teleporters.qh>
  22 #include <common/triggers/trigger/jumppads.qh>
  23
  24 #include <lib/warpzone/common.qh>
  25
  26 .float speed;
  27
  28 void havocbot_ai(entity this)
  29 {
  30         if(this.draggedby)
  31                 return;
  32
  33         if(bot_execute_commands(this))
  34                 return;
  35
  36         if (bot_strategytoken == this && !bot_strategytoken_taken)
  37         {
  38                 if(this.havocbot_blockhead)
  39                 {
  40                         this.havocbot_blockhead = false;
  41                 }
  42                 else
  43                 {
  44                         if (!this.jumppadcount && !STAT(FROZEN, this))
  45                                 this.havocbot_role(this); // little too far down the rabbit hole
  46                 }
  47
  48                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  49                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  50                 if(!this.goalcurrent)
  51                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  52                 {
  53                         // Look for the closest waypoint out of water
  54                         entity newgoal = NULL;
  55                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  56                         {
  57                                 if(it.origin.z < this.origin.z)
  58                                         continue;
  59
  60                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  61                                         continue;
  62
  63                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  64                                         continue;
  65
  66                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  67
  68                                 if(trace_fraction < 1)
  69                                         continue;
  70
  71                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  72                                         newgoal = it;
  73                         });
  74
  75                         if(newgoal)
  76                         {
  77                         //      te_wizspike(newgoal.origin);
  78                                 navigation_pushroute(this, newgoal);
  79                         }
  80                 }
  81
  82                 // token has been used this frame
  83                 bot_strategytoken_taken = true;
  84         }
  85
  86         if(IS_DEAD(this) || STAT(FROZEN, this))
  87         {
  88                 if (this.goalcurrent)
  89                         navigation_clearroute(this);
  90                 return;
  91         }
  92
  93         havocbot_chooseenemy(this);
  94
  95         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  96         {
  97                 .entity weaponentity = weaponentities[slot];
  98                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  99                 if(this.(weaponentity).bot_chooseweapontime < time)
 100                 {
 101                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 102                         havocbot_chooseweapon(this, weaponentity);
 103                 }
 104         }
 105         havocbot_aim(this);
 106         lag_update(this);
 107         if (this.bot_aimtarg)
 108         {
 109                 this.aistatus |= AI_STATUS_ATTACKING;
 110                 this.aistatus &= ~AI_STATUS_ROAMING;
 111
 112                 if(this.weapons)
 113                 {
 114                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 115                         {
 116                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 117                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 118                         }
 119                         else
 120                         {
 121                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 122                                 {
 123                                         .entity weaponentity = weaponentities[slot];
 124                                         Weapon w = this.(weaponentity).m_weapon;
 125                                         if(w == WEP_Null && slot != 0)
 126                                                 continue;
 127                                         w.wr_aim(w, this, weaponentity);
 128                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 129                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 130                                 }
 131                         }
 132                 }
 133                 else
 134                 {
 135                         if(IS_PLAYER(this.bot_aimtarg))
 136                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 137                 }
 138         }
 139         else if (this.goalcurrent)
 140         {
 141                 this.aistatus |= AI_STATUS_ROAMING;
 142                 this.aistatus &= ~AI_STATUS_ATTACKING;
 143
 144                 vector now, next;
 145                 float aimdistance,skillblend,distanceblend,blend;
 146
 147                 vector v = get_closer_dest(this.goalcurrent, this.origin);
 148                 if(this.goalcurrent.wpisbox)
 149                 {
 150                         // avoid a glitch when bot is teleported but teleport waypoint isn't removed yet
 151                         if(this.goalstack02 && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT
 152                         && this.lastteleporttime > 0 && time - this.lastteleporttime < 0.15)
 153                                 v = (this.goalstack02.absmin + this.goalstack02.absmax) * 0.5;
 154                         // aim to teleport origin if bot is inside teleport waypoint but hasn't touched the real teleport yet
 155                         else if(boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
 156                                 v = this.goalcurrent.origin;
 157                 }
 158                 next = now = v - (this.origin + this.view_ofs);
 159                 aimdistance = vlen(now);
 160
 161                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 162                 if(
 163                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 164                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 165                 )
 166                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 167
 168                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 169                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 170                 blend = skillblend * (1-distanceblend);
 171                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 172                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 173                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 174                 v = now + blend * (next - now);
 175                 //dprint(etos(this), " ");
 176                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 177                 //v = now * (distanceblend) + next * (1-distanceblend);
 178                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 179                         v.z = 0;
 180                 //dprint("walk at:", vtos(v), "\n");
 181                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 182                 bot_aimdir(this, v, -1);
 183         }
 184         havocbot_movetogoal(this);
 185
 186         // if the bot is not attacking, consider reloading weapons
 187         if (!(this.aistatus & AI_STATUS_ATTACKING))
 188         {
 189                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 190                 {
 191                         .entity weaponentity = weaponentities[slot];
 192
 193                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 194                                 continue;
 195
 196                         // we are currently holding a weapon that's not fully loaded, reload it
 197                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 198                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 199                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 200
 201                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 202                         // the code above executes next frame, starting the reloading then
 203                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 204                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 205                         {
 206                                 FOREACH(Weapons, it != WEP_Null, {
 207                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 208                                         {
 209                                                 this.(weaponentity).m_switchweapon = it;
 210                                                 break;
 211                                         }
 212                                 });
 213                         }
 214                 }
 215         }
 216 }
 217
 218 void havocbot_keyboard_movement(entity this, vector destorg)
 219 {
 220         vector keyboard;
 221
 222         if (time > this.havocbot_keyboardtime)
 223         {
 224                 float sk = skill + this.bot_moveskill;
 225                 this.havocbot_keyboardtime =
 226                         max(
 227                                 this.havocbot_keyboardtime
 228                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 229                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 230                         , time);
 231                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 232
 233                 float trigger = autocvar_bot_ai_keyboard_threshold;
 234                 float trigger1 = -trigger;
 235
 236                 // categorize forward movement
 237                 // at skill < 1.5 only forward
 238                 // at skill < 2.5 only individual directions
 239                 // at skill < 4.5 only individual directions, and forward diagonals
 240                 // at skill >= 4.5, all cases allowed
 241                 if (keyboard.x > trigger)
 242                 {
 243                         keyboard.x = 1;
 244                         if (sk < 2.5)
 245                                 keyboard.y = 0;
 246                 }
 247                 else if (keyboard.x < trigger1 && sk > 1.5)
 248                 {
 249                         keyboard.x = -1;
 250                         if (sk < 4.5)
 251                                 keyboard.y = 0;
 252                 }
 253                 else
 254                 {
 255                         keyboard.x = 0;
 256                         if (sk < 1.5)
 257                                 keyboard.y = 0;
 258                 }
 259                 if (sk < 4.5)
 260                         keyboard.z = 0;
 261
 262                 if (keyboard.y > trigger)
 263                         keyboard.y = 1;
 264                 else if (keyboard.y < trigger1)
 265                         keyboard.y = -1;
 266                 else
 267                         keyboard.y = 0;
 268
 269                 if (keyboard.z > trigger)
 270                         keyboard.z = 1;
 271                 else if (keyboard.z < trigger1)
 272                         keyboard.z = -1;
 273                 else
 274                         keyboard.z = 0;
 275
 276                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 277                 if (this.havocbot_ducktime > time)
 278                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 279         }
 280
 281         keyboard = this.havocbot_keyboard;
 282         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 283         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 284         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 285 }
 286
 287 void havocbot_bunnyhop(entity this, vector dir)
 288 {
 289         float bunnyhopdistance;
 290         vector deviation;
 291         float maxspeed;
 292
 293         // Don't jump when attacking
 294         if(this.aistatus & AI_STATUS_ATTACKING)
 295                 return;
 296
 297         if(IS_PLAYER(this.goalcurrent))
 298                 return;
 299
 300         maxspeed = autocvar_sv_maxspeed;
 301
 302         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 303                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 304         {
 305                 this.aistatus &= ~AI_STATUS_RUNNING;
 306                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 307                 this.bot_canruntogoal = 0;
 308                 this.bot_timelastseengoal = 0;
 309                 return;
 310         }
 311
 312         if(this.waterlevel > WATERLEVEL_WETFEET)
 313         {
 314                 this.aistatus &= ~AI_STATUS_RUNNING;
 315                 return;
 316         }
 317
 318         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 319         {
 320                 this.bot_canruntogoal = 0;
 321                 this.bot_timelastseengoal = 0;
 322         }
 323
 324         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 325         bunnyhopdistance = vlen(this.origin - gco);
 326
 327         // Run only to visible goals
 328         if(IS_ONGROUND(this))
 329         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 330         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 331         {
 332                         this.bot_lastseengoal = this.goalcurrent;
 333
 334                         // seen it before
 335                         if(this.bot_timelastseengoal)
 336                         {
 337                                 // for a period of time
 338                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 339                                 {
 340                                         float checkdistance;
 341                                         checkdistance = true;
 342
 343                                         // don't run if it is too close
 344                                         if(this.bot_canruntogoal==0)
 345                                         {
 346                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 347                                                         this.bot_canruntogoal = 1;
 348                                                 else
 349                                                         this.bot_canruntogoal = -1;
 350                                         }
 351
 352                                         if(this.bot_canruntogoal != 1)
 353                                                 return;
 354
 355                                         if(this.aistatus & AI_STATUS_ROAMING)
 356                                         if(this.goalcurrent.classname=="waypoint")
 357                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 358                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 359                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 360                                         {
 361                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 362                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 363                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 364                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 365
 366                                                 if(fabs(deviation.y) < 20)
 367                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 368                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 369                                                 {
 370                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 371                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 372                                                         {
 373                                                                 checkdistance = false;
 374                                                         }
 375                                                 }
 376                                         }
 377
 378                                         if(checkdistance)
 379                                         {
 380                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 381                                                 // increase stop distance in case the goal is on a slope or a lower platform
 382                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 383                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 384                                         }
 385                                         else
 386                                         {
 387                                                 this.aistatus |= AI_STATUS_RUNNING;
 388                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 389                                         }
 390                                 }
 391                         }
 392                         else
 393                         {
 394                                 this.bot_timelastseengoal = time;
 395                         }
 396         }
 397         else
 398         {
 399                 this.bot_timelastseengoal = 0;
 400         }
 401
 402 #if 0
 403         // Release jump button
 404         if(!cvar("sv_pogostick"))
 405         if((IS_ONGROUND(this)) == 0)
 406         {
 407                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 408                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 409
 410                 // Strafe
 411                 if(this.aistatus & AI_STATUS_RUNNING)
 412                 if(vlen(this.velocity)>maxspeed)
 413                 {
 414                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 415                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 416                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 417
 418                         if(fabs(deviation.y)>10)
 419                                 CS(this).movement_x = 0;
 420
 421                         if(deviation.y>10)
 422                                 CS(this).movement_y = maxspeed * -1;
 423                         else if(deviation.y<10)
 424                                 CS(this).movement_y = maxspeed;
 425
 426                 }
 427         }
 428 #endif
 429 }
 430
 431 // return true when bot isn't getting closer to the current goal
 432 bool havocbot_checkgoaldistance(entity this, vector gco)
 433 {
 434         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 435         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 436         float distance_time = this.goalcurrent_distance_time;
 437         if(distance_time < 0)
 438                 distance_time = -distance_time;
 439         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 440         {
 441                 if(!distance_time)
 442                         this.goalcurrent_distance_time = time;
 443                 else if (time - distance_time > 0.5)
 444                         return true;
 445         }
 446         else
 447         {
 448                 // reduce it a little bit so it works even with very small approaches to the goal
 449                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 450                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 451                 this.goalcurrent_distance_time = 0;
 452         }
 453         return false;
 454 }
 455
 456 void havocbot_movetogoal(entity this)
 457 {
 458         vector diff;
 459         vector dir;
 460         vector flatdir;
 461         vector evadeobstacle;
 462         vector evadelava;
 463         float maxspeed;
 464         vector gco;
 465         //float dist;
 466         vector dodge;
 467         //if (this.goalentity)
 468         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 469         CS(this).movement = '0 0 0';
 470         maxspeed = autocvar_sv_maxspeed;
 471
 472         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 473         // Jetpack navigation
 474         if(this.navigation_jetpack_goal)
 475         if(this.goalcurrent==this.navigation_jetpack_goal)
 476         if(this.ammo_fuel)
 477         {
 478                 if(autocvar_bot_debug_goalstack)
 479                 {
 480                         debuggoalstack(this);
 481                         te_wizspike(this.navigation_jetpack_point);
 482                 }
 483
 484                 // Take off
 485                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 486                 {
 487                         // Brake almost completely so it can get a good direction
 488                         if(vdist(this.velocity, >, 10))
 489                                 return;
 490                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 491                 }
 492
 493                 makevectors(this.v_angle.y * '0 1 0');
 494                 dir = normalize(this.navigation_jetpack_point - this.origin);
 495
 496                 // Landing
 497                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 498                 {
 499                         // Calculate brake distance in xy
 500                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 501                         float v = vlen(vec2(this.velocity));
 502                         float db = ((v ** 2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 503                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 504                         if(d < db || d < 500)
 505                         {
 506                                 // Brake
 507                                 if(v > maxspeed * 0.3)
 508                                 {
 509                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 510                                         return;
 511                                 }
 512                                 // Switch to normal mode
 513                                 this.navigation_jetpack_goal = NULL;
 514                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 515                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 516                                 return;
 517                         }
 518                 }
 519                 else if(checkpvs(this.origin,this.goalcurrent))
 520                 {
 521                         // If I can see the goal switch to landing code
 522                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 523                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 524                         return;
 525                 }
 526
 527                 // Flying
 528                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 529                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 530                 {
 531                         CS(this).movement_x = dir * v_forward * maxspeed;
 532                         CS(this).movement_y = dir * v_right * maxspeed;
 533                 }
 534                 return;
 535         }
 536
 537         // Handling of jump pads
 538         if(this.jumppadcount)
 539         {
 540                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 541                 {
 542                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 543                         navigation_poptouchedgoals(this);
 544                         return;
 545                 }
 546                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 547                 {
 548                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 549                         // but with some randomness so it can try out different paths
 550                         if(!this.goalcurrent)
 551                         {
 552                                 entity newgoal = NULL;
 553                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 554                                 {
 555                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 556                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 557                                                 continue;
 558
 559                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 560
 561                                         if(trace_fraction < 1)
 562                                                 continue;
 563
 564                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 565                                                 newgoal = it;
 566                                 });
 567
 568                                 if(newgoal)
 569                                 {
 570                                         this.ignoregoal = this.goalcurrent;
 571                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 572                                         navigation_clearroute(this);
 573                                         navigation_routetogoal(this, newgoal, this.origin);
 574                                         if(autocvar_bot_debug_goalstack)
 575                                                 debuggoalstack(this);
 576                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 577                                 }
 578                         }
 579                         else
 580                         {
 581                                 if (this.goalcurrent.bot_pickup)
 582                                 {
 583                                         entity jumppad_wp = this.goalcurrent_prev;
 584                                         navigation_poptouchedgoals(this);
 585                                         if(!this.goalcurrent && jumppad_wp.wp00)
 586                                         {
 587                                                 // head to the jumppad destination once bot reaches the goal item
 588                                                 navigation_pushroute(this, jumppad_wp.wp00);
 589                                         }
 590                                 }
 591                                 gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 592                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 593                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 594                                 else if(havocbot_checkgoaldistance(this, gco))
 595                                 {
 596                                         navigation_clearroute(this);
 597                                         navigation_goalrating_timeout_force(this);
 598                                 }
 599                                 else
 600                                         return;
 601                         }
 602                 }
 603                 else
 604                 {
 605                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 606                         {
 607                                 vector velxy = this.velocity; velxy_z = 0;
 608                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 609                                 {
 610                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 611                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 612                                 }
 613                                 return;
 614                         }
 615
 616                         // Don't chase players while using a jump pad
 617                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 618                                 return;
 619                 }
 620         }
 621         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 622                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 623
 624         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 625         if (skill > 6 && !(IS_ONGROUND(this)))
 626         {
 627                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 628                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 629                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 630
 631                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 632                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 633                 if(this.items & IT_JETPACK)
 634                 {
 635                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 636                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 637                         {
 638                                 if(this.velocity.z<0)
 639                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 640                         }
 641                         else
 642                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 643
 644                         // If there is no goal try to move forward
 645
 646                         if(this.goalcurrent==NULL)
 647                                 dir = v_forward;
 648                         else
 649                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 650
 651                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 652                         float xyspeed = xyvelocity * dir;
 653
 654                         if(xyspeed < (maxspeed / 2))
 655                         {
 656                                 makevectors(this.v_angle.y * '0 1 0');
 657                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 658                                 if(trace_fraction==1)
 659                                 {
 660                                         CS(this).movement_x = dir * v_forward * maxspeed;
 661                                         CS(this).movement_y = dir * v_right * maxspeed;
 662                                         if (skill < 10)
 663                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 664                                 }
 665                         }
 666
 667                         this.havocbot_blockhead = true;
 668
 669                         return;
 670                 }
 671                 else if(this.health + this.armorvalue > ROCKETJUMP_DAMAGE())
 672                 {
 673                         if(this.velocity.z < 0)
 674                         {
 675                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 676                                 {
 677                                         .entity weaponentity = weaponentities[slot];
 678
 679                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 680                                                 continue;
 681
 682                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 683                                         {
 684                                                 CS(this).movement_x = maxspeed;
 685
 686                                                 if(this.rocketjumptime)
 687                                                 {
 688                                                         if(time > this.rocketjumptime)
 689                                                         {
 690                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 691                                                                 this.rocketjumptime = 0;
 692                                                         }
 693                                                         return;
 694                                                 }
 695
 696                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 697                                                 this.v_angle_x = 90;
 698                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 699                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 700                                                 return;
 701                                         }
 702                                 }
 703                         }
 704                 }
 705                 else
 706                 {
 707                         // If there is no goal try to move forward
 708                         if(this.goalcurrent==NULL)
 709                                 CS(this).movement_x = maxspeed;
 710                 }
 711         }
 712
 713         // If we are under water with no goals, swim up
 714         if(this.waterlevel)
 715         if(this.goalcurrent==NULL)
 716         {
 717                 dir = '0 0 0';
 718                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 719                         dir.z = 1;
 720                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 721                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 722                 else
 723                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 724                 makevectors(this.v_angle.y * '0 1 0');
 725                 CS(this).movement_x = dir * v_forward * maxspeed;
 726                 CS(this).movement_y = dir * v_right * maxspeed;
 727                 CS(this).movement_z = dir * v_up * maxspeed;
 728         }
 729
 730         // if there is nowhere to go, exit
 731         if (this.goalcurrent == NULL)
 732                 return;
 733
 734
 735         bool locked_goal = false;
 736         if(this.goalentity && wasfreed(this.goalentity))
 737         {
 738                 navigation_clearroute(this);
 739                 navigation_goalrating_timeout_force(this);
 740                 return;
 741         }
 742         else if(this.goalentity.bot_pickup)
 743         {
 744                 if(this.goalentity.bot_pickup_respawning)
 745                 {
 746                         if(this.goalentity.solid) // item respawned
 747                                 this.goalentity.bot_pickup_respawning = false;
 748                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 749                         {
 750                                 if(checkpvs(this.origin, this.goalentity))
 751                                 {
 752                                         this.goalentity.bot_pickup_respawning = false;
 753                                         navigation_goalrating_timeout_expire(this, random());
 754                                 }
 755                                 locked_goal = true; // wait for item to respawn
 756                         }
 757                         else if(this.goalentity == this.goalcurrent)
 758                                 locked_goal = true; // wait for item to respawn
 759                 }
 760                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 761                 {
 762                         if(checkpvs(this.origin, this.goalentity))
 763                         {
 764                                 navigation_goalrating_timeout_expire(this, random());
 765                         }
 766                 }
 767         }
 768         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 769                 locked_goal = true;
 770
 771         if (IS_MOVABLE(this.goalcurrent))
 772         {
 773                 if (IS_DEAD(this.goalcurrent))
 774                 {
 775                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 776                         {
 777                                 navigation_goalrating_timeout_force(this);
 778                                 return;
 779                         }
 780                 }
 781                 else if (this.bot_tracewalk_time < time)
 782                 {
 783                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 784                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 785                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 786                         {
 787                                 navigation_goalrating_timeout_force(this);
 788                                 return;
 789                         }
 790                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 791                 }
 792         }
 793         if(!locked_goal)
 794         {
 795                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 796                 // in this case path finding can start directly from a waypoint instead of
 797                 // looking for all the reachable waypoints up to a certain distance
 798                 if (navigation_poptouchedgoals(this) && this.goalcurrent)
 799                 {
 800                         if (IS_MOVABLE(this.goalcurrent) && IS_DEAD(this.goalcurrent))
 801                         {
 802                                 // remove even if not visible
 803                                 navigation_goalrating_timeout_force(this);
 804                                 return;
 805                         }
 806                         else if (navigation_goalrating_timeout_can_be_anticipated(this))
 807                                 navigation_goalrating_timeout_force(this);
 808                 }
 809         }
 810
 811         // if ran out of goals try to use an alternative goal or get a new strategy asap
 812         if(this.goalcurrent == NULL)
 813         {
 814                 navigation_goalrating_timeout_force(this);
 815                 return;
 816         }
 817
 818
 819         if(autocvar_bot_debug_goalstack)
 820                 debuggoalstack(this);
 821
 822         bool bunnyhop_forbidden = false;
 823         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 824
 825         // in case bot ends up inside the teleport waypoint without touching
 826         // the teleport itself, head to the teleport origin
 827         if(this.goalcurrent.wpisbox && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z))
 828         {
 829                 bunnyhop_forbidden = true;
 830                 destorg = this.goalcurrent.origin;
 831                 if(destorg.z > this.origin.z)
 832                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 833         }
 834
 835         diff = destorg - this.origin;
 836
 837         if (fabs(diff.x) < 10 && fabs(diff.y) < 10
 838                 && this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout)
 839         {
 840                 destorg = this.origin;
 841                 diff.x = 0;
 842                 diff.y = 0;
 843         }
 844
 845         dir = normalize(diff);
 846         flatdir = diff;flatdir.z = 0;
 847         flatdir = normalize(flatdir);
 848         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 849
 850         //if (this.bot_dodgevector_time < time)
 851         {
 852                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 853                 //this.bot_dodgevector_jumpbutton = 1;
 854                 evadeobstacle = '0 0 0';
 855                 evadelava = '0 0 0';
 856
 857                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 858                 makevectors(this.v_angle.y * '0 1 0');
 859                 if (this.waterlevel)
 860                 {
 861                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 862                         {
 863                                 if(!this.goalcurrent)
 864                                         this.aistatus |= AI_STATUS_OUT_WATER;
 865                                 else if(gco.z > this.origin.z)
 866                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 867                         }
 868                         else
 869                         {
 870                                 dir = flatdir;
 871                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && gco.z < this.origin.z) &&
 872                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 873                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 874                                 else
 875                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 876                         }
 877                 }
 878                 else
 879                 {
 880                         float s;
 881                         vector offset;
 882                         if(this.aistatus & AI_STATUS_OUT_WATER)
 883                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 884
 885                         // jump if going toward an obstacle that doesn't look like stairs we
 886                         // can walk up directly
 887                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
 888                         tracebox(this.origin, this.mins, this.maxs, this.origin + offset, false, this);
 889                         if (trace_fraction < 1)
 890                         if (trace_plane_normal.z < 0.7)
 891                         {
 892                                 s = trace_fraction;
 893                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, this.origin + offset + stepheightvec, false, this);
 894                                 if (trace_fraction < s + 0.01)
 895                                 if (trace_plane_normal.z < 0.7)
 896                                 {
 897                                         s = trace_fraction;
 898                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, this.origin + offset + jumpstepheightvec, false, this);
 899                                         if (trace_fraction > s)
 900                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 901                                 }
 902                         }
 903
 904                         // if bot for some reason doesn't get close to the current goal find another one
 905                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
 906                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
 907                         if(havocbot_checkgoaldistance(this, gco))
 908                         {
 909                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
 910                                 {
 911                                         navigation_clearroute(this);
 912                                         navigation_goalrating_timeout_force(this);
 913                                         return;
 914                                 }
 915
 916                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
 917                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
 918                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 919                                 {
 920                                         navigation_clearroute(this);
 921                                         navigation_goalrating_timeout_force(this);
 922                                         return;
 923                                 }
 924
 925                                 // give bot only another chance to prevent bot getting stuck
 926                                 // in case it thinks it can walk but actually can't
 927                                 this.goalcurrent_distance_z = FLOAT_MAX;
 928                                 this.goalcurrent_distance_2d = FLOAT_MAX;
 929                                 this.goalcurrent_distance_time = -time; // mark second try
 930                         }
 931
 932                         // Check for water/slime/lava and dangerous edges
 933                         // (only when the bot is on the ground or jumping intentionally)
 934
 935                         vector dst_ahead = this.origin + this.view_ofs + offset;
 936                         vector dst_down = dst_ahead - '0 0 3000';
 937                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 938
 939                         bool unreachable = false;
 940                         s = CONTENT_SOLID;
 941                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 942                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
 943                         {
 944                                 // Look downwards
 945                                 traceline(dst_ahead , dst_down, true, NULL);
 946                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
 947                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
 948                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 949                                 {
 950                                         s = pointcontents(trace_endpos + '0 0 1');
 951                                         if (s != CONTENT_SOLID)
 952                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 953                                                 evadelava = normalize(this.velocity) * -1;
 954                                         else if (s == CONTENT_SKY)
 955                                                 evadeobstacle = normalize(this.velocity) * -1;
 956                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 957                                         {
 958                                                 // the traceline check isn't enough but is good as optimization,
 959                                                 // when not true (most of the time) this tracebox call is avoided
 960                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
 961                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 962                                                 {
 963                                                         if (gco.z > this.origin.z + jumpstepheightvec.z)
 964                                                         {
 965                                                                 // the goal is probably on an upper platform, assume bot can't get there
 966                                                                 unreachable = true;
 967                                                         }
 968                                                         else
 969                                                                 evadelava = normalize(this.velocity) * -1;
 970                                                 }
 971                                         }
 972                                 }
 973                         }
 974
 975                         dir = flatdir;
 976                         evadeobstacle.z = 0;
 977                         evadelava.z = 0;
 978                         makevectors(this.v_angle.y * '0 1 0');
 979
 980                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
 981                         {
 982                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
 983                                 if(IS_PLAYER(this.goalcurrent))
 984                                         unreachable = true;
 985                         }
 986                         if(unreachable)
 987                         {
 988                                 navigation_clearroute(this);
 989                                 navigation_goalrating_timeout_force(this);
 990                         }
 991                 }
 992
 993                 dodge = havocbot_dodge(this);
 994                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
 995                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 996                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
 997                 if(IS_PLAYER(trace_ent))
 998                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
 999
1000                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
1001         //      this.bot_dodgevector = dir;
1002         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1003         }
1004
1005         if(time < this.ladder_time)
1006         {
1007                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1008                 {
1009                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1010                                 dir.z = 1;
1011                 }
1012                 else
1013                 {
1014                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1015                                 dir.z = -1;
1016                 }
1017         }
1018
1019         //dir = this.bot_dodgevector;
1020         //if (this.bot_dodgevector_jumpbutton)
1021         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1022         CS(this).movement_x = dir * v_forward * maxspeed;
1023         CS(this).movement_y = dir * v_right * maxspeed;
1024         CS(this).movement_z = dir * v_up * maxspeed;
1025
1026         // Emulate keyboard interface
1027         if (skill < 10)
1028                 havocbot_keyboard_movement(this, destorg);
1029
1030         // Bunnyhop!
1031         //if(this.aistatus & AI_STATUS_ROAMING)
1032         if(!bunnyhop_forbidden && this.goalcurrent)
1033         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1034                 havocbot_bunnyhop(this, dir);
1035
1036         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1037         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1038         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1039 }
1040
1041 entity havocbot_gettarget(entity this, bool secondary)
1042 {
1043         entity best = NULL;
1044         vector eye = CENTER_OR_VIEWOFS(this);
1045         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1046         {
1047                 vector v = CENTER_OR_VIEWOFS(it);
1048                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1049                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1050                 if(bot_shouldattack(this, it))
1051                 {
1052                         traceline(eye, v, true, this);
1053                         if (trace_ent == it || trace_fraction >= 1)
1054                                 best = it;
1055                 }
1056         });
1057
1058         return best;
1059 }
1060
1061 void havocbot_chooseenemy(entity this)
1062 {
1063         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1064         {
1065                 this.enemy = NULL;
1066                 return;
1067         }
1068         if (this.enemy)
1069         {
1070                 if (!bot_shouldattack(this, this.enemy))
1071                 {
1072                         // enemy died or something, find a new target
1073                         this.enemy = NULL;
1074                         this.havocbot_chooseenemy_finished = time;
1075                 }
1076                 else if (this.havocbot_stickenemy)
1077                 {
1078                         // tracking last chosen enemy
1079                         // if enemy is visible
1080                         // and not really really far away
1081                         // and we're not severely injured
1082                         // then keep tracking for a half second into the future
1083                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1084                         if (trace_ent == this.enemy || trace_fraction == 1)
1085                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1086                         if (this.health > 30)
1087                         {
1088                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1089                                 this.havocbot_chooseenemy_finished = time + 0.5;
1090                                 return;
1091                         }
1092                         // enemy isn't visible, or is far away, or we're injured severely
1093                         // so stop preferring this enemy
1094                         // (it will still take a half second until a new one is chosen)
1095                         this.havocbot_stickenemy = 0;
1096                 }
1097         }
1098         if (time < this.havocbot_chooseenemy_finished)
1099                 return;
1100         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1101         vector eye = this.origin + this.view_ofs;
1102         entity best = NULL;
1103         float bestrating = 100000000;
1104
1105         // Backup hit flags
1106         int hf = this.dphitcontentsmask;
1107
1108         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1109
1110         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1111
1112         bool scan_transparent = false;
1113         bool scan_secondary_targets = false;
1114         bool have_secondary_targets = false;
1115         while(true)
1116         {
1117                 scan_secondary_targets = false;
1118 LABEL(scan_targets)
1119                 IL_EACH(g_bot_targets, it.bot_attack,
1120                 {
1121                         if(!scan_secondary_targets)
1122                         {
1123                                 if(it.classname == "misc_breakablemodel")
1124                                 {
1125                                         have_secondary_targets = true;
1126                                         continue;
1127                                 }
1128                         }
1129                         else if(it.classname != "misc_breakablemodel")
1130                                 continue;
1131
1132                         vector v = (it.absmin + it.absmax) * 0.5;
1133                         float rating = vlen2(v - eye);
1134                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1135                         if (bestrating > rating)
1136                         if (bot_shouldattack(this, it))
1137                         {
1138                                 traceline(eye, v, true, this);
1139                                 if (trace_ent == it || trace_fraction >= 1)
1140                                 {
1141                                         best = it;
1142                                         bestrating = rating;
1143                                 }
1144                         }
1145                 });
1146
1147                 if(!best && have_secondary_targets && !scan_secondary_targets)
1148                 {
1149                         scan_secondary_targets = true;
1150                         // restart the loop
1151                         bestrating = 100000000;
1152                         goto scan_targets;
1153                 }
1154
1155                 // I want to do a second scan if no enemy was found or I don't have weapons
1156                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1157                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
1158                         break;
1159                 if(scan_transparent)
1160                         break;
1161
1162                 // Set flags to see through transparent objects
1163                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1164
1165                 scan_transparent = true;
1166         }
1167
1168         // Restore hit flags
1169         this.dphitcontentsmask = hf;
1170
1171         this.enemy = best;
1172         this.havocbot_stickenemy = true;
1173         if(best && best.classname == "misc_breakablemodel")
1174                 this.havocbot_stickenemy = false;
1175 }
1176
1177 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1178 {
1179         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1180         // so skip this for them, or they'll never get to reload their weapons at all.
1181         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1182         if(skill < 5)
1183                 return false;
1184
1185         // if this weapon is scheduled for reloading, don't switch to it during combat
1186         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1187         {
1188                 FOREACH(Weapons, it != WEP_Null, {
1189                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1190                                 return true; // other weapon available
1191                 });
1192         }
1193
1194         return false;
1195 }
1196
1197 void havocbot_chooseweapon(entity this, .entity weaponentity)
1198 {
1199         int i;
1200
1201         // ;)
1202         if(g_weaponarena_weapons == WEPSET(TUBA))
1203         {
1204                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1205                 return;
1206         }
1207
1208         // TODO: clean this up by moving it to weapon code
1209         if(this.enemy==NULL)
1210         {
1211                 // If no weapon was chosen get the first available weapon
1212                 if(this.(weaponentity).m_weapon==WEP_Null)
1213                 FOREACH(Weapons, it != WEP_Null, {
1214                         if(client_hasweapon(this, it, weaponentity, true, false))
1215                         {
1216                                 this.(weaponentity).m_switchweapon = it;
1217                                 return;
1218                         }
1219                 });
1220                 return;
1221         }
1222
1223         // Do not change weapon during the next second after a combo
1224         float f = time - this.lastcombotime;
1225         if(f < 1)
1226                 return;
1227
1228         float w;
1229         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1230
1231         // Should it do a weapon combo?
1232         float af, ct, combo_time, combo;
1233
1234         af = ATTACK_FINISHED(this, 0);
1235         ct = autocvar_bot_ai_weapon_combo_threshold;
1236
1237         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1238         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1239         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1240
1241         combo = false;
1242
1243         if(autocvar_bot_ai_weapon_combo)
1244         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1245         if(af > combo_time)
1246         {
1247                 combo = true;
1248                 this.lastcombotime = time;
1249         }
1250
1251         distance *= (2 ** this.bot_rangepreference);
1252
1253         // Custom weapon list based on distance to the enemy
1254         if(bot_custom_weapon){
1255
1256                 // Choose weapons for far distance
1257                 if ( distance > bot_distance_far ) {
1258                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1259                                 w = bot_weapons_far[i];
1260                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1261                                 {
1262                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1263                                                 continue;
1264                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1265                                         return;
1266                                 }
1267                         }
1268                 }
1269
1270                 // Choose weapons for mid distance
1271                 if ( distance > bot_distance_close) {
1272                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1273                                 w = bot_weapons_mid[i];
1274                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1275                                 {
1276                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1277                                                 continue;
1278                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1279                                         return;
1280                                 }
1281                         }
1282                 }
1283
1284                 // Choose weapons for close distance
1285                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1286                         w = bot_weapons_close[i];
1287                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1288                         {
1289                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1290                                         continue;
1291                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1292                                 return;
1293                         }
1294                 }
1295         }
1296 }
1297
1298 void havocbot_aim(entity this)
1299 {
1300         if (time < this.nextaim)
1301                 return;
1302         this.nextaim = time + 0.1;
1303         vector myvel = this.velocity;
1304         if (!this.waterlevel)
1305                 myvel.z = 0;
1306         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1307         else if (this.enemy)
1308         {
1309                 vector enemyvel = this.enemy.velocity;
1310                 if (!this.enemy.waterlevel)
1311                         enemyvel.z = 0;
1312                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1313         }
1314         else
1315                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1316 }
1317
1318 bool havocbot_moveto_refresh_route(entity this)
1319 {
1320         // Refresh path to goal if necessary
1321         entity wp;
1322         wp = this.havocbot_personal_waypoint;
1323         navigation_goalrating_start(this);
1324         navigation_routerating(this, wp, 10000, 10000);
1325         navigation_goalrating_end(this);
1326         return (this.goalentity != NULL);
1327 }
1328
1329 float havocbot_moveto(entity this, vector pos)
1330 {
1331         entity wp;
1332
1333         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1334         {
1335                 // Step 4: Move to waypoint
1336                 if(this.havocbot_personal_waypoint==NULL)
1337                 {
1338                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1339                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1340                         return CMD_STATUS_ERROR;
1341                 }
1342
1343                 if (!bot_strategytoken_taken)
1344                 if(this.havocbot_personal_waypoint_searchtime<time)
1345                 {
1346                         bot_strategytoken_taken = true;
1347                         if(havocbot_moveto_refresh_route(this))
1348                         {
1349                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1350                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1351                                 this.havocbot_personal_waypoint_failcounter = 0;
1352                         }
1353                         else
1354                         {
1355                                 this.havocbot_personal_waypoint_failcounter += 1;
1356                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1357                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1358                                 {
1359                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1360                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1361                                         delete(this.havocbot_personal_waypoint);
1362                                         return CMD_STATUS_ERROR;
1363                                 }
1364                                 else
1365                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1366                         }
1367                 }
1368
1369                 if(autocvar_bot_debug_goalstack)
1370                         debuggoalstack(this);
1371
1372                 // Heading
1373                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
1374                 dir = dir - (this.origin + this.view_ofs);
1375                 dir.z = 0;
1376                 bot_aimdir(this, dir, -1);
1377
1378                 // Go!
1379                 havocbot_movetogoal(this);
1380
1381                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1382                 {
1383                         // Step 5: Waypoint reached
1384                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1385                         delete(this.havocbot_personal_waypoint);
1386                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1387                         return CMD_STATUS_FINISHED;
1388                 }
1389
1390                 return CMD_STATUS_EXECUTING;
1391         }
1392
1393         // Step 2: Linking waypoint
1394         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1395         {
1396                 // Wait until it is linked
1397                 if(!this.havocbot_personal_waypoint.wplinked)
1398                 {
1399                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1400                         return CMD_STATUS_EXECUTING;
1401                 }
1402
1403                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1404                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1405                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1406
1407                 // Step 3: Route to waypoint
1408                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1409
1410                 return CMD_STATUS_EXECUTING;
1411         }
1412
1413         // Step 1: Spawning waypoint
1414         wp = waypoint_spawnpersonal(this, pos);
1415         if(wp==NULL)
1416         {
1417                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1418                 return CMD_STATUS_ERROR;
1419         }
1420
1421         this.havocbot_personal_waypoint = wp;
1422         this.havocbot_personal_waypoint_failcounter = 0;
1423         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1424
1425         // if pos is inside a teleport, then let's mark it as teleport waypoint
1426         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1427         {
1428                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1429                 this.lastteleporttime = 0;
1430         });
1431
1432 /*
1433         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1434                 print("routing to a teleporter\n");
1435         else
1436                 print("routing to a non-teleporter\n");
1437 */
1438
1439         return CMD_STATUS_EXECUTING;
1440 }
1441
1442 float havocbot_resetgoal(entity this)
1443 {
1444         navigation_clearroute(this);
1445         return CMD_STATUS_FINISHED;
1446 }
1447
1448 void havocbot_setupbot(entity this)
1449 {
1450         this.bot_ai = havocbot_ai;
1451         this.cmd_moveto = havocbot_moveto;
1452         this.cmd_resetgoal = havocbot_resetgoal;
1453
1454         havocbot_chooserole(this);
1455 }
1456
1457 vector havocbot_dodge(entity this)
1458 {
1459         // LordHavoc: disabled because this is too expensive
1460         return '0 0 0';
1461 #if 0
1462         entity head;
1463         vector dodge, v, n;
1464         float danger, bestdanger, vl, d;
1465         dodge = '0 0 0';
1466         bestdanger = -20;
1467         // check for dangerous objects near bot or approaching bot
1468         head = findchainfloat(bot_dodge, true);
1469         while(head)
1470         {
1471                 if (head.owner != this)
1472                 {
1473                         vl = vlen(head.velocity);
1474                         if (vl > autocvar_sv_maxspeed * 0.3)
1475                         {
1476                                 n = normalize(head.velocity);
1477                                 v = this.origin - head.origin;
1478                                 d = v * n;
1479                                 if (d > (0 - head.bot_dodgerating))
1480                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1481                                 {
1482                                         // calculate direction and distance from the flight path, by removing the forward axis
1483                                         v = v - (n * (v * n));
1484                                         danger = head.bot_dodgerating - vlen(v);
1485                                         if (bestdanger < danger)
1486                                         {
1487                                                 bestdanger = danger;
1488                                                 // dodge to the side of the object
1489                                                 dodge = normalize(v);
1490                                         }
1491                                 }
1492                         }
1493                         else
1494                         {
1495                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1496                                 if (bestdanger < danger)
1497                                 {
1498                                         bestdanger = danger;
1499                                         dodge = normalize(this.origin - head.origin);
1500                                 }
1501                         }
1502                 }
1503                 head = head.chain;
1504         }
1505         return dodge;
1506 #endif
1507 }