qcsrc/server/campaign.qc

   1 #include "campaign.qh"
   2
   3 #include <common/mapinfo.qh>
   4 #include <common/weapons/_all.qh>
   5 #include <common/stats.qh>
   6
   7 #include "cheats.qh"
   8 #include <server/intermission.qh>
   9 #include "world.qh"
  10
  11 #include <common/campaign_common.qh>
  12
  13 // campaign cvars:
  14 //   _campaign_index: index of CURRENT map
  15 //   _campaign_name: name of the current campaign
  16 //   g_campaign(name)_index: index of current LAST map (saved)
  17 //   g_campaign_skill: bot skill offset
  18
  19 float campaign_level;
  20 float campaign_won;
  21 string campaign_index_var;
  22 //float checkrules_equality;
  23
  24 float CampaignBailout(string s)
  25 {
  26         cvar_set("g_campaign", "0");
  27         LOG_INFO("^4campaign initialization failed: ", s);
  28         if(autocvar__campaign_testrun)
  29                 error("CAMPAIGN FAIL AHAHAHAHAHAHAHAHAH))");
  30         return 1;
  31 }
  32
  33 float Campaign_Invalid()
  34 {
  35         string thismapname, wantedmapname;
  36         thismapname = GetMapname();
  37         wantedmapname = campaign_gametype[0];
  38         if(MapInfo_CurrentGametype() != MapInfo_Type_FromString(wantedmapname, false))
  39                 return CampaignBailout("wrong game type!");
  40         wantedmapname = campaign_mapname[0];
  41         if(wantedmapname != thismapname)
  42                 return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
  43         return 0;
  44 }
  45
  46 int Campaign_GetLevelNum()
  47 {
  48         return campaign_level + 1;
  49 }
  50
  51 string Campaign_GetMessage()
  52 {
  53         return strcat(campaign_shortdesc[0], "\n^3\n", campaign_longdesc[0]);
  54 }
  55
  56 void CampaignPreInit()
  57 {
  58         float baseskill;
  59         campaign_level = autocvar__campaign_index;
  60         campaign_name = strzone(autocvar__campaign_name);
  61         campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
  62         CampaignFile_Load(campaign_level, 2);
  63
  64         if(campaign_entries < 1)
  65         {
  66                 CampaignBailout("unknown map");
  67                 return;
  68         }
  69
  70         if(autocvar_sv_cheats)
  71         {
  72                 MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0], false));
  73                 CampaignFile_Unload();
  74                 CampaignBailout("JOLLY CHEATS AHAHAHAHAHAHAH))");
  75                 return;
  76         }
  77
  78         baseskill = max(0, autocvar_g_campaign_skill + campaign_botskill[0]);
  79         campaign_forcewin = false;
  80
  81         cvar_set("sv_public", "0");
  82         cvar_set("pausable", "1");
  83
  84         string cvar_campaignwrapper_list = strcat("; ", campaign_mutators[0], "; ");
  85         int argc = tokenizebyseparator(cvar_campaignwrapper_list, "; ");
  86         if(argc > 0)
  87         {
  88                 for(int j = 0; j < argc; ++j)
  89                 {
  90                         string arg = argv(j);
  91                         if(arg == "") continue;
  92                         _MapInfo_Parse_Settemp(mapname, MAPINFO_SETTEMP_ACL_USER, 0, arg, 1);
  93                 }
  94         }
  95
  96         cvar_settemp("g_campaign", "1");
  97         cvar_settemp("g_dm", "0");
  98         cvar_settemp("skill", ftos(baseskill));
  99         cvar_settemp("bot_number", ftos(campaign_bots[0]));
 100
 101         MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0], false));
 102
 103         if(Campaign_Invalid())
 104                 return;
 105 }
 106
 107 void CampaignPostInit()
 108 {
 109         // now some sanity checks
 110         if(Campaign_Invalid())
 111                 return;
 112         if(autocvar__campaign_testrun)
 113         {
 114                 cvar_set("fraglimit", "0");
 115                 cvar_set("leadlimit", "0");
 116                 cvar_set("timelimit", "0.01");
 117         }
 118         else
 119         {
 120                 // "default" uses implicit values, "" or "0" means no limit
 121                 tokenizebyseparator(campaign_fraglimit[0], "+");
 122                 if(argv(0) != "default") {
 123                         cvar_set("fraglimit", argv(0));
 124                 }
 125                 if(argv(1) != "default") {
 126                         cvar_set("leadlimit", argv(1));
 127                 }
 128                 if(campaign_timelimit[0] != "default") {
 129                         cvar_set("timelimit", campaign_timelimit[0]);
 130                 }
 131         }
 132 }
 133
 134 void CampaignSaveCvar(string cvarname, float value)
 135 {
 136         float fh;
 137         float len;
 138         string contents;
 139         string l;
 140
 141         registercvar(cvarname, ftos(value));
 142         cvar_set(cvarname, ftos(value));
 143         // note: cvarname must be remembered
 144
 145         fh = fopen("campaign.cfg", FILE_READ);
 146         contents = "";
 147         if(fh >= 0)
 148         {
 149                 while((l = fgets(fh)))
 150                 {
 151                         len = tokenize_console(l);
 152                         if(len != 3)
 153                                 continue;
 154                         if(argv(0) != "set")
 155                                 continue;
 156                         if(argv(1) == cvarname)
 157                                 continue;
 158                         contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
 159                 }
 160                 fclose(fh);
 161         }
 162         contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
 163         fh = fopen("campaign.cfg", FILE_WRITE);
 164         if(fh >= 0)
 165         {
 166                 fputs(fh, contents);
 167         }
 168         else
 169         {
 170                 error("Cannot write to campaign file");
 171         }
 172 }
 173
 174 void CampaignPreIntermission()
 175 {
 176         int won = 0;
 177         int lost = 0;
 178         string savevar;
 179
 180         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 181                 if(it.winning)
 182                         won += 1;
 183                 else
 184                         lost += 1;
 185         });
 186
 187         if(autocvar__campaign_testrun)
 188         {
 189                 campaign_won = 1;
 190                 bprint("Campaign test run, advancing level.\n");
 191         }
 192         else if(campaign_forcewin)
 193         {
 194                 campaign_won = 1;
 195                 bprint("The current level has been WON.\n");
 196         }
 197         else if(won == 1 && lost == 0 && checkrules_equality == 0)
 198         {
 199                 if(autocvar_timelimit != 0 && autocvar_fraglimit != 0 && time > autocvar_timelimit * 60) // checks if the timelimit has expired.
 200                 {
 201                         campaign_won = 0;
 202                         bprint("Time's up! The current level has been LOST.\n");
 203                         // sound!
 204                 }
 205                 else
 206                 {
 207                         campaign_won = 1;
 208                         bprint("The current level has been WON.\n");
 209                         // sound!
 210                 }
 211         }
 212         else if(autocvar_timelimit != 0 && time > autocvar_timelimit * 60)
 213         {
 214                 campaign_won = 0;
 215                 bprint("Time's up! The current level has been LOST.\n");
 216                 // sound!
 217         }
 218         else
 219         {
 220                 campaign_won = 0;
 221                 bprint("The current level has been LOST.\n");
 222                 // sound!
 223         }
 224
 225         if(campaign_won && cheatcount_total == 0 && !autocvar__campaign_testrun)
 226         {
 227                 if(campaign_level == cvar(campaign_index_var))
 228                 {
 229                         if(campaign_entries < 2)
 230                         {
 231                                 // I have won
 232                                 savevar = strcat("g_campaign", campaign_name, "_won");
 233                                 CampaignSaveCvar(savevar, 1);
 234                                 // advance level (for menu to show it right)
 235                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 236                         }
 237                         else
 238                         {
 239                                 // advance level
 240                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 241                         }
 242                 }
 243         }
 244 }
 245
 246 void CampaignPostIntermission()
 247 {
 248         // NOTE: campaign_won is 0 or 1, that is, points to the next level
 249
 250         if(campaign_won && campaign_entries < 2)
 251         {
 252                 // last map won!
 253                 LOG_DEBUG("^2test run: campaign looks GOOD");
 254                 localcmd("togglemenu 1\n");
 255                 CampaignFile_Unload();
 256                 return;
 257         }
 258
 259         CampaignSetup(campaign_won);
 260         CampaignFile_Unload();
 261         strunzone(campaign_index_var);
 262         strunzone(campaign_name);
 263         campaign_name = "";
 264 }
 265
 266
 267
 268 void CampaignLevelWarp(float n)
 269 {
 270         if(n < 0)
 271                 n = campaign_level + 1;
 272         CampaignFile_Unload();
 273         CampaignFile_Load(n, 1);
 274         if(campaign_entries)
 275                 CampaignSetup(0);
 276         else
 277                 error("Sorry, cheater. You are NOT WELCOME.");
 278         CampaignFile_Unload();
 279 }
 280