qcsrc/server/bot/navigation.qc

   1
   2 // rough simulation of walking from one point to another to test if a path
   3 // can be traveled, used for waypoint linking and havocbot
   4
   5 float tracewalk(entity e, vector start, vector m1, vector m2, vector end, float movemode)
   6 {
   7         local vector org;
   8         local vector move;
   9         local vector dir;
  10         local float dist;
  11         local float totaldist;
  12         local float stepdist;
  13         local float yaw;
  14         local float ignorehazards;
  15         local float swimming;
  16
  17         if(autocvar_bot_debug_tracewalk)
  18         {
  19                 debugresetnodes();
  20                 debugnode(start);
  21         }
  22
  23         move = end - start;
  24         move_z = 0;
  25         org = start;
  26         dist = totaldist = vlen(move);
  27         dir = normalize(move);
  28         stepdist = 32;
  29         ignorehazards = FALSE;
  30
  31         // Analyze starting point
  32         traceline(start, start, MOVE_NORMAL, e);
  33         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  34                 ignorehazards = TRUE;
  35         else
  36         {
  37                 traceline( start, start + '0 0 -65536', MOVE_NORMAL, e);
  38                 if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  39                 {
  40                         ignorehazards = TRUE;
  41                         swimming = TRUE;
  42                 }
  43         }
  44         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
  45         if (trace_startsolid)
  46         {
  47                 // Bad start
  48                 if(autocvar_bot_debug_tracewalk)
  49                         debugnodestatus(start, DEBUG_NODE_FAIL);
  50
  51                 //print("tracewalk: ", vtos(start), " is a bad start\n");
  52                 return FALSE;
  53         }
  54
  55         // Movement loop
  56         yaw = vectoyaw(move);
  57         move = end - org;
  58         for (;;)
  59         {
  60                 if (boxesoverlap(end, end, org + m1 + '-1 -1 -1', org + m2 + '1 1 1'))
  61                 {
  62                         // Succeeded
  63                         if(autocvar_bot_debug_tracewalk)
  64                                 debugnodestatus(org, DEBUG_NODE_SUCCESS);
  65
  66                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
  67                         return TRUE;
  68                 }
  69                 if(autocvar_bot_debug_tracewalk)
  70                         debugnode(org);
  71
  72                 if (dist <= 0)
  73                         break;
  74                 if (stepdist > dist)
  75                         stepdist = dist;
  76                 dist = dist - stepdist;
  77                 traceline(org, org, MOVE_NORMAL, e);
  78                 if (!ignorehazards)
  79                 {
  80                         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  81                         {
  82                                 // hazards blocking path
  83                                 if(autocvar_bot_debug_tracewalk)
  84                                         debugnodestatus(org, DEBUG_NODE_FAIL);
  85
  86                                 //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
  87                                 return FALSE;
  88                         }
  89                 }
  90                 if (trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
  91                 {
  92                         move = normalize(end - org);
  93                         tracebox(org, m1, m2, org + move * stepdist, movemode, e);
  94
  95                         if(autocvar_bot_debug_tracewalk)
  96                                 debugnode(trace_endpos);
  97
  98                         if (trace_fraction < 1)
  99                         {
 100                                 swimming = TRUE;
 101                                 org = trace_endpos - normalize(org - trace_endpos) * stepdist;
 102                                 for(; org_z < end_z + self.maxs_z; org_z += stepdist)
 103                                 {
 104                                                 if(autocvar_bot_debug_tracewalk)
 105                                                         debugnode(org);
 106
 107                                         if(pointcontents(org) == CONTENT_EMPTY)
 108                                                         break;
 109                                 }
 110
 111                                 if not (pointcontents(org + '0 0 1') == CONTENT_EMPTY)
 112                                 {
 113                                         if(autocvar_bot_debug_tracewalk)
 114                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 115
 116                                         return FALSE;
 117                                         //print("tracewalk: ", vtos(start), " failed under water\n");
 118                                 }
 119                                 continue;
 120
 121                         }
 122                         else
 123                                 org = trace_endpos;
 124                 }
 125                 else
 126                 {
 127                         move = dir * stepdist + org;
 128                         tracebox(org, m1, m2, move, movemode, e);
 129
 130                         if(autocvar_bot_debug_tracewalk)
 131                                 debugnode(trace_endpos);
 132
 133                         // hit something
 134                         if (trace_fraction < 1)
 135                         {
 136                                 // check if we can walk over this obstacle, possibly by jumpstepping
 137                                 tracebox(org + jumpstepheightvec, m1, m2, move + jumpstepheightvec, movemode, e);
 138                                 if (trace_fraction < 1 || trace_startsolid)
 139                                 {
 140                                         if(autocvar_bot_debug_tracewalk)
 141                                                 debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 142
 143                                         // check for doors
 144                                         traceline( org, move, movemode, e);
 145                                         if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 146                                         {
 147                                                 local vector nextmove;
 148                                                 move = trace_endpos;
 149                                                 while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 150                                                 {
 151                                                         nextmove = move + (dir * stepdist);
 152                                                         traceline( move, nextmove, movemode, e);
 153                                                         move = nextmove;
 154                                                 }
 155                                         }
 156                                         else
 157                                         {
 158                                                 if(autocvar_bot_debug_tracewalk)
 159                                                         debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 160
 161                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 162                                                 //te_explosion(trace_endpos);
 163                                                 //print(ftos(e.dphitcontentsmask), "\n");
 164                                                 return FALSE; // failed
 165                                         }
 166                                 }
 167                                 else
 168                                         move = trace_endpos;
 169                         }
 170                         else
 171                                 move = trace_endpos;
 172
 173                         // trace down from stepheight as far as possible and move there,
 174                         // if this starts in solid we try again without the stepup, and
 175                         // if that also fails we assume it is a wall
 176                         // (this is the same logic as the Quake walkmove function used)
 177                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 178
 179                         // moved successfully
 180                         if(swimming)
 181                         {
 182                                 local float c;
 183                                 c = pointcontents(org + '0 0 1');
 184                                 if not(c == CONTENT_WATER || c == CONTENT_LAVA || c == CONTENT_SLIME)
 185                                         swimming = FALSE;
 186                                 else
 187                                         continue;
 188                         }
 189
 190                         org = trace_endpos;
 191                 }
 192         }
 193
 194         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 195
 196         // moved but didn't arrive at the intended destination
 197         if(autocvar_bot_debug_tracewalk)
 198                 debugnodestatus(org, DEBUG_NODE_FAIL);
 199
 200         return FALSE;
 201 };
 202
 203 /////////////////////////////////////////////////////////////////////////////
 204 // goal stack
 205 /////////////////////////////////////////////////////////////////////////////
 206
 207 // completely empty the goal stack, used when deciding where to go
 208 void navigation_clearroute()
 209 {
 210         //print("bot ", etos(self), " clear\n");
 211         self.navigation_hasgoals = FALSE;
 212         self.goalcurrent = world;
 213         self.goalstack01 = world;
 214         self.goalstack02 = world;
 215         self.goalstack03 = world;
 216         self.goalstack04 = world;
 217         self.goalstack05 = world;
 218         self.goalstack06 = world;
 219         self.goalstack07 = world;
 220         self.goalstack08 = world;
 221         self.goalstack09 = world;
 222         self.goalstack10 = world;
 223         self.goalstack11 = world;
 224         self.goalstack12 = world;
 225         self.goalstack13 = world;
 226         self.goalstack14 = world;
 227         self.goalstack15 = world;
 228         self.goalstack16 = world;
 229         self.goalstack17 = world;
 230         self.goalstack18 = world;
 231         self.goalstack19 = world;
 232         self.goalstack20 = world;
 233         self.goalstack21 = world;
 234         self.goalstack22 = world;
 235         self.goalstack23 = world;
 236         self.goalstack24 = world;
 237         self.goalstack25 = world;
 238         self.goalstack26 = world;
 239         self.goalstack27 = world;
 240         self.goalstack28 = world;
 241         self.goalstack29 = world;
 242         self.goalstack30 = world;
 243         self.goalstack31 = world;
 244 };
 245
 246 // add a new goal at the beginning of the stack
 247 // (in other words: add a new prerequisite before going to the later goals)
 248 // NOTE: when a waypoint is added, the WP gets pushed first, then the
 249 // next-closest WP on the shortest path to the WP
 250 // That means, if the stack overflows, the bot will know how to do the FIRST 32
 251 // steps to the goal, and then recalculate the path.
 252 void navigation_pushroute(entity e)
 253 {
 254         //print("bot ", etos(self), " push ", etos(e), "\n");
 255         self.goalstack31 = self.goalstack30;
 256         self.goalstack30 = self.goalstack29;
 257         self.goalstack29 = self.goalstack28;
 258         self.goalstack28 = self.goalstack27;
 259         self.goalstack27 = self.goalstack26;
 260         self.goalstack26 = self.goalstack25;
 261         self.goalstack25 = self.goalstack24;
 262         self.goalstack24 = self.goalstack23;
 263         self.goalstack23 = self.goalstack22;
 264         self.goalstack22 = self.goalstack21;
 265         self.goalstack21 = self.goalstack20;
 266         self.goalstack20 = self.goalstack19;
 267         self.goalstack19 = self.goalstack18;
 268         self.goalstack18 = self.goalstack17;
 269         self.goalstack17 = self.goalstack16;
 270         self.goalstack16 = self.goalstack15;
 271         self.goalstack15 = self.goalstack14;
 272         self.goalstack14 = self.goalstack13;
 273         self.goalstack13 = self.goalstack12;
 274         self.goalstack12 = self.goalstack11;
 275         self.goalstack11 = self.goalstack10;
 276         self.goalstack10 = self.goalstack09;
 277         self.goalstack09 = self.goalstack08;
 278         self.goalstack08 = self.goalstack07;
 279         self.goalstack07 = self.goalstack06;
 280         self.goalstack06 = self.goalstack05;
 281         self.goalstack05 = self.goalstack04;
 282         self.goalstack04 = self.goalstack03;
 283         self.goalstack03 = self.goalstack02;
 284         self.goalstack02 = self.goalstack01;
 285         self.goalstack01 = self.goalcurrent;
 286         self.goalcurrent = e;
 287 };
 288
 289 // remove first goal from stack
 290 // (in other words: remove a prerequisite for reaching the later goals)
 291 // (used when a spawnfunc_waypoint is reached)
 292 void navigation_poproute()
 293 {
 294         //print("bot ", etos(self), " pop\n");
 295         self.goalcurrent = self.goalstack01;
 296         self.goalstack01 = self.goalstack02;
 297         self.goalstack02 = self.goalstack03;
 298         self.goalstack03 = self.goalstack04;
 299         self.goalstack04 = self.goalstack05;
 300         self.goalstack05 = self.goalstack06;
 301         self.goalstack06 = self.goalstack07;
 302         self.goalstack07 = self.goalstack08;
 303         self.goalstack08 = self.goalstack09;
 304         self.goalstack09 = self.goalstack10;
 305         self.goalstack10 = self.goalstack11;
 306         self.goalstack11 = self.goalstack12;
 307         self.goalstack12 = self.goalstack13;
 308         self.goalstack13 = self.goalstack14;
 309         self.goalstack14 = self.goalstack15;
 310         self.goalstack15 = self.goalstack16;
 311         self.goalstack16 = self.goalstack17;
 312         self.goalstack17 = self.goalstack18;
 313         self.goalstack18 = self.goalstack19;
 314         self.goalstack19 = self.goalstack20;
 315         self.goalstack20 = self.goalstack21;
 316         self.goalstack21 = self.goalstack22;
 317         self.goalstack22 = self.goalstack23;
 318         self.goalstack23 = self.goalstack24;
 319         self.goalstack24 = self.goalstack25;
 320         self.goalstack25 = self.goalstack26;
 321         self.goalstack26 = self.goalstack27;
 322         self.goalstack27 = self.goalstack28;
 323         self.goalstack28 = self.goalstack29;
 324         self.goalstack29 = self.goalstack30;
 325         self.goalstack30 = self.goalstack31;
 326         self.goalstack31 = world;
 327 };
 328
 329 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
 330 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
 331 {
 332         local entity waylist, w, best;
 333         local float dist, bestdist;
 334         local vector v, org, pm1, pm2;
 335         pm1 = ent.origin + ent.mins;
 336         pm2 = ent.origin + ent.maxs;
 337         waylist = findchain(classname, "waypoint");
 338
 339         // do two scans, because box test is cheaper
 340         w = waylist;
 341         while (w)
 342         {
 343                 // if object is touching spawnfunc_waypoint
 344                 if(w != ent)
 345                         if (boxesoverlap(pm1, pm2, w.absmin, w.absmax))
 346                                 return w;
 347                 w = w.chain;
 348         }
 349
 350         org = ent.origin + 0.5 * (ent.mins + ent.maxs);
 351         org_z = ent.origin_z + ent.mins_z - PL_MIN_z; // player height
 352         // TODO possibly make other code have the same support for bboxes
 353         if(ent.tag_entity)
 354                 org = org + ent.tag_entity.origin;
 355         if (navigation_testtracewalk)
 356                 te_plasmaburn(org);
 357
 358         best = world;
 359         bestdist = 1050;
 360
 361         // box check failed, try walk
 362         w = waylist;
 363         while (w)
 364         {
 365                 // if object can walk from spawnfunc_waypoint
 366                 if(w != ent)
 367                 {
 368                         if (w.wpisbox)
 369                         {
 370                                 local vector wm1, wm2;
 371                                 wm1 = w.origin + w.mins;
 372                                 wm2 = w.origin + w.maxs;
 373                                 v_x = bound(wm1_x, org_x, wm2_x);
 374                                 v_y = bound(wm1_y, org_y, wm2_y);
 375                                 v_z = bound(wm1_z, org_z, wm2_z);
 376                         }
 377                         else
 378                                 v = w.origin;
 379                         dist = vlen(v - org);
 380                         if (bestdist > dist)
 381                         {
 382                                 traceline(v, org, TRUE, ent);
 383                                 if (trace_fraction == 1)
 384                                 {
 385                                         if (walkfromwp)
 386                                         {
 387                                                 //print("^1can I reach ", vtos(org), " from ", vtos(v), "?\n");
 388                                                 if (tracewalk(ent, v, PL_MIN, PL_MAX, org, bot_navigation_movemode))
 389                                                 {
 390                                                         bestdist = dist;
 391                                                         best = w;
 392                                                 }
 393                                         }
 394                                         else
 395                                         {
 396                                                 if (tracewalk(ent, org, PL_MIN, PL_MAX, v, bot_navigation_movemode))
 397                                                 {
 398                                                         bestdist = dist;
 399                                                         best = w;
 400                                                 }
 401                                         }
 402                                 }
 403                         }
 404                 }
 405                 w = w.chain;
 406         }
 407         return best;
 408 }
 409
 410 // finds the waypoints near the bot initiating a navigation query
 411 float navigation_markroutes_nearestwaypoints(entity waylist, float maxdist)
 412 {
 413         local entity head;
 414         local vector v, m1, m2, diff;
 415         local float c;
 416 //      navigation_testtracewalk = TRUE;
 417         c = 0;
 418         head = waylist;
 419         while (head)
 420         {
 421                 if (!head.wpconsidered)
 422                 {
 423                         if (head.wpisbox)
 424                         {
 425                                 m1 = head.origin + head.mins;
 426                                 m2 = head.origin + head.maxs;
 427                                 v = self.origin;
 428                                 v_x = bound(m1_x, v_x, m2_x);
 429                                 v_y = bound(m1_y, v_y, m2_y);
 430                                 v_z = bound(m1_z, v_z, m2_z);
 431                         }
 432                         else
 433                                 v = head.origin;
 434                         diff = v - self.origin;
 435                         diff_z = max(0, diff_z);
 436                         if (vlen(diff) < maxdist)
 437                         {
 438                                 head.wpconsidered = TRUE;
 439                                 if (tracewalk(self, self.origin, self.mins, self.maxs, v, bot_navigation_movemode))
 440                                 {
 441                                         head.wpnearestpoint = v;
 442                                         head.wpcost = vlen(v - self.origin) + head.dmg;
 443                                         head.wpfire = 1;
 444                                         head.enemy = world;
 445                                         c = c + 1;
 446                                 }
 447                         }
 448                 }
 449                 head = head.chain;
 450         }
 451         //navigation_testtracewalk = FALSE;
 452         return c;
 453 }
 454
 455 // updates a path link if a spawnfunc_waypoint link is better than the current one
 456 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost2, vector p)
 457 {
 458         local vector m1;
 459         local vector m2;
 460         local vector v;
 461         if (wp.wpisbox)
 462         {
 463                 m1 = wp.absmin;
 464                 m2 = wp.absmax;
 465                 v_x = bound(m1_x, p_x, m2_x);
 466                 v_y = bound(m1_y, p_y, m2_y);
 467                 v_z = bound(m1_z, p_z, m2_z);
 468         }
 469         else
 470                 v = wp.origin;
 471         cost2 = cost2 + vlen(v - p);
 472         if (wp.wpcost > cost2)
 473         {
 474                 wp.wpcost = cost2;
 475                 wp.enemy = w;
 476                 wp.wpfire = 1;
 477                 wp.wpnearestpoint = v;
 478         }
 479 };
 480
 481 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
 482 void navigation_markroutes(entity fixed_source_waypoint)
 483 {
 484         local entity w, wp, waylist;
 485         local float searching, cost, cost2;
 486         local vector p;
 487         w = waylist = findchain(classname, "waypoint");
 488         while (w)
 489         {
 490                 w.wpconsidered = FALSE;
 491                 w.wpnearestpoint = '0 0 0';
 492                 w.wpcost = 10000000;
 493                 w.wpfire = 0;
 494                 w.enemy = world;
 495                 w = w.chain;
 496         }
 497
 498         if(fixed_source_waypoint)
 499         {
 500                 fixed_source_waypoint.wpconsidered = TRUE;
 501                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 502                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg;
 503                 fixed_source_waypoint.wpfire = 1;
 504                 fixed_source_waypoint.enemy = world;
 505         }
 506         else
 507         {
 508                 // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
 509                 // as this search is expensive we will use lower values if the bot is on the air
 510                 local float i, increment, maxdistance;
 511                 if(self.flags & FL_ONGROUND)
 512                 {
 513                         increment = 750;
 514                         maxdistance = 50000;
 515                 }
 516                 else
 517                 {
 518                         increment = 500;
 519                         maxdistance = 1500;
 520                 }
 521
 522                 for(i=increment;!navigation_markroutes_nearestwaypoints(waylist, i)&&i<maxdistance;i+=increment);
 523         }
 524
 525         searching = TRUE;
 526         while (searching)
 527         {
 528                 searching = FALSE;
 529                 w = waylist;
 530                 while (w)
 531                 {
 532                         if (w.wpfire)
 533                         {
 534                                 searching = TRUE;
 535                                 w.wpfire = 0;
 536                                 cost = w.wpcost;
 537                                 p = w.wpnearestpoint;
 538                                 wp = w.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp00mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 539                                 wp = w.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp01mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 540                                 wp = w.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp02mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 541                                 wp = w.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp03mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 542                                 wp = w.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp04mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 543                                 wp = w.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp05mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 544                                 wp = w.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp06mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 545                                 wp = w.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp07mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 546                                 wp = w.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp08mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 547                                 wp = w.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp09mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 548                                 wp = w.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp10mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 549                                 wp = w.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp11mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 550                                 wp = w.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp12mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 551                                 wp = w.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp13mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 552                                 wp = w.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp14mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 553                                 wp = w.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp15mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 554                                 wp = w.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp16mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 555                                 wp = w.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp17mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 556                                 wp = w.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp18mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 557                                 wp = w.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp19mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 558                                 wp = w.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp20mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 559                                 wp = w.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp21mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 560                                 wp = w.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp22mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 561                                 wp = w.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp23mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 562                                 wp = w.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp24mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 563                                 wp = w.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp25mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 564                                 wp = w.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp26mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 565                                 wp = w.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp27mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 566                                 wp = w.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp28mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 567                                 wp = w.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp29mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 568                                 wp = w.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp30mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 569                                 wp = w.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + w.wp31mincost) navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 570                                 }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
 571                         }
 572                         w = w.chain;
 573                 }
 574         }
 575 };
 576
 577 // queries the entire spawnfunc_waypoint network for pathes leading to the bot
 578 void navigation_markroutes_inverted(entity fixed_source_waypoint)
 579 {
 580         local entity w, wp, waylist;
 581         local float searching, cost, cost2;
 582         local vector p;
 583         w = waylist = findchain(classname, "waypoint");
 584         while (w)
 585         {
 586                 w.wpconsidered = FALSE;
 587                 w.wpnearestpoint = '0 0 0';
 588                 w.wpcost = 10000000;
 589                 w.wpfire = 0;
 590                 w.enemy = world;
 591                 w = w.chain;
 592         }
 593
 594         if(fixed_source_waypoint)
 595         {
 596                 fixed_source_waypoint.wpconsidered = TRUE;
 597                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 598                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg; // the cost to get from X to fixed_source_waypoint
 599                 fixed_source_waypoint.wpfire = 1;
 600                 fixed_source_waypoint.enemy = world;
 601         }
 602         else
 603         {
 604                 error("need to start with a waypoint\n");
 605         }
 606
 607         searching = TRUE;
 608         while (searching)
 609         {
 610                 searching = FALSE;
 611                 w = waylist;
 612                 while (w)
 613                 {
 614                         if (w.wpfire)
 615                         {
 616                                 searching = TRUE;
 617                                 w.wpfire = 0;
 618                                 cost = w.wpcost; // cost to walk from w to home
 619                                 p = w.wpnearestpoint;
 620                                 for(wp = waylist; wp; wp = wp.chain)
 621                                 {
 622                                         if(w != wp.wp00) if(w != wp.wp01) if(w != wp.wp02) if(w != wp.wp03)
 623                                         if(w != wp.wp04) if(w != wp.wp05) if(w != wp.wp06) if(w != wp.wp07)
 624                                         if(w != wp.wp08) if(w != wp.wp09) if(w != wp.wp10) if(w != wp.wp11)
 625                                         if(w != wp.wp12) if(w != wp.wp13) if(w != wp.wp14) if(w != wp.wp15)
 626                                         if(w != wp.wp16) if(w != wp.wp17) if(w != wp.wp18) if(w != wp.wp19)
 627                                         if(w != wp.wp20) if(w != wp.wp21) if(w != wp.wp22) if(w != wp.wp23)
 628                                         if(w != wp.wp24) if(w != wp.wp25) if(w != wp.wp26) if(w != wp.wp27)
 629                                         if(w != wp.wp28) if(w != wp.wp29) if(w != wp.wp30) if(w != wp.wp31)
 630                                                 continue;
 631                                         cost2 = cost + wp.dmg;
 632                                         navigation_markroutes_checkwaypoint(w, wp, cost2, p);
 633                                 }
 634                         }
 635                         w = w.chain;
 636                 }
 637         }
 638 };
 639
 640 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
 641 void navigation_routerating(entity e, float f, float rangebias)
 642 {
 643         entity nwp;
 644         vector o;
 645         if (!e)
 646                 return;
 647
 648         if(e.blacklisted)
 649                 return;
 650
 651         o = (e.absmin + e.absmax) * 0.5;
 652
 653         //print("routerating ", etos(e), " = ", ftos(f), " - ", ftos(rangebias), "\n");
 654
 655         // Evaluate path using jetpack
 656         if(g_jetpack)
 657         if(self.items & IT_JETPACK)
 658         if(autocvar_bot_ai_navigation_jetpack)
 659         if(vlen(self.origin - o) > autocvar_bot_ai_navigation_jetpack_mindistance)
 660         {
 661                 vector pointa, pointb;
 662
 663         //      dprint("jetpack ai: evaluating path for ", e.classname,"\n");
 664
 665                 // Point A
 666                 traceline(self.origin, self.origin + '0 0 65535', MOVE_NORMAL, self);
 667                 pointa = trace_endpos - '0 0 1';
 668
 669                 // Point B
 670                 traceline(o, o + '0 0 65535', MOVE_NORMAL, e);
 671                 pointb = trace_endpos - '0 0 1';
 672
 673                 // Can I see these two points from the sky?
 674                 traceline(pointa, pointb, MOVE_NORMAL, self);
 675
 676                 if(trace_fraction==1)
 677                 {
 678                 //      dprint("jetpack ai: can bridge these two points\n");
 679
 680                         // Lower the altitude of these points as much as possible
 681                         local float zdistance, xydistance, cost, t, fuel;
 682                         local vector down, npa, npb;
 683
 684                         down = '0 0 -1' * (PL_MAX_z - PL_MIN_z) * 10;
 685
 686                         do{
 687                                 npa = pointa + down;
 688                                 npb = pointb + down;
 689
 690                                 if(npa_z<=self.absmax_z)
 691                                         break;
 692
 693                                 if(npb_z<=e.absmax_z)
 694                                         break;
 695
 696                                 traceline(npa, npb, MOVE_NORMAL, self);
 697                                 if(trace_fraction==1)
 698                                 {
 699                                         pointa = npa;
 700                                         pointb = npb;
 701                                 }
 702                         }
 703                         while(trace_fraction == 1);
 704
 705
 706                         // Rough estimation of fuel consumption
 707                         // (ignores acceleration and current xyz velocity)
 708                         xydistance = vlen(pointa - pointb);
 709                         zdistance = fabs(pointa_z - self.origin_z);
 710
 711                         t = zdistance / autocvar_g_jetpack_maxspeed_up;
 712                         t += xydistance / autocvar_g_jetpack_maxspeed_side;
 713                         fuel = t * autocvar_g_jetpack_fuel * 0.8;
 714
 715                 //      dprint("jetpack ai: required fuel ", ftos(fuel), " self.ammo_fuel ", ftos(self.ammo_fuel),"\n");
 716
 717                         // enough fuel ?
 718                         if(self.ammo_fuel>fuel)
 719                         {
 720                                 // Estimate cost
 721                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
 722                                 //  - between air and ground speeds)
 723
 724                                 cost = xydistance / (autocvar_g_jetpack_maxspeed_side/autocvar_sv_maxspeed);
 725                                 cost += zdistance / (autocvar_g_jetpack_maxspeed_up/autocvar_sv_maxspeed);
 726                                 cost *= 1.5;
 727
 728                                 // Compare against other goals
 729                                 f = f * rangebias / (rangebias + cost);
 730
 731                                 if (navigation_bestrating < f)
 732                                 {
 733                         //              dprint("jetpack path: added goal", e.classname, " (with rating ", ftos(f), ")\n");
 734                                         navigation_bestrating = f;
 735                                         navigation_bestgoal = e;
 736                                         self.navigation_jetpack_goal = e;
 737                                         self.navigation_jetpack_point = pointb;
 738                                 }
 739                                 return;
 740                         }
 741                 }
 742         }
 743
 744         //te_wizspike(e.origin);
 745         //bprint(etos(e));
 746         //bprint("\n");
 747         // update the cached spawnfunc_waypoint link on a dynamic item entity
 748         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
 749         {
 750                 nwp = e;
 751         }
 752         else
 753         {
 754                 float search;
 755
 756                 search = TRUE;
 757
 758                 if(e.flags & FL_ITEM)
 759                 {
 760                         if not(e.flags & FL_WEAPON)
 761                         if(e.nearestwaypoint)
 762                                 search = FALSE;
 763                 }
 764                 else if (e.flags & FL_WEAPON)
 765                 {
 766                         if(e.classname != "droppedweapon")
 767                         if(e.nearestwaypoint)
 768                                 search = FALSE;
 769                 }
 770
 771                 if(search)
 772                 if (time > e.nearestwaypointtimeout)
 773                 {
 774                         nwp = navigation_findnearestwaypoint(e, TRUE);
 775                         if(nwp)
 776                                 e.nearestwaypoint = nwp;
 777                         else
 778                         {
 779                                 dprint("FAILED to find a nearest waypoint to '", e.classname, "' #", etos(e), "\n");
 780
 781                                 if(e.flags & FL_ITEM)
 782                                         e.blacklisted = TRUE;
 783                                 else if (e.flags & FL_WEAPON)
 784                                 {
 785                                         if(e.classname != "droppedweapon")
 786                                                 e.blacklisted = TRUE;
 787                                 }
 788
 789                                 if(e.blacklisted)
 790                                 {
 791                                         dprint("The entity '", e.classname, "' is going to be excluded from path finding during this match\n");
 792                                         return;
 793                                 }
 794                         }
 795
 796                         // TODO: Cleaner solution, probably handling this timeout from ctf.qc
 797                         if(e.classname=="item_flag_team")
 798                                 e.nearestwaypointtimeout = time + 2;
 799                         else
 800                                 e.nearestwaypointtimeout = time + random() * 3 + 5;
 801                 }
 802                 nwp = e.nearestwaypoint;
 803         }
 804
 805         //dprint("-- checking ", e.classname, " (with cost ", ftos(nwp.wpcost), ")\n");
 806         if (nwp)
 807         if (nwp.wpcost < 10000000)
 808         {
 809                 //te_wizspike(nwp.wpnearestpoint);
 810         //      dprint(e.classname, " ", ftos(f), "/(1+", ftos((nwp.wpcost + vlen(e.origin - nwp.wpnearestpoint))), "/", ftos(rangebias), ") = ");
 811                 f = f * rangebias / (rangebias + (nwp.wpcost + vlen(o - nwp.wpnearestpoint)));
 812                 //dprint("considering ", e.classname, " (with rating ", ftos(f), ")\n");
 813                 //dprint(ftos(f));
 814                 if (navigation_bestrating < f)
 815                 {
 816                 //      dprint("ground path: added goal ", e.classname, " (with rating ", ftos(f), ")\n");
 817                         navigation_bestrating = f;
 818                         navigation_bestgoal = e;
 819                 }
 820         }
 821         //dprint("\n");
 822 };
 823
 824 // adds an item to the the goal stack with the path to a given item
 825 float navigation_routetogoal(entity e, vector startposition)
 826 {
 827         self.goalentity = e;
 828
 829         // if there is no goal, just exit
 830         if (!e)
 831                 return FALSE;
 832
 833         self.navigation_hasgoals = TRUE;
 834
 835         // put the entity on the goal stack
 836         //print("routetogoal ", etos(e), "\n");
 837         navigation_pushroute(e);
 838
 839         if(g_jetpack)
 840         if(e==self.navigation_jetpack_goal)
 841                 return TRUE;
 842
 843         // if it can reach the goal there is nothing more to do
 844         if (tracewalk(self, startposition, PL_MIN, PL_MAX, (e.absmin + e.absmax) * 0.5, bot_navigation_movemode))
 845                 return TRUE;
 846
 847         // see if there are waypoints describing a path to the item
 848         if(e.classname != "waypoint" || (e.wpflags & WAYPOINTFLAG_PERSONAL))
 849                 e = e.nearestwaypoint;
 850         else
 851                 e = e.enemy; // we already have added it, so...
 852
 853         if(e == world)
 854                 return FALSE;
 855
 856         for (;;)
 857         {
 858                 // add the spawnfunc_waypoint to the path
 859                 navigation_pushroute(e);
 860                 e = e.enemy;
 861
 862                 if(e==world)
 863                         break;
 864         }
 865
 866         return FALSE;
 867 };
 868
 869 // removes any currently touching waypoints from the goal stack
 870 // (this is how bots detect if they reached a goal)
 871 void navigation_poptouchedgoals()
 872 {
 873         local vector org, m1, m2;
 874         org = self.origin;
 875         m1 = org + self.mins;
 876         m2 = org + self.maxs;
 877
 878         if(self.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 879         {
 880                 if(self.lastteleporttime>0)
 881                 if(time-self.lastteleporttime<(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL)?2:0.15)
 882                 {
 883                         if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
 884                         if(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && self.goalcurrent.owner==self)
 885                         {
 886                                 self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
 887                                 self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
 888                         }
 889                         navigation_poproute();
 890                         return;
 891                 }
 892         }
 893
 894         // If for some reason the bot is closer to the next goal, pop the current one
 895         if(self.goalstack01)
 896         if(vlen(self.goalcurrent.origin - self.origin) > vlen(self.goalstack01.origin - self.origin))
 897         if(checkpvs(self.origin + self.view_ofs, self.goalstack01))
 898         if(tracewalk(self, self.origin, self.mins, self.maxs, (self.goalstack01.absmin + self.goalstack01.absmax) * 0.5, bot_navigation_movemode))
 899         {
 900         ///     dprint("path optimized, removed a goal from the queue\n");
 901                 navigation_poproute();
 902                 // TODO this may also be a nice idea to do "early" (e.g. by
 903                 // manipulating the vlen() comparisons) to shorten paths in
 904                 // general - this would make bots walk more "on rails" than
 905                 // "zigzagging" which they currently do with sufficiently
 906                 // random-like waypoints, and thus can make a nice bot
 907                 // personality property
 908         }
 909
 910         // HACK: remove players/bots as goals, they can lead a bot to unexpected places (cliffs, lava, etc)
 911         // TODO: rate waypoints near the targetted player at that moment, instead of the player itself
 912         if(self.goalcurrent.classname=="player")
 913                 navigation_poproute();
 914
 915         // Loose goal touching check when running
 916         if(self.aistatus & AI_STATUS_RUNNING)
 917         if(self.goalcurrent.classname=="waypoint")
 918         {
 919                 if(vlen(self.origin - self.goalcurrent.origin)<150)
 920                 {
 921                         traceline(self.origin + self.view_ofs , self.goalcurrent.origin, TRUE, world);
 922                         if(trace_fraction==1)
 923                         {
 924                                 // Detect personal waypoints
 925                                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
 926                                 if(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && self.goalcurrent.owner==self)
 927                                 {
 928                                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
 929                                         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
 930                                 }
 931
 932                                 navigation_poproute();
 933                         }
 934                 }
 935         }
 936
 937         while (self.goalcurrent && boxesoverlap(m1, m2, self.goalcurrent.absmin, self.goalcurrent.absmax))
 938         {
 939                 // Detect personal waypoints
 940                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
 941                 if(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && self.goalcurrent.owner==self)
 942                 {
 943                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
 944                         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
 945                 }
 946
 947                 navigation_poproute();
 948         }
 949 }
 950
 951 // begin a goal selection session (queries spawnfunc_waypoint network)
 952 void navigation_goalrating_start()
 953 {
 954         if(self.aistatus & AI_STATUS_STUCK)
 955                 return;
 956
 957         self.navigation_jetpack_goal = world;
 958         navigation_bestrating = -1;
 959         self.navigation_hasgoals = FALSE;
 960         navigation_clearroute();
 961         navigation_bestgoal = world;
 962         navigation_markroutes(world);
 963 };
 964
 965 // ends a goal selection session (updates goal stack to the best goal)
 966 void navigation_goalrating_end()
 967 {
 968         if(self.aistatus & AI_STATUS_STUCK)
 969                 return;
 970
 971         navigation_routetogoal(navigation_bestgoal, self.origin);
 972 //      dprint("best goal ", self.goalcurrent.classname , "\n");
 973
 974         // If the bot got stuck then try to reach the farthest waypoint
 975         if not (self.navigation_hasgoals)
 976         if (autocvar_bot_wander_enable)
 977         {
 978                 if not(self.aistatus & AI_STATUS_STUCK)
 979                 {
 980                         dprint(self.netname, " cannot walk to any goal\n");
 981                         self.aistatus |= AI_STATUS_STUCK;
 982                 }
 983
 984                 self.navigation_hasgoals = FALSE; // Reset this value
 985         }
 986 };
 987
 988 void botframe_updatedangerousobjects(float maxupdate)
 989 {
 990         local entity head, bot_dodgelist;
 991         local vector m1, m2, v, o;
 992         local float c, d, danger;
 993         c = 0;
 994         bot_dodgelist = findchainfloat(bot_dodge, TRUE);
 995         botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
 996         while (botframe_dangerwaypoint != world)
 997         {
 998                 danger = 0;
 999                 m1 = botframe_dangerwaypoint.mins;
1000                 m2 = botframe_dangerwaypoint.maxs;
1001                 head = bot_dodgelist;
1002                 while (head)
1003                 {
1004                         v = head.origin;
1005                         v_x = bound(m1_x, v_x, m2_x);
1006                         v_y = bound(m1_y, v_y, m2_y);
1007                         v_z = bound(m1_z, v_z, m2_z);
1008                         o = (head.absmin + head.absmax) * 0.5;
1009                         d = head.bot_dodgerating - vlen(o - v);
1010                         if (d > 0)
1011                         {
1012                                 traceline(o, v, TRUE, world);
1013                                 if (trace_fraction == 1)
1014                                         danger = danger + d;
1015                         }
1016                         head = head.chain;
1017                 }
1018                 botframe_dangerwaypoint.dmg = danger;
1019                 c = c + 1;
1020                 if (c >= maxupdate)
1021                         break;
1022                 botframe_dangerwaypoint = find(botframe_dangerwaypoint, classname, "waypoint");
1023         }
1024 };
1025
1026 void navigation_unstuck()
1027 {
1028         float search_radius = 1000;
1029
1030         if not(autocvar_bot_wander_enable)
1031                 return;
1032
1033         if not(bot_waypoint_queue_owner)
1034         {
1035         //      dprint(self.netname, " sutck, taking over the waypoints queue\n");
1036                 bot_waypoint_queue_owner = self;
1037                 bot_waypoint_queue_bestgoal = world;
1038                 bot_waypoint_queue_bestgoalrating = 0;
1039         }
1040
1041         if(bot_waypoint_queue_owner!=self)
1042                 return;
1043
1044         if (bot_waypoint_queue_goal)
1045         {
1046                 // evaluate the next goal on the queue
1047                 float d = vlen(self.origin - bot_waypoint_queue_goal.origin);
1048                 // dprint(self.netname, " evaluating ", bot_waypoint_queue_goal.classname, " with distance ", ftos(d), "\n");
1049                 if(tracewalk(bot_waypoint_queue_goal, self.origin, PL_MIN, PL_MAX, bot_waypoint_queue_goal.origin, bot_navigation_movemode))
1050                 {
1051                         if( d > bot_waypoint_queue_bestgoalrating)
1052                         {
1053                                 bot_waypoint_queue_bestgoalrating = d;
1054                                 bot_waypoint_queue_bestgoal = bot_waypoint_queue_goal;
1055                         }
1056                 }
1057                 bot_waypoint_queue_goal = bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal;
1058
1059                 if not(bot_waypoint_queue_goal)
1060                 {
1061                         if (bot_waypoint_queue_bestgoal)
1062                         {
1063                                 dprint(self.netname, " stuck, reachable waypoint found, heading to it\n");
1064                                 navigation_routetogoal(bot_waypoint_queue_bestgoal, self.origin);
1065                                 self.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1066                                 self.aistatus &~= AI_STATUS_STUCK;
1067                         }
1068                         else
1069                         {
1070                                 dprint(self.netname, " stuck, cannot walk to any waypoint at all\n");
1071                         }
1072
1073                         bot_waypoint_queue_owner = world;
1074                 }
1075         }
1076         else
1077         {
1078                 if(bot_strategytoken!=self)
1079                         return;
1080
1081                 // build a new queue
1082                 dprint(self.netname, " stuck, scanning reachable waypoints within ", ftos(search_radius)," qu\n");
1083
1084                 entity head, first;
1085
1086                 first = world;
1087                 head = findradius(self.origin, search_radius);
1088
1089                 while(head)
1090                 {
1091                         if(head.classname=="waypoint")
1092                 //      if(!(head.wpflags & WAYPOINTFLAG_GENERATED))
1093                         {
1094                                 if(bot_waypoint_queue_goal)
1095                                         bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = head;
1096                                 else
1097                                         first = head;
1098
1099                                 bot_waypoint_queue_goal = head;
1100                                 bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = world;
1101                         }
1102
1103                         head = head.chain;
1104                 }
1105
1106                 if (first)
1107                         bot_waypoint_queue_goal = first;
1108                 else
1109                 {
1110                         dprint(self.netname, " stuck, cannot walk to any waypoint at all\n");
1111                         bot_waypoint_queue_owner = world;
1112                 }
1113         }
1114 }
1115
1116 // Support for debugging tracewalk visually
1117
1118 void debugresetnodes()
1119 {
1120         debuglastnode = '0 0 0';
1121 }
1122
1123 void debugnode(vector node)
1124 {
1125         if not(self.classname=="player")
1126                 return;
1127
1128         if(debuglastnode=='0 0 0')
1129         {
1130                 debuglastnode = node;
1131                 return;
1132         }
1133
1134         te_lightning2(world, node, debuglastnode);
1135         debuglastnode = node;
1136 }
1137
1138 void debugnodestatus(vector position, float status)
1139 {
1140         vector c;
1141
1142         switch (status)
1143         {
1144                 case DEBUG_NODE_SUCCESS:
1145                         c = '0 15 0';
1146                         break;
1147                 case DEBUG_NODE_WARNING:
1148                         c = '15 15 0';
1149                         break;
1150                 case DEBUG_NODE_FAIL:
1151                         c = '15 0 0';
1152                         break;
1153                 default:
1154                         c = '15 15 15';
1155         }
1156
1157         te_customflash(position, 40,  2, c);
1158 }
1159
1160 // Support for debugging the goal stack visually
1161
1162 .float goalcounter;
1163 .vector lastposition;
1164
1165 // Debug the goal stack visually
1166 void debuggoalstack()
1167 {
1168         local entity goal;
1169         local vector org, go;
1170
1171         if(self.goalcounter==0)goal=self.goalcurrent;
1172         else if(self.goalcounter==1)goal=self.goalstack01;
1173         else if(self.goalcounter==2)goal=self.goalstack02;
1174         else if(self.goalcounter==3)goal=self.goalstack03;
1175         else if(self.goalcounter==4)goal=self.goalstack04;
1176         else if(self.goalcounter==5)goal=self.goalstack05;
1177         else if(self.goalcounter==6)goal=self.goalstack06;
1178         else if(self.goalcounter==7)goal=self.goalstack07;
1179         else if(self.goalcounter==8)goal=self.goalstack08;
1180         else if(self.goalcounter==9)goal=self.goalstack09;
1181         else if(self.goalcounter==10)goal=self.goalstack10;
1182         else if(self.goalcounter==11)goal=self.goalstack11;
1183         else if(self.goalcounter==12)goal=self.goalstack12;
1184         else if(self.goalcounter==13)goal=self.goalstack13;
1185         else if(self.goalcounter==14)goal=self.goalstack14;
1186         else if(self.goalcounter==15)goal=self.goalstack15;
1187         else if(self.goalcounter==16)goal=self.goalstack16;
1188         else if(self.goalcounter==17)goal=self.goalstack17;
1189         else if(self.goalcounter==18)goal=self.goalstack18;
1190         else if(self.goalcounter==19)goal=self.goalstack19;
1191         else if(self.goalcounter==20)goal=self.goalstack20;
1192         else if(self.goalcounter==21)goal=self.goalstack21;
1193         else if(self.goalcounter==22)goal=self.goalstack22;
1194         else if(self.goalcounter==23)goal=self.goalstack23;
1195         else if(self.goalcounter==24)goal=self.goalstack24;
1196         else if(self.goalcounter==25)goal=self.goalstack25;
1197         else if(self.goalcounter==26)goal=self.goalstack26;
1198         else if(self.goalcounter==27)goal=self.goalstack27;
1199         else if(self.goalcounter==28)goal=self.goalstack28;
1200         else if(self.goalcounter==29)goal=self.goalstack29;
1201         else if(self.goalcounter==30)goal=self.goalstack30;
1202         else if(self.goalcounter==31)goal=self.goalstack31;
1203
1204         if(goal==world)
1205         {
1206                 self.goalcounter = 0;
1207                 self.lastposition='0 0 0';
1208                 return;
1209         }
1210
1211         if(self.lastposition=='0 0 0')
1212                 org = self.origin;
1213         else
1214                 org = self.lastposition;
1215
1216
1217         go = ( goal.absmin + goal.absmax ) * 0.5;
1218         te_lightning2(world, org, go);
1219         self.lastposition = go;
1220
1221         self.goalcounter++;
1222 }