qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/triggers/teleporters.qh>
  22 #include <common/triggers/trigger/jumppads.qh>
  23
  24 #include <lib/warpzone/common.qh>
  25
  26 .float speed;
  27
  28 void havocbot_ai(entity this)
  29 {
  30         if(this.draggedby)
  31                 return;
  32
  33         if(bot_execute_commands(this))
  34                 return;
  35
  36         if (bot_strategytoken == this && !bot_strategytoken_taken)
  37         {
  38                 if(this.havocbot_blockhead)
  39                 {
  40                         this.havocbot_blockhead = false;
  41                 }
  42                 else
  43                 {
  44                         if (!this.jumppadcount && !STAT(FROZEN, this))
  45                                 this.havocbot_role(this); // little too far down the rabbit hole
  46                 }
  47
  48                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  49                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  50                 if(!this.goalcurrent)
  51                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  52                 {
  53                         // Look for the closest waypoint out of water
  54                         entity newgoal = NULL;
  55                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  56                         {
  57                                 if(it.origin.z < this.origin.z)
  58                                         continue;
  59
  60                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  61                                         continue;
  62
  63                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  64                                         continue;
  65
  66                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  67
  68                                 if(trace_fraction < 1)
  69                                         continue;
  70
  71                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  72                                         newgoal = it;
  73                         });
  74
  75                         if(newgoal)
  76                         {
  77                         //      te_wizspike(newgoal.origin);
  78                                 navigation_pushroute(this, newgoal);
  79                         }
  80                 }
  81
  82                 // token has been used this frame
  83                 bot_strategytoken_taken = true;
  84         }
  85
  86         if(IS_DEAD(this) || STAT(FROZEN, this))
  87         {
  88                 if (this.goalcurrent)
  89                         navigation_clearroute(this);
  90                 return;
  91         }
  92
  93         havocbot_chooseenemy(this);
  94
  95         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  96         {
  97                 .entity weaponentity = weaponentities[slot];
  98                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  99                 if(this.(weaponentity).bot_chooseweapontime < time)
 100                 {
 101                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 102                         havocbot_chooseweapon(this, weaponentity);
 103                 }
 104         }
 105         havocbot_aim(this);
 106         lag_update(this);
 107         if (this.bot_aimtarg)
 108         {
 109                 this.aistatus |= AI_STATUS_ATTACKING;
 110                 this.aistatus &= ~AI_STATUS_ROAMING;
 111
 112                 if(this.weapons)
 113                 {
 114                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 115                         {
 116                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 117                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 118                         }
 119                         else
 120                         {
 121                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 122                                 {
 123                                         .entity weaponentity = weaponentities[slot];
 124                                         Weapon w = this.(weaponentity).m_weapon;
 125                                         if(w == WEP_Null && slot != 0)
 126                                                 continue;
 127                                         w.wr_aim(w, this, weaponentity);
 128                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 129                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 130                                 }
 131                         }
 132                 }
 133                 else
 134                 {
 135                         if(IS_PLAYER(this.bot_aimtarg))
 136                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 137                 }
 138         }
 139         else if (this.goalcurrent)
 140         {
 141                 this.aistatus |= AI_STATUS_ROAMING;
 142                 this.aistatus &= ~AI_STATUS_ATTACKING;
 143
 144                 vector v = '0 0 0', now, next;
 145                 float aimdistance,skillblend,distanceblend,blend;
 146
 147                 SET_DESTCOORDS(this.goalcurrent, this.origin, v);
 148                 if(this.goalcurrent.wpisbox)
 149                 {
 150                         // avoid a glitch when bot is teleported but teleport waypoint isn't removed yet
 151                         if(this.goalstack02 && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT
 152                         && this.lastteleporttime > 0 && time - this.lastteleporttime < 0.15)
 153                                 v = (this.goalstack02.absmin + this.goalstack02.absmax) * 0.5;
 154                         // aim to teleport origin if bot is inside teleport waypoint but hasn't touched the real teleport yet
 155                         else if(boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
 156                                 v = this.goalcurrent.origin;
 157                 }
 158                 next = now = v - (this.origin + this.view_ofs);
 159                 aimdistance = vlen(now);
 160
 161                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 162                 if(
 163                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 164                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 165                 )
 166                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 167
 168                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 169                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 170                 blend = skillblend * (1-distanceblend);
 171                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 172                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 173                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 174                 v = now + blend * (next - now);
 175                 //dprint(etos(this), " ");
 176                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 177                 //v = now * (distanceblend) + next * (1-distanceblend);
 178                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 179                         v.z = 0;
 180                 //dprint("walk at:", vtos(v), "\n");
 181                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 182                 bot_aimdir(this, v, -1);
 183         }
 184         havocbot_movetogoal(this);
 185
 186         // if the bot is not attacking, consider reloading weapons
 187         if (!(this.aistatus & AI_STATUS_ATTACKING))
 188         {
 189                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 190                 {
 191                         .entity weaponentity = weaponentities[slot];
 192
 193                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 194                                 continue;
 195
 196                         // we are currently holding a weapon that's not fully loaded, reload it
 197                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 198                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 199                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 200
 201                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 202                         // the code above executes next frame, starting the reloading then
 203                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 204                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 205                         {
 206                                 FOREACH(Weapons, it != WEP_Null, {
 207                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 208                                         {
 209                                                 this.(weaponentity).m_switchweapon = it;
 210                                                 break;
 211                                         }
 212                                 });
 213                         }
 214                 }
 215         }
 216 }
 217
 218 void havocbot_keyboard_movement(entity this, vector destorg)
 219 {
 220         vector keyboard;
 221
 222         if (time > this.havocbot_keyboardtime)
 223         {
 224                 float sk = skill + this.bot_moveskill;
 225                 this.havocbot_keyboardtime =
 226                         max(
 227                                 this.havocbot_keyboardtime
 228                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 229                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 230                         , time);
 231                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 232
 233                 float trigger = autocvar_bot_ai_keyboard_threshold;
 234                 float trigger1 = -trigger;
 235
 236                 // categorize forward movement
 237                 // at skill < 1.5 only forward
 238                 // at skill < 2.5 only individual directions
 239                 // at skill < 4.5 only individual directions, and forward diagonals
 240                 // at skill >= 4.5, all cases allowed
 241                 if (keyboard.x > trigger)
 242                 {
 243                         keyboard.x = 1;
 244                         if (sk < 2.5)
 245                                 keyboard.y = 0;
 246                 }
 247                 else if (keyboard.x < trigger1 && sk > 1.5)
 248                 {
 249                         keyboard.x = -1;
 250                         if (sk < 4.5)
 251                                 keyboard.y = 0;
 252                 }
 253                 else
 254                 {
 255                         keyboard.x = 0;
 256                         if (sk < 1.5)
 257                                 keyboard.y = 0;
 258                 }
 259                 if (sk < 4.5)
 260                         keyboard.z = 0;
 261
 262                 if (keyboard.y > trigger)
 263                         keyboard.y = 1;
 264                 else if (keyboard.y < trigger1)
 265                         keyboard.y = -1;
 266                 else
 267                         keyboard.y = 0;
 268
 269                 if (keyboard.z > trigger)
 270                         keyboard.z = 1;
 271                 else if (keyboard.z < trigger1)
 272                         keyboard.z = -1;
 273                 else
 274                         keyboard.z = 0;
 275
 276                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 277                 if (this.havocbot_ducktime > time)
 278                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 279         }
 280
 281         keyboard = this.havocbot_keyboard;
 282         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 283         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 284         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 285 }
 286
 287 void havocbot_bunnyhop(entity this, vector dir)
 288 {
 289         float bunnyhopdistance;
 290         vector deviation;
 291         float maxspeed;
 292         vector gco = '0 0 0', gno;
 293
 294         // Don't jump when attacking
 295         if(this.aistatus & AI_STATUS_ATTACKING)
 296                 return;
 297
 298         if(IS_PLAYER(this.goalcurrent))
 299                 return;
 300
 301         maxspeed = autocvar_sv_maxspeed;
 302
 303         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 304                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 305         {
 306                 this.aistatus &= ~AI_STATUS_RUNNING;
 307                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 308                 this.bot_canruntogoal = 0;
 309                 this.bot_timelastseengoal = 0;
 310                 return;
 311         }
 312
 313         if(this.waterlevel > WATERLEVEL_WETFEET)
 314         {
 315                 this.aistatus &= ~AI_STATUS_RUNNING;
 316                 return;
 317         }
 318
 319         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 320         {
 321                 this.bot_canruntogoal = 0;
 322                 this.bot_timelastseengoal = 0;
 323         }
 324
 325         SET_DESTCOORDS(this.goalcurrent, this.origin, gco);
 326         bunnyhopdistance = vlen(this.origin - gco);
 327
 328         // Run only to visible goals
 329         if(IS_ONGROUND(this))
 330         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 331         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 332         {
 333                         this.bot_lastseengoal = this.goalcurrent;
 334
 335                         // seen it before
 336                         if(this.bot_timelastseengoal)
 337                         {
 338                                 // for a period of time
 339                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 340                                 {
 341                                         float checkdistance;
 342                                         checkdistance = true;
 343
 344                                         // don't run if it is too close
 345                                         if(this.bot_canruntogoal==0)
 346                                         {
 347                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 348                                                         this.bot_canruntogoal = 1;
 349                                                 else
 350                                                         this.bot_canruntogoal = -1;
 351                                         }
 352
 353                                         if(this.bot_canruntogoal != 1)
 354                                                 return;
 355
 356                                         if(this.aistatus & AI_STATUS_ROAMING)
 357                                         if(this.goalcurrent.classname=="waypoint")
 358                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 359                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 360                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 361                                         {
 362                                                 gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 363                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 364                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 365                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 366
 367                                                 if(fabs(deviation.y) < 20)
 368                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 369                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 370                                                 {
 371                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 372                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 373                                                         {
 374                                                                 checkdistance = false;
 375                                                         }
 376                                                 }
 377                                         }
 378
 379                                         if(checkdistance)
 380                                         {
 381                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 382                                                 // increase stop distance in case the goal is on a slope or a lower platform
 383                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 384                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 385                                         }
 386                                         else
 387                                         {
 388                                                 this.aistatus |= AI_STATUS_RUNNING;
 389                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 390                                         }
 391                                 }
 392                         }
 393                         else
 394                         {
 395                                 this.bot_timelastseengoal = time;
 396                         }
 397         }
 398         else
 399         {
 400                 this.bot_timelastseengoal = 0;
 401         }
 402
 403 #if 0
 404         // Release jump button
 405         if(!cvar("sv_pogostick"))
 406         if((IS_ONGROUND(this)) == 0)
 407         {
 408                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 409                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 410
 411                 // Strafe
 412                 if(this.aistatus & AI_STATUS_RUNNING)
 413                 if(vlen(this.velocity)>maxspeed)
 414                 {
 415                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 416                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 417                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 418
 419                         if(fabs(deviation.y)>10)
 420                                 CS(this).movement_x = 0;
 421
 422                         if(deviation.y>10)
 423                                 CS(this).movement_y = maxspeed * -1;
 424                         else if(deviation.y<10)
 425                                 CS(this).movement_y = maxspeed;
 426
 427                 }
 428         }
 429 #endif
 430 }
 431
 432 // return true when bot isn't getting closer to the current goal
 433 bool havocbot_checkgoaldistance(entity this, vector gco)
 434 {
 435         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 436         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 437         float distance_time = this.goalcurrent_distance_time;
 438         if(distance_time < 0)
 439                 distance_time = -distance_time;
 440         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 441         {
 442                 if(!distance_time)
 443                         this.goalcurrent_distance_time = time;
 444                 else if (time - distance_time > 0.5)
 445                         return true;
 446         }
 447         else
 448         {
 449                 // reduce it a little bit so it works even with very small approaches to the goal
 450                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 451                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 452                 this.goalcurrent_distance_time = 0;
 453         }
 454         return false;
 455 }
 456
 457 void havocbot_movetogoal(entity this)
 458 {
 459         vector destorg = '0 0 0';
 460         vector diff;
 461         vector dir;
 462         vector flatdir;
 463         vector evadeobstacle;
 464         vector evadelava;
 465         float maxspeed;
 466         vector gco;
 467         //float dist;
 468         vector dodge;
 469         //if (this.goalentity)
 470         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 471         CS(this).movement = '0 0 0';
 472         maxspeed = autocvar_sv_maxspeed;
 473
 474         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 475         // Jetpack navigation
 476         if(this.navigation_jetpack_goal)
 477         if(this.goalcurrent==this.navigation_jetpack_goal)
 478         if(this.ammo_fuel)
 479         {
 480                 if(autocvar_bot_debug_goalstack)
 481                 {
 482                         debuggoalstack(this);
 483                         te_wizspike(this.navigation_jetpack_point);
 484                 }
 485
 486                 // Take off
 487                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 488                 {
 489                         // Brake almost completely so it can get a good direction
 490                         if(vdist(this.velocity, >, 10))
 491                                 return;
 492                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 493                 }
 494
 495                 makevectors(this.v_angle.y * '0 1 0');
 496                 dir = normalize(this.navigation_jetpack_point - this.origin);
 497
 498                 // Landing
 499                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 500                 {
 501                         // Calculate brake distance in xy
 502                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 503                         float v = vlen(vec2(this.velocity));
 504                         float db = ((v ** 2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 505                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 506                         if(d < db || d < 500)
 507                         {
 508                                 // Brake
 509                                 if(v > maxspeed * 0.3)
 510                                 {
 511                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 512                                         return;
 513                                 }
 514                                 // Switch to normal mode
 515                                 this.navigation_jetpack_goal = NULL;
 516                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 517                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 518                                 return;
 519                         }
 520                 }
 521                 else if(checkpvs(this.origin,this.goalcurrent))
 522                 {
 523                         // If I can see the goal switch to landing code
 524                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 525                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 526                         return;
 527                 }
 528
 529                 // Flying
 530                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 531                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 532                 {
 533                         CS(this).movement_x = dir * v_forward * maxspeed;
 534                         CS(this).movement_y = dir * v_right * maxspeed;
 535                 }
 536                 return;
 537         }
 538
 539         // Handling of jump pads
 540         if(this.jumppadcount)
 541         {
 542                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 543                 {
 544                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 545                         navigation_poptouchedgoals(this);
 546                         return;
 547                 }
 548                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 549                 {
 550                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 551                         // but with some randomness so it can try out different paths
 552                         if(!this.goalcurrent)
 553                         {
 554                                 entity newgoal = NULL;
 555                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 556                                 {
 557                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 558                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 559                                                 continue;
 560
 561                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 562
 563                                         if(trace_fraction < 1)
 564                                                 continue;
 565
 566                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 567                                                 newgoal = it;
 568                                 });
 569
 570                                 if(newgoal)
 571                                 {
 572                                         this.ignoregoal = this.goalcurrent;
 573                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 574                                         navigation_clearroute(this);
 575                                         navigation_routetogoal(this, newgoal, this.origin);
 576                                         if(autocvar_bot_debug_goalstack)
 577                                                 debuggoalstack(this);
 578                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 579                                 }
 580                         }
 581                         else
 582                         {
 583                                 if (this.goalcurrent.bot_pickup)
 584                                 {
 585                                         entity jumppad_wp = this.goalcurrent_prev;
 586                                         navigation_poptouchedgoals(this);
 587                                         if(!this.goalcurrent && jumppad_wp.wp00)
 588                                         {
 589                                                 // head to the jumppad destination once bot reaches the goal item
 590                                                 navigation_pushroute(this, jumppad_wp.wp00);
 591                                         }
 592                                 }
 593                                 gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 594                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 595                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 596                                 else if(havocbot_checkgoaldistance(this, gco))
 597                                 {
 598                                         navigation_clearroute(this);
 599                                         navigation_goalrating_timeout_force(this);
 600                                 }
 601                                 else
 602                                         return;
 603                         }
 604                 }
 605                 else
 606                 {
 607                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 608                         {
 609                                 vector velxy = this.velocity; velxy_z = 0;
 610                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 611                                 {
 612                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 613                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 614                                 }
 615                                 return;
 616                         }
 617
 618                         // Don't chase players while using a jump pad
 619                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 620                                 return;
 621                 }
 622         }
 623         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 624                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 625
 626         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 627         if (skill > 6 && !(IS_ONGROUND(this)))
 628         {
 629                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 630                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 631                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 632
 633                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 634                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 635                 if(this.items & IT_JETPACK)
 636                 {
 637                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 638                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 639                         {
 640                                 if(this.velocity.z<0)
 641                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 642                         }
 643                         else
 644                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 645
 646                         // If there is no goal try to move forward
 647
 648                         if(this.goalcurrent==NULL)
 649                                 dir = v_forward;
 650                         else
 651                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 652
 653                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 654                         float xyspeed = xyvelocity * dir;
 655
 656                         if(xyspeed < (maxspeed / 2))
 657                         {
 658                                 makevectors(this.v_angle.y * '0 1 0');
 659                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 660                                 if(trace_fraction==1)
 661                                 {
 662                                         CS(this).movement_x = dir * v_forward * maxspeed;
 663                                         CS(this).movement_y = dir * v_right * maxspeed;
 664                                         if (skill < 10)
 665                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 666                                 }
 667                         }
 668
 669                         this.havocbot_blockhead = true;
 670
 671                         return;
 672                 }
 673                 else if(this.health + this.armorvalue > ROCKETJUMP_DAMAGE())
 674                 {
 675                         if(this.velocity.z < 0)
 676                         {
 677                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 678                                 {
 679                                         .entity weaponentity = weaponentities[slot];
 680
 681                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 682                                                 continue;
 683
 684                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 685                                         {
 686                                                 CS(this).movement_x = maxspeed;
 687
 688                                                 if(this.rocketjumptime)
 689                                                 {
 690                                                         if(time > this.rocketjumptime)
 691                                                         {
 692                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 693                                                                 this.rocketjumptime = 0;
 694                                                         }
 695                                                         return;
 696                                                 }
 697
 698                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 699                                                 this.v_angle_x = 90;
 700                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 701                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 702                                                 return;
 703                                         }
 704                                 }
 705                         }
 706                 }
 707                 else
 708                 {
 709                         // If there is no goal try to move forward
 710                         if(this.goalcurrent==NULL)
 711                                 CS(this).movement_x = maxspeed;
 712                 }
 713         }
 714
 715         // If we are under water with no goals, swim up
 716         if(this.waterlevel)
 717         if(this.goalcurrent==NULL)
 718         {
 719                 dir = '0 0 0';
 720                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 721                         dir.z = 1;
 722                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 723                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 724                 else
 725                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 726                 makevectors(this.v_angle.y * '0 1 0');
 727                 CS(this).movement_x = dir * v_forward * maxspeed;
 728                 CS(this).movement_y = dir * v_right * maxspeed;
 729                 CS(this).movement_z = dir * v_up * maxspeed;
 730         }
 731
 732         // if there is nowhere to go, exit
 733         if (this.goalcurrent == NULL)
 734                 return;
 735
 736
 737         bool locked_goal = false;
 738         if(this.goalentity && wasfreed(this.goalentity))
 739         {
 740                 navigation_clearroute(this);
 741                 navigation_goalrating_timeout_force(this);
 742                 return;
 743         }
 744         else if(this.goalentity.bot_pickup)
 745         {
 746                 if(this.goalentity.bot_pickup_respawning)
 747                 {
 748                         if(this.goalentity.solid) // item respawned
 749                                 this.goalentity.bot_pickup_respawning = false;
 750                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 751                         {
 752                                 if(checkpvs(this.origin, this.goalentity))
 753                                 {
 754                                         this.goalentity.bot_pickup_respawning = false;
 755                                         navigation_clearroute(this);
 756                                         navigation_goalrating_timeout_force(this);
 757                                         return;
 758                                 }
 759                                 locked_goal = true; // wait for item to respawn
 760                         }
 761                         else if(this.goalentity == this.goalcurrent)
 762                                 locked_goal = true; // wait for item to respawn
 763                 }
 764                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 765                 {
 766                         if(checkpvs(this.origin, this.goalentity))
 767                         {
 768                                 navigation_clearroute(this);
 769                                 navigation_goalrating_timeout_force(this);
 770                                 return;
 771                         }
 772                 }
 773         }
 774         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 775                 locked_goal = true;
 776
 777         if(!locked_goal)
 778         {
 779                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 780                 // in this case path finding can start directly from a waypoint instead of
 781                 // looking for all the reachable waypoints up to a certain distance
 782                 if(navigation_poptouchedgoals(this) && this.goalcurrent)
 783                 {
 784                         if(navigation_goalrating_timeout_can_be_anticipated(this))
 785                                 navigation_goalrating_timeout_force(this);
 786                 }
 787         }
 788
 789         // if ran out of goals try to use an alternative goal or get a new strategy asap
 790         if(this.goalcurrent == NULL)
 791         {
 792                 navigation_goalrating_timeout_force(this);
 793                 return;
 794         }
 795
 796
 797         if(autocvar_bot_debug_goalstack)
 798                 debuggoalstack(this);
 799
 800         bool bunnyhop_forbidden = false;;
 801         SET_DESTCOORDS(this.goalcurrent, this.origin, destorg);
 802
 803         // in case bot ends up inside the teleport waypoint without touching
 804         // the teleport itself, head to the teleport origin
 805         if(this.goalcurrent.wpisbox && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z))
 806         {
 807                 bunnyhop_forbidden = true;
 808                 destorg = this.goalcurrent.origin;
 809                 if(destorg.z > this.origin.z)
 810                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 811         }
 812
 813         diff = destorg - this.origin;
 814
 815         if (fabs(diff.x) < 10 && fabs(diff.y) < 10
 816                 && this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout)
 817         {
 818                 destorg = this.origin;
 819                 diff.x = 0;
 820                 diff.y = 0;
 821         }
 822
 823         dir = normalize(diff);
 824         flatdir = diff;flatdir.z = 0;
 825         flatdir = normalize(flatdir);
 826         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 827
 828         //if (this.bot_dodgevector_time < time)
 829         {
 830                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 831                 //this.bot_dodgevector_jumpbutton = 1;
 832                 evadeobstacle = '0 0 0';
 833                 evadelava = '0 0 0';
 834
 835                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 836                 makevectors(this.v_angle.y * '0 1 0');
 837                 if (this.waterlevel)
 838                 {
 839                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 840                         {
 841                                 if(!this.goalcurrent)
 842                                         this.aistatus |= AI_STATUS_OUT_WATER;
 843                                 else if(gco.z > this.origin.z)
 844                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 845                         }
 846                         else
 847                         {
 848                                 dir = flatdir;
 849                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && gco.z < this.origin.z) &&
 850                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 851                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 852                                 else
 853                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 854                         }
 855                 }
 856                 else
 857                 {
 858                         float s;
 859                         vector offset;
 860                         if(this.aistatus & AI_STATUS_OUT_WATER)
 861                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 862
 863                         // jump if going toward an obstacle that doesn't look like stairs we
 864                         // can walk up directly
 865                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
 866                         tracebox(this.origin, this.mins, this.maxs, this.origin + offset, false, this);
 867                         if (trace_fraction < 1)
 868                         if (trace_plane_normal.z < 0.7)
 869                         {
 870                                 s = trace_fraction;
 871                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, this.origin + offset + stepheightvec, false, this);
 872                                 if (trace_fraction < s + 0.01)
 873                                 if (trace_plane_normal.z < 0.7)
 874                                 {
 875                                         s = trace_fraction;
 876                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, this.origin + offset + jumpstepheightvec, false, this);
 877                                         if (trace_fraction > s)
 878                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 879                                 }
 880                         }
 881
 882                         // if bot for some reason doesn't get close to the current goal find another one
 883                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
 884                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
 885                         if(havocbot_checkgoaldistance(this, gco))
 886                         {
 887                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
 888                                 {
 889                                         navigation_clearroute(this);
 890                                         navigation_goalrating_timeout_force(this);
 891                                         return;
 892                                 }
 893
 894                                 vector dest = '0 0 0';
 895                                 float dest_height = 0;
 896                                 SET_TRACEWALK_DESTCOORDS(this.goalcurrent, this.origin, dest, dest_height);
 897                                 if (!tracewalk(this, this.origin, this.mins, this.maxs, dest, dest_height, bot_navigation_movemode))
 898                                 {
 899                                         navigation_clearroute(this);
 900                                         navigation_goalrating_timeout_force(this);
 901                                         return;
 902                                 }
 903
 904                                 // give bot only another chance to prevent bot getting stuck
 905                                 // in case it thinks it can walk but actually can't
 906                                 this.goalcurrent_distance_z = FLOAT_MAX;
 907                                 this.goalcurrent_distance_2d = FLOAT_MAX;
 908                                 this.goalcurrent_distance_time = -time; // mark second try
 909                         }
 910
 911                         // Check for water/slime/lava and dangerous edges
 912                         // (only when the bot is on the ground or jumping intentionally)
 913
 914                         vector dst_ahead = this.origin + this.view_ofs + offset;
 915                         vector dst_down = dst_ahead - '0 0 3000';
 916                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 917
 918                         bool unreachable = false;
 919                         s = CONTENT_SOLID;
 920                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 921                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
 922                         {
 923                                 // Look downwards
 924                                 traceline(dst_ahead , dst_down, true, NULL);
 925                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
 926                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
 927                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 928                                 {
 929                                         s = pointcontents(trace_endpos + '0 0 1');
 930                                         if (s != CONTENT_SOLID)
 931                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 932                                                 evadelava = normalize(this.velocity) * -1;
 933                                         else if (s == CONTENT_SKY)
 934                                                 evadeobstacle = normalize(this.velocity) * -1;
 935                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 936                                         {
 937                                                 // the traceline check isn't enough but is good as optimization,
 938                                                 // when not true (most of the time) this tracebox call is avoided
 939                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
 940                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 941                                                 {
 942                                                         if (gco.z > this.origin.z + jumpstepheightvec.z)
 943                                                         {
 944                                                                 // the goal is probably on an upper platform, assume bot can't get there
 945                                                                 unreachable = true;
 946                                                         }
 947                                                         else
 948                                                                 evadelava = normalize(this.velocity) * -1;
 949                                                 }
 950                                         }
 951                                 }
 952                         }
 953
 954                         dir = flatdir;
 955                         evadeobstacle.z = 0;
 956                         evadelava.z = 0;
 957                         makevectors(this.v_angle.y * '0 1 0');
 958
 959                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
 960                         {
 961                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
 962                                 if(IS_PLAYER(this.goalcurrent))
 963                                         unreachable = true;
 964                         }
 965                         if(unreachable)
 966                         {
 967                                 navigation_clearroute(this);
 968                                 navigation_goalrating_timeout_force(this);
 969                         }
 970                 }
 971
 972                 dodge = havocbot_dodge(this);
 973                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
 974                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 975                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
 976                 if(IS_PLAYER(trace_ent))
 977                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
 978
 979                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 980         //      this.bot_dodgevector = dir;
 981         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
 982         }
 983
 984         if(time < this.ladder_time)
 985         {
 986                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
 987                 {
 988                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
 989                                 dir.z = 1;
 990                 }
 991                 else
 992                 {
 993                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
 994                                 dir.z = -1;
 995                 }
 996         }
 997
 998         //dir = this.bot_dodgevector;
 999         //if (this.bot_dodgevector_jumpbutton)
