qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/triggers/teleporters.qh>
  22 #include <common/triggers/trigger/jumppads.qh>
  23
  24 #include <lib/warpzone/common.qh>
  25
  26 .float speed;
  27
  28 void havocbot_ai(entity this)
  29 {
  30         if(this.draggedby)
  31                 return;
  32
  33         if(bot_execute_commands(this))
  34                 return;
  35
  36         if (bot_strategytoken == this && !bot_strategytoken_taken)
  37         {
  38                 if(this.havocbot_blockhead)
  39                 {
  40                         this.havocbot_blockhead = false;
  41                 }
  42                 else
  43                 {
  44                         if (!this.jumppadcount && !STAT(FROZEN, this))
  45                                 this.havocbot_role(this); // little too far down the rabbit hole
  46                 }
  47
  48                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  49                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  50                 if(!this.goalcurrent)
  51                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  52                 {
  53                         // Look for the closest waypoint out of water
  54                         entity newgoal = NULL;
  55                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  56                         {
  57                                 if(it.origin.z < this.origin.z)
  58                                         continue;
  59
  60                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  61                                         continue;
  62
  63                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  64                                         continue;
  65
  66                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  67
  68                                 if(trace_fraction < 1)
  69                                         continue;
  70
  71                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  72                                         newgoal = it;
  73                         });
  74
  75                         if(newgoal)
  76                         {
  77                         //      te_wizspike(newgoal.origin);
  78                                 navigation_pushroute(this, newgoal);
  79                         }
  80                 }
  81
  82                 // token has been used this frame
  83                 bot_strategytoken_taken = true;
  84         }
  85
  86         if(IS_DEAD(this) || STAT(FROZEN, this))
  87         {
  88                 if (this.goalcurrent)
  89                         navigation_clearroute(this);
  90                 return;
  91         }
  92
  93         havocbot_chooseenemy(this);
  94
  95         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  96         {
  97                 .entity weaponentity = weaponentities[slot];
  98                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  99                 if(this.(weaponentity).bot_chooseweapontime < time)
 100                 {
 101                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 102                         havocbot_chooseweapon(this, weaponentity);
 103                 }
 104         }
 105         havocbot_aim(this);
 106         lag_update(this);
 107         if (this.bot_aimtarg)
 108         {
 109                 this.aistatus |= AI_STATUS_ATTACKING;
 110                 this.aistatus &= ~AI_STATUS_ROAMING;
 111
 112                 if(this.weapons)
 113                 {
 114                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 115                         {
 116                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 117                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 118                         }
 119                         else
 120                         {
 121                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 122                                 {
 123                                         .entity weaponentity = weaponentities[slot];
 124                                         Weapon w = this.(weaponentity).m_weapon;
 125                                         if(w == WEP_Null && slot != 0)
 126                                                 continue;
 127                                         w.wr_aim(w, this, weaponentity);
 128                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 129                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 130                                 }
 131                         }
 132                 }
 133                 else
 134                 {
 135                         if(IS_PLAYER(this.bot_aimtarg))
 136                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 137                 }
 138         }
 139         else if (this.goalcurrent)
 140         {
 141                 this.aistatus |= AI_STATUS_ROAMING;
 142                 this.aistatus &= ~AI_STATUS_ATTACKING;
 143
 144                 vector v = '0 0 0', now, next;
 145                 float aimdistance,skillblend,distanceblend,blend;
 146
 147                 SET_DESTCOORDS(this.goalcurrent, this.origin, v);
 148                 if(this.goalcurrent.wpisbox)
 149                 {
 150                         // avoid a glitch when bot is teleported but teleport waypoint isn't removed yet
 151                         if(this.goalstack02 && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT
 152                         && this.lastteleporttime > 0 && time - this.lastteleporttime < 0.15)
 153                                 v = (this.goalstack02.absmin + this.goalstack02.absmax) * 0.5;
 154                         // aim to teleport origin if bot is inside teleport waypoint but hasn't touched the real teleport yet
 155                         else if(boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
 156                                 v = this.goalcurrent.origin;
 157                 }
 158                 next = now = v - (this.origin + this.view_ofs);
 159                 aimdistance = vlen(now);
 160
 161                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 162                 if(
 163                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 164                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 165                 )
 166                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 167
 168                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 169                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 170                 blend = skillblend * (1-distanceblend);
 171                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 172                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 173                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 174                 v = now + blend * (next - now);
 175                 //dprint(etos(this), " ");
 176                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 177                 //v = now * (distanceblend) + next * (1-distanceblend);
 178                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 179                         v.z = 0;
 180                 //dprint("walk at:", vtos(v), "\n");
 181                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 182                 bot_aimdir(this, v, -1);
 183         }
 184         havocbot_movetogoal(this);
 185
 186         // if the bot is not attacking, consider reloading weapons
 187         if (!(this.aistatus & AI_STATUS_ATTACKING))
 188         {
 189                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 190                 {
 191                         .entity weaponentity = weaponentities[slot];
 192
 193                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 194                                 continue;
 195
 196                         // we are currently holding a weapon that's not fully loaded, reload it
 197                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 198                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 199                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 200
 201                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 202                         // the code above executes next frame, starting the reloading then
 203                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 204                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 205                         {
 206                                 FOREACH(Weapons, it != WEP_Null, {
 207                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 208                                         {
 209                                                 this.(weaponentity).m_switchweapon = it;
 210                                                 break;
 211                                         }
 212                                 });
 213                         }
 214                 }
 215         }
 216 }
 217
 218 void havocbot_keyboard_movement(entity this, vector destorg)
 219 {
 220         vector keyboard;
 221
 222         if (time > this.havocbot_keyboardtime)
 223         {
 224                 float sk = skill + this.bot_moveskill;
 225                 this.havocbot_keyboardtime =
 226                         max(
 227                                 this.havocbot_keyboardtime
 228                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 229                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 230                         , time);
 231                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 232
 233                 float trigger = autocvar_bot_ai_keyboard_threshold;
 234                 float trigger1 = -trigger;
 235
 236                 // categorize forward movement
 237                 // at skill < 1.5 only forward
 238                 // at skill < 2.5 only individual directions
 239                 // at skill < 4.5 only individual directions, and forward diagonals
 240                 // at skill >= 4.5, all cases allowed
 241                 if (keyboard.x > trigger)
 242                 {
 243                         keyboard.x = 1;
 244                         if (sk < 2.5)
 245                                 keyboard.y = 0;
 246                 }
 247                 else if (keyboard.x < trigger1 && sk > 1.5)
 248                 {
 249                         keyboard.x = -1;
 250                         if (sk < 4.5)
 251                                 keyboard.y = 0;
 252                 }
 253                 else
 254                 {
 255                         keyboard.x = 0;
 256                         if (sk < 1.5)
 257                                 keyboard.y = 0;
 258                 }
 259                 if (sk < 4.5)
 260                         keyboard.z = 0;
 261
 262                 if (keyboard.y > trigger)
 263                         keyboard.y = 1;
 264                 else if (keyboard.y < trigger1)
 265                         keyboard.y = -1;
 266                 else
 267                         keyboard.y = 0;
 268
 269                 if (keyboard.z > trigger)
 270                         keyboard.z = 1;
 271                 else if (keyboard.z < trigger1)
 272                         keyboard.z = -1;
 273                 else
 274                         keyboard.z = 0;
 275
 276                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 277                 if (this.havocbot_ducktime > time)
 278                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 279         }
 280
 281         keyboard = this.havocbot_keyboard;
 282         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 283         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 284         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 285 }
 286
 287 void havocbot_bunnyhop(entity this, vector dir)
 288 {
 289         float bunnyhopdistance;
 290         vector deviation;
 291         float maxspeed;
 292         vector gco = '0 0 0', gno;
 293
 294         // Don't jump when attacking
 295         if(this.aistatus & AI_STATUS_ATTACKING)
 296                 return;
 297
 298         if(IS_PLAYER(this.goalcurrent))
 299                 return;
 300
 301         maxspeed = autocvar_sv_maxspeed;
 302
 303         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 304                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 305         {
 306                 this.aistatus &= ~AI_STATUS_RUNNING;
 307                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 308                 this.bot_canruntogoal = 0;
 309                 this.bot_timelastseengoal = 0;
 310                 return;
 311         }
 312
 313         if(this.waterlevel > WATERLEVEL_WETFEET)
 314         {
 315                 this.aistatus &= ~AI_STATUS_RUNNING;
 316                 return;
 317         }
 318
 319         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 320         {
 321                 this.bot_canruntogoal = 0;
 322                 this.bot_timelastseengoal = 0;
 323         }
 324
 325         SET_DESTCOORDS(this.goalcurrent, this.origin, gco);
 326         bunnyhopdistance = vlen(this.origin - gco);
 327
 328         // Run only to visible goals
 329         if(IS_ONGROUND(this))
 330         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 331         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 332         {
 333                         this.bot_lastseengoal = this.goalcurrent;
 334
 335                         // seen it before
 336                         if(this.bot_timelastseengoal)
 337                         {
 338                                 // for a period of time
 339                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 340                                 {
 341                                         float checkdistance;
 342                                         checkdistance = true;
 343
 344                                         // don't run if it is too close
 345                                         if(this.bot_canruntogoal==0)
 346                                         {
 347                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 348                                                         this.bot_canruntogoal = 1;
 349                                                 else
 350                                                         this.bot_canruntogoal = -1;
 351                                         }
 352
 353                                         if(this.bot_canruntogoal != 1)
 354                                                 return;
 355
 356                                         if(this.aistatus & AI_STATUS_ROAMING)
 357                                         if(this.goalcurrent.classname=="waypoint")
 358                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 359                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 360                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 361                                         {
 362                                                 gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 363                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 364                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 365                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 366
 367                                                 if(fabs(deviation.y) < 20)
 368                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 369                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 370                                                 {
 371                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 372                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 373                                                         {
 374                                                                 checkdistance = false;
 375                                                         }
 376                                                 }
 377                                         }
 378
 379                                         if(checkdistance)
 380                                         {
 381                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 382                                                 // increase stop distance in case the goal is on a slope or a lower platform
 383                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 384                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 385                                         }
 386                                         else
 387                                         {
 388                                                 this.aistatus |= AI_STATUS_RUNNING;
 389                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 390                                         }
 391                                 }
 392                         }
 393                         else
 394                         {
 395                                 this.bot_timelastseengoal = time;
 396                         }
 397         }
 398         else
 399         {
 400                 this.bot_timelastseengoal = 0;
 401         }
 402
 403 #if 0
 404         // Release jump button
 405         if(!cvar("sv_pogostick"))
 406         if((IS_ONGROUND(this)) == 0)
 407         {
 408                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 409                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 410
 411                 // Strafe
 412                 if(this.aistatus & AI_STATUS_RUNNING)
 413                 if(vlen(this.velocity)>maxspeed)
 414                 {
 415                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 416                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 417                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 418
 419                         if(fabs(deviation.y)>10)
 420                                 CS(this).movement_x = 0;
 421
 422                         if(deviation.y>10)
 423                                 CS(this).movement_y = maxspeed * -1;
 424                         else if(deviation.y<10)
 425                                 CS(this).movement_y = maxspeed;
 426
 427                 }
 428         }
 429 #endif
 430 }
 431
 432 // return true when bot isn't getting closer to the current goal
 433 bool havocbot_checkgoaldistance(entity this, vector gco)
 434 {
 435         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 436         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 437         float distance_time = this.goalcurrent_distance_time;
 438         if(distance_time < 0)
 439                 distance_time = -distance_time;
 440         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 441         {
 442                 if(!distance_time)
 443                         this.goalcurrent_distance_time = time;
 444                 else if (time - distance_time > 0.5)
 445                         return true;
 446         }
 447         else
 448         {
 449                 // reduce it a little bit so it works even with very small approaches to the goal
 450                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 451                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 452                 this.goalcurrent_distance_time = 0;
 453         }
 454         return false;
 455 }
 456
 457 void havocbot_movetogoal(entity this)
 458 {
 459         vector destorg = '0 0 0';
 460         vector diff;
 461         vector dir;
 462         vector flatdir;
 463         vector evadeobstacle;
 464         vector evadelava;
 465         float maxspeed;
 466         vector gco;
 467         //float dist;
 468         vector dodge;
 469         //if (this.goalentity)
 470         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 471         CS(this).movement = '0 0 0';
 472         maxspeed = autocvar_sv_maxspeed;
 473
 474         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 475         // Jetpack navigation
 476         if(this.navigation_jetpack_goal)
 477         if(this.goalcurrent==this.navigation_jetpack_goal)
 478         if(this.ammo_fuel)
 479         {
 480                 if(autocvar_bot_debug_goalstack)
 481                 {
 482                         debuggoalstack(this);
 483                         te_wizspike(this.navigation_jetpack_point);
 484                 }
 485
 486                 // Take off
 487                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 488                 {
 489                         // Brake almost completely so it can get a good direction
 490                         if(vdist(this.velocity, >, 10))
 491                                 return;
 492                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 493                 }
 494
 495                 makevectors(this.v_angle.y * '0 1 0');
 496                 dir = normalize(this.navigation_jetpack_point - this.origin);
 497
 498                 // Landing
 499                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 500                 {
 501                         // Calculate brake distance in xy
 502                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 503                         float v = vlen(vec2(this.velocity));
 504                         float db = ((v ** 2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 505                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 506                         if(d < db || d < 500)
 507                         {
 508                                 // Brake
 509                                 if(v > maxspeed * 0.3)
 510                                 {
 511                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 512                                         return;
 513                                 }
 514                                 // Switch to normal mode
 515                                 this.navigation_jetpack_goal = NULL;
 516                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 517                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 518                                 return;
 519                         }
 520                 }
 521                 else if(checkpvs(this.origin,this.goalcurrent))
 522                 {
 523                         // If I can see the goal switch to landing code
 524                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 525                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 526                         return;
 527                 }
 528
 529                 // Flying
 530                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 531                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 532                 {
 533                         CS(this).movement_x = dir * v_forward * maxspeed;
 534                         CS(this).movement_y = dir * v_right * maxspeed;
 535                 }
 536                 return;
 537         }
 538
 539         // Handling of jump pads
 540         if(this.jumppadcount)
 541         {
 542                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 543                 {
 544                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 545                         navigation_poptouchedgoals(this);
 546                         return;
 547                 }
 548                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 549                 {
 550                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 551                         // but with some randomness so it can try out different paths
 552                         if(!this.goalcurrent)
 553                         {
 554                                 entity newgoal = NULL;
 555                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 556                                 {
 557                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 558                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 559                                                 continue;
 560
 561                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 562
 563                                         if(trace_fraction < 1)
 564                                                 continue;
 565
 566                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 567                                                 newgoal = it;
 568                                 });
 569
 570                                 if(newgoal)
 571                                 {
 572                                         this.ignoregoal = this.goalcurrent;
 573                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 574                                         navigation_clearroute(this);
 575                                         navigation_routetogoal(this, newgoal, this.origin);
 576                                         if(autocvar_bot_debug_goalstack)
 577                                                 debuggoalstack(this);
 578                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 579                                 }
 580                         }
 581                         else
 582                         {
 583                                 if (this.goalcurrent.bot_pickup)
 584                                 {
 585                                         entity jumppad_wp = this.goalcurrent_prev;
 586                                         navigation_poptouchedgoals(this);
 587                                         if(!this.goalcurrent && jumppad_wp.wp00)
 588                                         {
 589                                                 // head to the jumppad destination once bot reaches the goal item
 590                                                 navigation_pushroute(this, jumppad_wp.wp00);
 591                                         }
 592                                 }
 593                                 gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 594                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 595                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 596                                 else if(havocbot_checkgoaldistance(this, gco))
 597                                 {
 598                                         navigation_clearroute(this);
 599                                         navigation_goalrating_timeout_force(this);
 600                                 }
 601                                 else
 602                                         return;
 603                         }
 604                 }
 605                 else
 606                 {
 607                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 608                         {
 609                                 vector velxy = this.velocity; velxy_z = 0;
 610                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 611                                 {
 612                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 613                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 614                                 }
 615                                 return;
 616                         }
 617
 618                         // Don't chase players while using a jump pad
 619                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 620                                 return;
 621                 }
 622         }
 623         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 624                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 625
 626         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 627         if (skill > 6 && !(IS_ONGROUND(this)))
 628         {
 629                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 630                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 631                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 632
 633                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 634                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 635                 if(this.items & IT_JETPACK)
 636                 {
 637                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 638                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 639                         {
 640                                 if(this.velocity.z<0)
 641                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 642                         }
 643                         else
 644                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 645
 646                         // If there is no goal try to move forward
 647
 648                         if(this.goalcurrent==NULL)
 649                                 dir = v_forward;
 650                         else
 651                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 652
 653                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 654                         float xyspeed = xyvelocity * dir;
 655
 656                         if(xyspeed < (maxspeed / 2))
 657                         {
 658                                 makevectors(this.v_angle.y * '0 1 0');
 659                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 660                                 if(trace_fraction==1)
 661                                 {
 662                                         CS(this).movement_x = dir * v_forward * maxspeed;
 663                                         CS(this).movement_y = dir * v_right * maxspeed;
 664                                         if (skill < 10)
 665                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 666                                 }
 667                         }
 668
 669                         this.havocbot_blockhead = true;
 670
 671                         return;
 672                 }
 673                 else if(this.health + this.armorvalue > ROCKETJUMP_DAMAGE())
 674                 {
 675                         if(this.velocity.z < 0)
 676                         {
 677                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 678                                 {
 679                                         .entity weaponentity = weaponentities[slot];
 680
 681                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 682                                                 continue;
 683
 684                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 685                                         {
 686                                                 CS(this).movement_x = maxspeed;
 687
 688                                                 if(this.rocketjumptime)
 689                                                 {
 690                                                         if(time > this.rocketjumptime)
 691                                                         {
 692                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 693                                                                 this.rocketjumptime = 0;
 694                                                         }
 695                                                         return;
 696                                                 }
 697
 698                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 699                                                 this.v_angle_x = 90;
 700                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 701                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 702                                                 return;
 703                                         }
 704                                 }
 705                         }
 706                 }
 707                 else
 708                 {
 709                         // If there is no goal try to move forward
 710                         if(this.goalcurrent==NULL)
 711                                 CS(this).movement_x = maxspeed;
 712                 }
 713         }
 714
 715         // If we are under water with no goals, swim up
 716         if(this.waterlevel)
 717         if(this.goalcurrent==NULL)
 718         {
 719                 dir = '0 0 0';
 720                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 721                         dir.z = 1;
 722                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 723                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 724                 else
 725                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 726                 makevectors(this.v_angle.y * '0 1 0');
 727                 CS(this).movement_x = dir * v_forward * maxspeed;
 728                 CS(this).movement_y = dir * v_right * maxspeed;
 729                 CS(this).movement_z = dir * v_up * maxspeed;
 730         }
 731
 732         // if there is nowhere to go, exit
 733         if (this.goalcurrent == NULL)
 734                 return;
 735
 736
 737         bool locked_goal = false;
 738         if(this.goalentity && wasfreed(this.goalentity))
 739         {
 740                 navigation_clearroute(this);
 741                 navigation_goalrating_timeout_force(this);
 742                 return;
 743         }
 744         else if(this.goalentity.bot_pickup)
 745         {
 746                 if(this.goalentity.bot_pickup_respawning)
 747                 {
 748                         if(this.goalentity.solid) // item respawned
 749                                 this.goalentity.bot_pickup_respawning = false;
 750                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 751                         {
 752                                 if(checkpvs(this.origin, this.goalentity))
 753                                 {
 754                                         this.goalentity.bot_pickup_respawning = false;
 755                                         navigation_goalrating_timeout_expire(this, random());
 756                                 }
 757                                 locked_goal = true; // wait for item to respawn
 758                         }
 759                         else if(this.goalentity == this.goalcurrent)
 760                                 locked_goal = true; // wait for item to respawn
 761                 }
 762                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 763                 {
 764                         if(checkpvs(this.origin, this.goalentity))
 765                         {
 766                                 navigation_goalrating_timeout_expire(this, random());
 767                         }
 768                 }
 769         }
 770         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 771                 locked_goal = true;
 772
 773         if(!locked_goal)
 774         {
 775                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 776                 // in this case path finding can start directly from a waypoint instead of
 777                 // looking for all the reachable waypoints up to a certain distance
 778                 if(navigation_poptouchedgoals(this) && this.goalcurrent)
 779                 {
 780                         if(navigation_goalrating_timeout_can_be_anticipated(this))
 781                                 navigation_goalrating_timeout_force(this);
 782                 }
 783         }
 784
 785         // if ran out of goals try to use an alternative goal or get a new strategy asap
 786         if(this.goalcurrent == NULL)
 787         {
 788                 navigation_goalrating_timeout_force(this);
 789                 return;
 790         }
 791
 792
 793         if(autocvar_bot_debug_goalstack)
 794                 debuggoalstack(this);
 795
 796         bool bunnyhop_forbidden = false;
 797         SET_DESTCOORDS(this.goalcurrent, this.origin, destorg);
 798
 799         // in case bot ends up inside the teleport waypoint without touching
 800         // the teleport itself, head to the teleport origin
 801         if(this.goalcurrent.wpisbox && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z))
 802         {
 803                 bunnyhop_forbidden = true;
 804                 destorg = this.goalcurrent.origin;
 805                 if(destorg.z > this.origin.z)
 806                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 807         }
 808
 809         diff = destorg - this.origin;
 810
 811         if (fabs(diff.x) < 10 && fabs(diff.y) < 10
 812                 && this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout)
 813         {
 814                 destorg = this.origin;
 815                 diff.x = 0;
 816                 diff.y = 0;
 817         }
 818
 819         dir = normalize(diff);
 820         flatdir = diff;flatdir.z = 0;
 821         flatdir = normalize(flatdir);
 822         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 823
 824         //if (this.bot_dodgevector_time < time)
 825         {
 826                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 827                 //this.bot_dodgevector_jumpbutton = 1;
 828                 evadeobstacle = '0 0 0';
 829                 evadelava = '0 0 0';
 830
 831                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 832                 makevectors(this.v_angle.y * '0 1 0');
 833                 if (this.waterlevel)
 834                 {
 835                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 836                         {
 837                                 if(!this.goalcurrent)
 838                                         this.aistatus |= AI_STATUS_OUT_WATER;
 839                                 else if(gco.z > this.origin.z)
 840                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 841                         }
 842                         else
 843                         {
 844                                 dir = flatdir;
 845                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && gco.z < this.origin.z) &&
 846                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 847                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 848                                 else
 849                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 850                         }
 851                 }
 852                 else
 853                 {
 854                         float s;
 855                         vector offset;
 856                         if(this.aistatus & AI_STATUS_OUT_WATER)
 857                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 858
 859                         // jump if going toward an obstacle that doesn't look like stairs we
 860                         // can walk up directly
 861                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
 862                         tracebox(this.origin, this.mins, this.maxs, this.origin + offset, false, this);
 863                         if (trace_fraction < 1)
 864                         if (trace_plane_normal.z < 0.7)
 865                         {
 866                                 s = trace_fraction;
 867                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, this.origin + offset + stepheightvec, false, this);
 868                                 if (trace_fraction < s + 0.01)
 869                                 if (trace_plane_normal.z < 0.7)
 870                                 {
 871                                         s = trace_fraction;
 872                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, this.origin + offset + jumpstepheightvec, false, this);
 873                                         if (trace_fraction > s)
 874                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 875                                 }
 876                         }
 877
 878                         // if bot for some reason doesn't get close to the current goal find another one
 879                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
 880                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
 881                         if(havocbot_checkgoaldistance(this, gco))
 882                         {
 883                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
 884                                 {
 885                                         navigation_clearroute(this);
 886                                         navigation_goalrating_timeout_force(this);
 887                                         return;
 888                                 }
 889
 890                                 vector dest = '0 0 0';
 891                                 float dest_height = 0;
 892                                 SET_TRACEWALK_DESTCOORDS(this.goalcurrent, this.origin, dest, dest_height);
 893                                 if (!tracewalk(this, this.origin, this.mins, this.maxs, dest, dest_height, bot_navigation_movemode))
 894                                 {
 895                                         navigation_clearroute(this);
 896                                         navigation_goalrating_timeout_force(this);
 897                                         return;
 898                                 }
 899
 900                                 // give bot only another chance to prevent bot getting stuck
 901                                 // in case it thinks it can walk but actually can't
 902                                 this.goalcurrent_distance_z = FLOAT_MAX;
 903                                 this.goalcurrent_distance_2d = FLOAT_MAX;
 904                                 this.goalcurrent_distance_time = -time; // mark second try
 905                         }
 906
 907                         // Check for water/slime/lava and dangerous edges
 908                         // (only when the bot is on the ground or jumping intentionally)
 909
 910                         vector dst_ahead = this.origin + this.view_ofs + offset;
 911                         vector dst_down = dst_ahead - '0 0 3000';
 912                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 913
 914                         bool unreachable = false;
 915                         s = CONTENT_SOLID;
 916                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 917                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
 918                         {
 919                                 // Look downwards
 920                                 traceline(dst_ahead , dst_down, true, NULL);
 921                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
 922                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
 923                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 924                                 {
 925                                         s = pointcontents(trace_endpos + '0 0 1');
 926                                         if (s != CONTENT_SOLID)
 927                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 928                                                 evadelava = normalize(this.velocity) * -1;
 929                                         else if (s == CONTENT_SKY)
 930                                                 evadeobstacle = normalize(this.velocity) * -1;
 931                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 932                                         {
 933                                                 // the traceline check isn't enough but is good as optimization,
 934                                                 // when not true (most of the time) this tracebox call is avoided
 935                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
 936                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 937                                                 {
 938                                                         if (gco.z > this.origin.z + jumpstepheightvec.z)
 939                                                         {
 940                                                                 // the goal is probably on an upper platform, assume bot can't get there
 941                                                                 unreachable = true;
 942                                                         }
 943                                                         else
 944                                                                 evadelava = normalize(this.velocity) * -1;
 945                                                 }
 946                                         }
 947                                 }
 948                         }
 949
 950                         dir = flatdir;
 951                         evadeobstacle.z = 0;
 952                         evadelava.z = 0;
 953                         makevectors(this.v_angle.y * '0 1 0');
 954
 955                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
 956                         {
 957                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
 958                                 if(IS_PLAYER(this.goalcurrent))
 959                                         unreachable = true;
 960                         }
 961                         if(unreachable)
 962                         {
 963                                 navigation_clearroute(this);
 964                                 navigation_goalrating_timeout_force(this);
 965                         }
 966                 }
 967
 968                 dodge = havocbot_dodge(this);
 969                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
 970                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 971                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
 972                 if(IS_PLAYER(trace_ent))
 973                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
 974
 975                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 976         //      this.bot_dodgevector = dir;
 977         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
 978         }
 979
 980         if(time < this.ladder_time)
 981         {
 982                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
 983                 {
 984                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
 985                                 dir.z = 1;
 986                 }
 987                 else
 988                 {
 989                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
 990                                 dir.z = -1;
 991                 }
 992         }
 993
 994         //dir = this.bot_dodgevector;
 995         //if (this.bot_dodgevector_jumpbutton)
 996         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
 997         CS(this).movement_x = dir * v_forward * maxspeed;
 998         CS(this).movement_y = dir * v_right * maxspeed;
 999         CS(this).movement_z = dir * v_up * maxspeed;
