qcsrc/server/campaign.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qc"
   5     #include "../dpdefs/dpextensions.qc"
   6     #include "sys-post.qh"
   7     #include "autocvars.qh"
   8     #include "defs.qh"
   9     #include "campaign.qh"
  10     #include "../common/campaign_common.qh"
  11     #include "../common/mapinfo.qh"
  12     #include "cheats.qh"
  13 #endif
  14
  15 // campaign cvars:
  16 //   _campaign_index: index of CURRENT map
  17 //   _campaign_name: name of the current campaign
  18 //   g_campaign(name)_index: index of current LAST map (saved)
  19 //   g_campaign_skill: bot skill offset
  20
  21 float campaign_level;
  22 float campaign_won;
  23 string campaign_index_var;
  24 //float checkrules_equality;
  25
  26 float CampaignBailout(string s)
  27 {
  28         cvar = cvar_normal;
  29         cvar_string = cvar_string_normal;
  30         cvar_set = cvar_set_normal;
  31         cvar_set("g_campaign", "0");
  32         print("^4campaign initialization failed: ", s, "\n");
  33         if(autocvar__campaign_testrun)
  34                 error("CAMPAIGN FAIL AHAHAHAHAHAHAHAHAH))");
  35         return 1;
  36 }
  37
  38 string cvar_campaignwrapper_list; // string of format ; var value; var value; var value;
  39 string cvar_string_campaignwrapper(string theCvar)
  40 {
  41         float p, q;
  42         p = strstrofs(cvar_campaignwrapper_list, strcat("; ", theCvar, " "), 0);
  43         if(p < 0)
  44                 return cvar_defstring(theCvar);
  45         p += strlen(theCvar) + 3;
  46         q = strstrofs(cvar_campaignwrapper_list, ";", p);
  47         if(q < 0)
  48                 return cvar_defstring(theCvar);
  49         return substring(cvar_campaignwrapper_list, p, q - p);
  50 }
  51 float cvar_campaignwrapper(string theCvar)
  52 {
  53         return stof(cvar_string_campaignwrapper(theCvar));
  54 }
  55 void cvar_set_campaignwrapper(string theCvar, string theValue)
  56 {
  57         if(cvar_string_campaignwrapper(theCvar) == theValue)
  58                 return;
  59         string s;
  60         s = cvar_campaignwrapper_list;
  61         cvar_campaignwrapper_list = strzone(strcat("; ", theCvar, " ", theValue, s));
  62         strunzone(s);
  63         //print(cvar_campaignwrapper_list, "\n");
  64 }
  65
  66 float Campaign_Invalid()
  67 {
  68         string thismapname, wantedmapname;
  69         thismapname = GetMapname();
  70         wantedmapname = campaign_gametype[0];
  71         if(MapInfo_CurrentGametype() != MapInfo_Type_FromString(wantedmapname))
  72                 return CampaignBailout("wrong game type!");
  73         wantedmapname = campaign_mapname[0];
  74         if(wantedmapname != thismapname)
  75                 return CampaignBailout(strcat("wrong map: ", wantedmapname, " != ", thismapname));
  76         return 0;
  77 }
  78
  79 void CampaignPreInit()
  80 {
  81         float baseskill;
  82         string title;
  83         if(autocvar_sv_cheats)
  84         {
  85                 CampaignBailout("JOLLY CHEATS AHAHAHAHAHAHAH))");
  86                 return;
  87         }
  88         campaign_level = autocvar__campaign_index;
  89         campaign_name = strzone(autocvar__campaign_name);
  90         campaign_index_var = strzone(strcat("g_campaign", campaign_name, "_index"));
  91         CampaignFile_Load(campaign_level, 2);
  92         if(campaign_entries < 1)
  93         {
  94                 CampaignBailout("unknown map");
  95                 return;
  96         }
  97
  98         baseskill = autocvar_g_campaign_skill;
  99         baseskill = baseskill + campaign_botskill[0];
 100         if(baseskill < 0)
 101                 baseskill = 0;
 102
 103         cvar_set("sv_public", "0");
 104         cvar_set("pausable", "1");
 105
 106         cvar_campaignwrapper_list = strzone(strcat("; ", campaign_mutators[0], "; "));
 107
 108         cvar = cvar_campaignwrapper;
 109         cvar_string = cvar_string_campaignwrapper;
 110         cvar_set = cvar_set_campaignwrapper;
 111
 112         cvar_set("g_campaign", "1");
 113         cvar_set("g_dm", "0");
 114         cvar_set("skill", ftos(baseskill));
 115         cvar_set("bot_number", ftos(campaign_bots[0]));
 116         MapInfo_SwitchGameType(MapInfo_Type_FromString(campaign_gametype[0]));
 117
 118         // copy sv_gravity cvar, as the engine needs it too (sorry, this will mess
 119         // with the menu a little still...)
 120         cvar_set_normal("sv_gravity", ftos(autocvar_sv_gravity));
 121
 122         if(Campaign_Invalid())
 123                 return;
 124
 125         title = campaign_shortdesc[0];
 126         title = strzone(strcat("Level ", ftos(campaign_level + 1), ": ", title));
 127         campaign_message = strzone(strcat(title, "\n^3\n", campaign_longdesc[0], "\n\n^1press jump to enter the game"));
 128         strunzone(title);
 129 }
 130
 131 string GetMapname();
 132 void CampaignPostInit()
 133 {
 134         // now some sanity checks
 135         if(Campaign_Invalid())
 136                 return;
 137         if(autocvar__campaign_testrun)
 138         {
 139                 cvar_set("fraglimit", "0");
 140                 cvar_set("timelimit", "0.01");
 141                 cvar_set_normal("fraglimit", "0");
 142                 cvar_set_normal("timelimit", "0.01");
 143         }
 144         else
 145         {
 146                 cvar_set("fraglimit", ftos(campaign_fraglimit[0]));
 147                 cvar_set("timelimit", ftos(campaign_timelimit[0]));
 148                 cvar_set_normal("fraglimit", ftos(campaign_fraglimit[0]));
 149                 cvar_set_normal("timelimit", ftos(campaign_timelimit[0]));
 150         }
 151 }
 152
 153 void CampaignSaveCvar(string cvarname, float value)
 154 {
 155         float fh;
 156         float len;
 157         string contents;
 158         string l;
 159
 160         registercvar(cvarname, ftos(value));
 161         cvar_set_normal(cvarname, ftos(value));
 162         // note: cvarname must be remembered
 163
 164         fh = fopen("campaign.cfg", FILE_READ);
 165         contents = "";
 166         if(fh >= 0)
 167         {
 168                 while((l = fgets(fh)))
 169                 {
 170                         len = tokenize_console(l);
 171                         if(len != 3)
 172                                 continue;
 173                         if(argv(0) != "set")
 174                                 continue;
 175                         if(argv(1) == cvarname)
 176                                 continue;
 177                         contents = strcat(contents, "set ", argv(1), " ", argv(2), "\n");
 178                 }
 179                 fclose(fh);
 180         }
 181         contents = strcat(contents, "set ", cvarname,  " ", ftos(value), "\n");
 182         fh = fopen("campaign.cfg", FILE_WRITE);
 183         if(fh >= 0)
 184         {
 185                 fputs(fh, contents);
 186         }
 187         else
 188         {
 189                 error("Cannot write to campaign file");
 190         }
 191 }
 192
 193 void CampaignPreIntermission()
 194 {
 195         entity head;
 196         float won;
 197         float lost;
 198         string savevar;
 199
 200         won = lost = 0;
 201
 202         head = findchain(classname, "player");
 203         while(head)
 204         {
 205                 if(IS_REAL_CLIENT(head))
 206                 {
 207                         if(head.winning)
 208                                 won = won + 1;
 209                         else
 210                                 lost = lost + 1;
 211                 }
 212                 head = head.chain;
 213         }
 214
 215         if(autocvar__campaign_testrun)
 216         {
 217                 campaign_won = 1;
 218                 bprint("Campaign test run, advancing level.\n");
 219         }
 220         else if(won == 1 && lost == 0 && checkrules_equality == 0)
 221         {
 222                 if(autocvar_timelimit != 0 && autocvar_fraglimit != 0 && time > autocvar_timelimit * 60) // checks if the timelimit has expired.
 223                 {
 224                         campaign_won = 0;
 225                         bprint("Time's up! The current level has been LOST.\n");
 226                         // sound!
 227                 }
 228                 else
 229                 {
 230                         campaign_won = 1;
 231                         bprint("The current level has been WON.\n");
 232                         // sound!
 233                 }
 234         }
 235         else if(autocvar_timelimit != 0 && time > autocvar_timelimit * 60)
 236         {
 237                 campaign_won = 0;
 238                 bprint("Time's up! The current level has been LOST.\n");
 239                 // sound!
 240         }
 241         else
 242         {
 243                 campaign_won = 0;
 244                 bprint("The current level has been LOST.\n");
 245                 // sound!
 246         }
 247
 248         if(campaign_won && cheatcount_total == 0 && !autocvar__campaign_testrun)
 249         {
 250                 if(campaign_level == cvar_normal(campaign_index_var))
 251                 {
 252                         if(campaign_entries < 2)
 253                         {
 254                                 // I have won
 255                                 savevar = strcat("g_campaign", campaign_name, "_won");
 256                                 CampaignSaveCvar(savevar, 1);
 257                                 // advance level (for menu to show it right)
 258                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 259                         }
 260                         else
 261                         {
 262                                 // advance level
 263                                 CampaignSaveCvar(campaign_index_var, campaign_level + 1);
 264                         }
 265                 }
 266         }
 267 }
 268
 269 void CampaignPostIntermission()
 270 {
 271         // NOTE: campaign_won is 0 or 1, that is, points to the next level
 272
 273         if(campaign_won && campaign_entries < 2)
 274         {
 275                 // last map won!
 276                 print("^2test run: campaign looks GOOD\n");
 277                 localcmd("togglemenu 1\n");
 278                 CampaignFile_Unload();
 279                 return;
 280         }
 281
 282         CampaignSetup(campaign_won);
 283         CampaignFile_Unload();
 284         strunzone(campaign_message);
 285         strunzone(campaign_index_var);
 286         strunzone(campaign_name);
 287         campaign_name = "";
 288 }
 289
 290
 291
 292 void CampaignLevelWarp(float n)
 293 {
 294         if(n < 0)
 295                 n = campaign_level + 1;
 296         CampaignFile_Unload();
 297         CampaignFile_Load(n, 1);
 298         if(campaign_entries)
 299                 CampaignSetup(0);
 300         else
 301                 error("Sorry, cheater. You are NOT WELCOME.");
 302         CampaignFile_Unload();
 303 }
 304