qcsrc/server/bot/default/scripting.qc

   1 #include "scripting.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include <common/state.qh>
   6 #include <common/physics/player.qh>
   7
   8 #include "bot.qh"
   9
  10 .int state;
  11
  12 .float bot_cmdqueuebuf_allocated;
  13 .float bot_cmdqueuebuf;
  14 .float bot_cmdqueuebuf_start;
  15 .float bot_cmdqueuebuf_end;
  16
  17 void bot_clearqueue(entity bot)
  18 {
  19         if(!bot.bot_cmdqueuebuf_allocated)
  20                 return;
  21         buf_del(bot.bot_cmdqueuebuf);
  22         bot.bot_cmdqueuebuf_allocated = false;
  23         LOG_TRACE("bot ", bot.netname, " queue cleared");
  24 }
  25
  26 void bot_queuecommand(entity bot, string cmdstring)
  27 {
  28         if(!bot.bot_cmdqueuebuf_allocated)
  29         {
  30                 bot.bot_cmdqueuebuf = buf_create();
  31                 bot.bot_cmdqueuebuf_allocated = true;
  32                 bot.bot_cmdqueuebuf_start = 0;
  33                 bot.bot_cmdqueuebuf_end = 0;
  34         }
  35
  36         bufstr_set(bot.bot_cmdqueuebuf, bot.bot_cmdqueuebuf_end, cmdstring);
  37
  38         // if the command was a "sound" command, precache the sound NOW
  39         // this prevents lagging!
  40         {
  41                 float sp;
  42                 string parm;
  43                 string cmdstr;
  44
  45                 sp = strstrofs(cmdstring, " ", 0);
  46                 if(sp >= 0)
  47                 {
  48                         parm = substring(cmdstring, sp + 1, -1);
  49                         cmdstr = substring(cmdstring, 0, sp);
  50                         if(cmdstr == "sound")
  51                         {
  52                                 // find the LAST word
  53                                 for (;;)
  54                                 {
  55                                         sp = strstrofs(parm, " ", 0);
  56                                         if(sp < 0)
  57                                                 break;
  58                                         parm = substring(parm, sp + 1, -1);
  59                                 }
  60                                 precache_sound(parm);
  61                         }
  62                 }
  63         }
  64
  65         bot.bot_cmdqueuebuf_end += 1;
  66 }
  67
  68 void bot_dequeuecommand(entity bot, float idx)
  69 {
  70         if(!bot.bot_cmdqueuebuf_allocated)
  71                 error("dequeuecommand but no queue allocated");
  72         if(idx < bot.bot_cmdqueuebuf_start)
  73                 error("dequeueing a command in the past");
  74         if(idx >= bot.bot_cmdqueuebuf_end)
  75                 error("dequeueing a command in the future");
  76         bufstr_set(bot.bot_cmdqueuebuf, idx, "");
  77         if(idx == bot.bot_cmdqueuebuf_start)
  78                 bot.bot_cmdqueuebuf_start += 1;
  79         if(bot.bot_cmdqueuebuf_start >= bot.bot_cmdqueuebuf_end)
  80                 bot_clearqueue(bot);
  81 }
  82
  83 string bot_readcommand(entity bot, float idx)
  84 {
  85         if(!bot.bot_cmdqueuebuf_allocated)
  86                 error("readcommand but no queue allocated");
  87         if(idx < bot.bot_cmdqueuebuf_start)
  88                 error("reading a command in the past");
  89         if(idx >= bot.bot_cmdqueuebuf_end)
  90                 error("reading a command in the future");
  91         return bufstr_get(bot.bot_cmdqueuebuf, idx);
  92 }
  93
  94 bool bot_havecommand(entity this, int idx)
  95 {
  96         if(!this.bot_cmdqueuebuf_allocated)
  97                 return false;
  98         if(idx < this.bot_cmdqueuebuf_start)
  99                 return false;
 100         if(idx >= this.bot_cmdqueuebuf_end)
 101                 return false;
 102         return true;
 103 }
 104
 105 const int MAX_BOT_PLACES = 4;
 106 .float bot_places_count;
 107 .entity bot_places[MAX_BOT_PLACES];
 108 .string bot_placenames[MAX_BOT_PLACES];
 109 entity bot_getplace(entity this, string placename)
 110 {
 111         entity e;
 112         if(substring(placename, 0, 1) == "@")
 113         {
 114                 int i, p;
 115                 placename = substring(placename, 1, -1);
 116                 string s, s2;
 117                 for(i = 0; i < this.bot_places_count; ++i)
 118                         if(this.(bot_placenames[i]) == placename)
 119                                 return this.(bot_places[i]);
 120                 // now: i == this.bot_places_count
 121                 s = s2 = cvar_string(placename);
 122                 p = strstrofs(s2, " ", 0);
 123                 if(p >= 0)
 124                 {
 125                         s = substring(s2, 0, p);
 126                         //print("places: ", placename, " -> ", cvar_string(placename), "\n");
 127                         cvar_set(placename, strcat(substring(s2, p+1, -1), " ", s));
 128                         //print("places: ", placename, " := ", cvar_string(placename), "\n");
 129                 }
 130                 e = find(NULL, targetname, s);
 131                 if(!e)
 132                         LOG_INFO("invalid place ", s, "\n");
 133                 if(i < MAX_BOT_PLACES)
 134                 {
 135                         this.(bot_placenames[i]) = strzone(placename);
 136                         this.(bot_places[i]) = e;
 137                         this.bot_places_count += 1;
 138                 }
 139                 return e;
 140         }
 141         else
 142         {
 143                 e = find(NULL, targetname, placename);
 144                 if(!e)
 145                         LOG_INFO("invalid place ", placename, "\n");
 146                 return e;
 147         }
 148 }
 149
 150
 151 // Initialize global commands list
 152 // NOTE: New commands should be initialized here
 153 void bot_commands_init()
 154 {
 155         bot_cmd_string[BOT_CMD_NULL] = "";
 156         bot_cmd_parm_type[BOT_CMD_NULL] = BOT_CMD_PARAMETER_NONE;
 157
 158         bot_cmd_string[BOT_CMD_PAUSE] = "pause";
 159         bot_cmd_parm_type[BOT_CMD_PAUSE] = BOT_CMD_PARAMETER_NONE;
 160
 161         bot_cmd_string[BOT_CMD_CONTINUE] = "continue";
 162         bot_cmd_parm_type[BOT_CMD_CONTINUE] = BOT_CMD_PARAMETER_NONE;
 163
 164         bot_cmd_string[BOT_CMD_WAIT] = "wait";
 165         bot_cmd_parm_type[BOT_CMD_WAIT] = BOT_CMD_PARAMETER_FLOAT;
 166
 167         bot_cmd_string[BOT_CMD_TURN] = "turn";
 168         bot_cmd_parm_type[BOT_CMD_TURN] = BOT_CMD_PARAMETER_FLOAT;
 169
 170         bot_cmd_string[BOT_CMD_MOVETO] = "moveto";
 171         bot_cmd_parm_type[BOT_CMD_MOVETO] = BOT_CMD_PARAMETER_VECTOR;
 172
 173         bot_cmd_string[BOT_CMD_MOVETOTARGET] = "movetotarget";
 174         bot_cmd_parm_type[BOT_CMD_MOVETOTARGET] = BOT_CMD_PARAMETER_STRING;
 175
 176         bot_cmd_string[BOT_CMD_RESETGOAL] = "resetgoal";
 177         bot_cmd_parm_type[BOT_CMD_RESETGOAL] = BOT_CMD_PARAMETER_NONE;
 178
 179         bot_cmd_string[BOT_CMD_CC] = "cc";
 180         bot_cmd_parm_type[BOT_CMD_CC] = BOT_CMD_PARAMETER_STRING;
 181
 182         bot_cmd_string[BOT_CMD_IF] = "if";
 183         bot_cmd_parm_type[BOT_CMD_IF] = BOT_CMD_PARAMETER_STRING;
 184
 185         bot_cmd_string[BOT_CMD_ELSE] = "else";
 186         bot_cmd_parm_type[BOT_CMD_ELSE] = BOT_CMD_PARAMETER_NONE;
 187
 188         bot_cmd_string[BOT_CMD_FI] = "fi";
 189         bot_cmd_parm_type[BOT_CMD_FI] = BOT_CMD_PARAMETER_NONE;
 190
 191         bot_cmd_string[BOT_CMD_RESETAIM] = "resetaim";
 192         bot_cmd_parm_type[BOT_CMD_RESETAIM] = BOT_CMD_PARAMETER_NONE;
 193
 194         bot_cmd_string[BOT_CMD_AIM] = "aim";
 195         bot_cmd_parm_type[BOT_CMD_AIM] = BOT_CMD_PARAMETER_STRING;
 196
 197         bot_cmd_string[BOT_CMD_AIMTARGET] = "aimtarget";
 198         bot_cmd_parm_type[BOT_CMD_AIMTARGET] = BOT_CMD_PARAMETER_STRING;
 199
 200         bot_cmd_string[BOT_CMD_PRESSKEY] = "presskey";
 201         bot_cmd_parm_type[BOT_CMD_PRESSKEY] = BOT_CMD_PARAMETER_STRING;
 202
 203         bot_cmd_string[BOT_CMD_RELEASEKEY] = "releasekey";
 204         bot_cmd_parm_type[BOT_CMD_RELEASEKEY] = BOT_CMD_PARAMETER_STRING;
 205
 206         bot_cmd_string[BOT_CMD_SELECTWEAPON] = "selectweapon";
 207         bot_cmd_parm_type[BOT_CMD_SELECTWEAPON] = BOT_CMD_PARAMETER_FLOAT;
 208
 209         bot_cmd_string[BOT_CMD_IMPULSE] = "impulse";
 210         bot_cmd_parm_type[BOT_CMD_IMPULSE] = BOT_CMD_PARAMETER_FLOAT;
 211
 212         bot_cmd_string[BOT_CMD_WAIT_UNTIL] = "wait_until";
 213         bot_cmd_parm_type[BOT_CMD_WAIT_UNTIL] = BOT_CMD_PARAMETER_FLOAT;
 214
 215         bot_cmd_string[BOT_CMD_BARRIER] = "barrier";
 216         bot_cmd_parm_type[BOT_CMD_BARRIER] = BOT_CMD_PARAMETER_NONE;
 217
 218         bot_cmd_string[BOT_CMD_CONSOLE] = "console";
 219         bot_cmd_parm_type[BOT_CMD_CONSOLE] = BOT_CMD_PARAMETER_STRING;
 220
 221         bot_cmd_string[BOT_CMD_SOUND] = "sound";
 222         bot_cmd_parm_type[BOT_CMD_SOUND] = BOT_CMD_PARAMETER_STRING;
 223
 224         bot_cmd_string[BOT_CMD_DEBUG_ASSERT_CANFIRE] = "debug_assert_canfire";
 225         bot_cmd_parm_type[BOT_CMD_DEBUG_ASSERT_CANFIRE] = BOT_CMD_PARAMETER_FLOAT;
 226
 227         bot_cmds_initialized = true;
 228 }
 229
 230 // Returns first bot with matching name
 231 entity find_bot_by_name(string name)
 232 {
 233         FOREACH_CLIENT(IS_BOT_CLIENT(it) && it.netname == name,
 234         {
 235                 return it;
 236         });
 237
 238         return NULL;
 239 }
 240
 241 // Returns a bot by number on list
 242 entity find_bot_by_number(float number)
 243 {
 244         entity bot;
 245         float c = 0;
 246
 247         if(!number)
 248                 return NULL;
 249
 250         bot = findchainflags(flags, FL_CLIENT); // TODO: doesn't findchainflags loop backwards through entities?
 251         while (bot)
 252         {
 253                 if(IS_BOT_CLIENT(bot))
 254                 {
 255                         if(++c==number)
 256                                 return bot;
 257                 }
 258                 bot = bot.chain;
 259         }
 260
 261         return NULL;
 262 }
 263
 264 float bot_decodecommand(string cmdstring)
 265 {
 266         float cmd_parm_type;
 267         float sp;
 268         string parm;
 269
 270         sp = strstrofs(cmdstring, " ", 0);
 271         if(sp < 0)
 272         {
 273                 parm = "";
 274         }
 275         else
 276         {
 277                 parm = substring(cmdstring, sp + 1, -1);
 278                 cmdstring = substring(cmdstring, 0, sp);
 279         }
 280
 281         if(!bot_cmds_initialized)
 282                 bot_commands_init();
 283
 284         int i;
 285         for(i=1;i<BOT_CMD_COUNTER;++i)
 286         {
 287                 if(bot_cmd_string[i]!=cmdstring)
 288                         continue;
 289
 290                 cmd_parm_type = bot_cmd_parm_type[i];
 291
 292                 if(cmd_parm_type!=BOT_CMD_PARAMETER_NONE&&parm=="")
 293                 {
 294                         LOG_INFO("ERROR: A parameter is required for this command\n");
 295                         return 0;
 296                 }
 297
 298                 // Load command into queue
 299                 bot_cmd.bot_cmd_type = i;
 300
 301                 // Attach parameter
 302                 switch(cmd_parm_type)
 303                 {
 304                         case BOT_CMD_PARAMETER_FLOAT:
 305                                 bot_cmd.bot_cmd_parm_float = stof(parm);
 306                                 break;
 307                         case BOT_CMD_PARAMETER_STRING:
 308                                 if(bot_cmd.bot_cmd_parm_string)
 309                                         strunzone(bot_cmd.bot_cmd_parm_string);
 310                                 bot_cmd.bot_cmd_parm_string = strzone(parm);
 311                                 break;
 312                         case BOT_CMD_PARAMETER_VECTOR:
 313                                 bot_cmd.bot_cmd_parm_vector = stov(parm);
 314                                 break;
 315                         default:
 316                                 break;
 317                 }
 318                 return 1;
 319         }
 320         LOG_INFO("ERROR: No such command '", cmdstring, "'\n");
 321         return 0;
 322 }
 323
 324 void bot_cmdhelp(string scmd)
 325 {
 326         int i, ntype;
 327         string stype;
 328
 329         if(!bot_cmds_initialized)
 330                 bot_commands_init();
 331
 332         for(i=1;i<BOT_CMD_COUNTER;++i)
 333         {
 334                 if(bot_cmd_string[i]!=scmd)
 335                         continue;
 336
 337                 ntype = bot_cmd_parm_type[i];
 338
 339                 switch(ntype)
 340                 {
 341                         case BOT_CMD_PARAMETER_FLOAT:
 342                                 stype = "float number";
 343                                 break;
 344                         case BOT_CMD_PARAMETER_STRING:
 345                                 stype = "string";
 346                                 break;
 347                         case BOT_CMD_PARAMETER_VECTOR:
 348                                 stype = "vector";
 349                                 break;
 350                         default:
 351                                 stype = "none";
 352                                 break;
 353                 }
 354
 355                 LOG_INFO(strcat("Command: ",bot_cmd_string[i],"\nParameter: <",stype,"> \n"));
 356
 357                 LOG_INFO("Description: ");
 358                 switch(i)
 359                 {
 360                         case BOT_CMD_PAUSE:
 361                                 LOG_INFO("Stops the bot completely. Any command other than 'continue' will be ignored.");
 362                                 break;
 363                         case BOT_CMD_CONTINUE:
 364                                 LOG_INFO("Disable paused status");
 365                                 break;
 366                         case BOT_CMD_WAIT:
 367                                 LOG_INFO("Pause command parsing and bot ai for N seconds. Pressed key will remain pressed");
 368                                 break;
 369                         case BOT_CMD_WAIT_UNTIL:
 370                                 LOG_INFO("Pause command parsing and bot ai until time is N from the last barrier. Pressed key will remain pressed");
 371                                 break;
 372                         case BOT_CMD_BARRIER:
 373                                 LOG_INFO("Waits till all bots that have a command queue reach this command. Pressed key will remain pressed");
 374                                 break;
 375                         case BOT_CMD_TURN:
 376                                 LOG_INFO("Look to the right or left N degrees. For turning to the left use positive numbers.");
 377                                 break;
 378                         case BOT_CMD_MOVETO:
 379                                 LOG_INFO("Walk to an specific coordinate on the map. Usage: moveto \"x y z\"");
 380                                 break;
 381                         case BOT_CMD_MOVETOTARGET:
 382                                 LOG_INFO("Walk to the specific target on the map");
 383                                 break;
 384                         case BOT_CMD_RESETGOAL:
 385                                 LOG_INFO("Resets the goal stack");
 386                                 break;
 387                         case BOT_CMD_CC:
 388                                 LOG_INFO("Execute client command. Examples: cc \"say something\"; cc god; cc \"name newnickname\"; cc kill;");
 389                                 break;
 390                         case BOT_CMD_IF:
 391                                 LOG_INFO("Perform simple conditional execution.\n");
 392                                 LOG_INFO("Syntax: \n");
 393                                 LOG_INFO("        sv_cmd .. if \"condition\"\n");
 394                                 LOG_INFO("        sv_cmd ..     <instruction if true>\n");
 395                                 LOG_INFO("        sv_cmd ..     <instruction if true>\n");
 396                                 LOG_INFO("        sv_cmd .. else\n");
 397                                 LOG_INFO("        sv_cmd ..     <instruction if false>\n");
 398                                 LOG_INFO("        sv_cmd ..     <instruction if false>\n");
 399                                 LOG_INFO("        sv_cmd .. fi\n");
 400                                 LOG_INFO("Conditions: a=b, a>b, a<b, a\t\t(spaces not allowed)\n");
 401                                 LOG_INFO("            Values in conditions can be numbers, cvars in the form cvar.cvar_string or special fields\n");
 402                                 LOG_INFO("Fields: health, speed, flagcarrier\n");
 403                                 LOG_INFO("Examples: if health>50; if health>cvar.g_balance_laser_primary_damage; if flagcarrier;");
 404                                 break;
 405                         case BOT_CMD_RESETAIM:
 406                                 LOG_INFO("Points the aim to the coordinates x,y 0,0");
 407                                 break;
 408                         case BOT_CMD_AIM:
 409                                 LOG_INFO("Move the aim x/y (horizontal/vertical) degrees relatives to the bot\n");
 410                                 LOG_INFO("There is a 3rd optional parameter telling in how many seconds the aim has to reach the new position\n");
 411                                 LOG_INFO("Examples: aim \"90 0\"        // Turn 90 degrees inmediately (positive numbers move to the left/up)\n");
 412                                 LOG_INFO("          aim \"0 90 2\"      // Will gradually look to the sky in the next two seconds");
 413                                 break;
 414                         case BOT_CMD_AIMTARGET:
 415                                 LOG_INFO("Points the aim to given target");
 416                                 break;
 417                         case BOT_CMD_PRESSKEY:
 418                                 LOG_INFO("Press one of the following keys: forward, backward, left, right, jump, crouch, attack1, attack2, use\n");
 419                                 LOG_INFO("Multiple keys can be pressed at time (with many presskey calls) and it will remain pressed until the command \"releasekey\" is called");
 420                                 LOG_INFO("Note: The script will not return the control to the bot ai until all keys are released");
 421                                 break;
 422                         case BOT_CMD_RELEASEKEY:
 423                                 LOG_INFO("Release previoulsy used keys. Use the parameter \"all\" to release all keys");
 424                                 break;
 425                         case BOT_CMD_SOUND:
 426                                 LOG_INFO("play sound file at bot location");
 427                                 break;
 428                         case BOT_CMD_DEBUG_ASSERT_CANFIRE:
 429                                 LOG_INFO("verify the state of the weapon entity");
 430                                 break;
 431                         default:
 432                                 LOG_INFO("This command has no description yet.");
 433                                 break;
 434                 }
 435                 LOG_INFO("\n");
 436         }
 437 }
 438
 439 void bot_list_commands()
 440 {
 441         int i;
 442         string ptype;
 443
 444         if(!bot_cmds_initialized)
 445                 bot_commands_init();
 446
 447         LOG_INFO("List of all available commands:\n");
 448         LOG_INFO("  Command - Parameter Type\n");
 449
 450         for(i=1;i<BOT_CMD_COUNTER;++i)
 451         {
 452                 switch(bot_cmd_parm_type[i])
 453                 {
 454                         case BOT_CMD_PARAMETER_FLOAT:
 455                                 ptype = "float number";
 456                                 break;
 457                         case BOT_CMD_PARAMETER_STRING:
 458                                 ptype = "string";
 459                                 break;
 460                         case BOT_CMD_PARAMETER_VECTOR:
 461                                 ptype = "vector";
 462                                 break;
 463                         default:
 464                                 ptype = "none";
 465                                 break;
 466                 }
 467                 LOG_INFO(strcat("  ",bot_cmd_string[i]," - <",ptype,"> \n"));
 468         }
 469 }
 470
 471 // Commands code
 472 .int bot_exec_status;
 473
 474 float bot_cmd_cc(entity this)
 475 {
 476         SV_ParseClientCommand(this, bot_cmd.bot_cmd_parm_string);
 477         return CMD_STATUS_FINISHED;
 478 }
 479
 480 float bot_cmd_impulse(entity this)
 481 {
 482         this.impulse = bot_cmd.bot_cmd_parm_float;
 483         return CMD_STATUS_FINISHED;
 484 }
 485
 486 float bot_cmd_continue(entity this)
 487 {
 488         bot_relinkplayerlist();
 489         this.bot_exec_status &= ~BOT_EXEC_STATUS_PAUSED;
 490         return CMD_STATUS_FINISHED;
 491 }
 492
 493 .float bot_cmd_wait_time;
 494 float bot_cmd_wait(entity this)
 495 {
 496         if(this.bot_exec_status & BOT_EXEC_STATUS_WAITING)
 497         {
 498                 if(time>=this.bot_cmd_wait_time)
 499                 {
 500                         this.bot_exec_status &= ~BOT_EXEC_STATUS_WAITING;
 501                         return CMD_STATUS_FINISHED;
 502                 }
 503                 else
 504                         return CMD_STATUS_EXECUTING;
 505         }
 506
 507         this.bot_cmd_wait_time = time + bot_cmd.bot_cmd_parm_float;
 508         this.bot_exec_status |= BOT_EXEC_STATUS_WAITING;
 509         return CMD_STATUS_EXECUTING;
 510 }
 511
 512 float bot_cmd_wait_until(entity this)
 513 {
 514         if(time < bot_cmd.bot_cmd_parm_float + bot_barriertime)
 515         {
 516                 this.bot_exec_status |= BOT_EXEC_STATUS_WAITING;
 517                 return CMD_STATUS_EXECUTING;
 518         }
 519         this.bot_exec_status &= ~BOT_EXEC_STATUS_WAITING;
 520         return CMD_STATUS_FINISHED;
 521 }
 522
 523 float bot_cmd_barrier(entity this)
 524 {
 525         // 0 = no barrier, 1 = waiting, 2 = waiting finished
 526
 527         if(this.bot_barrier == 0) // initialization
 528         {
 529                 this.bot_barrier = 1;
 530
 531                 //this.colormod = '4 4 0';
 532         }
 533
 534         if(this.bot_barrier == 1) // find other bots
 535         {
 536                 FOREACH_CLIENT(it.isbot, LAMBDA(
 537                         if(it.bot_cmdqueuebuf_allocated)
 538                         if(it.bot_barrier != 1)
 539                                 return CMD_STATUS_EXECUTING; // not all are at the barrier yet
 540                 ));
 541
 542                 // all bots hit the barrier!
 543
 544                 // acknowledge barrier
 545                 FOREACH_CLIENT(it.isbot, LAMBDA(it.bot_barrier = 2));
 546
 547                 bot_barriertime = time;
 548         }
 549
 550         // if we get here, the barrier is finished
 551         // so end it...
 552         this.bot_barrier = 0;
 553         //this.colormod = '0 0 0';
 554
 555         return CMD_STATUS_FINISHED;
 556 }
 557
 558 float bot_cmd_turn(entity this)
 559 {
 560         this.v_angle_y = this.v_angle.y + bot_cmd.bot_cmd_parm_float;
 561         this.v_angle_y = this.v_angle.y - floor(this.v_angle.y / 360) * 360;
 562         return CMD_STATUS_FINISHED;
 563 }
 564
 565 float bot_cmd_select_weapon(entity this)
 566 {
 567         float id = bot_cmd.bot_cmd_parm_float;
 568
 569         if(id < WEP_FIRST || id > WEP_LAST)
 570                 return CMD_STATUS_ERROR;
 571
 572         if(client_hasweapon(this, Weapons_from(id), true, false))
 573                 PS(this).m_switchweapon = Weapons_from(id);
 574         else
 575                 return CMD_STATUS_ERROR;
 576
 577         return CMD_STATUS_FINISHED;
 578 }
 579
 580 .int bot_cmd_condition_status;
 581
 582 const int CMD_CONDITION_NONE = 0;
 583 const int CMD_CONDITION_true = 1;
 584 const int CMD_CONDITION_false = 2;
 585 const int CMD_CONDITION_true_BLOCK = 4;
 586 const int CMD_CONDITION_false_BLOCK = 8;
 587
 588 float bot_cmd_eval(entity this, string expr)
 589 {
 590         // Search for numbers
 591         if(IS_DIGIT(substring(expr, 0, 1)))
 592                 return stof(expr);
 593
 594         // Search for cvars
 595         if(substring(expr, 0, 5)=="cvar.")
 596                 return cvar(substring(expr, 5, strlen(expr)));
 597
 598         // Search for fields
 599         switch(expr)
 600         {
 601                 case "health":
 602                         return this.health;
 603                 case "speed":
 604                         return vlen(this.velocity);
 605                 case "flagcarrier":
 606                         return ((this.flagcarried!=NULL));
 607         }
 608
 609         LOG_INFO(strcat("ERROR: Unable to convert the expression '",expr,"' into a numeric value\n"));
 610         return 0;
 611 }
 612
 613 float bot_cmd_if(entity this)
 614 {
 615         string expr, val_a, val_b;
 616         float cmpofs;
 617
 618         if(this.bot_cmd_condition_status != CMD_CONDITION_NONE)
 619         {
 620                 // Only one "if" block is allowed at time
 621                 LOG_INFO("ERROR: Only one conditional block can be processed at time");
 622                 bot_clearqueue(this);
 623                 return CMD_STATUS_ERROR;
 624         }
 625
 626         this.bot_cmd_condition_status |= CMD_CONDITION_true_BLOCK;
 627
 628         // search for operators
 629         expr = bot_cmd.bot_cmd_parm_string;
 630
 631         cmpofs = strstrofs(expr,"=",0);
 632
 633         if(cmpofs>0)
 634         {
 635                 val_a = substring(expr,0,cmpofs);
 636                 val_b = substring(expr,cmpofs+1,strlen(expr));
 637
 638                 if(bot_cmd_eval(this, val_a)==bot_cmd_eval(this, val_b))
 639                         this.bot_cmd_condition_status |= CMD_CONDITION_true;
 640                 else
 641                         this.bot_cmd_condition_status |= CMD_CONDITION_false;
 642
 643                 return CMD_STATUS_FINISHED;
 644         }
 645
 646         cmpofs = strstrofs(expr,">",0);
 647
 648         if(cmpofs>0)
 649         {
 650                 val_a = substring(expr,0,cmpofs);
 651                 val_b = substring(expr,cmpofs+1,strlen(expr));
 652
 653                 if(bot_cmd_eval(this, val_a)>bot_cmd_eval(this, val_b))
 654                         this.bot_cmd_condition_status |= CMD_CONDITION_true;
 655                 else
 656                         this.bot_cmd_condition_status |= CMD_CONDITION_false;
 657
 658                 return CMD_STATUS_FINISHED;
 659         }
 660
 661         cmpofs = strstrofs(expr,"<",0);
 662
 663         if(cmpofs>0)
 664         {
 665                 val_a = substring(expr,0,cmpofs);
 666                 val_b = substring(expr,cmpofs+1,strlen(expr));
 667
 668                 if(bot_cmd_eval(this, val_a)<bot_cmd_eval(this, val_b))
 669                         this.bot_cmd_condition_status |= CMD_CONDITION_true;
 670                 else
 671                         this.bot_cmd_condition_status |= CMD_CONDITION_false;
 672
 673                 return CMD_STATUS_FINISHED;
 674         }
 675
 676         if(bot_cmd_eval(this, expr))
 677                 this.bot_cmd_condition_status |= CMD_CONDITION_true;
 678         else
 679                 this.bot_cmd_condition_status |= CMD_CONDITION_false;
 680
 681         return CMD_STATUS_FINISHED;
 682 }
 683
 684 float bot_cmd_else(entity this)
 685 {
 686         this.bot_cmd_condition_status &= ~CMD_CONDITION_true_BLOCK;
 687         this.bot_cmd_condition_status |= CMD_CONDITION_false_BLOCK;
 688         return CMD_STATUS_FINISHED;
 689 }
 690
 691 float bot_cmd_fi(entity this)
 692 {
 693         this.bot_cmd_condition_status = CMD_CONDITION_NONE;
 694         return CMD_STATUS_FINISHED;
 695 }
 696
 697 float bot_cmd_resetaim(entity this)
 698 {
 699         this.v_angle = '0 0 0';
 700         return CMD_STATUS_FINISHED;
 701 }
 702
 703 .float bot_cmd_aim_begintime;
 704 .float bot_cmd_aim_endtime;
 705 .vector bot_cmd_aim_begin;
 706 .vector bot_cmd_aim_end;
 707
 708 float bot_cmd_aim(entity this)
 709 {
 710         // Current direction
 711         if(this.bot_cmd_aim_endtime)
 712         {
 713                 float progress;
 714
 715                 progress = min(1 - (this.bot_cmd_aim_endtime - time) / (this.bot_cmd_aim_endtime - this.bot_cmd_aim_begintime),1);
 716                 this.v_angle = this.bot_cmd_aim_begin + ((this.bot_cmd_aim_end - this.bot_cmd_aim_begin) * progress);
 717
 718                 if(time>=this.bot_cmd_aim_endtime)
 719                 {
 720                         this.bot_cmd_aim_endtime = 0;
 721                         return CMD_STATUS_FINISHED;
 722                 }
 723                 else
 724                         return CMD_STATUS_EXECUTING;
 725         }
 726
 727         // New aiming direction
 728         string parms;
 729         float tokens, step;
 730
 731         parms = bot_cmd.bot_cmd_parm_string;
 732
 733         tokens = tokenizebyseparator(parms, " ");
 734
 735         if(tokens<2||tokens>3)
 736                 return CMD_STATUS_ERROR;
 737
 738         step = (tokens == 3) ? stof(argv(2)) : 0;
 739
 740         if(step == 0)
 741         {
 742                 this.v_angle_x -= stof(argv(1));
 743                 this.v_angle_y += stof(argv(0));
 744                 return CMD_STATUS_FINISHED;
 745         }
 746
 747         this.bot_cmd_aim_begin = this.v_angle;
 748
 749         this.bot_cmd_aim_end_x = this.v_angle.x - stof(argv(1));
 750         this.bot_cmd_aim_end_y = this.v_angle.y + stof(argv(0));
 751         this.bot_cmd_aim_end_z = 0;
 752
 753         this.bot_cmd_aim_begintime = time;
 754         this.bot_cmd_aim_endtime = time + step;
 755
 756         return CMD_STATUS_EXECUTING;
 757 }
 758
 759 float bot_cmd_aimtarget(entity this)
 760 {
 761         if(this.bot_cmd_aim_endtime)
 762         {
 763                 return bot_cmd_aim(this);
 764         }
 765
 766         entity e;
 767         string parms;
 768         vector v;
 769         float tokens, step;
 770
 771         parms = bot_cmd.bot_cmd_parm_string;
 772
 773         tokens = tokenizebyseparator(parms, " ");
 774
 775         e = bot_getplace(this, argv(0));
 776         if(!e)
 777                 return CMD_STATUS_ERROR;
 778
 779         v = e.origin + (e.mins + e.maxs) * 0.5;
 780
 781         if(tokens==1)
 782         {
 783                 this.v_angle = vectoangles(v - (this.origin + this.view_ofs));
 784                 this.v_angle_x = -this.v_angle.x;
 785                 return CMD_STATUS_FINISHED;
 786         }
 787
 788         if(tokens<1||tokens>2)
 789                 return CMD_STATUS_ERROR;
 790
 791         step = stof(argv(1));
 792
 793         this.bot_cmd_aim_begin = this.v_angle;
 794         this.bot_cmd_aim_end = vectoangles(v - (this.origin + this.view_ofs));
 795         this.bot_cmd_aim_end_x = -this.bot_cmd_aim_end.x;
 796
 797         this.bot_cmd_aim_begintime = time;
 798         this.bot_cmd_aim_endtime = time + step;
 799
 800         return CMD_STATUS_EXECUTING;
 801 }
 802
 803 .int bot_cmd_keys;
 804
 805 const int BOT_CMD_KEY_NONE              = 0;
 806 const int BOT_CMD_KEY_FORWARD   = BIT(0);
 807 const int BOT_CMD_KEY_BACKWARD  = BIT(1);
 808 const int BOT_CMD_KEY_RIGHT     = BIT(2);
 809 const int BOT_CMD_KEY_LEFT              = BIT(3);
 810 const int BOT_CMD_KEY_JUMP              = BIT(4);
 811 const int BOT_CMD_KEY_ATTACK1   = BIT(5);
 812 const int BOT_CMD_KEY_ATTACK2   = BIT(6);
 813 const int BOT_CMD_KEY_USE               = BIT(7);
 814 const int BOT_CMD_KEY_HOOK              = BIT(8);
 815 const int BOT_CMD_KEY_CROUCH    = BIT(9);
 816 const int BOT_CMD_KEY_CHAT              = BIT(10);
 817
 818 bool bot_presskeys(entity this)
 819 {
 820         this.movement = '0 0 0';
 821         PHYS_INPUT_BUTTON_JUMP(this) = false;
 822         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 823         PHYS_INPUT_BUTTON_ATCK(this) = false;
 824         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 825         PHYS_INPUT_BUTTON_USE(this) = false;
 826         PHYS_INPUT_BUTTON_HOOK(this) = false;
 827         PHYS_INPUT_BUTTON_CHAT(this) = false;
 828
 829         if(this.bot_cmd_keys == BOT_CMD_KEY_NONE)
 830                 return false;
 831
 832         if(this.bot_cmd_keys & BOT_CMD_KEY_FORWARD)
 833                 this.movement_x = autocvar_sv_maxspeed;
 834         else if(this.bot_cmd_keys & BOT_CMD_KEY_BACKWARD)
 835                 this.movement_x = -autocvar_sv_maxspeed;
 836
 837         if(this.bot_cmd_keys & BOT_CMD_KEY_RIGHT)
 838                 this.movement_y = autocvar_sv_maxspeed;
 839         else if(this.bot_cmd_keys & BOT_CMD_KEY_LEFT)
 840                 this.movement_y = -autocvar_sv_maxspeed;
 841
 842         if(this.bot_cmd_keys & BOT_CMD_KEY_JUMP)
 843                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 844
 845         if(this.bot_cmd_keys & BOT_CMD_KEY_CROUCH)
 846                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 847
 848         if(this.bot_cmd_keys & BOT_CMD_KEY_ATTACK1)
 849                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 850
 851         if(this.bot_cmd_keys & BOT_CMD_KEY_ATTACK2)
 852                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 853
 854         if(this.bot_cmd_keys & BOT_CMD_KEY_USE)
 855                 PHYS_INPUT_BUTTON_USE(this) = true;
 856
 857         if(this.bot_cmd_keys & BOT_CMD_KEY_HOOK)
 858                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 859
 860         if(this.bot_cmd_keys & BOT_CMD_KEY_CHAT)
 861                 PHYS_INPUT_BUTTON_CHAT(this) = true;
 862
 863         return true;
 864 }
 865
 866
 867 float bot_cmd_keypress_handler(entity this, string key, float enabled)
 868 {
 869         switch(key)
 870         {
 871                 case "all":
 872                         if(enabled)
 873                                 this.bot_cmd_keys = power2of(20) - 1; // >:)
 874                         else
 875                                 this.bot_cmd_keys = BOT_CMD_KEY_NONE;
 876                 case "forward":
 877                         if(enabled)
 878                         {
 879                                 this.bot_cmd_keys |= BOT_CMD_KEY_FORWARD;
 880                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_BACKWARD;
 881                         }
 882                         else
 883                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_FORWARD;
 884                         break;
 885                 case "backward":
 886                         if(enabled)
 887                         {
 888                                 this.bot_cmd_keys |= BOT_CMD_KEY_BACKWARD;
 889                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_FORWARD;
 890                         }
 891                         else
 892                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_BACKWARD;
 893                         break;
 894                 case "left":
 895                         if(enabled)
 896                         {
 897                                 this.bot_cmd_keys |= BOT_CMD_KEY_LEFT;
 898                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_RIGHT;
 899                         }
 900                         else
 901                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_LEFT;
 902                         break;
 903                 case "right":
 904                         if(enabled)
 905                         {
 906                                 this.bot_cmd_keys |= BOT_CMD_KEY_RIGHT;
 907                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_LEFT;
 908                         }
 909                         else
 910                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_RIGHT;
 911                         break;
 912                 case "jump":
 913                         if(enabled)
 914                                 this.bot_cmd_keys |= BOT_CMD_KEY_JUMP;
 915                         else
 916                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_JUMP;
 917                         break;
 918                 case "crouch":
 919                         if(enabled)
 920                                 this.bot_cmd_keys |= BOT_CMD_KEY_CROUCH;
 921                         else
 922                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_CROUCH;
 923                         break;
 924                 case "attack1":
 925                         if(enabled)
 926                                 this.bot_cmd_keys |= BOT_CMD_KEY_ATTACK1;
 927                         else
 928                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_ATTACK1;
 929                         break;
 930                 case "attack2":
 931                         if(enabled)
 932                                 this.bot_cmd_keys |= BOT_CMD_KEY_ATTACK2;
 933                         else
 934                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_ATTACK2;
 935                         break;
 936                 case "use":
 937                         if(enabled)
 938                                 this.bot_cmd_keys |= BOT_CMD_KEY_USE;
 939                         else
 940                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_USE;
 941                         break;
 942                 case "hook":
 943                         if(enabled)
 944                                 this.bot_cmd_keys |= BOT_CMD_KEY_HOOK;
 945                         else
 946                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_HOOK;
 947                         break;
 948                 case "chat":
 949                         if(enabled)
 950                                 this.bot_cmd_keys |= BOT_CMD_KEY_CHAT;
 951                         else
 952                                 this.bot_cmd_keys &= ~BOT_CMD_KEY_CHAT;
 953                         break;
 954                 default:
 955                         break;
 956         }
 957
 958         return CMD_STATUS_FINISHED;
 959 }
 960
 961 float bot_cmd_presskey(entity this)
 962 {
 963         string key;
 964
 965         key = bot_cmd.bot_cmd_parm_string;
 966
 967         bot_cmd_keypress_handler(this, key,true);
 968
 969         return CMD_STATUS_FINISHED;
 970 }
 971
 972 float bot_cmd_releasekey(entity this)
 973 {
 974         string key;
 975
 976         key = bot_cmd.bot_cmd_parm_string;
 977
 978         return bot_cmd_keypress_handler(this, key,false);
 979 }
 980
 981 float bot_cmd_pause(entity this)
 982 {
 983         PHYS_INPUT_BUTTON_DRAG(this) = false;
 984         PHYS_INPUT_BUTTON_USE(this) = false;
 985         PHYS_INPUT_BUTTON_ATCK(this) = false;
 986         PHYS_INPUT_BUTTON_JUMP(this) = false;
 987         PHYS_INPUT_BUTTON_HOOK(this) = false;
 988         PHYS_INPUT_BUTTON_CHAT(this) = false;
 989         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 990         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 991
 992         this.movement = '0 0 0';
 993         this.bot_cmd_keys = BOT_CMD_KEY_NONE;
 994
 995         bot_clear(this);
 996         this.bot_exec_status |= BOT_EXEC_STATUS_PAUSED;
 997         return CMD_STATUS_FINISHED;
 998 }
 999
