qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "waypointsprites.qh"
   4
   5 #include "anticheat.qh"
   6 #include "cl_impulse.qh"
   7 #include "cl_player.qh"
   8 #include "ent_cs.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "g_damage.qh"
  16 #include "g_hook.qh"
  17 #include "command/common.qh"
  18 #include "cheats.qh"
  19 #include "g_world.qh"
  20 #include "race.qh"
  21 #include "antilag.qh"
  22 #include "campaign.qh"
  23 #include "command/common.qh"
  24
  25 #include "bot/bot.qh"
  26 #include "bot/navigation.qh"
  27
  28 #include "../common/vehicles/all.qh"
  29
  30 #include "weapons/hitplot.qh"
  31 #include "weapons/weaponsystem.qh"
  32
  33 #include "../common/net_notice.qh"
  34 #include "../common/physics.qh"
  35
  36 #include "../common/items/all.qc"
  37
  38 #include "../common/triggers/subs.qh"
  39 #include "../common/triggers/triggers.qh"
  40 #include "../common/triggers/trigger/secret.qh"
  41
  42 #include "../common/items/inventory.qh"
  43
  44 #include "../common/monsters/sv_monsters.qh"
  45
  46 #include "../warpzonelib/server.qh"
  47
  48
  49 void send_CSQC_teamnagger() {
  50         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  51         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  52 }
  53
  54 float ClientData_Send(entity to, int sf)
  55 {
  56         if(to != self.owner)
  57         {
  58                 error("wtf");
  59                 return false;
  60         }
  61
  62         entity e;
  63
  64         e = to;
  65         if(IS_SPEC(to))
  66                 e = to.enemy;
  67
  68         sf = 0;
  69
  70         if(e.race_completed)
  71                 sf |= 1; // forced scoreboard
  72         if(to.spectatee_status)
  73                 sf |= 2; // spectator ent number follows
  74         if(e.zoomstate)
  75                 sf |= 4; // zoomed
  76         if(e.porto_v_angle_held)
  77                 sf |= 8; // angles held
  78
  79         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  80         WriteByte(MSG_ENTITY, sf);
  81
  82         if(sf & 2)
  83                 WriteByte(MSG_ENTITY, to.spectatee_status);
  84
  85         if(sf & 8)
  86         {
  87                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  88                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  89         }
  90
  91         return true;
  92 }
  93
  94 void ClientData_Attach()
  95 {
  96         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  97         self.clientdata.drawonlytoclient = self;
  98         self.clientdata.owner = self;
  99 }
 100
 101 void ClientData_Detach()
 102 {
 103         remove(self.clientdata);
 104         self.clientdata = world;
 105 }
 106
 107 void ClientData_Touch(entity e)
 108 {
 109         e.clientdata.SendFlags = 1;
 110
 111         // make it spectatable
 112         entity e2;
 113         FOR_EACH_REALCLIENT(e2)
 114         {
 115                 if(e2 != e)
 116                         if(IS_SPEC(e2))
 117                                 if(e2.enemy == e)
 118                                         e2.clientdata.SendFlags = 1;
 119         }
 120 }
 121
 122 .string netname_previous;
 123
 124 void SetSpectator(entity player, entity spectatee);
 125
 126
 127 /*
 128 =============
 129 CheckPlayerModel
 130
 131 Checks if the argument string can be a valid playermodel.
 132 Returns a valid one in doubt.
 133 =============
 134 */
 135 string FallbackPlayerModel;
 136 string CheckPlayerModel(string plyermodel) {
 137         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 138         {
 139                 // note: we cannot summon Don Strunzone here, some player may
 140                 // still have the model string set. In case anyone manages how
 141                 // to change a cvar default, we'll have a small leak here.
 142                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 143         }
 144         // only in right path
 145         if( substring(plyermodel,0,14) != "models/player/")
 146                 return FallbackPlayerModel;
 147         // only good file extensions
 148         if(substring(plyermodel,-4,4) != ".zym")
 149         if(substring(plyermodel,-4,4) != ".dpm")
 150         if(substring(plyermodel,-4,4) != ".iqm")
 151         if(substring(plyermodel,-4,4) != ".md3")
 152         if(substring(plyermodel,-4,4) != ".psk")
 153                 return FallbackPlayerModel;
 154         // forbid the LOD models
 155         if(substring(plyermodel, -9,5) == "_lod1")
 156                 return FallbackPlayerModel;
 157         if(substring(plyermodel, -9,5) == "_lod2")
 158                 return FallbackPlayerModel;
 159         if(plyermodel != strtolower(plyermodel))
 160                 return FallbackPlayerModel;
 161         // also, restrict to server models
 162         if(autocvar_sv_servermodelsonly)
 163         {
 164                 if(!fexists(plyermodel))
 165                         return FallbackPlayerModel;
 166         }
 167         return plyermodel;
 168 }
 169
 170 void setplayermodel(entity e, string modelname)
 171 {
 172         precache_model(modelname);
 173         setmodel(e, modelname);
 174         player_setupanimsformodel();
 175         UpdatePlayerSounds();
 176 }
 177
 178 /*
 179 =============
 180 PutObserverInServer
 181
 182 putting a client as observer in the server
 183 =============
 184 */
 185 void FixPlayermodel();
 186 void PutObserverInServer (void)
 187 {
 188         entity  spot;
 189     self.hud = HUD_NORMAL;
 190
 191         if(IS_PLAYER(self)) { Send_Effect("spawn_event_neutral", self.origin, '0 0 0', 1); }
 192
 193         spot = SelectSpawnPoint (true);
 194         if(!spot)
 195                 error("No spawnpoints for observers?!?\n");
 196         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 197
 198         if(IS_REAL_CLIENT(self))
 199         {
 200                 Item_ItemsTime_SetTimesForPlayer(self);
 201                 msg_entity = self;
 202                 WriteByte(MSG_ONE, SVC_SETVIEW);
 203                 WriteEntity(MSG_ONE, self);
 204         }
 205
 206         self.frags = FRAGS_SPECTATOR;
 207         self.bot_attack = false;
 208
 209         MUTATOR_CALLHOOK(MakePlayerObserver);
 210
 211         Portal_ClearAll(self);
 212
 213         Unfreeze(self);
 214
 215         if(self.alivetime)
 216         {
 217                 if(!warmup_stage)
 218                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 219                 self.alivetime = 0;
 220         }
 221
 222         if(self.vehicle)
 223                 vehicles_exit(VHEF_RELEASE);
 224
 225         WaypointSprite_PlayerDead();
 226
 227         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 228                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 229
 230         if(self.killcount != -666)
 231         {
 232                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 233                 if(!intermission_running)
 234                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 235                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 236
 237                 if(self.just_joined == false) {
 238                         LogTeamchange(self.playerid, -1, 4);
 239                 } else
 240                         self.just_joined = false;
 241         }
 242
 243         PlayerScore_Clear(self); // clear scores when needed
 244
 245         accuracy_resend(self);
 246
 247         self.spectatortime = time;
 248
 249         self.classname = "observer";
 250         self.iscreature = false;
 251         self.teleportable = TELEPORT_SIMPLE;
 252         self.damagedbycontents = false;
 253         self.health = -666;
 254         self.takedamage = DAMAGE_NO;
 255         self.solid = SOLID_NOT;
 256         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 257         self.flags = FL_CLIENT | FL_NOTARGET;
 258         self.armorvalue = 666;
 259         self.effects = 0;
 260         self.armorvalue = autocvar_g_balance_armor_start;
 261         self.pauserotarmor_finished = 0;
 262         self.pauserothealth_finished = 0;
 263         self.pauseregen_finished = 0;
 264         self.damageforcescale = 0;
 265         self.death_time = 0;
 266         self.respawn_flags = 0;
 267         self.respawn_time = 0;
 268         self.stat_respawn_time = 0;
 269         self.alpha = 0;
 270         self.scale = 0;
 271         self.fade_time = 0;
 272         self.pain_frame = 0;
 273         self.pain_finished = 0;
 274         self.strength_finished = 0;
 275         self.invincible_finished = 0;
 276         self.superweapons_finished = 0;
 277         self.pushltime = 0;
 278         self.istypefrag = 0;
 279         self.think = func_null;
 280         self.nextthink = 0;
 281         self.hook_time = 0;
 282         self.deadflag = DEAD_NO;
 283         self.angles = spot.angles;
 284         self.angles_z = 0;
 285         self.fixangle = true;
 286         self.crouch = false;
 287         self.revival_time = 0;
 288
 289         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 290         self.prevorigin = self.origin;
 291         self.items = 0;
 292         self.weapons = '0 0 0';
 293         self.model = "";
 294         FixPlayermodel();
 295         setmodel(self, "null");
 296         self.drawonlytoclient = self;
 297
 298         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 299         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 300
 301         self.weapon = 0;
 302         self.weaponname = "";
 303         self.switchingweapon = 0;
 304         self.weaponmodel = "";
 305         self.weaponentity = world;
 306         self.exteriorweaponentity = world;
 307         self.killcount = -666;
 308         self.velocity = '0 0 0';
 309         self.avelocity = '0 0 0';
 310         self.punchangle = '0 0 0';
 311         self.punchvector = '0 0 0';
 312         self.oldvelocity = self.velocity;
 313         self.fire_endtime = -1;
 314         self.event_damage = func_null;
 315 }
 316
 317 .float model_randomizer;
 318 void FixPlayermodel()
 319 {
 320         string defaultmodel;
 321         float defaultskin, chmdl, oldskin, n, i;
 322         vector m1, m2;
 323
 324         defaultmodel = "";
 325         defaultskin = 0;
 326         chmdl = false;
 327
 328         if(autocvar_sv_defaultcharacter)
 329         {
 330                 if(teamplay)
 331                 {
 332                         string s;
 333                         s = Static_Team_ColorName_Lower(self.team);
 334                         if(s != "neutral")
 335                         {
 336                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 337                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 338                         }
 339                 }
 340
 341                 if(defaultmodel == "")
 342                 {
 343                         defaultmodel = autocvar_sv_defaultplayermodel;
 344                         defaultskin = autocvar_sv_defaultplayerskin;
 345                 }
 346
 347                 n = tokenize_console(defaultmodel);
 348                 if(n > 0)
 349                 {
 350                         defaultmodel = argv(floor(n * self.model_randomizer));
 351                         // However, do NOT randomize if the player-selected model is in the list.
 352                         for (i = 0; i < n; ++i)
 353                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 354                                         defaultmodel = argv(i);
 355                 }
 356
 357                 i = strstrofs(defaultmodel, ":", 0);
 358                 if(i >= 0)
 359                 {
 360                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 361                         defaultmodel = substring(defaultmodel, 0, i);
 362                 }
 363         }
 364
 365         if(defaultmodel != "")
 366         {
 367                 if (defaultmodel != self.model)
 368                 {
 369                         m1 = self.mins;
 370                         m2 = self.maxs;
 371                         setplayermodel (self, defaultmodel);
 372                         setsize (self, m1, m2);
 373                         chmdl = true;
 374                 }
 375
 376                 oldskin = self.skin;
 377                 self.skin = defaultskin;
 378         } else {
 379                 if (self.playermodel != self.model || self.playermodel == "")
 380                 {
 381                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 382                         m1 = self.mins;
 383                         m2 = self.maxs;
 384                         setplayermodel (self, self.playermodel);
 385                         setsize (self, m1, m2);
 386                         chmdl = true;
 387                 }
 388
 389                 oldskin = self.skin;
 390                 self.skin = stof(self.playerskin);
 391         }
 392
 393         if(chmdl || oldskin != self.skin) // model or skin has changed
 394         {
 395                 self.species = player_getspecies(); // update species
 396                 UpdatePlayerSounds(); // update skin sounds
 397         }
 398
 399         if(!teamplay)
 400                 if(strlen(autocvar_sv_defaultplayercolors))
 401                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 402                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 403 }
 404
 405 /*
 406 =============
 407 PutClientInServer
 408
 409 Called when a client spawns in the server
 410 =============
 411 */
 412 void PutClientInServer (void)
 413 {
 414         if(IS_BOT_CLIENT(self))
 415                 self.classname = "player";
 416         else if(IS_REAL_CLIENT(self))
 417         {
 418                 msg_entity = self;
 419                 WriteByte(MSG_ONE, SVC_SETVIEW);
 420                 WriteEntity(MSG_ONE, self);
 421         }
 422
 423         SetSpectator(self, world);
 424
 425         // reset player keys
 426         self.itemkeys = 0;
 427
 428         MUTATOR_CALLHOOK(PutClientInServer, self);
 429
 430         if(gameover)
 431                 self.classname = "observer";
 432
 433         if(IS_PLAYER(self))
 434         {
 435                 entity spot, oldself;
 436
 437                 accuracy_resend(self);
 438
 439                 if(self.team < 0)
 440                         JoinBestTeam(self, false, true);
 441
 442                 spot = SelectSpawnPoint (false);
 443                 if(!spot)
 444                 {
 445                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 446                         return; // spawn failed
 447                 }
 448
 449                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 450
 451                 self.classname = "player";
 452                 self.wasplayer = true;
 453                 self.iscreature = true;
 454                 self.teleportable = TELEPORT_NORMAL;
 455                 self.damagedbycontents = true;
 456                 self.movetype = MOVETYPE_WALK;
 457                 self.solid = SOLID_SLIDEBOX;
 458                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 459                 if(autocvar_g_playerclip_collisions)
 460                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 461                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 462                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 463                 self.frags = FRAGS_PLAYER;
 464                 if(INDEPENDENT_PLAYERS)
 465                         MAKE_INDEPENDENT_PLAYER(self);
 466                 self.flags = FL_CLIENT;
 467                 if(autocvar__notarget)
 468                         self.flags |= FL_NOTARGET;
 469                 self.takedamage = DAMAGE_AIM;
 470                 self.effects = 0;
 471                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 472                 self.air_finished = time + 12;
 473                 self.dmg = 2;
 474                 if(WEP_CVAR(vortex, charge))
 475                 {
 476                         if(WEP_CVAR_SEC(vortex, chargepool))
 477                                 self.vortex_chargepool_ammo = 1;
 478                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 479                 }
 480
 481                 if(warmup_stage)
 482                 {
 483                         self.ammo_shells = warmup_start_ammo_shells;
 484                         self.ammo_nails = warmup_start_ammo_nails;
 485                         self.ammo_rockets = warmup_start_ammo_rockets;
 486                         self.ammo_cells = warmup_start_ammo_cells;
 487                         self.ammo_plasma = warmup_start_ammo_plasma;
 488                         self.ammo_fuel = warmup_start_ammo_fuel;
 489                         self.health = warmup_start_health;
 490                         self.armorvalue = warmup_start_armorvalue;
 491                         self.weapons = WARMUP_START_WEAPONS;
 492                 }
 493                 else
 494                 {
 495                         self.ammo_shells = start_ammo_shells;
 496                         self.ammo_nails = start_ammo_nails;
 497                         self.ammo_rockets = start_ammo_rockets;
 498                         self.ammo_cells = start_ammo_cells;
 499                         self.ammo_plasma = start_ammo_plasma;
 500                         self.ammo_fuel = start_ammo_fuel;
 501                         self.health = start_health;
 502                         self.armorvalue = start_armorvalue;
 503                         self.weapons = start_weapons;
 504                 }
 505
 506                 if(self.weapons & WEPSET_SUPERWEAPONS)
 507                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 508                 else
 509                         self.superweapons_finished = 0;
 510
 511                 if(!warmup_stage)
 512                         Item_ItemsTime_ResetTimesForPlayer(self);
 513
 514                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 515                 {
 516                         if(g_weaponarena_random_with_blaster)
 517                                 self.weapons &= ~WEPSET_BLASTER;
 518                         W_RandomWeapons(self, g_weaponarena_random);
 519                         if(g_weaponarena_random_with_blaster)
 520                                 self.weapons |= WEPSET_BLASTER;
 521                 }
 522
 523                 self.items = start_items;
 524
 525                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 526                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 527                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 528                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 529                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 530                 //extend the pause of rotting if client was reset at the beginning of the countdown
 531                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 532                         self.spawnshieldtime += game_starttime - time;
 533                         self.pauserotarmor_finished += game_starttime - time;
 534                         self.pauserothealth_finished += game_starttime - time;
 535                         self.pauseregen_finished += game_starttime - time;
 536                 }
 537                 self.damageforcescale = 2;
 538                 self.death_time = 0;
 539                 self.respawn_flags = 0;
 540                 self.respawn_time = 0;
 541                 self.stat_respawn_time = 0;
 542                 self.scale = autocvar_sv_player_scale;
 543                 self.fade_time = 0;
 544                 self.pain_frame = 0;
 545                 self.pain_finished = 0;
 546                 self.strength_finished = 0;
 547                 self.invincible_finished = 0;
 548                 self.pushltime = 0;
 549                 // players have no think function
 550                 self.think = func_null;
 551                 self.nextthink = 0;
 552                 self.hook_time = 0;
 553                 self.dmg_team = 0;
 554                 self.ballistics_density = autocvar_g_ballistics_density_player;
 555
 556                 self.metertime = 0;
 557
 558                 self.deadflag = DEAD_NO;
 559
 560                 self.angles = spot.angles;
 561
 562                 self.angles_z = 0; // never spawn tilted even if the spot says to
 563                 if(IS_BOT_CLIENT(self))
 564                         self.v_angle = self.angles;
 565                 self.fixangle = true; // turn this way immediately
 566                 self.velocity = '0 0 0';
 567                 self.avelocity = '0 0 0';
 568                 self.punchangle = '0 0 0';
 569                 self.punchvector = '0 0 0';
 570                 self.oldvelocity = self.velocity;
 571                 self.fire_endtime = -1;
 572                 self.revival_time = 0;
 573
 574                 entity spawnevent = spawn();
 575                 spawnevent.owner = self;
 576                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 577
 578                 // Cut off any still running player sounds.
 579                 stopsound(self, CH_PLAYER_SINGLE);
 580
 581                 self.model = "";
 582                 FixPlayermodel();
 583                 self.drawonlytoclient = world;
 584
 585                 self.crouch = false;
 586                 self.view_ofs = PL_VIEW_OFS;
 587                 setsize (self, PL_MIN, PL_MAX);
 588                 self.spawnorigin = spot.origin;
 589                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 590                 // don't reset back to last position, even if new position is stuck in solid
 591                 self.oldorigin = self.origin;
 592                 self.prevorigin = self.origin;
 593                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 594                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 595         self.hud = HUD_NORMAL;
 596
 597                 self.event_damage = PlayerDamage;
 598
 599                 self.bot_attack = true;
 600                 self.monster_attack = true;
 601
 602                 self.spider_slowness = 0;
 603
 604                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 605
 606                 if(self.killcount == -666) {
 607                         PlayerScore_Clear(self);
 608                         self.killcount = 0;
 609                 }
 610
 611                 CL_SpawnWeaponentity();
 612                 self.alpha = default_player_alpha;
 613                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 614                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 615
 616                 self.speedrunning = false;
 617
 618                 //stuffcmd(self, "chase_active 0");
 619                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 620
 621                 target_voicescript_clear(self);
 622
 623                 // reset fields the weapons may use
 624                 for (int j = WEP_FIRST; j <= WEP_LAST; ++j)
 625                 {
 626                         WEP_ACTION(j, WR_RESETPLAYER);
 627
 628                         // all weapons must be fully loaded when we spawn
 629                         entity e = get_weaponinfo(j);
 630                         if (e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 631                                 self.(weapon_load[j]) = e.reloading_ammo;
 632                 }
 633
 634                 oldself = self;
 635                 self = spot;
 636                         activator = oldself;
 637                                 string s;
 638                                 s = self.target;
 639                                 self.target = string_null;
 640                                 SUB_UseTargets();
 641                                 self.target = s;
 642                         activator = world;
 643                 self = oldself;
 644
 645                 Unfreeze(self);
 646
 647                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 648
 649                 if(autocvar_spawn_debug)
 650                 {
 651                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 652                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 653                 }
 654
 655                 self.switchweapon = w_getbestweapon(self);
 656                 self.cnt = -1; // W_LastWeapon will not complain
 657                 self.weapon = 0;
 658                 self.weaponname = "";
 659                 self.switchingweapon = 0;
 660
 661                 if(!warmup_stage)
 662                         if(!self.alivetime)
 663                                 self.alivetime = time;
 664
 665                 antilag_clear(self);
 666         }
 667         else if(IS_OBSERVER(self))
 668         {
 669                 PutObserverInServer ();
 670         }
 671 }
 672
 673 .float ebouncefactor, ebouncestop; // electro's values
 674 // TODO do we need all these fields, or should we stop autodetecting runtime
 675 // changes and just have a console command to update this?
 676 float ClientInit_SendEntity(entity to, int sf)
 677 {
 678         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 679         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 680         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 681         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 682         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 683         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 684         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 685         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 686         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 687         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 688
 689         if(sv_foginterval && world.fog != "")
 690                 WriteString(MSG_ENTITY, world.fog);
 691         else
 692                 WriteString(MSG_ENTITY, "");
 693         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 694         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 695         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 696         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 697         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 698         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 699         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 700         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 701         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 702         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 703         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 704         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 705         return true;
 706 }
 707
 708 void ClientInit_CheckUpdate()
 709 {
 710         self.nextthink = time;
 711         if(self.count != autocvar_g_balance_armor_blockpercent)
 712         {
 713                 self.count = autocvar_g_balance_armor_blockpercent;
 714                 self.SendFlags |= 1;
 715         }
 716         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 717         {
 718                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 719                 self.SendFlags |= 1;
 720         }
 721         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 722         {
 723                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 724                 self.SendFlags |= 1;
 725         }
 726         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 727         {
 728                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 729                 self.SendFlags |= 1;
 730         }
 731         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 732         {
 733                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 734                 self.SendFlags |= 1;
 735         }
 736 }
 737
 738 void ClientInit_Spawn()
 739 {
 740         entity o;
 741         entity e;
 742         e = spawn();
 743         e.classname = "clientinit";
 744         e.think = ClientInit_CheckUpdate;
 745         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 746
 747         o = self;
 748         self = e;
 749         ClientInit_CheckUpdate();
 750         self = o;
 751 }
 752
 753 /*
 754 =============
 755 SetNewParms
 756 =============
 757 */
 758 void SetNewParms (void)
 759 {
 760         // initialize parms for a new player
 761         parm1 = -(86400 * 366);
 762 }
 763
 764 /*
 765 =============
 766 SetChangeParms
 767 =============
 768 */
 769 void SetChangeParms (void)
 770 {
 771         // save parms for level change
 772         parm1 = self.parm_idlesince - time;
 773 }
 774
 775 /*
 776 =============
 777 DecodeLevelParms
 778 =============
 779 */
 780 void DecodeLevelParms (void)
 781 {
 782         // load parms
 783         self.parm_idlesince = parm1;
 784         if(self.parm_idlesince == -(86400 * 366))
 785                 self.parm_idlesince = time;
 786
 787         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 788         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 789 }
 790
 791 /*
 792 =============
 793 ClientKill
 794
 795 Called when a client types 'kill' in the console
 796 =============
 797 */
 798
 799 .float clientkill_nexttime;
 800 void ClientKill_Now_TeamChange()
 801 {
 802         if(self.killindicator_teamchange == -1)
 803         {
 804                 JoinBestTeam( self, false, true );
 805         }
 806         else if(self.killindicator_teamchange == -2)
 807         {
 808                 if(blockSpectators)
 809                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 810                 PutObserverInServer();
 811         }
 812         else
 813                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 814         self.killindicator_teamchange = 0;
 815 }
 816
 817 void ClientKill_Now()
 818 {
 819         if(self.vehicle)
 820         {
 821             vehicles_exit(VHEF_RELEASE);
 822             if(!self.killindicator_teamchange)
 823             {
 824             self.vehicle_health = -1;
 825             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 826             }
 827         }
 828
 829         if(self.killindicator && !wasfreed(self.killindicator))
 830                 remove(self.killindicator);
 831
 832         self.killindicator = world;
 833
 834         if(self.killindicator_teamchange)
 835                 ClientKill_Now_TeamChange();
 836
 837         if(IS_PLAYER(self))
 838                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 839
 840         // now I am sure the player IS dead
 841 }
 842 void KillIndicator_Think()
 843 {
 844         if (gameover)
 845         {
 846                 self.owner.killindicator = world;
 847                 remove(self);
 848                 return;
 849         }
 850
 851         if (self.owner.alpha < 0 && !self.owner.vehicle)
 852         {
 853                 self.owner.killindicator = world;
 854                 remove(self);
 855                 return;
 856         }
 857
 858         if(self.cnt <= 0)
 859         {
 860                 self = self.owner;
 861                 ClientKill_Now(); // no oldself needed
 862                 return;
 863         }
 864     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 865     {
 866         self.nextthink = time + 1;
 867         self.cnt -= 1;
 868     }
 869         else
 870         {
 871                 if(self.cnt <= 10)
 872                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 873                 if(IS_REAL_CLIENT(self.owner))
 874                 {
 875                         if(self.cnt <= 10)
 876                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 877                 }
 878                 self.nextthink = time + 1;
 879                 self.cnt -= 1;
 880         }
 881 }
 882
 883 float clientkilltime;
 884 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 885 {
 886         float killtime;
 887         float starttime;
 888         entity e;
 889
 890         if (gameover)
 891                 return;
 892
 893         killtime = autocvar_g_balance_kill_delay;
 894
 895         if(g_race_qualifying || g_cts)
 896                 killtime = 0;
 897
 898     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 899     {
 900                 remove(self.killindicator);
 901                 self.killindicator = world;
 902
 903         ClientKill_Now(); // allow instant kill in this case
 904         return;
 905     }
 906
 907         self.killindicator_teamchange = targetteam;
 908
 909     if(!self.killindicator)
 910         {
 911                 if(self.deadflag == DEAD_NO)
 912                 {
 913                         killtime = max(killtime, self.clientkill_nexttime - time);
 914                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 915                 }
 916
 917                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 918                 {
 919                         ClientKill_Now();
 920                 }
 921                 else
 922                 {
 923                         starttime = max(time, clientkilltime);
 924
 925                         self.killindicator = spawn();
 926                         self.killindicator.owner = self;
 927                         self.killindicator.scale = 0.5;
 928                         setattachment(self.killindicator, self, "");
 929                         setorigin(self.killindicator, '0 0 52');
 930                         self.killindicator.think = KillIndicator_Think;
 931                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 932                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 933                         self.killindicator.cnt = ceil(killtime);
 934                         self.killindicator.count = bound(0, ceil(killtime), 10);
 935                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 936
 937                         for(e = world; (e = find(e, classname, "body")) != world; )
 938                         {
 939                                 if(e.enemy != self)
 940                                         continue;
 941                                 e.killindicator = spawn();
 942                                 e.killindicator.owner = e;
 943                                 e.killindicator.scale = 0.5;
 944                                 setattachment(e.killindicator, e, "");
 945                                 setorigin(e.killindicator, '0 0 52');
 946                                 e.killindicator.think = KillIndicator_Think;
 947                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 948                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 949                                 e.killindicator.cnt = ceil(killtime);
 950                         }
 951                         self.lip = 0;
 952                 }
 953         }
 954         if(self.killindicator)
 955         {
 956                 if(targetteam == 0) // just die
 957                 {
 958                         self.killindicator.colormod = '0 0 0';
 959                         if(IS_REAL_CLIENT(self))
 960                         if(self.killindicator.cnt > 0)
 961                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 962                 }
 963                 else if(targetteam == -1) // auto
 964                 {
 965                         self.killindicator.colormod = '0 1 0';
 966                         if(IS_REAL_CLIENT(self))
 967                         if(self.killindicator.cnt > 0)
 968                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 969                 }
 970                 else if(targetteam == -2) // spectate
 971                 {
 972                         self.killindicator.colormod = '0.5 0.5 0.5';
 973                         if(IS_REAL_CLIENT(self))
 974                         if(self.killindicator.cnt > 0)
 975                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 976                 }
 977                 else
 978                 {
 979                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 980                         if(IS_REAL_CLIENT(self))
 981                         if(self.killindicator.cnt > 0)
 982                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 983                 }
 984         }
 985
 986 }
 987
 988 void ClientKill (void)
 989 {
 990         if(gameover) return;
 991         if(self.player_blocked) return;
 992         if(self.frozen) return;
 993
 994         ClientKill_TeamChange(0);
 995 }
 996
 997 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 998 {
 999     e.killindicator = spawn();
1000     e.killindicator.owner = e;
1001     e.killindicator.think = KillIndicator_Think;
1002     e.killindicator.nextthink = time + (e.lip) * 0.05;
1003     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1004     e.killindicator.health = 1; // this is used to indicate that it should be silent
1005     e.lip = 0;
1006 }
1007
1008 void FixClientCvars(entity e)
1009 {
1010         // send prediction settings to the client
1011         stuffcmd(e, "\nin_bindmap 0 0\n");
1012         if(g_race || g_cts)
1013                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1014         if(autocvar_g_antilag == 3) // client side hitscan
1015                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1016         if(autocvar_sv_gentle)
1017                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1018 }
1019
1020 float PlayerInIDList(entity p, string idlist)
1021 {
1022         float n, i;
1023         string s;
1024
1025         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1026         if (!p.crypto_idfp)
1027                 return 0;
1028
1029         // this function allows abbreviated player IDs too!
1030         n = tokenize_console(idlist);
1031         for(i = 0; i < n; ++i)
1032         {
1033                 s = argv(i);
1034                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1035                         return 1;
1036         }
1037
1038         return 0;
1039 }
1040
1041 #ifdef DP_EXT_PRECONNECT
1042 /*
1043 =============
1044 ClientPreConnect
1045
1046 Called once (not at each match start) when a client begins a connection to the server
1047 =============
1048 */
1049 void ClientPreConnect (void)
1050 {
1051         if(autocvar_sv_eventlog)
1052         {
1053                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1054                         self.playerid,
1055                         num_for_edict(self),
1056                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1057                 ));
1058         }
1059 }
1060 #endif
1061
1062 /*
1063 =============
1064 ClientConnect
1065
1066 Called when a client connects to the server
1067 =============
1068 */
1069 void DecodeLevelParms (void);
1070 //void dom_player_join_team(entity pl);
1071 void set_dom_state(entity e);
1072 void ClientConnect (void)
1073 {
1074         float t;
1075
1076         if(IS_CLIENT(self))
1077         {
1078                 print("Warning: ClientConnect, but already connected!\n");
1079                 return;
1080         }
1081
1082         if(Ban_MaybeEnforceBanOnce(self))
1083                 return;
1084
1085         DecodeLevelParms();
1086
1087 #ifdef WATERMARK
1088         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1089 #endif
1090
1091         self.classname = "player_joining";
1092
1093         self.flags = FL_CLIENT;
1094         self.version_nagtime = time + 10 + random() * 10;
1095
1096         if(player_count<0)
1097         {
1098                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1099                 player_count = 0;
1100         }
1101
1102         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1103
1104         PlayerScore_Attach(self);
1105         ClientData_Attach();
1106         accuracy_init(self);
1107         Inventory_new(self);
1108
1109         bot_clientconnect();
1110
1111         playerdemo_init();
1112
1113         anticheat_init();
1114
1115         // identify the right forced team
1116         if(autocvar_g_campaign)
1117         {
1118                 if(IS_REAL_CLIENT(self)) // only players, not bots
1119                 {
1120                         switch(autocvar_g_campaign_forceteam)
1121                         {
1122                                 case 1: self.team_forced = NUM_TEAM_1; break;
1123                                 case 2: self.team_forced = NUM_TEAM_2; break;
1124                                 case 3: self.team_forced = NUM_TEAM_3; break;
1125                                 case 4: self.team_forced = NUM_TEAM_4; break;
1126                                 default: self.team_forced = 0;
1127                         }
1128                 }
1129         }
1130         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1131                 self.team_forced = NUM_TEAM_1;
1132         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1133                 self.team_forced = NUM_TEAM_2;
1134         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1135                 self.team_forced = NUM_TEAM_3;
1136         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1137                 self.team_forced = NUM_TEAM_4;
1138         else if(autocvar_g_forced_team_otherwise == "red")
1139                 self.team_forced = NUM_TEAM_1;
1140         else if(autocvar_g_forced_team_otherwise == "blue")
1141                 self.team_forced = NUM_TEAM_2;
1142         else if(autocvar_g_forced_team_otherwise == "yellow")
1143                 self.team_forced = NUM_TEAM_3;
1144         else if(autocvar_g_forced_team_otherwise == "pink")
1145                 self.team_forced = NUM_TEAM_4;
1146         else if(autocvar_g_forced_team_otherwise == "spectate")
1147                 self.team_forced = -1;
1148         else if(autocvar_g_forced_team_otherwise == "spectator")
1149                 self.team_forced = -1;
1150         else
1151                 self.team_forced = 0;
1152
1153         if(!teamplay)
1154                 if(self.team_forced > 0)
1155                         self.team_forced = 0;
1156
1157         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1158
1159         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1160                 self.classname = "observer";
1161         } else {
1162                 if(teamplay)
1163                 {
1164                         if(autocvar_g_balance_teams)
1165                         {
1166                                 self.classname = "player";
1167                                 campaign_bots_may_start = 1;
1168                         }
1169                         else
1170                         {
1171                                 self.classname = "observer"; // do it anyway
1172                         }
1173                 }
1174                 else
1175                 {
1176                         self.classname = "player";
1177                         campaign_bots_may_start = 1;
1178                 }
1179         }
1180
1181         self.playerid = (playerid_last = playerid_last + 1);
1182
1183         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1184
1185     if(IS_BOT_CLIENT(self))
1186         PlayerStats_GameReport_AddPlayer(self);
1187
1188         if(autocvar_sv_eventlog)
1189                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1190
1191         LogTeamchange(self.playerid, self.team, 1);
1192
1193         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1194
1195         self.netname_previous = strzone(self.netname);
1196
1197         if(IS_PLAYER(self) && teamplay)
1198                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1199         else
1200                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1201
1202         stuffcmd(self, strcat(clientstuff, "\n"));
1203         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1204
1205         FixClientCvars(self);
1206
1207         // spawnfunc_waypoint sprites
1208         WaypointSprite_InitClient(self);
1209
1210         // Wazat's grappling hook
1211         SetGrappleHookBindings();
1212
1213         // Jetpack binds
1214         stuffcmd(self, "alias +jetpack +button10\n");
1215         stuffcmd(self, "alias -jetpack -button10\n");
1216
1217         // get version info from player
1218         stuffcmd(self, "cmd clientversion $gameversion\n");
1219
1220         // get other cvars from player
1221         GetCvars(0);
1222
1223         // notify about available teams
1224         if(teamplay)
1225         {
1226                 CheckAllowedTeams(self);
1227                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1228                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1229         }
1230         else
1231                 stuffcmd(self, "set _teams_available 0\n");
1232
1233         attach_entcs();
1234
1235         bot_relinkplayerlist();
1236
1237         self.spectatortime = time;
1238         if(blockSpectators)
1239         {
1240                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1241         }
1242
1243         self.jointime = time;
1244         self.allowed_timeouts = autocvar_sv_timeout_number;
1245
1246         if(IS_REAL_CLIENT(self))
1247         {
1248                 if(!autocvar_g_campaign)
1249                 {
1250                         self.motd_actived_time = -1;
1251                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1252                 }
1253
1254                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1255                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1256         }
1257
1258         if(!sv_foginterval && world.fog != "")
1259                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1260
1261         W_HitPlotOpen(self);
1262
1263         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1264                 send_CSQC_teamnagger();
1265
1266         CheatInitClient();
1267
1268         CSQCMODEL_AUTOINIT();
1269
1270         self.model_randomizer = random();
1271
1272         if(IS_REAL_CLIENT(self))
1273                 sv_notice_join();
1274
1275         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1276                 entity oldself = self;
1277                 self = e;
1278                 e.init_for_player(oldself);
1279                 self = oldself;
1280         }
1281
1282         MUTATOR_CALLHOOK(ClientConnect, self);
1283 }
1284 /*
1285 =============
1286 ClientDisconnect
1287
1288 Called when a client disconnects from the server
1289 =============
1290 */
1291 .entity chatbubbleentity;
1292 void ReadyCount();
1293 void ClientDisconnect (void)
1294 {
1295         if(self.vehicle)
1296             vehicles_exit(VHEF_RELEASE);
1297
1298         if (!IS_CLIENT(self))
1299         {
1300                 print("Warning: ClientDisconnect without ClientConnect\n");
1301                 return;
1302         }
1303
1304         PlayerStats_GameReport_FinalizePlayer(self);
1305
1306         if(IS_PLAYER(self)) { Send_Effect("spawn_event_neutral", self.origin, '0 0 0', 1); }
1307
1308         CheatShutdownClient();
1309
1310         W_HitPlotClose(self);
1311
1312         anticheat_report();
1313         anticheat_shutdown();
1314
1315         playerdemo_shutdown();
1316
1317         bot_clientdisconnect();
1318
1319         if(self.entcs)
1320                 detach_entcs();
1321
1322         if(autocvar_sv_eventlog)
1323                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1324
1325         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1326
1327         MUTATOR_CALLHOOK(ClientDisconnect);
1328
1329         Portal_ClearAll(self);
1330
1331         Unfreeze(self);
1332
1333         RemoveGrapplingHook(self);
1334
1335         // Here, everything has been done that requires this player to be a client.
1336
1337         self.flags &= ~FL_CLIENT;
1338
1339         if (self.chatbubbleentity)
1340                 remove (self.chatbubbleentity);
1341
1342         if (self.killindicator)
1343                 remove (self.killindicator);
1344
1345         WaypointSprite_PlayerGone();
1346
1347         bot_relinkplayerlist();
1348
1349         accuracy_free(self);
1350         Inventory_delete(self);
1351         ClientData_Detach();
1352         PlayerScore_Detach(self);
1353
1354         if(self.netname_previous)
1355                 strunzone(self.netname_previous);
1356         if(self.clientstatus)
1357                 strunzone(self.clientstatus);
1358         if(self.weaponorder_byimpulse)
1359                 strunzone(self.weaponorder_byimpulse);
1360
1361         ClearPlayerSounds();
1362
1363         if(self.personal)
1364                 remove(self.personal);
1365
1366         self.playerid = 0;
1367         ReadyCount();
1368
1369         // free cvars
1370         GetCvars(-1);
1371 }
1372
1373 .float BUTTON_CHAT;
1374 void ChatBubbleThink()
1375 {
1376         self.nextthink = time;
1377         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1378         {
1379                 if(self.owner) // but why can that ever be world?
1380                         self.owner.chatbubbleentity = world;
1381                 remove(self);
1382                 return;
1383         }
1384         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1385 #ifdef TETRIS
1386                 || self.owner.tetris_on
1387 #endif
1388         )
1389                 self.model = self.mdl;
1390         else
1391                 self.model = "";
1392 }
1393
1394 void UpdateChatBubble()
1395 {
1396         if (self.alpha < 0)
1397                 return;
1398         // spawn a chatbubble entity if needed
1399         if (!self.chatbubbleentity)
1400         {
1401                 self.chatbubbleentity = spawn();
1402                 self.chatbubbleentity.owner = self;
1403                 self.chatbubbleentity.exteriormodeltoclient = self;
1404                 self.chatbubbleentity.think = ChatBubbleThink;
1405                 self.chatbubbleentity.nextthink = time;
1406                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1407                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1408                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1409                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1410                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1411                 self.chatbubbleentity.model = "";
1412                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1413         }
1414 }
1415
1416
1417 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1418 // added to the model skins
1419 /*void UpdateColorModHack()
1420 {
1421         float c;
1422         c = self.clientcolors & 15;
1423         // LordHavoc: only bothering to support white, green, red, yellow, blue
1424              if (!teamplay) self.colormod = '0 0 0';
1425         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1426         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1427         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1428         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1429         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1430         else self.colormod = '1 1 1';
1431 }*/
1432
1433 void respawn(void)
1434 {
1435         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1436         {
1437                 self.solid = SOLID_NOT;
1438                 self.takedamage = DAMAGE_NO;
1439                 self.movetype = MOVETYPE_FLY;
1440                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1441                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1442                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1443                 Send_Effect("respawn_ghost", self.origin, '0 0 0', 1);
1444                 if(autocvar_g_respawn_ghosts_maxtime)
1445                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1446         }
1447
1448         CopyBody(1);
1449
1450         self.effects |= EF_NODRAW; // prevent another CopyBody
1451         PutClientInServer();
1452 }
1453
1454 void play_countdown(float finished, string samp)
1455 {
1456         if(IS_REAL_CLIENT(self))
1457                 if(floor(finished - time - frametime) != floor(finished - time))
1458                         if(finished - time < 6)
1459                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1460 }
1461
1462 void player_powerups (void)
1463 {
1464         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1465         int items_prev = self.items;
1466
1467         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1468                 self.modelflags |= MF_ROCKET;
1469         else
1470                 self.modelflags &= ~MF_ROCKET;
1471
1472         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1473
1474         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1475                 return;
1476
1477         Fire_ApplyDamage(self);
1478         Fire_ApplyEffect(self);
1479
1480         if (!g_instagib)
1481         {
1482                 if (self.items & ITEM_Strength.m_itemid)
1483                 {
1484                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1485                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1486                         if (time > self.strength_finished)
1487                         {
1488                                 self.items = self.items - (self.items & ITEM_Strength.m_itemid);
1489                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1490                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1491                         }
1492                 }
1493                 else
1494                 {
1495                         if (time < self.strength_finished)
1496                         {
1497                                 self.items = self.items | ITEM_Strength.m_itemid;
1498                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1499                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1500                         }
1501                 }
1502                 if (self.items & ITEM_Shield.m_itemid)
1503                 {
1504                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1505                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1506                         if (time > self.invincible_finished)
1507                         {
1508                                 self.items = self.items - (self.items & ITEM_Shield.m_itemid);
1509                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1510                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1511                         }
1512                 }
1513                 else
1514                 {
1515                         if (time < self.invincible_finished)
1516                         {
1517                                 self.items = self.items | ITEM_Shield.m_itemid;
1518                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1519                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1520                         }
1521                 }
1522                 if (self.items & IT_SUPERWEAPON)
1523                 {
1524                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1525                         {
1526                                 self.superweapons_finished = 0;
1527                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1528                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1529                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1530                         }
1531                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1532                         {
1533                                 // don't let them run out
1534                         }
1535                         else
1536                         {
1537                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1538                                 if (time > self.superweapons_finished)
1539                                 {
1540                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1541                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1542                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1543                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1544                                 }
1545                         }
1546                 }
1547                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1548                 {
1549                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1550                         {
1551                                 self.items = self.items | IT_SUPERWEAPON;
1552                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1553                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1554                         }
1555                         else
1556                         {
1557                                 self.superweapons_finished = 0;
1558                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1559                         }
1560                 }
1561                 else
1562                 {
1563                         self.superweapons_finished = 0;
1564                 }
1565         }
1566
1567         if(autocvar_g_nodepthtestplayers)
1568                 self.effects = self.effects | EF_NODEPTHTEST;
1569
1570         if(autocvar_g_fullbrightplayers)
1571                 self.effects = self.effects | EF_FULLBRIGHT;
1572
1573         if (time >= game_starttime)
1574         if (time < self.spawnshieldtime)
1575                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1576
1577         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1578 }
1579
1580 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1581 {
1582         if(current > stable)
1583                 return current;
1584         else if(current > stable - 0.25) // when close enough, "snap"
1585                 return stable;
1586         else
1587                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1588 }
1589
1590 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1591 {
1592         if(current < stable)
1593                 return current;
1594         else if(current < stable + 0.25) // when close enough, "snap"
1595                 return stable;
1596         else
1597                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1598 }
1599
1600 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1601 {
1602         if(current > rotstable)
1603         {
1604                 if(rotframetime > 0)
1605                 {
1606                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1607                         current = max(rotstable, current - rotlinear * rotframetime);
1608                 }
1609         }
1610         else if(current < regenstable)
1611         {
1612                 if(regenframetime > 0)
1613                 {
1614                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1615                         current = min(regenstable, current + regenlinear * regenframetime);
1616                 }
1617         }
1618
1619         if(current > limit)
1620                 current = limit;
1621
1622         return current;
1623 }
1624
1625 void player_regen (void)
1626 {
1627         float max_mod, regen_mod, rot_mod, limit_mod;
1628         max_mod = regen_mod = rot_mod = limit_mod = 1;
1629         if(!MUTATOR_CALLHOOK(PlayerRegen, max_mod, regen_mod, rot_mod, limit_mod))
1630         if(!self.frozen)
1631         {
1632                 float minh, mina, maxh, maxa, limith, limita;
1633                 maxh = autocvar_g_balance_health_rotstable;
1634                 maxa = autocvar_g_balance_armor_rotstable;
1635                 minh = autocvar_g_balance_health_regenstable;
1636                 mina = autocvar_g_balance_armor_regenstable;
1637                 limith = autocvar_g_balance_health_limit;
1638                 limita = autocvar_g_balance_armor_limit;
1639
1640                 max_mod = regen_mod_max;
1641                 regen_mod = regen_mod_regen;
1642                 rot_mod = regen_mod_rot;
1643                 limit_mod = regen_mod_limit;
1644
1645                 maxh = maxh * max_mod;
1646                 minh = minh * max_mod;
1647                 limith = limith * limit_mod;
1648                 limita = limita * limit_mod;
1649
1650                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1651                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1652         }
1653
1654         // if player rotted to death...  die!
1655         // check this outside above checks, as player may still be able to rot to death
1656         if(self.health < 1)
1657         {
1658                 if(self.vehicle)
1659                         vehicles_exit(VHEF_RELEASE);
1660                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1661         }
1662
1663         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1664         {
1665                 float minf, maxf, limitf;
1666
1667                 maxf = autocvar_g_balance_fuel_rotstable;
1668                 minf = autocvar_g_balance_fuel_regenstable;
1669                 limitf = autocvar_g_balance_fuel_limit;
1670
1671                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1672         }
1673 }
1674
1675 float zoomstate_set;
1676 void SetZoomState(float z)
1677 {
1678         if(z != self.zoomstate)
1679         {
1680                 self.zoomstate = z;
1681                 ClientData_Touch(self);
1682         }
1683         zoomstate_set = 1;
1684 }
1685
1686 void GetPressedKeys(void) {
1687         MUTATOR_CALLHOOK(GetPressedKeys);
1688         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1689         X(self.pressedkeys, KEY_FORWARD,        self.movement_x > 0);
1690         X(self.pressedkeys, KEY_BACKWARD,       self.movement_x < 0);
1691         X(self.pressedkeys, KEY_RIGHT,          self.movement_y > 0);
1692         X(self.pressedkeys, KEY_LEFT,           self.movement_y < 0);
1693
1694         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1695         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1696         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1697         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1698         #undef X
1699 }
1700
1701 /*
1702 ======================
1703 spectate mode routines
1704 ======================
1705 */
1706
1707 void SpectateCopy(entity spectatee) {
1708         MUTATOR_CALLHOOK(SpectateCopy, spectatee, self);
1709         self.armortype = spectatee.armortype;
1710         self.armorvalue = spectatee.armorvalue;
1711         self.ammo_cells = spectatee.ammo_cells;
1712         self.ammo_plasma = spectatee.ammo_plasma;
1713         self.ammo_shells = spectatee.ammo_shells;
1714         self.ammo_nails = spectatee.ammo_nails;
1715         self.ammo_rockets = spectatee.ammo_rockets;
1716         self.ammo_fuel = spectatee.ammo_fuel;
1717         self.clip_load = spectatee.clip_load;
1718         self.clip_size = spectatee.clip_size;
1719         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1720         self.health = spectatee.health;
1721         self.impulse = 0;
1722         self.items = spectatee.items;
1723         self.last_pickup = spectatee.last_pickup;
1724         self.hit_time = spectatee.hit_time;
1725         self.metertime = spectatee.metertime;
1726         self.strength_finished = spectatee.strength_finished;
1727         self.invincible_finished = spectatee.invincible_finished;
1728         self.pressedkeys = spectatee.pressedkeys;
1729         self.weapons = spectatee.weapons;
1730         self.switchweapon = spectatee.switchweapon;
1731         self.switchingweapon = spectatee.switchingweapon;
1732         self.weapon = spectatee.weapon;
1733         self.vortex_charge = spectatee.vortex_charge;
1734         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1735         self.hagar_load = spectatee.hagar_load;
1736         self.arc_heat_percent = spectatee.arc_heat_percent;
1737         self.minelayer_mines = spectatee.minelayer_mines;
1738         self.punchangle = spectatee.punchangle;
1739         self.view_ofs = spectatee.view_ofs;
1740         self.velocity = spectatee.velocity;
1741         self.dmg_take = spectatee.dmg_take;
1742         self.dmg_save = spectatee.dmg_save;
1743         self.dmg_inflictor = spectatee.dmg_inflictor;
1744         self.v_angle = spectatee.v_angle;
1745         self.angles = spectatee.v_angle;
1746         self.frozen = spectatee.frozen;
1747         self.revive_progress = spectatee.revive_progress;
1748         if(!self.BUTTON_USE)
1749                 self.fixangle = true;
1750         setorigin(self, spectatee.origin);
1751         setsize(self, spectatee.mins, spectatee.maxs);
1752         SetZoomState(spectatee.zoomstate);
1753
1754     anticheat_spectatecopy(spectatee);
1755         self.hud = spectatee.hud;
1756         if(spectatee.vehicle)
1757     {
1758         self.fixangle = false;
1759         //self.velocity = spectatee.vehicle.velocity;
1760         self.vehicle_health = spectatee.vehicle_health;
1761         self.vehicle_shield = spectatee.vehicle_shield;
1762         self.vehicle_energy = spectatee.vehicle_energy;
1763         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1764         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1765         self.vehicle_reload1 = spectatee.vehicle_reload1;
1766         self.vehicle_reload2 = spectatee.vehicle_reload2;
1767
1768         msg_entity = self;
1769
1770         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1771             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1772             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1773             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1774
1775         //WriteByte (MSG_ONE, SVC_SETVIEW);
1776         //    WriteEntity(MSG_ONE, self);
1777         //makevectors(spectatee.v_angle);
1778         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1779     }
1780 }
1781
1782 float SpectateUpdate()
1783 {
1784         if(!self.enemy)
1785             return 0;
1786
1787         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1788         {
1789                 SetSpectator(self, world);
1790                 return 0;
1791         }
1792
1793         SpectateCopy(self.enemy);
1794
1795         return 1;
1796 }
1797
1798 float SpectateSet()
1799 {
1800         if(self.enemy.classname != "player")
1801                 return false;
1802         /*if(self.enemy.vehicle)
1803         {
1804
1805                 msg_entity = self;
1806                 WriteByte(MSG_ONE, SVC_SETVIEW);
1807                 WriteEntity(MSG_ONE, self.enemy);
1808                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1809
1810                 self.movetype = MOVETYPE_NONE;
1811                 accuracy_resend(self);
1812         }
1813         else
1814         {*/
1815                 msg_entity = self;
1816                 WriteByte(MSG_ONE, SVC_SETVIEW);
1817                 WriteEntity(MSG_ONE, self.enemy);
1818                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1819                 self.movetype = MOVETYPE_NONE;
1820                 accuracy_resend(self);
1821
1822                 if(!SpectateUpdate())
1823                         PutObserverInServer();
1824         //}
1825         return true;
1826 }
1827
1828 void SetSpectator(entity player, entity spectatee)
1829 {
1830         entity old_spectatee = player.enemy;
1831
1832         player.enemy = spectatee;
1833
1834         // WEAPONTODO
1835         // these are required to fix the spectator bug with arc
1836         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1837         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1838 }
1839
1840 float Spectate(entity pl)
1841 {
1842         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1843         if(pl.team != self.team)
1844                 return 0;
1845
1846         SetSpectator(self, pl);
1847         return SpectateSet();
1848 }
1849
1850 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1851 entity CA_SpectateNext(entity start) {
1852         if (start.team == self.team) {
1853                 return start;
1854         }
1855
1856         other = start;
1857         // continue from current player
1858         while(other && other.team != self.team) {
1859                 other = find(other, classname, "player");
1860         }
1861
1862         if (!other) {
1863                 // restart from begining
1864                 other = find(other, classname, "player");
1865                 while(other && other.team != self.team) {
1866                         other = find(other, classname, "player");
1867                 }
1868         }
1869
1870         return other;
1871 }
1872
1873 float SpectateNext()
1874 {
1875         other = find(self.enemy, classname, "player");
1876
1877         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1878                 // CA and ca players when spectating enemies is forbidden
1879                 other = CA_SpectateNext(other);
1880         } else {
1881                 // other modes and ca spectators or spectating enemies is allowed
1882                 if (!other)
1883                         other = find(other, classname, "player");
1884         }
1885
1886         if(other) { SetSpectator(self, other); }
1887
1888         return SpectateSet();
1889 }
1890
1891 float SpectatePrev()
1892 {
1893         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1894         other = findchain(classname, "player");
1895         if (!other) // no player
1896                 return false;
1897
1898         entity first = other;
1899         // skip players until current spectated player
1900         if(self.enemy)
1901         while(other && other != self.enemy)
1902                 other = other.chain;
1903
1904         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1905         {
1906                 do { other = other.chain; }
1907                 while(other && other.team != self.team);
1908
1909                 if (!other)
1910                 {
1911                         other = first;
1912                         while(other.team != self.team)
1913                                 other = other.chain;
1914                         if(other == self.enemy)
1915                                 return true;
1916                 }
1917         }
1918         else
1919         {
1920                 if(other.chain)
1921                         other = other.chain;
1922                 else
1923                         other = first;
1924         }
1925         SetSpectator(self, other);
1926         return SpectateSet();
1927 }
1928
1929 /*
1930 =============
1931 ShowRespawnCountdown()
1932
1933 Update a respawn countdown display.
1934 =============
1935 */
1936 void ShowRespawnCountdown()
1937 {
1938         float number;
1939         if(self.deadflag == DEAD_NO) // just respawned?
1940                 return;
1941         else
1942         {
1943                 number = ceil(self.respawn_time - time);
1944                 if(number <= 0)
1945                         return;
1946                 if(number <= self.respawn_countdown)
1947                 {
1948                         self.respawn_countdown = number - 1;
1949                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1950                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1951                 }
1952         }
1953 }
1954
1955 void LeaveSpectatorMode()
1956 {
1957         if(self.caplayer)
1958                 return;
1959         if(nJoinAllowed(self))
1960         {
1961                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1962                 {
1963                         self.classname = "player";
1964                         nades_RemoveBonus(self);
1965
1966                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1967                                 { JoinBestTeam(self, false, true); }
1968
1969                         if(autocvar_g_campaign)
1970                                 { campaign_bots_may_start = 1; }
1971
1972                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1973
1974                         PutClientInServer();
1975
1976                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1977                 }
1978                 else
1979                         stuffcmd(self, "menu_showteamselect\n");
1980         }
1981         else
1982         {
1983                 // Player may not join because g_maxplayers is set
1984                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1985         }
1986 }
1987
1988 /**
1989  * Determines whether the player is allowed to join. This depends on cvar
1990  * g_maxplayers, if it isn't used this function always return true, otherwise
1991  * it checks whether the number of currently playing players exceeds g_maxplayers.
1992  * @return int number of free slots for players, 0 if none
1993  */
1994 float nJoinAllowed(entity ignore) {
1995         if(!ignore)
1996         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1997         // so report 0 free slots if restricted
1998         {
1999                 if(autocvar_g_forced_team_otherwise == "spectate")
2000                         return 0;
2001                 if(autocvar_g_forced_team_otherwise == "spectator")
2002                         return 0;
2003         }
2004
2005         if(self.team_forced < 0)
2006                 return 0; // forced spectators can never join
2007
2008         // TODO simplify this
2009         entity e;
2010         float totalClients = 0;
2011         FOR_EACH_CLIENT(e)
2012                 if(e != ignore)
2013                         totalClients += 1;
2014
2015         if (!autocvar_g_maxplayers)
2016                 return maxclients - totalClients;
2017
2018         float currentlyPlaying = 0;
2019         FOR_EACH_REALCLIENT(e)
2020                 if(IS_PLAYER(e) || e.caplayer)
2021                         currentlyPlaying += 1;
2022
2023         if(currentlyPlaying < autocvar_g_maxplayers)
2024                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2025
2026         return 0;
2027 }
2028
2029 /**
2030  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2031  * g_maxplayers_spectator_blocktime seconds
2032  */
2033 void checkSpectatorBlock() {
2034         if(IS_SPEC(self) || IS_OBSERVER(self))
2035         if(!self.caplayer)
2036         if(IS_REAL_CLIENT(self))
2037         {
2038                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2039                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2040                         dropclient(self);
2041                 }
2042         }
2043 }
2044
2045 void PrintWelcomeMessage()
2046 {
2047         if(self.motd_actived_time == 0)
2048         {
2049                 if (autocvar_g_campaign) {
2050                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2051                                 self.motd_actived_time = time;
2052                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2053                         }
2054                 } else {
2055                         if (self.BUTTON_INFO) {
2056                                 self.motd_actived_time = time;
2057                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2058                         }
2059                 }
2060         }
2061         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2062         {
2063                 if (autocvar_g_campaign) {
2064                         if (self.BUTTON_INFO)
2065                                 self.motd_actived_time = time;
2066                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2067                                 self.motd_actived_time = 0;
2068                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2069                         }
2070                 } else {
2071                         if (self.BUTTON_INFO)
2072                                 self.motd_actived_time = time;
2073                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2074                                 self.motd_actived_time = 0;
2075                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2076                         }
2077                 }
2078         }
2079         else //if(self.motd_actived_time < 0) // just connected, motd is active
2080         {
2081                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2082                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2083                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2084                 {
2085                         // instanctly hide MOTD
2086                         self.motd_actived_time = 0;
2087                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2088                 }
2089         }
2090 }
2091
2092 void ObserverThink()
2093 {
2094         float prefered_movetype;
2095         if (self.flags & FL_JUMPRELEASED) {
2096                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2097                         self.flags &= ~FL_JUMPRELEASED;
2098                         self.flags |= FL_SPAWNING;
2099                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2100                         self.flags &= ~FL_JUMPRELEASED;
2101                         if(SpectateNext()) {
2102                                 self.classname = "spectator";
2103                         }
2104                 } else {
2105                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2106                         if (self.movetype != prefered_movetype)
2107                                 self.movetype = prefered_movetype;
2108                 }
2109         } else {
2110                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2111                         self.flags |= FL_JUMPRELEASED;
2112                         if(self.flags & FL_SPAWNING)
2113                         {
2114                                 self.flags &= ~FL_SPAWNING;
2115                                 LeaveSpectatorMode();
2116                                 return;
2117                         }
2118                 }
2119         }
2120 }
2121
2122 void SpectatorThink()
2123 {
2124         if (self.flags & FL_JUMPRELEASED) {
2125                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2126                         self.flags &= ~FL_JUMPRELEASED;
2127                         self.flags |= FL_SPAWNING;
2128                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2129                         self.flags &= ~FL_JUMPRELEASED;
2130                         if(SpectateNext()) {
2131                                 self.classname = "spectator";
2132                         } else {
2133                                 self.classname = "observer";
2134                                 PutClientInServer();
2135                         }
2136                         self.impulse = 0;
2137                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2138                         self.flags &= ~FL_JUMPRELEASED;
2139                         if(SpectatePrev()) {
2140                                 self.classname = "spectator";
2141                         } else {
2142                                 self.classname = "observer";
2143                                 PutClientInServer();
2144                         }
2145                         self.impulse = 0;
2146                 } else if (self.BUTTON_ATCK2) {
2147                         self.flags &= ~FL_JUMPRELEASED;
2148                         self.classname = "observer";
2149                         PutClientInServer();
2150                 } else {
2151                         if(!SpectateUpdate())
2152                                 PutObserverInServer();
2153                 }
2154         } else {
2155                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2156                         self.flags |= FL_JUMPRELEASED;
2157                         if(self.flags & FL_SPAWNING)
2158                         {
2159                                 self.flags &= ~FL_SPAWNING;
2160                                 LeaveSpectatorMode();
2161                                 return;
2162                         }
2163                 }
2164                 if(!SpectateUpdate())
2165                         PutObserverInServer();
2166         }
2167
2168         self.flags |= FL_CLIENT | FL_NOTARGET;
2169 }
2170
2171 void vehicles_enter (entity pl, entity veh);
2172 void PlayerUseKey()
2173 {
2174         if (!IS_PLAYER(self))
2175                 return;
2176
2177         if(self.vehicle)
2178         {
2179                 if(!gameover)
2180                 {
2181                         vehicles_exit(VHEF_NORMAL);
2182                         return;
2183                 }
2184         }
2185         else if(autocvar_g_vehicles_enter)
2186         {
2187                 if(!self.frozen)
2188                 if(self.deadflag == DEAD_NO)
2189                 if(!gameover)
2190                 {
2191                         entity head, closest_target = world;
2192                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2193
2194                         while(head) // find the closest acceptable target to enter
2195                         {
2196                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2197                                 if(head.deadflag == DEAD_NO)
2198                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2199                                 if(head.takedamage != DAMAGE_NO)
2200                                 {
2201                                         if(closest_target)
2202                                         {
2203                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2204                                                 { closest_target = head; }
2205                                         }
2206                                         else { closest_target = head; }
2207                                 }
2208
2209                                 head = head.chain;
2210                         }
2211
2212                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2213                 }
2214         }
2215
2216         // a use key was pressed; call handlers
2217         MUTATOR_CALLHOOK(PlayerUseKey);
2218 }
2219
2220 float isInvisibleString(string s)
2221 {
2222         float i, n, c;
2223         s = strdecolorize(s);
2224         for((i = 0), (n = strlen(s)); i < n; ++i)
2225         {
2226                 c = str2chr(s, i);
2227                 switch(c)
2228                 {
2229                         case 0:
2230                         case 32: // space
2231                                 break;
2232                         case 192: // charmap space
2233                                 if (!autocvar_utf8_enable)
2234                                         break;
2235                                 return false;
2236                         case 160: // space in unicode fonts
2237                         case 0xE000 + 192: // utf8 charmap space
2238                                 if (autocvar_utf8_enable)
2239                                         break;
2240                         default:
2241                                 return false;
2242                 }
2243         }
2244         return true;
2245 }
2246
2247 /*
2248 =============
2249 PlayerPreThink
2250
2251 Called every frame for each client before the physics are run
2252 =============
2253 */
2254 .float usekeypressed;
2255 void() nexball_setstatus;
2256 .float last_vehiclecheck;
2257 .int items_added;
2258 void PlayerPreThink (void)
2259 {
2260         WarpZone_PlayerPhysics_FixVAngle();
2261
2262         self.stat_game_starttime = game_starttime;
2263         self.stat_round_starttime = round_starttime;
2264         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2265         self.stat_leadlimit = autocvar_leadlimit;
2266
2267         self.weaponsinmap = weaponsInMap;
2268
2269         if(frametime)
2270         {
2271                 // physics frames: update anticheat stuff
2272                 anticheat_prethink();
2273         }
2274
2275         if(blockSpectators && frametime)
2276                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2277                 checkSpectatorBlock();
2278
2279         zoomstate_set = 0;
2280
2281         // Savage: Check for nameless players
2282         if (isInvisibleString(self.netname)) {
2283                 string new_name = strzone(strcat("Player@", self.netaddress));
2284                 if(autocvar_sv_eventlog)
2285                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2286                 if(self.netname_previous)
2287                         strunzone(self.netname_previous);
2288                 self.netname_previous = strzone(new_name);
2289                 self.netname = self.netname_previous;
2290                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2291         } else if(self.netname_previous != self.netname) {
2292                 if(autocvar_sv_eventlog)
2293                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2294                 if(self.netname_previous)
2295                         strunzone(self.netname_previous);
2296                 self.netname_previous = strzone(self.netname);
2297         }
2298
2299         // version nagging
2300         if(self.version_nagtime)
2301                 if(self.cvar_g_xonoticversion)
2302                         if(time > self.version_nagtime)
2303                         {
2304                                 // don't notify git users
2305                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2306                                 {
2307                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2308                                         {
2309                                                 // notify release users if connecting to git
2310                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2311                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2312                                         }
2313                                         else
2314                                         {
2315                                                 float r;
2316                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2317                                                 if(r < 0)
2318                                                 {
2319                                                         // give users new version
2320                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2321                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2322                                                 }
2323                                                 else if(r > 0)
2324                                                 {
2325                                                         // notify users about old server version
2326                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2327                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2328                                                 }
2329                                         }
2330                                 }
2331                                 self.version_nagtime = 0;
2332                         }
2333
2334         // GOD MODE info
2335         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2336         {
2337                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2338                 self.max_armorvalue = 0;
2339         }
2340
2341 #ifdef TETRIS
2342         if (TetrisPreFrame())
2343                 return;
2344 #endif
2345
2346         if(self.frozen == 2)
2347         {
2348                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2349                 self.health = max(1, self.revive_progress * start_health);
2350                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2351
2352                 if(self.revive_progress >= 1)
2353                         Unfreeze(self);
2354         }
2355         else if(self.frozen == 3)
2356         {
2357                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2358                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2359
2360                 if(self.health < 1)
2361                 {
2362                         if(self.vehicle)
2363                                 vehicles_exit(VHEF_RELEASE);
2364                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2365                 }
2366                 else if ( self.revive_progress <= 0 )
2367                         Unfreeze(self);
2368         }
2369
2370         MUTATOR_CALLHOOK(PlayerPreThink);
2371
2372         if(autocvar_g_vehicles_enter)
2373         if(time > self.last_vehiclecheck)
2374         if(IS_PLAYER(self))
2375         if(!gameover)
2376         if(!self.frozen)
2377         if(!self.vehicle)
2378         if(self.deadflag == DEAD_NO)
2379         {
2380                 entity veh;
2381                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2382                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2383                 if(veh.deadflag == DEAD_NO)
2384                 if(veh.takedamage != DAMAGE_NO)
2385                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2386                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2387                 else if(!veh.owner)
2388                 if(!veh.team || SAME_TEAM(self, veh))
2389                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2390                 else if(autocvar_g_vehicles_steal)
2391                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2392
2393                 self.last_vehiclecheck = time + 1;
2394         }
2395
2396         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2397         {
2398                 if(self.BUTTON_USE && !self.usekeypressed)
2399                         PlayerUseKey();
2400                 self.usekeypressed = self.BUTTON_USE;
2401         }
2402
2403         if(IS_REAL_CLIENT(self))
2404                 PrintWelcomeMessage();
2405
2406         if(IS_PLAYER(self))
2407         {
2408
2409                 CheckRules_Player();
2410
2411                 if (intermission_running)
2412                 {
2413                         IntermissionThink ();   // otherwise a button could be missed between
2414                         return;                                 // the think tics
2415                 }
2416
2417                 //don't allow the player to turn around while game is paused!
2418                 if(timeout_status == TIMEOUT_ACTIVE) {
2419                         // FIXME turn this into CSQC stuff
2420                         self.v_angle = self.lastV_angle;
2421                         self.angles = self.lastV_angle;
2422                         self.fixangle = true;
2423                 }
2424
2425                 if(frametime)
2426                 {
2427                         if(self.weapon == WEP_VORTEX.m_id && WEP_CVAR(vortex, charge))
2428                         {
2429                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2430                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2431                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2432
2433                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2434                                 {
2435                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2436                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2437                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2438                                 }
2439                         }
2440                         else
2441                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2442
2443                         player_powerups();
2444                 }
2445
2446                 if (self.deadflag != DEAD_NO)
2447                 {
2448                         if(self.personal && g_race_qualifying)
2449                         {
2450                                 if(time > self.respawn_time)
2451                                 {
2452                                         self.respawn_time = time + 1; // only retry once a second
2453                                         self.stat_respawn_time = self.respawn_time;
2454                                         respawn();
2455                                         self.impulse = 141;
2456                                 }
2457                         }
2458                         else
2459                         {
2460                                 float button_pressed;
2461                                 if(frametime)
2462                                         player_anim();
2463                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2464
2465                                 if (self.deadflag == DEAD_DYING)
2466                                 {
2467                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2468                                                 self.deadflag = DEAD_RESPAWNING;
2469                                         else if(!button_pressed)
2470                                                 self.deadflag = DEAD_DEAD;
2471                                 }
2472                                 else if (self.deadflag == DEAD_DEAD)
2473                                 {
2474                                         if(button_pressed)
2475                                                 self.deadflag = DEAD_RESPAWNABLE;
2476                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2477                                                 self.deadflag = DEAD_RESPAWNING;
2478                                 }
2479                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2480                                 {
2481                                         if(!button_pressed)
2482                                                 self.deadflag = DEAD_RESPAWNING;
2483                                 }
2484                                 else if (self.deadflag == DEAD_RESPAWNING)
2485                                 {
2486                                         if(time > self.respawn_time)
2487                                         {
2488                                                 self.respawn_time = time + 1; // only retry once a second
2489                                                 self.respawn_time_max = self.respawn_time;
2490                                                 respawn();
2491                                         }
2492                                 }
2493
2494                                 ShowRespawnCountdown();
2495
2496                                 if(self.respawn_flags & RESPAWN_SILENT)
2497                                         self.stat_respawn_time = 0;
2498                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2499                                         self.stat_respawn_time = self.respawn_time_max;
2500                                 else
2501                                         self.stat_respawn_time = self.respawn_time;
2502                         }
2503
2504                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2505                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2506                                 self.stat_respawn_time *= -1;
2507
2508                         return;
2509                 }
2510
2511                 self.prevorigin = self.origin;
2512
2513                 float do_crouch = self.BUTTON_CROUCH;
2514                 if(self.hook.state)
2515                         do_crouch = 0;
2516                 if(self.vehicle)
2517                         do_crouch = 0;
2518                 if(self.frozen)
2519                         do_crouch = 0;
2520
2521                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2522                 // It cannot be predicted by the engine!
2523                 if((self.weapon == WEP_SHOCKWAVE.m_id || self.weapon == WEP_SHOTGUN.m_id) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2524                         do_crouch = 0;
2525
2526                 if (do_crouch)
2527                 {
2528                         if (!self.crouch)
2529                         {
2530                                 self.crouch = true;
2531                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2532                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2533                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2534                         }
2535                 }
2536                 else
2537                 {
2538                         if (self.crouch)
2539                         {
2540                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2541                                 if (!trace_startsolid)
2542                                 {
2543                                         self.crouch = false;
2544                                         self.view_ofs = self.stat_pl_view_ofs;
2545                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2546                                 }
2547                         }
2548                 }
2549
2550                 FixPlayermodel();
2551
2552                 GrapplingHookFrame();
2553
2554                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2555                 //if(frametime)
2556                 {
2557                         self.items &= ~self.items_added;
2558
2559                         W_WeaponFrame();
2560
2561                         self.items_added = 0;
2562                         if(self.items & ITEM_Jetpack.m_itemid)
2563                                 if(self.items & ITEM_JetpackRegen.m_itemid || self.ammo_fuel >= 0.01)
2564                                         self.items_added |= IT_FUEL;
2565
2566                         self.items |= self.items_added;
2567                 }
2568
2569                 player_regen();
2570
2571                 // WEAPONTODO: Add a weapon request for this
2572                 // rot vortex charge to the charge limit
2573                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2574                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2575
2576                 if(frametime)
2577                         player_anim();
2578
2579                 // secret status
2580                 secrets_setstatus();
2581
2582                 // monsters status
2583                 monsters_setstatus();
2584
2585                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2586
2587                 //self.angles_y=self.v_angle_y + 90;   // temp
2588         } else if(gameover) {
2589                 if (intermission_running)
2590                         IntermissionThink ();   // otherwise a button could be missed between
2591                 return;
2592         } else if(IS_OBSERVER(self)) {
2593                 ObserverThink();
2594         } else if(IS_SPEC(self)) {
2595                 SpectatorThink();
2596         }
2597
2598         // WEAPONTODO: Add weapon request for this
2599         if(!zoomstate_set)
2600                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX.m_id) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE.m_id && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2601
2602         float oldspectatee_status;
2603         oldspectatee_status = self.spectatee_status;
2604         if(IS_SPEC(self))
2605                 self.spectatee_status = num_for_edict(self.enemy);
2606         else if(IS_OBSERVER(self))
2607                 self.spectatee_status = num_for_edict(self);
2608         else
2609                 self.spectatee_status = 0;
2610         if(self.spectatee_status != oldspectatee_status)
2611         {
2612                 ClientData_Touch(self);
2613         }
2614
2615         if(self.teamkill_soundtime)
2616         if(time > self.teamkill_soundtime)
2617         {
2618                 self.teamkill_soundtime = 0;
2619
2620                 entity oldpusher, oldself;
2621
2622                 oldself = self; self = self.teamkill_soundsource;
2623                 oldpusher = self.pusher; self.pusher = oldself;
2624
2625                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2626
2627                 self.pusher = oldpusher;
2628                 self = oldself;
2629         }
2630
2631         if(self.taunt_soundtime)
2632         if(time > self.taunt_soundtime)
2633         {
2634                 self.taunt_soundtime = 0;
2635                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2636         }
2637
2638         target_voicescript_next(self);
2639
2640         // WEAPONTODO: Move into weaponsystem somehow
2641         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2642         if(!self.weapon)
2643                 self.clip_load = self.clip_size = 0;
2644 }
2645
2646 /*
2647 =============
2648 PlayerPostThink
2649
2650 Called every frame for each client after the physics are run
2651 =============
2652 */
2653 .float idlekick_lasttimeleft;
2654 void PlayerPostThink (void)
2655 {
2656         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2657         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2658         {
2659                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2660                 {
2661                         if(self.idlekick_lasttimeleft)
2662                         {
2663                                 self.idlekick_lasttimeleft = 0;
2664                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2665                         }
2666                 }
2667                 else
2668                 {
2669                         float timeleft;
2670                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2671                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2672                         {
2673                                 if(!self.idlekick_lasttimeleft)
2674                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2675                         }
2676                         if(timeleft <= 0)
2677                         {
2678                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2679                                 dropclient(self);
2680                                 return;
2681                         }
2682                         else if(timeleft <= 10)
2683                         {
2684                                 if(timeleft != self.idlekick_lasttimeleft)
2685                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2686                                 self.idlekick_lasttimeleft = timeleft;
2687                         }
2688                 }
2689         }
2690
2691 #ifdef TETRIS
2692         if(self.impulse == 100)
2693                 ImpulseCommands();
2694         if (!TetrisPostFrame())
2695         {
2696 #endif
2697
2698         CheatFrame();
2699
2700         //CheckPlayerJump();
2701
2702         if(IS_PLAYER(self)) {
2703                 CheckRules_Player();
2704                 UpdateChatBubble();
2705                 if (self.impulse)
2706                         ImpulseCommands();
2707                 if (intermission_running)
2708                         return;         // intermission or finale
2709                 GetPressedKeys();
2710         }
2711
2712 #ifdef TETRIS
2713         }
2714 #endif
2715
2716         /*
2717         float i;
2718         for(i = 0; i < 1000; ++i)
2719         {
2720                 vector end;
2721                 end = self.origin + '0 0 1024' + 512 * randomvec();
2722                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2723                 if(trace_fraction < 1)
2724                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2725                 {
2726                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2727                         break;
2728                 }
2729         }
2730         */
2731
2732         if(self.waypointsprite_attachedforcarrier)
2733                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2734
2735         playerdemo_write();
2736
2737         CSQCMODEL_AUTOUPDATE();
2738 }