qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21
  22 #include "bot/bot.qh"
  23 #include "bot/navigation.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/teleporters.qh"
  31
  32 #include "../common/vehicles/all.qh"
  33
  34 #include "weapons/hitplot.qh"
  35 #include "weapons/weaponsystem.qh"
  36
  37 #include "../common/net_notice.qh"
  38 #include "../common/physics/player.qh"
  39
  40 #include "../common/items/all.qc"
  41
  42 #include "../common/mutators/mutator/waypoints/all.qh"
  43
  44 #include "../common/triggers/subs.qh"
  45 #include "../common/triggers/triggers.qh"
  46 #include "../common/triggers/trigger/secret.qh"
  47
  48 #include "../common/minigames/sv_minigames.qh"
  49
  50 #include "../common/items/inventory.qh"
  51
  52 #include "../common/monsters/sv_monsters.qh"
  53
  54 #include "../lib/warpzone/server.qh"
  55
  56 STATIC_METHOD(Client, Add, void(Client this, int _team))
  57 {
  58     WITHSELF(this, ClientConnect());
  59     TRANSMUTE(Player, this);
  60     this.frame = 12; // 7
  61     this.team = _team;
  62     WITHSELF(this, PutClientInServer());
  63 }
  64
  65 void PutObserverInServer(entity this);
  66 void ClientDisconnect();
  67
  68 STATIC_METHOD(Client, Remove, void(Client this))
  69 {
  70     TRANSMUTE(Observer, this);
  71     WITHSELF(this, PutClientInServer());
  72     WITHSELF(this, ClientDisconnect());
  73 }
  74
  75 void send_CSQC_teamnagger() {
  76         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  77 }
  78
  79 int CountSpectators(entity player, entity to)
  80 {
  81         if(!player) { return 0; } // not sure how, but best to be safe
  82
  83         int spec_count = 0;
  84
  85         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  86         {
  87                 spec_count++;
  88         });
  89
  90         return spec_count;
  91 }
  92
  93 void WriteSpectators(entity player, entity to)
  94 {
  95         if(!player) { return; } // not sure how, but best to be safe
  96
  97         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  98         {
  99                 WriteByte(MSG_ENTITY, num_for_edict(it));
 100         });
 101 }
 102
 103 bool ClientData_Send(entity this, entity to, int sf)
 104 {
 105         assert(to == this.owner, return false);
 106
 107         entity e = to;
 108         if (IS_SPEC(e)) e = e.enemy;
 109
 110         sf = 0;
 111         if (e.race_completed)       sf |= 1; // forced scoreboard
 112         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 113         if (e.zoomstate)            sf |= 4; // zoomed
 114         if (e.porto_v_angle_held)   sf |= 8; // angles held
 115         sf |= 16; // always check spectators
 116
 117         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 118         WriteByte(MSG_ENTITY, sf);
 119
 120         if (sf & 2)
 121         {
 122                 WriteByte(MSG_ENTITY, to.spectatee_status);
 123         }
 124         if (sf & 8)
 125         {
 126                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 127                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 128         }
 129
 130         if(sf & 16)
 131         {
 132                 float specs = CountSpectators(e, to);
 133                 WriteByte(MSG_ENTITY, specs);
 134                 WriteSpectators(e, to);
 135         }
 136
 137         return true;
 138 }
 139
 140 void ClientData_Attach(entity this)
 141 {
 142         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 143         this.clientdata.drawonlytoclient = this;
 144         this.clientdata.owner = this;
 145 }
 146
 147 void ClientData_Detach(entity this)
 148 {
 149         remove(this.clientdata);
 150         this.clientdata = NULL;
 151 }
 152
 153 void ClientData_Touch(entity e)
 154 {
 155         e.clientdata.SendFlags = 1;
 156
 157         // make it spectatable
 158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 159 }
 160
 161 .string netname_previous;
 162
 163 void SetSpectatee(entity player, entity spectatee);
 164
 165
 166 /*
 167 =============
 168 CheckPlayerModel
 169
 170 Checks if the argument string can be a valid playermodel.
 171 Returns a valid one in doubt.
 172 =============
 173 */
 174 string FallbackPlayerModel;
 175 string CheckPlayerModel(string plyermodel) {
 176         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 177         {
 178                 // note: we cannot summon Don Strunzone here, some player may
 179                 // still have the model string set. In case anyone manages how
 180                 // to change a cvar default, we'll have a small leak here.
 181                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 182         }
 183         // only in right path
 184         if( substring(plyermodel,0,14) != "models/player/")
 185                 return FallbackPlayerModel;
 186         // only good file extensions
 187         if(substring(plyermodel,-4,4) != ".zym")
 188         if(substring(plyermodel,-4,4) != ".dpm")
 189         if(substring(plyermodel,-4,4) != ".iqm")
 190         if(substring(plyermodel,-4,4) != ".md3")
 191         if(substring(plyermodel,-4,4) != ".psk")
 192                 return FallbackPlayerModel;
 193         // forbid the LOD models
 194         if(substring(plyermodel, -9,5) == "_lod1")
 195                 return FallbackPlayerModel;
 196         if(substring(plyermodel, -9,5) == "_lod2")
 197                 return FallbackPlayerModel;
 198         if(plyermodel != strtolower(plyermodel))
 199                 return FallbackPlayerModel;
 200         // also, restrict to server models
 201         if(autocvar_sv_servermodelsonly)
 202         {
 203                 if(!fexists(plyermodel))
 204                         return FallbackPlayerModel;
 205         }
 206         return plyermodel;
 207 }
 208
 209 void setplayermodel(entity e, string modelname)
 210 {
 211         precache_model(modelname);
 212         _setmodel(e, modelname);
 213         player_setupanimsformodel(e);
 214         if(!autocvar_g_debug_globalsounds)
 215                 UpdatePlayerSounds(e);
 216 }
 217
 218 void FixPlayermodel(entity player);
 219 /** putting a client as observer in the server */
 220 void PutObserverInServer(entity this)
 221 {
 222     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 223         PlayerState_detach(this);
 224
 225         if (IS_PLAYER(this) && this.health >= 1) {
 226         // despawn effect
 227                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 228     }
 229
 230     {
 231         entity spot = SelectSpawnPoint(this, true);
 232         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 233         this.angles = spot.angles;
 234         this.angles_z = 0;
 235         this.fixangle = true;
 236         // offset it so that the spectator spawns higher off the ground, looks better this way
 237         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 238         this.prevorigin = this.origin;
 239         if (IS_REAL_CLIENT(this))
 240         {
 241             msg_entity = this;
 242             WriteByte(MSG_ONE, SVC_SETVIEW);
 243             WriteEntity(MSG_ONE, this);
 244         }
 245         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 246         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 247         if(!autocvar_g_debug_globalsounds)
 248         {
 249                 // needed for player sounds
 250                 this.model = "";
 251                 FixPlayermodel(this);
 252         }
 253         setmodel(this, MDL_Null);
 254         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 255         this.view_ofs = '0 0 0';
 256     }
 257
 258     RemoveGrapplingHook(this);
 259         Portal_ClearAll(this);
 260         Unfreeze(this);
 261         SetSpectatee(this, world);
 262
 263         if (this.alivetime)
 264         {
 265                 if (!warmup_stage)
 266                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 267                 this.alivetime = 0;
 268         }
 269
 270         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 271
 272         WaypointSprite_PlayerDead(this);
 273
 274         if (mutator_returnvalue) {
 275             // mutator prevents resetting teams+score
 276         } else {
 277                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 278         this.frags = FRAGS_SPECTATOR;
 279         PlayerScore_Clear(this);  // clear scores when needed
 280     }
 281
 282         if (this.killcount != FRAGS_SPECTATOR)
 283         {
 284                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 285                 if(!intermission_running)
 286                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 287                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 288
 289                 if(this.just_joined == false) {
 290                         LogTeamchange(this.playerid, -1, 4);
 291                 } else
 292                         this.just_joined = false;
 293         }
 294
 295         accuracy_resend(this);
 296
 297         this.spectatortime = time;
 298         this.bot_attack = false;
 299     this.hud = HUD_NORMAL;
 300         TRANSMUTE(Observer, this);
 301         this.iscreature = false;
 302         this.teleportable = TELEPORT_SIMPLE;
 303         this.damagedbycontents = false;
 304         this.health = FRAGS_SPECTATOR;
 305         this.takedamage = DAMAGE_NO;
 306         this.solid = SOLID_NOT;
 307         this.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 308         this.flags = FL_CLIENT | FL_NOTARGET;
 309         this.armorvalue = 666;
 310         this.effects = 0;
 311         this.armorvalue = autocvar_g_balance_armor_start;
 312         this.pauserotarmor_finished = 0;
 313         this.pauserothealth_finished = 0;
 314         this.pauseregen_finished = 0;
 315         this.damageforcescale = 0;
 316         this.death_time = 0;
 317         this.respawn_flags = 0;
 318         this.respawn_time = 0;
 319         this.stat_respawn_time = 0;
 320         this.alpha = 0;
 321         this.scale = 0;
 322         this.fade_time = 0;
 323         this.pain_frame = 0;
 324         this.pain_finished = 0;
 325         this.strength_finished = 0;
 326         this.invincible_finished = 0;
 327         this.superweapons_finished = 0;
 328         this.pushltime = 0;
 329         this.istypefrag = 0;
 330         setthink(this, func_null);
 331         this.nextthink = 0;
 332         this.hook_time = 0;
 333         this.deadflag = DEAD_NO;
 334         this.crouch = false;
 335         this.revival_time = 0;
 336
 337         this.items = 0;
 338         this.weapons = '0 0 0';
 339         this.drawonlytoclient = this;
 340
 341         this.weaponname = "";
 342         this.weaponmodel = "";
 343         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 344         {
 345                 this.weaponentities[slot] = NULL;
 346         }
 347         this.exteriorweaponentity = NULL;
 348         this.killcount = FRAGS_SPECTATOR;
 349         this.velocity = '0 0 0';
 350         this.avelocity = '0 0 0';
 351         this.punchangle = '0 0 0';
 352         this.punchvector = '0 0 0';
 353         this.oldvelocity = this.velocity;
 354         this.fire_endtime = -1;
 355         this.event_damage = func_null;
 356 }
 357
 358 int player_getspecies(entity this)
 359 {
 360         get_model_parameters(this.model, this.skin);
 361         int s = get_model_parameters_species;
 362         get_model_parameters(string_null, 0);
 363         if (s < 0) return SPECIES_HUMAN;
 364         return s;
 365 }
 366
 367 .float model_randomizer;
 368 void FixPlayermodel(entity player)
 369 {
 370         string defaultmodel = "";
 371         int defaultskin = 0;
 372         if(autocvar_sv_defaultcharacter)
 373         {
 374                 if(teamplay)
 375                 {
 376                         string s = Static_Team_ColorName_Lower(player.team);
 377                         if (s != "neutral")
 378                         {
 379                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 380                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 381                         }
 382                 }
 383
 384                 if(defaultmodel == "")
 385                 {
 386                         defaultmodel = autocvar_sv_defaultplayermodel;
 387                         defaultskin = autocvar_sv_defaultplayerskin;
 388                 }
 389
 390                 int n = tokenize_console(defaultmodel);
 391                 if(n > 0)
 392                 {
 393                         defaultmodel = argv(floor(n * player.model_randomizer));
 394                         // However, do NOT randomize if the player-selected model is in the list.
 395                         for (int i = 0; i < n; ++i)
 396                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 397                                         defaultmodel = argv(i);
 398                 }
 399
 400                 int i = strstrofs(defaultmodel, ":", 0);
 401                 if(i >= 0)
 402                 {
 403                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 404                         defaultmodel = substring(defaultmodel, 0, i);
 405                 }
 406         }
 407         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 408         {
 409                 if(teamplay)
 410                 {
 411                         string s = Static_Team_ColorName_Lower(player.team);
 412                         if (s != "neutral")
 413                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 414                 }
 415
 416                 if(!defaultskin)
 417                         defaultskin = autocvar_sv_defaultplayerskin;
 418         }
 419
 420         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 421         defaultmodel = M_ARGV(0, string);
 422         defaultskin = M_ARGV(1, int);
 423
 424         bool chmdl = false;
 425         int oldskin;
 426         if(defaultmodel != "")
 427         {
 428                 if (defaultmodel != player.model)
 429                 {
 430                         vector m1 = player.mins;
 431                         vector m2 = player.maxs;
 432                         setplayermodel (player, defaultmodel);
 433                         setsize (player, m1, m2);
 434                         chmdl = true;
 435                 }
 436
 437                 oldskin = player.skin;
 438                 player.skin = defaultskin;
 439         } else {
 440                 if (player.playermodel != player.model || player.playermodel == "")
 441                 {
 442                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 443                         vector m1 = player.mins;
 444                         vector m2 = player.maxs;
 445                         setplayermodel (player, player.playermodel);
 446                         setsize (player, m1, m2);
 447                         chmdl = true;
 448                 }
 449
 450                 if(!autocvar_sv_defaultcharacterskin)
 451                 {
 452                         oldskin = player.skin;
 453                         player.skin = stof(player.playerskin);
 454                 }
 455                 else
 456                 {
 457                         oldskin = player.skin;
 458                         player.skin = defaultskin;
 459                 }
 460         }
 461
 462         if(chmdl || oldskin != player.skin) // model or skin has changed
 463         {
 464                 player.species = player_getspecies(player); // update species
 465                 if(!autocvar_g_debug_globalsounds)
 466                         UpdatePlayerSounds(player); // update skin sounds
 467         }
 468
 469         if(!teamplay)
 470                 if(strlen(autocvar_sv_defaultplayercolors))
 471                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 472                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 473 }
 474
 475
 476 /** Called when a client spawns in the server */
 477 void PutClientInServer()
 478 {ENGINE_EVENT();
 479         if (IS_BOT_CLIENT(this)) {
 480                 TRANSMUTE(Player, this);
 481         } else if (IS_REAL_CLIENT(this)) {
 482                 msg_entity = this;
 483                 WriteByte(MSG_ONE, SVC_SETVIEW);
 484                 WriteEntity(MSG_ONE, this);
 485         }
 486         if (gameover) {
 487                 TRANSMUTE(Observer, this);
 488         }
 489
 490         SetSpectatee(this, NULL);
 491
 492         // reset player keys
 493         this.itemkeys = 0;
 494
 495         MUTATOR_CALLHOOK(PutClientInServer, this);
 496
 497         if (IS_OBSERVER(this)) {
 498                 PutObserverInServer(this);
 499         } else if (IS_PLAYER(this)) {
 500                 PlayerState_attach(this);
 501                 accuracy_resend(this);
 502
 503                 if (this.team < 0)
 504                         JoinBestTeam(this, false, true);
 505
 506                 entity spot = SelectSpawnPoint(this, false);
 507                 if (!spot) {
 508                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 509                         return; // spawn failed
 510                 }
 511
 512                 TRANSMUTE(Player, this);
 513                 this.wasplayer = true;
 514                 this.iscreature = true;
 515                 this.teleportable = TELEPORT_NORMAL;
 516                 this.damagedbycontents = true;
 517                 this.movetype = MOVETYPE_WALK;
 518                 this.solid = SOLID_SLIDEBOX;
 519                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 520                 if (autocvar_g_playerclip_collisions)
 521                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 522                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 523                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 524                 this.frags = FRAGS_PLAYER;
 525                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 526                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 527                 if (autocvar__notarget)
 528                         this.flags |= FL_NOTARGET;
 529                 this.takedamage = DAMAGE_AIM;
 530                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 531                 this.dmg = 2; // WTF
 532
 533                 if (warmup_stage) {
 534                         this.ammo_shells = warmup_start_ammo_shells;
 535                         this.ammo_nails = warmup_start_ammo_nails;
 536                         this.ammo_rockets = warmup_start_ammo_rockets;
 537                         this.ammo_cells = warmup_start_ammo_cells;
 538                         this.ammo_plasma = warmup_start_ammo_plasma;
 539                         this.ammo_fuel = warmup_start_ammo_fuel;
 540                         this.health = warmup_start_health;
 541                         this.armorvalue = warmup_start_armorvalue;
 542                         this.weapons = WARMUP_START_WEAPONS;
 543                 } else {
 544                         this.ammo_shells = start_ammo_shells;
 545                         this.ammo_nails = start_ammo_nails;
 546                         this.ammo_rockets = start_ammo_rockets;
 547                         this.ammo_cells = start_ammo_cells;
 548                         this.ammo_plasma = start_ammo_plasma;
 549                         this.ammo_fuel = start_ammo_fuel;
 550                         this.health = start_health;
 551                         this.armorvalue = start_armorvalue;
 552                         this.weapons = start_weapons;
 553                 }
 554
 555                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 556
 557                 this.items = start_items;
 558
 559                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 560                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 561                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 562                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 563                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 564                 // extend the pause of rotting if client was reset at the beginning of the countdown
 565                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 566                         float f = game_starttime - time;
 567                         this.spawnshieldtime += f;
 568                         this.pauserotarmor_finished += f;
 569                         this.pauserothealth_finished += f;
 570                         this.pauseregen_finished += f;
 571                 }
 572                 this.damageforcescale = 2;
 573                 this.death_time = 0;
 574                 this.respawn_flags = 0;
 575                 this.respawn_time = 0;
 576                 this.stat_respawn_time = 0;
 577                 this.scale = autocvar_sv_player_scale;
 578                 this.fade_time = 0;
 579                 this.pain_frame = 0;
 580                 this.pain_finished = 0;
 581                 this.pushltime = 0;
 582                 setthink(this, func_null); // players have no think function
 583                 this.nextthink = 0;
 584                 this.dmg_team = 0;
 585                 this.ballistics_density = autocvar_g_ballistics_density_player;
 586
 587                 this.deadflag = DEAD_NO;
 588
 589                 this.angles = spot.angles;
 590                 this.angles_z = 0; // never spawn tilted even if the spot says to
 591                 if (IS_BOT_CLIENT(this))
 592                         this.v_angle = this.angles;
 593                 this.fixangle = true; // turn this way immediately
 594                 this.oldvelocity = this.velocity = '0 0 0';
 595                 this.avelocity = '0 0 0';
 596                 this.punchangle = '0 0 0';
 597                 this.punchvector = '0 0 0';
 598
 599                 this.strength_finished = 0;
 600                 this.invincible_finished = 0;
 601                 this.fire_endtime = -1;
 602                 this.revival_time = 0;
 603                 this.air_finished = time + 12;
 604
 605                 entity spawnevent = new_pure(spawnevent);
 606                 spawnevent.owner = this;
 607                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 608
 609                 // Cut off any still running player sounds.
 610                 stopsound(this, CH_PLAYER_SINGLE);
 611
 612                 this.model = "";
 613                 FixPlayermodel(this);
 614                 this.drawonlytoclient = NULL;
 615
 616                 this.crouch = false;
 617                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 618                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 619                 this.spawnorigin = spot.origin;
 620                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 621                 // don't reset back to last position, even if new position is stuck in solid
 622                 this.oldorigin = this.origin;
 623                 this.prevorigin = this.origin;
 624                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 625                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 626                 this.hud = HUD_NORMAL;
 627
 628                 this.event_damage = PlayerDamage;
 629
 630                 this.bot_attack = true;
 631                 this.monster_attack = true;
 632
 633                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 634
 635                 if (this.killcount == FRAGS_SPECTATOR) {
 636                         PlayerScore_Clear(this);
 637                         this.killcount = 0;
 638                 }
 639
 640                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 641                 {
 642                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 643                 }
 644                 this.alpha = default_player_alpha;
 645                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 646                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 647
 648                 this.speedrunning = false;
 649
 650                 target_voicescript_clear(this);
 651
 652                 // reset fields the weapons may use
 653                 FOREACH(Weapons, true, LAMBDA(
 654                         it.wr_resetplayer(it, this);
 655                         // reload all reloadable weapons
 656                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 657                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 658                         }
 659                 ));
 660
 661                 {
 662                         string s = spot.target;
 663                         spot.target = string_null;
 664                         SUB_UseTargets(spot, this, NULL);
 665                         spot.target = s;
 666                 }
 667
 668                 Unfreeze(this);
 669
 670                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 671
 672                 if (autocvar_spawn_debug)
 673                 {
 674                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 675                         remove(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 676                 }
 677
 678                 PS(this).m_switchweapon = w_getbestweapon(this);
 679                 this.cnt = -1; // W_LastWeapon will not complain
 680                 PS(this).m_weapon = WEP_Null;
 681                 this.weaponname = "";
 682                 PS(this).m_switchingweapon = WEP_Null;
 683
 684                 if (!warmup_stage && !this.alivetime)
 685                         this.alivetime = time;
 686
 687                 antilag_clear(this, CS(this));
 688         }
 689 }
 690
 691 void ClientInit_misc(entity this);
 692
 693 .float ebouncefactor, ebouncestop; // electro's values
 694 // TODO do we need all these fields, or should we stop autodetecting runtime
 695 // changes and just have a console command to update this?
 696 bool ClientInit_SendEntity(entity this, entity to, int sf)
 697 {
 698         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 699         return = true;
 700         msg_entity = to;
 701         // MSG_INIT replacement
 702         // TODO: make easier to use
 703         Registry_send_all();
 704         W_PROP_reload(MSG_ONE, to);
 705         ClientInit_misc(this);
 706         MUTATOR_CALLHOOK(Ent_Init);
 707 }
 708 void ClientInit_misc(entity this)
 709 {
 710         int channel = MSG_ONE;
 711         WriteHeader(channel, ENT_CLIENT_INIT);
 712         WriteByte(channel, g_nexball_meter_period * 32);
 713         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 714         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 715         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 716         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 717         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 718         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 719         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 720         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 721
 722         if(sv_foginterval && world.fog != "")
 723                 WriteString(channel, world.fog);
 724         else
 725                 WriteString(channel, "");
 726         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 727         WriteByte(channel, serverflags); // client has to know if it should zoom or not
 728         WriteCoord(channel, autocvar_g_trueaim_minrange);
 729 }
 730
 731 void ClientInit_CheckUpdate(entity this)
 732 {
 733         this.nextthink = time;
 734         if(this.count != autocvar_g_balance_armor_blockpercent)
 735         {
 736                 this.count = autocvar_g_balance_armor_blockpercent;
 737                 this.SendFlags |= 1;
 738         }
 739 }
 740
 741 void ClientInit_Spawn()
 742 {
 743         entity e = new_pure(clientinit);
 744         setthink(e, ClientInit_CheckUpdate);
 745         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 746
 747         ClientInit_CheckUpdate(e);
 748 }
 749
 750 /*
 751 =============
 752 SetNewParms
 753 =============
 754 */
 755 void SetNewParms ()
 756 {
 757         // initialize parms for a new player
 758         parm1 = -(86400 * 366);
 759
 760         MUTATOR_CALLHOOK(SetNewParms);
 761 }
 762
 763 /*
 764 =============
 765 SetChangeParms
 766 =============
 767 */
 768 void SetChangeParms ()
 769 {ENGINE_EVENT();
 770         // save parms for level change
 771         parm1 = this.parm_idlesince - time;
 772
 773         MUTATOR_CALLHOOK(SetChangeParms);
 774 }
 775
 776 /*
 777 =============
 778 DecodeLevelParms
 779 =============
 780 */
 781 void DecodeLevelParms(entity this)
 782 {
 783         // load parms
 784         this.parm_idlesince = parm1;
 785         if (this.parm_idlesince == -(86400 * 366))
 786                 this.parm_idlesince = time;
 787
 788         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 789         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 790
 791         MUTATOR_CALLHOOK(DecodeLevelParms);
 792 }
 793
 794 /*
 795 =============
 796 ClientKill
 797
 798 Called when a client types 'kill' in the console
 799 =============
 800 */
 801
 802 .float clientkill_nexttime;
 803 void ClientKill_Now_TeamChange(entity this)
 804 {
 805         if(this.killindicator_teamchange == -1)
 806         {
 807                 JoinBestTeam( this, false, true );
 808         }
 809         else if(this.killindicator_teamchange == -2)
 810         {
 811                 if(blockSpectators)
 812                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 813                 PutObserverInServer(this);
 814         }
 815         else
 816                 WITHSELF(this, SV_ChangeTeam(this.killindicator_teamchange - 1));
 817         this.killindicator_teamchange = 0;
 818 }
 819
 820 void ClientKill_Now(entity this)
 821 {
 822         if(this.vehicle)
 823         {
 824             vehicles_exit(this.vehicle, VHEF_RELEASE);
 825             if(!this.killindicator_teamchange)
 826             {
 827             this.vehicle_health = -1;
 828             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 829             }
 830         }
 831
 832         if(this.killindicator && !wasfreed(this.killindicator))
 833                 remove(this.killindicator);
 834
 835         this.killindicator = world;
 836
 837         if(this.killindicator_teamchange)
 838                 ClientKill_Now_TeamChange(this);
 839
 840         if(IS_PLAYER(this))
 841                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 842
 843         // now I am sure the player IS dead
 844 }
 845 void KillIndicator_Think(entity this)
 846 {
 847         if (gameover)
 848         {
 849                 this.owner.killindicator = world;
 850                 remove(this);
 851                 return;
 852         }
 853
 854         if (this.owner.alpha < 0 && !this.owner.vehicle)
 855         {
 856                 this.owner.killindicator = world;
 857                 remove(this);
 858                 return;
 859         }
 860
 861         if(this.cnt <= 0)
 862         {
 863                 ClientKill_Now(this.owner);
 864                 return;
 865         }
 866     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 867     {
 868         this.nextthink = time + 1;
 869         this.cnt -= 1;
 870     }
 871         else
 872         {
 873                 if(this.cnt <= 10)
 874                         setmodel(this, MDL_NUM(this.cnt));
 875                 if(IS_REAL_CLIENT(this.owner))
 876                 {
 877                         if(this.cnt <= 10)
 878                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 879                 }
 880                 this.nextthink = time + 1;
 881                 this.cnt -= 1;
 882         }
 883 }
 884
 885 float clientkilltime;
 886 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 887 {
 888         float killtime;
 889         float starttime;
 890         entity e;
 891
 892         if (gameover)
 893                 return;
 894
 895         killtime = autocvar_g_balance_kill_delay;
 896
 897         if(g_race_qualifying || g_cts)
 898                 killtime = 0;
 899
 900     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 901         return;
 902
 903         this.killindicator_teamchange = targetteam;
 904
 905     if(!this.killindicator)
 906         {
 907                 if(!IS_DEAD(this))
 908                 {
 909                         killtime = max(killtime, this.clientkill_nexttime - time);
 910                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 911                 }
 912
 913                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 914                 {
 915                         ClientKill_Now(this);
 916                 }
 917                 else
 918                 {
 919                         starttime = max(time, clientkilltime);
 920
 921                         this.killindicator = spawn();
 922                         this.killindicator.owner = this;
 923                         this.killindicator.scale = 0.5;
 924                         setattachment(this.killindicator, this, "");
 925                         setorigin(this.killindicator, '0 0 52');
 926                         setthink(this.killindicator, KillIndicator_Think);
 927                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 928                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 929                         this.killindicator.cnt = ceil(killtime);
 930                         this.killindicator.count = bound(0, ceil(killtime), 10);
 931                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 932
 933                         for(e = world; (e = find(e, classname, "body")) != world; )
 934                         {
 935                                 if(e.enemy != this)
 936                                         continue;
 937                                 e.killindicator = spawn();
 938                                 e.killindicator.owner = e;
 939                                 e.killindicator.scale = 0.5;
 940                                 setattachment(e.killindicator, e, "");
 941                                 setorigin(e.killindicator, '0 0 52');
 942                                 setthink(e.killindicator, KillIndicator_Think);
 943                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 944                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 945                                 e.killindicator.cnt = ceil(killtime);
 946                         }
 947                         this.lip = 0;
 948                 }
 949         }
 950         if(this.killindicator)
 951         {
 952                 if(targetteam == 0) // just die
 953                 {
 954                         this.killindicator.colormod = '0 0 0';
 955                         if(IS_REAL_CLIENT(this))
 956                         if(this.killindicator.cnt > 0)
 957                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 958                 }
 959                 else if(targetteam == -1) // auto
 960                 {
 961                         this.killindicator.colormod = '0 1 0';
 962                         if(IS_REAL_CLIENT(this))
 963                         if(this.killindicator.cnt > 0)
 964                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 965                 }
 966                 else if(targetteam == -2) // spectate
 967                 {
 968                         this.killindicator.colormod = '0.5 0.5 0.5';
 969                         if(IS_REAL_CLIENT(this))
 970                         if(this.killindicator.cnt > 0)
 971                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 972                 }
 973                 else
 974                 {
 975                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 976                         if(IS_REAL_CLIENT(this))
 977                         if(this.killindicator.cnt > 0)
 978                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 979                 }
 980         }
 981
 982 }
 983
 984 void ClientKill ()
 985 {ENGINE_EVENT();
 986         if(gameover) return;
 987         if(this.player_blocked) return;
 988         if(STAT(FROZEN, this)) return;
 989
 990         ClientKill_TeamChange(this, 0);
 991 }
 992
 993 void FixClientCvars(entity e)
 994 {
 995         // send prediction settings to the client
 996         stuffcmd(e, "\nin_bindmap 0 0\n");
 997         if(autocvar_g_antilag == 3) // client side hitscan
 998                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 999         if(autocvar_sv_gentle)
1000                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1001
1002         MUTATOR_CALLHOOK(FixClientCvars, e);
1003 }
1004
1005 float PlayerInIDList(entity p, string idlist)
1006 {
1007         float n, i;
1008         string s;
1009
1010         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1011         if (!p.crypto_idfp)
1012                 return 0;
1013
1014         // this function allows abbreviated player IDs too!
1015         n = tokenize_console(idlist);
1016         for(i = 0; i < n; ++i)
1017         {
1018                 s = argv(i);
1019                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1020                         return 1;
1021         }
1022
1023         return 0;
1024 }
1025
1026 #ifdef DP_EXT_PRECONNECT
1027 /*
1028 =============
1029 ClientPreConnect
1030
1031 Called once (not at each match start) when a client begins a connection to the server
1032 =============
1033 */
1034 void ClientPreConnect ()
1035 {ENGINE_EVENT();
1036         if(autocvar_sv_eventlog)
1037         {
1038                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1039                         this.playerid,
1040                         etof(this),
1041                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1042                 ));
1043         }
1044 }
1045 #endif
1046
1047 /**
1048 =============
1049 ClientConnect
1050
1051 Called when a client connects to the server
1052 =============
1053 */
1054 void ClientConnect()
1055 {ENGINE_EVENT();
1056         if (Ban_MaybeEnforceBanOnce(this)) return;
1057         assert(!IS_CLIENT(this), return);
1058         this.flags |= FL_CLIENT;
1059         assert(player_count >= 0, player_count = 0);
1060
1061 #ifdef WATERMARK
1062         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1063 #endif
1064         this.version_nagtime = time + 10 + random() * 10;
1065         TRANSMUTE(Client, this);
1066
1067         // identify the right forced team
1068         if (autocvar_g_campaign)
1069         {
1070                 if (IS_REAL_CLIENT(this)) // only players, not bots
1071                 {
1072                         switch (autocvar_g_campaign_forceteam)
1073                         {
1074                                 case 1: this.team_forced = NUM_TEAM_1; break;
1075                                 case 2: this.team_forced = NUM_TEAM_2; break;
1076                                 case 3: this.team_forced = NUM_TEAM_3; break;
1077                                 case 4: this.team_forced = NUM_TEAM_4; break;
1078                                 default: this.team_forced = 0;
1079                         }
1080                 }
1081         }
1082         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1083         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1084         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1085         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1086         else switch (autocvar_g_forced_team_otherwise)
1087         {
1088                 default: this.team_forced = 0; break;
1089                 case "red": this.team_forced = NUM_TEAM_1; break;
1090                 case "blue": this.team_forced = NUM_TEAM_2; break;
1091                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1092                 case "pink": this.team_forced = NUM_TEAM_4; break;
1093                 case "spectate":
1094                 case "spectator":
1095                         this.team_forced = -1;
1096                         break;
1097         }
1098         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1099
1100     {
1101         int id = this.playerid;
1102         this.playerid = 0; // silent
1103             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1104             this.playerid = id;
1105     }
1106
1107         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1108                 TRANSMUTE(Observer, this);
1109         } else {
1110                 if (!teamplay || autocvar_g_balance_teams) {
1111                         TRANSMUTE(Player, this);
1112                         campaign_bots_may_start = true;
1113                 } else {
1114                         TRANSMUTE(Observer, this); // do it anyway
1115                 }
1116         }
1117
1118         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1119
1120         // always track bots, don't ask for cl_allow_uidtracking
1121     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1122
1123         if (autocvar_sv_eventlog)
1124                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1125
1126         LogTeamchange(this.playerid, this.team, 1);
1127
1128         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1129
1130         this.netname_previous = strzone(this.netname);
1131
1132         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && IS_PLAYER(this)) ? APP_TEAM_ENT(this, INFO_JOIN_CONNECT_TEAM) : INFO_JOIN_CONNECT), this.netname);
1133
1134         stuffcmd(this, clientstuff, "\n");
1135         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1136
1137         FixClientCvars(this);
1138
1139         // get version info from player
1140         stuffcmd(this, "cmd clientversion $gameversion\n");
1141
1142         // notify about available teams
1143         if (teamplay)
1144         {
1145                 CheckAllowedTeams(this);
1146                 int t = 0;
1147                 if (c1 >= 0) t |= BIT(0);
1148                 if (c2 >= 0) t |= BIT(1);
1149                 if (c3 >= 0) t |= BIT(2);
1150                 if (c4 >= 0) t |= BIT(3);
1151                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1152         }
1153         else
1154         {
1155                 stuffcmd(this, "set _teams_available 0\n");
1156         }
1157
1158         bot_relinkplayerlist();
1159
1160         this.spectatortime = time;
1161         if (blockSpectators)
1162         {
1163                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1164         }
1165
1166         this.jointime = time;
1167         this.allowed_timeouts = autocvar_sv_timeout_number;
1168
1169         if (IS_REAL_CLIENT(this))
1170         {
1171                 if (!autocvar_g_campaign)
1172                 {
1173                         this.motd_actived_time = -1;
1174                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1175                 }
1176
1177                 if (g_weaponarena_weapons == WEPSET(TUBA))
1178                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1179         }
1180
1181         if (!sv_foginterval && world.fog != "")
1182                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1183
1184         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)))
1185                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1186                         send_CSQC_teamnagger();
1187
1188         CSQCMODEL_AUTOINIT(this);
1189
1190         this.model_randomizer = random();
1191
1192         if (IS_REAL_CLIENT(this))
1193                 sv_notice_join(this);
1194
1195         FOREACH_ENTITY_FLOAT(init_for_player_needed, true, {
1196                 it.init_for_player(it, this);
1197         });
1198
1199         MUTATOR_CALLHOOK(ClientConnect, this);
1200 }
1201 /*
1202 =============
1203 ClientDisconnect
1204
1205 Called when a client disconnects from the server
1206 =============
1207 */
1208 .entity chatbubbleentity;
1209 void ReadyCount();
1210 void ClientDisconnect()
1211 {ENGINE_EVENT();
1212         assert(IS_CLIENT(this), return);
1213
1214         PlayerStats_GameReport_FinalizePlayer(this);
1215         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1216         if (this.active_minigame) part_minigame(this);
1217         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1218
1219         if (autocvar_sv_eventlog)
1220                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1221
1222         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1223
1224         SetSpectatee(this, NULL);
1225
1226     MUTATOR_CALLHOOK(ClientDisconnect, this);
1227
1228         ClientState_detach(this);
1229
1230         Portal_ClearAll(this);
1231
1232         Unfreeze(this);
1233
1234         RemoveGrapplingHook(this);
1235
1236         // Here, everything has been done that requires this player to be a client.
1237
1238         this.flags &= ~FL_CLIENT;
1239
1240         if (this.chatbubbleentity) remove(this.chatbubbleentity);
1241         if (this.killindicator) remove(this.killindicator);
1242
1243         WaypointSprite_PlayerGone(this);
1244
1245         bot_relinkplayerlist();
1246
1247         if (this.netname_previous) strunzone(this.netname_previous);
1248         if (this.clientstatus) strunzone(this.clientstatus);
1249         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1250         if (this.personal) remove(this.personal);
1251
1252         this.playerid = 0;
1253         ReadyCount();
1254         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1255 }
1256
1257 void ChatBubbleThink(entity this)
1258 {
1259         this.nextthink = time;
1260         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1261         {
1262                 if(this.owner) // but why can that ever be world?
1263                         this.owner.chatbubbleentity = world;
1264                 remove(this);
1265                 return;
1266         }
1267
1268         this.mdl = "";
1269
1270         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1271         {
1272                 if ( this.owner.active_minigame )
1273                         this.mdl = "models/sprites/minigame_busy.iqm";
1274                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1275                         this.mdl = "models/misc/chatbubble.spr";
1276         }
1277
1278         if ( this.model != this.mdl )
1279                 _setmodel(this, this.mdl);
1280
1281 }
1282
1283 void UpdateChatBubble(entity this)
1284 {
1285         if (this.alpha < 0)
1286                 return;
1287         // spawn a chatbubble entity if needed
1288         if (!this.chatbubbleentity)
1289         {
1290                 this.chatbubbleentity = new(chatbubbleentity);
1291                 this.chatbubbleentity.owner = this;
1292                 this.chatbubbleentity.exteriormodeltoclient = this;
1293                 setthink(this.chatbubbleentity, ChatBubbleThink);
1294                 this.chatbubbleentity.nextthink = time;
1295                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1296                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1297                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1298                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1299                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1300                 //this.chatbubbleentity.model = "";
1301                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1302         }
1303 }
1304
1305
1306 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1307 // added to the model skins
1308 /*void UpdateColorModHack()
1309 {
1310         float c;
1311         c = this.clientcolors & 15;
1312         // LordHavoc: only bothering to support white, green, red, yellow, blue
1313              if (!teamplay) this.colormod = '0 0 0';
1314         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1315         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1316         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1317         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1318         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1319         else this.colormod = '1 1 1';
1320 }*/
1321
1322 void respawn(entity this)
1323 {
1324         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1325         {
1326                 this.solid = SOLID_NOT;
1327                 this.takedamage = DAMAGE_NO;
1328                 this.movetype = MOVETYPE_FLY;
1329                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1330                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1331                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1332                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1333                 if(autocvar_g_respawn_ghosts_maxtime)
1334                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1335         }
1336
1337         CopyBody(this, 1);
1338
1339         this.effects |= EF_NODRAW; // prevent another CopyBody
1340         WITHSELF(this, PutClientInServer());
1341 }
1342
1343 void play_countdown(entity this, float finished, Sound samp)
1344 {
1345     TC(Sound, samp);
1346         if(IS_REAL_CLIENT(this))
1347                 if(floor(finished - time - frametime) != floor(finished - time))
1348                         if(finished - time < 6)
1349                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1350 }
1351
1352 void player_powerups(entity this)
1353 {
1354         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1355         int items_prev = this.items;
1356
1357         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1358                 this.modelflags |= MF_ROCKET;
1359         else
1360                 this.modelflags &= ~MF_ROCKET;
1361
1362         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1363
1364         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1365                 return;
1366
1367         Fire_ApplyDamage(this);
1368         Fire_ApplyEffect(this);
1369
1370         if (!g_instagib)
1371         {
1372                 if (this.items & ITEM_Strength.m_itemid)
1373                 {
1374                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1375                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1376                         if (time > this.strength_finished)
1377                         {
1378                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1379                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1380                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1381                         }
1382                 }
1383                 else
1384                 {
1385                         if (time < this.strength_finished)
1386                         {
1387                                 this.items = this.items | ITEM_Strength.m_itemid;
1388                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1389                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1390                         }
1391                 }
1392                 if (this.items & ITEM_Shield.m_itemid)
1393                 {
1394                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1395                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1396                         if (time > this.invincible_finished)
1397                         {
1398                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1399                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1400                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1401                         }
1402                 }
1403                 else
1404                 {
1405                         if (time < this.invincible_finished)
1406                         {
1407                                 this.items = this.items | ITEM_Shield.m_itemid;
1408                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1409                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1410                         }
1411                 }
1412                 if (this.items & IT_SUPERWEAPON)
1413                 {
1414                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1415                         {
1416                                 this.superweapons_finished = 0;
1417                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1418                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1419                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1420                         }
1421                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1422                         {
1423                                 // don't let them run out
1424                         }
1425                         else
1426                         {
1427                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1428                                 if (time > this.superweapons_finished)
1429                                 {
1430                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1431                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1432                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1433                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1434                                 }
1435                         }
1436                 }
1437                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1438                 {
1439                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1440                         {
1441                                 this.items = this.items | IT_SUPERWEAPON;
1442                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1443                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1444                         }
1445                         else
1446                         {
1447                                 this.superweapons_finished = 0;
1448                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1449                         }
1450                 }
1451                 else
1452                 {
1453                         this.superweapons_finished = 0;
1454                 }
1455         }
1456
1457         if(autocvar_g_nodepthtestplayers)
1458                 this.effects = this.effects | EF_NODEPTHTEST;
1459
1460         if(autocvar_g_fullbrightplayers)
1461                 this.effects = this.effects | EF_FULLBRIGHT;
1462
1463         if (time >= game_starttime)
1464         if (time < this.spawnshieldtime)
1465                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1466
1467         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1468 }
1469
1470 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1471 {
1472         if(current > stable)
1473                 return current;
1474         else if(current > stable - 0.25) // when close enough, "snap"
1475                 return stable;
1476         else
1477                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1478 }
1479
1480 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1481 {
1482         if(current < stable)
1483                 return current;
1484         else if(current < stable + 0.25) // when close enough, "snap"
1485                 return stable;
1486         else
1487                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1488 }
1489
1490 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1491 {
1492         if(current > rotstable)
1493         {
1494                 if(rotframetime > 0)
1495                 {
1496                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1497                         current = max(rotstable, current - rotlinear * rotframetime);
1498                 }
1499         }
1500         else if(current < regenstable)
1501         {
1502                 if(regenframetime > 0)
1503                 {
1504                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1505                         current = min(regenstable, current + regenlinear * regenframetime);
1506                 }
1507         }
1508
1509         if(current > limit)
1510                 current = limit;
1511
1512         return current;
1513 }
1514
1515 void player_regen(entity this)
1516 {
1517         float max_mod, regen_mod, rot_mod, limit_mod;
1518         max_mod = regen_mod = rot_mod = limit_mod = 1;
1519
1520         float regen_health = autocvar_g_balance_health_regen;
1521         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1522         float regen_health_rot = autocvar_g_balance_health_rot;
1523         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1524         float regen_health_stable = autocvar_g_balance_health_regenstable;
1525         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1526         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1527                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1528         max_mod = M_ARGV(1, float);
1529         regen_mod = M_ARGV(2, float);
1530         rot_mod = M_ARGV(3, float);
1531         limit_mod = M_ARGV(4, float);
1532         regen_health = M_ARGV(5, float);
1533         regen_health_linear = M_ARGV(6, float);
1534         regen_health_rot = M_ARGV(7, float);
1535         regen_health_rotlinear = M_ARGV(8, float);
1536         regen_health_stable = M_ARGV(9, float);
1537         regen_health_rotstable = M_ARGV(10, float);
1538
1539
1540         if(!mutator_returnvalue)
1541         if(!STAT(FROZEN, this))
1542         {
1543                 float mina, maxa, limith, limita;
1544                 maxa = autocvar_g_balance_armor_rotstable;
1545                 mina = autocvar_g_balance_armor_regenstable;
1546                 limith = autocvar_g_balance_health_limit;
1547                 limita = autocvar_g_balance_armor_limit;
1548
1549                 regen_health_rotstable = regen_health_rotstable * max_mod;
1550                 regen_health_stable = regen_health_stable * max_mod;
1551                 limith = limith * limit_mod;
1552                 limita = limita * limit_mod;
1553
1554                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1555                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1556         }
1557
1558         // if player rotted to death...  die!
1559         // check this outside above checks, as player may still be able to rot to death
1560         if(this.health < 1)
1561         {
1562                 if(this.vehicle)
1563                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1564                 if(this.event_damage)
1565                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1566         }
1567
1568         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1569         {
1570                 float minf, maxf, limitf;
1571
1572                 maxf = autocvar_g_balance_fuel_rotstable;
1573                 minf = autocvar_g_balance_fuel_regenstable;
1574                 limitf = autocvar_g_balance_fuel_limit;
1575
1576                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1577         }
1578 }
1579
1580 bool zoomstate_set;
1581 void SetZoomState(entity this, float z)
1582 {
1583         if(z != this.zoomstate)
1584         {
1585                 this.zoomstate = z;
1586                 ClientData_Touch(this);
1587         }
1588         zoomstate_set = true;
1589 }
1590
1591 void GetPressedKeys(entity this)
1592 {
1593         MUTATOR_CALLHOOK(GetPressedKeys, this);
1594         int keys = this.pressedkeys;
1595         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1596         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1597         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1598         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1599
1600         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1601         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1602         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1603         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1604         this.pressedkeys = keys;
1605 }
1606
1607 /*
1608 ======================
1609 spectate mode routines
1610 ======================
1611 */
1612
1613 void SpectateCopy(entity this, entity spectatee)
1614 {
1615     TC(Client, this); TC(Client, spectatee);
1616
1617         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1618         PS(this) = PS(spectatee);
1619         this.armortype = spectatee.armortype;
1620         this.armorvalue = spectatee.armorvalue;
1621         this.ammo_cells = spectatee.ammo_cells;
1622         this.ammo_plasma = spectatee.ammo_plasma;
1623         this.ammo_shells = spectatee.ammo_shells;
1624         this.ammo_nails = spectatee.ammo_nails;
1625         this.ammo_rockets = spectatee.ammo_rockets;
1626         this.ammo_fuel = spectatee.ammo_fuel;
1627         this.clip_load = spectatee.clip_load;
1628         this.clip_size = spectatee.clip_size;
1629         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1630         this.health = spectatee.health;
1631         this.impulse = 0;
1632         this.items = spectatee.items;
1633         this.last_pickup = spectatee.last_pickup;
1634         this.hit_time = spectatee.hit_time;
1635         this.strength_finished = spectatee.strength_finished;
1636         this.invincible_finished = spectatee.invincible_finished;
1637         this.pressedkeys = spectatee.pressedkeys;
1638         this.weapons = spectatee.weapons;
1639         this.vortex_charge = spectatee.vortex_charge;
1640         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1641         this.hagar_load = spectatee.hagar_load;
1642         this.arc_heat_percent = spectatee.arc_heat_percent;
1643         this.minelayer_mines = spectatee.minelayer_mines;
1644         this.punchangle = spectatee.punchangle;
1645         this.view_ofs = spectatee.view_ofs;
1646         this.velocity = spectatee.velocity;
1647         this.dmg_take = spectatee.dmg_take;
1648         this.dmg_save = spectatee.dmg_save;
1649         this.dmg_inflictor = spectatee.dmg_inflictor;
1650         this.v_angle = spectatee.v_angle;
1651         this.angles = spectatee.v_angle;
1652         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1653         this.revive_progress = spectatee.revive_progress;
1654         if(!PHYS_INPUT_BUTTON_USE(this))
1655                 this.fixangle = true;
1656         setorigin(this, spectatee.origin);
1657         setsize(this, spectatee.mins, spectatee.maxs);
1658         SetZoomState(this, spectatee.zoomstate);
1659
1660     anticheat_spectatecopy(this, spectatee);
1661         this.hud = spectatee.hud;
1662         if(spectatee.vehicle)
1663     {
1664         this.fixangle = false;
1665         //this.velocity = spectatee.vehicle.velocity;
1666         this.vehicle_health = spectatee.vehicle_health;
1667         this.vehicle_shield = spectatee.vehicle_shield;
1668         this.vehicle_energy = spectatee.vehicle_energy;
1669         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1670         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1671         this.vehicle_reload1 = spectatee.vehicle_reload1;
1672         this.vehicle_reload2 = spectatee.vehicle_reload2;
1673
1674         msg_entity = this;
1675
1676         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1677             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1678             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1679             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1680
1681         //WriteByte (MSG_ONE, SVC_SETVIEW);
1682         //    WriteEntity(MSG_ONE, this);
1683         //makevectors(spectatee.v_angle);
1684         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1685     }
1686 }
1687
1688 bool SpectateUpdate(entity this)
1689 {
1690         if(!this.enemy)
1691             return false;
1692
1693         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1694         {
1695                 SetSpectatee(this, NULL);
1696                 return false;
1697         }
1698
1699         SpectateCopy(this, this.enemy);
1700
1701         return true;
1702 }
1703
1704 bool SpectateSet(entity this)
1705 {
1706         if(!IS_PLAYER(this.enemy))
1707                 return false;
1708
1709         ClientData_Touch(this.enemy);
1710
1711         msg_entity = this;
1712         WriteByte(MSG_ONE, SVC_SETVIEW);
1713         WriteEntity(MSG_ONE, this.enemy);
1714         this.movetype = MOVETYPE_NONE;
1715         accuracy_resend(this);
1716
1717         if(!SpectateUpdate(this))
1718                 PutObserverInServer(this);
1719
1720         return true;
1721 }
1722
1723 void SetSpectatee(entity this, entity spectatee)
1724 {
1725         entity old_spectatee = this.enemy;
1726
1727         this.enemy = spectatee;
1728
1729         // WEAPONTODO
1730         // these are required to fix the spectator bug with arc
1731         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1732         if(this.enemy && this.enemy.arc_beam) { this.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1733
1734         // needed to update spectator list
1735         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1736 }
1737
1738 bool Spectate(entity this, entity pl)
1739 {
1740         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1741                 return false;
1742         pl = M_ARGV(1, entity);
1743
1744         SetSpectatee(this, pl);
1745         return SpectateSet(this);
1746 }
1747
1748 bool SpectateNext(entity this)
1749 {
1750         other = find(this.enemy, classname, STR_PLAYER);
1751
1752         if (MUTATOR_CALLHOOK(SpectateNext, this, other))
1753                 other = M_ARGV(1, entity);
1754         else if (!other)
1755                 other = find(other, classname, STR_PLAYER);
1756
1757         if(other) { SetSpectatee(this, other); }
1758
1759         return SpectateSet(this);
1760 }
1761
1762 bool SpectatePrev(entity this)
1763 {
1764         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1765         other = findchain(classname, STR_PLAYER);
1766         if (!other) // no player
1767                 return false;
1768
1769         entity first = other;
1770         // skip players until current spectated player
1771         if(this.enemy)
1772         while(other && other != this.enemy)
1773                 other = other.chain;
1774
1775         switch (MUTATOR_CALLHOOK(SpectatePrev, this, other, first))
1776         {
1777                 case MUT_SPECPREV_FOUND:
1778                     other = M_ARGV(1, entity);
1779                     break;
1780                 case MUT_SPECPREV_RETURN:
1781                     other = M_ARGV(1, entity);
1782                     return true;
1783                 case MUT_SPECPREV_CONTINUE:
1784                 default:
1785                 {
1786                         if(other.chain)
1787                                 other = other.chain;
1788                         else
1789                                 other = first;
1790                         break;
1791                 }
1792         }
1793
1794         SetSpectatee(this, other);
1795         return SpectateSet(this);
1796 }
1797
1798 /*
1799 =============
1800 ShowRespawnCountdown()
1801
1802 Update a respawn countdown display.
1803 =============
1804 */
1805 void ShowRespawnCountdown(entity this)
1806 {
1807         float number;
1808         if(!IS_DEAD(this)) // just respawned?
1809                 return;
1810         else
1811         {
1812                 number = ceil(this.respawn_time - time);
1813                 if(number <= 0)
1814                         return;
1815                 if(number <= this.respawn_countdown)
1816                 {
1817                         this.respawn_countdown = number - 1;
1818                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1819                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1820                 }
1821         }
1822 }
1823
1824 void LeaveSpectatorMode(entity this)
1825 {
1826         if(this.caplayer)
1827                 return;
1828         if(nJoinAllowed(this, this))
1829         {
1830                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1831                 {
1832                         TRANSMUTE(Player, this);
1833
1834                         SetSpectatee(self, world);
1835
1836                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1837                                 { JoinBestTeam(this, false, true); }
1838
1839                         if(autocvar_g_campaign)
1840                                 { campaign_bots_may_start = true; }
1841
1842                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1843
1844                         WITHSELF(this, PutClientInServer());
1845
1846                         if(IS_PLAYER(this)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, ((teamplay && this.team != -1) ? APP_TEAM_ENT(this, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), this.netname); }
1847                 }
1848                 else
1849                         stuffcmd(this, "menu_showteamselect\n");
1850         }
1851         else
1852         {
1853                 // Player may not join because g_maxplayers is set
1854                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1855         }
1856 }
1857
1858 /**
1859  * Determines whether the player is allowed to join. This depends on cvar
1860  * g_maxplayers, if it isn't used this function always return true, otherwise
1861  * it checks whether the number of currently playing players exceeds g_maxplayers.
1862  * @return int number of free slots for players, 0 if none
1863  */
1864 bool nJoinAllowed(entity this, entity ignore)
1865 {
1866         if(!ignore)
1867         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1868         // so report 0 free slots if restricted
1869         {
1870                 if(autocvar_g_forced_team_otherwise == "spectate")
1871                         return false;
1872                 if(autocvar_g_forced_team_otherwise == "spectator")
1873                         return false;
1874         }
1875
1876         if(this.team_forced < 0)
1877                 return false; // forced spectators can never join
1878
1879         // TODO simplify this
1880         int totalClients = 0;
1881         int currentlyPlaying = 0;
1882         FOREACH_CLIENT(true, LAMBDA(
1883                 if(it != ignore)
1884                         ++totalClients;
1885                 if(IS_REAL_CLIENT(it))
1886                 if(IS_PLAYER(it) || it.caplayer)
1887                         ++currentlyPlaying;
1888         ));
1889
1890         if (!autocvar_g_maxplayers)
1891                 return maxclients - totalClients;
1892
1893         if(currentlyPlaying < autocvar_g_maxplayers)
1894                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1895
1896         return false;
1897 }
1898
1899 /**
1900  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1901  * g_maxplayers_spectator_blocktime seconds
1902  */
1903 void checkSpectatorBlock(entity this)
1904 {
1905         if(IS_SPEC(this) || IS_OBSERVER(this))
1906         if(!this.caplayer)
1907         if(IS_REAL_CLIENT(this))
1908         {
1909                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1910                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1911                         dropclient(this);
1912                 }
1913         }
1914 }
1915
1916 void PrintWelcomeMessage(entity this)
1917 {
1918         if(this.motd_actived_time == 0)
1919         {
1920                 if (autocvar_g_campaign) {
1921                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1922                                 this.motd_actived_time = time;
1923                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1924                         }
1925                 } else {
1926                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1927                                 this.motd_actived_time = time;
1928                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1929                         }
1930                 }
1931         }
1932         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1933         {
1934                 if (autocvar_g_campaign) {
1935                         if (PHYS_INPUT_BUTTON_INFO(this))
1936                                 this.motd_actived_time = time;
1937                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1938                                 this.motd_actived_time = 0;
1939                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1940                         }
1941                 } else {
1942                         if (PHYS_INPUT_BUTTON_INFO(this))
1943                                 this.motd_actived_time = time;
1944                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1945                                 this.motd_actived_time = 0;
1946                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1947                         }
1948                 }
1949         }
1950         else //if(this.motd_actived_time < 0) // just connected, motd is active
1951         {
1952                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
1953                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1954                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
1955                 {
1956                         // instanctly hide MOTD
1957                         this.motd_actived_time = 0;
1958                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1959                 }
1960         }
1961 }
1962
1963 void ObserverThink(entity this)
1964 {
1965         if ( this.impulse )
1966         {
1967                 MinigameImpulse(this, this.impulse);
1968                 this.impulse = 0;
1969         }
1970         float prefered_movetype;
1971         if (this.flags & FL_JUMPRELEASED) {
1972                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
1973                         this.flags &= ~FL_JUMPRELEASED;
1974                         this.flags |= FL_SPAWNING;
1975                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
1976                         this.flags &= ~FL_JUMPRELEASED;
1977                         if(SpectateNext(this)) {
1978                                 TRANSMUTE(Spectator, this);
1979                         }
1980                 } else {
1981                         prefered_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
1982                         if (this.movetype != prefered_movetype)
1983                                 this.movetype = prefered_movetype;
1984                 }
1985         } else {
1986                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
1987                         this.flags |= FL_JUMPRELEASED;
1988                         if(this.flags & FL_SPAWNING)
1989                         {
1990                                 this.flags &= ~FL_SPAWNING;
1991                                 LeaveSpectatorMode(this);
1992                                 return;
1993                         }
1994                 }
1995         }
1996 }
1997
1998 void SpectatorThink(entity this)
1999 {
2000         if ( this.impulse )
2001         {
2002                 if(MinigameImpulse(this, this.impulse))
2003                         this.impulse = 0;
2004         }
2005         if (this.flags & FL_JUMPRELEASED) {
2006                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
2007                         this.flags &= ~FL_JUMPRELEASED;
2008                         this.flags |= FL_SPAWNING;
2009                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2010                         this.flags &= ~FL_JUMPRELEASED;
2011                         if(SpectateNext(this)) {
2012                                 TRANSMUTE(Spectator, this);
2013                         } else {
2014                                 TRANSMUTE(Observer, this);
2015                                 WITHSELF(this, PutClientInServer());
2016                         }
2017                         this.impulse = 0;
2018                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2019                         this.flags &= ~FL_JUMPRELEASED;
2020                         if(SpectatePrev(this)) {
2021                                 TRANSMUTE(Spectator, this);
2022                         } else {
2023                                 TRANSMUTE(Observer, this);
2024                                 WITHSELF(this, PutClientInServer());
2025                         }
2026                         this.impulse = 0;
2027                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2028                         this.flags &= ~FL_JUMPRELEASED;
2029                         TRANSMUTE(Observer, this);
2030                         WITHSELF(this, PutClientInServer());
2031                 } else {
2032                         if(!SpectateUpdate(this))
2033                                 PutObserverInServer(this);
2034                 }
2035         } else {
2036                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2037                         this.flags |= FL_JUMPRELEASED;
2038                         if(this.flags & FL_SPAWNING)
2039                         {
2040                                 this.flags &= ~FL_SPAWNING;
2041                                 LeaveSpectatorMode(this);
2042                                 return;
2043                         }
2044                 }
2045                 if(!SpectateUpdate(this))
2046                         PutObserverInServer(this);
2047         }
2048
2049         this.flags |= FL_CLIENT | FL_NOTARGET;
2050 }
2051
2052 void vehicles_enter (entity pl, entity veh);
2053 void PlayerUseKey(entity this)
2054 {
2055         if (!IS_PLAYER(this))
2056                 return;
2057
2058         if(this.vehicle)
2059         {
2060                 if(!gameover)
2061                 {
2062                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2063                         return;
2064                 }
2065         }
2066         else if(autocvar_g_vehicles_enter)
2067         {
2068                 if(!STAT(FROZEN, this))
2069                 if(!IS_DEAD(this))
2070                 if(!gameover)
2071                 {
2072                         entity head, closest_target = world;
2073                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2074
2075                         while(head) // find the closest acceptable target to enter
2076                         {
2077                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2078                                 if(!IS_DEAD(head))
2079                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2080                                 if(head.takedamage != DAMAGE_NO)
2081                                 {
2082                                         if(closest_target)
2083                                         {
2084                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2085                                                 { closest_target = head; }
2086                                         }
2087                                         else { closest_target = head; }
2088                                 }
2089
2090                                 head = head.chain;
2091                         }
2092
2093                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2094                 }
2095         }
2096
2097         // a use key was pressed; call handlers
2098         MUTATOR_CALLHOOK(PlayerUseKey, this);
2099 }
2100
2101
2102 /*
2103 =============
2104 PlayerPreThink
2105
2106 Called every frame for each client before the physics are run
2107 =============
2108 */
2109 .float usekeypressed;
2110 .float last_vehiclecheck;
2111 .int items_added;
2112 void PlayerPreThink ()
2113 {ENGINE_EVENT();
2114         WarpZone_PlayerPhysics_FixVAngle(this);
2115
2116     STAT(GAMESTARTTIME, this) = game_starttime;
2117         STAT(ROUNDSTARTTIME, this) = round_starttime;
2118         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2119         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2120
2121         STAT(WEAPONSINMAP, this) = weaponsInMap;
2122
2123         if (frametime) {
2124                 // physics frames: update anticheat stuff
2125                 anticheat_prethink(this);
2126         }
2127
2128         if (blockSpectators && frametime) {
2129                 // WORKAROUND: only use dropclient in server frames (frametime set).
2130                 // Never use it in cl_movement frames (frametime zero).
2131                 checkSpectatorBlock(this);
2132     }
2133
2134         zoomstate_set = false;
2135
2136         // Check for nameless players
2137         if (isInvisibleString(this.netname)) {
2138                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2139                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2140         }
2141         if (this.netname != this.netname_previous) {
2142                 if (autocvar_sv_eventlog) {
2143                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2144         }
2145                 if (this.netname_previous) strunzone(this.netname_previous);
2146                 this.netname_previous = strzone(this.netname);
2147         }
2148
2149         // version nagging
2150         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2151         this.version_nagtime = 0;
2152         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2153             // git client
2154         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2155             // git server
2156             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2157         } else {
2158             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2159             if (r < 0) { // old client
2160                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2161             } else if (r > 0) { // old server
2162                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2163             }
2164         }
2165     }
2166
2167         // GOD MODE info
2168         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2169         {
2170                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2171                 this.max_armorvalue = 0;
2172         }
2173
2174         if (STAT(FROZEN, this) == 2)
2175         {
2176                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2177                 this.health = max(1, this.revive_progress * start_health);
2178                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2179
2180                 if (this.revive_progress >= 1)
2181                         Unfreeze(this);
2182         }
2183         else if (STAT(FROZEN, this) == 3)
2184         {
2185                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2186                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2187
2188                 if (this.health < 1)
2189                 {
2190                         if (this.vehicle)
2191                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2192                         if(this.event_damage)
2193                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2194                 }
2195                 else if (this.revive_progress <= 0)
2196                         Unfreeze(this);
2197         }
2198
2199         MUTATOR_CALLHOOK(PlayerPreThink, this);
2200
2201         if(autocvar_g_vehicles_enter)
2202         if(time > this.last_vehiclecheck)
2203         if(IS_PLAYER(this))
2204         if(!gameover)
2205         if(!STAT(FROZEN, this))
2206         if(!this.vehicle)
2207         if(!IS_DEAD(this))
2208         {
2209                 entity veh;
2210                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2211                 if(vdist(veh.origin - this.origin, <, autocvar_g_vehicles_enter_radius))
2212                 if(!IS_DEAD(veh))
2213                 if(veh.takedamage != DAMAGE_NO)
2214                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, this))
2215                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2216                 else if(!veh.owner)
2217                 if(!veh.team || SAME_TEAM(this, veh))
2218                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2219                 else if(autocvar_g_vehicles_steal)
2220                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2221
2222                 this.last_vehiclecheck = time + 1;
2223         }
2224
2225         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2226         {
2227                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2228                         PlayerUseKey(this);
2229                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2230         }
2231
2232         if (IS_REAL_CLIENT(this))
2233                 PrintWelcomeMessage(this);
2234
2235         if (IS_PLAYER(this)) {
2236                 CheckRules_Player(this);
2237
2238                 if (intermission_running) {
2239                         IntermissionThink(this);
2240                         return;
2241                 }
2242
2243                 if (timeout_status == TIMEOUT_ACTIVE) {
2244             // don't allow the player to turn around while game is paused
2245                         // FIXME turn this into CSQC stuff
2246                         this.v_angle = this.lastV_angle;
2247                         this.angles = this.lastV_angle;
2248                         this.fixangle = true;
2249                 }
2250
2251                 if (frametime) player_powerups(this);
2252
2253                 if (IS_DEAD(this)) {
2254                         if (this.personal && g_race_qualifying) {
2255                                 if (time > this.respawn_time) {
2256                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2257                                         respawn(this);
2258                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2259                                 }
2260                         } else {
2261                                 if (frametime) player_anim(this);
2262                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2263
2264                                 if (this.deadflag == DEAD_DYING) {
2265                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max)) {
2266                                                 this.deadflag = DEAD_RESPAWNING;
2267                                         } else if (!button_pressed) {
2268                                                 this.deadflag = DEAD_DEAD;
2269                     }
2270                                 } else if (this.deadflag == DEAD_DEAD) {
2271                                         if (button_pressed) {
2272                                                 this.deadflag = DEAD_RESPAWNABLE;
2273                                         } else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)) {
2274                                                 this.deadflag = DEAD_RESPAWNING;
2275                     }
2276                                 } else if (this.deadflag == DEAD_RESPAWNABLE) {
2277                                         if (!button_pressed) {
2278                                                 this.deadflag = DEAD_RESPAWNING;
2279                     }
2280                                 } else if (this.deadflag == DEAD_RESPAWNING) {
2281                                         if (time > this.respawn_time) {
2282                                                 this.respawn_time = time + 1; // only retry once a second
2283                                                 this.respawn_time_max = this.respawn_time;
2284                                                 respawn(this);
2285                                         }
2286                                 }
2287
2288                                 ShowRespawnCountdown(this);
2289
2290                                 if (this.respawn_flags & RESPAWN_SILENT)
2291                                         STAT(RESPAWN_TIME, this) = 0;
2292                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2293                                 {
2294                                         if (time < this.respawn_time)
2295                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2296                                         else if (this.deadflag != DEAD_RESPAWNING)
2297                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2298                                 }
2299                                 else
2300                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2301                         }
2302
2303                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2304                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2305                                 STAT(RESPAWN_TIME, this) *= -1;
2306
2307                         return;
2308                 }
2309
2310                 this.prevorigin = this.origin;
2311
2312                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2313         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
2314                 if (this.hook.state) {
2315                         do_crouch = false;
2316                 } else if (this.vehicle) {
2317                         do_crouch = false;
2318                 } else if (STAT(FROZEN, this)) {
2319                         do_crouch = false;
2320         } else if ((PS(this).m_weapon == WEP_SHOTGUN || PS(this).m_weapon == WEP_SHOCKWAVE) && this.(weaponentity).wframe == WFRAME_FIRE2 && time < this.(weaponentity).weapon_nextthink) {
2321                     // WEAPONTODO: predict
2322                         do_crouch = false;
2323         }
2324
2325                 if (do_crouch) {
2326                         if (!this.crouch) {
2327                                 this.crouch = true;
2328                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2329                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2330                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2331                         }
2332                 } else if (this.crouch) {
2333             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2334             if (!trace_startsolid) {
2335                 this.crouch = false;
2336                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2337                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2338             }
2339                 }
2340
2341                 FixPlayermodel(this);
2342
2343                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2344                 //if(frametime)
2345                 {
2346                         this.items &= ~this.items_added;
2347
2348                         W_WeaponFrame(this);
2349
2350                         this.items_added = 0;
2351                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2352                 this.items_added |= IT_FUEL;
2353
2354                         this.items |= this.items_added;
2355                 }
2356
2357                 player_regen(this);
2358
2359                 // WEAPONTODO: Add a weapon request for this
2360                 // rot vortex charge to the charge limit
2361                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2362                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2363
2364                 if (frametime) player_anim(this);
2365
2366                 // secret status
2367                 secrets_setstatus(this);
2368
2369                 // monsters status
2370                 monsters_setstatus(this);
2371
2372                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2373         }
2374         else if (gameover) {
2375                 if (intermission_running) IntermissionThink(this);
2376                 return;
2377         }
2378         else if (IS_OBSERVER(this)) {
2379                 ObserverThink(this);
2380         }
2381         else if (IS_SPEC(this)) {
2382                 SpectatorThink(this);
2383         }
2384
2385         // WEAPONTODO: Add weapon request for this
2386         if (!zoomstate_set) {
2387                 SetZoomState(this,
2388                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2389                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2390                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2391                 );
2392     }
2393
2394         int oldspectatee_status = this.spectatee_status;
2395         if (IS_SPEC(this)) {
2396                 this.spectatee_status = etof(this.enemy);
2397         } else if (IS_OBSERVER(this)) {
2398                 this.spectatee_status = etof(this);
2399         } else {
2400                 this.spectatee_status = 0;
2401     }
2402         if (this.spectatee_status != oldspectatee_status) {
2403                 ClientData_Touch(this);
2404                 if (g_race || g_cts) race_InitSpectator();
2405         }
2406
2407         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2408         {
2409                 this.teamkill_soundtime = 0;
2410
2411                 entity e = this.teamkill_soundsource;
2412                 entity oldpusher = e.pusher;
2413                 e.pusher = this;
2414                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2415                 e.pusher = oldpusher;
2416         }
2417
2418         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2419                 this.taunt_soundtime = 0;
2420                 PlayerSound(this, playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2421         }
2422
2423         target_voicescript_next(this);
2424
2425         // WEAPONTODO: Move into weaponsystem somehow
2426         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2427         if (PS(this).m_weapon == WEP_Null)
2428                 this.clip_load = this.clip_size = 0;
2429 }
2430
2431 void DrownPlayer(entity this)
2432 {
2433         if(IS_DEAD(this))
2434                 return;
2435
2436         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2437         {
2438                 if(this.air_finished < time)
2439                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOICETYPE_PLAYERSOUND);
2440                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2441                 this.dmg = 2;
2442         }
2443         else if (this.air_finished < time)
2444         {       // drown!
2445                 if (this.pain_finished < time)
2446                 {
2447                         Damage (this, world, world, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2448                         this.pain_finished = time + 0.5;
2449                 }
2450         }
2451 }
2452
2453 /*
2454 =============
2455 PlayerPostThink
2456
2457 Called every frame for each client after the physics are run
2458 =============
2459 */
2460 .float idlekick_lasttimeleft;
2461 void PlayerPostThink ()
2462 {ENGINE_EVENT();
2463         if (sv_maxidle > 0)
2464         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2465         if (IS_REAL_CLIENT(this))
2466         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2467         {
2468                 if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2469                 {
2470                         if (this.idlekick_lasttimeleft)
2471                         {
2472                                 this.idlekick_lasttimeleft = 0;
2473                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2474                         }
2475                 }
2476                 else
2477                 {
2478                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2479                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2480                                 if (!this.idlekick_lasttimeleft)
2481                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2482                         }
2483                         if (timeleft <= 0) {
2484                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2485                                 dropclient(this);
2486                                 return;
2487                         }
2488                         else if (timeleft <= 10) {
2489                                 if (timeleft != this.idlekick_lasttimeleft) {
2490                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2491                 }
2492                                 this.idlekick_lasttimeleft = timeleft;
2493                         }
2494                 }
2495         }
2496
2497         CheatFrame(this);
2498
2499         //CheckPlayerJump();
2500
2501         if (IS_PLAYER(this)) {
2502                 DrownPlayer(this);
2503                 CheckRules_Player(this);
2504                 UpdateChatBubble(this);
2505                 if (this.impulse) ImpulseCommands(this);
2506                 if (intermission_running) return; // intermission or finale
2507                 GetPressedKeys(this);
2508         }
2509
2510         if (this.waypointsprite_attachedforcarrier) {
2511             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2512                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2513     }
2514
2515         playerdemo_write(this);
2516
2517         CSQCMODEL_AUTOUPDATE(this);
2518 }