qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/triggers/teleporters.qh>
  22 #include <common/triggers/trigger/jumppads.qh>
  23
  24 #include <lib/warpzone/common.qh>
  25
  26 .float speed;
  27
  28 void havocbot_ai(entity this)
  29 {
  30         if(this.draggedby)
  31                 return;
  32
  33         if(bot_execute_commands(this))
  34                 return;
  35
  36         if (bot_strategytoken == this && !bot_strategytoken_taken)
  37         {
  38                 if(this.havocbot_blockhead)
  39                 {
  40                         this.havocbot_blockhead = false;
  41                 }
  42                 else
  43                 {
  44                         if (!this.jumppadcount && !STAT(FROZEN, this))
  45                                 this.havocbot_role(this); // little too far down the rabbit hole
  46                 }
  47
  48                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  49                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  50                 if(!this.goalcurrent)
  51                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  52                 {
  53                         // Look for the closest waypoint out of water
  54                         entity newgoal = NULL;
  55                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  56                         {
  57                                 if(it.origin.z < this.origin.z)
  58                                         continue;
  59
  60                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  61                                         continue;
  62
  63                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  64                                         continue;
  65
  66                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  67
  68                                 if(trace_fraction < 1)
  69                                         continue;
  70
  71                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  72                                         newgoal = it;
  73                         });
  74
  75                         if(newgoal)
  76                         {
  77                         //      te_wizspike(newgoal.origin);
  78                                 navigation_pushroute(this, newgoal);
  79                         }
  80                 }
  81
  82                 // token has been used this frame
  83                 bot_strategytoken_taken = true;
  84         }
  85
  86         if(IS_DEAD(this) || STAT(FROZEN, this))
  87         {
  88                 if (this.goalcurrent)
  89                         navigation_clearroute(this);
  90                 return;
  91         }
  92
  93         havocbot_chooseenemy(this);
  94
  95         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  96         {
  97                 .entity weaponentity = weaponentities[slot];
  98                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  99                 if(this.(weaponentity).bot_chooseweapontime < time)
 100                 {
 101                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 102                         havocbot_chooseweapon(this, weaponentity);
 103                 }
 104         }
 105         havocbot_aim(this);
 106         lag_update(this);
 107         if (this.bot_aimtarg)
 108         {
 109                 this.aistatus |= AI_STATUS_ATTACKING;
 110                 this.aistatus &= ~AI_STATUS_ROAMING;
 111
 112                 if(this.weapons)
 113                 {
 114                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 115                         {
 116                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 117                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 118                         }
 119                         else
 120                         {
 121                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 122                                 {
 123                                         .entity weaponentity = weaponentities[slot];
 124                                         Weapon w = this.(weaponentity).m_weapon;
 125                                         if(w == WEP_Null && slot != 0)
 126                                                 continue;
 127                                         w.wr_aim(w, this, weaponentity);
 128                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 129                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 130                                 }
 131                         }
 132                 }
 133                 else
 134                 {
 135                         if(IS_PLAYER(this.bot_aimtarg))
 136                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 137                 }
 138         }
 139         else if (this.goalcurrent)
 140         {
 141                 this.aistatus |= AI_STATUS_ROAMING;
 142                 this.aistatus &= ~AI_STATUS_ATTACKING;
 143
 144                 vector now, next;
 145                 float aimdistance,skillblend,distanceblend,blend;
 146
 147                 vector v = get_closer_dest(this.goalcurrent, this.origin);
 148                 if(this.goalcurrent.wpisbox)
 149                 {
 150                         // avoid a glitch when bot is teleported but teleport waypoint isn't removed yet
 151                         if(this.goalstack02 && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT
 152                         && this.lastteleporttime > 0 && time - this.lastteleporttime < 0.15)
 153                                 v = (this.goalstack02.absmin + this.goalstack02.absmax) * 0.5;
 154                         // aim to teleport origin if bot is inside teleport waypoint but hasn't touched the real teleport yet
 155                         else if(boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
 156                                 v = this.goalcurrent.origin;
 157                 }
 158                 next = now = v - (this.origin + this.view_ofs);
 159                 aimdistance = vlen(now);
 160
 161                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 162                 if(
 163                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 164                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 165                 )
 166                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 167
 168                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 169                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 170                 blend = skillblend * (1-distanceblend);
 171                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 172                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 173                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 174                 v = now + blend * (next - now);
 175                 //dprint(etos(this), " ");
 176                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 177                 //v = now * (distanceblend) + next * (1-distanceblend);
 178                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 179                         v.z = 0;
 180                 //dprint("walk at:", vtos(v), "\n");
 181                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 182                 bot_aimdir(this, v, -1);
 183         }
 184         havocbot_movetogoal(this);
 185
 186         // if the bot is not attacking, consider reloading weapons
 187         if (!(this.aistatus & AI_STATUS_ATTACKING))
 188         {
 189                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 190                 {
 191                         .entity weaponentity = weaponentities[slot];
 192
 193                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 194                                 continue;
 195
 196                         // we are currently holding a weapon that's not fully loaded, reload it
 197                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 198                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 199                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 200
 201                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 202                         // the code above executes next frame, starting the reloading then
 203                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 204                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 205                         {
 206                                 FOREACH(Weapons, it != WEP_Null, {
 207                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 208                                         {
 209                                                 this.(weaponentity).m_switchweapon = it;
 210                                                 break;
 211                                         }
 212                                 });
 213                         }
 214                 }
 215         }
 216 }
 217
 218 void havocbot_keyboard_movement(entity this, vector destorg)
 219 {
 220         vector keyboard;
 221
 222         if (time > this.havocbot_keyboardtime)
 223         {
 224                 float sk = skill + this.bot_moveskill;
 225                 this.havocbot_keyboardtime =
 226                         max(
 227                                 this.havocbot_keyboardtime
 228                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 229                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 230                         , time);
 231                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 232
 233                 float trigger = autocvar_bot_ai_keyboard_threshold;
 234                 float trigger1 = -trigger;
 235
 236                 // categorize forward movement
 237                 // at skill < 1.5 only forward
 238                 // at skill < 2.5 only individual directions
 239                 // at skill < 4.5 only individual directions, and forward diagonals
 240                 // at skill >= 4.5, all cases allowed
 241                 if (keyboard.x > trigger)
 242                 {
 243                         keyboard.x = 1;
 244                         if (sk < 2.5)
 245                                 keyboard.y = 0;
 246                 }
 247                 else if (keyboard.x < trigger1 && sk > 1.5)
 248                 {
 249                         keyboard.x = -1;
 250                         if (sk < 4.5)
 251                                 keyboard.y = 0;
 252                 }
 253                 else
 254                 {
 255                         keyboard.x = 0;
 256                         if (sk < 1.5)
 257                                 keyboard.y = 0;
 258                 }
 259                 if (sk < 4.5)
 260                         keyboard.z = 0;
 261
 262                 if (keyboard.y > trigger)
 263                         keyboard.y = 1;
 264                 else if (keyboard.y < trigger1)
 265                         keyboard.y = -1;
 266                 else
 267                         keyboard.y = 0;
 268
 269                 if (keyboard.z > trigger)
 270                         keyboard.z = 1;
 271                 else if (keyboard.z < trigger1)
 272                         keyboard.z = -1;
 273                 else
 274                         keyboard.z = 0;
 275
 276                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 277                 if (this.havocbot_ducktime > time)
 278                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 279         }
 280
 281         keyboard = this.havocbot_keyboard;
 282         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 283         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 284         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 285 }
 286
 287 void havocbot_bunnyhop(entity this, vector dir)
 288 {
 289         float bunnyhopdistance;
 290         vector deviation;
 291         float maxspeed;
 292
 293         // Don't jump when attacking
 294         if(this.aistatus & AI_STATUS_ATTACKING)
 295                 return;
 296
 297         if(IS_PLAYER(this.goalcurrent))
 298                 return;
 299
 300         maxspeed = autocvar_sv_maxspeed;
 301
 302         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 303                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 304         {
 305                 this.aistatus &= ~AI_STATUS_RUNNING;
 306                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 307                 this.bot_canruntogoal = 0;
 308                 this.bot_timelastseengoal = 0;
 309                 return;
 310         }
 311
 312         if(this.waterlevel > WATERLEVEL_WETFEET)
 313         {
 314                 this.aistatus &= ~AI_STATUS_RUNNING;
 315                 return;
 316         }
 317
 318         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 319         {
 320                 this.bot_canruntogoal = 0;
 321                 this.bot_timelastseengoal = 0;
 322         }
 323
 324         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 325         bunnyhopdistance = vlen(this.origin - gco);
 326
 327         // Run only to visible goals
 328         if(IS_ONGROUND(this))
 329         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 330         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 331         {
 332                         this.bot_lastseengoal = this.goalcurrent;
 333
 334                         // seen it before
 335                         if(this.bot_timelastseengoal)
 336                         {
 337                                 // for a period of time
 338                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 339                                 {
 340                                         float checkdistance;
 341                                         checkdistance = true;
 342
 343                                         // don't run if it is too close
 344                                         if(this.bot_canruntogoal==0)
 345                                         {
 346                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 347                                                         this.bot_canruntogoal = 1;
 348                                                 else
 349                                                         this.bot_canruntogoal = -1;
 350                                         }
 351
 352                                         if(this.bot_canruntogoal != 1)
 353                                                 return;
 354
 355                                         if(this.aistatus & AI_STATUS_ROAMING)
 356                                         if(this.goalcurrent.classname=="waypoint")
 357                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 358                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 359                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 360                                         {
 361                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 362                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 363                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 364                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 365
 366                                                 if(fabs(deviation.y) < 20)
 367                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 368                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 369                                                 {
 370                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 371                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 372                                                         {
 373                                                                 checkdistance = false;
 374                                                         }
 375                                                 }
 376                                         }
 377
 378                                         if(checkdistance)
 379                                         {
 380                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 381                                                 // increase stop distance in case the goal is on a slope or a lower platform
 382                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 383                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 384                                         }
 385                                         else
 386                                         {
 387                                                 this.aistatus |= AI_STATUS_RUNNING;
 388                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 389                                         }
 390                                 }
 391                         }
 392                         else
 393                         {
 394                                 this.bot_timelastseengoal = time;
 395                         }
 396         }
 397         else
 398         {
 399                 this.bot_timelastseengoal = 0;
 400         }
 401
 402 #if 0
 403         // Release jump button
 404         if(!cvar("sv_pogostick"))
 405         if((IS_ONGROUND(this)) == 0)
 406         {
 407                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 408                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 409
 410                 // Strafe
 411                 if(this.aistatus & AI_STATUS_RUNNING)
 412                 if(vlen(this.velocity)>maxspeed)
 413                 {
 414                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 415                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 416                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 417
 418                         if(fabs(deviation.y)>10)
 419                                 CS(this).movement_x = 0;
 420
 421                         if(deviation.y>10)
 422                                 CS(this).movement_y = maxspeed * -1;
 423                         else if(deviation.y<10)
 424                                 CS(this).movement_y = maxspeed;
 425
 426                 }
 427         }
 428 #endif
 429 }
 430
 431 // return true when bot isn't getting closer to the current goal
 432 bool havocbot_checkgoaldistance(entity this, vector gco)
 433 {
 434         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 435         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 436         float distance_time = this.goalcurrent_distance_time;
 437         if(distance_time < 0)
 438                 distance_time = -distance_time;
 439         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 440         {
 441                 if(!distance_time)
 442                         this.goalcurrent_distance_time = time;
 443                 else if (time - distance_time > 0.5)
 444                         return true;
 445         }
 446         else
 447         {
 448                 // reduce it a little bit so it works even with very small approaches to the goal
 449                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 450                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 451                 this.goalcurrent_distance_time = 0;
 452         }
 453         return false;
 454 }
 455
 456 void havocbot_movetogoal(entity this)
 457 {
 458         vector diff;
 459         vector dir;
 460         vector flatdir;
 461         vector evadeobstacle;
 462         vector evadelava;
 463         float maxspeed;
 464         //float dist;
 465         vector dodge;
 466         //if (this.goalentity)
 467         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 468         CS(this).movement = '0 0 0';
 469         maxspeed = autocvar_sv_maxspeed;
 470
 471         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 472         // Jetpack navigation
 473         if(this.navigation_jetpack_goal)
 474         if(this.goalcurrent==this.navigation_jetpack_goal)
 475         if(this.ammo_fuel)
 476         {
 477                 if(autocvar_bot_debug_goalstack)
 478                 {
 479                         debuggoalstack(this);
 480                         te_wizspike(this.navigation_jetpack_point);
 481                 }
 482
 483                 // Take off
 484                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 485                 {
 486                         // Brake almost completely so it can get a good direction
 487                         if(vdist(this.velocity, >, 10))
 488                                 return;
 489                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 490                 }
 491
 492                 makevectors(this.v_angle.y * '0 1 0');
 493                 dir = normalize(this.navigation_jetpack_point - this.origin);
 494
 495                 // Landing
 496                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 497                 {
 498                         // Calculate brake distance in xy
 499                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 500                         float v = vlen(vec2(this.velocity));
 501                         float db = ((v ** 2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 502                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 503                         if(d < db || d < 500)
 504                         {
 505                                 // Brake
 506                                 if(v > maxspeed * 0.3)
 507                                 {
 508                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 509                                         return;
 510                                 }
 511                                 // Switch to normal mode
 512                                 this.navigation_jetpack_goal = NULL;
 513                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 514                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 515                                 return;
 516                         }
 517                 }
 518                 else if(checkpvs(this.origin,this.goalcurrent))
 519                 {
 520                         // If I can see the goal switch to landing code
 521                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 522                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 523                         return;
 524                 }
 525
 526                 // Flying
 527                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 528                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 529                 {
 530                         CS(this).movement_x = dir * v_forward * maxspeed;
 531                         CS(this).movement_y = dir * v_right * maxspeed;
 532                 }
 533                 return;
 534         }
 535
 536         // Handling of jump pads
 537         if(this.jumppadcount)
 538         {
 539                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 540                 {
 541                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 542                         navigation_poptouchedgoals(this);
 543                         return;
 544                 }
 545                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 546                 {
 547                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 548                         // but with some randomness so it can try out different paths
 549                         if(!this.goalcurrent)
 550                         {
 551                                 entity newgoal = NULL;
 552                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 553                                 {
 554                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 555                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 556                                                 continue;
 557
 558                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 559
 560                                         if(trace_fraction < 1)
 561                                                 continue;
 562
 563                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 564                                                 newgoal = it;
 565                                 });
 566
 567                                 if(newgoal)
 568                                 {
 569                                         this.ignoregoal = this.goalcurrent;
 570                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 571                                         navigation_clearroute(this);
 572                                         navigation_routetogoal(this, newgoal, this.origin);
 573                                         if(autocvar_bot_debug_goalstack)
 574                                                 debuggoalstack(this);
 575                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 576                                 }
 577                         }
 578                         else
 579                         {
 580                                 if (this.goalcurrent.bot_pickup)
 581                                 {
 582                                         entity jumppad_wp = this.goalcurrent_prev;
 583                                         navigation_poptouchedgoals(this);
 584                                         if(!this.goalcurrent && jumppad_wp.wp00)
 585                                         {
 586                                                 // head to the jumppad destination once bot reaches the goal item
 587                                                 navigation_pushroute(this, jumppad_wp.wp00);
 588                                         }
 589                                 }
 590                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 591                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 592                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 593                                 else if(havocbot_checkgoaldistance(this, gco))
 594                                 {
 595                                         navigation_clearroute(this);
 596                                         navigation_goalrating_timeout_force(this);
 597                                 }
 598                                 else
 599                                         return;
 600                         }
 601                 }
 602                 else
 603                 {
 604                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 605                         {
 606                                 vector velxy = this.velocity; velxy_z = 0;
 607                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 608                                 {
 609                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 610                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 611                                 }
 612                                 return;
 613                         }
 614
 615                         // Don't chase players while using a jump pad
 616                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 617                                 return;
 618                 }
 619         }
 620         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 621                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 622
 623         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 624         if (skill > 6 && !(IS_ONGROUND(this)))
 625         {
 626                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 627                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 628                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 629
 630                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 631                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 632                 if(this.items & IT_JETPACK)
 633                 {
 634                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 635                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 636                         {
 637                                 if(this.velocity.z<0)
 638                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 639                         }
 640                         else
 641                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 642
 643                         // If there is no goal try to move forward
 644
 645                         if(this.goalcurrent==NULL)
 646                                 dir = v_forward;
 647                         else
 648                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 649
 650                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 651                         float xyspeed = xyvelocity * dir;
 652
 653                         if(xyspeed < (maxspeed / 2))
 654                         {
 655                                 makevectors(this.v_angle.y * '0 1 0');
 656                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 657                                 if(trace_fraction==1)
 658                                 {
 659                                         CS(this).movement_x = dir * v_forward * maxspeed;
 660                                         CS(this).movement_y = dir * v_right * maxspeed;
 661                                         if (skill < 10)
 662                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 663                                 }
 664                         }
 665
 666                         this.havocbot_blockhead = true;
 667
 668                         return;
 669                 }
 670                 else if(this.health + this.armorvalue > ROCKETJUMP_DAMAGE())
 671                 {
 672                         if(this.velocity.z < 0)
 673                         {
 674                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 675                                 {
 676                                         .entity weaponentity = weaponentities[slot];
 677
 678                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 679                                                 continue;
 680
 681                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 682                                         {
 683                                                 CS(this).movement_x = maxspeed;
 684
 685                                                 if(this.rocketjumptime)
 686                                                 {
 687                                                         if(time > this.rocketjumptime)
 688                                                         {
 689                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 690                                                                 this.rocketjumptime = 0;
 691                                                         }
 692                                                         return;
 693                                                 }
 694
 695                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 696                                                 this.v_angle_x = 90;
 697                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 698                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 699                                                 return;
 700                                         }
 701                                 }
 702                         }
 703                 }
 704                 else
 705                 {
 706                         // If there is no goal try to move forward
 707                         if(this.goalcurrent==NULL)
 708                                 CS(this).movement_x = maxspeed;
 709                 }
 710         }
 711
 712         // If we are under water with no goals, swim up
 713         if(this.waterlevel && !this.goalcurrent)
 714         {
 715                 dir = '0 0 0';
 716                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 717                         dir.z = 1;
 718                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 719                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 720                 else
 721                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 722                 makevectors(this.v_angle.y * '0 1 0');
 723                 CS(this).movement_x = dir * v_forward * maxspeed;
 724                 CS(this).movement_y = dir * v_right * maxspeed;
 725                 CS(this).movement_z = dir * v_up * maxspeed;
 726         }
 727
 728         // if there is nowhere to go, exit
 729         if (this.goalcurrent == NULL)
 730                 return;
 731
 732
 733         bool locked_goal = false;
 734         if((this.goalentity && wasfreed(this.goalentity))
 735                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 736         {
 737                 navigation_clearroute(this);
 738                 navigation_goalrating_timeout_force(this);
 739                 return;
 740         }
 741         else if(this.goalentity.tag_entity)
 742         {
 743                 navigation_goalrating_timeout_expire(this, 2);
 744         }
 745         else if(this.goalentity.bot_pickup)
 746         {
 747                 if(this.goalentity.bot_pickup_respawning)
 748                 {
 749                         if(this.goalentity.solid) // item respawned
 750                                 this.goalentity.bot_pickup_respawning = false;
 751                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 752                         {
 753                                 if(checkpvs(this.origin, this.goalentity))
 754                                 {
 755                                         this.goalentity.bot_pickup_respawning = false;
 756                                         navigation_goalrating_timeout_expire(this, random());
 757                                 }
 758                                 locked_goal = true; // wait for item to respawn
 759                         }
 760                         else if(this.goalentity == this.goalcurrent)
 761                                 locked_goal = true; // wait for item to respawn
 762                 }
 763                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 764                 {
 765                         if(checkpvs(this.origin, this.goalentity))
 766                         {
 767                                 navigation_goalrating_timeout_expire(this, random());
 768                         }
 769                 }
 770         }
 771         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 772                 locked_goal = true;
 773
 774         navigation_shortenpath(this);
 775
 776         if (IS_MOVABLE(this.goalcurrent))
 777         {
 778                 if (IS_DEAD(this.goalcurrent))
 779                 {
 780                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 781                         {
 782                                 navigation_goalrating_timeout_force(this);
 783                                 return;
 784                         }
 785                 }
 786                 else if (this.bot_tracewalk_time < time)
 787                 {
 788                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 789                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 790                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 791                         {
 792                                 navigation_goalrating_timeout_force(this);
 793                                 return;
 794                         }
 795                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 796                 }
 797         }
 798         if(!locked_goal)
 799         {
 800                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 801                 // in this case path finding can start directly from a waypoint instead of
 802                 // looking for all the reachable waypoints up to a certain distance
 803                 if (navigation_poptouchedgoals(this) && this.goalcurrent)
 804                 {
 805                         if (IS_MOVABLE(this.goalcurrent) && IS_DEAD(this.goalcurrent))
 806                         {
 807                                 // remove even if not visible
 808                                 navigation_goalrating_timeout_force(this);
 809                                 return;
 810                         }
 811                         else if (navigation_goalrating_timeout_can_be_anticipated(this))
 812                                 navigation_goalrating_timeout_force(this);
 813                 }
 814         }
 815
 816         // if ran out of goals try to use an alternative goal or get a new strategy asap
 817         if(this.goalcurrent == NULL)
 818         {
 819                 navigation_goalrating_timeout_force(this);
 820                 return;
 821         }
 822
 823
 824         if(autocvar_bot_debug_goalstack)
 825                 debuggoalstack(this);
 826
 827         bool bunnyhop_forbidden = false;
 828         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 829
 830         // in case bot ends up inside the teleport waypoint without touching
 831         // the teleport itself, head to the teleport origin
 832         if(this.goalcurrent.wpisbox && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z))
 833         {
 834                 bunnyhop_forbidden = true;
 835                 destorg = this.goalcurrent.origin;
 836                 if(destorg.z > this.origin.z)
 837                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 838         }
 839
 840         diff = destorg - this.origin;
 841
 842         if (fabs(diff.x) < 10 && fabs(diff.y) < 10
 843                 && this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout)
 844         {
 845                 destorg = this.origin;
 846                 diff.x = 0;
 847                 diff.y = 0;
 848         }
 849
 850         dir = normalize(diff);
 851         flatdir = diff;flatdir.z = 0;
 852         flatdir = normalize(flatdir);
 853
 854         //if (this.bot_dodgevector_time < time)
 855         {
 856                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 857                 //this.bot_dodgevector_jumpbutton = 1;
 858                 evadeobstacle = '0 0 0';
 859                 evadelava = '0 0 0';
 860
 861                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 862                 makevectors(this.v_angle.y * '0 1 0');
 863                 if (this.waterlevel)
 864                 {
 865                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 866                         {
 867                                 if(!this.goalcurrent)
 868                                         this.aistatus |= AI_STATUS_OUT_WATER;
 869                                 else if(destorg.z > this.origin.z)
 870                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 871                         }
 872                         else
 873                         {
 874                                 dir = flatdir;
 875                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 876                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 877                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 878                                 else
 879                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 880                         }
 881                 }
 882                 else
 883                 {
 884                         float s;
 885                         vector offset;
 886                         if(this.aistatus & AI_STATUS_OUT_WATER)
 887                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 888
 889                         // jump if going toward an obstacle that doesn't look like stairs we
 890                         // can walk up directly
 891                         vector deviation = '0 0 0';
 892                         if (this.velocity)
 893                         {
 894                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 895                                 while (deviation.y < -180) deviation.y += 360;
 896                                 while (deviation.y > 180) deviation.y -= 360;
 897                         }
 898                         vector flat_diff = vec2(diff);
 899                         offset = max(32, vlen(vec2(this.velocity)) * cos(deviation.y * DEG2RAD) * 0.2) * flatdir;
 900                         vector actual_destorg = this.origin + offset;
 901                         if (!this.goalstack01 || this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 902                         {
 903                                 if (vlen2(flat_diff) < vlen2(offset))
 904                                 {
 905                                         actual_destorg.x = destorg.x;
 906                                         actual_destorg.y = destorg.y;
 907                                 }
 908                         }
 909                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 910                         {
 911                                 actual_destorg.x = destorg.x;
 912                                 actual_destorg.y = destorg.y;
 913                         }
 914                         else if (vlen2(flat_diff) < vlen2(offset))
 915                         {
 916                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 917                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 918                                 float next_dist = vlen(vec2(this.origin + offset - destorg));
 919                                 actual_destorg = vec2(destorg) + next_dist * next_dir;
 920                                 actual_destorg.z = this.origin.z;
 921                         }
 922
 923                         tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
 924                         if (trace_fraction < 1)
 925                         if (trace_plane_normal.z < 0.7)
 926                         {
 927                                 s = trace_fraction;
 928                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
 929                                 if (trace_fraction < s + 0.01)
 930                                 if (trace_plane_normal.z < 0.7)
 931                                 {
 932                                         s = trace_fraction;
 933                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, actual_destorg + jumpstepheightvec, false, this);
 934                                         if (trace_fraction > s)
 935                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 936                                 }
 937                         }
 938
 939                         // if bot for some reason doesn't get close to the current goal find another one
 940                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
 941                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
 942                         if(havocbot_checkgoaldistance(this, destorg))
 943                         {
 944                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
 945                                 {
 946                                         navigation_clearroute(this);
 947                                         navigation_goalrating_timeout_force(this);
 948                                         return;
 949                                 }
 950
 951                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
 952                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
 953                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 954                                 {
 955                                         navigation_clearroute(this);
 956                                         navigation_goalrating_timeout_force(this);
 957                                         return;
 958                                 }
 959
 960                                 // give bot only another chance to prevent bot getting stuck
 961                                 // in case it thinks it can walk but actually can't
 962                                 this.goalcurrent_distance_z = FLOAT_MAX;
 963                                 this.goalcurrent_distance_2d = FLOAT_MAX;
 964                                 this.goalcurrent_distance_time = -time; // mark second try
 965                         }
 966
 967                         // Check for water/slime/lava and dangerous edges
 968                         // (only when the bot is on the ground or jumping intentionally)
 969
 970                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
 971                         vector dst_ahead = this.origin + this.view_ofs + offset;
 972                         vector dst_down = dst_ahead - '0 0 3000';
 973                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 974
 975                         bool unreachable = false;
 976                         s = CONTENT_SOLID;
 977                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 978                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
 979                         {
 980                                 // Look downwards
 981                                 traceline(dst_ahead , dst_down, true, NULL);
 982                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
 983                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
 984                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 985                                 {
 986                                         s = pointcontents(trace_endpos + '0 0 1');
 987                                         if (s != CONTENT_SOLID)
 988                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 989                                                 evadelava = normalize(this.velocity) * -1;
 990                                         else if (s == CONTENT_SKY)
 991                                                 evadeobstacle = normalize(this.velocity) * -1;
 992                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 993                                         {
 994                                                 // the traceline check isn't enough but is good as optimization,
 995                                                 // when not true (most of the time) this tracebox call is avoided
 996                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
 997                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 998                                                 {
 999                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1000                                                         {
1001                                                                 // the goal is probably on an upper platform, assume bot can't get there
1002                                                                 unreachable = true;
1003                                                         }
1004                                                         else
1005                                                                 evadelava = normalize(this.velocity) * -1;
1006                                                 }
1007                                         }
1008                                 }
1009                         }
1010
1011                         dir = flatdir;
1012                         evadeobstacle.z = 0;
1013                         evadelava.z = 0;
1014                         makevectors(this.v_angle.y * '0 1 0');
1015
1016                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1017                         {
1018                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1019                                 if(IS_PLAYER(this.goalcurrent))
1020                                         unreachable = true;
1021                         }
1022                         if(unreachable)
1023                         {
1024                                 navigation_clearroute(this);
1025                                 navigation_goalrating_timeout_force(this);
1026                                 this.ignoregoal = this.goalcurrent;
1027                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1028                         }
1029                 }
1030
1031                 dodge = havocbot_dodge(this);
1032                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
1033                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1034                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
1035                 if(IS_PLAYER(trace_ent))
1036                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
1037
1038                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
1039         //      this.bot_dodgevector = dir;
1040         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1041         }
1042
1043         if(time < this.ladder_time)
1044         {
1045                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1046                 {
1047                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1048                                 dir.z = 1;
1049                 }
1050                 else
1051                 {
1052                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1053                                 dir.z = -1;
1054                 }
1055         }
1056
1057         //dir = this.bot_dodgevector;
1058         //if (this.bot_dodgevector_jumpbutton)
1059         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1060         CS(this).movement_x = dir * v_forward * maxspeed;
1061         CS(this).movement_y = dir * v_right * maxspeed;
1062         CS(this).movement_z = dir * v_up * maxspeed;
1063
1064         // Emulate keyboard interface
1065         if (skill < 10)
1066                 havocbot_keyboard_movement(this, destorg);
1067
1068         // Bunnyhop!
1069         //if(this.aistatus & AI_STATUS_ROAMING)
1070         if(!bunnyhop_forbidden && this.goalcurrent)
1071         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1072                 havocbot_bunnyhop(this, dir);
1073
1074         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1075         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1076         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1077 }
1078
1079 entity havocbot_gettarget(entity this, bool secondary)
1080 {
1081         entity best = NULL;
1082         vector eye = CENTER_OR_VIEWOFS(this);
1083         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1084         {
1085                 vector v = CENTER_OR_VIEWOFS(it);
1086                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1087                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1088                 if(bot_shouldattack(this, it))
1089                 {
1090                         traceline(eye, v, true, this);
1091                         if (trace_ent == it || trace_fraction >= 1)
1092                                 best = it;
1093                 }
1094         });
1095
1096         return best;
1097 }
1098
1099 void havocbot_chooseenemy(entity this)
1100 {
1101         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1102         {
1103                 this.enemy = NULL;
1104                 return;
1105         }
1106         if (this.enemy)
1107         {
1108                 if (!bot_shouldattack(this, this.enemy))
1109                 {
1110                         // enemy died or something, find a new target
1111                         this.enemy = NULL;
1112                         this.havocbot_chooseenemy_finished = time;
1113                 }
1114                 else if (this.havocbot_stickenemy)
1115                 {
1116                         // tracking last chosen enemy
1117                         // if enemy is visible
1118                         // and not really really far away
1119                         // and we're not severely injured
1120                         // then keep tracking for a half second into the future
1121                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1122                         if (trace_ent == this.enemy || trace_fraction == 1)
1123                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1124                         if (this.health > 30)
1125                         {
1126                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1127                                 this.havocbot_chooseenemy_finished = time + 0.5;
1128                                 return;
1129                         }
1130                         // enemy isn't visible, or is far away, or we're injured severely
1131                         // so stop preferring this enemy
1132                         // (it will still take a half second until a new one is chosen)
1133                         this.havocbot_stickenemy = 0;
1134                 }
1135         }
1136         if (time < this.havocbot_chooseenemy_finished)
1137                 return;
1138         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1139         vector eye = this.origin + this.view_ofs;
1140         entity best = NULL;
1141         float bestrating = 100000000;
1142
1143         // Backup hit flags
1144         int hf = this.dphitcontentsmask;
1145
1146         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1147
1148         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1149
1150         bool scan_transparent = false;
1151         bool scan_secondary_targets = false;
1152         bool have_secondary_targets = false;
1153         while(true)
1154         {
1155                 scan_secondary_targets = false;
1156 LABEL(scan_targets)
1157                 IL_EACH(g_bot_targets, it.bot_attack,
1158                 {
1159                         if(!scan_secondary_targets)
1160                         {
1161                                 if(it.classname == "misc_breakablemodel")
1162                                 {
1163                                         have_secondary_targets = true;
1164                                         continue;
1165                                 }
1166                         }
1167                         else if(it.classname != "misc_breakablemodel")
1168                                 continue;
1169
1170                         vector v = (it.absmin + it.absmax) * 0.5;
1171                         float rating = vlen2(v - eye);
1172                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1173                         if (bestrating > rating)
1174                         if (bot_shouldattack(this, it))
1175                         {
1176                                 traceline(eye, v, true, this);
1177                                 if (trace_ent == it || trace_fraction >= 1)
1178                                 {
1179                                         best = it;
1180                                         bestrating = rating;
1181                                 }
1182                         }
1183                 });
1184
1185                 if(!best && have_secondary_targets && !scan_secondary_targets)
1186                 {
1187                         scan_secondary_targets = true;
1188                         // restart the loop
1189                         bestrating = 100000000;
1190                         goto scan_targets;
1191                 }
1192
1193                 // I want to do a second scan if no enemy was found or I don't have weapons
1194                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1195                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
1196                         break;
1197                 if(scan_transparent)
1198                         break;
1199
1200                 // Set flags to see through transparent objects
1201                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1202
1203                 scan_transparent = true;
1204         }
1205
1206         // Restore hit flags
1207         this.dphitcontentsmask = hf;
1208
1209         this.enemy = best;
1210         this.havocbot_stickenemy = true;
1211         if(best && best.classname == "misc_breakablemodel")
1212                 this.havocbot_stickenemy = false;
1213 }
1214
1215 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1216 {
1217         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1218         // so skip this for them, or they'll never get to reload their weapons at all.
1219         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1220         if(skill < 5)
1221                 return false;
1222
1223         // if this weapon is scheduled for reloading, don't switch to it during combat
1224         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1225         {
1226                 FOREACH(Weapons, it != WEP_Null, {
1227                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1228                                 return true; // other weapon available
1229                 });
1230         }
1231
1232         return false;
1233 }
1234
1235 void havocbot_chooseweapon(entity this, .entity weaponentity)
1236 {
1237         int i;
1238
1239         // ;)
1240         if(g_weaponarena_weapons == WEPSET(TUBA))
1241         {
1242                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1243                 return;
1244         }
1245
1246         // TODO: clean this up by moving it to weapon code
1247         if(this.enemy==NULL)
1248         {
1249                 // If no weapon was chosen get the first available weapon
1250                 if(this.(weaponentity).m_weapon==WEP_Null)
1251                 FOREACH(Weapons, it != WEP_Null, {
1252                         if(client_hasweapon(this, it, weaponentity, true, false))
1253                         {
1254                                 this.(weaponentity).m_switchweapon = it;
1255                                 return;
1256                         }
1257                 });
1258                 return;
1259         }
1260
1261         // Do not change weapon during the next second after a combo
1262         float f = time - this.lastcombotime;
1263         if(f < 1)
1264                 return;
1265
1266         float w;
1267         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1268
1269         // Should it do a weapon combo?
1270         float af, ct, combo_time, combo;
1271
1272         af = ATTACK_FINISHED(this, 0);
1273         ct = autocvar_bot_ai_weapon_combo_threshold;
1274
1275         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1276         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1277         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1278
1279         combo = false;
1280
1281         if(autocvar_bot_ai_weapon_combo)
1282         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1283         if(af > combo_time)
1284         {
1285                 combo = true;
1286                 this.lastcombotime = time;
1287         }
1288
1289         distance *= (2 ** this.bot_rangepreference);
1290
1291         // Custom weapon list based on distance to the enemy
1292         if(bot_custom_weapon){
1293
1294                 // Choose weapons for far distance
1295                 if ( distance > bot_distance_far ) {
1296                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1297                                 w = bot_weapons_far[i];
1298                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1299                                 {
1300                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1301                                                 continue;
1302                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1303                                         return;
1304                                 }
1305                         }
1306                 }
1307
1308                 // Choose weapons for mid distance
1309                 if ( distance > bot_distance_close) {
1310                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1311                                 w = bot_weapons_mid[i];
1312                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1313                                 {
1314                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1315                                                 continue;
1316                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1317                                         return;
1318                                 }
1319                         }
1320                 }
1321
1322                 // Choose weapons for close distance
1323                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1324                         w = bot_weapons_close[i];
1325                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1326                         {
1327                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1328                                         continue;
1329                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1330                                 return;
1331                         }
1332                 }
1333         }
1334 }
1335
1336 void havocbot_aim(entity this)
1337 {
1338         if (time < this.nextaim)
1339                 return;
1340         this.nextaim = time + 0.1;
1341         vector myvel = this.velocity;
1342         if (!this.waterlevel)
1343                 myvel.z = 0;
1344         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1345         else if (this.enemy)
1346         {
1347                 vector enemyvel = this.enemy.velocity;
1348                 if (!this.enemy.waterlevel)
1349                         enemyvel.z = 0;
1350                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1351         }
1352         else
1353                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1354 }
1355
1356 bool havocbot_moveto_refresh_route(entity this)
1357 {
1358         // Refresh path to goal if necessary
1359         entity wp;
1360         wp = this.havocbot_personal_waypoint;
1361         navigation_goalrating_start(this);
1362         navigation_routerating(this, wp, 10000, 10000);
1363         navigation_goalrating_end(this);
1364         return (this.goalentity != NULL);
1365 }
1366
1367 float havocbot_moveto(entity this, vector pos)
1368 {
1369         entity wp;
1370
1371         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1372         {
1373                 // Step 4: Move to waypoint
1374                 if(this.havocbot_personal_waypoint==NULL)
1375                 {
1376                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1377                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1378                         return CMD_STATUS_ERROR;
1379                 }
1380
1381                 if (!bot_strategytoken_taken)
1382                 if(this.havocbot_personal_waypoint_searchtime<time)
1383                 {
1384                         bot_strategytoken_taken = true;
1385                         if(havocbot_moveto_refresh_route(this))
1386                         {
1387                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1388                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1389                                 this.havocbot_personal_waypoint_failcounter = 0;
1390                         }
1391                         else
1392                         {
1393                                 this.havocbot_personal_waypoint_failcounter += 1;
1394                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1395                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1396                                 {
1397                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1398                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1399                                         delete(this.havocbot_personal_waypoint);
1400                                         return CMD_STATUS_ERROR;
1401                                 }
1402                                 else
1403                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1404                         }
1405                 }
1406
1407                 if(autocvar_bot_debug_goalstack)
1408                         debuggoalstack(this);
1409
1410                 // Heading
1411                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
1412                 dir = dir - (this.origin + this.view_ofs);
1413                 dir.z = 0;
1414                 bot_aimdir(this, dir, -1);
1415
1416                 // Go!
1417                 havocbot_movetogoal(this);
1418
1419                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1420                 {
1421                         // Step 5: Waypoint reached
1422                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1423                         delete(this.havocbot_personal_waypoint);
1424                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1425                         return CMD_STATUS_FINISHED;
1426                 }
1427
1428                 return CMD_STATUS_EXECUTING;
1429         }
1430
1431         // Step 2: Linking waypoint
1432         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1433         {
1434                 // Wait until it is linked
1435                 if(!this.havocbot_personal_waypoint.wplinked)
1436                 {
1437                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1438                         return CMD_STATUS_EXECUTING;
1439                 }
1440
1441                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1442                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1443                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1444
1445                 // Step 3: Route to waypoint
1446                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1447
1448                 return CMD_STATUS_EXECUTING;
1449         }
1450
1451         // Step 1: Spawning waypoint
1452         wp = waypoint_spawnpersonal(this, pos);
1453         if(wp==NULL)
1454         {
1455                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1456                 return CMD_STATUS_ERROR;
1457         }
1458
1459         this.havocbot_personal_waypoint = wp;
1460         this.havocbot_personal_waypoint_failcounter = 0;
1461         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1462
1463         // if pos is inside a teleport, then let's mark it as teleport waypoint
1464         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1465         {
1466                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1467                 this.lastteleporttime = 0;
1468         });
1469
1470 /*
1471         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1472                 print("routing to a teleporter\n");
1473         else
1474                 print("routing to a non-teleporter\n");
1475 */
1476
1477         return CMD_STATUS_EXECUTING;
1478 }
1479
1480 float havocbot_resetgoal(entity this)
1481 {
1482         navigation_clearroute(this);
1483         return CMD_STATUS_FINISHED;
1484 }
1485
1486 void havocbot_setupbot(entity this)
1487 {
1488         this.bot_ai = havocbot_ai;
1489         this.cmd_moveto = havocbot_moveto;
1490         this.cmd_resetgoal = havocbot_resetgoal;
1491
1492         havocbot_chooserole(this);
1493 }
1494
1495 vector havocbot_dodge(entity this)
1496 {
1497         // LordHavoc: disabled because this is too expensive
1498         return '0 0 0';
1499 #if 0
1500         entity head;
1501         vector dodge, v, n;
1502         float danger, bestdanger, vl, d;
1503         dodge = '0 0 0';
1504         bestdanger = -20;
1505         // check for dangerous objects near bot or approaching bot
1506         head = findchainfloat(bot_dodge, true);
1507         while(head)
1508         {
1509                 if (head.owner != this)
1510                 {
1511                         vl = vlen(head.velocity);
1512                         if (vl > autocvar_sv_maxspeed * 0.3)
1513                         {
1514                                 n = normalize(head.velocity);
1515                                 v = this.origin - head.origin;
1516                                 d = v * n;
1517                                 if (d > (0 - head.bot_dodgerating))
1518                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1519                                 {
1520                                         // calculate direction and distance from the flight path, by removing the forward axis
1521                                         v = v - (n * (v * n));
1522                                         danger = head.bot_dodgerating - vlen(v);
1523                                         if (bestdanger < danger)
1524                                         {
1525                                                 bestdanger = danger;
1526                                                 // dodge to the side of the object
1527                                                 dodge = normalize(v);
1528                                         }
1529                                 }
1530                         }
1531                         else
1532                         {
1533                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1534                                 if (bestdanger < danger)
1535                                 {
1536                                         bestdanger = danger;
1537                                         dodge = normalize(this.origin - head.origin);
1538                                 }
1539                         }
1540                 }
1541                 head = head.chain;
1542         }
1543         return dodge;
1544 #endif
1545 }