1000 float bot_cmd_moveto(entity this)
1001 {
1002         return this.cmd_moveto(this, bot_cmd.bot_cmd_parm_vector);
1003 }
1004
1005 float bot_cmd_movetotarget(entity this)
1006 {
1007         entity e;
1008         e = bot_getplace(this, bot_cmd.bot_cmd_parm_string);
1009         if(!e)
1010                 return CMD_STATUS_ERROR;
1011         return this.cmd_moveto(this, e.origin + (e.mins + e.maxs) * 0.5);
1012 }
1013
1014 float bot_cmd_resetgoal(entity this)
1015 {
1016         return this.cmd_resetgoal(this);
1017 }
1018
1019
1020 float bot_cmd_sound(entity this)
1021 {
1022         string f;
1023         f = bot_cmd.bot_cmd_parm_string;
1024
1025         float n = tokenizebyseparator(f, " ");
1026
1027         string sample = f;
1028         float chan = CH_WEAPON_B;
1029         float vol = VOL_BASE;
1030         float atten = ATTEN_MIN;
1031
1032         if(n >= 1)
1033                 sample = argv(n - 1);
1034         if(n >= 2)
1035                 chan = stof(argv(0));
1036         if(n >= 3)
1037                 vol = stof(argv(1));
1038         if(n >= 4)
1039                 atten = stof(argv(2));
1040
1041         precache_sound(f);
1042         _sound(this, chan, sample, vol, atten);
1043
1044         return CMD_STATUS_FINISHED;
1045 }
1046
1047 .entity tuba_note;
1048 float bot_cmd_debug_assert_canfire(entity this)
1049 {
1050         float f = bot_cmd.bot_cmd_parm_float;
1051
1052         int slot = 0; // TODO: unhardcode?
1053         .entity weaponentity = weaponentities[slot];
1054         if(this.(weaponentity).state != WS_READY)
1055         {
1056                 if(f)
1057                 {
1058                         this.colormod = '0 8 8';
1059                         LOG_INFO("Bot ", this.netname, " using ", this.weaponname, " wants to fire, inhibited by weaponentity state\n");
1060                 }
1061         }
1062         else if(ATTACK_FINISHED(this, slot) > time)
1063         {
1064                 if(f)
1065                 {
1066                         this.colormod = '8 0 8';
1067                         LOG_INFO("Bot ", this.netname, " using ", this.weaponname, " wants to fire, inhibited by ATTACK_FINISHED (", ftos(ATTACK_FINISHED(this, slot) - time), " seconds left)\n");
1068                 }
1069         }
1070         else if(this.tuba_note)
1071         {
1072                 if(f)
1073                 {
1074                         this.colormod = '8 0 0';
1075                         LOG_INFO("Bot ", this.netname, " using ", this.weaponname, " wants to fire, bot still has an active tuba note\n");
1076                 }
1077         }
1078         else
1079         {
1080                 if(!f)
1081                 {
1082                         this.colormod = '8 8 0';
1083                         LOG_INFO("Bot ", this.netname, " using ", this.weaponname, " thinks it has fired, but apparently did not; ATTACK_FINISHED says ", ftos(ATTACK_FINISHED(this, slot) - time), " seconds left\n");
1084                 }
1085         }
1086
1087         return CMD_STATUS_FINISHED;
1088 }
1089
1090 //
1091
1092 void bot_command_executed(entity this, bool rm)
1093 {
1094         entity cmd;
1095
1096         cmd = bot_cmd;
1097
1098         if(rm)
1099                 bot_dequeuecommand(this, this.bot_cmd_execution_index);
1100
1101         this.bot_cmd_execution_index++;
1102 }
1103
1104 void bot_setcurrentcommand(entity this)
1105 {
1106         bot_cmd = NULL;
1107
1108         if(!this.bot_cmd_current)
1109         {
1110                 this.bot_cmd_current = new_pure(bot_cmd);
1111         }
1112
1113         bot_cmd = this.bot_cmd_current;
1114         if(bot_cmd.bot_cmd_index != this.bot_cmd_execution_index || this.bot_cmd_execution_index == 0)
1115         {
1116                 if(bot_havecommand(this, this.bot_cmd_execution_index))
1117                 {
1118                         string cmdstring;
1119                         cmdstring = bot_readcommand(this, this.bot_cmd_execution_index);
1120                         if(bot_decodecommand(cmdstring))
1121                         {
1122                                 bot_cmd.owner = this;
1123                                 bot_cmd.bot_cmd_index = this.bot_cmd_execution_index;
1124                         }
1125                         else
1126                         {
1127                                 // Invalid command, remove from queue
1128                                 bot_cmd = NULL;
1129                                 bot_dequeuecommand(this, this.bot_cmd_execution_index);
1130                                 this.bot_cmd_execution_index++;
1131                         }
1132                 }
1133                 else
1134                         bot_cmd = NULL;
1135         }
1136 }
1137
1138 void bot_resetqueues()
1139 {
1140         FOREACH_CLIENT(it.isbot, LAMBDA(
1141                 it.bot_cmd_execution_index = 0;
1142                 bot_clearqueue(it);
1143                 // also, cancel all barriers
1144                 it.bot_barrier = 0;
1145                 for(int i = 0; i < it.bot_places_count; ++i)
1146                 {
1147                         strunzone(it.(bot_placenames[i]));
1148                         it.(bot_placenames[i]) = string_null;
1149                 }
1150                 it.bot_places_count = 0;
1151         ));
1152
1153         bot_barriertime = time;
1154 }
1155
1156 // Here we map commands to functions and deal with complex interactions between commands and execution states
1157 // NOTE: Of course you need to include your commands here too :)
1158 float bot_execute_commands_once(entity this)
1159 {
1160         float status, ispressingkey;
1161
1162         // Find command
1163         bot_setcurrentcommand(this);
1164
1165         // Ignore all commands except continue when the bot is paused
1166         if(!(self.bot_exec_status & BOT_EXEC_STATUS_PAUSED))
1167         {
1168                 // if we have no bot command, better return
1169                 // old logic kept pressing previously pressed keys, but that has problems
1170                 // (namely, it means you cannot make a bot "normal" ever again)
1171                 // to keep a bot walking for a while, use the "wait" bot command
1172                 if(bot_cmd == world)
1173                         return 0;
1174         }
1175         else if(bot_cmd.bot_cmd_type != BOT_CMD_CONTINUE)
1176         {
1177                 if(bot_cmd.bot_cmd_type!=BOT_CMD_NULL)
1178                 {
1179                         bot_command_executed(this, true);
1180                         LOG_INFO( "WARNING: Commands are ignored while the bot is paused. Use the command 'continue' instead.\n");
1181                 }
1182                 return 1;
1183         }
1184
1185         // Keep pressing keys raised by the "presskey" command
1186         ispressingkey = boolean(bot_presskeys(this));
1187
1188         // Handle conditions
1189         if (!(bot_cmd.bot_cmd_type==BOT_CMD_FI||bot_cmd.bot_cmd_type==BOT_CMD_ELSE))
1190         if(this.bot_cmd_condition_status & CMD_CONDITION_true && this.bot_cmd_condition_status & CMD_CONDITION_false_BLOCK)
1191         {
1192                 bot_command_executed(this, true);
1193                 return -1;
1194         }
1195         else if(this.bot_cmd_condition_status & CMD_CONDITION_false && this.bot_cmd_condition_status & CMD_CONDITION_true_BLOCK)
1196         {
1197                 bot_command_executed(this, true);
1198                 return -1;
1199         }
1200
1201         // Map commands to functions
1202         switch(bot_cmd.bot_cmd_type)
1203         {
1204                 case BOT_CMD_NULL:
1205                         return ispressingkey;
1206                         //break;
1207                 case BOT_CMD_PAUSE:
1208                         status = bot_cmd_pause(this);
1209                         break;
1210                 case BOT_CMD_CONTINUE:
1211                         status = bot_cmd_continue(this);
1212                         break;
1213                 case BOT_CMD_WAIT:
1214                         status = bot_cmd_wait(this);
1215                         break;
1216                 case BOT_CMD_WAIT_UNTIL:
1217                         status = bot_cmd_wait_until(this);
1218                         break;
1219                 case BOT_CMD_TURN:
1220                         status = bot_cmd_turn(this);
1221                         break;
1222                 case BOT_CMD_MOVETO:
1223                         status = bot_cmd_moveto(this);
1224                         break;
1225                 case BOT_CMD_MOVETOTARGET:
1226                         status = bot_cmd_movetotarget(this);
1227                         break;
1228                 case BOT_CMD_RESETGOAL:
1229                         status = bot_cmd_resetgoal(this);
1230                         break;
1231                 case BOT_CMD_CC:
1232                         status = bot_cmd_cc(this);
1233                         break;
1234                 case BOT_CMD_IF:
1235                         status = bot_cmd_if(this);
1236                         break;
1237                 case BOT_CMD_ELSE:
1238                         status = bot_cmd_else(this);
1239                         break;
1240                 case BOT_CMD_FI:
1241                         status = bot_cmd_fi(this);
1242                         break;
1243                 case BOT_CMD_RESETAIM:
1244                         status = bot_cmd_resetaim(this);
1245                         break;
1246                 case BOT_CMD_AIM:
1247                         status = bot_cmd_aim(this);
1248                         break;
1249                 case BOT_CMD_AIMTARGET:
1250                         status = bot_cmd_aimtarget(this);
1251                         break;
1252                 case BOT_CMD_PRESSKEY:
1253                         status = bot_cmd_presskey(this);
1254                         break;
1255                 case BOT_CMD_RELEASEKEY:
1256                         status = bot_cmd_releasekey(this);
1257                         break;
1258                 case BOT_CMD_SELECTWEAPON:
1259                         status = bot_cmd_select_weapon(this);
1260                         break;
1261                 case BOT_CMD_IMPULSE:
1262                         status = bot_cmd_impulse(this);
1263                         break;
1264                 case BOT_CMD_BARRIER:
1265                         status = bot_cmd_barrier(this);
1266                         break;
1267                 case BOT_CMD_CONSOLE:
1268                         localcmd(strcat(bot_cmd.bot_cmd_parm_string, "\n"));
1269                         status = CMD_STATUS_FINISHED;
1270                         break;
1271                 case BOT_CMD_SOUND:
1272                         status = bot_cmd_sound(this);
1273                         break;
1274                 case BOT_CMD_DEBUG_ASSERT_CANFIRE:
1275                         status = bot_cmd_debug_assert_canfire(this);
1276                         break;
1277                 default:
1278                         LOG_INFO(strcat("ERROR: Invalid command on queue with id '",ftos(bot_cmd.bot_cmd_type),"'\n"));
1279                         return 0;
1280         }
1281
1282         if (status==CMD_STATUS_ERROR)
1283                 LOG_INFO(strcat("ERROR: The command '",bot_cmd_string[bot_cmd.bot_cmd_type],"' returned an error status\n"));
1284
1285         // Move execution pointer
1286         if(status==CMD_STATUS_EXECUTING)
1287         {
1288                 return 1;
1289         }
1290         else
1291         {
1292                 if(autocvar_g_debug_bot_commands)
1293                 {
1294                         string parms;
1295
1296                         switch(bot_cmd_parm_type[bot_cmd.bot_cmd_type])
1297                         {
1298                                 case BOT_CMD_PARAMETER_FLOAT:
1299                                         parms = ftos(bot_cmd.bot_cmd_parm_float);
1300                                         break;
1301                                 case BOT_CMD_PARAMETER_STRING:
1302                                         parms = bot_cmd.bot_cmd_parm_string;
1303                                         break;
1304                                 case BOT_CMD_PARAMETER_VECTOR:
1305                                         parms = vtos(bot_cmd.bot_cmd_parm_vector);
1306                                         break;
1307                                 default:
1308                                         parms = "";
1309                                         break;
1310                         }
1311                         clientcommand(this,strcat("say ^7", bot_cmd_string[bot_cmd.bot_cmd_type]," ",parms,"\n"));
1312                 }
1313
1314                 bot_command_executed(this, true);
1315         }
1316
1317         if(status == CMD_STATUS_FINISHED)
1318                 return -1;
1319
1320         return CMD_STATUS_ERROR;
1321 }
1322
1323 // This function should be (the only) called directly from the bot ai loop
1324 int bot_execute_commands(entity this)
1325 {
1326         int f;
1327         do
1328         {
1329                 f = bot_execute_commands_once(this);
1330         }
1331         while(f < 0);
1332         return f;
1333 }