qcsrc/server/cl_client.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qc"
   5     #include "../dpdefs/dpextensions.qc"
   6     #include "sys-post.qh"
   7     #include "../warpzonelib/server.qh"
   8     #include "../common/constants.qh"
   9     #include "../common/teams.qh"
  10     #include "../common/util.qh"
  11     #include "../common/net_notice.qh"
  12     #include "../common/monsters/monsters.qh"
  13     #include "../common/monsters/sv_monsters.qh"
  14     #include "../common/weapons/weapons.qh"
  15     #include "t_items.qh"
  16     #include "autocvars.qh"
  17     #include "constants.qh"
  18     #include "defs.qh"
  19     #include "../common/notifications.qh"
  20     #include "../common/deathtypes.qh"
  21     #include "mutators/mutators_include.qh"
  22     #include "vehicles/vehicles_def.qh"
  23     #include "campaign.qh"
  24     #include "../common/mapinfo.qh"
  25     #include "command/common.qh"
  26     #include "command/vote.qh"
  27     #include "../csqcmodellib/sv_model.qh"
  28     #include "anticheat.qh"
  29     #include "cheats.qh"
  30     #include "../common/playerstats.qh"
  31     #include "portals.qh"
  32     #include "g_hook.qh"
  33     #include "scores.qh"
  34     #include "spawnpoints.qh"
  35     #include "ipban.qh"
  36     #include "race.qh"
  37     #include "antilag.qh"
  38     #include "playerdemo.qh"
  39 #endif
  40
  41 void send_CSQC_teamnagger() {
  42         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  43         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  44 }
  45
  46 float ClientData_Send(entity to, float sf)
  47 {
  48         if(to != self.owner)
  49         {
  50                 error("wtf");
  51                 return false;
  52         }
  53
  54         entity e;
  55
  56         e = to;
  57         if(IS_SPEC(to))
  58                 e = to.enemy;
  59
  60         sf = 0;
  61
  62         if(e.race_completed)
  63                 sf |= 1; // forced scoreboard
  64         if(to.spectatee_status)
  65                 sf |= 2; // spectator ent number follows
  66         if(e.zoomstate)
  67                 sf |= 4; // zoomed
  68         if(e.porto_v_angle_held)
  69                 sf |= 8; // angles held
  70
  71         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  72         WriteByte(MSG_ENTITY, sf);
  73
  74         if(sf & 2)
  75                 WriteByte(MSG_ENTITY, to.spectatee_status);
  76
  77         if(sf & 8)
  78         {
  79                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  80                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  81         }
  82
  83         return true;
  84 }
  85
  86 void ClientData_Attach()
  87 {
  88         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  89         self.clientdata.drawonlytoclient = self;
  90         self.clientdata.owner = self;
  91 }
  92
  93 void ClientData_Detach()
  94 {
  95         remove(self.clientdata);
  96         self.clientdata = world;
  97 }
  98
  99 void ClientData_Touch(entity e)
 100 {
 101         e.clientdata.SendFlags = 1;
 102
 103         // make it spectatable
 104         entity e2;
 105         FOR_EACH_REALCLIENT(e2)
 106         {
 107                 if(e2 != e)
 108                         if(IS_SPEC(e2))
 109                                 if(e2.enemy == e)
 110                                         e2.clientdata.SendFlags = 1;
 111         }
 112 }
 113
 114 .string netname_previous;
 115
 116 void SetSpectator(entity player, entity spectatee);
 117
 118
 119 /*
 120 =============
 121 CheckPlayerModel
 122
 123 Checks if the argument string can be a valid playermodel.
 124 Returns a valid one in doubt.
 125 =============
 126 */
 127 string FallbackPlayerModel;
 128 string CheckPlayerModel(string plyermodel) {
 129         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 130         {
 131                 // note: we cannot summon Don Strunzone here, some player may
 132                 // still have the model string set. In case anyone manages how
 133                 // to change a cvar default, we'll have a small leak here.
 134                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 135         }
 136         // only in right path
 137         if( substring(plyermodel,0,14) != "models/player/")
 138                 return FallbackPlayerModel;
 139         // only good file extensions
 140         if(substring(plyermodel,-4,4) != ".zym")
 141         if(substring(plyermodel,-4,4) != ".dpm")
 142         if(substring(plyermodel,-4,4) != ".iqm")
 143         if(substring(plyermodel,-4,4) != ".md3")
 144         if(substring(plyermodel,-4,4) != ".psk")
 145                 return FallbackPlayerModel;
 146         // forbid the LOD models
 147         if(substring(plyermodel, -9,5) == "_lod1")
 148                 return FallbackPlayerModel;
 149         if(substring(plyermodel, -9,5) == "_lod2")
 150                 return FallbackPlayerModel;
 151         if(plyermodel != strtolower(plyermodel))
 152                 return FallbackPlayerModel;
 153         // also, restrict to server models
 154         if(autocvar_sv_servermodelsonly)
 155         {
 156                 if(!fexists(plyermodel))
 157                         return FallbackPlayerModel;
 158         }
 159         return plyermodel;
 160 }
 161
 162 void setplayermodel(entity e, string modelname)
 163 {
 164         precache_model(modelname);
 165         setmodel(e, modelname);
 166         player_setupanimsformodel();
 167         UpdatePlayerSounds();
 168 }
 169
 170 /*
 171 =============
 172 PutObserverInServer
 173
 174 putting a client as observer in the server
 175 =============
 176 */
 177 void FixPlayermodel();
 178 void PutObserverInServer (void)
 179 {
 180         entity  spot;
 181     self.hud = HUD_NORMAL;
 182
 183         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 184
 185         spot = SelectSpawnPoint (true);
 186         if(!spot)
 187                 error("No spawnpoints for observers?!?\n");
 188         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 189
 190         if(IS_REAL_CLIENT(self))
 191         {
 192                 msg_entity = self;
 193                 WriteByte(MSG_ONE, SVC_SETVIEW);
 194                 WriteEntity(MSG_ONE, self);
 195         }
 196
 197         self.frags = FRAGS_SPECTATOR;
 198
 199         MUTATOR_CALLHOOK(MakePlayerObserver);
 200
 201         Portal_ClearAll(self);
 202
 203         Unfreeze(self);
 204
 205         if(self.alivetime)
 206         {
 207                 if(!warmup_stage)
 208                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 209                 self.alivetime = 0;
 210         }
 211
 212         if(self.vehicle)
 213                 vehicles_exit(VHEF_RELESE);
 214
 215         WaypointSprite_PlayerDead();
 216
 217         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 218                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 219
 220         if(self.killcount != -666)
 221         {
 222                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 223                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 224                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 225
 226                 if(self.just_joined == false) {
 227                         LogTeamchange(self.playerid, -1, 4);
 228                 } else
 229                         self.just_joined = false;
 230         }
 231
 232         PlayerScore_Clear(self); // clear scores when needed
 233
 234         accuracy_resend(self);
 235
 236         self.spectatortime = time;
 237
 238         self.classname = "observer";
 239         self.iscreature = false;
 240         self.teleportable = TELEPORT_SIMPLE;
 241         self.damagedbycontents = false;
 242         self.health = -666;
 243         self.takedamage = DAMAGE_NO;
 244         self.solid = SOLID_NOT;
 245         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 246         self.flags = FL_CLIENT | FL_NOTARGET;
 247         self.armorvalue = 666;
 248         self.effects = 0;
 249         self.armorvalue = autocvar_g_balance_armor_start;
 250         self.pauserotarmor_finished = 0;
 251         self.pauserothealth_finished = 0;
 252         self.pauseregen_finished = 0;
 253         self.damageforcescale = 0;
 254         self.death_time = 0;
 255         self.respawn_flags = 0;
 256         self.respawn_time = 0;
 257         self.stat_respawn_time = 0;
 258         self.alpha = 0;
 259         self.scale = 0;
 260         self.fade_time = 0;
 261         self.pain_frame = 0;
 262         self.pain_finished = 0;
 263         self.strength_finished = 0;
 264         self.invincible_finished = 0;
 265         self.superweapons_finished = 0;
 266         self.pushltime = 0;
 267         self.istypefrag = 0;
 268         self.think = func_null;
 269         self.nextthink = 0;
 270         self.hook_time = 0;
 271         self.deadflag = DEAD_NO;
 272         self.angles = spot.angles;
 273         self.angles_z = 0;
 274         self.fixangle = true;
 275         self.crouch = false;
 276         self.revival_time = 0;
 277
 278         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 279         self.prevorigin = self.origin;
 280         self.items = 0;
 281         self.weapons = '0 0 0';
 282         self.model = "";
 283         FixPlayermodel();
 284         setmodel(self, "null");
 285         self.drawonlytoclient = self;
 286
 287         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 288         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 289
 290         self.weapon = 0;
 291         self.weaponname = "";
 292         self.switchingweapon = 0;
 293         self.weaponmodel = "";
 294         self.weaponentity = world;
 295         self.exteriorweaponentity = world;
 296         self.killcount = -666;
 297         self.velocity = '0 0 0';
 298         self.avelocity = '0 0 0';
 299         self.punchangle = '0 0 0';
 300         self.punchvector = '0 0 0';
 301         self.oldvelocity = self.velocity;
 302         self.fire_endtime = -1;
 303         self.event_damage = func_null;
 304 }
 305
 306 .float model_randomizer;
 307 void FixPlayermodel()
 308 {
 309         string defaultmodel;
 310         float defaultskin, chmdl, oldskin, n, i;
 311         vector m1, m2;
 312
 313         defaultmodel = "";
 314         defaultskin = 0;
 315         chmdl = false;
 316
 317         if(autocvar_sv_defaultcharacter == 1)
 318         {
 319                 if(teamplay)
 320                 {
 321                         string s;
 322                         s = Static_Team_ColorName_Lower(self.team);
 323                         if(s != "neutral")
 324                         {
 325                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 326                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 327                         }
 328                 }
 329
 330                 if(defaultmodel == "")
 331                 {
 332                         defaultmodel = autocvar_sv_defaultplayermodel;
 333                         defaultskin = autocvar_sv_defaultplayerskin;
 334                 }
 335
 336                 n = tokenize_console(defaultmodel);
 337                 if(n > 0)
 338                 {
 339                         defaultmodel = argv(floor(n * self.model_randomizer));
 340                         // However, do NOT randomize if the player-selected model is in the list.
 341                         for (i = 0; i < n; ++i)
 342                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 343                                         defaultmodel = argv(i);
 344                 }
 345
 346                 i = strstrofs(defaultmodel, ":", 0);
 347                 if(i >= 0)
 348                 {
 349                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 350                         defaultmodel = substring(defaultmodel, 0, i);
 351                 }
 352         }
 353
 354         if(defaultmodel != "")
 355         {
 356                 if (defaultmodel != self.model)
 357                 {
 358                         m1 = self.mins;
 359                         m2 = self.maxs;
 360                         setplayermodel (self, defaultmodel);
 361                         setsize (self, m1, m2);
 362                         chmdl = true;
 363                 }
 364
 365                 oldskin = self.skin;
 366                 self.skin = defaultskin;
 367         } else {
 368                 if (self.playermodel != self.model || self.playermodel == "")
 369                 {
 370                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 371                         m1 = self.mins;
 372                         m2 = self.maxs;
 373                         setplayermodel (self, self.playermodel);
 374                         setsize (self, m1, m2);
 375                         chmdl = true;
 376                 }
 377
 378                 oldskin = self.skin;
 379                 self.skin = stof(self.playerskin);
 380         }
 381
 382         if(chmdl || oldskin != self.skin) // model or skin has changed
 383         {
 384                 self.species = player_getspecies(); // update species
 385                 UpdatePlayerSounds(); // update skin sounds
 386         }
 387
 388         if(!teamplay)
 389                 if(strlen(autocvar_sv_defaultplayercolors))
 390                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 391                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 392 }
 393
 394 /*
 395 =============
 396 PutClientInServer
 397
 398 Called when a client spawns in the server
 399 =============
 400 */
 401 void PutClientInServer (void)
 402 {
 403         if(IS_BOT_CLIENT(self))
 404                 self.classname = "player";
 405         else if(IS_REAL_CLIENT(self))
 406         {
 407                 msg_entity = self;
 408                 WriteByte(MSG_ONE, SVC_SETVIEW);
 409                 WriteEntity(MSG_ONE, self);
 410         }
 411
 412         SetSpectator(self, world);
 413
 414         // reset player keys
 415         self.itemkeys = 0;
 416
 417         MUTATOR_CALLHOOK(PutClientInServer);
 418
 419         if(gameover)
 420                 self.classname = "observer";
 421
 422         if(IS_PLAYER(self))
 423         {
 424                 entity spot, oldself;
 425                 float j;
 426
 427                 accuracy_resend(self);
 428
 429                 if(self.team < 0)
 430                         JoinBestTeam(self, false, true);
 431
 432                 spot = SelectSpawnPoint (false);
 433                 if(!spot)
 434                 {
 435                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 436                         return; // spawn failed
 437                 }
 438
 439                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 440
 441                 if(self.vehicle)
 442                         vehicles_exit(VHEF_RELESE);
 443
 444                 self.classname = "player";
 445                 self.wasplayer = true;
 446                 self.iscreature = true;
 447                 self.teleportable = TELEPORT_NORMAL;
 448                 self.damagedbycontents = true;
 449                 self.movetype = MOVETYPE_WALK;
 450                 self.solid = SOLID_SLIDEBOX;
 451                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 452                 if(autocvar_g_playerclip_collisions)
 453                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 454                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 455                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 456                 self.frags = FRAGS_PLAYER;
 457                 if(INDEPENDENT_PLAYERS)
 458                         MAKE_INDEPENDENT_PLAYER(self);
 459                 self.flags = FL_CLIENT;
 460                 if(autocvar__notarget)
 461                         self.flags |= FL_NOTARGET;
 462                 self.takedamage = DAMAGE_AIM;
 463                 self.effects = 0;
 464                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 465                 self.air_finished = time + 12;
 466                 self.dmg = 2;
 467                 if(WEP_CVAR(vortex, charge))
 468                 {
 469                         if(WEP_CVAR_SEC(vortex, chargepool))
 470                                 self.vortex_chargepool_ammo = 1;
 471                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 472                 }
 473
 474                 if(warmup_stage)
 475                 {
 476                         self.ammo_shells = warmup_start_ammo_shells;
 477                         self.ammo_nails = warmup_start_ammo_nails;
 478                         self.ammo_rockets = warmup_start_ammo_rockets;
 479                         self.ammo_cells = warmup_start_ammo_cells;
 480                         self.ammo_plasma = warmup_start_ammo_plasma;
 481                         self.ammo_fuel = warmup_start_ammo_fuel;
 482                         self.health = warmup_start_health;
 483                         self.armorvalue = warmup_start_armorvalue;
 484                         self.weapons = WARMUP_START_WEAPONS;
 485                 }
 486                 else
 487                 {
 488                         self.ammo_shells = start_ammo_shells;
 489                         self.ammo_nails = start_ammo_nails;
 490                         self.ammo_rockets = start_ammo_rockets;
 491                         self.ammo_cells = start_ammo_cells;
 492                         self.ammo_plasma = start_ammo_plasma;
 493                         self.ammo_fuel = start_ammo_fuel;
 494                         self.health = start_health;
 495                         self.armorvalue = start_armorvalue;
 496                         self.weapons = start_weapons;
 497                 }
 498
 499                 if(self.weapons & WEPSET_SUPERWEAPONS)
 500                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 501                 else
 502                         self.superweapons_finished = 0;
 503
 504                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 505                 {
 506                         if(g_weaponarena_random_with_blaster)
 507                                 self.weapons &= ~WEPSET_BLASTER;
 508                         W_RandomWeapons(self, g_weaponarena_random);
 509                         if(g_weaponarena_random_with_blaster)
 510                                 self.weapons |= WEPSET_BLASTER;
 511                 }
 512
 513                 self.items = start_items;
 514
 515                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 516                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 517                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 518                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 519                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 520                 //extend the pause of rotting if client was reset at the beginning of the countdown
 521                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 522                         self.spawnshieldtime += game_starttime - time;
 523                         self.pauserotarmor_finished += game_starttime - time;
 524                         self.pauserothealth_finished += game_starttime - time;
 525                         self.pauseregen_finished += game_starttime - time;
 526                 }
 527                 self.damageforcescale = 2;
 528                 self.death_time = 0;
 529                 self.respawn_flags = 0;
 530                 self.respawn_time = 0;
 531                 self.stat_respawn_time = 0;
 532                 self.scale = 0;
 533                 self.fade_time = 0;
 534                 self.pain_frame = 0;
 535                 self.pain_finished = 0;
 536                 self.strength_finished = 0;
 537                 self.invincible_finished = 0;
 538                 self.pushltime = 0;
 539                 // players have no think function
 540                 self.think = func_null;
 541                 self.nextthink = 0;
 542                 self.hook_time = 0;
 543                 self.dmg_team = 0;
 544                 self.ballistics_density = autocvar_g_ballistics_density_player;
 545
 546                 self.metertime = 0;
 547
 548                 self.deadflag = DEAD_NO;
 549
 550                 self.angles = spot.angles;
 551
 552                 self.angles_z = 0; // never spawn tilted even if the spot says to
 553                 if(IS_BOT_CLIENT(self))
 554                         self.v_angle = self.angles;
 555                 self.fixangle = true; // turn this way immediately
 556                 self.velocity = '0 0 0';
 557                 self.avelocity = '0 0 0';
 558                 self.punchangle = '0 0 0';
 559                 self.punchvector = '0 0 0';
 560                 self.oldvelocity = self.velocity;
 561                 self.fire_endtime = -1;
 562                 self.revival_time = 0;
 563
 564                 entity spawnevent = spawn();
 565                 spawnevent.owner = self;
 566                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 567
 568                 // Cut off any still running player sounds.
 569                 stopsound(self, CH_PLAYER_SINGLE);
 570
 571                 self.model = "";
 572                 FixPlayermodel();
 573                 self.drawonlytoclient = world;
 574
 575                 self.crouch = false;
 576                 self.view_ofs = PL_VIEW_OFS;
 577                 setsize (self, PL_MIN, PL_MAX);
 578                 self.spawnorigin = spot.origin;
 579                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 580                 // don't reset back to last position, even if new position is stuck in solid
 581                 self.oldorigin = self.origin;
 582                 self.prevorigin = self.origin;
 583                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 584                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 585         self.hud = HUD_NORMAL;
 586
 587                 self.event_damage = PlayerDamage;
 588
 589                 self.bot_attack = true;
 590                 self.monster_attack = true;
 591
 592                 self.spider_slowness = 0;
 593
 594                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 595
 596                 if(self.killcount == -666) {
 597                         PlayerScore_Clear(self);
 598                         self.killcount = 0;
 599                 }
 600
 601                 CL_SpawnWeaponentity();
 602                 self.alpha = default_player_alpha;
 603                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 604                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 605
 606                 self.speedrunning = false;
 607
 608                 //stuffcmd(self, "chase_active 0");
 609                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 610
 611                 target_voicescript_clear(self);
 612
 613                 // reset fields the weapons may use
 614                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 615                 {
 616                         WEP_ACTION(j, WR_RESETPLAYER);
 617
 618                         // all weapons must be fully loaded when we spawn
 619                         entity e;
 620                         e = get_weaponinfo(j);
 621                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 622                                 self.(weapon_load[j]) = e.reloading_ammo;
 623                 }
 624
 625                 oldself = self;
 626                 self = spot;
 627                         activator = oldself;
 628                                 string s;
 629                                 s = self.target;
 630                                 self.target = string_null;
 631                                 SUB_UseTargets();
 632                                 self.target = s;
 633                         activator = world;
 634                 self = oldself;
 635
 636                 Unfreeze(self);
 637
 638                 spawn_spot = spot;
 639                 MUTATOR_CALLHOOK(PlayerSpawn);
 640
 641                 if(autocvar_spawn_debug)
 642                 {
 643                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 644                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 645                 }
 646
 647                 self.switchweapon = w_getbestweapon(self);
 648                 self.cnt = -1; // W_LastWeapon will not complain
 649                 self.weapon = 0;
 650                 self.weaponname = "";
 651                 self.switchingweapon = 0;
 652
 653                 if(!warmup_stage)
 654                         if(!self.alivetime)
 655                                 self.alivetime = time;
 656
 657                 antilag_clear(self);
 658         }
 659         else if(IS_OBSERVER(self))
 660         {
 661                 PutObserverInServer ();
 662         }
 663 }
 664
 665 .float ebouncefactor, ebouncestop; // electro's values
 666 // TODO do we need all these fields, or should we stop autodetecting runtime
 667 // changes and just have a console command to update this?
 668 float ClientInit_SendEntity(entity to, float sf)
 669 {
 670         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 671         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 672         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 673         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 674         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 675         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 676         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 677         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 678         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 679         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 680
 681         if(sv_foginterval && world.fog != "")
 682                 WriteString(MSG_ENTITY, world.fog);
 683         else
 684                 WriteString(MSG_ENTITY, "");
 685         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 686         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 687         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 688         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 689         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 690         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 691         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 692         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 693         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 694         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 695         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 696         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 697         return true;
 698 }
 699
 700 void ClientInit_CheckUpdate()
 701 {
 702         self.nextthink = time;
 703         if(self.count != autocvar_g_balance_armor_blockpercent)
 704         {
 705                 self.count = autocvar_g_balance_armor_blockpercent;
 706                 self.SendFlags |= 1;
 707         }
 708         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 709         {
 710                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 711                 self.SendFlags |= 1;
 712         }
 713         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 714         {
 715                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 716                 self.SendFlags |= 1;
 717         }
 718         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 719         {
 720                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 721                 self.SendFlags |= 1;
 722         }
 723         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 724         {
 725                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 726                 self.SendFlags |= 1;
 727         }
 728 }
 729
 730 void ClientInit_Spawn()
 731 {
 732         entity o;
 733         entity e;
 734         e = spawn();
 735         e.classname = "clientinit";
 736         e.think = ClientInit_CheckUpdate;
 737         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 738
 739         o = self;
 740         self = e;
 741         ClientInit_CheckUpdate();
 742         self = o;
 743 }
 744
 745 /*
 746 =============
 747 SetNewParms
 748 =============
 749 */
 750 void SetNewParms (void)
 751 {
 752         // initialize parms for a new player
 753         parm1 = -(86400 * 366);
 754 }
 755
 756 /*
 757 =============
 758 SetChangeParms
 759 =============
 760 */
 761 void SetChangeParms (void)
 762 {
 763         // save parms for level change
 764         parm1 = self.parm_idlesince - time;
 765 }
 766
 767 /*
 768 =============
 769 DecodeLevelParms
 770 =============
 771 */
 772 void DecodeLevelParms (void)
 773 {
 774         // load parms
 775         self.parm_idlesince = parm1;
 776         if(self.parm_idlesince == -(86400 * 366))
 777                 self.parm_idlesince = time;
 778
 779         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 780         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 781 }
 782
 783 /*
 784 =============
 785 ClientKill
 786
 787 Called when a client types 'kill' in the console
 788 =============
 789 */
 790
 791 .float clientkill_nexttime;
 792 void ClientKill_Now_TeamChange()
 793 {
 794         if(self.killindicator_teamchange == -1)
 795         {
 796                 JoinBestTeam( self, false, true );
 797         }
 798         else if(self.killindicator_teamchange == -2)
 799         {
 800                 if(blockSpectators)
 801                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 802                 PutObserverInServer();
 803         }
 804         else
 805                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 806         self.killindicator_teamchange = 0;
 807 }
 808
 809 void ClientKill_Now()
 810 {
 811         if(self.vehicle)
 812         {
 813             vehicles_exit(VHEF_RELESE);
 814             if(!self.killindicator_teamchange)
 815             {
 816             self.vehicle_health = -1;
 817             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 818             }
 819         }
 820
 821         if(self.killindicator && !wasfreed(self.killindicator))
 822                 remove(self.killindicator);
 823
 824         self.killindicator = world;
 825
 826         if(self.killindicator_teamchange)
 827                 ClientKill_Now_TeamChange();
 828
 829         if(IS_PLAYER(self))
 830                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 831
 832         // now I am sure the player IS dead
 833 }
 834 void KillIndicator_Think()
 835 {
 836         if (gameover)
 837         {
 838                 self.owner.killindicator = world;
 839                 remove(self);
 840                 return;
 841         }
 842
 843         if (self.owner.alpha < 0 && !self.owner.vehicle)
 844         {
 845                 self.owner.killindicator = world;
 846                 remove(self);
 847                 return;
 848         }
 849
 850         if(self.cnt <= 0)
 851         {
 852                 self = self.owner;
 853                 ClientKill_Now(); // no oldself needed
 854                 return;
 855         }
 856     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 857     {
 858         self.nextthink = time + 1;
 859         self.cnt -= 1;
 860     }
 861         else
 862         {
 863                 if(self.cnt <= 10)
 864                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 865                 if(IS_REAL_CLIENT(self.owner))
 866                 {
 867                         if(self.cnt <= 10)
 868                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 869                 }
 870                 self.nextthink = time + 1;
 871                 self.cnt -= 1;
 872         }
 873 }
 874
 875 float clientkilltime;
 876 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 877 {
 878         float killtime;
 879         float starttime;
 880         entity e;
 881
 882         if (gameover)
 883                 return;
 884
 885         killtime = autocvar_g_balance_kill_delay;
 886
 887         if(g_race_qualifying || g_cts)
 888                 killtime = 0;
 889
 890     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 891     {
 892                 remove(self.killindicator);
 893                 self.killindicator = world;
 894
 895         ClientKill_Now(); // allow instant kill in this case
 896         return;
 897     }
 898
 899         self.killindicator_teamchange = targetteam;
 900
 901     if(!self.killindicator)
 902         {
 903                 if(self.deadflag == DEAD_NO)
 904                 {
 905                         killtime = max(killtime, self.clientkill_nexttime - time);
 906                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 907                 }
 908
 909                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 910                 {
 911                         ClientKill_Now();
 912                 }
 913                 else
 914                 {
 915                         starttime = max(time, clientkilltime);
 916
 917                         self.killindicator = spawn();
 918                         self.killindicator.owner = self;
 919                         self.killindicator.scale = 0.5;
 920                         setattachment(self.killindicator, self, "");
 921                         setorigin(self.killindicator, '0 0 52');
 922                         self.killindicator.think = KillIndicator_Think;
 923                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 924                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 925                         self.killindicator.cnt = ceil(killtime);
 926                         self.killindicator.count = bound(0, ceil(killtime), 10);
 927                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 928
 929                         for(e = world; (e = find(e, classname, "body")) != world; )
 930                         {
 931                                 if(e.enemy != self)
 932                                         continue;
 933                                 e.killindicator = spawn();
 934                                 e.killindicator.owner = e;
 935                                 e.killindicator.scale = 0.5;
 936                                 setattachment(e.killindicator, e, "");
 937                                 setorigin(e.killindicator, '0 0 52');
 938                                 e.killindicator.think = KillIndicator_Think;
 939                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 940                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 941                                 e.killindicator.cnt = ceil(killtime);
 942                         }
 943                         self.lip = 0;
 944                 }
 945         }
 946         if(self.killindicator)
 947         {
 948                 if(targetteam == 0) // just die
 949                 {
 950                         self.killindicator.colormod = '0 0 0';
 951                         if(IS_REAL_CLIENT(self))
 952                         if(self.killindicator.cnt > 0)
 953                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 954                 }
 955                 else if(targetteam == -1) // auto
 956                 {
 957                         self.killindicator.colormod = '0 1 0';
 958                         if(IS_REAL_CLIENT(self))
 959                         if(self.killindicator.cnt > 0)
 960                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 961                 }
 962                 else if(targetteam == -2) // spectate
 963                 {
 964                         self.killindicator.colormod = '0.5 0.5 0.5';
 965                         if(IS_REAL_CLIENT(self))
 966                         if(self.killindicator.cnt > 0)
 967                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 968                 }
 969                 else
 970                 {
 971                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 972                         if(IS_REAL_CLIENT(self))
 973                         if(self.killindicator.cnt > 0)
 974                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 975                 }
 976         }
 977
 978 }
 979
 980 void ClientKill (void)
 981 {
 982         if(gameover) return;
 983         if(self.player_blocked) return;
 984         if(self.frozen) return;
 985
 986         ClientKill_TeamChange(0);
 987 }
 988
 989 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 990 {
 991     e.killindicator = spawn();
 992     e.killindicator.owner = e;
 993     e.killindicator.think = KillIndicator_Think;
 994     e.killindicator.nextthink = time + (e.lip) * 0.05;
 995     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 996     e.killindicator.health = 1; // this is used to indicate that it should be silent
 997     e.lip = 0;
 998 }
 999