1000
1001         // Emulate keyboard interface
1002         if (skill < 10)
1003                 havocbot_keyboard_movement(this, destorg);
1004
1005         // Bunnyhop!
1006         //if(this.aistatus & AI_STATUS_ROAMING)
1007         if(!bunnyhop_forbidden && this.goalcurrent)
1008         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1009                 havocbot_bunnyhop(this, dir);
1010
1011         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1012         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1013         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1014 }
1015
1016 entity havocbot_gettarget(entity this, bool secondary)
1017 {
1018         entity best = NULL;
1019         vector eye = CENTER_OR_VIEWOFS(this);
1020         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1021         {
1022                 vector v = CENTER_OR_VIEWOFS(it);
1023                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1024                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1025                 if(bot_shouldattack(this, it))
1026                 {
1027                         traceline(eye, v, true, this);
1028                         if (trace_ent == it || trace_fraction >= 1)
1029                                 best = it;
1030                 }
1031         });
1032
1033         return best;
1034 }
1035
1036 void havocbot_chooseenemy(entity this)
1037 {
1038         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1039         {
1040                 this.enemy = NULL;
1041                 return;
1042         }
1043         if (this.enemy)
1044         {
1045                 if (!bot_shouldattack(this, this.enemy))
1046                 {
1047                         // enemy died or something, find a new target
1048                         this.enemy = NULL;
1049                         this.havocbot_chooseenemy_finished = time;
1050                 }
1051                 else if (this.havocbot_stickenemy)
1052                 {
1053                         // tracking last chosen enemy
1054                         // if enemy is visible
1055                         // and not really really far away
1056                         // and we're not severely injured
1057                         // then keep tracking for a half second into the future
1058                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1059                         if (trace_ent == this.enemy || trace_fraction == 1)
1060                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1061                         if (this.health > 30)
1062                         {
1063                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1064                                 this.havocbot_chooseenemy_finished = time + 0.5;
1065                                 return;
1066                         }
1067                         // enemy isn't visible, or is far away, or we're injured severely
1068                         // so stop preferring this enemy
1069                         // (it will still take a half second until a new one is chosen)
1070                         this.havocbot_stickenemy = 0;
1071                 }
1072         }
1073         if (time < this.havocbot_chooseenemy_finished)
1074                 return;
1075         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1076         vector eye = this.origin + this.view_ofs;
1077         entity best = NULL;
1078         float bestrating = 100000000;
1079
1080         // Backup hit flags
1081         int hf = this.dphitcontentsmask;
1082
1083         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1084
1085         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1086
1087         bool scan_transparent = false;
1088         bool scan_secondary_targets = false;
1089         bool have_secondary_targets = false;
1090         while(true)
1091         {
1092                 scan_secondary_targets = false;
1093 LABEL(scan_targets)
1094                 IL_EACH(g_bot_targets, it.bot_attack,
1095                 {
1096                         if(!scan_secondary_targets)
1097                         {
1098                                 if(it.classname == "misc_breakablemodel")
1099                                 {
1100                                         have_secondary_targets = true;
1101                                         continue;
1102                                 }
1103                         }
1104                         else if(it.classname != "misc_breakablemodel")
1105                                 continue;
1106
1107                         vector v = (it.absmin + it.absmax) * 0.5;
1108                         float rating = vlen2(v - eye);
1109                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1110                         if (bestrating > rating)
1111                         if (bot_shouldattack(this, it))
1112                         {
1113                                 traceline(eye, v, true, this);
1114                                 if (trace_ent == it || trace_fraction >= 1)
1115                                 {
1116                                         best = it;
1117                                         bestrating = rating;
1118                                 }
1119                         }
1120                 });
1121
1122                 if(!best && have_secondary_targets && !scan_secondary_targets)
1123                 {
1124                         scan_secondary_targets = true;
1125                         // restart the loop
1126                         bestrating = 100000000;
1127                         goto scan_targets;
1128                 }
1129
1130                 // I want to do a second scan if no enemy was found or I don't have weapons
1131                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1132                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
1133                         break;
1134                 if(scan_transparent)
1135                         break;
1136
1137                 // Set flags to see through transparent objects
1138                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1139
1140                 scan_transparent = true;
1141         }
1142
1143         // Restore hit flags
1144         this.dphitcontentsmask = hf;
1145
1146         this.enemy = best;
1147         this.havocbot_stickenemy = true;
1148         if(best && best.classname == "misc_breakablemodel")
1149                 this.havocbot_stickenemy = false;
1150 }
1151
1152 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1153 {
1154         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1155         // so skip this for them, or they'll never get to reload their weapons at all.
1156         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1157         if(skill < 5)
1158                 return false;
1159
1160         // if this weapon is scheduled for reloading, don't switch to it during combat
1161         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1162         {
1163                 FOREACH(Weapons, it != WEP_Null, {
1164                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1165                                 return true; // other weapon available
1166                 });
1167         }
1168
1169         return false;
1170 }
1171
1172 void havocbot_chooseweapon(entity this, .entity weaponentity)
1173 {
1174         int i;
1175
1176         // ;)
1177         if(g_weaponarena_weapons == WEPSET(TUBA))
1178         {
1179                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1180                 return;
1181         }
1182
1183         // TODO: clean this up by moving it to weapon code
1184         if(this.enemy==NULL)
1185         {
1186                 // If no weapon was chosen get the first available weapon
1187                 if(this.(weaponentity).m_weapon==WEP_Null)
1188                 FOREACH(Weapons, it != WEP_Null, {
1189                         if(client_hasweapon(this, it, weaponentity, true, false))
1190                         {
1191                                 this.(weaponentity).m_switchweapon = it;
1192                                 return;
1193                         }
1194                 });
1195                 return;
1196         }
1197
1198         // Do not change weapon during the next second after a combo
1199         float f = time - this.lastcombotime;
1200         if(f < 1)
1201                 return;
1202
1203         float w;
1204         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1205
1206         // Should it do a weapon combo?
1207         float af, ct, combo_time, combo;
1208
1209         af = ATTACK_FINISHED(this, 0);
1210         ct = autocvar_bot_ai_weapon_combo_threshold;
1211
1212         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1213         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1214         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1215
1216         combo = false;
1217
1218         if(autocvar_bot_ai_weapon_combo)
1219         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1220         if(af > combo_time)
1221         {
1222                 combo = true;
1223                 this.lastcombotime = time;
1224         }
1225
1226         distance *= (2 ** this.bot_rangepreference);
1227
1228         // Custom weapon list based on distance to the enemy
1229         if(bot_custom_weapon){
1230
1231                 // Choose weapons for far distance
1232                 if ( distance > bot_distance_far ) {
1233                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1234                                 w = bot_weapons_far[i];
1235                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1236                                 {
1237                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1238                                                 continue;
1239                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1240                                         return;
1241                                 }
1242                         }
1243                 }
1244
1245                 // Choose weapons for mid distance
1246                 if ( distance > bot_distance_close) {
1247                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1248                                 w = bot_weapons_mid[i];
1249                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1250                                 {
1251                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1252                                                 continue;
1253                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1254                                         return;
1255                                 }
1256                         }
1257                 }
1258
1259                 // Choose weapons for close distance
1260                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1261                         w = bot_weapons_close[i];
1262                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1263                         {
1264                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1265                                         continue;
1266                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1267                                 return;
1268                         }
1269                 }
1270         }
1271 }
1272
1273 void havocbot_aim(entity this)
1274 {
1275         if (time < this.nextaim)
1276                 return;
1277         this.nextaim = time + 0.1;
1278         vector myvel = this.velocity;
1279         if (!this.waterlevel)
1280                 myvel.z = 0;
1281         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1282         else if (this.enemy)
1283         {
1284                 vector enemyvel = this.enemy.velocity;
1285                 if (!this.enemy.waterlevel)
1286                         enemyvel.z = 0;
1287                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1288         }
1289         else
1290                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1291 }
1292
1293 bool havocbot_moveto_refresh_route(entity this)
1294 {
1295         // Refresh path to goal if necessary
1296         entity wp;
1297         wp = this.havocbot_personal_waypoint;
1298         navigation_goalrating_start(this);
1299         navigation_routerating(this, wp, 10000, 10000);
1300         navigation_goalrating_end(this);
1301         return (this.goalentity != NULL);
1302 }
1303
1304 float havocbot_moveto(entity this, vector pos)
1305 {
1306         entity wp;
1307
1308         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1309         {
1310                 // Step 4: Move to waypoint
1311                 if(this.havocbot_personal_waypoint==NULL)
1312                 {
1313                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1314                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1315                         return CMD_STATUS_ERROR;
1316                 }
1317
1318                 if (!bot_strategytoken_taken)
1319                 if(this.havocbot_personal_waypoint_searchtime<time)
1320                 {
1321                         bot_strategytoken_taken = true;
1322                         if(havocbot_moveto_refresh_route(this))
1323                         {
1324                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1325                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1326                                 this.havocbot_personal_waypoint_failcounter = 0;
1327                         }
1328                         else
1329                         {
1330                                 this.havocbot_personal_waypoint_failcounter += 1;
1331                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1332                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1333                                 {
1334                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1335                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1336                                         delete(this.havocbot_personal_waypoint);
1337                                         return CMD_STATUS_ERROR;
1338                                 }
1339                                 else
1340                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1341                         }
1342                 }
1343
1344                 if(autocvar_bot_debug_goalstack)
1345                         debuggoalstack(this);
1346
1347                 // Heading
1348                 vector dir = '0 0 0';
1349                 SET_DESTCOORDS(this.goalcurrent, this.origin, dir);
1350                 dir = dir - (this.origin + this.view_ofs);
1351                 dir.z = 0;
1352                 bot_aimdir(this, dir, -1);
1353
1354                 // Go!
1355                 havocbot_movetogoal(this);
1356
1357                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1358                 {
1359                         // Step 5: Waypoint reached
1360                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1361                         delete(this.havocbot_personal_waypoint);
1362                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1363                         return CMD_STATUS_FINISHED;
1364                 }
1365
1366                 return CMD_STATUS_EXECUTING;
1367         }
1368
1369         // Step 2: Linking waypoint
1370         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1371         {
1372                 // Wait until it is linked
1373                 if(!this.havocbot_personal_waypoint.wplinked)
1374                 {
1375                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1376                         return CMD_STATUS_EXECUTING;
1377                 }
1378
1379                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1380                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1381                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1382
1383                 // Step 3: Route to waypoint
1384                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1385
1386                 return CMD_STATUS_EXECUTING;
1387         }
1388
1389         // Step 1: Spawning waypoint
1390         wp = waypoint_spawnpersonal(this, pos);
1391         if(wp==NULL)
1392         {
1393                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1394                 return CMD_STATUS_ERROR;
1395         }
1396
1397         this.havocbot_personal_waypoint = wp;
1398         this.havocbot_personal_waypoint_failcounter = 0;
1399         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1400
1401         // if pos is inside a teleport, then let's mark it as teleport waypoint
1402         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1403         {
1404                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1405                 this.lastteleporttime = 0;
1406         });
1407
1408 /*
1409         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1410                 print("routing to a teleporter\n");
1411         else
1412                 print("routing to a non-teleporter\n");
1413 */
1414
1415         return CMD_STATUS_EXECUTING;
1416 }
1417
1418 float havocbot_resetgoal(entity this)
1419 {
1420         navigation_clearroute(this);
1421         return CMD_STATUS_FINISHED;
1422 }
1423
1424 void havocbot_setupbot(entity this)
1425 {
1426         this.bot_ai = havocbot_ai;
1427         this.cmd_moveto = havocbot_moveto;
1428         this.cmd_resetgoal = havocbot_resetgoal;
1429
1430         havocbot_chooserole(this);
1431 }
1432
1433 vector havocbot_dodge(entity this)
1434 {
1435         // LordHavoc: disabled because this is too expensive
1436         return '0 0 0';
1437 #if 0
1438         entity head;
1439         vector dodge, v, n;
1440         float danger, bestdanger, vl, d;
1441         dodge = '0 0 0';
1442         bestdanger = -20;
1443         // check for dangerous objects near bot or approaching bot
1444         head = findchainfloat(bot_dodge, true);
1445         while(head)
1446         {
1447                 if (head.owner != this)
1448                 {
1449                         vl = vlen(head.velocity);
1450                         if (vl > autocvar_sv_maxspeed * 0.3)
1451                         {
1452                                 n = normalize(head.velocity);
1453                                 v = this.origin - head.origin;
1454                                 d = v * n;
1455                                 if (d > (0 - head.bot_dodgerating))
1456                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1457                                 {
1458                                         // calculate direction and distance from the flight path, by removing the forward axis
1459                                         v = v - (n * (v * n));
1460                                         danger = head.bot_dodgerating - vlen(v);
1461                                         if (bestdanger < danger)
1462                                         {
1463                                                 bestdanger = danger;
1464                                                 // dodge to the side of the object
1465                                                 dodge = normalize(v);
1466                                         }
1467                                 }
1468                         }
1469                         else
1470                         {
1471                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1472                                 if (bestdanger < danger)
1473                                 {
1474                                         bestdanger = danger;
1475                                         dodge = normalize(this.origin - head.origin);
1476                                 }
1477                         }
1478                 }
1479                 head = head.chain;
1480         }
1481         return dodge;
1482 #endif
1483 }