qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ent_cs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "spawnpoints.qh"
  13 #include "g_damage.qh"
  14 #include "g_hook.qh"
  15 #include "command/common.qh"
  16 #include "cheats.qh"
  17 #include "g_world.qh"
  18 #include "race.qh"
  19 #include "antilag.qh"
  20 #include "campaign.qh"
  21 #include "command/common.qh"
  22
  23 #include "bot/bot.qh"
  24 #include "bot/navigation.qh"
  25
  26 #include "../common/vehicles/all.qh"
  27 #include "../common/triggers/teleporters.qh"
  28
  29 #include "weapons/hitplot.qh"
  30 #include "weapons/weaponsystem.qh"
  31
  32 #include "../common/net_notice.qh"
  33 #include "../common/physics.qh"
  34
  35 #include "../common/items/all.qc"
  36
  37 #include "../common/mutators/mutator/waypoints/all.qh"
  38
  39 #include "../common/triggers/subs.qh"
  40 #include "../common/triggers/triggers.qh"
  41 #include "../common/triggers/trigger/secret.qh"
  42
  43 #include "../common/minigames/sv_minigames.qh"
  44
  45 #include "../common/items/inventory.qh"
  46
  47 #include "../common/monsters/sv_monsters.qh"
  48
  49 #include "../lib/warpzone/server.qh"
  50
  51
  52 void send_CSQC_teamnagger() {
  53         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  54         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  55 }
  56
  57 bool ClientData_Send(entity this, entity to, int sf)
  58 {
  59         if(to != self.owner)
  60         {
  61                 error("wtf");
  62                 return false;
  63         }
  64
  65         entity e;
  66
  67         e = to;
  68         if(IS_SPEC(to))
  69                 e = to.enemy;
  70
  71         sf = 0;
  72
  73         if(e.race_completed)
  74                 sf |= 1; // forced scoreboard
  75         if(to.spectatee_status)
  76                 sf |= 2; // spectator ent number follows
  77         if(e.zoomstate)
  78                 sf |= 4; // zoomed
  79         if(e.porto_v_angle_held)
  80                 sf |= 8; // angles held
  81
  82         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  83         WriteByte(MSG_ENTITY, sf);
  84
  85         if(sf & 2)
  86                 WriteByte(MSG_ENTITY, to.spectatee_status);
  87
  88         if(sf & 8)
  89         {
  90                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  91                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  92         }
  93
  94         return true;
  95 }
  96
  97 void ClientData_Attach()
  98 {SELFPARAM();
  99         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
 100         self.clientdata.drawonlytoclient = self;
 101         self.clientdata.owner = self;
 102 }
 103
 104 void ClientData_Detach()
 105 {SELFPARAM();
 106         remove(self.clientdata);
 107         self.clientdata = world;
 108 }
 109
 110 void ClientData_Touch(entity e)
 111 {
 112         e.clientdata.SendFlags = 1;
 113
 114         // make it spectatable
 115         entity e2;
 116         FOR_EACH_REALCLIENT(e2)
 117         {
 118                 if(e2 != e)
 119                         if(IS_SPEC(e2))
 120                                 if(e2.enemy == e)
 121                                         e2.clientdata.SendFlags = 1;
 122         }
 123 }
 124
 125 .string netname_previous;
 126
 127 void SetSpectator(entity player, entity spectatee);
 128
 129
 130 /*
 131 =============
 132 CheckPlayerModel
 133
 134 Checks if the argument string can be a valid playermodel.
 135 Returns a valid one in doubt.
 136 =============
 137 */
 138 string FallbackPlayerModel;
 139 string CheckPlayerModel(string plyermodel) {
 140         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 141         {
 142                 // note: we cannot summon Don Strunzone here, some player may
 143                 // still have the model string set. In case anyone manages how
 144                 // to change a cvar default, we'll have a small leak here.
 145                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 146         }
 147         // only in right path
 148         if( substring(plyermodel,0,14) != "models/player/")
 149                 return FallbackPlayerModel;
 150         // only good file extensions
 151         if(substring(plyermodel,-4,4) != ".zym")
 152         if(substring(plyermodel,-4,4) != ".dpm")
 153         if(substring(plyermodel,-4,4) != ".iqm")
 154         if(substring(plyermodel,-4,4) != ".md3")
 155         if(substring(plyermodel,-4,4) != ".psk")
 156                 return FallbackPlayerModel;
 157         // forbid the LOD models
 158         if(substring(plyermodel, -9,5) == "_lod1")
 159                 return FallbackPlayerModel;
 160         if(substring(plyermodel, -9,5) == "_lod2")
 161                 return FallbackPlayerModel;
 162         if(plyermodel != strtolower(plyermodel))
 163                 return FallbackPlayerModel;
 164         // also, restrict to server models
 165         if(autocvar_sv_servermodelsonly)
 166         {
 167                 if(!fexists(plyermodel))
 168                         return FallbackPlayerModel;
 169         }
 170         return plyermodel;
 171 }
 172
 173 void setplayermodel(entity e, string modelname)
 174 {
 175         precache_model(modelname);
 176         _setmodel(e, modelname);
 177         player_setupanimsformodel();
 178         UpdatePlayerSounds();
 179 }
 180
 181 /*
 182 =============
 183 PutObserverInServer
 184
 185 putting a client as observer in the server
 186 =============
 187 */
 188 void FixPlayermodel();
 189 void PutObserverInServer (void)
 190 {SELFPARAM();
 191         entity  spot;
 192     self.hud = HUD_NORMAL;
 193
 194         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
 195
 196         spot = SelectSpawnPoint (true);
 197         if(!spot)
 198                 error("No spawnpoints for observers?!?\n");
 199         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 200
 201         if(IS_REAL_CLIENT(self))
 202         {
 203                 msg_entity = self;
 204                 WriteByte(MSG_ONE, SVC_SETVIEW);
 205                 WriteEntity(MSG_ONE, self);
 206         }
 207
 208         self.frags = FRAGS_SPECTATOR;
 209         self.bot_attack = false;
 210
 211         MUTATOR_CALLHOOK(MakePlayerObserver);
 212
 213         Portal_ClearAll(self);
 214
 215         Unfreeze(self);
 216
 217         if(self.alivetime)
 218         {
 219                 if(!warmup_stage)
 220                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 221                 self.alivetime = 0;
 222         }
 223
 224         if(self.vehicle)
 225                 vehicles_exit(VHEF_RELEASE);
 226
 227         WaypointSprite_PlayerDead();
 228
 229         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 230                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 231
 232         if(self.killcount != -666)
 233         {
 234                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 235                 if(!intermission_running)
 236                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 237                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 238
 239                 if(self.just_joined == false) {
 240                         LogTeamchange(self.playerid, -1, 4);
 241                 } else
 242                         self.just_joined = false;
 243         }
 244
 245         PlayerScore_Clear(self); // clear scores when needed
 246
 247         accuracy_resend(self);
 248
 249         self.spectatortime = time;
 250
 251         self.classname = "observer";
 252         self.iscreature = false;
 253         self.teleportable = TELEPORT_SIMPLE;
 254         self.damagedbycontents = false;
 255         self.health = -666;
 256         self.takedamage = DAMAGE_NO;
 257         self.solid = SOLID_NOT;
 258         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 259         self.flags = FL_CLIENT | FL_NOTARGET;
 260         self.armorvalue = 666;
 261         self.effects = 0;
 262         self.armorvalue = autocvar_g_balance_armor_start;
 263         self.pauserotarmor_finished = 0;
 264         self.pauserothealth_finished = 0;
 265         self.pauseregen_finished = 0;
 266         self.damageforcescale = 0;
 267         self.death_time = 0;
 268         self.respawn_flags = 0;
 269         self.respawn_time = 0;
 270         self.stat_respawn_time = 0;
 271         self.alpha = 0;
 272         self.scale = 0;
 273         self.fade_time = 0;
 274         self.pain_frame = 0;
 275         self.pain_finished = 0;
 276         self.strength_finished = 0;
 277         self.invincible_finished = 0;
 278         self.superweapons_finished = 0;
 279         self.pushltime = 0;
 280         self.istypefrag = 0;
 281         self.think = func_null;
 282         self.nextthink = 0;
 283         self.hook_time = 0;
 284         self.deadflag = DEAD_NO;
 285         self.angles = spot.angles;
 286         self.angles_z = 0;
 287         self.fixangle = true;
 288         self.crouch = false;
 289         self.revival_time = 0;
 290
 291         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 292         self.prevorigin = self.origin;
 293         self.items = 0;
 294         self.weapons = '0 0 0';
 295         self.model = "";
 296         FixPlayermodel();
 297         setmodel(self, MDL_Null);
 298         self.drawonlytoclient = self;
 299
 300         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 301         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 302
 303         self.weapon = 0;
 304         self.weaponname = "";
 305         self.switchingweapon = 0;
 306         self.weaponmodel = "";
 307         self.weaponentity = world;
 308         self.exteriorweaponentity = world;
 309         self.killcount = -666;
 310         self.velocity = '0 0 0';
 311         self.avelocity = '0 0 0';
 312         self.punchangle = '0 0 0';
 313         self.punchvector = '0 0 0';
 314         self.oldvelocity = self.velocity;
 315         self.fire_endtime = -1;
 316         self.event_damage = func_null;
 317 }
 318
 319 .float model_randomizer;
 320 void FixPlayermodel()
 321 {SELFPARAM();
 322         string defaultmodel;
 323         float defaultskin, chmdl, oldskin, n, i;
 324         vector m1, m2;
 325
 326         defaultmodel = "";
 327         defaultskin = 0;
 328         chmdl = false;
 329
 330         if(autocvar_sv_defaultcharacter)
 331         {
 332                 if(teamplay)
 333                 {
 334                         string s = Static_Team_ColorName_Lower(self.team);
 335                         if (s != "neutral")
 336                         {
 337                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 338                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 339                         }
 340                 }
 341
 342                 if(defaultmodel == "")
 343                 {
 344                         defaultmodel = autocvar_sv_defaultplayermodel;
 345                         defaultskin = autocvar_sv_defaultplayerskin;
 346                 }
 347
 348                 n = tokenize_console(defaultmodel);
 349                 if(n > 0)
 350                 {
 351                         defaultmodel = argv(floor(n * self.model_randomizer));
 352                         // However, do NOT randomize if the player-selected model is in the list.
 353                         for (i = 0; i < n; ++i)
 354                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 355                                         defaultmodel = argv(i);
 356                 }
 357
 358                 i = strstrofs(defaultmodel, ":", 0);
 359                 if(i >= 0)
 360                 {
 361                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 362                         defaultmodel = substring(defaultmodel, 0, i);
 363                 }
 364         }
 365
 366         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
 367         defaultmodel = ret_string;
 368         defaultskin = ret_int;
 369
 370         if(defaultmodel != "")
 371         {
 372                 if (defaultmodel != self.model)
 373                 {
 374                         m1 = self.mins;
 375                         m2 = self.maxs;
 376                         setplayermodel (self, defaultmodel);
 377                         setsize (self, m1, m2);
 378                         chmdl = true;
 379                 }
 380
 381                 oldskin = self.skin;
 382                 self.skin = defaultskin;
 383         } else {
 384                 if (self.playermodel != self.model || self.playermodel == "")
 385                 {
 386                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 387                         m1 = self.mins;
 388                         m2 = self.maxs;
 389                         setplayermodel (self, self.playermodel);
 390                         setsize (self, m1, m2);
 391                         chmdl = true;
 392                 }
 393
 394                 oldskin = self.skin;
 395                 self.skin = stof(self.playerskin);
 396         }
 397
 398         if(chmdl || oldskin != self.skin) // model or skin has changed
 399         {
 400                 self.species = player_getspecies(); // update species
 401                 UpdatePlayerSounds(); // update skin sounds
 402         }
 403
 404         if(!teamplay)
 405                 if(strlen(autocvar_sv_defaultplayercolors))
 406                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 407                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 408 }
 409
 410
 411 /** Called when a client spawns in the server */
 412 void PutClientInServer()
 413 {
 414         SELFPARAM();
 415         if(IS_BOT_CLIENT(self))
 416                 self.classname = "player";
 417         else if(IS_REAL_CLIENT(self))
 418         {
 419                 msg_entity = self;
 420                 WriteByte(MSG_ONE, SVC_SETVIEW);
 421                 WriteEntity(MSG_ONE, self);
 422         }
 423
 424         SetSpectator(self, world);
 425
 426         // reset player keys
 427         self.itemkeys = 0;
 428
 429         MUTATOR_CALLHOOK(PutClientInServer, self);
 430
 431         if(gameover)
 432                 self.classname = "observer";
 433
 434         if(IS_PLAYER(self))
 435         {
 436                 entity spot;
 437
 438                 accuracy_resend(self);
 439
 440                 if(self.team < 0)
 441                         JoinBestTeam(self, false, true);
 442
 443                 spot = SelectSpawnPoint (false);
 444                 if(!spot)
 445                 {
 446                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 447                         return; // spawn failed
 448                 }
 449
 450                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 451
 452                 self.classname = "player";
 453                 self.wasplayer = true;
 454                 self.iscreature = true;
 455                 self.teleportable = TELEPORT_NORMAL;
 456                 self.damagedbycontents = true;
 457                 self.movetype = MOVETYPE_WALK;
 458                 self.solid = SOLID_SLIDEBOX;
 459                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 460                 if(autocvar_g_playerclip_collisions)
 461                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 462                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 463                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 464                 self.frags = FRAGS_PLAYER;
 465                 if(INDEPENDENT_PLAYERS)
 466                         MAKE_INDEPENDENT_PLAYER(self);
 467                 self.flags = FL_CLIENT | FL_PICKUPITEMS;
 468                 if(autocvar__notarget)
 469                         self.flags |= FL_NOTARGET;
 470                 self.takedamage = DAMAGE_AIM;
 471                 self.effects = 0;
 472                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 473                 self.air_finished = time + 12;
 474                 self.dmg = 2;
 475                 if(WEP_CVAR(vortex, charge))
 476                 {
 477                         if(WEP_CVAR_SEC(vortex, chargepool))
 478                                 self.vortex_chargepool_ammo = 1;
 479                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 480                 }
 481
 482                 if(warmup_stage)
 483                 {
 484                         self.ammo_shells = warmup_start_ammo_shells;
 485                         self.ammo_nails = warmup_start_ammo_nails;
 486                         self.ammo_rockets = warmup_start_ammo_rockets;
 487                         self.ammo_cells = warmup_start_ammo_cells;
 488                         self.ammo_plasma = warmup_start_ammo_plasma;
 489                         self.ammo_fuel = warmup_start_ammo_fuel;
 490                         self.health = warmup_start_health;
 491                         self.armorvalue = warmup_start_armorvalue;
 492                         self.weapons = WARMUP_START_WEAPONS;
 493                 }
 494                 else
 495                 {
 496                         self.ammo_shells = start_ammo_shells;
 497                         self.ammo_nails = start_ammo_nails;
 498                         self.ammo_rockets = start_ammo_rockets;
 499                         self.ammo_cells = start_ammo_cells;
 500                         self.ammo_plasma = start_ammo_plasma;
 501                         self.ammo_fuel = start_ammo_fuel;
 502                         self.health = start_health;
 503                         self.armorvalue = start_armorvalue;
 504                         self.weapons = start_weapons;
 505                 }
 506
 507                 if(self.weapons & WEPSET_SUPERWEAPONS)
 508                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 509                 else
 510                         self.superweapons_finished = 0;
 511
 512                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 513                 {
 514                         if(g_weaponarena_random_with_blaster)
 515                                 self.weapons &= ~WEPSET(BLASTER);
 516                         W_RandomWeapons(self, g_weaponarena_random);
 517                         if(g_weaponarena_random_with_blaster)
 518                                 self.weapons |= WEPSET(BLASTER);
 519                 }
 520
 521                 self.items = start_items;
 522
 523                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 524                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 525                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 526                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 527                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 528                 //extend the pause of rotting if client was reset at the beginning of the countdown
 529                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 530                         self.spawnshieldtime += game_starttime - time;
 531                         self.pauserotarmor_finished += game_starttime - time;
 532                         self.pauserothealth_finished += game_starttime - time;
 533                         self.pauseregen_finished += game_starttime - time;
 534                 }
 535                 self.damageforcescale = 2;
 536                 self.death_time = 0;
 537                 self.respawn_flags = 0;
 538                 self.respawn_time = 0;
 539                 self.stat_respawn_time = 0;
 540                 self.scale = autocvar_sv_player_scale;
 541                 self.fade_time = 0;
 542                 self.pain_frame = 0;
 543                 self.pain_finished = 0;
 544                 self.strength_finished = 0;
 545                 self.invincible_finished = 0;
 546                 self.pushltime = 0;
 547                 // players have no think function
 548                 self.think = func_null;
 549                 self.nextthink = 0;
 550                 self.hook_time = 0;
 551                 self.dmg_team = 0;
 552                 self.ballistics_density = autocvar_g_ballistics_density_player;
 553
 554                 self.metertime = 0;
 555
 556                 self.deadflag = DEAD_NO;
 557
 558                 self.angles = spot.angles;
 559
 560                 self.angles_z = 0; // never spawn tilted even if the spot says to
 561                 if(IS_BOT_CLIENT(self))
 562                         self.v_angle = self.angles;
 563                 self.fixangle = true; // turn this way immediately
 564                 self.velocity = '0 0 0';
 565                 self.avelocity = '0 0 0';
 566                 self.punchangle = '0 0 0';
 567                 self.punchvector = '0 0 0';
 568                 self.oldvelocity = self.velocity;
 569                 self.fire_endtime = -1;
 570                 self.revival_time = 0;
 571
 572                 entity spawnevent = spawn();
 573                 spawnevent.owner = self;
 574                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 575
 576                 // Cut off any still running player sounds.
 577                 stopsound(self, CH_PLAYER_SINGLE);
 578
 579                 self.model = "";
 580                 FixPlayermodel();
 581                 self.drawonlytoclient = world;
 582
 583                 self.crouch = false;
 584                 self.view_ofs = PL_VIEW_OFS;
 585                 setsize (self, PL_MIN, PL_MAX);
 586                 self.spawnorigin = spot.origin;
 587                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 588                 // don't reset back to last position, even if new position is stuck in solid
 589                 self.oldorigin = self.origin;
 590                 self.prevorigin = self.origin;
 591                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 592                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 593         self.hud = HUD_NORMAL;
 594
 595                 self.event_damage = PlayerDamage;
 596
 597                 self.bot_attack = true;
 598                 self.monster_attack = true;
 599
 600                 self.spider_slowness = 0;
 601
 602                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 603
 604                 if(self.killcount == -666) {
 605                         PlayerScore_Clear(self);
 606                         self.killcount = 0;
 607                 }
 608
 609                 CL_SpawnWeaponentity(self);
 610                 self.alpha = default_player_alpha;
 611                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 612                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 613
 614                 self.speedrunning = false;
 615
 616                 //stuffcmd(self, "chase_active 0");
 617                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 618
 619                 target_voicescript_clear(self);
 620
 621                 // reset fields the weapons may use
 622                 for (int j = WEP_FIRST; j <= WEP_LAST; ++j)
 623                 {
 624                         Weapon w = get_weaponinfo(j);
 625                         w.wr_resetplayer(w);
 626
 627                         // all weapons must be fully loaded when we spawn
 628                         entity e = get_weaponinfo(j);
 629                         if (e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 630                                 self.(weapon_load[j]) = e.reloading_ammo;
 631                 }
 632
 633                 string s = spot.target;
 634                 spot.target = string_null;
 635                 activator = self;
 636                 WITH(entity, self, spot, SUB_UseTargets());
 637                 activator = world;
 638                 spot.target = s;
 639
 640                 Unfreeze(self);
 641
 642                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 643
 644                 if(autocvar_spawn_debug)
 645                 {
 646                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 647                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 648                 }
 649
 650                 self.switchweapon = w_getbestweapon(self);
 651                 self.cnt = -1; // W_LastWeapon will not complain
 652                 self.weapon = 0;
 653                 self.weaponname = "";
 654                 self.switchingweapon = 0;
 655
 656                 if(!warmup_stage)
 657                         if(!self.alivetime)
 658                                 self.alivetime = time;
 659
 660                 antilag_clear(self);
 661         }
 662         else if(IS_OBSERVER(self))
 663         {
 664                 PutObserverInServer ();
 665         }
 666 }
 667
 668 .float ebouncefactor, ebouncestop; // electro's values
 669 // TODO do we need all these fields, or should we stop autodetecting runtime
 670 // changes and just have a console command to update this?
 671 bool ClientInit_SendEntity(entity this, entity to, int sf)
 672 {
 673         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 674         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 675         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 676         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 677         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 678         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 679         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 680         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 681         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 682         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 683
 684         if(sv_foginterval && world.fog != "")
 685                 WriteString(MSG_ENTITY, world.fog);
 686         else
 687                 WriteString(MSG_ENTITY, "");
 688         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 689         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 690         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 691         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 692         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 693         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 694         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 695         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 696         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 697         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 698         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 699         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 700         return true;
 701 }
 702
 703 void ClientInit_CheckUpdate()
 704 {SELFPARAM();
 705         self.nextthink = time;
 706         if(self.count != autocvar_g_balance_armor_blockpercent)
 707         {
 708                 self.count = autocvar_g_balance_armor_blockpercent;
 709                 self.SendFlags |= 1;
 710         }
 711         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 712         {
 713                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 714                 self.SendFlags |= 1;
 715         }
 716         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 717         {
 718                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 719                 self.SendFlags |= 1;
 720         }
 721         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 722         {
 723                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 724                 self.SendFlags |= 1;
 725         }
 726         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 727         {
 728                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 729                 self.SendFlags |= 1;
 730         }
 731 }
 732
 733 void ClientInit_Spawn()
 734 {SELFPARAM();
 735         entity e = spawn();
 736         e.classname = "clientinit";
 737         e.think = ClientInit_CheckUpdate;
 738         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 739
 740         WITH(entity, self, e, ClientInit_CheckUpdate());
 741 }
 742
 743 /*
 744 =============
 745 SetNewParms
 746 =============
 747 */
 748 void SetNewParms (void)
 749 {
 750         // initialize parms for a new player
 751         parm1 = -(86400 * 366);
 752
 753         MUTATOR_CALLHOOK(SetNewParms);
 754 }
 755
 756 /*
 757 =============
 758 SetChangeParms
 759 =============
 760 */
 761 void SetChangeParms (void)
 762 {SELFPARAM();
 763         // save parms for level change
 764         parm1 = self.parm_idlesince - time;
 765
 766         MUTATOR_CALLHOOK(SetChangeParms);
 767 }
 768
 769 /*
 770 =============
 771 DecodeLevelParms
 772 =============
 773 */
 774 void DecodeLevelParms (void)
 775 {SELFPARAM();
 776         // load parms
 777         self.parm_idlesince = parm1;
 778         if(self.parm_idlesince == -(86400 * 366))
 779                 self.parm_idlesince = time;
 780
 781         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 782         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 783
 784         MUTATOR_CALLHOOK(DecodeLevelParms);
 785 }
 786
 787 /*
 788 =============
 789 ClientKill
 790
 791 Called when a client types 'kill' in the console
 792 =============
 793 */
 794
 795 .float clientkill_nexttime;
 796 void ClientKill_Now_TeamChange()
 797 {SELFPARAM();
 798         if(self.killindicator_teamchange == -1)
 799         {
 800                 JoinBestTeam( self, false, true );
 801         }
 802         else if(self.killindicator_teamchange == -2)
 803         {
 804                 if(blockSpectators)
 805                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 806                 PutObserverInServer();
 807         }
 808         else
 809                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 810         self.killindicator_teamchange = 0;
 811 }
 812
 813 void ClientKill_Now()
 814 {SELFPARAM();
 815         if(self.vehicle)
 816         {
 817             vehicles_exit(VHEF_RELEASE);
 818             if(!self.killindicator_teamchange)
 819             {
 820             self.vehicle_health = -1;
 821             Damage(self, self, self, 1 , DEATH_KILL.m_id, self.origin, '0 0 0');
 822             }
 823         }
 824
 825         if(self.killindicator && !wasfreed(self.killindicator))
 826                 remove(self.killindicator);
 827
 828         self.killindicator = world;
 829
 830         if(self.killindicator_teamchange)
 831                 ClientKill_Now_TeamChange();
 832
 833         if(IS_PLAYER(self))
 834                 Damage(self, self, self, 100000, DEATH_KILL.m_id, self.origin, '0 0 0');
 835
 836         // now I am sure the player IS dead
 837 }
 838 void KillIndicator_Think()
 839 {SELFPARAM();
 840         if (gameover)
 841         {
 842                 self.owner.killindicator = world;
 843                 remove(self);
 844                 return;
 845         }
 846
 847         if (self.owner.alpha < 0 && !self.owner.vehicle)
 848         {
 849                 self.owner.killindicator = world;
 850                 remove(self);
 851                 return;
 852         }
 853
 854         if(self.cnt <= 0)
 855         {
 856                 WITH(entity, self, self.owner, ClientKill_Now());
 857                 return;
 858         }
 859     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 860     {
 861         self.nextthink = time + 1;
 862         self.cnt -= 1;
 863     }
 864         else
 865         {
 866                 if(self.cnt <= 10)
 867                         setmodel(self, MDL_NUM(self.cnt));
 868                 if(IS_REAL_CLIENT(self.owner))
 869                 {
 870                         if(self.cnt <= 10)
 871                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 872                 }
 873                 self.nextthink = time + 1;
 874                 self.cnt -= 1;
 875         }
 876 }
 877
 878 float clientkilltime;
 879 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 880 {SELFPARAM();
 881         float killtime;
 882         float starttime;
 883         entity e;
 884
 885         if (gameover)
 886                 return;
 887
 888         killtime = autocvar_g_balance_kill_delay;
 889
 890         if(g_race_qualifying || g_cts)
 891                 killtime = 0;
 892
 893     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 894     {
 895                 remove(self.killindicator);
 896                 self.killindicator = world;
 897
 898         ClientKill_Now(); // allow instant kill in this case
 899         return;
 900     }
 901
 902         self.killindicator_teamchange = targetteam;
 903
 904     if(!self.killindicator)
 905         {
 906                 if(self.deadflag == DEAD_NO)
 907                 {
 908                         killtime = max(killtime, self.clientkill_nexttime - time);
 909                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 910                 }
 911
 912                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 913                 {
 914                         ClientKill_Now();
 915                 }
 916                 else
 917                 {
 918                         starttime = max(time, clientkilltime);
 919
 920                         self.killindicator = spawn();
 921                         self.killindicator.owner = self;
 922                         self.killindicator.scale = 0.5;
 923                         setattachment(self.killindicator, self, "");
 924                         setorigin(self.killindicator, '0 0 52');
 925                         self.killindicator.think = KillIndicator_Think;
 926                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 927                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 928                         self.killindicator.cnt = ceil(killtime);
 929                         self.killindicator.count = bound(0, ceil(killtime), 10);
 930                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 931
 932                         for(e = world; (e = find(e, classname, "body")) != world; )
 933                         {
 934                                 if(e.enemy != self)
 935                                         continue;
 936                                 e.killindicator = spawn();
 937                                 e.killindicator.owner = e;
 938                                 e.killindicator.scale = 0.5;
 939                                 setattachment(e.killindicator, e, "");
 940                                 setorigin(e.killindicator, '0 0 52');
 941                                 e.killindicator.think = KillIndicator_Think;
 942                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 943                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 944                                 e.killindicator.cnt = ceil(killtime);
 945                         }
 946                         self.lip = 0;
 947                 }
 948         }
 949         if(self.killindicator)
 950         {
 951                 if(targetteam == 0) // just die
 952                 {
 953                         self.killindicator.colormod = '0 0 0';
 954                         if(IS_REAL_CLIENT(self))
 955                         if(self.killindicator.cnt > 0)
 956                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 957                 }
 958                 else if(targetteam == -1) // auto
 959                 {
 960                         self.killindicator.colormod = '0 1 0';
 961                         if(IS_REAL_CLIENT(self))
 962                         if(self.killindicator.cnt > 0)
 963                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 964                 }
 965                 else if(targetteam == -2) // spectate
 966                 {
 967                         self.killindicator.colormod = '0.5 0.5 0.5';
 968                         if(IS_REAL_CLIENT(self))
 969                         if(self.killindicator.cnt > 0)
 970                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 971                 }
 972                 else
 973                 {
 974                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 975                         if(IS_REAL_CLIENT(self))
 976                         if(self.killindicator.cnt > 0)
 977                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 978                 }
 979         }
 980
 981 }
 982
 983 void ClientKill (void)
 984 {SELFPARAM();
 985         if(gameover) return;
 986         if(self.player_blocked) return;
 987         if(self.frozen) return;
 988
 989         ClientKill_TeamChange(0);
 990 }
 991
 992 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 993 {
 994     e.killindicator = spawn();
 995     e.killindicator.owner = e;
 996     e.killindicator.think = KillIndicator_Think;
 997     e.killindicator.nextthink = time + (e.lip) * 0.05;
 998     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 999     e.killindicator.health = 1; // this is used to indicate that it should be silent
1000     e.lip = 0;
1001 }
1002
1003 void FixClientCvars(entity e)
1004 {
1005         // send prediction settings to the client
1006         stuffcmd(e, "\nin_bindmap 0 0\n");
1007         if(g_race || g_cts)
1008                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1009         if(autocvar_g_antilag == 3) // client side hitscan
1010                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1011         if(autocvar_sv_gentle)
1012                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1013 }
1014
1015 float PlayerInIDList(entity p, string idlist)
1016 {
1017         float n, i;
1018         string s;
1019
1020         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1021         if (!p.crypto_idfp)
1022                 return 0;
1023
1024         // this function allows abbreviated player IDs too!
1025         n = tokenize_console(idlist);
1026         for(i = 0; i < n; ++i)
1027         {
1028                 s = argv(i);
1029                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1030                         return 1;
1031         }
1032
1033         return 0;
1034 }
1035
1036 #ifdef DP_EXT_PRECONNECT
1037 /*
1038 =============
1039 ClientPreConnect
1040
1041 Called once (not at each match start) when a client begins a connection to the server
1042 =============
1043 */
1044 void ClientPreConnect (void)
1045 {SELFPARAM();
1046         if(autocvar_sv_eventlog)
1047         {
1048                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1049                         self.playerid,
1050                         num_for_edict(self),
1051                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1052                 ));
1053         }
1054 }
1055 #endif
1056
1057 /*
1058 =============
1059 ClientConnect
1060
1061 Called when a client connects to the server
1062 =============
1063 */
1064 void DecodeLevelParms (void);
1065 void ClientConnect (void)
1066 {SELFPARAM();
1067         float t;
1068
1069         if(IS_CLIENT(self))
1070         {
1071                 LOG_INFO("Warning: ClientConnect, but already connected!\n");
1072                 return;
1073         }
1074
1075         if(Ban_MaybeEnforceBanOnce(self))
1076                 return;
1077
1078         DecodeLevelParms();
1079
1080 #ifdef WATERMARK
1081         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1082 #endif
1083
1084         self.classname = "player_joining";
1085
1086         self.flags = FL_CLIENT;
1087         self.version_nagtime = time + 10 + random() * 10;
1088
1089         if(player_count<0)
1090         {
1091                 LOG_TRACE("BUG player count is lower than zero, this cannot happen!\n");
1092                 player_count = 0;
1093         }
1094
1095         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1096
1097         PlayerScore_Attach(self);
1098         ClientData_Attach();
1099         accuracy_init(self);
1100         Inventory_new(self);
1101
1102         bot_clientconnect();
1103
1104         playerdemo_init();
1105
1106         anticheat_init();
1107
1108         // identify the right forced team
1109         if(autocvar_g_campaign)
1110         {
1111                 if(IS_REAL_CLIENT(self)) // only players, not bots
1112                 {
1113                         switch(autocvar_g_campaign_forceteam)
1114                         {
1115                                 case 1: self.team_forced = NUM_TEAM_1; break;
1116                                 case 2: self.team_forced = NUM_TEAM_2; break;
1117                                 case 3: self.team_forced = NUM_TEAM_3; break;
1118                                 case 4: self.team_forced = NUM_TEAM_4; break;
1119                                 default: self.team_forced = 0;
1120                         }
1121                 }
1122         }
1123         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1124                 self.team_forced = NUM_TEAM_1;
1125         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1126                 self.team_forced = NUM_TEAM_2;
1127         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1128                 self.team_forced = NUM_TEAM_3;
1129         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1130                 self.team_forced = NUM_TEAM_4;
1131         else if(autocvar_g_forced_team_otherwise == "red")
1132                 self.team_forced = NUM_TEAM_1;
1133         else if(autocvar_g_forced_team_otherwise == "blue")
1134                 self.team_forced = NUM_TEAM_2;
1135         else if(autocvar_g_forced_team_otherwise == "yellow")
1136                 self.team_forced = NUM_TEAM_3;
1137         else if(autocvar_g_forced_team_otherwise == "pink")
1138                 self.team_forced = NUM_TEAM_4;
1139         else if(autocvar_g_forced_team_otherwise == "spectate")
1140                 self.team_forced = -1;
1141         else if(autocvar_g_forced_team_otherwise == "spectator")
1142                 self.team_forced = -1;
1143         else
1144                 self.team_forced = 0;
1145
1146         if(!teamplay)
1147                 if(self.team_forced > 0)
1148                         self.team_forced = 0;
1149
1150         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1151
1152         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1153                 self.classname = "observer";
1154         } else {
1155                 if(teamplay)
1156                 {
1157                         if(autocvar_g_balance_teams)
1158                         {
1159                                 self.classname = "player";
1160                                 campaign_bots_may_start = 1;
1161                         }
1162                         else
1163                         {
1164                                 self.classname = "observer"; // do it anyway
1165                         }
1166                 }
1167                 else
1168                 {
1169                         self.classname = "player";
1170                         campaign_bots_may_start = 1;
1171                 }
1172         }
1173
1174         self.playerid = (playerid_last = playerid_last + 1);
1175
1176         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1177
1178     if(IS_BOT_CLIENT(self))
1179         PlayerStats_GameReport_AddPlayer(self);
1180
1181         if(autocvar_sv_eventlog)
1182                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1183
1184         LogTeamchange(self.playerid, self.team, 1);
1185
1186         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1187
1188         self.netname_previous = strzone(self.netname);
1189
1190         if(IS_PLAYER(self) && teamplay)
1191                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1192         else
1193                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1194
1195         stuffcmd(self, strcat(clientstuff, "\n"));
1196         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1197
1198         FixClientCvars(self);
1199
1200         // spawnfunc_waypoint sprites
1201         WaypointSprite_InitClient(self);
1202
1203         // Wazat's grappling hook
1204         SetGrappleHookBindings();
1205
1206         // Jetpack binds
1207         stuffcmd(self, "alias +jetpack +button10\n");
1208         stuffcmd(self, "alias -jetpack -button10\n");
1209
1210         // get version info from player
1211         stuffcmd(self, "cmd clientversion $gameversion\n");
1212
1213         // get other cvars from player
1214         GetCvars(0);
1215
1216         // notify about available teams
1217         if(teamplay)
1218         {
1219                 CheckAllowedTeams(self);
1220                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1221                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1222         }
1223         else
1224                 stuffcmd(self, "set _teams_available 0\n");
1225
1226         attach_entcs(self);
1227
1228         bot_relinkplayerlist();
1229
1230         self.spectatortime = time;
1231         if(blockSpectators)
1232         {
1233                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1234         }
1235
1236         self.jointime = time;
1237         self.allowed_timeouts = autocvar_sv_timeout_number;
1238
1239         if(IS_REAL_CLIENT(self))
1240         {
1241                 if(!autocvar_g_campaign)
1242                 {
1243                         self.motd_actived_time = -1;
1244                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1245                 }
1246
1247                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET(TUBA)))
1248                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1249         }
1250
1251         if(!sv_foginterval && world.fog != "")
1252                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1253
1254         W_HitPlotOpen(self);
1255
1256         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1257                 send_CSQC_teamnagger();
1258
1259         CheatInitClient();
1260
1261         CSQCMODEL_AUTOINIT(self);
1262
1263         self.model_randomizer = random();
1264
1265         if(IS_REAL_CLIENT(self))
1266                 sv_notice_join();
1267
1268         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1269                 WITH(entity, self, e, e.init_for_player(this));
1270         }
1271
1272         MUTATOR_CALLHOOK(ClientConnect, self);
1273 }
1274 /*
1275 =============
1276 ClientDisconnect
1277
1278 Called when a client disconnects from the server
1279 =============
1280 */
1281 .entity chatbubbleentity;
1282 void ReadyCount();
1283 void ClientDisconnect (void)
1284 {SELFPARAM();
1285         if(self.vehicle)
1286             vehicles_exit(VHEF_RELEASE);
1287
1288         if (!IS_CLIENT(self))
1289         {
1290                 LOG_INFO("Warning: ClientDisconnect without ClientConnect\n");
1291                 return;
1292         }
1293
1294         PlayerStats_GameReport_FinalizePlayer(self);
1295
1296         if ( self.active_minigame )
1297                 part_minigame(self);
1298
1299         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
1300
1301         CheatShutdownClient();
1302
1303         W_HitPlotClose(self);
1304
1305         anticheat_report();
1306         anticheat_shutdown();
1307
1308         playerdemo_shutdown();
1309
1310         bot_clientdisconnect();
1311
1312         detach_entcs(self);
1313
1314         if(autocvar_sv_eventlog)
1315                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1316
1317         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1318
1319         MUTATOR_CALLHOOK(ClientDisconnect);
1320
1321         Portal_ClearAll(self);
1322
1323         Unfreeze(self);
1324
1325         RemoveGrapplingHook(self);
1326
1327         // Here, everything has been done that requires this player to be a client.
1328
1329         self.flags &= ~FL_CLIENT;
1330
1331         if (self.chatbubbleentity)
1332                 remove (self.chatbubbleentity);
1333
1334         if (self.killindicator)
1335                 remove (self.killindicator);
1336
1337         WaypointSprite_PlayerGone();
1338
1339         bot_relinkplayerlist();
1340
1341         accuracy_free(self);
1342         Inventory_delete(self);
1343         ClientData_Detach();
1344         PlayerScore_Detach(self);
1345
1346         if(self.netname_previous)
1347                 strunzone(self.netname_previous);
1348         if(self.clientstatus)
1349                 strunzone(self.clientstatus);
1350         if(self.weaponorder_byimpulse)
1351                 strunzone(self.weaponorder_byimpulse);
1352
1353         ClearPlayerSounds();
1354
1355         if(self.personal)
1356                 remove(self.personal);
1357
1358         self.playerid = 0;
1359         ReadyCount();
1360
1361         // free cvars
1362         GetCvars(-1);
1363 }
1364
1365 .float BUTTON_CHAT;
1366 void ChatBubbleThink()
1367 {SELFPARAM();
1368         self.nextthink = time;
1369         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1370         {
1371                 if(self.owner) // but why can that ever be world?
1372                         self.owner.chatbubbleentity = world;
1373                 remove(self);
1374                 return;
1375         }
1376
1377         self.mdl = "";
1378
1379         if ( !self.owner.deadflag && IS_PLAYER(self.owner) )
1380         {
1381                 if ( self.owner.active_minigame )
1382                         self.mdl = "models/sprites/minigame_busy.iqm";
1383                 else if ( self.owner.BUTTON_CHAT )
1384                         self.mdl = "models/misc/chatbubble.spr";
1385         }
1386
1387         if ( self.model != self.mdl )
1388                 _setmodel(self, self.mdl);
1389
1390 }
1391
1392 void UpdateChatBubble()
1393 {SELFPARAM();
1394         if (self.alpha < 0)
1395                 return;
1396         // spawn a chatbubble entity if needed
1397         if (!self.chatbubbleentity)
1398         {
1399                 self.chatbubbleentity = spawn();
1400                 self.chatbubbleentity.owner = self;
1401                 self.chatbubbleentity.exteriormodeltoclient = self;
1402                 self.chatbubbleentity.think = ChatBubbleThink;
1403                 self.chatbubbleentity.nextthink = time;
1404                 setmodel(self.chatbubbleentity, MDL_CHAT); // precision set below
1405                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1406                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1407                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1408                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1409                 //self.chatbubbleentity.model = "";
1410                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1411         }
1412 }
1413
1414
1415 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1416 // added to the model skins
1417 /*void UpdateColorModHack()
1418 {
1419         float c;
1420         c = self.clientcolors & 15;
1421         // LordHavoc: only bothering to support white, green, red, yellow, blue
1422              if (!teamplay) self.colormod = '0 0 0';
1423         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1424         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1425         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1426         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1427         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1428         else self.colormod = '1 1 1';
1429 }*/
1430
1431 void respawn(void)
1432 {SELFPARAM();
1433         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1434         {
1435                 self.solid = SOLID_NOT;
1436                 self.takedamage = DAMAGE_NO;
1437                 self.movetype = MOVETYPE_FLY;
1438                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1439                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1440                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1441                 Send_Effect(EFFECT_RESPAWN_GHOST, self.origin, '0 0 0', 1);
1442                 if(autocvar_g_respawn_ghosts_maxtime)
1443                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1444         }
1445
1446         CopyBody(1);
1447
1448         self.effects |= EF_NODRAW; // prevent another CopyBody
1449         PutClientInServer();
1450 }
1451
1452 void play_countdown(float finished, string samp)
1453 {SELFPARAM();
1454         if(IS_REAL_CLIENT(self))
1455                 if(floor(finished - time - frametime) != floor(finished - time))
1456                         if(finished - time < 6)
1457                                 _sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1458 }
1459
1460 void player_powerups (void)
1461 {SELFPARAM();
1462         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1463         int items_prev = self.items;
1464
1465         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1466                 self.modelflags |= MF_ROCKET;
1467         else
1468                 self.modelflags &= ~MF_ROCKET;
1469
1470         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1471
1472         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1473                 return;
1474
1475         Fire_ApplyDamage(self);
1476         Fire_ApplyEffect(self);
1477
1478         if (!g_instagib)
1479         {
1480                 if (self.items & ITEM_Strength.m_itemid)
1481                 {
1482                         play_countdown(self.strength_finished, SND(POWEROFF));
1483                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1484                         if (time > self.strength_finished)
1485                         {
1486                                 self.items = self.items - (self.items & ITEM_Strength.m_itemid);
1487                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1488                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1489                         }
1490                 }
1491                 else
1492                 {
1493                         if (time < self.strength_finished)
1494                         {
1495                                 self.items = self.items | ITEM_Strength.m_itemid;
1496                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1497                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1498                         }
1499                 }
1500                 if (self.items & ITEM_Shield.m_itemid)
1501                 {
1502                         play_countdown(self.invincible_finished, SND(POWEROFF));
1503                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1504                         if (time > self.invincible_finished)
1505                         {
1506                                 self.items = self.items - (self.items & ITEM_Shield.m_itemid);
1507                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1508                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1509                         }
1510                 }
1511                 else
1512                 {
1513                         if (time < self.invincible_finished)
1514                         {
1515                                 self.items = self.items | ITEM_Shield.m_itemid;
1516                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1517                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1518                         }
1519                 }
1520                 if (self.items & IT_SUPERWEAPON)
1521                 {
1522                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1523                         {
1524                                 self.superweapons_finished = 0;
1525                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1526                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1527                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1528                         }
1529                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1530                         {
1531                                 // don't let them run out
1532                         }
1533                         else
1534                         {
1535                                 play_countdown(self.superweapons_finished, SND(POWEROFF));
1536                                 if (time > self.superweapons_finished)
1537                                 {
1538                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1539                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1540                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1541                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1542                                 }
1543                         }
1544                 }
1545                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1546                 {
1547                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1548                         {
1549                                 self.items = self.items | IT_SUPERWEAPON;
1550                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1551                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1552                         }
1553                         else
1554                         {
1555                                 self.superweapons_finished = 0;
1556                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1557                         }
1558                 }
1559                 else
1560                 {
1561                         self.superweapons_finished = 0;
1562                 }
1563         }
1564
1565         if(autocvar_g_nodepthtestplayers)
1566                 self.effects = self.effects | EF_NODEPTHTEST;
1567
1568         if(autocvar_g_fullbrightplayers)
1569                 self.effects = self.effects | EF_FULLBRIGHT;
1570
1571         if (time >= game_starttime)
1572         if (time < self.spawnshieldtime)
1573                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1574
1575         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1576 }
1577
1578 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1579 {
1580         if(current > stable)
1581                 return current;
1582         else if(current > stable - 0.25) // when close enough, "snap"
1583                 return stable;
1584         else
1585                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1586 }
1587
1588 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1589 {
1590         if(current < stable)
1591                 return current;
1592         else if(current < stable + 0.25) // when close enough, "snap"
1593                 return stable;
1594         else
1595                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1596 }
1597
1598 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1599 {
1600         if(current > rotstable)
1601         {
1602                 if(rotframetime > 0)
1603                 {
1604                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1605                         current = max(rotstable, current - rotlinear * rotframetime);
1606                 }
1607         }
1608         else if(current < regenstable)
1609         {
1610                 if(regenframetime > 0)
1611                 {
1612                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1613                         current = min(regenstable, current + regenlinear * regenframetime);
1614                 }
1615         }
1616
1617         if(current > limit)
1618                 current = limit;
1619
1620         return current;
1621 }
1622
1623 void player_regen (void)
1624 {SELFPARAM();
1625         float max_mod, regen_mod, rot_mod, limit_mod;
1626         max_mod = regen_mod = rot_mod = limit_mod = 1;
1627         regen_mod_max = max_mod;
1628         regen_mod_regen = regen_mod;
1629         regen_mod_rot = rot_mod;
1630         regen_mod_limit = limit_mod;
1631
1632         regen_health = autocvar_g_balance_health_regen;
1633         regen_health_linear = autocvar_g_balance_health_regenlinear;
1634         regen_health_rot = autocvar_g_balance_health_rot;
1635         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1636         regen_health_stable = autocvar_g_balance_health_regenstable;
1637         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1638         if(!MUTATOR_CALLHOOK(PlayerRegen))
1639         if(!self.frozen)
1640         {
1641                 float mina, maxa, limith, limita;
1642                 maxa = autocvar_g_balance_armor_rotstable;
1643                 mina = autocvar_g_balance_armor_regenstable;
1644                 limith = autocvar_g_balance_health_limit;
1645                 limita = autocvar_g_balance_armor_limit;
1646
1647                 max_mod = regen_mod_max;
1648                 regen_mod = regen_mod_regen;
1649                 rot_mod = regen_mod_rot;
1650                 limit_mod = regen_mod_limit;
1651
1652                 regen_health_rotstable = regen_health_rotstable * max_mod;
1653                 regen_health_stable = regen_health_stable * max_mod;
1654                 limith = limith * limit_mod;
1655                 limita = limita * limit_mod;
1656
1657                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1658                 self.health = CalcRotRegen(self.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > self.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1659         }
1660
1661         // if player rotted to death...  die!
1662         // check this outside above checks, as player may still be able to rot to death
1663         if(self.health < 1)
1664         {
1665                 if(self.vehicle)
1666                         vehicles_exit(VHEF_RELEASE);
1667                 self.event_damage(self, self, 1, DEATH_ROT.m_id, self.origin, '0 0 0');
1668         }
1669
1670         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1671         {
1672                 float minf, maxf, limitf;
1673
1674                 maxf = autocvar_g_balance_fuel_rotstable;
1675                 minf = autocvar_g_balance_fuel_regenstable;
1676                 limitf = autocvar_g_balance_fuel_limit;
1677
1678                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1679         }
1680 }
1681
1682 float zoomstate_set;
1683 void SetZoomState(float z)
1684 {SELFPARAM();
1685         if(z != self.zoomstate)
1686         {
1687                 self.zoomstate = z;
1688                 ClientData_Touch(self);
1689         }
1690         zoomstate_set = 1;
1691 }
1692
1693 void GetPressedKeys()
1694 {SELFPARAM();
1695         MUTATOR_CALLHOOK(GetPressedKeys);
1696         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1697         X(self.pressedkeys, KEY_FORWARD,        self.movement_x > 0);
1698         X(self.pressedkeys, KEY_BACKWARD,       self.movement_x < 0);
1699         X(self.pressedkeys, KEY_RIGHT,          self.movement_y > 0);
1700         X(self.pressedkeys, KEY_LEFT,           self.movement_y < 0);
1701
1702         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1703         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1704         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1705         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1706         #undef X
1707 }
1708
1709 /*
1710 ======================
1711 spectate mode routines
1712 ======================
1713 */
1714
1715 void SpectateCopy(entity spectatee)
1716 {SELFPARAM();
1717         MUTATOR_CALLHOOK(SpectateCopy, spectatee, self);
1718         self.armortype = spectatee.armortype;
1719         self.armorvalue = spectatee.armorvalue;
1720         self.ammo_cells = spectatee.ammo_cells;
1721         self.ammo_plasma = spectatee.ammo_plasma;
1722         self.ammo_shells = spectatee.ammo_shells;
1723         self.ammo_nails = spectatee.ammo_nails;
1724         self.ammo_rockets = spectatee.ammo_rockets;
1725         self.ammo_fuel = spectatee.ammo_fuel;
1726         self.clip_load = spectatee.clip_load;
1727         self.clip_size = spectatee.clip_size;
1728         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1729         self.health = spectatee.health;
1730         self.impulse = 0;
1731         self.items = spectatee.items;
1732         self.last_pickup = spectatee.last_pickup;
1733         self.hit_time = spectatee.hit_time;
1734         self.metertime = spectatee.metertime;
1735         self.strength_finished = spectatee.strength_finished;
1736         self.invincible_finished = spectatee.invincible_finished;
1737         self.pressedkeys = spectatee.pressedkeys;
1738         self.weapons = spectatee.weapons;
1739         self.switchweapon = spectatee.switchweapon;
1740         self.switchingweapon = spectatee.switchingweapon;
1741         self.weapon = spectatee.weapon;
1742         self.vortex_charge = spectatee.vortex_charge;
1743         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1744         self.hagar_load = spectatee.hagar_load;
1745         self.arc_heat_percent = spectatee.arc_heat_percent;
1746         self.minelayer_mines = spectatee.minelayer_mines;
1747         self.punchangle = spectatee.punchangle;
1748         self.view_ofs = spectatee.view_ofs;
1749         self.velocity = spectatee.velocity;
1750         self.dmg_take = spectatee.dmg_take;
1751         self.dmg_save = spectatee.dmg_save;
1752         self.dmg_inflictor = spectatee.dmg_inflictor;
1753         self.v_angle = spectatee.v_angle;
1754         self.angles = spectatee.v_angle;
1755         self.frozen = spectatee.frozen;
1756         self.revive_progress = spectatee.revive_progress;
1757         if(!self.BUTTON_USE)
1758                 self.fixangle = true;
1759         setorigin(self, spectatee.origin);
1760         setsize(self, spectatee.mins, spectatee.maxs);
1761         SetZoomState(spectatee.zoomstate);
1762
1763     anticheat_spectatecopy(spectatee);
1764         self.hud = spectatee.hud;
1765         if(spectatee.vehicle)
1766     {
1767         self.fixangle = false;
1768         //self.velocity = spectatee.vehicle.velocity;
1769         self.vehicle_health = spectatee.vehicle_health;
1770         self.vehicle_shield = spectatee.vehicle_shield;
1771         self.vehicle_energy = spectatee.vehicle_energy;
1772         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1773         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1774         self.vehicle_reload1 = spectatee.vehicle_reload1;
1775         self.vehicle_reload2 = spectatee.vehicle_reload2;
1776
1777         msg_entity = self;
1778
1779         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1780             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1781             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1782             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1783
1784         //WriteByte (MSG_ONE, SVC_SETVIEW);
1785         //    WriteEntity(MSG_ONE, self);
1786         //makevectors(spectatee.v_angle);
1787         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1788     }
1789 }
1790
1791 bool SpectateUpdate()
1792 {SELFPARAM();
1793         if(!self.enemy)
1794             return false;
1795
1796         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1797         {
1798                 SetSpectator(self, world);
1799                 return false;
1800         }
1801
1802         SpectateCopy(self.enemy);
1803
1804         return true;
1805 }
1806
1807 bool SpectateSet()
1808 {SELFPARAM();
1809         if(!IS_PLAYER(self.enemy))
1810                 return false;
1811
1812         msg_entity = self;
1813         WriteByte(MSG_ONE, SVC_SETVIEW);
1814         WriteEntity(MSG_ONE, self.enemy);
1815         self.movetype = MOVETYPE_NONE;
1816         accuracy_resend(self);
1817
1818         if(!SpectateUpdate())
1819                 PutObserverInServer();
1820
1821         return true;
1822 }
1823
1824 void SetSpectator(entity player, entity spectatee)
1825 {
1826         entity old_spectatee = player.enemy;
1827
1828         player.enemy = spectatee;
1829
1830         // WEAPONTODO
1831         // these are required to fix the spectator bug with arc
1832         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1833         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1834 }
1835
1836 bool Spectate(entity pl)
1837 {SELFPARAM();
1838         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1839         if(DIFF_TEAM(pl, self))
1840                 return false;
1841
1842         SetSpectator(self, pl);
1843         return SpectateSet();
1844 }
1845
1846 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1847 entity CA_SpectateNext(entity start)
1848 {SELFPARAM();
1849         if(SAME_TEAM(start, self))
1850                 return start;
1851
1852         other = start;
1853         // continue from current player
1854         while(other && DIFF_TEAM(other, self))
1855                 other = find(other, classname, "player");
1856
1857         if (!other)
1858         {
1859                 // restart from begining
1860                 other = find(other, classname, "player");
1861                 while(other && DIFF_TEAM(other, self))
1862                         other = find(other, classname, "player");
1863         }
1864
1865         return other;
1866 }
1867
1868 bool SpectateNext()
1869 {SELFPARAM();
1870         other = find(self.enemy, classname, "player");
1871
1872         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1873                 // CA and ca players when spectating enemies is forbidden
1874                 other = CA_SpectateNext(other);
1875         else
1876         {
1877                 // other modes and ca spectators or spectating enemies is allowed
1878                 if (!other)
1879                         other = find(other, classname, "player");
1880         }
1881
1882         if(other) { SetSpectator(self, other); }
1883
1884         return SpectateSet();
1885 }
1886
1887 bool SpectatePrev()
1888 {SELFPARAM();
1889         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1890         other = findchain(classname, "player");
1891         if (!other) // no player
1892                 return false;
1893
1894         entity first = other;
1895         // skip players until current spectated player
1896         if(self.enemy)
1897         while(other && other != self.enemy)
1898                 other = other.chain;
1899
1900         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1901         {
1902                 do { other = other.chain; }
1903                 while(other && DIFF_TEAM(other, self));
1904
1905                 if (!other)
1906                 {
1907                         other = first;
1908                         while(other && DIFF_TEAM(other, self))
1909                                 other = other.chain;
1910                         if(other == self.enemy)
1911                                 return true;
1912                 }
1913         }
1914         else
1915         {
1916                 if(other.chain)
1917                         other = other.chain;
1918                 else
1919                         other = first;
1920         }
1921         SetSpectator(self, other);
1922         return SpectateSet();
1923 }
1924
1925 /*
1926 =============
1927 ShowRespawnCountdown()
1928
1929 Update a respawn countdown display.
1930 =============
1931 */
1932 void ShowRespawnCountdown()
1933 {SELFPARAM();
1934         float number;
1935         if(self.deadflag == DEAD_NO) // just respawned?
1936                 return;
1937         else
1938         {
1939                 number = ceil(self.respawn_time - time);
1940                 if(number <= 0)
1941                         return;
1942                 if(number <= self.respawn_countdown)
1943                 {
1944                         self.respawn_countdown = number - 1;
1945                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1946                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1947                 }
1948         }
1949 }
1950
1951 void LeaveSpectatorMode()
1952 {SELFPARAM();
1953         if(self.caplayer)
1954                 return;
1955         if(nJoinAllowed(self))
1956         {
1957                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1958                 {
1959                         self.classname = "player";
1960                         nades_RemoveBonus(self);
1961
1962                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1963                                 { JoinBestTeam(self, false, true); }
1964
1965                         if(autocvar_g_campaign)
1966                                 { campaign_bots_may_start = 1; }
1967
1968                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1969
1970                         PutClientInServer();
1971
1972                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1973                 }
1974                 else
1975                         stuffcmd(self, "menu_showteamselect\n");
1976         }
1977         else
1978         {
1979                 // Player may not join because g_maxplayers is set
1980                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1981         }
1982 }
1983
1984 /**
1985  * Determines whether the player is allowed to join. This depends on cvar
1986  * g_maxplayers, if it isn't used this function always return true, otherwise
1987  * it checks whether the number of currently playing players exceeds g_maxplayers.
1988  * @return int number of free slots for players, 0 if none
1989  */
1990 float nJoinAllowed(entity ignore)
1991 {SELFPARAM();
1992         if(!ignore)
1993         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1994         // so report 0 free slots if restricted
1995         {
1996                 if(autocvar_g_forced_team_otherwise == "spectate")
1997                         return 0;
1998                 if(autocvar_g_forced_team_otherwise == "spectator")
1999                         return 0;
2000         }
2001
2002         if(self.team_forced < 0)
2003                 return 0; // forced spectators can never join
2004
2005         // TODO simplify this
2006         entity e;
2007         float totalClients = 0;
2008         FOR_EACH_CLIENT(e)
2009                 if(e != ignore)
2010                         totalClients += 1;
2011
2012         if (!autocvar_g_maxplayers)
2013                 return maxclients - totalClients;
2014
2015         float currentlyPlaying = 0;
2016         FOR_EACH_REALCLIENT(e)
2017                 if(IS_PLAYER(e) || e.caplayer)
2018                         currentlyPlaying += 1;
2019
2020         if(currentlyPlaying < autocvar_g_maxplayers)
2021                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2022
2023         return 0;
2024 }
2025
2026 /**
2027  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2028  * g_maxplayers_spectator_blocktime seconds
2029  */
2030 void checkSpectatorBlock()
2031 {SELFPARAM();
2032         if(IS_SPEC(self) || IS_OBSERVER(self))
2033         if(!self.caplayer)
2034         if(IS_REAL_CLIENT(self))
2035         {
2036                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2037                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2038                         dropclient(self);
2039                 }
2040         }
2041 }
2042
2043 void PrintWelcomeMessage()
2044 {SELFPARAM();
2045         if(self.motd_actived_time == 0)
2046         {
2047                 if (autocvar_g_campaign) {
2048                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2049                                 self.motd_actived_time = time;
2050                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2051                         }
2052                 } else {
2053                         if (self.BUTTON_INFO) {
2054                                 self.motd_actived_time = time;
2055                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2056                         }
2057                 }
2058         }
2059         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2060         {
2061                 if (autocvar_g_campaign) {
2062                         if (self.BUTTON_INFO)
2063                                 self.motd_actived_time = time;
2064                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2065                                 self.motd_actived_time = 0;
2066                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2067                         }
2068                 } else {
2069                         if (self.BUTTON_INFO)
2070                                 self.motd_actived_time = time;
2071                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2072                                 self.motd_actived_time = 0;
2073                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2074                         }
2075                 }
2076         }
2077         else //if(self.motd_actived_time < 0) // just connected, motd is active
2078         {
2079                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2080                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2081                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2082                 {
2083                         // instanctly hide MOTD
2084                         self.motd_actived_time = 0;
2085                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2086                 }
2087         }
2088 }
2089
2090 void ObserverThink()
2091 {SELFPARAM();
2092         if ( self.impulse )
2093         {
2094                 MinigameImpulse(self.impulse);
2095                 self.impulse = 0;
2096         }
2097         float prefered_movetype;
2098         if (self.flags & FL_JUMPRELEASED) {
2099                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2100                         self.flags &= ~FL_JUMPRELEASED;
2101                         self.flags |= FL_SPAWNING;
2102                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2103                         self.flags &= ~FL_JUMPRELEASED;
2104                         if(SpectateNext()) {
2105                                 self.classname = "spectator";
2106                         }
2107                 } else {
2108                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2109                         if (self.movetype != prefered_movetype)
2110                                 self.movetype = prefered_movetype;
2111                 }
2112         } else {
2113                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2114                         self.flags |= FL_JUMPRELEASED;
2115                         if(self.flags & FL_SPAWNING)
2116                         {
2117                                 self.flags &= ~FL_SPAWNING;
2118                                 LeaveSpectatorMode();
2119                                 return;
2120                         }
2121                 }
2122         }
2123 }
2124
2125 void SpectatorThink()
2126 {SELFPARAM();
2127         if ( self.impulse )
2128         {
2129                 if(MinigameImpulse(self.impulse))
2130                         self.impulse = 0;
2131         }
2132         if (self.flags & FL_JUMPRELEASED) {
2133                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2134                         self.flags &= ~FL_JUMPRELEASED;
2135                         self.flags |= FL_SPAWNING;
2136                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2137                         self.flags &= ~FL_JUMPRELEASED;
2138                         if(SpectateNext()) {
2139                                 self.classname = "spectator";
2140                         } else {
2141                                 self.classname = "observer";
2142                                 PutClientInServer();
2143                         }
2144                         self.impulse = 0;
2145                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2146                         self.flags &= ~FL_JUMPRELEASED;
2147                         if(SpectatePrev()) {
2148                                 self.classname = "spectator";
2149                         } else {
2150                                 self.classname = "observer";
2151                                 PutClientInServer();
2152                         }
2153                         self.impulse = 0;
2154                 } else if (self.BUTTON_ATCK2) {
2155                         self.flags &= ~FL_JUMPRELEASED;
2156                         self.classname = "observer";
2157                         PutClientInServer();
2158                 } else {
2159                         if(!SpectateUpdate())
2160                                 PutObserverInServer();
2161                 }
2162         } else {
2163                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2164                         self.flags |= FL_JUMPRELEASED;
2165                         if(self.flags & FL_SPAWNING)
2166                         {
2167                                 self.flags &= ~FL_SPAWNING;
2168                                 LeaveSpectatorMode();
2169                                 return;
2170                         }
2171                 }
2172                 if(!SpectateUpdate())
2173                         PutObserverInServer();
2174         }
2175
2176         self.flags |= FL_CLIENT | FL_NOTARGET;
2177 }
2178
2179 void vehicles_enter (entity pl, entity veh);
2180 void PlayerUseKey()
2181 {SELFPARAM();
2182         if (!IS_PLAYER(self))
2183                 return;
2184
2185         if(self.vehicle)
2186         {
2187                 if(!gameover)
2188                 {
2189                         vehicles_exit(VHEF_NORMAL);
2190                         return;
2191                 }
2192         }
2193         else if(autocvar_g_vehicles_enter)
2194         {
2195                 if(!self.frozen)
2196                 if(self.deadflag == DEAD_NO)
2197                 if(!gameover)
2198                 {
2199                         entity head, closest_target = world;
2200                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2201
2202                         while(head) // find the closest acceptable target to enter
2203                         {
2204                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2205                                 if(head.deadflag == DEAD_NO)
2206                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2207                                 if(head.takedamage != DAMAGE_NO)
2208                                 {
2209                                         if(closest_target)
2210                                         {
2211                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2212                                                 { closest_target = head; }
2213                                         }
2214                                         else { closest_target = head; }
2215                                 }
2216
2217                                 head = head.chain;
2218                         }
2219
2220                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2221                 }
2222         }
2223
2224         // a use key was pressed; call handlers
2225         MUTATOR_CALLHOOK(PlayerUseKey);
2226 }
2227
2228 float isInvisibleString(string s)
2229 {
2230         float i, n, c;
2231         s = strdecolorize(s);
2232         for((i = 0), (n = strlen(s)); i < n; ++i)
2233         {
2234                 c = str2chr(s, i);
2235                 switch(c)
2236                 {
2237                         case 0:
2238                         case 32: // space
2239                                 break;
2240                         case 192: // charmap space
2241                                 if (!autocvar_utf8_enable)
2242                                         break;
2243                                 return false;
2244                         case 160: // space in unicode fonts
2245                         case 0xE000 + 192: // utf8 charmap space
2246                                 if (autocvar_utf8_enable)
2247                                         break;
2248                         default:
2249                                 return false;
2250                 }
2251         }
2252         return true;
2253 }
2254
2255 /*
2256 =============
2257 PlayerPreThink
2258
2259 Called every frame for each client before the physics are run
2260 =============
2261 */
2262 .float usekeypressed;
2263 void() nexball_setstatus;
2264 .float last_vehiclecheck;
2265 .int items_added;
2266 void PlayerPreThink (void)
2267 {SELFPARAM();
2268         WarpZone_PlayerPhysics_FixVAngle();
2269
2270         self.stat_game_starttime = game_starttime;
2271         self.stat_round_starttime = round_starttime;
2272         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2273         self.stat_leadlimit = autocvar_leadlimit;
2274
2275         self.weaponsinmap = weaponsInMap;
2276
2277         if(frametime)
2278         {
2279                 // physics frames: update anticheat stuff
2280                 anticheat_prethink();
2281         }
2282
2283         if(blockSpectators && frametime)
2284                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2285                 checkSpectatorBlock();
2286
2287         zoomstate_set = 0;
2288
2289         // Savage: Check for nameless players
2290         if (isInvisibleString(self.netname)) {
2291                 string new_name = strzone(strcat("Player@", ftos(self.playerid)));
2292                 if(autocvar_sv_eventlog)
2293                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2294                 if(self.netname_previous)
2295                         strunzone(self.netname_previous);
2296                 self.netname_previous = strzone(new_name);
2297                 self.netname = self.netname_previous;
2298                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2299         } else if(self.netname_previous != self.netname) {
2300                 if(autocvar_sv_eventlog)
2301                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2302                 if(self.netname_previous)
2303                         strunzone(self.netname_previous);
2304                 self.netname_previous = strzone(self.netname);
2305         }
2306
2307         // version nagging
2308         if(self.version_nagtime)
2309                 if(self.cvar_g_xonoticversion)
2310                         if(time > self.version_nagtime)
2311                         {
2312                                 // don't notify git users
2313                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2314                                 {
2315                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2316                                         {
2317                                                 // notify release users if connecting to git
2318                                                 LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2319                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2320                                         }
2321                                         else
2322                                         {
2323                                                 float r;
2324                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2325                                                 if(r < 0)
2326                                                 {
2327                                                         // give users new version
2328                                                         LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2329                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2330                                                 }
2331                                                 else if(r > 0)
2332                                                 {
2333                                                         // notify users about old server version
2334                                                         LOG_INFO("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2335                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2336                                                 }
2337                                         }
2338                                 }
2339                                 self.version_nagtime = 0;
2340                         }
2341
2342         // GOD MODE info
2343         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2344         {
2345                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2346                 self.max_armorvalue = 0;
2347         }
2348
2349         if(self.frozen == 2)
2350         {
2351                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2352                 self.health = max(1, self.revive_progress * start_health);
2353                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2354
2355                 if(self.revive_progress >= 1)
2356                         Unfreeze(self);
2357         }
2358         else if(self.frozen == 3)
2359         {
2360                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2361                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2362
2363                 if(self.health < 1)
2364                 {
2365                         if(self.vehicle)
2366                                 vehicles_exit(VHEF_RELEASE);
2367                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, self.origin, '0 0 0');
2368                 }
2369                 else if ( self.revive_progress <= 0 )
2370                         Unfreeze(self);
2371         }
2372
2373         MUTATOR_CALLHOOK(PlayerPreThink);
2374
2375         if(autocvar_g_vehicles_enter)
2376         if(time > self.last_vehiclecheck)
2377         if(IS_PLAYER(self))
2378         if(!gameover)
2379         if(!self.frozen)
2380         if(!self.vehicle)
2381         if(self.deadflag == DEAD_NO)
2382         {
2383                 entity veh;
2384                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2385                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2386                 if(veh.deadflag == DEAD_NO)
2387                 if(veh.takedamage != DAMAGE_NO)
2388                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2389                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2390                 else if(!veh.owner)
2391                 if(!veh.team || SAME_TEAM(self, veh))
2392                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2393                 else if(autocvar_g_vehicles_steal)
2394                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2395
2396                 self.last_vehiclecheck = time + 1;
2397         }
2398
2399         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2400         {
2401                 if(self.BUTTON_USE && !self.usekeypressed)
2402                         PlayerUseKey();
2403                 self.usekeypressed = self.BUTTON_USE;
2404         }
2405
2406         if(IS_REAL_CLIENT(self))
2407                 PrintWelcomeMessage();
2408
2409         if(IS_PLAYER(self))
2410         {
2411
2412                 CheckRules_Player();
2413
2414                 if (intermission_running)
2415                 {
2416                         IntermissionThink ();   // otherwise a button could be missed between
2417                         return;                                 // the think tics
2418                 }
2419
2420                 //don't allow the player to turn around while game is paused!
2421                 if(timeout_status == TIMEOUT_ACTIVE) {
2422                         // FIXME turn this into CSQC stuff
2423                         self.v_angle = self.lastV_angle;
2424                         self.angles = self.lastV_angle;
2425                         self.fixangle = true;
2426                 }
2427
2428                 if(frametime)
2429                 {
2430                         if(self.weapon == WEP_VORTEX.m_id && WEP_CVAR(vortex, charge))
2431                         {
2432                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2433                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2434                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2435
2436                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2437                                 {
2438                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2439                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2440                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2441                                 }
2442                         }
2443                         else
2444                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2445
2446                         player_powerups();
2447                 }
2448
2449                 if (self.deadflag != DEAD_NO)
2450                 {
2451                         if(self.personal && g_race_qualifying)
2452                         {
2453                                 if(time > self.respawn_time)
2454                                 {
2455                                         self.respawn_time = time + 1; // only retry once a second
2456                                         self.stat_respawn_time = self.respawn_time;
2457                                         respawn();
2458                                         self.impulse = 141;
2459                                 }
2460                         }
2461                         else
2462                         {
2463                                 float button_pressed;
2464                                 if(frametime)
2465                                         player_anim();
2466                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2467
2468                                 if (self.deadflag == DEAD_DYING)
2469                                 {
2470                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2471                                                 self.deadflag = DEAD_RESPAWNING;
2472                                         else if(!button_pressed)
2473                                                 self.deadflag = DEAD_DEAD;
2474                                 }
2475                                 else if (self.deadflag == DEAD_DEAD)
2476                                 {
2477                                         if(button_pressed)
2478                                                 self.deadflag = DEAD_RESPAWNABLE;
2479                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2480                                                 self.deadflag = DEAD_RESPAWNING;
2481                                 }
2482                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2483                                 {
2484                                         if(!button_pressed)
2485                                                 self.deadflag = DEAD_RESPAWNING;
2486                                 }
2487                                 else if (self.deadflag == DEAD_RESPAWNING)
2488                                 {
2489                                         if(time > self.respawn_time)
2490                                         {
2491                                                 self.respawn_time = time + 1; // only retry once a second
2492                                                 self.respawn_time_max = self.respawn_time;
2493                                                 respawn();
2494                                         }
2495                                 }
2496
2497                                 ShowRespawnCountdown();
2498
2499                                 if(self.respawn_flags & RESPAWN_SILENT)
2500                                         self.stat_respawn_time = 0;
2501                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2502                                         self.stat_respawn_time = self.respawn_time_max;
2503                                 else
2504                                         self.stat_respawn_time = self.respawn_time;
2505                         }
2506
2507                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2508                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2509                                 self.stat_respawn_time *= -1;
2510
2511                         return;
2512                 }
2513
2514                 self.prevorigin = self.origin;
2515
2516                 float do_crouch = self.BUTTON_CROUCH;
2517                 if(self.hook.state)
2518                         do_crouch = 0;
2519                 if(self.vehicle)
2520                         do_crouch = 0;
2521                 if(self.frozen)
2522                         do_crouch = 0;
2523
2524                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2525                 // It cannot be predicted by the engine!
2526                 if((self.weapon == WEP_SHOCKWAVE.m_id || self.weapon == WEP_SHOTGUN.m_id) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2527                         do_crouch = 0;
2528
2529                 if (do_crouch)
2530                 {
2531                         if (!self.crouch)
2532                         {
2533                                 self.crouch = true;
2534                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2535                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2536                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2537                         }
2538                 }
2539                 else
2540                 {
2541                         if (self.crouch)
2542                         {
2543                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2544                                 if (!trace_startsolid)
2545                                 {
2546                                         self.crouch = false;
2547                                         self.view_ofs = self.stat_pl_view_ofs;
2548                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2549                                 }
2550                         }
2551                 }
2552
2553                 FixPlayermodel();
2554
2555                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2556                 //if(frametime)
2557                 {
2558                         self.items &= ~self.items_added;
2559
2560                         W_WeaponFrame(self);
2561
2562                         self.items_added = 0;
2563                         if(self.items & ITEM_Jetpack.m_itemid)
2564                                 if(self.items & ITEM_JetpackRegen.m_itemid || self.ammo_fuel >= 0.01)
2565                                         self.items_added |= IT_FUEL;
2566
2567                         self.items |= self.items_added;
2568                 }
2569
2570                 player_regen();
2571
2572                 // WEAPONTODO: Add a weapon request for this
2573                 // rot vortex charge to the charge limit
2574                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2575                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2576
2577                 if(frametime)
2578                         player_anim();
2579
2580                 // secret status
2581                 secrets_setstatus();
2582
2583                 // monsters status
2584                 monsters_setstatus();
2585
2586                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2587
2588                 //self.angles_y=self.v_angle_y + 90;   // temp
2589         } else if(gameover) {
2590                 if (intermission_running)
2591                         IntermissionThink ();   // otherwise a button could be missed between
2592                 return;
2593         } else if(IS_OBSERVER(self)) {
2594                 ObserverThink();
2595         } else if(IS_SPEC(self)) {
2596                 SpectatorThink();
2597         }
2598
2599         // WEAPONTODO: Add weapon request for this
2600         if(!zoomstate_set)
2601                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX.m_id) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE.m_id && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2602
2603         float oldspectatee_status;
2604         oldspectatee_status = self.spectatee_status;
2605         if(IS_SPEC(self))
2606                 self.spectatee_status = num_for_edict(self.enemy);
2607         else if(IS_OBSERVER(self))
2608                 self.spectatee_status = num_for_edict(self);
2609         else
2610                 self.spectatee_status = 0;
2611         if(self.spectatee_status != oldspectatee_status)
2612         {
2613                 ClientData_Touch(self);
2614         }
2615
2616         if(self.teamkill_soundtime)
2617         if(time > self.teamkill_soundtime)
2618         {
2619                 self.teamkill_soundtime = 0;
2620
2621                 setself(self.teamkill_soundsource);
2622                 entity oldpusher = self.pusher;
2623                 self.pusher = this;
2624
2625                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2626
2627                 self.pusher = oldpusher;
2628                 setself(this);
2629         }
2630
2631         if(self.taunt_soundtime)
2632         if(time > self.taunt_soundtime)
2633         {
2634                 self.taunt_soundtime = 0;
2635                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2636         }
2637
2638         target_voicescript_next(self);
2639
2640         // WEAPONTODO: Move into weaponsystem somehow
2641         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2642         if(!self.weapon)
2643                 self.clip_load = self.clip_size = 0;
2644 }
2645
2646 /*
2647 =============
2648 PlayerPostThink
2649
2650 Called every frame for each client after the physics are run
2651 =============
2652 */
2653 .float idlekick_lasttimeleft;
2654 void PlayerPostThink (void)
2655 {SELFPARAM();
2656         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2657         if(IS_REAL_CLIENT(self))
2658         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2659         {
2660                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2661                 {
2662                         if(self.idlekick_lasttimeleft)
2663                         {
2664                                 self.idlekick_lasttimeleft = 0;
2665                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2666                         }
2667                 }
2668                 else
2669                 {
2670                         float timeleft;
2671                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2672                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2673                         {
2674                                 if(!self.idlekick_lasttimeleft)
2675                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2676                         }
2677                         if(timeleft <= 0)
2678                         {
2679                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2680                                 dropclient(self);
2681                                 return;
2682                         }
2683                         else if(timeleft <= 10)
2684                         {
2685                                 if(timeleft != self.idlekick_lasttimeleft)
2686                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2687                                 self.idlekick_lasttimeleft = timeleft;
2688                         }
2689                 }
2690         }
2691
2692         CheatFrame();
2693
2694         //CheckPlayerJump();
2695
2696         if(IS_PLAYER(self)) {
2697                 CheckRules_Player();
2698                 UpdateChatBubble();
2699                 if (self.impulse)
2700                         ImpulseCommands();
2701                 if (intermission_running)
2702                         return;         // intermission or finale
2703                 GetPressedKeys();
2704         }
2705
2706         /*
2707         float i;
2708         for(i = 0; i < 1000; ++i)
2709         {
2710                 vector end;
2711                 end = self.origin + '0 0 1024' + 512 * randomvec();
2712                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2713                 if(trace_fraction < 1)
2714                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2715                 {
2716                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2717                         break;
2718                 }
2719         }
2720         */
2721
2722         if(self.waypointsprite_attachedforcarrier)
2723                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id));
2724
2725         playerdemo_write();
2726
2727         CSQCMODEL_AUTOUPDATE(self);
2728 }