1000         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1001         CS(this).movement_x = dir * v_forward * maxspeed;
1002         CS(this).movement_y = dir * v_right * maxspeed;
1003         CS(this).movement_z = dir * v_up * maxspeed;
1004
1005         // Emulate keyboard interface
1006         if (skill < 10)
1007                 havocbot_keyboard_movement(this, destorg);
1008
1009         // Bunnyhop!
1010         //if(this.aistatus & AI_STATUS_ROAMING)
1011         if(!bunnyhop_forbidden && this.goalcurrent)
1012         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1013                 havocbot_bunnyhop(this, dir);
1014
1015         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1016         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1017         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1018 }
1019
1020 entity havocbot_gettarget(entity this, bool secondary)
1021 {
1022         entity best = NULL;
1023         vector eye = CENTER_OR_VIEWOFS(this);
1024         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1025         {
1026                 vector v = CENTER_OR_VIEWOFS(it);
1027                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1028                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1029                 if(bot_shouldattack(this, it))
1030                 {
1031                         traceline(eye, v, true, this);
1032                         if (trace_ent == it || trace_fraction >= 1)
1033                                 best = it;
1034                 }
1035         });
1036
1037         return best;
1038 }
1039
1040 void havocbot_chooseenemy(entity this)
1041 {
1042         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1043         {
1044                 this.enemy = NULL;
1045                 return;
1046         }
1047         if (this.enemy)
1048         {
1049                 if (!bot_shouldattack(this, this.enemy))
1050                 {
1051                         // enemy died or something, find a new target
1052                         this.enemy = NULL;
1053                         this.havocbot_chooseenemy_finished = time;
1054                 }
1055                 else if (this.havocbot_stickenemy)
1056                 {
1057                         // tracking last chosen enemy
1058                         // if enemy is visible
1059                         // and not really really far away
1060                         // and we're not severely injured
1061                         // then keep tracking for a half second into the future
1062                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1063                         if (trace_ent == this.enemy || trace_fraction == 1)
1064                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1065                         if (this.health > 30)
1066                         {
1067                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1068                                 this.havocbot_chooseenemy_finished = time + 0.5;
1069                                 return;
1070                         }
1071                         // enemy isn't visible, or is far away, or we're injured severely
1072                         // so stop preferring this enemy
1073                         // (it will still take a half second until a new one is chosen)
1074                         this.havocbot_stickenemy = 0;
1075                 }
1076         }
1077         if (time < this.havocbot_chooseenemy_finished)
1078                 return;
1079         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1080         vector eye = this.origin + this.view_ofs;
1081         entity best = NULL;
1082         float bestrating = 100000000;
1083
1084         // Backup hit flags
1085         int hf = this.dphitcontentsmask;
1086
1087         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1088
1089         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1090
1091         bool scan_transparent = false;
1092         bool scan_secondary_targets = false;
1093         bool have_secondary_targets = false;
1094         while(true)
1095         {
1096                 scan_secondary_targets = false;
1097 LABEL(scan_targets)
1098                 IL_EACH(g_bot_targets, it.bot_attack,
1099                 {
1100                         if(!scan_secondary_targets)
1101                         {
1102                                 if(it.classname == "misc_breakablemodel")
1103                                 {
1104                                         have_secondary_targets = true;
1105                                         continue;
1106                                 }
1107                         }
1108                         else if(it.classname != "misc_breakablemodel")
1109                                 continue;
1110
1111                         vector v = (it.absmin + it.absmax) * 0.5;
1112                         float rating = vlen2(v - eye);
1113                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1114                         if (bestrating > rating)
1115                         if (bot_shouldattack(this, it))
1116                         {
1117                                 traceline(eye, v, true, this);
1118                                 if (trace_ent == it || trace_fraction >= 1)
1119                                 {
1120                                         best = it;
1121                                         bestrating = rating;
1122                                 }
1123                         }
1124                 });
1125
1126                 if(!best && have_secondary_targets && !scan_secondary_targets)
1127                 {
1128                         scan_secondary_targets = true;
1129                         // restart the loop
1130                         bestrating = 100000000;
1131                         goto scan_targets;
1132                 }
1133
1134                 // I want to do a second scan if no enemy was found or I don't have weapons
1135                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1136                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
1137                         break;
1138                 if(scan_transparent)
1139                         break;
1140
1141                 // Set flags to see through transparent objects
1142                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1143
1144                 scan_transparent = true;
1145         }
1146
1147         // Restore hit flags
1148         this.dphitcontentsmask = hf;
1149
1150         this.enemy = best;
1151         this.havocbot_stickenemy = true;
1152         if(best && best.classname == "misc_breakablemodel")
1153                 this.havocbot_stickenemy = false;
1154 }
1155
1156 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1157 {
1158         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1159         // so skip this for them, or they'll never get to reload their weapons at all.
1160         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1161         if(skill < 5)
1162                 return false;
1163
1164         // if this weapon is scheduled for reloading, don't switch to it during combat
1165         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1166         {
1167                 FOREACH(Weapons, it != WEP_Null, {
1168                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1169                                 return true; // other weapon available
1170                 });
1171         }
1172
1173         return false;
1174 }
1175
1176 void havocbot_chooseweapon(entity this, .entity weaponentity)
1177 {
1178         int i;
1179
1180         // ;)
1181         if(g_weaponarena_weapons == WEPSET(TUBA))
1182         {
1183                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1184                 return;
1185         }
1186
1187         // TODO: clean this up by moving it to weapon code
1188         if(this.enemy==NULL)
1189         {
1190                 // If no weapon was chosen get the first available weapon
1191                 if(this.(weaponentity).m_weapon==WEP_Null)
1192                 FOREACH(Weapons, it != WEP_Null, {
1193                         if(client_hasweapon(this, it, weaponentity, true, false))
1194                         {
1195                                 this.(weaponentity).m_switchweapon = it;
1196                                 return;
1197                         }
1198                 });
1199                 return;
1200         }
1201
1202         // Do not change weapon during the next second after a combo
1203         float f = time - this.lastcombotime;
1204         if(f < 1)
1205                 return;
1206
1207         float w;
1208         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1209
1210         // Should it do a weapon combo?
1211         float af, ct, combo_time, combo;
1212
1213         af = ATTACK_FINISHED(this, 0);
1214         ct = autocvar_bot_ai_weapon_combo_threshold;
1215
1216         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1217         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1218         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1219
1220         combo = false;
1221
1222         if(autocvar_bot_ai_weapon_combo)
1223         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1224         if(af > combo_time)
1225         {
1226                 combo = true;
1227                 this.lastcombotime = time;
1228         }
1229
1230         distance *= (2 ** this.bot_rangepreference);
1231
1232         // Custom weapon list based on distance to the enemy
1233         if(bot_custom_weapon){
1234
1235                 // Choose weapons for far distance
1236                 if ( distance > bot_distance_far ) {
1237                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1238                                 w = bot_weapons_far[i];
1239                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1240                                 {
1241                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1242                                                 continue;
1243                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1244                                         return;
1245                                 }
1246                         }
1247                 }
1248
1249                 // Choose weapons for mid distance
1250                 if ( distance > bot_distance_close) {
1251                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1252                                 w = bot_weapons_mid[i];
1253                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1254                                 {
1255                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1256                                                 continue;
1257                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1258                                         return;
1259                                 }
1260                         }
1261                 }
1262
1263                 // Choose weapons for close distance
1264                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1265                         w = bot_weapons_close[i];
1266                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1267                         {
1268                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1269                                         continue;
1270                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1271                                 return;
1272                         }
1273                 }
1274         }
1275 }
1276
1277 void havocbot_aim(entity this)
1278 {
1279         if (time < this.nextaim)
1280                 return;
1281         this.nextaim = time + 0.1;
1282         vector myvel = this.velocity;
1283         if (!this.waterlevel)
1284                 myvel.z = 0;
1285         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1286         else if (this.enemy)
1287         {
1288                 vector enemyvel = this.enemy.velocity;
1289                 if (!this.enemy.waterlevel)
1290                         enemyvel.z = 0;
1291                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1292         }
1293         else
1294                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1295 }
1296
1297 bool havocbot_moveto_refresh_route(entity this)
1298 {
1299         // Refresh path to goal if necessary
1300         entity wp;
1301         wp = this.havocbot_personal_waypoint;
1302         navigation_goalrating_start(this);
1303         navigation_routerating(this, wp, 10000, 10000);
1304         navigation_goalrating_end(this);
1305         return (this.goalentity != NULL);
1306 }
1307
1308 float havocbot_moveto(entity this, vector pos)
1309 {
1310         entity wp;
1311
1312         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1313         {
1314                 // Step 4: Move to waypoint
1315                 if(this.havocbot_personal_waypoint==NULL)
1316                 {
1317                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1318                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1319                         return CMD_STATUS_ERROR;
1320                 }
1321
1322                 if (!bot_strategytoken_taken)
1323                 if(this.havocbot_personal_waypoint_searchtime<time)
1324                 {
1325                         bot_strategytoken_taken = true;
1326                         if(havocbot_moveto_refresh_route(this))
1327                         {
1328                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1329                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1330                                 this.havocbot_personal_waypoint_failcounter = 0;
1331                         }
1332                         else
1333                         {
1334                                 this.havocbot_personal_waypoint_failcounter += 1;
1335                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1336                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1337                                 {
1338                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1339                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1340                                         delete(this.havocbot_personal_waypoint);
1341                                         return CMD_STATUS_ERROR;
1342                                 }
1343                                 else
1344                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1345                         }
1346                 }
1347
1348                 if(autocvar_bot_debug_goalstack)
1349                         debuggoalstack(this);
1350
1351                 // Heading
1352                 vector dir = '0 0 0';
1353                 SET_DESTCOORDS(this.goalcurrent, this.origin, dir);
1354                 dir = dir - (this.origin + this.view_ofs);
1355                 dir.z = 0;
1356                 bot_aimdir(this, dir, -1);
1357
1358                 // Go!
1359                 havocbot_movetogoal(this);
1360
1361                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1362                 {
1363                         // Step 5: Waypoint reached
1364                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1365                         delete(this.havocbot_personal_waypoint);
1366                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1367                         return CMD_STATUS_FINISHED;
1368                 }
1369
1370                 return CMD_STATUS_EXECUTING;
1371         }
1372
1373         // Step 2: Linking waypoint
1374         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1375         {
1376                 // Wait until it is linked
1377                 if(!this.havocbot_personal_waypoint.wplinked)
1378                 {
1379                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1380                         return CMD_STATUS_EXECUTING;
1381                 }
1382
1383                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1384                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1385                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1386
1387                 // Step 3: Route to waypoint
1388                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1389
1390                 return CMD_STATUS_EXECUTING;
1391         }
1392
1393         // Step 1: Spawning waypoint
1394         wp = waypoint_spawnpersonal(this, pos);
1395         if(wp==NULL)
1396         {
1397                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1398                 return CMD_STATUS_ERROR;
1399         }
1400
1401         this.havocbot_personal_waypoint = wp;
1402         this.havocbot_personal_waypoint_failcounter = 0;
1403         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1404
1405         // if pos is inside a teleport, then let's mark it as teleport waypoint
1406         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1407         {
1408                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1409                 this.lastteleporttime = 0;
1410         });
1411
1412 /*
1413         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1414                 print("routing to a teleporter\n");
1415         else
1416                 print("routing to a non-teleporter\n");
1417 */
1418
1419         return CMD_STATUS_EXECUTING;
1420 }
1421
1422 float havocbot_resetgoal(entity this)
1423 {
1424         navigation_clearroute(this);
1425         return CMD_STATUS_FINISHED;
1426 }
1427
1428 void havocbot_setupbot(entity this)
1429 {
1430         this.bot_ai = havocbot_ai;
1431         this.cmd_moveto = havocbot_moveto;
1432         this.cmd_resetgoal = havocbot_resetgoal;
1433
1434         havocbot_chooserole(this);
1435 }
1436
1437 vector havocbot_dodge(entity this)
1438 {
1439         // LordHavoc: disabled because this is too expensive
1440         return '0 0 0';
1441 #if 0
1442         entity head;
1443         vector dodge, v, n;
1444         float danger, bestdanger, vl, d;
1445         dodge = '0 0 0';
1446         bestdanger = -20;
1447         // check for dangerous objects near bot or approaching bot
1448         head = findchainfloat(bot_dodge, true);
1449         while(head)
1450         {
1451                 if (head.owner != this)
1452                 {
1453                         vl = vlen(head.velocity);
1454                         if (vl > autocvar_sv_maxspeed * 0.3)
1455                         {
1456                                 n = normalize(head.velocity);
1457                                 v = this.origin - head.origin;
1458                                 d = v * n;
1459                                 if (d > (0 - head.bot_dodgerating))
1460                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1461                                 {
1462                                         // calculate direction and distance from the flight path, by removing the forward axis
1463                                         v = v - (n * (v * n));
1464                                         danger = head.bot_dodgerating - vlen(v);
1465                                         if (bestdanger < danger)
1466                                         {
1467                                                 bestdanger = danger;
1468                                                 // dodge to the side of the object
1469                                                 dodge = normalize(v);
1470                                         }
1471                                 }
1472                         }
1473                         else
1474                         {
1475                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1476                                 if (bestdanger < danger)
1477                                 {
1478                                         bestdanger = danger;
1479                                         dodge = normalize(this.origin - head.origin);
1480                                 }
1481                         }
1482                 }
1483                 head = head.chain;
1484         }
1485         return dodge;
1486 #endif
1487 }