qcsrc/server/bot/default/scripting.qc

   1 #include "scripting.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include <common/state.qh>
   6 #include <common/physics/player.qh>
   7
   8 #include "bot.qh"
   9
  10 .int state;
  11
  12 .float bot_cmdqueuebuf_allocated;
  13 .float bot_cmdqueuebuf;
  14 .float bot_cmdqueuebuf_start;
  15 .float bot_cmdqueuebuf_end;
  16
  17 void bot_clearqueue(entity bot)
  18 {
  19         if(!bot.bot_cmdqueuebuf_allocated)
  20                 return;
  21         buf_del(bot.bot_cmdqueuebuf);
  22         bot.bot_cmdqueuebuf_allocated = false;
  23         LOG_TRACE("bot ", bot.netname, " queue cleared");
  24 }
  25
  26 void bot_queuecommand(entity bot, string cmdstring)
  27 {
  28         if(!bot.bot_cmdqueuebuf_allocated)
  29         {
  30                 bot.bot_cmdqueuebuf = buf_create();
  31                 bot.bot_cmdqueuebuf_allocated = true;
  32                 bot.bot_cmdqueuebuf_start = 0;
  33                 bot.bot_cmdqueuebuf_end = 0;
  34         }
  35
  36         bufstr_set(bot.bot_cmdqueuebuf, bot.bot_cmdqueuebuf_end, cmdstring);
  37
  38         // if the command was a "sound" command, precache the sound NOW
  39         // this prevents lagging!
  40         {
  41                 float sp;
  42                 string parm;
  43                 string cmdstr;
  44
  45                 sp = strstrofs(cmdstring, " ", 0);
  46                 if(sp >= 0)
  47                 {
  48                         parm = substring(cmdstring, sp + 1, -1);
  49                         cmdstr = substring(cmdstring, 0, sp);
  50                         if(cmdstr == "sound")
  51                         {
  52                                 // find the LAST word
  53                                 for (;;)
  54                                 {
  55                                         sp = strstrofs(parm, " ", 0);
  56                                         if(sp < 0)
  57                                                 break;
  58                                         parm = substring(parm, sp + 1, -1);
  59                                 }
  60                                 precache_sound(parm);
  61                         }
  62                 }
  63         }
  64
  65         bot.bot_cmdqueuebuf_end += 1;
  66 }
  67
  68 void bot_dequeuecommand(entity bot, float idx)
  69 {
  70         if(!bot.bot_cmdqueuebuf_allocated)
  71                 error("dequeuecommand but no queue allocated");
  72         if(idx < bot.bot_cmdqueuebuf_start)
  73                 error("dequeueing a command in the past");
  74         if(idx >= bot.bot_cmdqueuebuf_end)
  75                 error("dequeueing a command in the future");
  76         bufstr_set(bot.bot_cmdqueuebuf, idx, "");
  77         if(idx == bot.bot_cmdqueuebuf_start)
  78                 bot.bot_cmdqueuebuf_start += 1;
  79         if(bot.bot_cmdqueuebuf_start >= bot.bot_cmdqueuebuf_end)
  80                 bot_clearqueue(bot);
  81 }
  82
  83 string bot_readcommand(entity bot, float idx)
  84 {
  85         if(!bot.bot_cmdqueuebuf_allocated)
  86                 error("readcommand but no queue allocated");
  87         if(idx < bot.bot_cmdqueuebuf_start)
  88                 error("reading a command in the past");
  89         if(idx >= bot.bot_cmdqueuebuf_end)
  90                 error("reading a command in the future");
  91         return bufstr_get(bot.bot_cmdqueuebuf, idx);
  92 }
  93
  94 bool bot_havecommand(entity this, int idx)
  95 {
  96         if(!this.bot_cmdqueuebuf_allocated)
  97                 return false;
  98         if(idx < this.bot_cmdqueuebuf_start)
  99                 return false;
 100         if(idx >= this.bot_cmdqueuebuf_end)
 101                 return false;
 102         return true;
 103 }
 104
 105 const int MAX_BOT_PLACES = 4;
 106 .float bot_places_count;
 107 .entity bot_places[MAX_BOT_PLACES];
 108 .string bot_placenames[MAX_BOT_PLACES];
 109 entity bot_getplace(entity this, string placename)
 110 {
 111         entity e;
 112         if(substring(placename, 0, 1) == "@")
 113         {
 114                 int i, p;
 115                 placename = substring(placename, 1, -1);
 116                 string s, s2;
 117                 for(i = 0; i < this.bot_places_count; ++i)
 118                         if(this.(bot_placenames[i]) == placename)
 119                                 return this.(bot_places[i]);
 120                 // now: i == this.bot_places_count
 121                 s = s2 = cvar_string(placename);
 122                 p = strstrofs(s2, " ", 0);
 123                 if(p >= 0)
 124                 {
 125                         s = substring(s2, 0, p);
 126                         //print("places: ", placename, " -> ", cvar_string(placename), "\n");
 127                         cvar_set(placename, strcat(substring(s2, p+1, -1), " ", s));
 128                         //print("places: ", placename, " := ", cvar_string(placename), "\n");
 129                 }
 130                 e = find(NULL, targetname, s);
 131                 if(!e)
 132                         LOG_INFO("invalid place ", s, "\n");
 133                 if(i < MAX_BOT_PLACES)
 134                 {
 135                         this.(bot_placenames[i]) = strzone(placename);
 136                         this.(bot_places[i]) = e;
 137                         this.bot_places_count += 1;
 138                 }
 139                 return e;
 140         }
 141         else
 142         {
 143                 e = find(NULL, targetname, placename);
 144                 if(!e)
 145                         LOG_INFO("invalid place ", placename, "\n");
 146                 return e;
 147         }
 148 }
 149
 150
 151 // Initialize global commands list
 152 // NOTE: New commands should be initialized here
 153 void bot_commands_init()
 154 {
 155         bot_cmd_string[BOT_CMD_NULL] = "";
 156         bot_cmd_parm_type[BOT_CMD_NULL] = BOT_CMD_PARAMETER_NONE;
 157
 158         bot_cmd_string[BOT_CMD_PAUSE] = "pause";
 159         bot_cmd_parm_type[BOT_CMD_PAUSE] = BOT_CMD_PARAMETER_NONE;
 160
 161         bot_cmd_string[BOT_CMD_CONTINUE] = "continue";
 162         bot_cmd_parm_type[BOT_CMD_CONTINUE] = BOT_CMD_PARAMETER_NONE;
 163
 164         bot_cmd_string[BOT_CMD_WAIT] = "wait";
 165         bot_cmd_parm_type[BOT_CMD_WAIT] = BOT_CMD_PARAMETER_FLOAT;
 166
 167         bot_cmd_string[BOT_CMD_TURN] = "turn";
 168         bot_cmd_parm_type[BOT_CMD_TURN] = BOT_CMD_PARAMETER_FLOAT;
 169
 170         bot_cmd_string[BOT_CMD_MOVETO] = "moveto";
 171         bot_cmd_parm_type[BOT_CMD_MOVETO] = BOT_CMD_PARAMETER_VECTOR;
 172
 173         bot_cmd_string[BOT_CMD_MOVETOTARGET] = "movetotarget";
 174         bot_cmd_parm_type[BOT_CMD_MOVETOTARGET] = BOT_CMD_PARAMETER_STRING;
 175
 176         bot_cmd_string[BOT_CMD_RESETGOAL] = "resetgoal";
 177         bot_cmd_parm_type[BOT_CMD_RESETGOAL] = BOT_CMD_PARAMETER_NONE;
 178
 179         bot_cmd_string[BOT_CMD_CC] = "cc";
 180         bot_cmd_parm_type[BOT_CMD_CC] = BOT_CMD_PARAMETER_STRING;
 181
 182         bot_cmd_string[BOT_CMD_IF] = "if";
 183         bot_cmd_parm_type[BOT_CMD_IF] = BOT_CMD_PARAMETER_STRING;
 184
 185         bot_cmd_string[BOT_CMD_ELSE] = "else";
 186         bot_cmd_parm_type[BOT_CMD_ELSE] = BOT_CMD_PARAMETER_NONE;
 187
 188         bot_cmd_string[BOT_CMD_FI] = "fi";
 189         bot_cmd_parm_type[BOT_CMD_FI] = BOT_CMD_PARAMETER_NONE;
 190
 191         bot_cmd_string[BOT_CMD_RESETAIM] = "resetaim";
 192         bot_cmd_parm_type[BOT_CMD_RESETAIM] = BOT_CMD_PARAMETER_NONE;
 193
 194         bot_cmd_string[BOT_CMD_AIM] = "aim";
 195         bot_cmd_parm_type[BOT_CMD_AIM] = BOT_CMD_PARAMETER_STRING;
 196
 197         bot_cmd_string[BOT_CMD_AIMTARGET] = "aimtarget";
 198         bot_cmd_parm_type[BOT_CMD_AIMTARGET] = BOT_CMD_PARAMETER_STRING;
 199
 200         bot_cmd_string[BOT_CMD_PRESSKEY] = "presskey";
 201         bot_cmd_parm_type[BOT_CMD_PRESSKEY] = BOT_CMD_PARAMETER_STRING;
 202
 203         bot_cmd_string[BOT_CMD_RELEASEKEY] = "releasekey";
 204         bot_cmd_parm_type[BOT_CMD_RELEASEKEY] = BOT_CMD_PARAMETER_STRING;
 205
 206         bot_cmd_string[BOT_CMD_SELECTWEAPON] = "selectweapon";
 207         bot_cmd_parm_type[BOT_CMD_SELECTWEAPON] = BOT_CMD_PARAMETER_FLOAT;
 208
 209         bot_cmd_string[BOT_CMD_IMPULSE] = "impulse";
 210         bot_cmd_parm_type[BOT_CMD_IMPULSE] = BOT_CMD_PARAMETER_FLOAT;
 211
 212         bot_cmd_string[BOT_CMD_WAIT_UNTIL] = "wait_until";
 213         bot_cmd_parm_type[BOT_CMD_WAIT_UNTIL] = BOT_CMD_PARAMETER_FLOAT;
 214
 215         bot_cmd_string[BOT_CMD_BARRIER] = "barrier";
 216         bot_cmd_parm_type[BOT_CMD_BARRIER] = BOT_CMD_PARAMETER_NONE;
 217
 218         bot_cmd_string[BOT_CMD_CONSOLE] = "console";
 219         bot_cmd_parm_type[BOT_CMD_CONSOLE] = BOT_CMD_PARAMETER_STRING;
 220
 221         bot_cmd_string[BOT_CMD_SOUND] = "sound";
 222         bot_cmd_parm_type[BOT_CMD_SOUND] = BOT_CMD_PARAMETER_STRING;
 223
 224         bot_cmd_string[BOT_CMD_DEBUG_ASSERT_CANFIRE] = "debug_assert_canfire";
 225         bot_cmd_parm_type[BOT_CMD_DEBUG_ASSERT_CANFIRE] = BOT_CMD_PARAMETER_FLOAT;
 226
 227         bot_cmds_initialized = true;
 228 }
 229
 230 // Returns first bot with matching name
 231 entity find_bot_by_name(string name)
 232 {
 233         FOREACH_CLIENT(IS_BOT_CLIENT(it) && it.netname == name,
 234         {
 235                 return it;
 236         });
 237
 238         return NULL;
 239 }
 240
 241 // Returns a bot by number on list
 242 entity find_bot_by_number(float number)
 243 {
 244         entity bot;
 245         float c = 0;
 246
 247         if(!number)
 248                 return NULL;
 249
 250         bot = findchainflags(flags, FL_CLIENT); // TODO: doesn't findchainflags loop backwards through entities?
 251         while (bot)
 252         {
 253                 if(IS_BOT_CLIENT(bot))
 254                 {
 255                         if(++c==number)
 256                                 return bot;
 257                 }
 258                 bot = bot.chain;
 259         }
 260
 261         return NULL;
 262 }
 263
 264 float bot_decodecommand(string cmdstring)
 265 {
 266         float cmd_parm_type;
 267         float sp;
 268         string parm;
 269
 270         sp = strstrofs(cmdstring, " ", 0);
 271         if(sp < 0)
 272         {
 273                 parm = "";
 274         }
 275         else
 276         {
 277                 parm = substring(cmdstring, sp + 1, -1);
 278                 cmdstring = substring(cmdstring, 0, sp);
 279         }
 280
 281         if(!bot_cmds_initialized)
 282                 bot_commands_init();
 283
 284         int i;
 285         for(i=1;i<BOT_CMD_COUNTER;++i)
 286         {
 287                 if(bot_cmd_string[i]!=cmdstring)
 288                         continue;
 289
 290                 cmd_parm_type = bot_cmd_parm_type[i];
 291
 292                 if(cmd_parm_type!=BOT_CMD_PARAMETER_NONE&&parm=="")
 293                 {
 294                         LOG_INFO("ERROR: A parameter is required for this command\n");
 295                         return 0;
 296                 }
 297
 298                 // Load command into queue
 299                 bot_cmd.bot_cmd_type = i;
 300
 301                 // Attach parameter
 302                 switch(cmd_parm_type)
 303                 {
 304                         case BOT_CMD_PARAMETER_FLOAT:
 305                                 bot_cmd.bot_cmd_parm_float = stof(parm);
 306                                 break;
 307                         case BOT_CMD_PARAMETER_STRING:
 308                                 if(bot_cmd.bot_cmd_parm_string)
 309                                         strunzone(bot_cmd.bot_cmd_parm_string);
 310                                 bot_cmd.bot_cmd_parm_string = strzone(parm);
 311                                 break;
 312                         case BOT_CMD_PARAMETER_VECTOR:
 313                                 bot_cmd.bot_cmd_parm_vector = stov(parm);
 314                                 break;
 315                         default:
 316                                 break;
 317                 }
 318                 return 1;
 319         }
 320         LOG_INFO("ERROR: No such command '", cmdstring, "'\n");
 321         return 0;
 322 }
 323
 324 void bot_cmdhelp(string scmd)
 325 {
 326         int i, ntype;
 327         string stype;
 328
 329         if(!bot_cmds_initialized)
 330                 bot_commands_init();
 331
 332         for(i=1;i<BOT_CMD_COUNTER;++i)
 333         {
 334                 if(bot_cmd_string[i]!=scmd)
 335                         continue;
 336
 337                 ntype = bot_cmd_parm_type[i];
 338
 339                 switch(ntype)
 340                 {
 341                         case BOT_CMD_PARAMETER_FLOAT:
 342                                 stype = "float number";
 343                                 break;
 344                         case BOT_CMD_PARAMETER_STRING:
 345                                 stype = "string";
 346                                 break;
 347                         case BOT_CMD_PARAMETER_VECTOR:
 348                                 stype = "vector";
 349                                 break;
 350                         default:
 351                                 stype = "none";
 352                                 break;
 353                 }
 354
 355                 LOG_INFO(strcat("Command: ",bot_cmd_string[i],"\nParameter: <",stype,"> \n"));
 356
 357                 LOG_INFO("Description: ");
 358                 switch(i)
 359                 {
 360                         case BOT_CMD_PAUSE:
 361                                 LOG_INFO("Stops the bot completely. Any command other than 'continue' will be ignored.");
 362                                 break;
 363                         case BOT_CMD_CONTINUE:
 364                                 LOG_INFO("Disable paused status");
 365                                 break;
 366                         case BOT_CMD_WAIT:
 367                                 LOG_INFO("Pause command parsing and bot ai for N seconds. Pressed key will remain pressed");
 368                                 break;
 369                         case BOT_CMD_WAIT_UNTIL:
 370                                 LOG_INFO("Pause command parsing and bot ai until time is N from the last barrier. Pressed key will remain pressed");
 371                                 break;
 372                         case BOT_CMD_BARRIER:
 373                                 LOG_INFO("Waits till all bots that have a command queue reach this command. Pressed key will remain pressed");
 374                                 break;
 375                         case BOT_CMD_TURN:
 376                                 LOG_INFO("Look to the right or left N degrees. For turning to the left use positive numbers.");
 377                                 break;
 378                         case BOT_CMD_MOVETO:
 379                                 LOG_INFO("Walk to an specific coordinate on the map. Usage: moveto \"x y z\"");
 380                                 break;
 381                         case BOT_CMD_MOVETOTARGET:
 382                                 LOG_INFO("Walk to the specific target on the map");
 383                                 break;
 384                         case BOT_CMD_RESETGOAL:
 385                                 LOG_INFO("Resets the goal stack");
 386                                 break;
 387                         case BOT_CMD_CC:
 388                                 LOG_INFO("Execute client command. Examples: cc \"say something\"; cc god; cc \"name newnickname\"; cc kill;");
 389                                 break;
 390                         case BOT_CMD_IF:
 391                                 LOG_INFO("Perform simple conditional execution.\n");
 392                                 LOG_INFO("Syntax: \n");
 393                                 LOG_INFO("        sv_cmd .. if \"condition\"\n");
 394                                 LOG_INFO("        sv_cmd ..     <instruction if true>\n");
 395                                 LOG_INFO("        sv_cmd ..     <instruction if true>\n");
 396                                 LOG_INFO("        sv_cmd .. else\n");
 397                                 LOG_INFO("        sv_cmd ..     <instruction if false>\n");
 398                                 LOG_INFO("        sv_cmd ..     <instruction if false>\n");
 399                                 LOG_INFO("        sv_cmd .. fi\n");
 400                                 LOG_INFO("Conditions: a=b, a>b, a<b, a\t\t(spaces not allowed)\n");
 401                                 LOG_INFO("            Values in conditions can be numbers, cvars in the form cvar.cvar_string or special fields\n");
 402                                 LOG_INFO("Fields: health, speed, flagcarrier\n");
 403                                 LOG_INFO("Examples: if health>50; if health>cvar.g_balance_laser_primary_damage; if flagcarrier;");
 404                                 break;
 405                         case BOT_CMD_RESETAIM:
 406                                 LOG_INFO("Points the aim to the coordinates x,y 0,0");
 407                                 break;
 408                         case BOT_CMD_AIM:
 409                                 LOG_INFO("Move the aim x/y (horizontal/vertical) degrees relatives to the bot\n");
 410                                 LOG_INFO("There is a 3rd optional parameter telling in how many seconds the aim has to reach the new position\n");
 411                                 LOG_INFO("Examples: aim \"90 0\"        // Turn 90 degrees inmediately (positive numbers move to the left/up)\n");
 412                                 LOG_INFO("          aim \"0 90 2\"      // Will gradually look to the sky in the next two seconds");
 413                                 break;
 414                         case BOT_CMD_AIMTARGET:
 415                                 LOG_INFO("Points the aim to given target");
 416                                 break;
 417                         case BOT_CMD_PRESSKEY:
 418                                 LOG_INFO("Press one of the following keys: forward, backward, left, right, jump, crouch, attack1, attack2, use\n");
 419                                 LOG_INFO("Multiple keys can be pressed at time (with many presskey calls) and it will remain pressed until the command \"releasekey\" is called");
 420                                 LOG_INFO("Note: The script will not return the control to the bot ai until all keys are released");
 421                                 break;
 422                         case BOT_CMD_RELEASEKEY:
 423                                 LOG_INFO("Release previoulsy used keys. Use the parameter \"all\" to release all keys");
 424                                 break;
 425                         case BOT_CMD_SOUND:
 426                                 LOG_INFO("play sound file at bot location");
 427                                 break;
 428                         case BOT_CMD_DEBUG_ASSERT_CANFIRE:
 429                                 LOG_INFO("verify the state of the weapon entity");
 430                                 break;
 431                         default:
 432                                 LOG_INFO("This command has no description yet.");
 433                                 break;
 434                 }
 435                 LOG_INFO("\n");
 436         }
 437 }
 438
 439 void bot_list_commands()
 440 {
 441         int i;
 442         string ptype;
 443
 444         if(!bot_cmds_initialized)
 445                 bot_commands_init();
 446
 447         LOG_INFO("List of all available commands:\n");
 448         LOG_INFO("  Command - Parameter Type\n");
 449
 450         for(i=1;i<BOT_CMD_COUNTER;++i)
 451         {
 452                 switch(bot_cmd_parm_type[i])
 453                 {
 454                         case BOT_CMD_PARAMETER_FLOAT:
 455                                 ptype = "float number";
 456                                 break;
 457                         case BOT_CMD_PARAMETER_STRING:
 458                                 ptype = "string";
 459                                 break;
 460                         case BOT_CMD_PARAMETER_VECTOR:
 461                                 ptype = "vector";
 462                                 break;
 463                         default:
 464                                 ptype = "none";
 465                                 break;
 466                 }
 467                 LOG_INFO(strcat("  ",bot_cmd_string[i]," - <",ptype,"> \n"));
 468         }
 469 }
 470
 471 // Commands code
 472 .int bot_exec_status;
 473
 474 float bot_cmd_cc(entity this)
 475 {
 476         SV_ParseClientCommand(this, bot_cmd.bot_cmd_parm_string);
 477         return CMD_STATUS_FINISHED;
 478 }
 479
 480 float bot_cmd_impulse(entity this)
 481 {
 482         this.impulse = bot_cmd.bot_cmd_parm_float;
 483         return CMD_STATUS_FINISHED;
 484 }
 485
 486 float bot_cmd_continue(entity this)
 487 {
 488         this.bot_exec_status &= ~BOT_EXEC_STATUS_PAUSED;
 489         return CMD_STATUS_FINISHED;
 490 }
 491
 492 .float bot_cmd_wait_time;
 493 float bot_cmd_wait(entity this)
 494 {
 495         if(this.bot_exec_status & BOT_EXEC_STATUS_WAITING)
 496         {
 497                 if(time>=this.bot_cmd_wait_time)
 498                 {
 499                         this.bot_exec_status &= ~BOT_EXEC_STATUS_WAITING;
 500                         return CMD_STATUS_FINISHED;
 501                 }
 502                 else
 503                         return CMD_STATUS_EXECUTING;
 504         }
 505
 506         this.bot_cmd_wait_time = time + bot_cmd.bot_cmd_parm_float;
 507         this.bot_exec_status |= BOT_EXEC_STATUS_WAITING;
 508         return CMD_STATUS_EXECUTING;
 509 }
 510
 511 float bot_cmd_wait_until(entity this)
 512 {
 513         if(time < bot_cmd.bot_cmd_parm_float + bot_barriertime)
 514         {
 515                 this.bot_exec_status |= BOT_EXEC_STATUS_WAITING;
 516                 return CMD_STATUS_EXECUTING;
 517         }
 518         this.bot_exec_status &= ~BOT_EXEC_STATUS_WAITING;
 519         return CMD_STATUS_FINISHED;
 520 }
 521
 522 float bot_cmd_barrier(entity this)
 523 {
 524         // 0 = no barrier, 1 = waiting, 2 = waiting finished
 525
 526         if(this.bot_barrier == 0) // initialization
 527         {
 528                 this.bot_barrier = 1;
 529
 530                 //this.colormod = '4 4 0';
 531         }
 532
 533         if(this.bot_barrier == 1) // find other bots
 534         {
 535                 FOREACH_CLIENT(it.isbot, LAMBDA(
 536                         if(it.bot_cmdqueuebuf_allocated)
 537                         if(it.bot_barrier != 1)
 538                                 return CMD_STATUS_EXECUTING; // not all are at the barrier yet
 539                 ));
 540
 541                 // all bots hit the barrier!
 542
 543                 // acknowledge barrier
 544                 FOREACH_CLIENT(it.isbot, LAMBDA(it.bot_barrier = 2));
 545
 546                 bot_barriertime = time;
 547         }
 548
 549         // if we get here, the barrier is finished
 550         // so end it...
 551         this.bot_barrier = 0;
 552         //this.colormod = '0 0 0';
 553
 554         return CMD_STATUS_FINISHED;
 555 }
 556
 557 float bot_cmd_turn(entity this)
 558 {
 559         this.v_angle_y = this.v_angle.y + bot_cmd.bot_cmd_parm_float;
 560         this.v_angle_y = this.v_angle.y - floor(this.v_angle.y / 360) * 360;
 561         return CMD_STATUS_FINISHED;
 562 }
 563
 564 float bot_cmd_select_weapon(entity this)
 565 {
 566         float id = bot_cmd.bot_cmd_parm_float;
 567
 568         if(id < WEP_FIRST || id > WEP_LAST)
 569                 return CMD_STATUS_ERROR;
 570
 571         if(client_hasweapon(this, Weapons_from(id), true, false))
 572                 PS(this).m_switchweapon = Weapons_from(id);
 573         else
 574                 return CMD_STATUS_ERROR;
 575
 576         return CMD_STATUS_FINISHED;
 577 }
 578
 579 .int bot_cmd_condition_status;
 580
 581 const int CMD_CONDITION_NONE = 0;
 582 const int CMD_CONDITION_true = 1;
 583 const int CMD_CONDITION_false = 2;
 584 const int CMD_CONDITION_true_BLOCK = 4;
 585 const int CMD_CONDITION_false_BLOCK = 8;
 586
 587 float bot_cmd_eval(entity this, string expr)
 588 {
 589         // Search for numbers
 590         if(strstrofs("0123456789", substring(expr, 0, 1), 0) >= 0)
 591         {
 592                 return stof(expr);
 593         }
 594
 595         // Search for cvars
 596         if(substring(expr, 0, 5)=="cvar.")
 597         {
 598                 return cvar(substring(expr, 5, strlen(expr)));
 599         }
 600
 601         // Search for fields
 602         switch(expr)
 603         {
 604                 case "health":
 605                         return this.health;
 606                 case "speed":
 607                         return vlen(this.velocity);
 608                 case "flagcarrier":
 609                         return ((this.flagcarried!=NULL));
 610         }
 611
 612         LOG_INFO(strcat("ERROR: Unable to convert the expression '",expr,"' into a numeric value\n"));
 613         return 0;
 614 }
 615
 616 float bot_cmd_if(entity this)
 617 {
 618         string expr, val_a, val_b;
 619         float cmpofs;
 620
 621         if(this.bot_cmd_condition_status != CMD_CONDITION_NONE)
 622         {
 623                 // Only one "if" block is allowed at time
 624                 LOG_INFO("ERROR: Only one conditional block can be processed at time");
 625                 bot_clearqueue(this);
 626                 return CMD_STATUS_ERROR;
 627         }
 628
 629         this.bot_cmd_condition_status |= CMD_CONDITION_true_BLOCK;
 630
 631         // search for operators
 632         expr = bot_cmd.bot_cmd_parm_string;
 633
 634         cmpofs = strstrofs(expr,"=",0);
 635
 636         if(cmpofs>0)
 637         {
 638                 val_a = substring(expr,0,cmpofs);
 639                 val_b = substring(expr,cmpofs+1,strlen(expr));
 640
 641                 if(bot_cmd_eval(this, val_a)==bot_cmd_eval(this, val_b))
 642                         this.bot_cmd_condition_status |= CMD_CONDITION_true;
 643                 else
 644                         this.bot_cmd_condition_status |= CMD_CONDITION_false;
 645
 646                 return CMD_STATUS_FINISHED;
 647         }
 648
 649         cmpofs = strstrofs(expr,">",0);
 650
 651         if(cmpofs>0)
 652         {
 653                 val_a = substring(expr,0,cmpofs);
 654                 val_b = substring(expr,cmpofs+1,strlen(expr));
 655
 656                 if(bot_cmd_eval(this, val_a)>bot_cmd_eval(this, val_b))
 657                         this.bot_cmd_condition_status |= CMD_CONDITION_true;
 658                 else
 659                         this.bot_cmd_condition_status |= CMD_CONDITION_false;
 660
 661                 return CMD_STATUS_FINISHED;
 662         }
 663
 664         cmpofs = strstrofs(expr,"<",0);
 665
 666         if(cmpofs>0)
 667         {
 668                 val_a = substring(expr,0,cmpofs);
 669                 val_b = substring(expr,cmpofs+1,strlen(expr));
 670
 671                 if(bot_cmd_eval(this, val_a)<bot_cmd_eval(this, val_b))
 672                         this.bot_cmd_condition_status |= CMD_CONDITION_true;
 673                 else
 674                         this.bot_cmd_condition_status |= CMD_CONDITION_false;
 675
 676                 return CMD_STATUS_FINISHED;
 677         }
 678
 679         if(bot_cmd_eval(this, expr))
 680                 this.bot_cmd_condition_status |= CMD_CONDITION_true;
 681         else
 682                 this.bot_cmd_condition_status |= CMD_CONDITION_false;
 683
 684         return CMD_STATUS_FINISHED;
 685 }
 686
 687 float bot_cmd_else(entity this)
 688 {
 689         this.bot_cmd_condition_status &= ~CMD_CONDITION_true_BLOCK;
 690         this.bot_cmd_condition_status |= CMD_CONDITION_false_BLOCK;
 691         return CMD_STATUS_FINISHED;
 692 }
 693
 694 float bot_cmd_fi(entity this)
 695 {
 696         this.bot_cmd_condition_status = CMD_CONDITION_NONE;
 697         return CMD_STATUS_FINISHED;
 698 }
 699
 700 float bot_cmd_resetaim(entity this)
 701 {
 702         this.v_angle = '0 0 0';
 703         return CMD_STATUS_FINISHED;
 704 }
 705
 706 .float bot_cmd_aim_begintime;
 707 .float bot_cmd_aim_endtime;
 708 .vector bot_cmd_aim_begin;
 709 .vector bot_cmd_aim_end;
 710
 711 float bot_cmd_aim(entity this)
 712 {
 713         // Current direction
 714         if(this.bot_cmd_aim_endtime)
 715         {
 716                 float progress;
 717
 718                 progress = min(1 - (this.bot_cmd_aim_endtime - time) / (this.bot_cmd_aim_endtime - this.bot_cmd_aim_begintime),1);
 719                 this.v_angle = this.bot_cmd_aim_begin + ((this.bot_cmd_aim_end - this.bot_cmd_aim_begin) * progress);
 720
 721                 if(time>=this.bot_cmd_aim_endtime)
 722                 {
 723                         this.bot_cmd_aim_endtime = 0;
 724                         return CMD_STATUS_FINISHED;
 725                 }
 726                 else
 727                         return CMD_STATUS_EXECUTING;
 728         }
 729
 730         // New aiming direction
 731         string parms;
 732         float tokens, step;
 733
 734         parms = bot_cmd.bot_cmd_parm_string;
 735
 736         tokens = tokenizebyseparator(parms, " ");
 737
 738         if(tokens<2||tokens>3)
 739                 return CMD_STATUS_ERROR;
 740
 741         step = (tokens == 3) ? stof(argv(2)) : 0;
 742
 743         if(step == 0)
 744         {
 745                 this.v_angle_x -= stof(argv(1));
 746                 this.v_angle_y += stof(argv(0));
 747                 return CMD_STATUS_FINISHED;
 748         }
 749
 750         this.bot_cmd_aim_begin = this.v_angle;
 751
 752         this.bot_cmd_aim_end_x = this.v_angle.x - stof(argv(1));
 753         this.bot_cmd_aim_end_y = this.v_angle.y + stof(argv(0));
 754         this.bot_cmd_aim_end_z = 0;
 755
 756         this.bot_cmd_aim_begintime = time;
 757         this.bot_cmd_aim_endtime = time + step;
 758
 759         return CMD_STATUS_EXECUTING;
 760 }
 761
 762 float bot_cmd_aimtarget(entity this)
 763 {
 764         if(this.bot_cmd_aim_endtime)
 765         {
 766                 return bot_cmd_aim(this);
 767         }
 768
 769         entity e;
 770         string parms;
 771         vector v;
 772         float tokens, step;
 773
 774         parms = bot_cmd.bot_cmd_parm_string;
 775
 776         tokens = tokenizebyseparator(parms, " ");
 777
 778         e = bot_getplace(this, argv(0));
 779         if(!e)
 780                 return CMD_STATUS_ERROR;
 781
 782         v = e.origin + (e.mins + e.maxs) * 0.5;
 783
 784         if(tokens==1)
 785         {
 786                 this.v_angle = vectoangles(v - (this.origin + this.view_ofs));
 787                 this.v_angle_x = -this.v_angle.x;
 788                 return CMD_STATUS_FINISHED;
 789         }
 790
 791         if(tokens<1||tokens>2)
 792                 return CMD_STATUS_ERROR;
 793
 794         step = stof(argv(1));
 795
 796         this.bot_cmd_aim_begin = this.v_angle;
 797         this.bot_cmd_aim_end = vectoangles(v - (this.origin + this.view_ofs));
 798         this.bot_cmd_aim_end_x = -this.bot_cmd_aim_end.x;
 799
 800         this.bot_cmd_aim_begintime = time;
 801         this.bot_cmd_aim_endtime = time + step;
 802
 803         return CMD_STATUS_EXECUTING;
 804 }
 805
 806 .int bot_cmd_keys;
 807
 808 const int BOT_CMD_KEY_NONE              = 0;
 809 const int BOT_CMD_KEY_FORWARD   = BIT(0);
 810 const int BOT_CMD_KEY_BACKWARD  = BIT(1);
 811 const int BOT_CMD_KEY_RIGHT     = BIT(2);
 812 const int BOT_CMD_KEY_LEFT              = BIT(3);
 813 const int BOT_CMD_KEY_JUMP              = BIT(4);
 814 const int BOT_CMD_KEY_ATTACK1   = BIT(5);
 815 const int BOT_CMD_KEY_ATTACK2   = BIT(6);
 816 const int BOT_CMD_KEY_USE               = BIT(7);
 817 const int BOT_CMD_KEY_HOOK              = BIT(8);
 818 const int BOT_CMD_KEY_CROUCH    = BIT(9);
 819 const int BOT_CMD_KEY_CHAT              = BIT(10);
 820
 821 bool bot_presskeys(entity this)
 822 {
 823         this.movement = '0 0 0';
 824         PHYS_INPUT_BUTTON_JUMP(this) = false;
 825         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 826         PHYS_INPUT_BUTTON_ATCK(this) = false;
 827         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 828         PHYS_INPUT_BUTTON_USE(this) = false;
 829         PHYS_INPUT_BUTTON_HOOK(this) = false;
 830         PHYS_INPUT_BUTTON_CHAT(this) = false;
 831
 832         if(this.bot_cmd_keys == BOT_CMD_KEY_NONE)
 833                 return false;
 834
 835         if(this.bot_cmd_keys & BOT_CMD_KEY_FORWARD)
 836                 this.movement_x = autocvar_sv_maxspeed;
 837         else if(this.bot_cmd_keys & BOT_CMD_KEY_BACKWARD)
 838                 this.movement_x = -autocvar_sv_maxspeed;
 839
 840         if(this.bot_cmd_keys & BOT_CMD_KEY_RIGHT)
 841                 this.movement_y = autocvar_sv_maxspeed;
 842         else if(this.bot_cmd_keys & BOT_CMD_KEY_LEFT)
 843                 this.movement_y = -autocvar_sv_maxspeed;
 844
 845         if(this.bot_cmd_keys & BOT_CMD_KEY_JUMP)
 846                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 847
 848         if(this.bot_cmd_keys & BOT_CMD_KEY_CROUCH)
 849                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 850
 851         if(this.bot_cmd_keys & BOT_CMD_KEY_ATTACK1)
 852                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 853
 854         if(this.bot_cmd_keys & BOT_CMD_KEY_ATTACK2)
 855                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 856
 857         if(this.bot_cmd_keys & BOT_CMD_KEY_USE)
 858                 PHYS_INPUT_BUTTON_USE(this) = true;
 859
 860         if(this.bot_cmd_keys & BOT_CMD_KEY_HOOK)
 861                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 862
 863         if(this.bot_cmd_keys & BOT_CMD_KEY_CHAT)
 864                 PHYS_INPUT_BUTTON_CHAT(this) = true;
 865
 866         return true;
 867 }
 868
 869
 870 float bot_cmd_keypress_handler(entity this, string key, float enabled)
 871 {
 872         switch(key)
 873         {
 874                 case "all":
 875                         if(enabled)
 876                                 this.bot_cmd_keys = power2of(20) - 1; // >:)
 877                         else
 878                                 this.bot_cmd_keys = BOT_CMD_KEY_NONE;
 879                 case "forward":
 880                         if(enabled)
 881                         {
 882                                 this.bot_cmd_keys |= BOT_CMD_KEY_FORWARD;
 883                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_BACKWARD;
 884                         }
 885                         else
 886                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_FORWARD;
 887                         break;
 888                 case "backward":
 889                         if(enabled)
 890                         {
 891                                 this.bot_cmd_keys |= BOT_CMD_KEY_BACKWARD;
 892                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_FORWARD;
 893                         }
 894                         else
 895                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_BACKWARD;
 896                         break;
 897                 case "left":
 898                         if(enabled)
 899                         {
 900                                 this.bot_cmd_keys |= BOT_CMD_KEY_LEFT;
 901                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_RIGHT;
 902                         }
 903                         else
 904                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_LEFT;
 905                         break;
 906                 case "right":
 907                         if(enabled)
 908                         {
 909                                 this.bot_cmd_keys |= BOT_CMD_KEY_RIGHT;
 910                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_LEFT;
 911                         }
 912                         else
 913                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_RIGHT;
 914                         break;
 915                 case "jump":
 916                         if(enabled)
 917                                 this.bot_cmd_keys |= BOT_CMD_KEY_JUMP;
 918                         else
 919                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_JUMP;
 920                         break;
 921                 case "crouch":
 922                         if(enabled)
 923                                 this.bot_cmd_keys |= BOT_CMD_KEY_CROUCH;
 924                         else
 925                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_CROUCH;
 926                         break;
 927                 case "attack1":
 928                         if(enabled)
 929                                 this.bot_cmd_keys |= BOT_CMD_KEY_ATTACK1;
 930                         else
 931                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_ATTACK1;
 932                         break;
 933                 case "attack2":
 934                         if(enabled)
 935                                 this.bot_cmd_keys |= BOT_CMD_KEY_ATTACK2;
 936                         else
 937                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_ATTACK2;
 938                         break;
 939                 case "use":
 940                         if(enabled)
 941                                 this.bot_cmd_keys |= BOT_CMD_KEY_USE;
 942                         else
 943                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_USE;
 944                         break;
 945                 case "hook":
 946                         if(enabled)
 947                                 this.bot_cmd_keys |= BOT_CMD_KEY_HOOK;
 948                         else
 949                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_HOOK;
 950                         break;
 951                 case "chat":
 952                         if(enabled)
 953                                 this.bot_cmd_keys |= BOT_CMD_KEY_CHAT;
 954                         else
 955                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_CHAT;
 956                         break;
 957                 default:
 958                         break;
 959         }
 960
 961         return CMD_STATUS_FINISHED;
 962 }
 963
 964 float bot_cmd_presskey(entity this)
 965 {
 966         string key;
 967
 968         key = bot_cmd.bot_cmd_parm_string;
 969
 970         bot_cmd_keypress_handler(this, key,true);
 971
 972         return CMD_STATUS_FINISHED;
 973 }
 974
 975 float bot_cmd_releasekey(entity this)
 976 {
 977         string key;
 978
 979         key = bot_cmd.bot_cmd_parm_string;
 980
 981         return bot_cmd_keypress_handler(this, key,false);
 982 }
 983
 984 float bot_cmd_pause(entity this)
 985 {
 986         PHYS_INPUT_BUTTON_DRAG(this) = false;
 987         PHYS_INPUT_BUTTON_USE(this) = false;
 988         PHYS_INPUT_BUTTON_ATCK(this) = false;
 989         PHYS_INPUT_BUTTON_JUMP(this) = false;
 990         PHYS_INPUT_BUTTON_HOOK(this) = false;
 991         PHYS_INPUT_BUTTON_CHAT(this) = false;
 992         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 993         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 994
 995         this.movement = '0 0 0';
 996         this.bot_cmd_keys = BOT_CMD_KEY_NONE;
 997
 998         this.bot_exec_status |= BOT_EXEC_STATUS_PAUSED;
 999         return CMD_STATUS_FINISHED;
1000 }
1001
1002 float bot_cmd_moveto(entity this)
1003 {
1004         return this.cmd_moveto(this, bot_cmd.bot_cmd_parm_vector);
1005 }
1006
1007 float bot_cmd_movetotarget(entity this)
1008 {
1009         entity e;
1010         e = bot_getplace(this, bot_cmd.bot_cmd_parm_string);
1011         if(!e)
1012                 return CMD_STATUS_ERROR;
1013         return this.cmd_moveto(this, e.origin + (e.mins + e.maxs) * 0.5);
1014 }
1015
1016 float bot_cmd_resetgoal(entity this)
1017 {
1018         return this.cmd_resetgoal(this);
1019 }
1020
1021
1022 float bot_cmd_sound(entity this)
1023 {
1024         string f;
1025         f = bot_cmd.bot_cmd_parm_string;
1026
1027         float n = tokenizebyseparator(f, " ");
1028
1029         string sample = f;
1030         float chan = CH_WEAPON_B;
1031         float vol = VOL_BASE;
1032         float atten = ATTEN_MIN;
1033
1034         if(n >= 1)
1035                 sample = argv(n - 1);
1036         if(n >= 2)
1037                 chan = stof(argv(0));
1038         if(n >= 3)
1039                 vol = stof(argv(1));
1040         if(n >= 4)
1041                 atten = stof(argv(2));
1042
1043         precache_sound(f);
1044         _sound(this, chan, sample, vol, atten);
1045
1046         return CMD_STATUS_FINISHED;
1047 }
1048
1049 .entity tuba_note;
1050 float bot_cmd_debug_assert_canfire(entity this)
1051 {
1052         float f = bot_cmd.bot_cmd_parm_float;
1053
1054         int slot = 0; // TODO: unhardcode?
1055         .entity weaponentity = weaponentities[slot];
1056         if(this.(weaponentity).state != WS_READY)
1057         {
1058                 if(f)
1059                 {
1060                         this.colormod = '0 8 8';
1061                         LOG_INFO("Bot ", this.netname, " using ", this.weaponname, " wants to fire, inhibited by weaponentity state\n");
1062                 }
1063         }
1064         else if(ATTACK_FINISHED(this, slot) > time)
1065         {
1066                 if(f)
1067                 {
1068                         this.colormod = '8 0 8';
1069                         LOG_INFO("Bot ", this.netname, " using ", this.weaponname, " wants to fire, inhibited by ATTACK_FINISHED (", ftos(ATTACK_FINISHED(this, slot) - time), " seconds left)\n");
1070                 }
1071         }
1072         else if(this.tuba_note)
1073         {
1074                 if(f)
1075                 {
1076                         this.colormod = '8 0 0';
1077                         LOG_INFO("Bot ", this.netname, " using ", this.weaponname, " wants to fire, bot still has an active tuba note\n");
1078                 }
1079         }
1080         else
1081         {
1082                 if(!f)
1083                 {
1084                         this.colormod = '8 8 0';
1085                         LOG_INFO("Bot ", this.netname, " using ", this.weaponname, " thinks it has fired, but apparently did not; ATTACK_FINISHED says ", ftos(ATTACK_FINISHED(this, slot) - time), " seconds left\n");
1086                 }
1087         }
1088
1089         return CMD_STATUS_FINISHED;
1090 }
1091
1092 //
1093
1094 void bot_command_executed(entity this, bool rm)
1095 {
1096         entity cmd;
1097
1098         cmd = bot_cmd;
1099
1100         if(rm)
1101                 bot_dequeuecommand(this, this.bot_cmd_execution_index);
1102
1103         this.bot_cmd_execution_index++;
1104 }
1105
1106 void bot_setcurrentcommand(entity this)
1107 {
1108         bot_cmd = NULL;
1109
1110         if(!this.bot_cmd_current)
1111         {
1112                 this.bot_cmd_current = new_pure(bot_cmd);
1113                 this.bot_cmd_current.is_bot_cmd = true;
1114         }
1115
1116         bot_cmd = this.bot_cmd_current;
1117         if(bot_cmd.bot_cmd_index != this.bot_cmd_execution_index || this.bot_cmd_execution_index == 0)
1118         {
1119                 if(bot_havecommand(this, this.bot_cmd_execution_index))
1120                 {
1121                         string cmdstring;
1122                         cmdstring = bot_readcommand(this, this.bot_cmd_execution_index);
1123                         if(bot_decodecommand(cmdstring))
1124                         {
1125                                 bot_cmd.owner = this;
1126                                 bot_cmd.bot_cmd_index = this.bot_cmd_execution_index;
1127                         }
1128                         else
1129                         {
1130                                 // Invalid command, remove from queue
1131                                 bot_cmd = NULL;
1132                                 bot_dequeuecommand(this, this.bot_cmd_execution_index);
1133                                 this.bot_cmd_execution_index++;
1134                         }
1135                 }
1136                 else
1137                         bot_cmd = NULL;
1138         }
1139 }
1140
1141 void bot_resetqueues()
1142 {
1143         FOREACH_CLIENT(it.isbot, LAMBDA(
1144                 it.bot_cmd_execution_index = 0;
1145                 bot_clearqueue(it);
1146                 // also, cancel all barriers
1147                 it.bot_barrier = 0;
1148                 for(int i = 0; i < it.bot_places_count; ++i)
1149                 {
1150                         strunzone(it.(bot_placenames[i]));
1151                         it.(bot_placenames[i]) = string_null;
1152                 }
1153                 it.bot_places_count = 0;
1154         ));
1155
1156         bot_barriertime = time;
1157 }
1158
1159 // Here we map commands to functions and deal with complex interactions between commands and execution states
1160 // NOTE: Of course you need to include your commands here too :)
1161 float bot_execute_commands_once(entity this)
1162 {
1163         float status, ispressingkey;
1164
1165         // Find command
1166         bot_setcurrentcommand(this);
1167
1168         // if we have no bot command, better return
1169         // old logic kept pressing previously pressed keys, but that has problems
1170         // (namely, it means you cannot make a bot "normal" ever again)
1171         // to keep a bot walking for a while, use the "wait" bot command
1172         if(bot_cmd == NULL)
1173                 return false;
1174
1175         // Ignore all commands except continue when the bot is paused
1176         if(this.bot_exec_status & BOT_EXEC_STATUS_PAUSED)
1177         if(bot_cmd.bot_cmd_type!=BOT_CMD_CONTINUE)
1178         {
1179                 if(bot_cmd.bot_cmd_type!=BOT_CMD_NULL)
1180                 {
1181                         bot_command_executed(this, true);
1182                         LOG_INFO( "WARNING: Commands are ignored while the bot is paused. Use the command 'continue' instead.\n");
1183                 }
1184                 return 1;
1185         }
1186
1187         // Keep pressing keys raised by the "presskey" command
1188         ispressingkey = boolean(bot_presskeys(this));
1189
1190         // Handle conditions
1191         if (!(bot_cmd.bot_cmd_type==BOT_CMD_FI||bot_cmd.bot_cmd_type==BOT_CMD_ELSE))
1192         if(this.bot_cmd_condition_status & CMD_CONDITION_true && this.bot_cmd_condition_status & CMD_CONDITION_false_BLOCK)
1193         {
1194                 bot_command_executed(this, true);
1195                 return -1;
1196         }
1197         else if(this.bot_cmd_condition_status & CMD_CONDITION_false && this.bot_cmd_condition_status & CMD_CONDITION_true_BLOCK)
1198         {
1199                 bot_command_executed(this, true);
1200                 return -1;
1201         }
1202
1203         // Map commands to functions
1204         switch(bot_cmd.bot_cmd_type)
1205         {
1206                 case BOT_CMD_NULL:
1207                         return ispressingkey;
1208                         //break;
1209                 case BOT_CMD_PAUSE:
1210                         status = bot_cmd_pause(this);
1211                         break;
1212                 case BOT_CMD_CONTINUE:
1213                         status = bot_cmd_continue(this);
1214                         break;
1215                 case BOT_CMD_WAIT:
1216                         status = bot_cmd_wait(this);
1217                         break;
1218                 case BOT_CMD_WAIT_UNTIL:
1219                         status = bot_cmd_wait_until(this);
1220                         break;
1221                 case BOT_CMD_TURN:
1222                         status = bot_cmd_turn(this);
1223                         break;
1224                 case BOT_CMD_MOVETO:
1225                         status = bot_cmd_moveto(this);
1226                         break;
1227                 case BOT_CMD_MOVETOTARGET:
1228                         status = bot_cmd_movetotarget(this);
1229                         break;
1230                 case BOT_CMD_RESETGOAL:
1231                         status = bot_cmd_resetgoal(this);
1232                         break;
1233                 case BOT_CMD_CC:
1234                         status = bot_cmd_cc(this);
1235                         break;
1236                 case BOT_CMD_IF:
1237                         status = bot_cmd_if(this);
1238                         break;
1239                 case BOT_CMD_ELSE:
1240                         status = bot_cmd_else(this);
1241                         break;
1242                 case BOT_CMD_FI:
1243                         status = bot_cmd_fi(this);
1244                         break;
1245                 case BOT_CMD_RESETAIM:
1246                         status = bot_cmd_resetaim(this);
1247                         break;
1248                 case BOT_CMD_AIM:
1249                         status = bot_cmd_aim(this);
1250                         break;
1251                 case BOT_CMD_AIMTARGET:
1252                         status = bot_cmd_aimtarget(this);
1253                         break;
1254                 case BOT_CMD_PRESSKEY:
1255                         status = bot_cmd_presskey(this);
1256                         break;
1257                 case BOT_CMD_RELEASEKEY:
1258                         status = bot_cmd_releasekey(this);
1259                         break;
1260                 case BOT_CMD_SELECTWEAPON:
1261                         status = bot_cmd_select_weapon(this);
1262                         break;
1263                 case BOT_CMD_IMPULSE:
1264                         status = bot_cmd_impulse(this);
1265                         break;
1266                 case BOT_CMD_BARRIER:
1267                         status = bot_cmd_barrier(this);
1268                         break;
1269                 case BOT_CMD_CONSOLE:
1270                         localcmd(strcat(bot_cmd.bot_cmd_parm_string, "\n"));
1271                         status = CMD_STATUS_FINISHED;
1272                         break;
1273                 case BOT_CMD_SOUND:
1274                         status = bot_cmd_sound(this);
1275                         break;
1276                 case BOT_CMD_DEBUG_ASSERT_CANFIRE:
1277                         status = bot_cmd_debug_assert_canfire(this);
1278                         break;
1279                 default:
1280                         LOG_INFO(strcat("ERROR: Invalid command on queue with id '",ftos(bot_cmd.bot_cmd_type),"'\n"));
1281                         return 0;
1282         }
1283
1284         if (status==CMD_STATUS_ERROR)
1285                 LOG_INFO(strcat("ERROR: The command '",bot_cmd_string[bot_cmd.bot_cmd_type],"' returned an error status\n"));
1286
1287         // Move execution pointer
1288         if(status==CMD_STATUS_EXECUTING)
1289         {
1290                 return 1;
1291         }
1292         else
1293         {
1294                 if(autocvar_g_debug_bot_commands)
1295                 {
1296                         string parms;
1297
1298                         switch(bot_cmd_parm_type[bot_cmd.bot_cmd_type])
1299                         {
1300                                 case BOT_CMD_PARAMETER_FLOAT:
1301                                         parms = ftos(bot_cmd.bot_cmd_parm_float);
1302                                         break;
1303                                 case BOT_CMD_PARAMETER_STRING:
1304                                         parms = bot_cmd.bot_cmd_parm_string;
1305                                         break;
1306                                 case BOT_CMD_PARAMETER_VECTOR:
1307                                         parms = vtos(bot_cmd.bot_cmd_parm_vector);
1308                                         break;
1309                                 default:
1310                                         parms = "";
1311                                         break;
1312                         }
1313                         clientcommand(this,strcat("say ^7", bot_cmd_string[bot_cmd.bot_cmd_type]," ",parms,"\n"));
1314                 }
1315
1316                 bot_command_executed(this, true);
1317         }
1318
1319         if(status == CMD_STATUS_FINISHED)
1320                 return -1;
1321
1322         return CMD_STATUS_ERROR;
1323 }
1324
1325 // This function should be (the only) called directly from the bot ai loop
1326 int bot_execute_commands(entity this)
1327 {
1328         int f;
1329         do
1330         {
1331                 f = bot_execute_commands_once(this);
1332         }
1333         while(f < 0);
1334         return f;
1335 }