qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teamplay)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck >= 0)
 136                 if(spot.team != teamcheck)
 137                         return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(autocvar_spawn_debugview)
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck >= 0)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck >= 0)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         if(anypoint)
 329                 teamcheck = -1;
 330         else if(have_team_spawns > 0)
 331         {
 332                 if(have_team_spawns_forteam[self.team] == 0)
 333                 {
 334                         // we request a spawn for a team, and we have team
 335                         // spawns, but that team has no spawns?
 336                         if(have_team_spawns_forteam[0])
 337                                 // try noteam spawns
 338                                 teamcheck = 0;
 339                         else
 340                                 // if not, any spawn has to do
 341                                 teamcheck = -1;
 342                 }
 343                 else
 344                         teamcheck = self.team; // MUST be team
 345         }
 346         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 347                 teamcheck = 0; // MUST be noteam
 348         else
 349                 teamcheck = -1;
 350                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 351
 352
 353         // get the list of players
 354         playerlist = findchain(classname, "player");
 355         // get the entire list of spots
 356         firstspot = findchain(classname, "info_player_deathmatch");
 357         // filter out the bad ones
 358         // (note this returns the original list if none survived)
 359         if(anypoint)
 360         {
 361                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362         }
 363         else
 364         {
 365                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 366                 if(!firstspot_new)
 367                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 368                 firstspot = firstspot_new;
 369
 370                 // there is 50/50 chance of choosing a random spot or the furthest spot
 371                 // (this means that roughly every other spawn will be furthest, so you
 372                 // usually won't get fragged at spawn twice in a row)
 373                 if (arena_roundbased && !g_ca)
 374                 {
 375                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 376                         if(firstspot_new)
 377                                 firstspot = firstspot_new;
 378                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 379                 }
 380                 else if (random() > autocvar_g_spawn_furthest)
 381                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 382                 else
 383                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 384         }
 385
 386         if(autocvar_spawn_debugview)
 387         {
 388                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 389
 390                 entity e;
 391                 if(teamcheck >= 0)
 392                         for(e = firstspot; e; e = e.chain)
 393                                 if(e.team != teamcheck)
 394                                         error("invalid spawn found");
 395         }
 396
 397         if (!spot)
 398         {
 399                 if(autocvar_spawn_debug)
 400                         GotoNextMap();
 401                 else
 402                 {
 403                         if(some_spawn_has_been_used)
 404                                 return world; // team can't spawn any more, because of actions of other team
 405                         else
 406                                 error("Cannot find a spawn point - please fix the map!");
 407                 }
 408         }
 409
 410         return spot;
 411 }
 412
 413 /*
 414 =============
 415 CheckPlayerModel
 416
 417 Checks if the argument string can be a valid playermodel.
 418 Returns a valid one in doubt.
 419 =============
 420 */
 421 string FallbackPlayerModel;
 422 string CheckPlayerModel(string plyermodel) {
 423         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 424         {
 425                 // note: we cannot summon Don Strunzone here, some player may
 426                 // still have the model string set. In case anyone manages how
 427                 // to change a cvar default, we'll have a small leak here.
 428                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 429         }
 430         if(strlen(plyermodel) < 4)
 431                 return FallbackPlayerModel;
 432         if( substring(plyermodel,0,14) != "models/player/")
 433                 return FallbackPlayerModel;
 434         else if(autocvar_sv_servermodelsonly)
 435         {
 436                 if(substring(plyermodel,-4,4) != ".zym")
 437                 if(substring(plyermodel,-4,4) != ".dpm")
 438                 if(substring(plyermodel,-4,4) != ".iqm")
 439                 if(substring(plyermodel,-4,4) != ".md3")
 440                 if(substring(plyermodel,-4,4) != ".psk")
 441                         return FallbackPlayerModel;
 442                 // forbid the LOD models
 443                 if(substring(plyermodel, -9,5) == "_lod1")
 444                         return FallbackPlayerModel;
 445                 if(substring(plyermodel, -9,5) == "_lod2")
 446                         return FallbackPlayerModel;
 447                 if(plyermodel != strtolower(plyermodel))
 448                         return FallbackPlayerModel;
 449                 if(!fexists(plyermodel))
 450                         return FallbackPlayerModel;
 451         }
 452         return plyermodel;
 453 }
 454
 455 /*
 456 =============
 457 Client_customizeentityforclient
 458
 459 LOD reduction
 460 =============
 461 */
 462 void Client_uncustomizeentityforclient()
 463 {
 464         if(self.modelindex == 0) // no need to uncustomize then
 465                 return;
 466         self.modelindex = self.modelindex_lod0;
 467         self.skin = self.skinindex;
 468 }
 469
 470 float Client_customizeentityforclient()
 471 {
 472         entity modelsource;
 473
 474         if(self.modelindex == 0)
 475                 return TRUE;
 476
 477         // forcemodel stuff
 478
 479 #ifdef PROFILING
 480         float t0;
 481         t0 = gettime(GETTIME_HIRES); // reference
 482 #endif
 483
 484         modelsource = self;
 485
 486 #ifdef ALLOW_FORCEMODELS
 487         if(other.cvar_cl_forceplayermodelsfromxonotic)
 488                 if not(self.modelindex_lod0_from_xonotic)
 489                         modelsource = other;
 490         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 491                 modelsource = other;
 492 #endif
 493
 494         self.skin = modelsource.skinindex;
 495
 496 #if 0
 497         if(modelsource == self)
 498                 self.skin = modelsource.skinindex;
 499         else
 500                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 501 #endif
 502
 503         // self: me
 504         // other: the player viewing me
 505         float distance;
 506         float f;
 507
 508         if(other.cvar_cl_playerdetailreduction <= 0)
 509         {
 510                 if(other.cvar_cl_playerdetailreduction <= -2)
 511                         self.modelindex = modelsource.modelindex_lod2;
 512                 else if(other.cvar_cl_playerdetailreduction <= -1)
 513                         self.modelindex = modelsource.modelindex_lod1;
 514                 else
 515                         self.modelindex = modelsource.modelindex_lod0;
 516         }
 517         else
 518         {
 519                 distance = vlen(self.origin - other.origin);
 520                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 521                 if(f > sv_loddistance2)
 522                         self.modelindex = modelsource.modelindex_lod2;
 523                 else if(f > sv_loddistance1)
 524                         self.modelindex = modelsource.modelindex_lod1;
 525                 else
 526                         self.modelindex = modelsource.modelindex_lod0;
 527         }
 528
 529 #ifdef PROFILING
 530         float t1;
 531         t1 = gettime(GETTIME_HIRES); // reference
 532         client_cefc_accumulator += (t1 - t0);
 533 #endif
 534
 535         return TRUE;
 536 }
 537
 538 void setmodel_lod(entity e, string modelname)
 539 {
 540         string s;
 541
 542         if(sv_loddistance1)
 543         {
 544                 // FIXME: this only supports 3-letter extensions
 545                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 546                 if(fexists(s))
 547                 {
 548                         setmodel(e, s); // players have high precision
 549                         self.modelindex_lod1 = self.modelindex;
 550                 }
 551                 else
 552                         self.modelindex_lod1 = -1;
 553
 554                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 555                 if(fexists(s))
 556                 {
 557                         setmodel(e, s); // players have high precision
 558                         self.modelindex_lod2 = self.modelindex;
 559                 }
 560                 else
 561                         self.modelindex_lod2 = -1;
 562
 563                 precache_model(modelname);
 564                 setmodel(e, modelname); // players have high precision
 565                 self.modelindex_lod0 = self.modelindex;
 566
 567                 if(self.modelindex_lod1 < 0)
 568                         self.modelindex_lod1 = self.modelindex;
 569
 570                 if(self.modelindex_lod2 < 0)
 571                         self.modelindex_lod2 = self.modelindex;
 572         }
 573         else
 574         {
 575                 precache_model(modelname);
 576                 setmodel(e, modelname); // players have high precision
 577                 self.modelindex_lod0 = self.modelindex;
 578                         // save it for possible player model forcing
 579         }
 580
 581         s = whichpack(self.model);
 582         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 583
 584         player_setupanimsformodel();
 585         UpdatePlayerSounds();
 586 }
 587
 588 /*
 589 =============
 590 PutObserverInServer
 591
 592 putting a client as observer in the server
 593 =============
 594 */
 595 void FixPlayermodel();
 596 void PutObserverInServer (void)
 597 {
 598         entity  spot;
 599     self.hud = HUD_NORMAL;
 600         race_PreSpawnObserver();
 601
 602         spot = SelectSpawnPoint (TRUE);
 603         if(!spot)
 604                 error("No spawnpoints for observers?!?\n");
 605         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 606
 607         if(clienttype(self) == CLIENTTYPE_REAL)
 608         {
 609                 msg_entity = self;
 610                 WriteByte(MSG_ONE, SVC_SETVIEW);
 611                 WriteEntity(MSG_ONE, self);
 612         }
 613
 614         DropAllRunes(self);
 615         MUTATOR_CALLHOOK(MakePlayerObserver);
 616
 617         Portal_ClearAll(self);
 618
 619         if(self.alivetime)
 620         {
 621                 PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 622                 self.alivetime = 0;
 623         }
 624
 625         if(self.vehicle)
 626             vehicles_exit(VHEF_RELESE);
 627
 628         if(self.flagcarried)
 629                 DropFlag(self.flagcarried, world, world);
 630
 631         if(self.ballcarried && g_nexball)
 632                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 633
 634         WaypointSprite_PlayerDead();
 635
 636         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 637                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 638
 639         if(self.killcount != -666) {
 640                 if(g_lms) {
 641                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 642                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 643                         else
 644                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 645                 } else
 646                         bprint ("^4", self.netname, "^4 is spectating now\n");
 647
 648                 if(self.just_joined == FALSE) {
 649                         LogTeamchange(self.playerid, -1, 4);
 650                 } else
 651                         self.just_joined = FALSE;
 652         }
 653
 654         PlayerScore_Clear(self); // clear scores when needed
 655
 656         accuracy_resend(self);
 657
 658         self.spectatortime = time;
 659
 660         self.classname = "observer";
 661         self.iscreature = FALSE;
 662         self.health = -666;
 663         self.takedamage = DAMAGE_NO;
 664         self.solid = SOLID_NOT;
 665         self.movetype = MOVETYPE_NOCLIP;
 666         self.flags = FL_CLIENT | FL_NOTARGET;
 667         self.armorvalue = 666;
 668         self.effects = 0;
 669         self.armorvalue = autocvar_g_balance_armor_start;
 670         self.pauserotarmor_finished = 0;
 671         self.pauserothealth_finished = 0;
 672         self.pauseregen_finished = 0;
 673         self.damageforcescale = 0;
 674         self.death_time = 0;
 675         self.dead_frame = 0;
 676         self.alpha = 0;
 677         self.scale = 0;
 678         self.fade_time = 0;
 679         self.pain_frame = 0;
 680         self.pain_finished = 0;
 681         self.strength_finished = 0;
 682         self.invincible_finished = 0;
 683         self.pushltime = 0;
 684         self.think = SUB_Null;
 685         self.nextthink = 0;
 686         self.hook_time = 0;
 687         self.runes = 0;
 688         self.deadflag = DEAD_NO;
 689         self.angles = spot.angles;
 690         self.angles_z = 0;
 691         self.fixangle = TRUE;
 692         self.crouch = FALSE;
 693
 694         self.view_ofs = PL_VIEW_OFS;
 695         setorigin (self, spot.origin);
 696         setsize (self, '0 0 0', '0 0 0');
 697         self.prevorigin = self.origin;
 698         self.items = 0;
 699         self.weapons = 0;
 700         self.model = "";
 701         FixPlayermodel();
 702         self.model = "";
 703         self.modelindex = 0;
 704         self.weapon = 0;
 705         self.weaponmodel = "";
 706         self.weaponentity = world;
 707         self.exteriorweaponentity = world;
 708         self.killcount = -666;
 709         self.velocity = '0 0 0';
 710         self.avelocity = '0 0 0';
 711         self.punchangle = '0 0 0';
 712         self.punchvector = '0 0 0';
 713         self.oldvelocity = self.velocity;
 714         self.fire_endtime = -1;
 715
 716         if(sv_loddistance1)
 717                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 718
 719         if(g_arena)
 720         {
 721                 if(self.version_mismatch)
 722                 {
 723                         Spawnqueue_Unmark(self);
 724                         Spawnqueue_Remove(self);
 725                 }
 726                 else
 727                 {
 728                         Spawnqueue_Insert(self);
 729                 }
 730         }
 731         else if(g_lms)
 732         {
 733                 // Only if the player cannot play at all
 734                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 735                         self.frags = FRAGS_SPECTATOR;
 736                 else
 737                         self.frags = FRAGS_LMS_LOSER;
 738         }
 739         else
 740                 self.frags = FRAGS_SPECTATOR;
 741 }
 742
 743 void FixPlayermodel()
 744 {
 745         local string defaultmodel;
 746         local float defaultskin, chmdl, oldskin;
 747         local vector m1, m2;
 748
 749         defaultmodel = "";
 750
 751         if(autocvar_sv_defaultcharacter == 1) {
 752                 defaultskin = 0;
 753
 754                 if(teamplay)
 755                 {
 756                         string s;
 757                         s = Team_ColorNameLowerCase(self.team);
 758                         if(s != "neutral")
 759                         {
 760                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 761                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 762                         }
 763                 }
 764
 765                 if(defaultmodel == "")
 766                 {
 767                         defaultmodel = autocvar_sv_defaultplayermodel;
 768                         defaultskin = autocvar_sv_defaultplayerskin;
 769                 }
 770         }
 771
 772         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 773         {
 774                 if(self.model != "")
 775                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 776                 self.model = ""; // force the != checks to return true
 777         }
 778
 779         if(defaultmodel != "")
 780         {
 781                 if (defaultmodel != self.model)
 782                 {
 783                         m1 = self.mins;
 784                         m2 = self.maxs;
 785                         setmodel_lod (self, defaultmodel);
 786                         setsize (self, m1, m2);
 787                         chmdl = TRUE;
 788                 }
 789
 790                 oldskin = self.skinindex;
 791                 self.skinindex = defaultskin;
 792         } else {
 793                 if (self.playermodel != self.model || self.playermodel == "")
 794                 {
 795                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 796                         m1 = self.mins;
 797                         m2 = self.maxs;
 798                         setmodel_lod (self, self.playermodel);
 799                         setsize (self, m1, m2);
 800                         chmdl = TRUE;
 801                 }
 802
 803                 oldskin = self.skinindex;
 804                 self.skinindex = stof(self.playerskin);
 805         }
 806
 807         if(chmdl || oldskin != self.skinindex)
 808                 self.species = player_getspecies(); // model or skin has changed
 809
 810         if(!teamplay)
 811                 if(strlen(autocvar_sv_defaultplayercolors))
 812                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 813                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 814 }
 815
 816 void PlayerTouchExplode(entity p1, entity p2)
 817 {
 818         vector org;
 819         org = (p1.origin + p2.origin) * 0.5;
 820         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 821
 822         te_explosion(org);
 823
 824         entity e;
 825         e = spawn();
 826         setorigin(e, org);
 827         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 828         remove(e);
 829 }
 830
 831 /*
 832 =============
 833 PutClientInServer
 834
 835 Called when a client spawns in the server
 836 =============
 837 */
 838 //void() ctf_playerchanged;
 839 void PutClientInServer (void)
 840 {
 841         if(clienttype(self) == CLIENTTYPE_BOT)
 842         {
 843                 self.classname = "player";
 844         }
 845         else if(clienttype(self) == CLIENTTYPE_REAL)
 846         {
 847                 msg_entity = self;
 848                 WriteByte(MSG_ONE, SVC_SETVIEW);
 849                 WriteEntity(MSG_ONE, self);
 850         }
 851
 852         // player is dead and becomes observer
 853         // FIXME fix LMS scoring for new system
 854         if(g_lms)
 855         {
 856                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 857                         self.classname = "observer";
 858         }
 859
 860         if(g_arena || (g_ca && !allowed_to_spawn))
 861         if(!self.spawned)
 862                 self.classname = "observer";
 863
 864         if(gameover)
 865                 self.classname = "observer";
 866
 867         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 868                 entity spot, oldself;
 869                 float j;
 870
 871                 accuracy_resend(self);
 872
 873                 if(self.team < 0)
 874                         JoinBestTeam(self, FALSE, TRUE);
 875
 876                 race_PreSpawn();
 877
 878                 spot = SelectSpawnPoint (FALSE);
 879                 if(!spot)
 880                 {
 881                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 882                         return; // spawn failed
 883                 }
 884
 885                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 886
 887                 self.classname = "player";
 888                 self.wasplayer = TRUE;
 889                 self.iscreature = TRUE;
 890                 self.movetype = MOVETYPE_WALK;
 891                 self.solid = SOLID_SLIDEBOX;
 892                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 893                 if(autocvar_g_playerclip_collisions)
 894                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 895                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 896                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 897                 self.frags = FRAGS_PLAYER;
 898                 if(independent_players)
 899                         MAKE_INDEPENDENT_PLAYER(self);
 900                 self.flags = FL_CLIENT;
 901                 self.takedamage = DAMAGE_AIM;
 902                 if(g_minstagib)
 903                         self.effects = EF_FULLBRIGHT;
 904                 else
 905                         self.effects = 0;
 906                 self.air_finished = time + 12;
 907                 self.dmg = 2;
 908                 if(autocvar_g_balance_nex_charge)
 909                 {
 910                         if(autocvar_g_balance_nex_secondary_chargepool)
 911                                 self.nex_chargepool_ammo = 1;
 912                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 913                 }
 914
 915                 if(inWarmupStage)
 916                 {
 917                         self.ammo_shells = warmup_start_ammo_shells;
 918                         self.ammo_nails = warmup_start_ammo_nails;
 919                         self.ammo_rockets = warmup_start_ammo_rockets;
 920                         self.ammo_cells = warmup_start_ammo_cells;
 921                         self.ammo_fuel = warmup_start_ammo_fuel;
 922                         self.health = warmup_start_health;
 923                         self.armorvalue = warmup_start_armorvalue;
 924                         self.weapons = warmup_start_weapons;
 925                 }
 926                 else
 927                 {
 928                         self.ammo_shells = start_ammo_shells;
 929                         self.ammo_nails = start_ammo_nails;
 930                         self.ammo_rockets = start_ammo_rockets;
 931                         self.ammo_cells = start_ammo_cells;
 932                         self.ammo_fuel = start_ammo_fuel;
 933                         self.health = start_health;
 934                         self.armorvalue = start_armorvalue;
 935                         self.weapons = start_weapons;
 936                 }
 937
 938                 if(g_weaponarena_random)
 939                 {
 940                         if(g_weaponarena_random_with_laser)
 941                                 self.weapons &~= WEPBIT_LASER;
 942                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 943                         if(g_weaponarena_random_with_laser)
 944                                 self.weapons |= WEPBIT_LASER;
 945                 }
 946
 947                 self.items = start_items;
 948                 self.jump_interval = time;
 949
 950                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 951                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 952                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 953                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 954                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 955                 //extend the pause of rotting if client was reset at the beginning of the countdown
 956                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 957                         self.spawnshieldtime += game_starttime - time;
 958                         self.pauserotarmor_finished += game_starttime - time;
 959                         self.pauserothealth_finished += game_starttime - time;
 960                         self.pauseregen_finished += game_starttime - time;
 961                 }
 962                 self.damageforcescale = 2;
 963                 self.death_time = 0;
 964                 self.dead_frame = 0;
 965                 self.alpha = 0;
 966                 self.scale = 0;
 967                 self.fade_time = 0;
 968                 self.pain_frame = 0;
 969                 self.pain_finished = 0;
 970                 self.strength_finished = 0;
 971                 self.invincible_finished = 0;
 972                 self.pushltime = 0;
 973                 // players have no think function
 974                 self.think = SUB_Null;
 975                 self.nextthink = 0;
 976                 self.hook_time = 0;
 977                 self.dmg_team = 0;
 978                 self.ballistics_density = autocvar_g_ballistics_density_player;
 979
 980                 self.metertime = 0;
 981
 982                 self.runes = 0;
 983
 984                 self.deadflag = DEAD_NO;
 985
 986                 self.angles = spot.angles;
 987
 988                 self.angles_z = 0; // never spawn tilted even if the spot says to
 989                 self.fixangle = TRUE; // turn this way immediately
 990                 self.velocity = '0 0 0';
 991                 self.avelocity = '0 0 0';
 992                 self.punchangle = '0 0 0';
 993                 self.punchvector = '0 0 0';
 994                 self.oldvelocity = self.velocity;
 995                 self.fire_endtime = -1;
 996
 997                 msg_entity = self;
 998                 WRITESPECTATABLE_MSG_ONE({
 999                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1000                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
1001                 });
1002
1003                 if(sv_loddistance1)
1004                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
1005
1006                 self.model = "";
1007                 FixPlayermodel();
1008
1009                 self.crouch = FALSE;
1010                 self.view_ofs = PL_VIEW_OFS;
1011                 setsize (self, PL_MIN, PL_MAX);
1012                 self.spawnorigin = spot.origin;
1013                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
1014                 // don't reset back to last position, even if new position is stuck in solid
1015                 self.oldorigin = self.origin;
1016                 self.prevorigin = self.origin;
1017                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
1018                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
1019
1020                 if(g_arena)
1021                 {
1022                         Spawnqueue_Remove(self);
1023                         Spawnqueue_Mark(self);
1024                 }
1025
1026                 else if(g_ca)
1027                         self.caplayer = 1;
1028
1029                 self.event_damage = PlayerDamage;
1030
1031                 self.bot_attack = TRUE;
1032
1033                 self.statdraintime = time + 5;
1034                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
1035
1036                 if(self.killcount == -666) {
1037                         PlayerScore_Clear(self);
1038                         self.killcount = 0;
1039                 }
1040
1041                 self.cnt = WEP_LASER;
1042
1043                 CL_SpawnWeaponentity();
1044                 self.alpha = default_player_alpha;
1045                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
1046                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1047
1048                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
1049                 self.lms_traveled_distance = 0;
1050                 self.speedrunning = FALSE;
1051
1052                 race_PostSpawn(spot);
1053
1054                 if(autocvar_spawn_debug)
1055                 {
1056                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1057                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1058                 }
1059
1060                 //stuffcmd(self, "chase_active 0");
1061                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1062
1063                 if (autocvar_g_spawnsound)
1064                         sound (self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1065
1066                 if(g_assault) {
1067                         if(self.team == assault_attacker_team)
1068                                 centerprint(self, "You are attacking!");
1069                         else
1070                                 centerprint(self, "You are defending!");
1071                 }
1072
1073                 target_voicescript_clear(self);
1074
1075                 // reset fields the weapons may use
1076                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1077                 {
1078                         weapon_action(j, WR_RESETPLAYER);
1079
1080                         // all weapons must be fully loaded when we spawn
1081                         entity e;
1082                         e = get_weaponinfo(j);
1083                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
1084                                 self.weapon_load[j] = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
1085                 }
1086                 self.weapon_forbidchange = FALSE;
1087
1088                 oldself = self;
1089                 self = spot;
1090                         activator = oldself;
1091                                 string s;
1092                                 s = self.target;
1093                                 self.target = string_null;
1094                                 SUB_UseTargets();
1095                                 self.target = s;
1096                         activator = world;
1097                 self = oldself;
1098
1099                 MUTATOR_CALLHOOK(PlayerSpawn);
1100
1101                 self.switchweapon = w_getbestweapon(self);
1102                 self.cnt = self.switchweapon;
1103                 self.weapon = 0;
1104
1105                 if(!self.alivetime)
1106                         self.alivetime = time;
1107         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1108                 PutObserverInServer ();
1109         }
1110
1111         //if(g_ctf)
1112         //      ctf_playerchanged();
1113 }
1114
1115 .float ebouncefactor, ebouncestop; // electro's values
1116 // TODO do we need all these fields, or should we stop autodetecting runtime
1117 // changes and just have a console command to update this?
1118 float ClientInit_SendEntity(entity to, float sf)
1119 {
1120         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1121         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1122         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1123         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1124         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1125         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1126         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1127         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1128         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1129         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1130         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1131         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1132         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1133         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1134         if(sv_foginterval && world.fog != "")
1135                 WriteString(MSG_ENTITY, world.fog);
1136         else
1137                 WriteString(MSG_ENTITY, "");
1138         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1139         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1140         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
1141         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
1142         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
1143         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
1144         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
1145         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
1146         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
1147         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
1148         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
1149         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
1150         return TRUE;
1151 }
1152
1153 void ClientInit_CheckUpdate()
1154 {
1155         self.nextthink = time;
1156         if(self.count != autocvar_g_balance_armor_blockpercent)
1157         {
1158                 self.count = autocvar_g_balance_armor_blockpercent;
1159                 self.SendFlags |= 1;
1160         }
1161         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
1162         {
1163                 self.cnt = autocvar_g_balance_weaponswitchdelay;
1164                 self.SendFlags |= 1;
1165         }
1166         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
1167         {
1168                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
1169                 self.SendFlags |= 1;
1170         }
1171         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
1172         {
1173                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
1174                 self.SendFlags |= 1;
1175         }
1176         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
1177         {
1178                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
1179                 self.SendFlags |= 1;
1180         }
1181         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
1182         {
1183                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
1184                 self.SendFlags |= 1;
1185         }
1186 }
1187
1188 void ClientInit_Spawn()
1189 {
1190         entity o;
1191         entity e;
1192         e = spawn();
1193         e.classname = "clientinit";
1194         e.think = ClientInit_CheckUpdate;
1195         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1196
1197         o = self;
1198         self = e;
1199         ClientInit_CheckUpdate();
1200         self = o;
1201 }
1202
1203 /*
1204 =============
1205 SetNewParms
1206 =============
1207 */
1208 void SetNewParms (void)
1209 {
1210         // initialize parms for a new player
1211         parm1 = -(86400 * 366);
1212 }
1213
1214 /*
1215 =============
1216 SetChangeParms
1217 =============
1218 */
1219 void SetChangeParms (void)
1220 {
1221         // save parms for level change
1222         parm1 = self.parm_idlesince - time;
1223 }
1224
1225 /*
1226 =============
1227 DecodeLevelParms
1228 =============
1229 */
1230 void DecodeLevelParms (void)
1231 {
1232         // load parms
1233         self.parm_idlesince = parm1;
1234         if(self.parm_idlesince == -(86400 * 366))
1235                 self.parm_idlesince = time;
1236
1237         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1238         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1239 }
1240
1241 /*
1242 =============
1243 ClientKill
1244
1245 Called when a client types 'kill' in the console
1246 =============
1247 */
1248
1249 .float clientkill_nexttime;
1250 void ClientKill_Now_TeamChange()
1251 {
1252         if(self.killindicator_teamchange == -1)
1253         {
1254                 self.team = -1;
1255                 JoinBestTeam( self, FALSE, FALSE );
1256         }
1257         else if(self.killindicator_teamchange == -2)
1258         {
1259                 if(g_ca)
1260                         self.caplayer = 0;
1261                 if(blockSpectators)
1262                         sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1263                 PutObserverInServer();
1264         }
1265         else
1266                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1267 }
1268
1269 void ClientKill_Now()
1270 {
1271         if(self.vehicle)
1272         {
1273             vehicles_exit(VHEF_RELESE);
1274             if(!self.killindicator_teamchange)
1275             {
1276             self.vehicle_health = -1;
1277             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1278             }
1279         }
1280
1281         if(self.killindicator && !wasfreed(self.killindicator))
1282                 remove(self.killindicator);
1283
1284         self.killindicator = world;
1285
1286         if(self.killindicator_teamchange)
1287                 ClientKill_Now_TeamChange();
1288
1289         // in any case:
1290         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1291
1292         // now I am sure the player IS dead
1293 }
1294 void KillIndicator_Think()
1295 {
1296         if (gameover)
1297         {
1298                 if (self.owner.killindicator)
1299                 {
1300                         remove(self.owner.killindicator);
1301                         self.owner.killindicator = world;
1302                 }
1303                 return;
1304         }
1305
1306         if (!self.owner.modelindex)
1307         {
1308                 self.owner.killindicator = world;
1309                 remove(self);
1310                 return;
1311         }
1312
1313         if(self.cnt <= 0)
1314         {
1315                 self = self.owner;
1316                 ClientKill_Now(); // no oldself needed
1317                 return;
1318         }
1319     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1320     {
1321         self.nextthink = time + 1;
1322         self.cnt -= 1;
1323     }
1324         else
1325         {
1326                 if(self.cnt <= 10)
1327                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1328                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1329                 {
1330                         if(self.cnt <= 10)
1331                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1332                         if(self.owner.killindicator_teamchange)
1333                         {
1334                                 if(self.owner.killindicator_teamchange == -1)
1335                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1336                                 else if(self.owner.killindicator_teamchange == -2)
1337                                         centerprint(self.owner, strcat("Spectating in ", ftos(self.cnt), " seconds"));
1338                                 else
1339                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1340                         }
1341                         else
1342                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1343                 }
1344                 self.nextthink = time + 1;
1345                 self.cnt -= 1;
1346         }
1347 }
1348
1349 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1350 {
1351         float killtime;
1352         entity e;
1353
1354         if (gameover)
1355         {
1356                 if (self.killindicator)
1357                 {
1358                         remove(self.killindicator);
1359                         self.killindicator = world;
1360                 }
1361                 return;
1362         }
1363
1364         killtime = autocvar_g_balance_kill_delay;
1365
1366         if(g_race_qualifying || g_cts)
1367                 killtime = 0;
1368
1369     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1370     {
1371                 remove(self.killindicator);
1372                 self.killindicator = world;
1373
1374         ClientKill_Now(); // allow instant kill in this case
1375         return;
1376     }
1377
1378         self.killindicator_teamchange = targetteam;
1379
1380     if(!self.killindicator)
1381         {
1382                 if(self.modelindex && self.deadflag == DEAD_NO)
1383                 {
1384                         killtime = max(killtime, self.clientkill_nexttime - time);
1385                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1386                 }
1387
1388                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1389                 {
1390                         ClientKill_Now();
1391                 }
1392                 else
1393                 {
1394                         self.killindicator = spawn();
1395                         self.killindicator.owner = self;
1396                         self.killindicator.scale = 0.5;
1397                         setattachment(self.killindicator, self, "");
1398                         setorigin(self.killindicator, '0 0 52');
1399                         self.killindicator.think = KillIndicator_Think;
1400                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1401                         self.killindicator.cnt = ceil(killtime);
1402                         self.killindicator.count = bound(0, ceil(killtime), 10);
1403                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1404
1405                         for(e = world; (e = find(e, classname, "body")) != world; )
1406                         {
1407                                 if(e.enemy != self)
1408                                         continue;
1409                                 e.killindicator = spawn();
1410                                 e.killindicator.owner = e;
1411                                 e.killindicator.scale = 0.5;
1412                                 setattachment(e.killindicator, e, "");
1413                                 setorigin(e.killindicator, '0 0 52');
1414                                 e.killindicator.think = KillIndicator_Think;
1415                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1416                                 e.killindicator.cnt = ceil(killtime);
1417                         }
1418                         self.lip = 0;
1419                 }
1420         }
1421         if(self.killindicator)
1422         {
1423                 if(targetteam == 0) // just die
1424                         self.killindicator.colormod = '0 0 0';
1425                 else if(targetteam == -1) // auto
1426                         self.killindicator.colormod = '0 1 0';
1427                 else if(targetteam == -2) // spectate
1428                         self.killindicator.colormod = '0.5 0.5 0.5';
1429                 else
1430                         self.killindicator.colormod = TeamColor(targetteam);
1431         }
1432 }
1433
1434 void ClientKill (void)
1435 {
1436         if (gameover)
1437                 return;
1438
1439         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1440         {
1441                 // do nothing
1442         }
1443     else if(self.freezetag_frozen)
1444     {
1445         // do nothing
1446     }
1447         else
1448                 ClientKill_TeamChange(0);
1449 }
1450
1451 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1452 {
1453     e.killindicator = spawn();
1454     e.killindicator.owner = e;
1455     e.killindicator.think = KillIndicator_Think;
1456     e.killindicator.nextthink = time + (e.lip) * 0.05;
1457     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1458     e.killindicator.health = 1; // this is used to indicate that it should be silent
1459     e.lip = 0;
1460 }
1461
1462 void DoTeamChange(float destteam)
1463 {
1464         float t, c0;
1465
1466         if (gameover)
1467         {
1468                 if (self.killindicator)
1469                 {
1470                         remove(self.killindicator);
1471                         self.killindicator = world;
1472                 }
1473                 return;
1474         }
1475
1476         if(!teamplay)
1477         {
1478                 if(destteam >= 0)
1479                         SetPlayerColors(self, destteam);
1480                 return;
1481         }
1482
1483         if(self.classname == "player")
1484         if(destteam == -1)
1485         {
1486                 CheckAllowedTeams(self);
1487                 t = FindSmallestTeam(self, TRUE);
1488                 switch(self.team)
1489                 {
1490                         case COLOR_TEAM1: c0 = c1; break;
1491                         case COLOR_TEAM2: c0 = c2; break;
1492                         case COLOR_TEAM3: c0 = c3; break;
1493                         case COLOR_TEAM4: c0 = c4; break;
1494                         default:          c0 = 999;
1495                 }
1496                 switch(t)
1497                 {
1498                         case 1:
1499                                 if(c0 > c1)
1500                                         destteam = COLOR_TEAM1;
1501                                 break;
1502                         case 2:
1503                                 if(c0 > c2)
1504                                         destteam = COLOR_TEAM2;
1505                                 break;
1506                         case 3:
1507                                 if(c0 > c3)
1508                                         destteam = COLOR_TEAM3;
1509                                 break;
1510                         case 4:
1511                                 if(c0 > c4)
1512                                         destteam = COLOR_TEAM4;
1513                                 break;
1514                 }
1515                 if(destteam == -1)
1516                         return;
1517         }
1518         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1519                 return;
1520         ClientKill_TeamChange(destteam);
1521 }
1522
1523 void FixClientCvars(entity e)
1524 {
1525         // send prediction settings to the client
1526         stuffcmd(e, "\nin_bindmap 0 0\n");
1527         if(g_race || g_cts)
1528                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1529         if(autocvar_g_antilag == 3) // client side hitscan
1530                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1531         if(sv_gentle)
1532                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1533         /*
1534          * we no longer need to stuff this. Remove this comment block if you feel
1535          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1536         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1537         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1538         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1539         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1540         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1541         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1542         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1543         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1544         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1545         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1546         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1547         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1548         stuffcmd(e, "cl_movement_edgefriction 1\n");
1549          */
1550 }
1551
1552 float PlayerInIDList(entity p, string idlist)
1553 {
1554         float n, i;
1555         string s;
1556
1557         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1558         if not(p.crypto_idfp)
1559                 return 0;
1560
1561         // this function allows abbreviated player IDs too!
1562         n = tokenize_console(idlist);
1563         for(i = 0; i < n; ++i)
1564         {
1565                 s = argv(i);
1566                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1567                         return 1;
1568         }
1569
1570         return 0;
1571 }
1572
1573 /*
1574 =============
1575 ClientConnect
1576
1577 Called when a client connects to the server
1578 =============
1579 */
1580 //void ctf_clientconnect();
1581 string ColoredTeamName(float t);
1582 void DecodeLevelParms (void);
1583 //void dom_player_join_team(entity pl);
1584 void set_dom_state(entity e);
1585 void ClientConnect (void)
1586 {
1587         float t;
1588
1589         if(self.flags & FL_CLIENT)
1590         {
1591                 print("Warning: ClientConnect, but already connected!\n");
1592                 return;
1593         }
1594
1595         if(Ban_MaybeEnforceBan(self))
1596                 return;
1597
1598         DecodeLevelParms();
1599
1600 #ifdef WATERMARK
1601         sprint(self, strcat("^4SVQC Build information: ^1", WATERMARK(), "\n"));
1602 #endif
1603
1604         self.classname = "player_joining";
1605
1606         self.flags = FL_CLIENT;
1607         self.version_nagtime = time + 10 + random() * 10;
1608
1609         if(player_count<0)
1610         {
1611                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1612                 player_count = 0;
1613         }
1614
1615         PlayerScore_Attach(self);
1616         ClientData_Attach();
1617         accuracy_init(self);
1618
1619         bot_clientconnect();
1620
1621         playerdemo_init();
1622
1623         anticheat_init();
1624
1625         race_PreSpawnObserver();
1626
1627         //if(g_domination)
1628         //      dom_player_join_team(self);
1629
1630         // identify the right forced team
1631         if(autocvar_g_campaign)
1632         {
1633                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1634                 {
1635                         switch(autocvar_g_campaign_forceteam)
1636                         {
1637                                 case 1: self.team_forced = COLOR_TEAM1; break;
1638                                 case 2: self.team_forced = COLOR_TEAM2; break;
1639                                 case 3: self.team_forced = COLOR_TEAM3; break;
1640                                 case 4: self.team_forced = COLOR_TEAM4; break;
1641                                 default: self.team_forced = 0;
1642                         }
1643                 }
1644         }
1645         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1646                 self.team_forced = COLOR_TEAM1;
1647         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1648                 self.team_forced = COLOR_TEAM2;
1649         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1650                 self.team_forced = COLOR_TEAM3;
1651         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1652                 self.team_forced = COLOR_TEAM4;
1653         else if(autocvar_g_forced_team_otherwise == "red")
1654                 self.team_forced = COLOR_TEAM1;
1655         else if(autocvar_g_forced_team_otherwise == "blue")
1656                 self.team_forced = COLOR_TEAM2;
1657         else if(autocvar_g_forced_team_otherwise == "yellow")
1658                 self.team_forced = COLOR_TEAM3;
1659         else if(autocvar_g_forced_team_otherwise == "pink")
1660                 self.team_forced = COLOR_TEAM4;
1661         else if(autocvar_g_forced_team_otherwise == "spectate")
1662                 self.team_forced = -1;
1663         else if(autocvar_g_forced_team_otherwise == "spectator")
1664                 self.team_forced = -1;
1665         else
1666                 self.team_forced = 0;
1667
1668         if(!teamplay)
1669                 if(self.team_forced > 0)
1670                         self.team_forced = 0;
1671
1672         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1673
1674         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1675                 self.classname = "observer";
1676         } else {
1677                 if(teamplay)
1678                 {
1679                         if(autocvar_g_balance_teams || autocvar_g_balance_teams_force)
1680                         {
1681                                 self.classname = "player";
1682                                 campaign_bots_may_start = 1;
1683                         }
1684                         else
1685                         {
1686                                 self.classname = "observer"; // do it anyway
1687                         }
1688                 }
1689                 else
1690                 {
1691                         self.classname = "player";
1692                         campaign_bots_may_start = 1;
1693                 }
1694         }
1695
1696         self.playerid = (playerid_last = playerid_last + 1);
1697
1698     if(clienttype(self) == CLIENTTYPE_BOT)
1699         PlayerStats_AddPlayer(self);
1700
1701         if(autocvar_sv_eventlog)
1702                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1703
1704         LogTeamchange(self.playerid, self.team, 1);
1705
1706         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1707
1708         self.netname_previous = strzone(self.netname);
1709
1710         bprint("^4", self.netname, "^4 connected");
1711
1712         if(self.classname != "observer" && (g_domination || g_ctf))
1713                 bprint(" and joined the ", ColoredTeamName(self.team));
1714
1715         bprint("\n");
1716
1717         self.welcomemessage_time = 0;
1718
1719         stuffcmd(self, strcat(clientstuff, "\n"));
1720         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1721         stuffcmd(self, "cl_particles_reloadeffects\n");
1722
1723         FixClientCvars(self);
1724
1725         // spawnfunc_waypoint sprites
1726         WaypointSprite_InitClient(self);
1727
1728         // Wazat's grappling hook
1729         SetGrappleHookBindings();
1730
1731         // get autoswitch state from player when he toggles it
1732         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1733
1734         // get version info from player
1735         stuffcmd(self, "cmd clientversion $gameversion\n");
1736
1737         // get other cvars from player
1738         GetCvars(0);
1739
1740         // notify about available teams
1741         if(teamplay)
1742         {
1743                 CheckAllowedTeams(self);
1744                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1745                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1746         }
1747         else
1748                 stuffcmd(self, "set _teams_available 0\n");
1749
1750         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1751
1752         if(g_arena || g_ca)
1753         {
1754                 self.classname = "observer";
1755                 if(g_arena)
1756                         Spawnqueue_Insert(self);
1757         }
1758         /*else if(g_ctf)
1759         {
1760                 ctf_clientconnect();
1761         }*/
1762
1763         attach_entcs();
1764
1765         bot_relinkplayerlist();
1766
1767         self.spectatortime = time;
1768         if(blockSpectators)
1769         {
1770                 sprint(self, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1771         }
1772
1773         self.jointime = time;
1774         self.allowedTimeouts = autocvar_sv_timeout_number;
1775
1776         if(clienttype(self) == CLIENTTYPE_REAL)
1777         {
1778                 if(autocvar_g_bugrigs || g_weaponarena == WEPBIT_TUBA)
1779                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1780         }
1781
1782         if(g_lms)
1783         {
1784                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1785                 {
1786                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1787                         self.frags = FRAGS_SPECTATOR;
1788                 }
1789         }
1790
1791         if(!sv_foginterval && world.fog != "")
1792                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1793
1794         SoundEntity_Attach(self);
1795
1796         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1797         {
1798                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1799                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1800         }
1801         else
1802                 self.hitplotfh = -1;
1803
1804         if(g_race || g_cts) {
1805                 string rr;
1806                 if(g_cts)
1807                         rr = CTS_RECORD;
1808                 else
1809                         rr = RACE_RECORD;
1810                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1811
1812                 msg_entity = self;
1813                 race_send_recordtime(MSG_ONE);
1814                 race_send_speedaward(MSG_ONE);
1815
1816                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1817                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1818                 race_send_speedaward_alltimebest(MSG_ONE);
1819
1820                 float i;
1821                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1822                         race_SendRankings(i, 0, 0, MSG_ONE);
1823                 }
1824         }
1825         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1826                 send_CSQC_teamnagger();
1827
1828         if (g_domination)
1829                 set_dom_state(self);
1830
1831         CheatInitClient();
1832 }
1833
1834 /*
1835 =============
1836 ClientDisconnect
1837
1838 Called when a client disconnects from the server
1839 =============
1840 */
1841 .entity chatbubbleentity;
1842 void ReadyCount();
1843 void ClientDisconnect (void)
1844 {
1845         if(self.vehicle)
1846             vehicles_exit(VHEF_RELESE);
1847
1848         if not(self.flags & FL_CLIENT)
1849         {
1850                 print("Warning: ClientDisconnect without ClientConnect\n");
1851                 return;
1852         }
1853
1854         PlayerStats_AddGlobalInfo(self);
1855
1856         CheatShutdownClient();
1857
1858         if(self.hitplotfh >= 0)
1859         {
1860                 fclose(self.hitplotfh);
1861                 self.hitplotfh = -1;
1862         }
1863
1864         anticheat_report();
1865         anticheat_shutdown();
1866
1867         playerdemo_shutdown();
1868
1869         bot_clientdisconnect();
1870
1871         if(self.entcs)
1872                 detach_entcs();
1873
1874         if(autocvar_sv_eventlog)
1875                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1876         bprint ("^4",self.netname);
1877         bprint ("^4 disconnected\n");
1878
1879         SoundEntity_Detach(self);
1880
1881         DropAllRunes(self);
1882         MUTATOR_CALLHOOK(ClientDisconnect);
1883
1884         Portal_ClearAll(self);
1885
1886         if(self.flagcarried)
1887                 DropFlag(self.flagcarried, world, world);
1888         if(self.ballcarried && g_nexball)
1889                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1890
1891         // Here, everything has been done that requires this player to be a client.
1892
1893         self.flags &~= FL_CLIENT;
1894
1895         if (self.chatbubbleentity)
1896                 remove (self.chatbubbleentity);
1897
1898         if (self.killindicator)
1899                 remove (self.killindicator);
1900
1901         WaypointSprite_PlayerGone();
1902
1903         bot_relinkplayerlist();
1904
1905         if(g_arena)
1906         {
1907                 Spawnqueue_Unmark(self);
1908                 Spawnqueue_Remove(self);
1909         }
1910
1911         accuracy_free(self);
1912         ClientData_Detach();
1913         PlayerScore_Detach(self);
1914
1915         if(self.netname_previous)
1916                 strunzone(self.netname_previous);
1917         if(self.clientstatus)
1918                 strunzone(self.clientstatus);
1919         if(self.weaponorder_byimpulse)
1920                 strunzone(self.weaponorder_byimpulse);
1921
1922         ClearPlayerSounds();
1923
1924         if(self.personal)
1925                 remove(self.personal);
1926
1927         self.playerid = 0;
1928         ReadyCount();
1929
1930         // free cvars
1931         GetCvars(-1);
1932 }
1933
1934 .float BUTTON_CHAT;
1935 void ChatBubbleThink()
1936 {
1937         self.nextthink = time;
1938         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1939         {
1940                 if(self.owner) // but why can that ever be world?
1941                         self.owner.chatbubbleentity = world;
1942                 remove(self);
1943                 return;
1944         }
1945         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1946 #ifdef TETRIS
1947                 || self.owner.tetris_on
1948 #endif
1949         )
1950                 self.model = self.mdl;
1951         else
1952                 self.model = "";
1953 };
1954
1955 void UpdateChatBubble()
1956 {
1957         if (!self.modelindex)
1958                 return;
1959         // spawn a chatbubble entity if needed
1960         if (!self.chatbubbleentity)
1961         {
1962                 self.chatbubbleentity = spawn();
1963                 self.chatbubbleentity.owner = self;
1964                 self.chatbubbleentity.exteriormodeltoclient = self;
1965                 self.chatbubbleentity.think = ChatBubbleThink;
1966                 self.chatbubbleentity.nextthink = time;
1967                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1968                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1969                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1970                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1971                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1972                 self.chatbubbleentity.model = "";
1973                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1974         }
1975 }
1976
1977
1978 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1979 // added to the model skins
1980 /*void UpdateColorModHack()
1981 {
1982         local float c;
1983         c = self.clientcolors & 15;
1984         // LordHavoc: only bothering to support white, green, red, yellow, blue
1985              if (!teamplay) self.colormod = '0 0 0';
1986         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1987         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1988         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1989         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1990         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1991         else self.colormod = '1 1 1';
1992 };*/
1993
1994 .float oldcolormap;
1995 void respawn(void)
1996 {
1997         if(self.modelindex != 0 && autocvar_g_respawn_ghosts)
1998         {
1999                 self.solid = SOLID_NOT;
2000                 self.takedamage = DAMAGE_NO;
2001                 self.movetype = MOVETYPE_FLY;
2002                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
2003                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
2004                 self.effects |= EF_ADDITIVE;
2005                 self.oldcolormap = self.colormap;
2006                 self.colormap = 512;
2007                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
2008                 if(autocvar_g_respawn_ghosts_maxtime)
2009                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
2010         }
2011
2012         CopyBody(1);
2013         self.effects |= EF_NODRAW; // prevent another CopyBody
2014         if(self.oldcolormap)
2015         {
2016                 self.colormap = self.oldcolormap;
2017                 self.oldcolormap = 0;
2018         }
2019         PutClientInServer();
2020 }
2021
2022 void play_countdown(float finished, string samp)
2023 {
2024         if(clienttype(self) == CLIENTTYPE_REAL)
2025                 if(floor(finished - time - frametime) != floor(finished - time))
2026                         if(finished - time < 6)
2027                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
2028 }
2029
2030 /**
2031  * When sv_timeout is used this function returs strings like
2032  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
2033  * Called by centerprint functions
2034  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
2035  */
2036 string getTimeoutText(float addOneSecond) {
2037         if (!autocvar_sv_timeout || !timeoutStatus)
2038                 return "";
2039
2040         local string retStr;
2041         if (timeoutStatus == 1) {
2042                 if (addOneSecond == 1) {
2043                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
2044                 }
2045                 else {
2046                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
2047                 }
2048                 return retStr;
2049         }
2050         else if (timeoutStatus == 2) {
2051                 if (addOneSecond) {
2052                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
2053                         //don't show messages like "Timeout ends in 0 seconds"...
2054                         if ((remainingTimeoutTime + 1) > 0)
2055                                 return retStr;
2056                         else
2057                                 return "";
2058                 }
2059                 else {
2060                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
2061                         //don't show messages like "Timeout ends in 0 seconds"...
2062                         if (remainingTimeoutTime > 0)
2063                                 return retStr;
2064                         else
2065                                 return "";
2066                 }
2067         }
2068         else return "";
2069 }
2070
2071 void player_powerups (void)
2072 {
2073         // add a way to see what the items were BEFORE all of these checks for the mutator hook
2074         olditems = self.items;
2075
2076         if((self.items & IT_USING_JETPACK) && !self.deadflag)
2077         {
2078                 SoundEntity_StartSound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
2079                 self.modelflags |= MF_ROCKET;
2080         }
2081         else
2082         {
2083                 SoundEntity_StopSound(self, CH_TRIGGER_SINGLE);
2084                 self.modelflags &~= MF_ROCKET;
2085         }
2086
2087         self.effects &~= (EF_DIMLIGHT | EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
2088
2089         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
2090                 return;
2091
2092         Fire_ApplyDamage(self);
2093         Fire_ApplyEffect(self);
2094
2095         if (g_minstagib)
2096         {
2097                 self.effects |= EF_FULLBRIGHT;
2098
2099                 if (self.items & IT_STRENGTH)
2100                 {
2101                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2102                         if (time > self.strength_finished)
2103                         {
2104                                 self.alpha = default_player_alpha;
2105                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
2106                                 self.items &~= IT_STRENGTH;
2107                                 sprint(self, "^3Invisibility has worn off\n");
2108                         }
2109                 }
2110                 else
2111                 {
2112                         if (time < self.strength_finished)
2113                         {
2114                                 self.alpha = g_minstagib_invis_alpha;
2115                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
2116                                 self.items |= IT_STRENGTH;
2117                                 sprint(self, "^3You are invisible\n");
2118                         }
2119                 }
2120
2121                 if (self.items & IT_INVINCIBLE)
2122                 {
2123                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2124                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2125                         {
2126                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2127                                 sprint(self, "^3Speed has worn off\n");
2128                         }
2129                 }
2130                 else
2131                 {
2132                         if (time < self.invincible_finished)
2133                         {
2134                                 self.items = self.items | IT_INVINCIBLE;
2135                                 sprint(self, "^3You are on speed\n");
2136                         }
2137                 }
2138         }
2139         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
2140         {
2141                 if (self.items & IT_STRENGTH)
2142                 {
2143                         play_countdown(self.strength_finished, "misc/poweroff.wav");
2144                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
2145                         if (time > self.strength_finished && autocvar_g_balance_powerup_timer)
2146                         {
2147                                 self.items = self.items - (self.items & IT_STRENGTH);
2148                                 sprint(self, "^3Strength has worn off\n");
2149                         }
2150                 }
2151                 else
2152                 {
2153                         if (time < self.strength_finished)
2154                         {
2155                                 self.items = self.items | IT_STRENGTH;
2156                                 sprint(self, "^3Strength infuses your weapons with devastating power\n");
2157                         }
2158                 }
2159                 if (self.items & IT_INVINCIBLE)
2160                 {
2161                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
2162                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
2163                         if (time > self.invincible_finished && autocvar_g_balance_powerup_timer)
2164                         {
2165                                 self.items = self.items - (self.items & IT_INVINCIBLE);
2166                                 sprint(self, "^3Shield has worn off\n");
2167                         }
2168                 }
2169                 else
2170                 {
2171                         if (time < self.invincible_finished)
2172                         {
2173                                 self.items = self.items | IT_INVINCIBLE;
2174                                 sprint(self, "^3Shield surrounds you\n");
2175                         }
2176                 }
2177
2178                 if(autocvar_g_nodepthtestplayers)
2179                         self.effects = self.effects | EF_NODEPTHTEST;
2180
2181                 if(autocvar_g_fullbrightplayers)
2182                         self.effects = self.effects | EF_FULLBRIGHT;
2183
2184                 // midair gamemode: damage only while in the air
2185                 // if in midair mode, being on ground grants temporary invulnerability
2186                 // (this is so that multishot weapon don't clear the ground flag on the
2187                 // first damage in the frame, leaving the player vulnerable to the
2188                 // remaining hits in the same frame)
2189                 if (self.flags & FL_ONGROUND)
2190                 if (g_midair)
2191                         self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
2192
2193                 if (time >= game_starttime)
2194                 if (time < self.spawnshieldtime)
2195                         self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2196         }
2197
2198         MUTATOR_CALLHOOK(PlayerPowerups);
2199 }
2200
2201 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2202 {
2203         if(current > stable)
2204                 return current;
2205         else if(current > stable - 0.25) // when close enough, "snap"
2206                 return stable;
2207         else
2208                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2209 }
2210
2211 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2212 {
2213         if(current < stable)
2214                 return current;
2215         else if(current < stable + 0.25) // when close enough, "snap"
2216                 return stable;
2217         else
2218                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2219 }
2220
2221 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2222 {
2223         if(current > rotstable)
2224         {
2225                 if(rotframetime > 0)
2226                 {
2227                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2228                         current = max(rotstable, current - rotlinear * rotframetime);
2229                 }
2230         }
2231         else if(current < regenstable)
2232         {
2233                 if(regenframetime > 0)
2234                 {
2235                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2236                         current = min(regenstable, current + regenlinear * regenframetime);
2237                 }
2238         }
2239
2240         if(current > limit)
2241                 current = limit;
2242
2243         return current;
2244 }
2245
2246 void player_regen (void)
2247 {
2248         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2249         maxh = autocvar_g_balance_health_rotstable;
2250         maxa = autocvar_g_balance_armor_rotstable;
2251         maxf = autocvar_g_balance_fuel_rotstable;
2252         minh = autocvar_g_balance_health_regenstable;
2253         mina = autocvar_g_balance_armor_regenstable;
2254         minf = autocvar_g_balance_fuel_regenstable;
2255         limith = autocvar_g_balance_health_limit;
2256         limita = autocvar_g_balance_armor_limit;
2257         limitf = autocvar_g_balance_fuel_limit;
2258
2259         max_mod = regen_mod = rot_mod = limit_mod = 1;
2260
2261         if (self.runes & RUNE_REGEN)
2262         {
2263                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2264                 {
2265                         regen_mod = autocvar_g_balance_rune_regen_combo_regenrate;
2266                         max_mod = autocvar_g_balance_rune_regen_combo_hpmod;
2267                         limit_mod = autocvar_g_balance_rune_regen_combo_limitmod;
2268                 }
2269                 else
2270                 {
2271                         regen_mod = autocvar_g_balance_rune_regen_regenrate;
2272                         max_mod = autocvar_g_balance_rune_regen_hpmod;
2273                         limit_mod = autocvar_g_balance_rune_regen_limitmod;
2274                 }
2275         }
2276         else if (self.runes & CURSE_VENOM)
2277         {
2278                 max_mod = autocvar_g_balance_curse_venom_hpmod;
2279                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2280                         rot_mod = autocvar_g_balance_rune_regen_combo_rotrate;
2281                 else
2282                         rot_mod = autocvar_g_balance_curse_venom_rotrate;
2283                 limit_mod = autocvar_g_balance_curse_venom_limitmod;
2284                 //if (!self.runes & RUNE_REGEN)
2285                 //      rot_mod = autocvar_g_balance_curse_venom_rotrate;
2286         }
2287         maxh = maxh * max_mod;
2288         //maxa = maxa * max_mod;
2289         //maxf = maxf * max_mod;
2290         minh = minh * max_mod;
2291         //mina = mina * max_mod;
2292         //minf = minf * max_mod;
2293         limith = limith * limit_mod;
2294         limita = limita * limit_mod;
2295         //limitf = limitf * limit_mod;
2296
2297         if(g_lms && g_ca)
2298                 rot_mod = 0;
2299
2300         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2301         {
2302                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2303                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2304
2305                 // if player rotted to death...  die!
2306                 if(self.health < 1)
2307                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2308         }
2309
2310         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2311                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2312 }
2313
2314 float zoomstate_set;
2315 void SetZoomState(float z)
2316 {
2317         if(z != self.zoomstate)
2318         {
2319                 self.zoomstate = z;
2320                 ClientData_Touch(self);
2321         }
2322         zoomstate_set = 1;
2323 }
2324
2325 void GetPressedKeys(void) {
2326         MUTATOR_CALLHOOK(GetPressedKeys);
2327         if (self.movement_x > 0) // get if movement keys are pressed
2328         {       // forward key pressed
2329                 self.pressedkeys |= KEY_FORWARD;
2330                 self.pressedkeys &~= KEY_BACKWARD;
2331         }
2332         else if (self.movement_x < 0)
2333         {       // backward key pressed
2334                 self.pressedkeys |= KEY_BACKWARD;
2335                 self.pressedkeys &~= KEY_FORWARD;
2336         }
2337         else
2338         {       // no x input
2339                 self.pressedkeys &~= KEY_FORWARD;
2340                 self.pressedkeys &~= KEY_BACKWARD;
2341         }
2342
2343         if (self.movement_y > 0)
2344         {       // right key pressed
2345                 self.pressedkeys |= KEY_RIGHT;
2346                 self.pressedkeys &~= KEY_LEFT;
2347         }
2348         else if (self.movement_y < 0)
2349         {       // left key pressed
2350                 self.pressedkeys |= KEY_LEFT;
2351                 self.pressedkeys &~= KEY_RIGHT;
2352         }
2353         else
2354         {       // no y input
2355                 self.pressedkeys &~= KEY_RIGHT;
2356                 self.pressedkeys &~= KEY_LEFT;
2357         }
2358
2359         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2360                 self.pressedkeys |= KEY_JUMP;
2361         else
2362                 self.pressedkeys &~= KEY_JUMP;
2363         if (self.BUTTON_CROUCH)
2364                 self.pressedkeys |= KEY_CROUCH;
2365         else
2366                 self.pressedkeys &~= KEY_CROUCH;
2367 }
2368
2369 /*
2370 ======================
2371 spectate mode routines
2372 ======================
2373 */
2374
2375 void SpectateCopy(entity spectatee) {
2376         other = spectatee;
2377         MUTATOR_CALLHOOK(SpectateCopy);
2378         self.armortype = spectatee.armortype;
2379         self.armorvalue = spectatee.armorvalue;
2380         self.ammo_cells = spectatee.ammo_cells;
2381         self.ammo_shells = spectatee.ammo_shells;
2382         self.ammo_nails = spectatee.ammo_nails;
2383         self.ammo_rockets = spectatee.ammo_rockets;
2384         self.ammo_fuel = spectatee.ammo_fuel;
2385         self.clip_load = spectatee.clip_load;
2386         self.clip_size = spectatee.clip_size;
2387         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2388         self.health = spectatee.health;
2389         self.impulse = 0;
2390         self.items = spectatee.items;
2391         self.last_pickup = spectatee.last_pickup;
2392         self.hit_time = spectatee.hit_time;
2393         self.metertime = spectatee.metertime;
2394         self.strength_finished = spectatee.strength_finished;
2395         self.invincible_finished = spectatee.invincible_finished;
2396         self.pressedkeys = spectatee.pressedkeys;
2397         self.weapons = spectatee.weapons;
2398         self.switchweapon = spectatee.switchweapon;
2399         self.weapon = spectatee.weapon;
2400         self.nex_charge = spectatee.nex_charge;
2401         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2402         self.hagar_load = spectatee.hagar_load;
2403         self.minelayer_mines = spectatee.minelayer_mines;
2404         self.punchangle = spectatee.punchangle;
2405         self.view_ofs = spectatee.view_ofs;
2406         self.v_angle = spectatee.v_angle;
2407         self.velocity = spectatee.velocity;
2408         self.dmg_take = spectatee.dmg_take;
2409         self.dmg_save = spectatee.dmg_save;
2410         self.dmg_inflictor = spectatee.dmg_inflictor;
2411         self.angles = spectatee.v_angle;
2412         self.fixangle = TRUE;
2413         setorigin(self, spectatee.origin);
2414         setsize(self, spectatee.mins, spectatee.maxs);
2415         SetZoomState(spectatee.zoomstate);
2416
2417         anticheat_spectatecopy(spectatee);
2418
2419         //self.vehicle = spectatee.vehicle;
2420
2421         self.hud = spectatee.hud;
2422         if(spectatee.vehicle)
2423     {
2424         setorigin(self, spectatee.origin);
2425         self.velocity = spectatee.vehicle.velocity;
2426         self.v_angle += spectatee.vehicle.angles;
2427         //self.v_angle_x *= -1;
2428         self.vehicle_health = spectatee.vehicle_health;
2429         self.vehicle_shield = spectatee.vehicle_shield;
2430         self.vehicle_energy = spectatee.vehicle_energy;
2431         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2432         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2433         self.vehicle_reload1 = spectatee.vehicle_reload1;
2434         self.vehicle_reload2 = spectatee.vehicle_reload2;
2435
2436         msg_entity = self;
2437         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
2438         WriteEntity(MSG_ONE, spectatee);
2439         //self.tur_head = spectatee.vehicle.vehicle_viewport;
2440     }
2441 }
2442
2443 float SpectateUpdate() {
2444         if(!self.enemy)
2445             return 0;
2446
2447         if (self == self.enemy)
2448                 return 0;
2449
2450         if(self.enemy.classname != "player")
2451                 return 0;
2452
2453         SpectateCopy(self.enemy);
2454
2455         return 1;
2456 }
2457
2458 float SpectateNext() {
2459         other = find(self.enemy, classname, "player");
2460
2461         if (!other)
2462                 other = find(other, classname, "player");
2463
2464         if (other)
2465                 self.enemy = other;
2466
2467         if(self.enemy.classname == "player") {
2468             if(self.enemy.vehicle)
2469             {
2470             msg_entity = self;
2471             WriteByte(MSG_ONE, SVC_SETVIEWPORT);
2472             WriteEntity(MSG_ONE, self.enemy);
2473             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2474             self.movetype = MOVETYPE_NONE;
2475             accuracy_resend(self);
2476             }
2477             else
2478             {
2479             msg_entity = self;
2480             WriteByte(MSG_ONE, SVC_SETVIEW);
2481             WriteEntity(MSG_ONE, self.enemy);
2482             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2483             self.movetype = MOVETYPE_NONE;
2484             accuracy_resend(self);
2485
2486             if(!SpectateUpdate())
2487                 PutObserverInServer();
2488         }
2489         return 1;
2490         } else {
2491                 return 0;
2492         }
2493 }
2494
2495 /*
2496 =============
2497 ShowRespawnCountdown()
2498
2499 Update a respawn countdown display.
2500 =============
2501 */
2502 void ShowRespawnCountdown()
2503 {
2504         float number;
2505         if(self.deadflag == DEAD_NO) // just respawned?
2506                 return;
2507         else
2508         {
2509                 number = ceil(self.death_time - time);
2510                 if(number <= 0)
2511                         return;
2512                 if(number <= self.respawn_countdown)
2513                 {
2514                         self.respawn_countdown = number - 1;
2515                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2516                                 AnnounceTo(self, strcat(ftos(number), ""));
2517                 }
2518         }
2519 }
2520
2521 void LeaveSpectatorMode()
2522 {
2523         if(nJoinAllowed(1)) {
2524                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0) {
2525                         self.classname = "player";
2526
2527                         if(autocvar_g_campaign || autocvar_g_balance_teams || autocvar_g_balance_teams_force)
2528                                 JoinBestTeam(self, FALSE, TRUE);
2529
2530                         if(autocvar_g_campaign)
2531                                 campaign_bots_may_start = 1;
2532
2533                         PutClientInServer();
2534
2535                         if(self.classname == "player")
2536                                 bprint ("^4", self.netname, "^4 is playing now\n");
2537
2538                         if(!autocvar_g_campaign)
2539                                 centerprint(self,""); // clear MOTD
2540
2541                         return;
2542                 } else {
2543                         if (g_ca && self.caplayer) {
2544                         }       // do nothing
2545                         else
2546                                 stuffcmd(self,"menu_showteamselect\n");
2547                         return;
2548                 }
2549         }
2550         else {
2551                 //player may not join because of g_maxplayers is set
2552                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2553         }
2554 }
2555
2556 /**
2557  * Determines whether the player is allowed to join. This depends on cvar
2558  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2559  * it checks whether the number of currently playing players exceeds g_maxplayers.
2560  * @return int number of free slots for players, 0 if none
2561  */
2562 float nJoinAllowed(float includeMe) {
2563         if(self.team_forced < 0)
2564                 return FALSE; // forced spectators can never join
2565
2566         // TODO simplify this
2567         local entity e;
2568
2569         local float totalClients;
2570         FOR_EACH_CLIENT(e)
2571                 totalClients += 1;
2572
2573         if (!autocvar_g_maxplayers)
2574                 return maxclients - totalClients + includeMe;
2575
2576         local float currentlyPlaying;
2577         FOR_EACH_REALPLAYER(e)
2578                 currentlyPlaying += 1;
2579
2580         if(currentlyPlaying < autocvar_g_maxplayers)
2581                 return min(maxclients - totalClients + includeMe, autocvar_g_maxplayers - currentlyPlaying);
2582
2583         return 0;
2584 }
2585
2586 /**
2587  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2588  * g_maxplayers_spectator_blocktime seconds
2589  */
2590 void checkSpectatorBlock() {
2591         if(self.classname == "spectator" || self.classname == "observer") {
2592                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2593                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2594                         dropclient(self);
2595                 }
2596         }
2597 }
2598
2599 void ObserverThink()
2600 {
2601         if (self.flags & FL_JUMPRELEASED) {
2602                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2603                         self.welcomemessage_time = 0;
2604                         self.flags &~= FL_JUMPRELEASED;
2605                         self.flags |= FL_SPAWNING;
2606                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2607                         self.welcomemessage_time = 0;
2608                         self.flags &~= FL_JUMPRELEASED;
2609                         if(SpectateNext() == 1) {
2610                                 self.classname = "spectator";
2611                         }
2612                 }
2613         } else {
2614                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2615                         self.flags |= FL_JUMPRELEASED;
2616                         if(self.flags & FL_SPAWNING)
2617                         {
2618                                 self.flags &~= FL_SPAWNING;
2619                                 LeaveSpectatorMode();
2620                                 return;
2621                         }
2622                 }
2623         }
2624         PrintWelcomeMessage(self);
2625 }
2626
2627 void SpectatorThink()
2628 {
2629         if (self.flags & FL_JUMPRELEASED) {
2630                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2631                         self.welcomemessage_time = 0;
2632                         self.flags &~= FL_JUMPRELEASED;
2633                         self.flags |= FL_SPAWNING;
2634                 } else if(self.BUTTON_ATCK) {
2635                         self.welcomemessage_time = 0;
2636                         self.flags &~= FL_JUMPRELEASED;
2637                         if(SpectateNext() == 1) {
2638                                 self.classname = "spectator";
2639                         } else {
2640                                 self.classname = "observer";
2641                                 PutClientInServer();
2642                         }
2643                 } else if (self.BUTTON_ATCK2) {
2644                         self.welcomemessage_time = 0;
2645                         self.flags &~= FL_JUMPRELEASED;
2646                         self.classname = "observer";
2647                         PutClientInServer();
2648                 } else {
2649                         if(!SpectateUpdate())
2650                                 PutObserverInServer();
2651                 }
2652         } else {
2653                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2654                         self.flags |= FL_JUMPRELEASED;
2655                         if(self.flags & FL_SPAWNING)
2656                         {
2657                                 self.flags &~= FL_SPAWNING;
2658                                 LeaveSpectatorMode();
2659                                 return;
2660                         }
2661                 }
2662                 if(!SpectateUpdate())
2663                         PutObserverInServer();
2664         }
2665
2666         PrintWelcomeMessage(self);
2667         self.flags |= FL_CLIENT | FL_NOTARGET;
2668 }
2669
2670 float ctf_usekey();
2671 void PlayerUseKey()
2672 {
2673         if(self.classname != "player")
2674                 return;
2675
2676         if(self.vehicle)
2677         {
2678         vehicles_exit(VHEF_NORMAL);
2679         return;
2680         }
2681
2682         // a use key was pressed; call handlers
2683         if(ctf_usekey())
2684                 return;
2685
2686         MUTATOR_CALLHOOK(PlayerUseKey);
2687 }
2688
2689 .float touchexplode_time;
2690
2691 /*
2692 =============
2693 PlayerPreThink
2694
2695 Called every frame for each client before the physics are run
2696 =============
2697 */
2698 .float usekeypressed;
2699 void() ctf_setstatus;
2700 void() nexball_setstatus;
2701 .float items_added;
2702 void PlayerPreThink (void)
2703 {
2704         WarpZone_PlayerPhysics_FixVAngle();
2705
2706         self.stat_game_starttime = game_starttime;
2707         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2708         self.stat_leadlimit = autocvar_leadlimit;
2709
2710         if(frametime)
2711         {
2712                 // physics frames: update anticheat stuff
2713                 anticheat_prethink();
2714         }
2715
2716         if(blockSpectators && frametime)
2717                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2718                 checkSpectatorBlock();
2719
2720         zoomstate_set = 0;
2721
2722         if(self.netname_previous != self.netname)
2723         {
2724                 if(autocvar_sv_eventlog)
2725                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2726                 if(self.netname_previous)
2727                         strunzone(self.netname_previous);
2728                 self.netname_previous = strzone(self.netname);
2729         }
2730
2731         // version nagging
2732         if(self.version_nagtime)
2733                 if(self.cvar_g_xonoticversion)
2734                         if(time > self.version_nagtime)
2735                         {
2736                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2737                                 {
2738                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0)
2739                                         {
2740                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2741                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2742                                         }
2743                                         else
2744                                         {
2745                                                 float r;
2746                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2747                                                 if(r < 0)
2748                                                 {
2749                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2750                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2751                                                 }
2752                                                 else if(r > 0)
2753                                                 {
2754                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2755                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2756                                                 }
2757                                         }
2758                                 }
2759                                 self.version_nagtime = 0;
2760                         }
2761
2762         // GOD MODE info
2763         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2764         {
2765                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2766                 self.max_armorvalue = 0;
2767         }
2768
2769 #ifdef TETRIS
2770         if (TetrisPreFrame())
2771                 return;
2772 #endif
2773
2774         MUTATOR_CALLHOOK(PlayerPreThink);
2775
2776         if(self.BUTTON_USE && !self.usekeypressed)
2777                 PlayerUseKey();
2778         self.usekeypressed = self.BUTTON_USE;
2779
2780         if(self.classname == "player") {
2781 //              if(self.netname == "Wazat")
2782 //                      bprint(self.classname, "\n");
2783
2784                 CheckRules_Player();
2785
2786                 PrintWelcomeMessage(self);
2787
2788                 if (intermission_running)
2789                 {
2790                         IntermissionThink ();   // otherwise a button could be missed between
2791                         return;                                 // the think tics
2792                 }
2793
2794                 //don't allow the player to turn around while game is paused!
2795                 if(timeoutStatus == 2) {
2796                         // FIXME turn this into CSQC stuff
2797                         self.v_angle = self.lastV_angle;
2798                         self.angles = self.lastV_angle;
2799                         self.fixangle = TRUE;
2800                 }
2801
2802                 if(frametime)
2803                 {
2804                         if(self.health <= 0 && autocvar_g_deathglow)
2805                         {
2806                                 if(self.glowmod_x > 0)
2807                                         self.glowmod_x -= autocvar_g_deathglow * frametime;
2808                                 else
2809                                         self.glowmod_x = -1;
2810                                 if(self.glowmod_y > 0)
2811                                         self.glowmod_y -= autocvar_g_deathglow * frametime;
2812                                 else
2813                                         self.glowmod_y = -1;
2814                                 if(self.glowmod_z > 0)
2815                                         self.glowmod_z -= autocvar_g_deathglow * frametime;
2816                                 else
2817                                         self.glowmod_z = -1;
2818                         }
2819                         else
2820                         {
2821                                 // set weapon and player glowmod
2822                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2823
2824                                 if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2825                                 {
2826                                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2827                                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2828                                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2829
2830                                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2831                                         {
2832                                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2833                                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2834                                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2835                                         }
2836                                 }
2837                                 else
2838                                         self.weaponentity_glowmod = self.glowmod;
2839                         }
2840                         player_powerups();
2841                 }
2842
2843                 if (self.deadflag != DEAD_NO)
2844                 {
2845                         float button_pressed, force_respawn;
2846                         if(self.personal && g_race_qualifying)
2847                         {
2848                                 if(time > self.death_time)
2849                                 {
2850                                         self.death_time = time + 1; // only retry once a second
2851                                         respawn();
2852                                         self.impulse = 141;
2853                                 }
2854                         }
2855                         else
2856                         {
2857                                 if(frametime)
2858                                         player_anim();
2859                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2860                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2861                                 if (self.deadflag == DEAD_DYING)
2862                                 {
2863                                         if(force_respawn)
2864                                                 self.deadflag = DEAD_RESPAWNING;
2865                                         else if(!button_pressed)
2866                                                 self.deadflag = DEAD_DEAD;
2867                                 }
2868                                 else if (self.deadflag == DEAD_DEAD)
2869                                 {
2870                                         if(button_pressed)
2871                                                 self.deadflag = DEAD_RESPAWNABLE;
2872                                 }
2873                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2874                                 {
2875                                         if(!button_pressed)
2876                                                 self.deadflag = DEAD_RESPAWNING;
2877                                 }
2878                                 else if (self.deadflag == DEAD_RESPAWNING)
2879                                 {
2880                                         if(time > self.death_time)
2881                                         {
2882                                                 self.death_time = time + 1; // only retry once a second
2883                                                 respawn();
2884                                         }
2885                                 }
2886                                 ShowRespawnCountdown();
2887                         }
2888                         return;
2889                 }
2890
2891                 if(g_touchexplode)
2892                 if(time > self.touchexplode_time)
2893                 if(self.classname == "player")
2894                 if(self.deadflag == DEAD_NO)
2895                 if not(IS_INDEPENDENT_PLAYER(self))
2896                 FOR_EACH_PLAYER(other) if(self != other)
2897                 {
2898                         if(time > other.touchexplode_time)
2899                         if(other.deadflag == DEAD_NO)
2900                         if not(IS_INDEPENDENT_PLAYER(other))
2901                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2902                         {
2903                                 PlayerTouchExplode(self, other);
2904                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2905                         }
2906                 }
2907
2908                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2909                 {
2910                         vector dist;
2911
2912                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2913                         dist = self.prevorigin - self.origin;
2914                         dist_z = 0;
2915                         self.lms_traveled_distance += fabs(vlen(dist));
2916
2917                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2918                         {
2919                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2920                                 self.lms_traveled_distance = 0;
2921                         }
2922
2923                         if(time > self.lms_nextcheck)
2924                         {
2925                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2926                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2927                                 {
2928                                         centerprint(self, autocvar_g_lms_campcheck_message);
2929                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2930                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2931                                         Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2932                                 }
2933                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2934                                 self.lms_traveled_distance = 0;
2935                         }
2936                 }
2937
2938                 self.prevorigin = self.origin;
2939
2940                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2941                 {
2942                         if (!self.crouch)
2943                         {
2944                                 self.crouch = TRUE;
2945                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2946                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2947                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2948                         }
2949                 }
2950                 else
2951                 {
2952                         if (self.crouch)
2953                         {
2954                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2955                                 if (!trace_startsolid)
2956                                 {
2957                                         self.crouch = FALSE;
2958                                         self.view_ofs = PL_VIEW_OFS;
2959                                         setsize (self, PL_MIN, PL_MAX);
2960                                 }
2961                         }
2962                 }
2963
2964                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2965                 {
2966                         if(self.bloodloss_timer < time)
2967                         {
2968                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2969                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2970                         }
2971                 }
2972
2973                 FixPlayermodel();
2974
2975                 GrapplingHookFrame();
2976
2977                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2978                 //if(frametime)
2979                 {
2980                         self.items &~= self.items_added;
2981
2982                         W_WeaponFrame();
2983
2984                         self.items_added = 0;
2985                         if(self.items & IT_JETPACK)
2986                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2987                                         self.items_added |= IT_FUEL;
2988
2989                         self.items |= self.items_added;
2990                 }
2991
2992                 player_regen();
2993
2994                 // rot nex charge to the charge limit
2995                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2996                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2997
2998                 if(frametime)
2999                         player_anim();
3000
3001                 if (g_minstagib)
3002                         minstagib_ammocheck();
3003
3004                 if(g_ctf)
3005                         ctf_setstatus();
3006
3007                 if(g_nexball)
3008                         nexball_setstatus();
3009
3010                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
3011
3012                 //self.angles_y=self.v_angle_y + 90;   // temp
3013         } else if(gameover) {
3014                 if (intermission_running)
3015                         IntermissionThink ();   // otherwise a button could be missed between
3016                 return;
3017         } else if(self.classname == "observer") {
3018                 ObserverThink();
3019         } else if(self.classname == "spectator") {
3020                 SpectatorThink();
3021         }
3022
3023         if(!zoomstate_set)
3024                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
3025
3026         float oldspectatee_status;
3027         oldspectatee_status = self.spectatee_status;
3028         if(self.classname == "spectator")
3029                 self.spectatee_status = num_for_edict(self.enemy);
3030         else if(self.classname == "observer")
3031                 self.spectatee_status = num_for_edict(self);
3032         else
3033                 self.spectatee_status = 0;
3034         if(self.spectatee_status != oldspectatee_status)
3035         {
3036                 ClientData_Touch(self);
3037                 if(g_race || g_cts)
3038                         race_InitSpectator();
3039         }
3040
3041         if(self.teamkill_soundtime)
3042         if(time > self.teamkill_soundtime)
3043         {
3044                 self.teamkill_soundtime = 0;
3045
3046                 entity oldpusher, oldself;
3047
3048                 oldself = self; self = self.teamkill_soundsource;
3049                 oldpusher = self.pusher; self.pusher = oldself;
3050
3051                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
3052
3053                 self.pusher = oldpusher;
3054                 self = oldself;
3055         }
3056
3057         if(self.taunt_soundtime)
3058         if(time > self.taunt_soundtime)
3059         {
3060                 self.taunt_soundtime = 0;
3061                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
3062         }
3063
3064         target_voicescript_next(self);
3065
3066         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
3067         if(!self.weapon)
3068                 self.clip_load = self.clip_size = 0;
3069 }
3070
3071 float isInvisibleString(string s)
3072 {
3073         float i, n, c;
3074         s = strdecolorize(s);
3075         for((i = 0), (n = strlen(s)); i < n; ++i)
3076         {
3077                 c = str2chr(s, i);
3078                 switch(c)
3079                 {
3080                         case 0:
3081                         case 32: // space
3082                                 break;
3083                         case 192: // charmap space
3084                                 if (!autocvar_utf8_enable)
3085                                         break;
3086                                 return FALSE;
3087                         case 160: // space in unicode fonts
3088                         case 0xE000 + 192: // utf8 charmap space
3089                                 if (autocvar_utf8_enable)
3090                                         break;
3091                         default:
3092                                 return FALSE;
3093                 }
3094         }
3095         return TRUE;
3096 }
3097
3098 /*
3099 =============
3100 PlayerPostThink
3101
3102 Called every frame for each client after the physics are run
3103 =============
3104 */
3105 .float idlekick_lasttimeleft;
3106 .entity showheadshotbbox;
3107 void showheadshotbbox_think()
3108 {
3109         if(self.owner.showheadshotbbox != self)
3110         {
3111                 remove(self);
3112                 return;
3113         }
3114         self.nextthink = time;
3115         setorigin(self, self.owner.origin);
3116         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
3117 }
3118 void PlayerPostThink (void)
3119 {
3120         // Savage: Check for nameless players
3121         if (isInvisibleString(self.netname)) {
3122                 self.netname = "Player";
3123                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
3124         }
3125
3126         if(sv_maxidle && frametime)
3127         {
3128                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
3129                 float timeleft;
3130                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
3131                 if(timeleft <= 0)
3132                 {
3133                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
3134                         AnnounceTo(self, "terminated");
3135                         dropclient(self);
3136                         return;
3137                 }
3138                 else if(timeleft <= 10)
3139                 {
3140                         if(timeleft != self.idlekick_lasttimeleft)
3141                         {
3142                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
3143                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
3144                         }
3145                 }
3146                 else
3147                 {
3148                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
3149                 }
3150                 self.idlekick_lasttimeleft = timeleft;
3151         }
3152
3153 #ifdef TETRIS
3154         if(self.impulse == 100)
3155                 ImpulseCommands();
3156         if (TetrisPostFrame())
3157                 return;
3158 #endif
3159
3160         CheatFrame();
3161
3162         if(self.classname == "player") {
3163                 CheckRules_Player();
3164                 UpdateChatBubble();
3165                 if (self.impulse)
3166                         ImpulseCommands();
3167                 if (intermission_running)
3168                         return;         // intermission or finale
3169                 GetPressedKeys();
3170         } else if (self.classname == "observer") {
3171                 //do nothing
3172         } else if (self.classname == "spectator") {
3173                 //do nothing
3174         }
3175
3176         /*
3177         float i;
3178         for(i = 0; i < 1000; ++i)
3179         {
3180                 vector end;
3181                 end = self.origin + '0 0 1024' + 512 * randomvec();
3182                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
3183                 if(trace_fraction < 1)
3184                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
3185                 {
3186                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
3187                         break;
3188                 }
3189         }
3190         */
3191
3192         Arena_Warmup();
3193
3194         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
3195
3196         if(self.waypointsprite_attachedforcarrier)
3197                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
3198
3199         if(self.classname == "player" && self.deadflag == DEAD_NO && autocvar_r_showbboxes)
3200         {
3201                 if(!self.showheadshotbbox)
3202                 {
3203                         self.showheadshotbbox = spawn();
3204                         self.showheadshotbbox.classname = "headshotbbox";
3205                         self.showheadshotbbox.owner = self;
3206                         self.showheadshotbbox.think = showheadshotbbox_think;
3207                         self.showheadshotbbox.nextthink = time;
3208                         self = self.showheadshotbbox;
3209                         self.think();
3210                         self = self.owner;
3211                 }
3212         }
3213         else
3214         {
3215                 if(self.showheadshotbbox)
3216                         if(self.showheadshotbbox && !wasfreed(self.showheadshotbbox))
3217                 remove(self.showheadshotbbox);
3218         }
3219
3220         playerdemo_write();
3221
3222         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
3223         {
3224                 if(!self.stored_netname)
3225                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
3226                 if(self.stored_netname != self.netname)
3227                 {
3228                         db_put(ServerProgsDB, strcat("uid2name", self.crypto_idfp), self.netname);
3229                         strunzone(self.stored_netname);
3230                         self.stored_netname = strzone(self.netname);
3231                 }
3232         }
3233
3234         /*
3235         if(g_race)
3236                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3237         */
3238 }