1000 void FixClientCvars(entity e)
1001 {
1002         // send prediction settings to the client
1003         stuffcmd(e, "\nin_bindmap 0 0\n");
1004         if(g_race || g_cts)
1005                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1006         if(autocvar_g_antilag == 3) // client side hitscan
1007                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1008         if(autocvar_sv_gentle)
1009                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1010 }
1011
1012 float PlayerInIDList(entity p, string idlist)
1013 {
1014         float n, i;
1015         string s;
1016
1017         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1018         if (!p.crypto_idfp)
1019                 return 0;
1020
1021         // this function allows abbreviated player IDs too!
1022         n = tokenize_console(idlist);
1023         for(i = 0; i < n; ++i)
1024         {
1025                 s = argv(i);
1026                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1027                         return 1;
1028         }
1029
1030         return 0;
1031 }
1032
1033 /*
1034 =============
1035 ClientConnect
1036
1037 Called when a client connects to the server
1038 =============
1039 */
1040 void DecodeLevelParms (void);
1041 //void dom_player_join_team(entity pl);
1042 void set_dom_state(entity e);
1043 void ClientConnect (void)
1044 {
1045         float t;
1046
1047         if(IS_CLIENT(self))
1048         {
1049                 print("Warning: ClientConnect, but already connected!\n");
1050                 return;
1051         }
1052
1053         if(Ban_MaybeEnforceBanOnce(self))
1054                 return;
1055
1056         DecodeLevelParms();
1057
1058 #ifdef WATERMARK
1059         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1060 #endif
1061
1062         self.classname = "player_joining";
1063
1064         self.flags = FL_CLIENT;
1065         self.version_nagtime = time + 10 + random() * 10;
1066
1067         if(player_count<0)
1068         {
1069                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1070                 player_count = 0;
1071         }
1072
1073         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1074
1075         PlayerScore_Attach(self);
1076         ClientData_Attach();
1077         accuracy_init(self);
1078
1079         bot_clientconnect();
1080
1081         playerdemo_init();
1082
1083         anticheat_init();
1084
1085         // identify the right forced team
1086         if(autocvar_g_campaign)
1087         {
1088                 if(IS_REAL_CLIENT(self)) // only players, not bots
1089                 {
1090                         switch(autocvar_g_campaign_forceteam)
1091                         {
1092                                 case 1: self.team_forced = NUM_TEAM_1; break;
1093                                 case 2: self.team_forced = NUM_TEAM_2; break;
1094                                 case 3: self.team_forced = NUM_TEAM_3; break;
1095                                 case 4: self.team_forced = NUM_TEAM_4; break;
1096                                 default: self.team_forced = 0;
1097                         }
1098                 }
1099         }
1100         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1101                 self.team_forced = NUM_TEAM_1;
1102         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1103                 self.team_forced = NUM_TEAM_2;
1104         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1105                 self.team_forced = NUM_TEAM_3;
1106         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1107                 self.team_forced = NUM_TEAM_4;
1108         else if(autocvar_g_forced_team_otherwise == "red")
1109                 self.team_forced = NUM_TEAM_1;
1110         else if(autocvar_g_forced_team_otherwise == "blue")
1111                 self.team_forced = NUM_TEAM_2;
1112         else if(autocvar_g_forced_team_otherwise == "yellow")
1113                 self.team_forced = NUM_TEAM_3;
1114         else if(autocvar_g_forced_team_otherwise == "pink")
1115                 self.team_forced = NUM_TEAM_4;
1116         else if(autocvar_g_forced_team_otherwise == "spectate")
1117                 self.team_forced = -1;
1118         else if(autocvar_g_forced_team_otherwise == "spectator")
1119                 self.team_forced = -1;
1120         else
1121                 self.team_forced = 0;
1122
1123         if(!teamplay)
1124                 if(self.team_forced > 0)
1125                         self.team_forced = 0;
1126
1127         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1128
1129         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1130                 self.classname = "observer";
1131         } else {
1132                 if(teamplay)
1133                 {
1134                         if(autocvar_g_balance_teams)
1135                         {
1136                                 self.classname = "player";
1137                                 campaign_bots_may_start = 1;
1138                         }
1139                         else
1140                         {
1141                                 self.classname = "observer"; // do it anyway
1142                         }
1143                 }
1144                 else
1145                 {
1146                         self.classname = "player";
1147                         campaign_bots_may_start = 1;
1148                 }
1149         }
1150
1151         self.playerid = (playerid_last = playerid_last + 1);
1152
1153         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1154
1155     if(IS_BOT_CLIENT(self))
1156         PlayerStats_GameReport_AddPlayer(self);
1157
1158         if(autocvar_sv_eventlog)
1159                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1160
1161         LogTeamchange(self.playerid, self.team, 1);
1162
1163         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1164
1165         self.netname_previous = strzone(self.netname);
1166
1167         if(IS_PLAYER(self) && teamplay)
1168                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1169         else
1170                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1171
1172         stuffcmd(self, strcat(clientstuff, "\n"));
1173         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1174
1175         FixClientCvars(self);
1176
1177         // spawnfunc_waypoint sprites
1178         WaypointSprite_InitClient(self);
1179
1180         // Wazat's grappling hook
1181         SetGrappleHookBindings();
1182
1183         // Jetpack binds
1184         stuffcmd(self, "alias +jetpack +button10\n");
1185         stuffcmd(self, "alias -jetpack -button10\n");
1186
1187         // get version info from player
1188         stuffcmd(self, "cmd clientversion $gameversion\n");
1189
1190         // get other cvars from player
1191         GetCvars(0);
1192
1193         // notify about available teams
1194         if(teamplay)
1195         {
1196                 CheckAllowedTeams(self);
1197                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1198                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1199         }
1200         else
1201                 stuffcmd(self, "set _teams_available 0\n");
1202
1203         attach_entcs();
1204
1205         bot_relinkplayerlist();
1206
1207         self.spectatortime = time;
1208         if(blockSpectators)
1209         {
1210                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1211         }
1212
1213         self.jointime = time;
1214         self.allowed_timeouts = autocvar_sv_timeout_number;
1215
1216         if(IS_REAL_CLIENT(self))
1217         {
1218                 if(!autocvar_g_campaign)
1219                 {
1220                         self.motd_actived_time = -1;
1221                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1222                 }
1223
1224                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1225                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1226         }
1227
1228         if(!sv_foginterval && world.fog != "")
1229                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1230
1231         W_HitPlotOpen(self);
1232
1233         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1234                 send_CSQC_teamnagger();
1235
1236         CheatInitClient();
1237
1238         CSQCMODEL_AUTOINIT();
1239
1240         self.model_randomizer = random();
1241
1242         if(IS_REAL_CLIENT(self))
1243                 sv_notice_join();
1244
1245         MUTATOR_CALLHOOK(ClientConnect);
1246 }
1247 /*
1248 =============
1249 ClientDisconnect
1250
1251 Called when a client disconnects from the server
1252 =============
1253 */
1254 .entity chatbubbleentity;
1255 void ReadyCount();
1256 void ClientDisconnect (void)
1257 {
1258         if(self.vehicle)
1259             vehicles_exit(VHEF_RELESE);
1260
1261         if (!IS_CLIENT(self))
1262         {
1263                 print("Warning: ClientDisconnect without ClientConnect\n");
1264                 return;
1265         }
1266
1267         PlayerStats_GameReport_FinalizePlayer(self);
1268
1269         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1270
1271         CheatShutdownClient();
1272
1273         W_HitPlotClose(self);
1274
1275         anticheat_report();
1276         anticheat_shutdown();
1277
1278         playerdemo_shutdown();
1279
1280         bot_clientdisconnect();
1281
1282         if(self.entcs)
1283                 detach_entcs();
1284
1285         if(autocvar_sv_eventlog)
1286                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1287
1288         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1289
1290         MUTATOR_CALLHOOK(ClientDisconnect);
1291
1292         Portal_ClearAll(self);
1293
1294         Unfreeze(self);
1295
1296         RemoveGrapplingHook(self);
1297
1298         // Here, everything has been done that requires this player to be a client.
1299
1300         self.flags &= ~FL_CLIENT;
1301
1302         if (self.chatbubbleentity)
1303                 remove (self.chatbubbleentity);
1304
1305         if (self.killindicator)
1306                 remove (self.killindicator);
1307
1308         WaypointSprite_PlayerGone();
1309
1310         bot_relinkplayerlist();
1311
1312         accuracy_free(self);
1313         ClientData_Detach();
1314         PlayerScore_Detach(self);
1315
1316         if(self.netname_previous)
1317                 strunzone(self.netname_previous);
1318         if(self.clientstatus)
1319                 strunzone(self.clientstatus);
1320         if(self.weaponorder_byimpulse)
1321                 strunzone(self.weaponorder_byimpulse);
1322
1323         ClearPlayerSounds();
1324
1325         if(self.personal)
1326                 remove(self.personal);
1327
1328         self.playerid = 0;
1329         ReadyCount();
1330
1331         // free cvars
1332         GetCvars(-1);
1333 }
1334
1335 .float BUTTON_CHAT;
1336 void ChatBubbleThink()
1337 {
1338         self.nextthink = time;
1339         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1340         {
1341                 if(self.owner) // but why can that ever be world?
1342                         self.owner.chatbubbleentity = world;
1343                 remove(self);
1344                 return;
1345         }
1346         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1347 #ifdef TETRIS
1348                 || self.owner.tetris_on
1349 #endif
1350         )
1351                 self.model = self.mdl;
1352         else
1353                 self.model = "";
1354 }
1355
1356 void UpdateChatBubble()
1357 {
1358         if (self.alpha < 0)
1359                 return;
1360         // spawn a chatbubble entity if needed
1361         if (!self.chatbubbleentity)
1362         {
1363                 self.chatbubbleentity = spawn();
1364                 self.chatbubbleentity.owner = self;
1365                 self.chatbubbleentity.exteriormodeltoclient = self;
1366                 self.chatbubbleentity.think = ChatBubbleThink;
1367                 self.chatbubbleentity.nextthink = time;
1368                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1369                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1370                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs.z * '0 0 1');
1371                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1372                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1373                 self.chatbubbleentity.model = "";
1374                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1375         }
1376 }
1377
1378
1379 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1380 // added to the model skins
1381 /*void UpdateColorModHack()
1382 {
1383         float c;
1384         c = self.clientcolors & 15;
1385         // LordHavoc: only bothering to support white, green, red, yellow, blue
1386              if (!teamplay) self.colormod = '0 0 0';
1387         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1388         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1389         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1390         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1391         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1392         else self.colormod = '1 1 1';
1393 }*/
1394
1395 void respawn(void)
1396 {
1397         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1398         {
1399                 self.solid = SOLID_NOT;
1400                 self.takedamage = DAMAGE_NO;
1401                 self.movetype = MOVETYPE_FLY;
1402                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1403                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1404                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1405                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1406                 if(autocvar_g_respawn_ghosts_maxtime)
1407                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1408         }
1409
1410         CopyBody(1);
1411
1412         self.effects |= EF_NODRAW; // prevent another CopyBody
1413         PutClientInServer();
1414 }
1415
1416 void play_countdown(float finished, string samp)
1417 {
1418         if(IS_REAL_CLIENT(self))
1419                 if(floor(finished - time - frametime) != floor(finished - time))
1420                         if(finished - time < 6)
1421                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1422 }
1423
1424 void player_powerups (void)
1425 {
1426         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1427         olditems = self.items;
1428
1429         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1430                 self.modelflags |= MF_ROCKET;
1431         else
1432                 self.modelflags &= ~MF_ROCKET;
1433
1434         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1435
1436         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1437                 return;
1438
1439         Fire_ApplyDamage(self);
1440         Fire_ApplyEffect(self);
1441
1442         if (!g_instagib)
1443         {
1444                 if (self.items & IT_STRENGTH)
1445                 {
1446                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1447                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1448                         if (time > self.strength_finished)
1449                         {
1450                                 self.items = self.items - (self.items & IT_STRENGTH);
1451                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1452                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1453                         }
1454                 }
1455                 else
1456                 {
1457                         if (time < self.strength_finished)
1458                         {
1459                                 self.items = self.items | IT_STRENGTH;
1460                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1461                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1462                         }
1463                 }
1464                 if (self.items & IT_INVINCIBLE)
1465                 {
1466                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1467                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1468                         if (time > self.invincible_finished)
1469                         {
1470                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1471                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1472                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1473                         }
1474                 }
1475                 else
1476                 {
1477                         if (time < self.invincible_finished)
1478                         {
1479                                 self.items = self.items | IT_INVINCIBLE;
1480                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1481                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1482                         }
1483                 }
1484                 if (self.items & IT_SUPERWEAPON)
1485                 {
1486                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1487                         {
1488                                 self.superweapons_finished = 0;
1489                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1490                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1491                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1492                         }
1493                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1494                         {
1495                                 // don't let them run out
1496                         }
1497                         else
1498                         {
1499                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1500                                 if (time > self.superweapons_finished)
1501                                 {
1502                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1503                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1504                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1505                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1506                                 }
1507                         }
1508                 }
1509                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1510                 {
1511                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1512                         {
1513                                 self.items = self.items | IT_SUPERWEAPON;
1514                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1515                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1516                         }
1517                         else
1518                         {
1519                                 self.superweapons_finished = 0;
1520                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1521                         }
1522                 }
1523                 else
1524                 {
1525                         self.superweapons_finished = 0;
1526                 }
1527         }
1528
1529         if(autocvar_g_nodepthtestplayers)
1530                 self.effects = self.effects | EF_NODEPTHTEST;
1531
1532         if(autocvar_g_fullbrightplayers)
1533                 self.effects = self.effects | EF_FULLBRIGHT;
1534
1535         if (time >= game_starttime)
1536         if (time < self.spawnshieldtime)
1537                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1538
1539         MUTATOR_CALLHOOK(PlayerPowerups);
1540 }
1541
1542 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1543 {
1544         if(current > stable)
1545                 return current;
1546         else if(current > stable - 0.25) // when close enough, "snap"
1547                 return stable;
1548         else
1549                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1550 }
1551
1552 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1553 {
1554         if(current < stable)
1555                 return current;
1556         else if(current < stable + 0.25) // when close enough, "snap"
1557                 return stable;
1558         else
1559                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1560 }
1561
1562 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1563 {
1564         if(current > rotstable)
1565         {
1566                 if(rotframetime > 0)
1567                 {
1568                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1569                         current = max(rotstable, current - rotlinear * rotframetime);
1570                 }
1571         }
1572         else if(current < regenstable)
1573         {
1574                 if(regenframetime > 0)
1575                 {
1576                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1577                         current = min(regenstable, current + regenlinear * regenframetime);
1578                 }
1579         }
1580
1581         if(current > limit)
1582                 current = limit;
1583
1584         return current;
1585 }
1586
1587 void player_regen (void)
1588 {
1589         float max_mod, regen_mod, rot_mod, limit_mod;
1590         max_mod = regen_mod = rot_mod = limit_mod = 1;
1591         regen_mod_max = max_mod;
1592         regen_mod_regen = regen_mod;
1593         regen_mod_rot = rot_mod;
1594         regen_mod_limit = limit_mod;
1595         if(!MUTATOR_CALLHOOK(PlayerRegen))
1596         if(!self.frozen)
1597         {
1598                 float minh, mina, maxh, maxa, limith, limita;
1599                 maxh = autocvar_g_balance_health_rotstable;
1600                 maxa = autocvar_g_balance_armor_rotstable;
1601                 minh = autocvar_g_balance_health_regenstable;
1602                 mina = autocvar_g_balance_armor_regenstable;
1603                 limith = autocvar_g_balance_health_limit;
1604                 limita = autocvar_g_balance_armor_limit;
1605
1606                 max_mod = regen_mod_max;
1607                 regen_mod = regen_mod_regen;
1608                 rot_mod = regen_mod_rot;
1609                 limit_mod = regen_mod_limit;
1610
1611                 maxh = maxh * max_mod;
1612                 minh = minh * max_mod;
1613                 limith = limith * limit_mod;
1614                 limita = limita * limit_mod;
1615
1616                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1617                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1618         }
1619
1620         // if player rotted to death...  die!
1621         // check this outside above checks, as player may still be able to rot to death
1622         if(self.health < 1)
1623                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1624
1625         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1626         {
1627                 float minf, maxf, limitf;
1628
1629                 maxf = autocvar_g_balance_fuel_rotstable;
1630                 minf = autocvar_g_balance_fuel_regenstable;
1631                 limitf = autocvar_g_balance_fuel_limit;
1632
1633                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1634         }
1635 }
1636
1637 float zoomstate_set;
1638 void SetZoomState(float z)
1639 {
1640         if(z != self.zoomstate)
1641         {
1642                 self.zoomstate = z;
1643                 ClientData_Touch(self);
1644         }
1645         zoomstate_set = 1;
1646 }
1647
1648 void GetPressedKeys(void) {
1649         MUTATOR_CALLHOOK(GetPressedKeys);
1650         if (self.movement.x > 0) // get if movement keys are pressed
1651         {       // forward key pressed
1652                 self.pressedkeys |= KEY_FORWARD;
1653                 self.pressedkeys &= ~KEY_BACKWARD;
1654         }
1655         else if (self.movement.x < 0)
1656         {       // backward key pressed
1657                 self.pressedkeys |= KEY_BACKWARD;
1658                 self.pressedkeys &= ~KEY_FORWARD;
1659         }
1660         else
1661         {       // no x input
1662                 self.pressedkeys &= ~KEY_FORWARD;
1663                 self.pressedkeys &= ~KEY_BACKWARD;
1664         }
1665
1666         if (self.movement.y > 0)
1667         {       // right key pressed
1668                 self.pressedkeys |= KEY_RIGHT;
1669                 self.pressedkeys &= ~KEY_LEFT;
1670         }
1671         else if (self.movement.y < 0)
1672         {       // left key pressed
1673                 self.pressedkeys |= KEY_LEFT;
1674                 self.pressedkeys &= ~KEY_RIGHT;
1675         }
1676         else
1677         {       // no y input
1678                 self.pressedkeys &= ~KEY_RIGHT;
1679                 self.pressedkeys &= ~KEY_LEFT;
1680         }
1681
1682         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1683                 self.pressedkeys |= KEY_JUMP;
1684         else
1685                 self.pressedkeys &= ~KEY_JUMP;
1686         if (self.BUTTON_CROUCH)
1687                 self.pressedkeys |= KEY_CROUCH;
1688         else
1689                 self.pressedkeys &= ~KEY_CROUCH;
1690
1691         if (self.BUTTON_ATCK)
1692                 self.pressedkeys |= KEY_ATCK;
1693         else
1694                 self.pressedkeys &= ~KEY_ATCK;
1695         if (self.BUTTON_ATCK2)
1696                 self.pressedkeys |= KEY_ATCK2;
1697         else
1698                 self.pressedkeys &= ~KEY_ATCK2;
1699 }
1700
1701 /*
1702 ======================
1703 spectate mode routines
1704 ======================
1705 */
1706
1707 void SpectateCopy(entity spectatee) {
1708         other = spectatee;
1709         MUTATOR_CALLHOOK(SpectateCopy);
1710         self.armortype = spectatee.armortype;
1711         self.armorvalue = spectatee.armorvalue;
1712         self.ammo_cells = spectatee.ammo_cells;
1713         self.ammo_plasma = spectatee.ammo_plasma;
1714         self.ammo_shells = spectatee.ammo_shells;
1715         self.ammo_nails = spectatee.ammo_nails;
1716         self.ammo_rockets = spectatee.ammo_rockets;
1717         self.ammo_fuel = spectatee.ammo_fuel;
1718         self.clip_load = spectatee.clip_load;
1719         self.clip_size = spectatee.clip_size;
1720         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1721         self.health = spectatee.health;
1722         self.impulse = 0;
1723         self.items = spectatee.items;
1724         self.last_pickup = spectatee.last_pickup;
1725         self.hit_time = spectatee.hit_time;
1726         self.metertime = spectatee.metertime;
1727         self.strength_finished = spectatee.strength_finished;
1728         self.invincible_finished = spectatee.invincible_finished;
1729         self.pressedkeys = spectatee.pressedkeys;
1730         self.weapons = spectatee.weapons;
1731         self.switchweapon = spectatee.switchweapon;
1732         self.switchingweapon = spectatee.switchingweapon;
1733         self.weapon = spectatee.weapon;
1734         self.vortex_charge = spectatee.vortex_charge;
1735         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1736         self.hagar_load = spectatee.hagar_load;
1737         self.arc_heat_percent = spectatee.arc_heat_percent;
1738         self.minelayer_mines = spectatee.minelayer_mines;
1739         self.punchangle = spectatee.punchangle;
1740         self.view_ofs = spectatee.view_ofs;
1741         self.velocity = spectatee.velocity;
1742         self.dmg_take = spectatee.dmg_take;
1743         self.dmg_save = spectatee.dmg_save;
1744         self.dmg_inflictor = spectatee.dmg_inflictor;
1745         self.v_angle = spectatee.v_angle;
1746         self.angles = spectatee.v_angle;
1747         self.frozen = spectatee.frozen;
1748         self.revive_progress = spectatee.revive_progress;
1749         if(!self.BUTTON_USE)
1750                 self.fixangle = true;
1751         setorigin(self, spectatee.origin);
1752         setsize(self, spectatee.mins, spectatee.maxs);
1753         SetZoomState(spectatee.zoomstate);
1754
1755     anticheat_spectatecopy(spectatee);
1756         self.hud = spectatee.hud;
1757         if(spectatee.vehicle)
1758     {
1759         self.fixangle = false;
1760         //self.velocity = spectatee.vehicle.velocity;
1761         self.vehicle_health = spectatee.vehicle_health;
1762         self.vehicle_shield = spectatee.vehicle_shield;
1763         self.vehicle_energy = spectatee.vehicle_energy;
1764         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1765         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1766         self.vehicle_reload1 = spectatee.vehicle_reload1;
1767         self.vehicle_reload2 = spectatee.vehicle_reload2;
1768
1769         msg_entity = self;
1770
1771         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1772             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1773             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1774             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1775
1776         //WriteByte (MSG_ONE, SVC_SETVIEW);
1777         //    WriteEntity(MSG_ONE, self);
1778         //makevectors(spectatee.v_angle);
1779         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1780     }
1781 }
1782
1783 float SpectateUpdate()
1784 {
1785         if(!self.enemy)
1786             return 0;
1787
1788         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1789         {
1790                 SetSpectator(self, world);
1791                 return 0;
1792         }
1793
1794         SpectateCopy(self.enemy);
1795
1796         return 1;
1797 }
1798
1799 float SpectateSet()
1800 {
1801         if(self.enemy.classname != "player")
1802                 return false;
1803         /*if(self.enemy.vehicle)
1804         {
1805
1806                 msg_entity = self;
1807                 WriteByte(MSG_ONE, SVC_SETVIEW);
1808                 WriteEntity(MSG_ONE, self.enemy);
1809                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1810
1811                 self.movetype = MOVETYPE_NONE;
1812                 accuracy_resend(self);
1813         }
1814         else
1815         {*/
1816                 msg_entity = self;
1817                 WriteByte(MSG_ONE, SVC_SETVIEW);
1818                 WriteEntity(MSG_ONE, self.enemy);
1819                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1820                 self.movetype = MOVETYPE_NONE;
1821                 accuracy_resend(self);
1822
1823                 if(!SpectateUpdate())
1824                         PutObserverInServer();
1825         //}
1826         return true;
1827 }
1828
1829 void SetSpectator(entity player, entity spectatee)
1830 {
1831         entity old_spectatee = player.enemy;
1832
1833         player.enemy = spectatee;
1834
1835         // WEAPONTODO
1836         // these are required to fix the spectator bug with arc
1837         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1838         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1839 }
1840
1841 float Spectate(entity pl)
1842 {
1843         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1844         if(pl.team != self.team)
1845                 return 0;
1846
1847         SetSpectator(self, pl);
1848         return SpectateSet();
1849 }
1850
1851 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1852 entity CA_SpectateNext(entity start) {
1853         if (start.team == self.team) {
1854                 return start;
1855         }
1856
1857         other = start;
1858         // continue from current player
1859         while(other && other.team != self.team) {
1860                 other = find(other, classname, "player");
1861         }
1862
1863         if (!other) {
1864                 // restart from begining
1865                 other = find(other, classname, "player");
1866                 while(other && other.team != self.team) {
1867                         other = find(other, classname, "player");
1868                 }
1869         }
1870
1871         return other;
1872 }
1873
1874 float SpectateNext()
1875 {
1876         other = find(self.enemy, classname, "player");
1877
1878         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1879                 // CA and ca players when spectating enemies is forbidden
1880                 other = CA_SpectateNext(other);
1881         } else {
1882                 // other modes and ca spectators or spectating enemies is allowed
1883                 if (!other)
1884                         other = find(other, classname, "player");
1885         }
1886
1887         if(other) { SetSpectator(self, other); }
1888
1889         return SpectateSet();
1890 }
1891
1892 float SpectatePrev()
1893 {
1894         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1895         other = findchain(classname, "player");
1896         if (!other) // no player
1897                 return false;
1898
1899         entity first = other;
1900         // skip players until current spectated player
1901         if(self.enemy)
1902         while(other && other != self.enemy)
1903                 other = other.chain;
1904
1905         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1906         {
1907                 do { other = other.chain; }
1908                 while(other && other.team != self.team);
1909
1910                 if (!other)
1911                 {
1912                         other = first;
1913                         while(other.team != self.team)
1914                                 other = other.chain;
1915                         if(other == self.enemy)
1916                                 return true;
1917                 }
1918         }
1919         else
1920         {
1921                 if(other.chain)
1922                         other = other.chain;
1923                 else
1924                         other = first;
1925         }
1926         SetSpectator(self, other);
1927         return SpectateSet();
1928 }
1929
1930 /*
1931 =============
1932 ShowRespawnCountdown()
1933
1934 Update a respawn countdown display.
1935 =============
1936 */
1937 void ShowRespawnCountdown()
1938 {
1939         float number;
1940         if(self.deadflag == DEAD_NO) // just respawned?
1941                 return;
1942         else
1943         {
1944                 number = ceil(self.respawn_time - time);
1945                 if(number <= 0)
1946                         return;
1947                 if(number <= self.respawn_countdown)
1948                 {
1949                         self.respawn_countdown = number - 1;
1950                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1951                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1952                 }
1953         }
1954 }
1955
1956 void LeaveSpectatorMode()
1957 {
1958         if(self.caplayer)
1959                 return;
1960         if(nJoinAllowed(self))
1961         {
1962                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1963                 {
1964                         self.classname = "player";
1965                         nades_RemoveBonus(self);
1966
1967                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1968                                 { JoinBestTeam(self, false, true); }
1969
1970                         if(autocvar_g_campaign)
1971                                 { campaign_bots_may_start = 1; }
1972
1973                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1974
1975                         PutClientInServer();
1976
1977                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1978                 }
1979                 else
1980                         stuffcmd(self, "menu_showteamselect\n");
1981         }
1982         else
1983         {
1984                 // Player may not join because g_maxplayers is set
1985                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1986         }
1987 }
1988
1989 /**
1990  * Determines whether the player is allowed to join. This depends on cvar
1991  * g_maxplayers, if it isn't used this function always return true, otherwise
1992  * it checks whether the number of currently playing players exceeds g_maxplayers.
1993  * @return int number of free slots for players, 0 if none
1994  */
1995 float nJoinAllowed(entity ignore) {
1996         if(!ignore)
1997         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1998         // so report 0 free slots if restricted
1999         {
2000                 if(autocvar_g_forced_team_otherwise == "spectate")
2001                         return 0;
2002                 if(autocvar_g_forced_team_otherwise == "spectator")
2003                         return 0;
2004         }
2005
2006         if(self.team_forced < 0)
2007                 return 0; // forced spectators can never join
2008
2009         // TODO simplify this
2010         entity e;
2011         float totalClients = 0;
2012         FOR_EACH_CLIENT(e)
2013                 if(e != ignore)
2014                         totalClients += 1;
2015
2016         if (!autocvar_g_maxplayers)
2017                 return maxclients - totalClients;
2018
2019         float currentlyPlaying = 0;
2020         FOR_EACH_REALCLIENT(e)
2021                 if(IS_PLAYER(e) || e.caplayer)
2022                         currentlyPlaying += 1;
2023
2024         if(currentlyPlaying < autocvar_g_maxplayers)
2025                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2026
2027         return 0;
2028 }
2029
2030 /**
2031  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2032  * g_maxplayers_spectator_blocktime seconds
2033  */
2034 void checkSpectatorBlock() {
2035         if(IS_SPEC(self) || IS_OBSERVER(self))
2036         if(!self.caplayer)
2037         if(IS_REAL_CLIENT(self))
2038         {
2039                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2040                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2041                         dropclient(self);
2042                 }
2043         }
2044 }
2045
2046 void PrintWelcomeMessage()
2047 {
2048         if(self.motd_actived_time == 0)
2049         {
2050                 if (autocvar_g_campaign) {
2051                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2052                                 self.motd_actived_time = time;
2053                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2054                         }
2055                 } else {
2056                         if (self.BUTTON_INFO) {
2057                                 self.motd_actived_time = time;
2058                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2059                         }
2060                 }
2061         }
2062         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2063         {
2064                 if (autocvar_g_campaign) {
2065                         if (self.BUTTON_INFO)
2066                                 self.motd_actived_time = time;
2067                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2068                                 self.motd_actived_time = 0;
2069                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2070                         }
2071                 } else {
2072                         if (self.BUTTON_INFO)
2073                                 self.motd_actived_time = time;
2074                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2075                                 self.motd_actived_time = 0;
2076                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2077                         }
2078                 }
2079         }
2080         else //if(self.motd_actived_time < 0) // just connected, motd is active
2081         {
2082                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2083                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2084                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2085                 {
2086                         // instanctly hide MOTD
2087                         self.motd_actived_time = 0;
2088                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2089                 }
2090         }
2091 }
2092
2093 void ObserverThink()
2094 {
2095         float prefered_movetype;
2096         if (self.flags & FL_JUMPRELEASED) {
2097                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2098                         self.flags &= ~FL_JUMPRELEASED;
2099                         self.flags |= FL_SPAWNING;
2100                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2101                         self.flags &= ~FL_JUMPRELEASED;
2102                         if(SpectateNext()) {
2103                                 self.classname = "spectator";
2104                         }
2105                 } else {
2106                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2107                         if (self.movetype != prefered_movetype)
2108                                 self.movetype = prefered_movetype;
2109                 }
2110         } else {
2111                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2112                         self.flags |= FL_JUMPRELEASED;
2113                         if(self.flags & FL_SPAWNING)
2114                         {
2115                                 self.flags &= ~FL_SPAWNING;
2116                                 LeaveSpectatorMode();
2117                                 return;
2118                         }
2119                 }
2120         }
2121 }
2122
2123 void SpectatorThink()
2124 {
2125         if (self.flags & FL_JUMPRELEASED) {
2126                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2127                         self.flags &= ~FL_JUMPRELEASED;
2128                         self.flags |= FL_SPAWNING;
2129                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2130                         self.flags &= ~FL_JUMPRELEASED;
2131                         if(SpectateNext()) {
2132                                 self.classname = "spectator";
2133                         } else {
2134                                 self.classname = "observer";
2135                                 PutClientInServer();
2136                         }
2137                         self.impulse = 0;
2138                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2139                         self.flags &= ~FL_JUMPRELEASED;
2140                         if(SpectatePrev()) {
2141                                 self.classname = "spectator";
2142                         } else {
2143                                 self.classname = "observer";
2144                                 PutClientInServer();
2145                         }
2146                         self.impulse = 0;
2147                 } else if (self.BUTTON_ATCK2) {
2148                         self.flags &= ~FL_JUMPRELEASED;
2149                         self.classname = "observer";
2150                         PutClientInServer();
2151                 } else {
2152                         if(!SpectateUpdate())
2153                                 PutObserverInServer();
2154                 }
2155         } else {
2156                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2157                         self.flags |= FL_JUMPRELEASED;
2158                         if(self.flags & FL_SPAWNING)
2159                         {
2160                                 self.flags &= ~FL_SPAWNING;
2161                                 LeaveSpectatorMode();
2162                                 return;
2163                         }
2164                 }
2165                 if(!SpectateUpdate())
2166                         PutObserverInServer();
2167         }
2168
2169         self.flags |= FL_CLIENT | FL_NOTARGET;
2170 }
2171
2172 void PlayerUseKey()
2173 {
2174         if (!IS_PLAYER(self))
2175                 return;
2176
2177         if(self.vehicle)
2178         {
2179         vehicles_exit(VHEF_NORMAL);
2180         return;
2181         }
2182
2183         // a use key was pressed; call handlers
2184         MUTATOR_CALLHOOK(PlayerUseKey);
2185 }
2186
2187 float isInvisibleString(string s)
2188 {
2189         float i, n, c;
2190         s = strdecolorize(s);
2191         for((i = 0), (n = strlen(s)); i < n; ++i)
2192         {
2193                 c = str2chr(s, i);
2194                 switch(c)
2195                 {
2196                         case 0:
2197                         case 32: // space
2198                                 break;
2199                         case 192: // charmap space
2200                                 if (!autocvar_utf8_enable)
2201                                         break;
2202                                 return false;
2203                         case 160: // space in unicode fonts
2204                         case 0xE000 + 192: // utf8 charmap space
2205                                 if (autocvar_utf8_enable)
2206                                         break;
2207                         default:
2208                                 return false;
2209                 }
2210         }
2211         return true;
2212 }
2213
2214 /*
2215 =============
2216 PlayerPreThink
2217
2218 Called every frame for each client before the physics are run
2219 =============
2220 */
2221 .float usekeypressed;
2222 void() nexball_setstatus;
2223 .float items_added;
2224 void PlayerPreThink (void)
2225 {
2226         WarpZone_PlayerPhysics_FixVAngle();
2227
2228         self.stat_game_starttime = game_starttime;
2229         self.stat_round_starttime = round_starttime;
2230         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2231         self.stat_leadlimit = autocvar_leadlimit;
2232
2233         if(frametime)
2234         {
2235                 // physics frames: update anticheat stuff
2236                 anticheat_prethink();
2237         }
2238
2239         if(blockSpectators && frametime)
2240                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2241                 checkSpectatorBlock();
2242
2243         zoomstate_set = 0;
2244
2245         // Savage: Check for nameless players
2246         if (isInvisibleString(self.netname)) {
2247                 string new_name = strzone(strcat("Player@", self.netaddress));
2248                 if(autocvar_sv_eventlog)
2249                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2250                 if(self.netname_previous)
2251                         strunzone(self.netname_previous);
2252                 self.netname_previous = strzone(new_name);
2253                 self.netname = self.netname_previous;
2254                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2255         } else if(self.netname_previous != self.netname) {
2256                 if(autocvar_sv_eventlog)
2257                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2258                 if(self.netname_previous)
2259                         strunzone(self.netname_previous);
2260                 self.netname_previous = strzone(self.netname);
2261         }
2262
2263         // version nagging
2264         if(self.version_nagtime)
2265                 if(self.cvar_g_xonoticversion)
2266                         if(time > self.version_nagtime)
2267                         {
2268                                 // don't notify git users
2269                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2270                                 {
2271                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2272                                         {
2273                                                 // notify release users if connecting to git
2274                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2275                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2276                                         }
2277                                         else
2278                                         {
2279                                                 float r;
2280                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2281                                                 if(r < 0)
2282                                                 {
2283                                                         // give users new version
2284                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2285                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2286                                                 }
2287                                                 else if(r > 0)
2288                                                 {
2289                                                         // notify users about old server version
2290                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2291                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2292                                                 }
2293                                         }
2294                                 }
2295                                 self.version_nagtime = 0;
2296                         }
2297
2298         // GOD MODE info
2299         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2300         {
2301                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2302                 self.max_armorvalue = 0;
2303         }
2304
2305 #ifdef TETRIS
2306         if (TetrisPreFrame())
2307                 return;
2308 #endif
2309
2310         if(self.frozen == 2)
2311         {
2312                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2313                 self.health = max(1, self.revive_progress * start_health);
2314                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2315
2316                 if(self.revive_progress >= 1)
2317                         Unfreeze(self);
2318         }
2319         else if(self.frozen == 3)
2320         {
2321                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2322                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2323
2324                 if(self.health < 1)
2325                 {
2326                         if(self.vehicle)
2327                                 vehicles_exit(VHEF_RELESE);
2328                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2329                 }
2330                 else if ( self.revive_progress <= 0 )
2331                         Unfreeze(self);
2332         }
2333
2334         MUTATOR_CALLHOOK(PlayerPreThink);
2335
2336         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2337         {
2338                 if(self.BUTTON_USE && !self.usekeypressed)
2339                         PlayerUseKey();
2340                 self.usekeypressed = self.BUTTON_USE;
2341         }
2342
2343         if(IS_REAL_CLIENT(self))
2344                 PrintWelcomeMessage();
2345
2346         if(IS_PLAYER(self))
2347         {
2348
2349                 CheckRules_Player();
2350
2351                 if (intermission_running)
2352                 {
2353                         IntermissionThink ();   // otherwise a button could be missed between
2354                         return;                                 // the think tics
2355                 }
2356
2357                 //don't allow the player to turn around while game is paused!
2358                 if(timeout_status == TIMEOUT_ACTIVE) {
2359                         // FIXME turn this into CSQC stuff
2360                         self.v_angle = self.lastV_angle;
2361                         self.angles = self.lastV_angle;
2362                         self.fixangle = true;
2363                 }
2364
2365                 if(frametime)
2366                 {
2367                         if(self.weapon == WEP_VORTEX && WEP_CVAR(vortex, charge))
2368                         {
2369                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2370                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2371                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2372
2373                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2374                                 {
2375                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2376                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2377                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2378                                 }
2379                         }
2380                         else
2381                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2382
2383                         player_powerups();
2384                 }
2385
2386                 if (self.deadflag != DEAD_NO)
2387                 {
2388                         if(self.personal && g_race_qualifying)
2389                         {
2390                                 if(time > self.respawn_time)
2391                                 {
2392                                         self.respawn_time = time + 1; // only retry once a second
2393                                         self.stat_respawn_time = self.respawn_time;
2394                                         respawn();
2395                                         self.impulse = 141;
2396                                 }
2397                         }
2398                         else
2399                         {
2400                                 float button_pressed;
2401                                 if(frametime)
2402                                         player_anim();
2403                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2404
2405                                 if (self.deadflag == DEAD_DYING)
2406                                 {
2407                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2408                                                 self.deadflag = DEAD_RESPAWNING;
2409                                         else if(!button_pressed)
2410                                                 self.deadflag = DEAD_DEAD;
2411                                 }
2412                                 else if (self.deadflag == DEAD_DEAD)
2413                                 {
2414                                         if(button_pressed)
2415                                                 self.deadflag = DEAD_RESPAWNABLE;
2416                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2417                                                 self.deadflag = DEAD_RESPAWNING;
2418                                 }
2419                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2420                                 {
2421                                         if(!button_pressed)
2422                                                 self.deadflag = DEAD_RESPAWNING;
2423                                 }
2424                                 else if (self.deadflag == DEAD_RESPAWNING)
2425                                 {
2426                                         if(time > self.respawn_time)
2427                                         {
2428                                                 self.respawn_time = time + 1; // only retry once a second
2429                                                 self.respawn_time_max = self.respawn_time;
2430                                                 respawn();
2431                                         }
2432                                 }
2433
2434                                 ShowRespawnCountdown();
2435
2436                                 if(self.respawn_flags & RESPAWN_SILENT)
2437                                         self.stat_respawn_time = 0;
2438                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2439                                         self.stat_respawn_time = self.respawn_time_max;
2440                                 else
2441                                         self.stat_respawn_time = self.respawn_time;
2442                         }
2443
2444                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2445                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2446                                 self.stat_respawn_time *= -1;
2447
2448                         return;
2449                 }
2450
2451                 self.prevorigin = self.origin;
2452
2453                 float do_crouch = self.BUTTON_CROUCH;
2454                 if(self.hook.state)
2455                         do_crouch = 0;
2456                 if(self.vehicle)
2457                         do_crouch = 0;
2458                 if(self.frozen)
2459                         do_crouch = 0;
2460
2461                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2462                 // It cannot be predicted by the engine!
2463                 if((self.weapon == WEP_SHOCKWAVE || self.weapon == WEP_SHOTGUN) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2464                         do_crouch = 0;
2465
2466                 if (do_crouch)
2467                 {
2468                         if (!self.crouch)
2469                         {
2470                                 self.crouch = true;
2471                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2472                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2473                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2474                         }
2475                 }
2476                 else
2477                 {
2478                         if (self.crouch)
2479                         {
2480                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, false, self);
2481                                 if (!trace_startsolid)
2482                                 {
2483                                         self.crouch = false;
2484                                         self.view_ofs = PL_VIEW_OFS;
2485                                         setsize (self, PL_MIN, PL_MAX);
2486                                 }
2487                         }
2488                 }
2489
2490                 FixPlayermodel();
2491
2492                 GrapplingHookFrame();
2493
2494                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2495                 //if(frametime)
2496                 {
2497                         self.items &= ~self.items_added;
2498
2499                         W_WeaponFrame();
2500
2501                         self.items_added = 0;
2502                         if(self.items & IT_JETPACK)
2503                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2504                                         self.items_added |= IT_FUEL;
2505
2506                         self.items |= self.items_added;
2507                 }
2508
2509                 player_regen();
2510
2511                 // WEAPONTODO: Add a weapon request for this
2512                 // rot vortex charge to the charge limit
2513                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2514                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2515
2516                 if(frametime)
2517                         player_anim();
2518
2519                 // secret status
2520                 secrets_setstatus();
2521
2522                 // monsters status
2523                 monsters_setstatus();
2524
2525                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2526
2527                 //self.angles_y=self.v_angle_y + 90;   // temp
2528         } else if(gameover) {
2529                 if (intermission_running)
2530                         IntermissionThink ();   // otherwise a button could be missed between
2531                 return;
2532         } else if(IS_OBSERVER(self)) {
2533                 ObserverThink();
2534         } else if(IS_SPEC(self)) {
2535                 SpectatorThink();
2536         }
2537
2538         // WEAPONTODO: Add weapon request for this
2539         if(!zoomstate_set)
2540                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2541
2542         float oldspectatee_status;
2543         oldspectatee_status = self.spectatee_status;
2544         if(IS_SPEC(self))
2545                 self.spectatee_status = num_for_edict(self.enemy);
2546         else if(IS_OBSERVER(self))
2547                 self.spectatee_status = num_for_edict(self);
2548         else
2549                 self.spectatee_status = 0;
2550         if(self.spectatee_status != oldspectatee_status)
2551         {
2552                 ClientData_Touch(self);
2553         }
2554
2555         if(self.teamkill_soundtime)
2556         if(time > self.teamkill_soundtime)
2557         {
2558                 self.teamkill_soundtime = 0;
2559
2560                 entity oldpusher, oldself;
2561
2562                 oldself = self; self = self.teamkill_soundsource;
2563                 oldpusher = self.pusher; self.pusher = oldself;
2564
2565                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2566
2567                 self.pusher = oldpusher;
2568                 self = oldself;
2569         }
2570
2571         if(self.taunt_soundtime)
2572         if(time > self.taunt_soundtime)
2573         {
2574                 self.taunt_soundtime = 0;
2575                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2576         }
2577
2578         target_voicescript_next(self);
2579
2580         // WEAPONTODO: Move into weaponsystem somehow
2581         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2582         if(!self.weapon)
2583                 self.clip_load = self.clip_size = 0;
2584 }
2585
2586 /*
2587 =============
2588 PlayerPostThink
2589
2590 Called every frame for each client after the physics are run
2591 =============
2592 */
2593 .float idlekick_lasttimeleft;
2594 void PlayerPostThink (void)
2595 {
2596         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2597         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2598         {
2599                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2600                 {
2601                         if(self.idlekick_lasttimeleft)
2602                         {
2603                                 self.idlekick_lasttimeleft = 0;
2604                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2605                         }
2606                 }
2607                 else
2608                 {
2609                         float timeleft;
2610                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2611                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2612                         {
2613                                 if(!self.idlekick_lasttimeleft)
2614                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2615                         }
2616                         if(timeleft <= 0)
2617                         {
2618                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2619                                 dropclient(self);
2620                                 return;
2621                         }
2622                         else if(timeleft <= 10)
2623                         {
2624                                 if(timeleft != self.idlekick_lasttimeleft)
2625                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2626                                 self.idlekick_lasttimeleft = timeleft;
2627                         }
2628                 }
2629         }
2630
2631 #ifdef TETRIS
2632         if(self.impulse == 100)
2633                 ImpulseCommands();
2634         if (!TetrisPostFrame())
2635         {
2636 #endif
2637
2638         CheatFrame();
2639
2640         //CheckPlayerJump();
2641
2642         if(IS_PLAYER(self)) {
2643                 CheckRules_Player();
2644                 UpdateChatBubble();
2645                 if (self.impulse)
2646                         ImpulseCommands();
2647                 if (intermission_running)
2648                         return;         // intermission or finale
2649                 GetPressedKeys();
2650         }
2651
2652 #ifdef TETRIS
2653         }
2654 #endif
2655
2656         /*
2657         float i;
2658         for(i = 0; i < 1000; ++i)
2659         {
2660                 vector end;
2661                 end = self.origin + '0 0 1024' + 512 * randomvec();
2662                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2663                 if(trace_fraction < 1)
2664                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2665                 {
2666                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2667                         break;
2668                 }
2669         }
2670         */
2671
2672         if(self.waypointsprite_attachedforcarrier)
2673                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2674
2675         playerdemo_write();
2676
2677         CSQCMODEL_AUTOUPDATE();
2678 }