qcsrc/server/bot/navigation.qc

   1
   2 // rough simulation of walking from one point to another to test if a path
   3 // can be traveled, used for waypoint linking and havocbot
   4
   5 float tracewalk(entity e, vector start, vector m1, vector m2, vector end, float movemode)
   6 {
   7         local vector org;
   8         local vector move;
   9         local vector dir;
  10         local float dist;
  11         local float totaldist;
  12         local float stepdist;
  13         local float yaw;
  14         local float ignorehazards;
  15         local float swimming;
  16
  17         if(autocvar_bot_debug_tracewalk)
  18         {
  19                 debugresetnodes();
  20                 debugnode(start);
  21         }
  22
  23         move = end - start;
  24         move_z = 0;
  25         org = start;
  26         dist = totaldist = vlen(move);
  27         dir = normalize(move);
  28         stepdist = 32;
  29         ignorehazards = FALSE;
  30
  31         // Analyze starting point
  32         traceline(start, start, MOVE_NORMAL, e);
  33         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  34                 ignorehazards = TRUE;
  35         else
  36         {
  37                 traceline( start, start + '0 0 -65536', MOVE_NORMAL, e);
  38                 if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  39                 {
  40                         ignorehazards = TRUE;
  41                         swimming = TRUE;
  42                 }
  43         }
  44         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
  45         if (trace_startsolid)
  46         {
  47                 // Bad start
  48                 if(autocvar_bot_debug_tracewalk)
  49                         debugnodestatus(start, DEBUG_NODE_FAIL);
  50
  51                 //print("tracewalk: ", vtos(start), " is a bad start\n");
  52                 return FALSE;
  53         }
  54
  55         // Movement loop
  56         yaw = vectoyaw(move);
  57         move = end - org;
  58         for (;;)
  59         {
  60                 if (boxesoverlap(end, end, org + m1 + '-1 -1 -1', org + m2 + '1 1 1'))
  61                 {
  62                         // Succeeded
  63                         if(autocvar_bot_debug_tracewalk)
  64                                 debugnodestatus(org, DEBUG_NODE_SUCCESS);
  65
  66                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
  67                         return TRUE;
  68                 }
  69                 if(autocvar_bot_debug_tracewalk)
  70                         debugnode(org);
  71
  72                 if (dist <= 0)
  73                         break;
  74                 if (stepdist > dist)
  75                         stepdist = dist;
  76                 dist = dist - stepdist;
  77                 traceline(org, org, MOVE_NORMAL, e);
  78                 if (!ignorehazards)
  79                 {
  80                         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  81                         {
  82                                 // hazards blocking path
  83                                 if(autocvar_bot_debug_tracewalk)
  84                                         debugnodestatus(org, DEBUG_NODE_FAIL);
  85
  86                                 //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
  87                                 return FALSE;
  88                         }
  89                 }
  90                 if (trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
  91                 {
  92                         move = normalize(end - org);
  93                         tracebox(org, m1, m2, org + move * stepdist, movemode, e);
  94
  95                         if(autocvar_bot_debug_tracewalk)
  96                                 debugnode(trace_endpos);
  97
  98                         if (trace_fraction < 1)
  99                         {
 100                                 swimming = TRUE;
 101                                 org = trace_endpos - normalize(org - trace_endpos) * stepdist;
 102                                 for(; org_z < end_z + self.maxs_z; org_z += stepdist)
 103                                 {
 104                                                 if(autocvar_bot_debug_tracewalk)
 105                                                         debugnode(org);
 106
 107                                         if(pointcontents(org) == CONTENT_EMPTY)
 108                                                         break;
 109                                 }
 110
 111                                 if not (pointcontents(org + '0 0 1') == CONTENT_EMPTY)
 112                                 {
 113                                         if(autocvar_bot_debug_tracewalk)
 114                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 115
 116                                         return FALSE;
 117                                         //print("tracewalk: ", vtos(start), " failed under water\n");
 118                                 }
 119                                 continue;
 120
 121                         }
 122                         else
 123                                 org = trace_endpos;
 124                 }
 125                 else
 126                 {
 127                         move = dir * stepdist + org;
 128                         tracebox(org, m1, m2, move, movemode, e);
 129
 130                         if(autocvar_bot_debug_tracewalk)
 131                                 debugnode(trace_endpos);
 132
 133                         // hit something
 134                         if (trace_fraction < 1)
 135                         {
 136                                 // check if we can walk over this obstacle
 137                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 138                                 if (trace_fraction < 1 || trace_startsolid)
 139                                 {
 140                                         if(autocvar_bot_debug_tracewalk)
 141                                                 debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 142
 143                                         // check for doors
 144                                         traceline( org, move, movemode, e);
 145                                         if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 146                                         {
 147                                                 local vector nextmove;
 148                                                 move = trace_endpos;
 149                                                 while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 150                                                 {
 151                                                         nextmove = move + (dir * stepdist);
 152                                                         traceline( move, nextmove, movemode, e);
 153                                                         move = nextmove;
 154                                                 }
 155                                         }
 156                                         else
 157                                         {
 158                                                 if(autocvar_bot_debug_tracewalk)
 159                                                         debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 160
 161                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 162                                                 //te_explosion(trace_endpos);
 163                                                 //print(ftos(e.dphitcontentsmask), "\n");
 164                                                 return FALSE; // failed
 165                                         }
 166                                 }
 167                                 else
 168                                         move = trace_endpos;
 169                         }
 170                         else
 171                                 move = trace_endpos;
 172
 173                         // trace down from stepheight as far as possible and move there,
 174                         // if this starts in solid we try again without the stepup, and
 175                         // if that also fails we assume it is a wall
 176                         // (this is the same logic as the Quake walkmove function used)
 177                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 178
 179                         // moved successfully
 180                         if(swimming)
 181                         {
 182                                 local float c;
 183                                 c = pointcontents(org + '0 0 1');
 184                                 if not(c == CONTENT_WATER || c == CONTENT_LAVA || c == CONTENT_SLIME)
 185                                         swimming = FALSE;
 186                                 else
 187                                         continue;
 188                         }
 189
 190                         org = trace_endpos;
 191                 }
 192         }
 193
 194         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 195
 196         // moved but didn't arrive at the intended destination
 197         if(autocvar_bot_debug_tracewalk)
 198                 debugnodestatus(org, DEBUG_NODE_FAIL);
 199
 200         return FALSE;
 201 };
 202
 203 /////////////////////////////////////////////////////////////////////////////
 204 // goal stack
 205 /////////////////////////////////////////////////////////////////////////////
 206
 207 // completely empty the goal stack, used when deciding where to go
 208 void navigation_clearroute()
 209 {
 210         //print("bot ", etos(self), " clear\n");
 211         self.navigation_hasgoals = FALSE;
 212         self.goalcurrent = world;
 213         self.goalstack01 = world;
 214         self.goalstack02 = world;
 215         self.goalstack03 = world;
 216         self.goalstack04 = world;
 217         self.goalstack05 = world;
 218         self.goalstack06 = world;
 219         self.goalstack07 = world;
 220         self.goalstack08 = world;
 221         self.goalstack09 = world;
 222         self.goalstack10 = world;
 223         self.goalstack11 = world;
 224         self.goalstack12 = world;
 225         self.goalstack13 = world;
 226         self.goalstack14 = world;
 227         self.goalstack15 = world;
 228         self.goalstack16 = world;
 229         self.goalstack17 = world;
 230         self.goalstack18 = world;
 231         self.goalstack19 = world;
 232         self.goalstack20 = world;
 233         self.goalstack21 = world;
 234         self.goalstack22 = world;
 235         self.goalstack23 = world;
 236         self.goalstack24 = world;
 237         self.goalstack25 = world;
 238         self.goalstack26 = world;
 239         self.goalstack27 = world;
 240         self.goalstack28 = world;
 241         self.goalstack29 = world;
 242         self.goalstack30 = world;
 243         self.goalstack31 = world;
 244 };
 245
 246 // add a new goal at the beginning of the stack
 247 // (in other words: add a new prerequisite before going to the later goals)
 248 // NOTE: when a waypoint is added, the WP gets pushed first, then the
 249 // next-closest WP on the shortest path to the WP
 250 // That means, if the stack overflows, the bot will know how to do the FIRST 32
 251 // steps to the goal, and then recalculate the path.
 252 void navigation_pushroute(entity e)
 253 {
 254         //print("bot ", etos(self), " push ", etos(e), "\n");
 255         self.goalstack31 = self.goalstack30;
 256         self.goalstack30 = self.goalstack29;
 257         self.goalstack29 = self.goalstack28;
 258         self.goalstack28 = self.goalstack27;
 259         self.goalstack27 = self.goalstack26;
 260         self.goalstack26 = self.goalstack25;
 261         self.goalstack25 = self.goalstack24;
 262         self.goalstack24 = self.goalstack23;
 263         self.goalstack23 = self.goalstack22;
 264         self.goalstack22 = self.goalstack21;
 265         self.goalstack21 = self.goalstack20;
 266         self.goalstack20 = self.goalstack19;
 267         self.goalstack19 = self.goalstack18;
 268         self.goalstack18 = self.goalstack17;
 269         self.goalstack17 = self.goalstack16;
 270         self.goalstack16 = self.goalstack15;
 271         self.goalstack15 = self.goalstack14;
 272         self.goalstack14 = self.goalstack13;
 273         self.goalstack13 = self.goalstack12;
 274         self.goalstack12 = self.goalstack11;
 275         self.goalstack11 = self.goalstack10;
 276         self.goalstack10 = self.goalstack09;
 277         self.goalstack09 = self.goalstack08;
 278         self.goalstack08 = self.goalstack07;
 279         self.goalstack07 = self.goalstack06;
 280         self.goalstack06 = self.goalstack05;
 281         self.goalstack05 = self.goalstack04;
 282         self.goalstack04 = self.goalstack03;
 283         self.goalstack03 = self.goalstack02;
 284         self.goalstack02 = self.goalstack01;
 285         self.goalstack01 = self.goalcurrent;
 286         self.goalcurrent = e;
 287 };
 288
 289 // remove first goal from stack
 290 // (in other words: remove a prerequisite for reaching the later goals)
 291 // (used when a spawnfunc_waypoint is reached)
 292 void navigation_poproute()
 293 {
 294         //print("bot ", etos(self), " pop\n");
 295         self.goalcurrent = self.goalstack01;
 296         self.goalstack01 = self.goalstack02;
 297         self.goalstack02 = self.goalstack03;
 298         self.goalstack03 = self.goalstack04;
 299         self.goalstack04 = self.goalstack05;
 300         self.goalstack05 = self.goalstack06;
 301         self.goalstack06 = self.goalstack07;
 302         self.goalstack07 = self.goalstack08;
 303         self.goalstack08 = self.goalstack09;
 304         self.goalstack09 = self.goalstack10;
 305         self.goalstack10 = self.goalstack11;
 306         self.goalstack11 = self.goalstack12;
 307         self.goalstack12 = self.goalstack13;
 308         self.goalstack13 = self.goalstack14;
 309         self.goalstack14 = self.goalstack15;
 310         self.goalstack15 = self.goalstack16;
 311         self.goalstack16 = self.goalstack17;
 312         self.goalstack17 = self.goalstack18;
 313         self.goalstack18 = self.goalstack19;
 314         self.goalstack19 = self.goalstack20;
 315         self.goalstack20 = self.goalstack21;
 316         self.goalstack21 = self.goalstack22;
 317         self.goalstack22 = self.goalstack23;
 318         self.goalstack23 = self.goalstack24;
 319         self.goalstack24 = self.goalstack25;
 320         self.goalstack25 = self.goalstack26;
 321         self.goalstack26 = self.goalstack27;
 322         self.goalstack27 = self.goalstack28;
 323         self.goalstack28 = self.goalstack29;
 324         self.goalstack29 = self.goalstack30;
 325         self.goalstack30 = self.goalstack31;
 326         self.goalstack31 = world;
 327 };
 328
 329 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
 330 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
 331 {
 332         local entity waylist, w, best;
 333         local float dist, bestdist;
 334         local vector v, org, pm1, pm2;
 335         pm1 = ent.origin + ent.mins;
 336         pm2 = ent.origin + ent.maxs;
 337         waylist = findchain(classname, "waypoint");
 338
 339         // do two scans, because box test is cheaper
 340         w = waylist;
 341         while (w)
 342         {
 343                 // if object is touching spawnfunc_waypoint
 344                 if(w != ent)
 345                         if (boxesoverlap(pm1, pm2, w.absmin, w.absmax))
 346                                 return w;
 347                 w = w.chain;
 348         }
 349
 350         org = ent.origin + 0.5 * (ent.mins + ent.maxs);
 351         org_z = ent.origin_z + ent.mins_z - PL_MIN_z; // player height
 352         // TODO possibly make other code have the same support for bboxes
 353         if(ent.tag_entity)
 354                 org = org + ent.tag_entity.origin;
 355         if (navigation_testtracewalk)
 356                 te_plasmaburn(org);
 357
 358         best = world;
 359         bestdist = 1050;
 360
 361         // box check failed, try walk
 362         w = waylist;
 363         while (w)
 364         {
 365                 // if object can walk from spawnfunc_waypoint
 366                 if(w != ent)
 367                 {
 368                         if (w.wpisbox)
 369                         {
 370                                 local vector wm1, wm2;
 371                                 wm1 = w.origin + w.mins;
 372                                 wm2 = w.origin + w.maxs;
 373                                 v_x = bound(wm1_x, org_x, wm2_x);
 374                                 v_y = bound(wm1_y, org_y, wm2_y);
 375                                 v_z = bound(wm1_z, org_z, wm2_z);
 376                         }
 377                         else
 378                                 v = w.origin;
 379                         dist = vlen(v - org);
 380                         if (bestdist > dist)
 381                         {
 382                                 traceline(v, org, TRUE, ent);
 383                                 if (trace_fraction == 1)
 384                                 {
 385                                         if (walkfromwp)
 386                                         {
 387                                                 //print("^1can I reach ", vtos(org), " from ", vtos(v), "?\n");
 388                                                 if (tracewalk(ent, v, PL_MIN, PL_MAX, org, bot_navigation_movemode))
 389                                                 {
 390                                                         bestdist = dist;
 391                                                         best = w;
 392                                                 }
 393                                         }
 394                                         else
 395                                         {
 396                                                 if (tracewalk(ent, org, PL_MIN, PL_MAX, v, bot_navigation_movemode))
 397                                                 {
 398                                                         bestdist = dist;
 399                                                         best = w;
 400                                                 }
 401                                         }
 402                                 }
 403                         }
 404                 }
 405                 w = w.chain;
 406         }
 407         return best;
 408 }
 409
 410 // finds the waypoints near the bot initiating a navigation query
 411 float navigation_markroutes_nearestwaypoints(entity waylist, float maxdist)
 412 {
 413         local entity head;
 414         local vector v, m1, m2, diff;
 415         local float c;
 416 //      navigation_testtracewalk = TRUE;
 417         c = 0;
 418         head = waylist;
 419         while (head)
 420         {
 421                 if (!head.wpconsidered)
 422                 {
 423                         if (head.wpisbox)
 424                         {
 425                                 m1 = head.origin + head.mins;
 426                                 m2 = head.origin + head.maxs;
 427                                 v = self.origin;
 428                                 v_x = bound(m1_x, v_x, m2_x);
 429                                 v_y = bound(m1_y, v_y, m2_y);
 430                                 v_z = bound(m1_z, v_z, m2_z);
 431                         }
 432                         else
 433                                 v = head.origin;
 434                         diff = v - self.origin;
 435                         diff_z = max(0, diff_z);
 436                         if (vlen(diff) < maxdist)
 437                         {
 438                                 head.wpconsidered = TRUE;
 439                                 if (tracewalk(self, self.origin, self.mins, self.maxs, v, bot_navigation_movemode))
 440                                 {
 441                                         head.wpnearestpoint = v;
 442                                         head.wpcost = vlen(v - self.origin) + head.dmg;
 443                                         head.wpfire = 1;
 444                                         head.enemy = world;
 445                                         c = c + 1;
 446                                 }
 447                         }
 448                 }
 449                 head = head.chain;
 450         }
 451         //navigation_testtracewalk = FALSE;
 452         return c;
 453 }
 454
 455 // updates a path link if a spawnfunc_waypoint link is better than the current one
 456 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost2, vector p)
 457 {
 458         local vector m1;
 459         local vector m2;
 460         local vector v;
 461         if (wp.wpisbox)
 462         {
 463                 m1 = wp.absmin;
 464                 m2 = wp.absmax;
 465                 v_x = bound(m1_x, p_x, m2_x);
 466                 v_y = bound(m1_y, p_y, m2_y);
 467                 v_z = bound(m1_z, p_z, m2_z);
 468         }
 469         else
 470                 v = wp.origin;
 471         cost2 = cost2 + vlen(v - p);
 472         if (wp.wpcost > cost2)
 473         {
 474                 wp.wpcost = cost2;
 475                 wp.enemy = w;
 476                 wp.wpfire = 1;
 477                 wp.wpnearestpoint = v;
 478         }
 479 };
 480
 481 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
 482 void navigation_markroutes(entity fixed_source_waypoint)
 483 {
 484         local entity w, wp, waylist;
 485         local float searching, cost, cost2;
 486         local vector p;
 487         w = waylist = findchain(classname, "waypoint");
 488         while (w)
 489         {
 490                 w.wpconsidered = FALSE;
 491                 w.wpnearestpoint = '0 0 0';
 492                 w.wpcost = 10000000;
 493                 w.wpfire = 0;
 494                 w.enemy = world;
 495                 w = w.chain;
 496         }
 497
 498         if(fixed_source_waypoint)
 499         {
 500                 fixed_source_waypoint.wpconsidered = TRUE;
 501                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 502                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg;
 503                 fixed_source_waypoint.wpfire = 1;
 504                 fixed_source_waypoint.enemy = world;
 505         }
 506         else
 507         {
 508                 // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
 509                 // as this search is expensive we will use lower values if the bot is on the air
 510                 local float i, increment, maxdistance;
 511                 if(self.flags & FL_ONGROUND)
 512                 {
 513                         increment = 750;
 514                         maxdistance = 50000;
 515                 }
 516                 else
 517                 {
 518                         increment = 500;
 519                         maxdistance = 1500;
 520                 }
 521
 522                 for(i=increment;!navigation_markroutes_nearestwaypoints(waylist, i)&&i<maxdistance;i+=increment);
 523         }
 524
 525         searching = TRUE;
 526         while (searching)
 527         {
 528                 searching = FALSE;
 529                 w = waylist;
 530                 while (w)
 531                 {
 532                         if (w.wpfire)
 533                         {
 534                                 searching = TRUE;
 535                                 w.wpfire = 0;
 536                                 cost = w.wpcost;
 537                                 p = w.wpnearestpoint;
 538                                 wp = w.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp00mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 539                                 wp = w.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp01mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 540                                 wp = w.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp02mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 541                                 wp = w.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp03mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 542                                 wp = w.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp04mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 543                                 wp = w.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp05mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 544                                 wp = w.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp06mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 545                                 wp = w.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp07mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 546                                 wp = w.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp08mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 547                                 wp = w.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp09mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 548                                 wp = w.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp10mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 549                                 wp = w.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp11mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 550                                 wp = w.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp12mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 551                                 wp = w.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp13mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 552                                 wp = w.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp14mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 553                                 wp = w.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp15mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 554                                 wp = w.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp16mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 555                                 wp = w.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp17mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 556                                 wp = w.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp18mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 557                                 wp = w.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp19mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 558                                 wp = w.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp20mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 559                                 wp = w.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp21mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 560                                 wp = w.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp22mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 561                                 wp = w.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp23mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 562                                 wp = w.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp24mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 563                                 wp = w.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp25mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 564                                 wp = w.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp26mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 565                                 wp = w.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp27mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 566                                 wp = w.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp28mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 567                                 wp = w.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp29mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 568                                 wp = w.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp30mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 569                                 wp = w.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp31mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 570                                 }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
 571                         }
 572                         w = w.chain;
 573                 }
 574         }
 575 };
 576
 577 // queries the entire spawnfunc_waypoint network for pathes leading to the bot
 578 void navigation_markroutes_inverted(entity fixed_source_waypoint)
 579 {
 580         local entity w, wp, waylist;
 581         local float searching, cost, cost2;
 582         local vector p;
 583         w = waylist = findchain(classname, "waypoint");
 584         while (w)
 585         {
 586                 w.wpconsidered = FALSE;
 587                 w.wpnearestpoint = '0 0 0';
 588                 w.wpcost = 10000000;
 589                 w.wpfire = 0;
 590                 w.enemy = world;
 591                 w = w.chain;
 592         }
 593
 594         if(fixed_source_waypoint)
 595         {
 596                 fixed_source_waypoint.wpconsidered = TRUE;
 597                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 598                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg; // the cost to get from X to fixed_source_waypoint
 599                 fixed_source_waypoint.wpfire = 1;
 600                 fixed_source_waypoint.enemy = world;
 601         }
 602         else
 603         {
 604                 error("need to start with a waypoint\n");
 605         }
 606
 607         searching = TRUE;
 608         while (searching)
 609         {
 610                 searching = FALSE;
 611                 w = waylist;
 612                 while (w)
 613                 {
 614                         if (w.wpfire)
 615                         {
 616                                 searching = TRUE;
 617                                 w.wpfire = 0;
 618                                 cost = w.wpcost; // cost to walk from w to home
 619                                 p = w.wpnearestpoint;
 620                                 for(wp = waylist; wp; wp = wp.chain)
 621                                 {
 622                                         if(w != wp.wp00) if(w != wp.wp01) if(w != wp.wp02) if(w != wp.wp03)
 623                                         if(w != wp.wp04) if(w != wp.wp05) if(w != wp.wp06) if(w != wp.wp07)
 624                                         if(w != wp.wp08) if(w != wp.wp09) if(w != wp.wp10) if(w != wp.wp11)
 625                                         if(w != wp.wp12) if(w != wp.wp13) if(w != wp.wp14) if(w != wp.wp15)
 626                                         if(w != wp.wp16) if(w != wp.wp17) if(w != wp.wp18) if(w != wp.wp19)
 627                                         if(w != wp.wp20) if(w != wp.wp21) if(w != wp.wp22) if(w != wp.wp23)
 628                                         if(w != wp.wp24) if(w != wp.wp25) if(w != wp.wp26) if(w != wp.wp27)
 629                                         if(w != wp.wp28) if(w != wp.wp29) if(w != wp.wp30) if(w != wp.wp31)
 630                                                 continue;
 631                                         cost2 = cost + wp.dmg;
 632                                         navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 633                                 }
 634                         }
 635                         w = w.chain;
 636                 }
 637         }
 638 };
 639
 640 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
 641 void navigation_routerating(entity e, float f, float rangebias)
 642 {
 643         entity nwp;
 644         if (!e)
 645                 return;
 646
 647         if(e.blacklisted)
 648                 return;
 649
 650         //print("routerating ", etos(e), " = ", ftos(f), " - ", ftos(rangebias), "\n");
 651
 652         // Evaluate path using jetpack
 653         if(g_jetpack)
 654         if(self.items & IT_JETPACK)
 655         if(autocvar_bot_ai_navigation_jetpack)
 656         if(vlen(self.origin - e.origin) > autocvar_bot_ai_navigation_jetpack_mindistance)
 657         {
 658                 vector pointa, pointb;
 659
 660         //      dprint("jetpack ai: evaluating path for ", e.classname,"\n");
 661
 662                 // Point A
 663                 traceline(self.origin, self.origin + '0 0 65535', MOVE_NORMAL, self);
 664                 pointa = trace_endpos - '0 0 1';
 665
 666                 // Point B
 667                 traceline(e.origin, e.origin + '0 0 65535', MOVE_NORMAL, e);
 668                 pointb = trace_endpos - '0 0 1';
 669
 670                 // Can I see these two points from the sky?
 671                 traceline(pointa, pointb, MOVE_NORMAL, self);
 672
 673                 if(trace_fraction==1)
 674                 {
 675                 //      dprint("jetpack ai: can bridge these two points\n");
 676
 677                         // Lower the altitude of these points as much as possible
 678                         local float zdistance, xydistance, cost, t, fuel;
 679                         local vector down, npa, npb;
 680
 681                         down = '0 0 -1' * (PL_MAX_z - PL_MIN_z) * 10;
 682
 683                         do{
 684                                 npa = pointa + down;
 685                                 npb = pointb + down;
 686
 687                                 if(npa_z<=self.absmax_z)
 688                                         break;
 689
 690                                 if(npb_z<=e.absmax_z)
 691                                         break;
 692
 693                                 traceline(npa, npb, MOVE_NORMAL, self);
 694                                 if(trace_fraction==1)
 695                                 {
 696                                         pointa = npa;
 697                                         pointb = npb;
 698                                 }
 699                         }
 700                         while(trace_fraction == 1);
 701
 702
 703                         // Rough estimation of fuel consumption
 704                         // (ignores acceleration and current xyz velocity)
 705                         xydistance = vlen(pointa - pointb);
 706                         zdistance = fabs(pointa_z - self.origin_z);
 707
 708                         t = zdistance / autocvar_g_jetpack_maxspeed_up;
 709                         t += xydistance / autocvar_g_jetpack_maxspeed_side;
 710                         fuel = t * autocvar_g_jetpack_fuel * 0.8;
 711
 712                 //      dprint("jetpack ai: required fuel ", ftos(fuel), " self.ammo_fuel ", ftos(self.ammo_fuel),"\n");
 713
 714                         // enough fuel ?
 715                         if(self.ammo_fuel>fuel)
 716                         {
 717                                 // Estimate cost
 718                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
 719                                 //  - between air and ground speeds)
 720
 721                                 cost = xydistance / (autocvar_g_jetpack_maxspeed_side/autocvar_sv_maxspeed);
 722                                 cost += zdistance / (autocvar_g_jetpack_maxspeed_up/autocvar_sv_maxspeed);
 723                                 cost *= 1.5;
 724
 725                                 // Compare against other goals
 726                                 f = f * rangebias / (rangebias + cost);
 727
 728                                 if (navigation_bestrating < f)
 729                                 {
 730                         //              dprint("jetpack path: added goal", e.classname, " (with rating ", ftos(f), ")\n");
 731                                         navigation_bestrating = f;
 732                                         navigation_bestgoal = e;
 733                                         self.navigation_jetpack_goal = e;
 734                                         self.navigation_jetpack_point = pointb;
 735                                 }
 736                                 return;
 737                         }
 738                 }
 739         }
 740
 741         //te_wizspike(e.origin);
 742         //bprint(etos(e));
 743         //bprint("\n");
 744         // update the cached spawnfunc_waypoint link on a dynamic item entity
 745         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
 746         {
 747                 nwp = e;
 748         }
 749         else
 750         {
 751                 float search;
 752
 753                 search = TRUE;
 754
 755                 if(e.flags & FL_ITEM)
 756                 {
 757                         if not(e.flags & FL_WEAPON)
 758                         if(e.nearestwaypoint)
 759                                 search = FALSE;
 760                 }
 761                 else if (e.flags & FL_WEAPON)
 762                 {
 763                         if(e.classname != "droppedweapon")
 764                         if(e.nearestwaypoint)
 765                                 search = FALSE;
 766                 }
 767
 768                 if(search)
 769                 if (time > e.nearestwaypointtimeout)
 770                 {
 771                         nwp = navigation_findnearestwaypoint(e, TRUE);
 772                         if(nwp)
 773                                 e.nearestwaypoint = nwp;
 774                         else
 775                         {
 776                                 dprint("FAILED to find a nearest waypoint to '", e.classname, "' #", etos(e), "\n");
 777
 778                                 if(e.flags & FL_ITEM)
 779                                         e.blacklisted = TRUE;
 780                                 else if (e.flags & FL_WEAPON)
 781                                 {
 782                                         if(e.classname != "droppedweapon")
 783                                                 e.blacklisted = TRUE;
 784                                 }
 785
 786                                 if(e.blacklisted)
 787                                 {
 788                                         dprint("The entity '", e.classname, "' is going to be excluded from path finding during this match\n");
 789                                         return;
 790                                 }
 791                         }
 792
 793                         // TODO: Cleaner solution, probably handling this timeout from ctf.qc
 794                         if(e.classname=="item_flag_team")
 795                                 e.nearestwaypointtimeout = time + 2;
 796                         else
 797                                 e.nearestwaypointtimeout = time + random() * 3 + 5;
 798                 }
 799                 nwp = e.nearestwaypoint;
 800         }
 801
 802         //dprint("-- checking ", e.classname, " (with cost ", ftos(nwp.wpcost), ")\n");
 803         if (nwp)
 804         if (nwp.wpcost < 10000000)
 805         {
 806                 //te_wizspike(nwp.wpnearestpoint);
 807         //      dprint(e.classname, " ", ftos(f), "/(1+", ftos((nwp.wpcost + vlen(e.origin - nwp.wpnearestpoint))), "/", ftos(rangebias), ") = ");
 808                 f = f * rangebias / (rangebias + (nwp.wpcost + vlen(e.origin - nwp.wpnearestpoint)));
 809                 //dprint("considering ", e.classname, " (with rating ", ftos(f), ")\n");
 810                 //dprint(ftos(f));
 811                 if (navigation_bestrating < f)
 812                 {
 813                 //      dprint("ground path: added goal ", e.classname, " (with rating ", ftos(f), ")\n");
 814                         navigation_bestrating = f;
 815                         navigation_bestgoal = e;
 816                 }
 817         }
 818         //dprint("\n");
 819 };
 820
 821 // adds an item to the the goal stack with the path to a given item
 822 float navigation_routetogoal(entity e, vector startposition)
 823 {
 824         self.goalentity = e;
 825
 826         // if there is no goal, just exit
 827         if (!e)
 828                 return FALSE;
 829
 830         self.navigation_hasgoals = TRUE;
 831
 832         // put the entity on the goal stack
 833         //print("routetogoal ", etos(e), "\n");
 834         navigation_pushroute(e);
 835
 836         if(g_jetpack)
 837         if(e==self.navigation_jetpack_goal)
 838                 return TRUE;
 839
 840         // if it can reach the goal there is nothing more to do
 841         if (tracewalk(self, startposition, PL_MIN, PL_MAX, e.origin, bot_navigation_movemode))
 842                 return TRUE;
 843
 844         // see if there are waypoints describing a path to the item
 845         if(e.classname != "waypoint" || (e.wpflags & WAYPOINTFLAG_PERSONAL))
 846                 e = e.nearestwaypoint;
 847         else
 848                 e = e.enemy; // we already have added it, so...
 849
 850         if(e == world)
 851                 return FALSE;
 852
 853         for (;;)
 854         {
 855                 // add the spawnfunc_waypoint to the path
 856                 navigation_pushroute(e);
 857                 e = e.enemy;
 858
 859                 if(e==world)
 860                         break;
 861         }
 862
 863         return FALSE;
 864 };
 865
 866 // removes any currently touching waypoints from the goal stack
 867 // (this is how bots detect if they reached a goal)
 868 void navigation_poptouchedgoals()
 869 {
 870         local vector org, m1, m2;
 871         org = self.origin;
 872         m1 = org + self.mins;
 873         m2 = org + self.maxs;
 874
 875         if(self.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 876         {
 877                 if(self.lastteleporttime>0)
 878                 if(time-self.lastteleporttime<(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL)?2:0.15)
 879                 {
 880                         if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
 881                         if(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && self.goalcurrent.owner==self)
 882                         {
 883                                 self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
 884                                 self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
 885                         }
 886                         navigation_poproute();
 887                         return;
 888                 }
 889         }
 890
 891         // Loose goal touching check when running
 892         if(self.aistatus & AI_STATUS_RUNNING)
 893         if(self.goalcurrent.classname=="waypoint")
 894         {
 895                 if(vlen(self.origin - self.goalcurrent.origin)<150)
 896                 {
 897                         traceline(self.origin + self.view_ofs , self.goalcurrent.origin, TRUE, world);
 898                         if(trace_fraction==1)
 899                         {
 900                                 // Detect personal waypoints
 901                                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
 902                                 if(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && self.goalcurrent.owner==self)
 903                                 {
 904                                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
 905                                         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
 906                                 }
 907
 908                                 navigation_poproute();
 909                         }
 910                 }
 911         }
 912
 913         while (self.goalcurrent && boxesoverlap(m1, m2, self.goalcurrent.absmin, self.goalcurrent.absmax))
 914         {
 915                 // Detect personal waypoints
 916                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
 917                 if(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && self.goalcurrent.owner==self)
 918                 {
 919                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
 920                         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
 921                 }
 922
 923                 navigation_poproute();
 924         }
 925 }
 926
 927 // begin a goal selection session (queries spawnfunc_waypoint network)
 928 void navigation_goalrating_start()
 929 {
 930         if(self.aistatus & AI_STATUS_STUCK)
 931                 return;
 932
 933         self.navigation_jetpack_goal = world;
 934         navigation_bestrating = -1;
 935         self.navigation_hasgoals = FALSE;
 936         navigation_clearroute();
 937         navigation_bestgoal = world;
 938         navigation_markroutes(world);
 939 };
 940
 941 // ends a goal selection session (updates goal stack to the best goal)
 942 void navigation_goalrating_end()
 943 {
 944         if(self.aistatus & AI_STATUS_STUCK)
 945                 return;
 946
 947         navigation_routetogoal(navigation_bestgoal, self.origin);
 948 //      dprint("best goal ", self.goalcurrent.classname , "\n");
 949
 950         // If the bot got stuck then try to reach the farthest waypoint
 951         if not (self.navigation_hasgoals)
 952         if (autocvar_bot_wander_enable)
 953         {
 954                 if not(self.aistatus & AI_STATUS_STUCK)
 955                 {
 956                         dprint(self.netname, " cannot walk to any goal\n");
 957                         self.aistatus |= AI_STATUS_STUCK;
 958                 }
 959
 960                 self.navigation_hasgoals = FALSE; // Reset this value
 961         }
 962 };
 963
 964 void botframe_updatedangerousobjects(float maxupdate)
 965 {
 966         local entity head, bot_dodgelist;
 967         local vector m1, m2, v;
 968         local float c, d, danger;
 969         c = 0;
 970         bot_dodgelist = findchainfloat(bot_dodge, TRUE);
 971         botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
 972         while (botframe_dangerwaypoint != world)
 973         {
 974                 danger = 0;
 975                 m1 = botframe_dangerwaypoint.mins;
 976                 m2 = botframe_dangerwaypoint.maxs;
 977                 head = bot_dodgelist;
 978                 while (head)
 979                 {
 980                         v = head.origin;
 981                         v_x = bound(m1_x, v_x, m2_x);
 982                         v_y = bound(m1_y, v_y, m2_y);
 983                         v_z = bound(m1_z, v_z, m2_z);
 984                         d = head.bot_dodgerating - vlen(head.origin - v);
 985                         if (d > 0)
 986                         {
 987                                 traceline(head.origin, v, TRUE, world);
 988                                 if (trace_fraction == 1)
 989                                         danger = danger + d;
 990                         }
 991                         head = head.chain;
 992                 }
 993                 botframe_dangerwaypoint.dmg = danger;
 994                 c = c + 1;
 995                 if (c >= maxupdate)
 996                         break;
 997                 botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
 998         }
 999 };
1000
1001 void navigation_unstuck()
1002 {
1003         float search_radius = 1000;
1004
1005         if not(autocvar_bot_wander_enable)
1006                 return;
1007
1008         if not(bot_waypoint_queue_owner)
1009         {
1010         //      dprint(self.netname, " sutck, taking over the waypoints queue\n");
1011                 bot_waypoint_queue_owner = self;
1012                 bot_waypoint_queue_bestgoal = world;
1013                 bot_waypoint_queue_bestgoalrating = 0;
1014         }
1015
1016         if(bot_waypoint_queue_owner!=self)
1017                 return;
1018
1019         if (bot_waypoint_queue_goal)
1020         {
1021                 // evaluate the next goal on the queue
1022                 float d = vlen(self.origin - bot_waypoint_queue_goal.origin);
1023                 // dprint(self.netname, " evaluating ", bot_waypoint_queue_goal.classname, " with distance ", ftos(d), "\n");
1024                 if(tracewalk(bot_waypoint_queue_goal, self.origin, PL_MIN, PL_MAX, bot_waypoint_queue_goal.origin, bot_navigation_movemode))
1025                 {
1026                         if( d > bot_waypoint_queue_bestgoalrating)
1027                         {
1028                                 bot_waypoint_queue_bestgoalrating = d;
1029                                 bot_waypoint_queue_bestgoal = bot_waypoint_queue_goal;
1030                         }
1031                 }
1032                 bot_waypoint_queue_goal = bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal;
1033
1034                 if not(bot_waypoint_queue_goal)
1035                 {
1036                         if (bot_waypoint_queue_bestgoal)
1037                         {
1038                                 dprint(self.netname, " stuck, reachable waypoint found, heading to it\n");
1039                                 navigation_routetogoal(bot_waypoint_queue_bestgoal, self.origin);
1040                                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1041                                 self.aistatus &~= AI_STATUS_STUCK;
1042                         }
1043                         else
1044                         {
1045                                 dprint(self.netname, " stuck, cannot walk to any waypoint at all\n");
1046                         }
1047
1048                         bot_waypoint_queue_owner = world;
1049                 }
1050         }
1051         else
1052         {
1053                 if(bot_strategytoken!=self)
1054                         return;
1055
1056                 // build a new queue
1057                 dprint(self.netname, " stuck, scanning reachable waypoints within ", ftos(search_radius)," qu\n");
1058
1059                 entity head, first;
1060
1061                 first = world;
1062                 head = findradius(self.origin, search_radius);
1063
1064                 while(head)
1065                 {
1066                         if(head.classname=="waypoint")
1067                 //      if(!(head.wpflags & WAYPOINTFLAG_GENERATED))
1068                         {
1069                                 if(bot_waypoint_queue_goal)
1070                                         bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = head;
1071                                 else
1072                                         first = head;
1073
1074                                 bot_waypoint_queue_goal = head;
1075                                 bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = world;
1076                         }
1077
1078                         head = head.chain;
1079                 }
1080
1081                 if (first)
1082                         bot_waypoint_queue_goal = first;
1083                 else
1084                 {
1085                         dprint(self.netname, " stuck, cannot walk to any waypoint at all\n");
1086                         bot_waypoint_queue_owner = world;
1087                 }
1088         }
1089 }
1090
1091 // Support for debugging tracewalk visually
1092
1093 void debugresetnodes()
1094 {
1095         debuglastnode = '0 0 0';
1096 }
1097
1098 void debugnode(vector node)
1099 {
1100         if not(self.classname=="player")
1101                 return;
1102
1103         if(debuglastnode=='0 0 0')
1104         {
1105                 debuglastnode = node;
1106                 return;
1107         }
1108
1109         te_lightning2(world, node, debuglastnode);
1110         debuglastnode = node;
1111 }
1112
1113 void debugnodestatus(vector position, float status)
1114 {
1115         vector c;
1116
1117         switch (status)
1118         {
1119                 case DEBUG_NODE_SUCCESS:
1120                         c = '0 15 0';
1121                         break;
1122                 case DEBUG_NODE_WARNING:
1123                         c = '15 15 0';
1124                         break;
1125                 case DEBUG_NODE_FAIL:
1126                         c = '15 0 0';
1127                         break;
1128                 default:
1129                         c = '15 15 15';
1130         }
1131
1132         te_customflash(position, 40,  2, c);
1133 }
1134
1135 // Support for debugging the goal stack visually
1136
1137 .float goalcounter;
1138 .vector lastposition;
1139
1140 // Debug the goal stack visually
1141 void debuggoalstack()
1142 {
1143         local entity goal;
1144         local vector org;
1145
1146         if(self.goalcounter==0)goal=self.goalcurrent;
1147         else if(self.goalcounter==1)goal=self.goalstack01;
1148         else if(self.goalcounter==2)goal=self.goalstack02;
1149         else if(self.goalcounter==3)goal=self.goalstack03;
1150         else if(self.goalcounter==4)goal=self.goalstack04;
1151         else if(self.goalcounter==5)goal=self.goalstack05;
1152         else if(self.goalcounter==6)goal=self.goalstack06;
1153         else if(self.goalcounter==7)goal=self.goalstack07;
1154         else if(self.goalcounter==8)goal=self.goalstack08;
1155         else if(self.goalcounter==9)goal=self.goalstack09;
1156         else if(self.goalcounter==10)goal=self.goalstack10;
1157         else if(self.goalcounter==11)goal=self.goalstack11;
1158         else if(self.goalcounter==12)goal=self.goalstack12;
1159         else if(self.goalcounter==13)goal=self.goalstack13;
1160         else if(self.goalcounter==14)goal=self.goalstack14;
1161         else if(self.goalcounter==15)goal=self.goalstack15;
1162         else if(self.goalcounter==16)goal=self.goalstack16;
1163         else if(self.goalcounter==17)goal=self.goalstack17;
1164         else if(self.goalcounter==18)goal=self.goalstack18;
1165         else if(self.goalcounter==19)goal=self.goalstack19;
1166         else if(self.goalcounter==20)goal=self.goalstack20;
1167         else if(self.goalcounter==21)goal=self.goalstack21;
1168         else if(self.goalcounter==22)goal=self.goalstack22;
1169         else if(self.goalcounter==23)goal=self.goalstack23;
1170         else if(self.goalcounter==24)goal=self.goalstack24;
1171         else if(self.goalcounter==25)goal=self.goalstack25;
1172         else if(self.goalcounter==26)goal=self.goalstack26;
1173         else if(self.goalcounter==27)goal=self.goalstack27;
1174         else if(self.goalcounter==28)goal=self.goalstack28;
1175         else if(self.goalcounter==29)goal=self.goalstack29;
1176         else if(self.goalcounter==30)goal=self.goalstack30;
1177         else if(self.goalcounter==31)goal=self.goalstack31;
1178
1179         if(goal==world)
1180         {
1181                 self.goalcounter = 0;
1182                 self.lastposition='0 0 0';
1183                 return;
1184         }
1185
1186         if(self.lastposition=='0 0 0')
1187                 org = self.origin;
1188         else
1189                 org = self.lastposition;
1190
1191
1192         te_lightning2(world, org, goal.origin);
1193         self.lastposition = goal.origin;
1194
1195         self.goalcounter++;
1196 }