qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(0, SVC_TEMPENTITY);
   6         WriteByte(0, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 void Announce(string snd) {
  10         WriteByte(MSG_ALL, SVC_TEMPENTITY);
  11         WriteByte(MSG_ALL, TE_CSQC_ANNOUNCE);
  12         WriteString(MSG_ALL, snd);
  13 }
  14
  15 void AnnounceTo(entity e, string snd) {
  16         if (clienttype(e) == CLIENTTYPE_REAL)
  17         {
  18                 msg_entity = e;
  19                 WriteByte(MSG_ONE, SVC_TEMPENTITY);
  20                 WriteByte(MSG_ONE, TE_CSQC_ANNOUNCE);
  21                 WriteString(MSG_ONE, snd);
  22         }
  23 }
  24
  25 float ClientData_Send(entity to, float sf)
  26 {
  27         if(to != self.owner)
  28         {
  29                 error("wtf");
  30                 return FALSE;
  31         }
  32
  33         entity e;
  34
  35         e = to;
  36         if(to.classname == "spectator")
  37                 e = to.enemy;
  38
  39         sf = 0;
  40
  41         if(e.race_completed)
  42                 sf |= 1; // forced scoreboard
  43         if(to.spectatee_status)
  44                 sf |= 2; // spectator ent number follows
  45         if(e.zoomstate)
  46                 sf |= 4; // zoomed
  47         if(e.porto_v_angle_held)
  48                 sf |= 8; // angles held
  49
  50         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  51         WriteByte(MSG_ENTITY, sf);
  52
  53         if(sf & 2)
  54                 WriteByte(MSG_ENTITY, to.spectatee_status);
  55
  56         if(sf & 8)
  57         {
  58                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  59                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  60         }
  61
  62         return TRUE;
  63 }
  64
  65 void ClientData_Attach()
  66 {
  67         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  68         self.clientdata.drawonlytoclient = self;
  69         self.clientdata.owner = self;
  70 }
  71
  72 void ClientData_Detach()
  73 {
  74         remove(self.clientdata);
  75         self.clientdata = world;
  76 }
  77
  78 void ClientData_Touch(entity e)
  79 {
  80         e.clientdata.SendFlags = 1;
  81
  82         // make it spectatable
  83         entity e2;
  84         FOR_EACH_REALCLIENT(e2)
  85         {
  86                 if(e2 != e)
  87                         if(e2.classname == "spectator")
  88                                 if(e2.enemy == e)
  89                                         e2.clientdata.SendFlags = 1;
  90         }
  91 }
  92
  93
  94 .vector spawnpoint_score;
  95 .string netname_previous;
  96
  97 void spawnfunc_info_player_survivor (void)
  98 {
  99         spawnfunc_info_player_deathmatch();
 100 }
 101
 102 void spawnfunc_info_player_start (void)
 103 {
 104         spawnfunc_info_player_deathmatch();
 105 }
 106
 107 void spawnfunc_info_player_deathmatch (void)
 108 {
 109         self.classname = "info_player_deathmatch";
 110         relocate_spawnpoint();
 111 }
 112
 113 void spawnpoint_use()
 114 {
 115         if(teams_matter)
 116         if(have_team_spawns > 0)
 117         {
 118                 self.team = activator.team;
 119                 some_spawn_has_been_used = 1;
 120         }
 121 };
 122
 123 // Returns:
 124 //   _x: prio (-1 if unusable)
 125 //   _y: weight
 126 vector Spawn_Score(entity spot, entity playerlist, float teamcheck, float anypoint)
 127 {
 128         float shortest, thisdist;
 129         float prio;
 130         entity player;
 131
 132         prio = 0;
 133
 134         // filter out spots for the wrong team
 135         if(teamcheck)
 136         if(spot.team != teamcheck)
 137                 return '-1 0 0';
 138
 139         if(race_spawns)
 140                 if(spot.target == "")
 141                         return '-1 0 0';
 142
 143         if(clienttype(self) == CLIENTTYPE_REAL)
 144         {
 145                 if(spot.restriction == 1)
 146                         return '-1 0 0';
 147         }
 148         else
 149         {
 150                 if(spot.restriction == 2)
 151                         return '-1 0 0';
 152         }
 153
 154         // filter out spots for assault
 155         if(spot.target != "") {
 156                 local entity ent;
 157                 float good, found;
 158                 ent = find(world, targetname, spot.target);
 159
 160                 while(ent) {
 161                         if(ent.classname == "target_objective")
 162                         {
 163                                 found = 1;
 164                                 if(ent.health < 0 || ent.health >= ASSAULT_VALUE_INACTIVE)
 165                                         return '-1 0 0';
 166                                 good = 1;
 167                         }
 168                         else if(ent.classname == "trigger_race_checkpoint")
 169                         {
 170                                 found = 1;
 171                                 if(!anypoint) // spectators may spawn everywhere
 172
 173                                 {
 174                                         if(g_race_qualifying)
 175                                         {
 176                                                 // spawn at first
 177                                                 if(ent.race_checkpoint != 0)
 178                                                         return '-1 0 0';
 179                                                 if(spot.race_place != race_lowest_place_spawn)
 180                                                         return '-1 0 0';
 181                                         }
 182                                         else
 183                                         {
 184                                                 if(ent.race_checkpoint != self.race_respawn_checkpoint)
 185                                                         return '-1 0 0';
 186                                                 // try reusing the previous spawn
 187                                                 if(ent == self.race_respawn_spotref || spot == self.race_respawn_spotref)
 188                                                         prio += 1;
 189                                                 if(ent.race_checkpoint == 0)
 190                                                 {
 191                                                         float pl;
 192                                                         pl = self.race_place;
 193                                                         if(pl > race_highest_place_spawn)
 194                                                                 pl = 0;
 195                                                         if(pl == 0 && !self.race_started)
 196                                                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 197                                                         if(spot.race_place != pl)
 198                                                                 return '-1 0 0';
 199                                                 }
 200                                         }
 201                                 }
 202                                 good = 1;
 203                         }
 204                         ent = find(ent, targetname, spot.target);
 205                 }
 206
 207                 if(found && !good)
 208                         return '-1 0 0';
 209         }
 210
 211         player = playerlist;
 212         shortest = vlen(world.maxs - world.mins);
 213         for(player = playerlist; player; player = player.chain)
 214                 if (player != self)
 215                 {
 216                         thisdist = vlen(player.origin - spot.origin);
 217                         if (thisdist < shortest)
 218                                 shortest = thisdist;
 219                 }
 220         return prio * '1 0 0' + shortest * '0 1 0';
 221 }
 222
 223 float spawn_allbad;
 224 float spawn_allgood;
 225 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck, float anypoint)
 226 {
 227         local entity spot, spotlist, spotlistend;
 228         spawn_allgood = TRUE;
 229         spawn_allbad = TRUE;
 230
 231         spotlist = world;
 232         spotlistend = world;
 233
 234         for(spot = firstspot; spot; spot = spot.chain)
 235         {
 236                 spot.spawnpoint_score = Spawn_Score(spot, playerlist, teamcheck, anypoint);
 237
 238                 if(cvar("spawn_debugview"))
 239                 {
 240                         setmodel(spot, "models/runematch/rune.mdl");
 241                         if(spot.spawnpoint_score_y < mindist)
 242                         {
 243                                 spot.colormod = '1 0 0';
 244                                 spot.scale = 1;
 245                         }
 246                         else
 247                         {
 248                                 spot.colormod = '0 1 0';
 249                                 spot.scale = spot.spawnpoint_score_y / mindist;
 250                         }
 251                 }
 252
 253                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 254                 {
 255                         if(spot.spawnpoint_score_y < mindist)
 256                         {
 257                                 // too short distance
 258                                 spawn_allgood = FALSE;
 259                         }
 260                         else
 261                         {
 262                                 // perfect
 263                                 spawn_allbad = FALSE;
 264
 265                                 if(spotlistend)
 266                                         spotlistend.chain = spot;
 267                                 spotlistend = spot;
 268                                 if(!spotlist)
 269                                         spotlist = spot;
 270
 271                                 /*
 272                                 if(teamcheck)
 273                                 if(spot.team != teamcheck)
 274                                         error("invalid spawn added");
 275
 276                                 print("added ", etos(spot), "\n");
 277                                 */
 278                         }
 279                 }
 280         }
 281         if(spotlistend)
 282                 spotlistend.chain = world;
 283
 284         /*
 285                 entity e;
 286                 if(teamcheck)
 287                         for(e = spotlist; e; e = e.chain)
 288                         {
 289                                 print("seen ", etos(e), "\n");
 290                                 if(e.team != teamcheck)
 291                                         error("invalid spawn found");
 292                         }
 293         */
 294
 295         return spotlist;
 296 }
 297
 298 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 299 {
 300         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 301         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 302         local entity spot;
 303
 304         RandomSelection_Init();
 305         for(spot = firstspot; spot; spot = spot.chain)
 306                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 307
 308         return RandomSelection_chosen_ent;
 309 }
 310
 311 /*
 312 =============
 313 SelectSpawnPoint
 314
 315 Finds a point to respawn
 316 =============
 317 */
 318 entity SelectSpawnPoint (float anypoint)
 319 {
 320         local float teamcheck;
 321         local entity firstspot_new;
 322         local entity spot, firstspot, playerlist;
 323
 324         spot = find (world, classname, "testplayerstart");
 325         if (spot)
 326                 return spot;
 327
 328         teamcheck = 0;
 329
 330         if(!anypoint && have_team_spawns > 0)
 331                 teamcheck = self.team;
 332
 333         // get the list of players
 334         playerlist = findchain(classname, "player");
 335         // get the entire list of spots
 336         firstspot = findchain(classname, "info_player_deathmatch");
 337         // filter out the bad ones
 338         // (note this returns the original list if none survived)
 339         if(anypoint)
 340         {
 341                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 342         }
 343         else
 344         {
 345                 firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck, anypoint);
 346                 if(!firstspot_new)
 347                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, -1, teamcheck, anypoint);
 348                 firstspot = firstspot_new;
 349
 350                 // there is 50/50 chance of choosing a random spot or the furthest spot
 351                 // (this means that roughly every other spawn will be furthest, so you
 352                 // usually won't get fragged at spawn twice in a row)
 353                 if (arena_roundbased && !g_ca)
 354                 {
 355                         firstspot_new = Spawn_FilterOutBadSpots(firstspot, playerlist, 800, teamcheck, anypoint);
 356                         if(firstspot_new)
 357                                 firstspot = firstspot_new;
 358                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 359                 }
 360                 else if (random() > cvar("g_spawn_furthest"))
 361                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 362                 else
 363                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 364         }
 365
 366         if(cvar("spawn_debugview"))
 367         {
 368                 print("spot mindistance: ", vtos(spot.spawnpoint_score), "\n");
 369
 370                 entity e;
 371                 if(teamcheck)
 372                         for(e = firstspot; e; e = e.chain)
 373                                 if(e.team != teamcheck)
 374                                         error("invalid spawn found");
 375         }
 376
 377         if (!spot)
 378         {
 379                 if(cvar("spawn_debug"))
 380                         GotoNextMap();
 381                 else
 382                 {
 383                         if(some_spawn_has_been_used)
 384                                 return world; // team can't spawn any more, because of actions of other team
 385                         else
 386                                 error("Cannot find a spawn point - please fix the map!");
 387                 }
 388         }
 389
 390         return spot;
 391 }
 392
 393 /*
 394 =============
 395 CheckPlayerModel
 396
 397 Checks if the argument string can be a valid playermodel.
 398 Returns a valid one in doubt.
 399 =============
 400 */
 401 string FallbackPlayerModel;
 402 string CheckPlayerModel(string plyermodel) {
 403         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 404         {
 405                 // note: we cannot summon Don Strunzone here, some player may
 406                 // still have the model string set. In case anyone manages how
 407                 // to change a cvar default, we'll have a small leak here.
 408                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 409         }
 410         if(strlen(plyermodel) < 4)
 411                 return FallbackPlayerModel;
 412         if( substring(plyermodel,0,14) != "models/player/")
 413                 return FallbackPlayerModel;
 414         else if(cvar("sv_servermodelsonly"))
 415         {
 416                 if(substring(plyermodel,-4,4) != ".zym")
 417                 if(substring(plyermodel,-4,4) != ".dpm")
 418                 if(substring(plyermodel,-4,4) != ".iqm")
 419                 if(substring(plyermodel,-4,4) != ".md3")
 420                 if(substring(plyermodel,-4,4) != ".psk")
 421                         return FallbackPlayerModel;
 422                 // forbid the LOD models
 423                 if(substring(plyermodel, -9,5) == "_lod1")
 424                         return FallbackPlayerModel;
 425                 if(substring(plyermodel, -9,5) == "_lod2")
 426                         return FallbackPlayerModel;
 427                 if(plyermodel != strtolower(plyermodel))
 428                         return FallbackPlayerModel;
 429                 if(!fexists(plyermodel))
 430                         return FallbackPlayerModel;
 431         }
 432         return plyermodel;
 433 }
 434
 435 /*
 436 =============
 437 Client_customizeentityforclient
 438
 439 LOD reduction
 440 =============
 441 */
 442 void Client_uncustomizeentityforclient()
 443 {
 444         if(self.modelindex == 0) // no need to uncustomize then
 445                 return;
 446         self.modelindex = self.modelindex_lod0;
 447         self.skin = self.skinindex;
 448 }
 449
 450 float Client_customizeentityforclient()
 451 {
 452         entity modelsource;
 453
 454         if(self.modelindex == 0)
 455                 return TRUE;
 456
 457         // forcemodel stuff
 458
 459 #ifdef PROFILING
 460         float t0;
 461         t0 = gettime(GETTIME_HIRES); // reference
 462 #endif
 463
 464         modelsource = self;
 465
 466 #ifdef ALLOW_FORCEMODELS
 467         if(other.cvar_cl_forceplayermodelsfromxonotic)
 468                 if not(self.modelindex_lod0_from_xonotic)
 469                         modelsource = other;
 470         if(other.cvar_cl_forceplayermodels && sv_clforceplayermodels)
 471                 modelsource = other;
 472 #endif
 473
 474         self.skin = modelsource.skinindex;
 475
 476 #if 0
 477         if(modelsource == self)
 478                 self.skin = modelsource.skinindex;
 479         else
 480                 self.skin = mod(modelsource.skinindex, 3); // forbid the fbskins as forced skins
 481 #endif
 482
 483         // self: me
 484         // other: the player viewing me
 485         float distance;
 486         float f;
 487
 488         if(other.cvar_cl_playerdetailreduction <= 0)
 489         {
 490                 if(other.cvar_cl_playerdetailreduction <= -2)
 491                         self.modelindex = modelsource.modelindex_lod2;
 492                 else if(other.cvar_cl_playerdetailreduction <= -1)
 493                         self.modelindex = modelsource.modelindex_lod1;
 494                 else
 495                         self.modelindex = modelsource.modelindex_lod0;
 496         }
 497         else
 498         {
 499                 distance = vlen(self.origin - other.origin);
 500                 f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 501                 if(f > sv_loddistance2)
 502                         self.modelindex = modelsource.modelindex_lod2;
 503                 else if(f > sv_loddistance1)
 504                         self.modelindex = modelsource.modelindex_lod1;
 505                 else
 506                         self.modelindex = modelsource.modelindex_lod0;
 507         }
 508
 509 #ifdef PROFILING
 510         float t1;
 511         t1 = gettime(GETTIME_HIRES); // reference
 512         client_cefc_accumulator += (t1 - t0);
 513 #endif
 514
 515         return TRUE;
 516 }
 517
 518 void setmodel_lod(entity e, string modelname)
 519 {
 520         string s;
 521
 522         if(sv_loddistance1)
 523         {
 524                 // FIXME: this only supports 3-letter extensions
 525                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
 526                 if(fexists(s))
 527                 {
 528                         setmodel(e, s); // players have high precision
 529                         self.modelindex_lod1 = self.modelindex;
 530                 }
 531                 else
 532                         self.modelindex_lod1 = -1;
 533
 534                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
 535                 if(fexists(s))
 536                 {
 537                         setmodel(e, s); // players have high precision
 538                         self.modelindex_lod2 = self.modelindex;
 539                 }
 540                 else
 541                         self.modelindex_lod2 = -1;
 542
 543                 precache_model(modelname);
 544                 setmodel(e, modelname); // players have high precision
 545                 self.modelindex_lod0 = self.modelindex;
 546
 547                 if(self.modelindex_lod1 < 0)
 548                         self.modelindex_lod1 = self.modelindex;
 549
 550                 if(self.modelindex_lod2 < 0)
 551                         self.modelindex_lod2 = self.modelindex;
 552         }
 553         else
 554         {
 555                 precache_model(modelname);
 556                 setmodel(e, modelname); // players have high precision
 557                 self.modelindex_lod0 = self.modelindex;
 558                         // save it for possible player model forcing
 559         }
 560
 561         s = whichpack(self.model);
 562         self.modelindex_lod0_from_xonotic = ((s == "") || (substring(s, 0, 4) == "data"));
 563
 564         player_setupanimsformodel();
 565         UpdatePlayerSounds();
 566 }
 567
 568 /*
 569 =============
 570 PutObserverInServer
 571
 572 putting a client as observer in the server
 573 =============
 574 */
 575 void FixPlayermodel();
 576 void PutObserverInServer (void)
 577 {
 578         entity  spot;
 579
 580         race_PreSpawnObserver();
 581
 582         spot = SelectSpawnPoint (TRUE);
 583         if(!spot)
 584                 error("No spawnpoints for observers?!?\n");
 585         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 586
 587         if(clienttype(self) == CLIENTTYPE_REAL)
 588         {
 589                 msg_entity = self;
 590                 WriteByte(MSG_ONE, SVC_SETVIEW);
 591                 WriteEntity(MSG_ONE, self);
 592         }
 593
 594         DropAllRunes(self);
 595
 596         Portal_ClearAll(self);
 597
 598         if(self.flagcarried)
 599                 DropFlag(self.flagcarried, world, world);
 600
 601         if(self.ballcarried)
 602                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
 603
 604         WaypointSprite_PlayerDead();
 605
 606         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 607                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 608
 609         if(self.killcount != -666) {
 610                 if(g_lms) {
 611                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 612                                 bprint ("^4", self.netname, "^4 has no more lives left\n");
 613                         else
 614                                 bprint ("^4", self.netname, "^4 is spectating now\n"); // TODO turn this into a proper forfeit?
 615                 } else
 616                         bprint ("^4", self.netname, "^4 is spectating now\n");
 617
 618                 if(self.just_joined == FALSE) {
 619                         LogTeamchange(self.playerid, -1, 4);
 620                 } else
 621                         self.just_joined = FALSE;
 622         }
 623
 624         PlayerScore_Clear(self); // clear scores when needed
 625
 626         self.spectatortime = time;
 627
 628         self.classname = "observer";
 629         self.iscreature = FALSE;
 630         self.health = -666;
 631         self.takedamage = DAMAGE_NO;
 632         self.solid = SOLID_NOT;
 633         self.movetype = MOVETYPE_NOCLIP;
 634         self.flags = FL_CLIENT | FL_NOTARGET;
 635         self.armorvalue = 666;
 636         self.effects = 0;
 637         self.armorvalue = cvar("g_balance_armor_start");
 638         self.pauserotarmor_finished = 0;
 639         self.pauserothealth_finished = 0;
 640         self.pauseregen_finished = 0;
 641         self.damageforcescale = 0;
 642         self.death_time = 0;
 643         self.dead_frame = 0;
 644         self.alpha = 0;
 645         self.scale = 0;
 646         self.fade_time = 0;
 647         self.pain_frame = 0;
 648         self.pain_finished = 0;
 649         self.strength_finished = 0;
 650         self.invincible_finished = 0;
 651         self.pushltime = 0;
 652         self.think = SUB_Null;
 653         self.nextthink = 0;
 654         self.hook_time = 0;
 655         self.runes = 0;
 656         self.deadflag = DEAD_NO;
 657         self.angles = spot.angles;
 658         self.angles_z = 0;
 659         self.fixangle = TRUE;
 660         self.crouch = FALSE;
 661
 662         self.view_ofs = PL_VIEW_OFS;
 663         setorigin (self, spot.origin);
 664         setsize (self, '0 0 0', '0 0 0');
 665         self.prevorigin = self.origin;
 666         self.items = 0;
 667         self.weapons = 0;
 668         self.model = "";
 669         FixPlayermodel();
 670         self.model = "";
 671         self.modelindex = 0;
 672         self.weapon = 0;
 673         self.weaponmodel = "";
 674         self.weaponentity = world;
 675         self.exteriorweaponentity = world;
 676         self.killcount = -666;
 677         self.velocity = '0 0 0';
 678         self.avelocity = '0 0 0';
 679         self.punchangle = '0 0 0';
 680         self.punchvector = '0 0 0';
 681         self.oldvelocity = self.velocity;
 682         self.fire_endtime = -1;
 683
 684         if(sv_loddistance1)
 685                 SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 686
 687         if(g_arena)
 688         {
 689                 if(self.version_mismatch)
 690                 {
 691                         Spawnqueue_Unmark(self);
 692                         Spawnqueue_Remove(self);
 693                 }
 694                 else
 695                 {
 696                         Spawnqueue_Insert(self);
 697                 }
 698         }
 699         else if(g_lms)
 700         {
 701                 // Only if the player cannot play at all
 702                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 703                         self.frags = FRAGS_SPECTATOR;
 704                 else
 705                         self.frags = FRAGS_LMS_LOSER;
 706         }
 707         else
 708                 self.frags = FRAGS_SPECTATOR;
 709
 710         MUTATOR_CALLHOOK(MakePlayerObserver);
 711 }
 712
 713 float RestrictSkin(float s)
 714 {
 715         if(!teams_matter)
 716                 return s;
 717         if(s == 6)
 718                 return 6;
 719         return mod(s, 3);
 720 }
 721
 722 void FixPlayermodel()
 723 {
 724         local string defaultmodel;
 725         local float defaultskin, chmdl, oldskin;
 726         local vector m1, m2;
 727
 728         defaultmodel = "";
 729
 730         if(cvar("sv_defaultcharacter") == 1) {
 731                 defaultskin = 0;
 732
 733                 if(teams_matter)
 734                 {
 735                         string s;
 736                         s = Team_ColorNameLowerCase(self.team);
 737                         if(s != "neutral")
 738                         {
 739                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 740                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 741                         }
 742                 }
 743
 744                 if(defaultmodel == "")
 745                 {
 746                         defaultmodel = cvar_string("sv_defaultplayermodel");
 747                         defaultskin = cvar("sv_defaultplayerskin");
 748                 }
 749         }
 750
 751         if(self.modelindex == 0 && self.deadflag == DEAD_NO)
 752         {
 753                 if(self.model != "")
 754                         bprint("\{1}^1Player ", self.netname, "^1 has a zero modelindex, trying to fix...\n");
 755                 self.model = ""; // force the != checks to return true
 756         }
 757
 758         if(defaultmodel != "")
 759         {
 760                 if (defaultmodel != self.model)
 761                 {
 762                         m1 = self.mins;
 763                         m2 = self.maxs;
 764                         setmodel_lod (self, defaultmodel);
 765                         setsize (self, m1, m2);
 766                         chmdl = TRUE;
 767                 }
 768
 769                 oldskin = self.skinindex;
 770                 self.skinindex = defaultskin;
 771         } else {
 772                 if (self.playermodel != self.model || self.playermodel == "")
 773                 {
 774                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 775                         m1 = self.mins;
 776                         m2 = self.maxs;
 777                         setmodel_lod (self, self.playermodel);
 778                         setsize (self, m1, m2);
 779                         chmdl = TRUE;
 780                 }
 781
 782                 oldskin = self.skinindex;
 783                 self.skinindex = RestrictSkin(stof(self.playerskin));
 784         }
 785
 786         if(chmdl || oldskin != self.skinindex)
 787                 self.species = player_getspecies(); // model or skin has changed
 788
 789         if(!teams_matter)
 790                 if(strlen(cvar_string("sv_defaultplayercolors")))
 791                         if(self.clientcolors != cvar("sv_defaultplayercolors"))
 792                                 setcolor(self, cvar("sv_defaultplayercolors"));
 793 }
 794
 795 void PlayerTouchExplode(entity p1, entity p2)
 796 {
 797         vector org;
 798         org = (p1.origin + p2.origin) * 0.5;
 799         org_z += (p1.mins_z + p2.mins_z) * 0.5;
 800
 801         te_explosion(org);
 802
 803         entity e;
 804         e = spawn();
 805         setorigin(e, org);
 806         RadiusDamage(e, world, g_touchexplode_damage, g_touchexplode_edgedamage, g_touchexplode_radius, world, g_touchexplode_force, DEATH_TOUCHEXPLODE, world);
 807         remove(e);
 808 }
 809
 810 /*
 811 =============
 812 PutClientInServer
 813
 814 Called when a client spawns in the server
 815 =============
 816 */
 817 //void() ctf_playerchanged;
 818 void PutClientInServer (void)
 819 {
 820         if(clienttype(self) == CLIENTTYPE_BOT)
 821         {
 822                 self.classname = "player";
 823         }
 824         else if(clienttype(self) == CLIENTTYPE_REAL)
 825         {
 826                 msg_entity = self;
 827                 WriteByte(MSG_ONE, SVC_SETVIEW);
 828                 WriteEntity(MSG_ONE, self);
 829         }
 830
 831         // player is dead and becomes observer
 832         // FIXME fix LMS scoring for new system
 833         if(g_lms)
 834         {
 835                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 836                         self.classname = "observer";
 837         }
 838
 839         if(g_arena || (g_ca && !allowed_to_spawn))
 840         if(!self.spawned)
 841                 self.classname = "observer";
 842
 843         if(gameover)
 844                 self.classname = "observer";
 845
 846         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 847                 entity spot, oldself;
 848                 float j;
 849
 850                 if(self.team < 0)
 851                         JoinBestTeam(self, FALSE, TRUE);
 852
 853                 race_PreSpawn();
 854
 855                 spot = SelectSpawnPoint (FALSE);
 856                 if(!spot)
 857                 {
 858                         centerprint(self, "Sorry, no spawnpoints available!\nHope your team can fix it...");
 859                         return; // spawn failed
 860                 }
 861
 862                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 863
 864                 self.classname = "player";
 865                 self.wasplayer = TRUE;
 866                 self.iscreature = TRUE;
 867                 self.movetype = MOVETYPE_WALK;
 868                 self.solid = SOLID_SLIDEBOX;
 869                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 870                 if(cvar("g_playerclip_collisions"))
 871                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 872                 if(clienttype(self) == CLIENTTYPE_BOT && cvar("g_botclip_collisions"))
 873                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 874                 self.frags = FRAGS_PLAYER;
 875                 if(independent_players)
 876                         MAKE_INDEPENDENT_PLAYER(self);
 877                 self.flags = FL_CLIENT;
 878                 self.takedamage = DAMAGE_AIM;
 879                 if(g_minstagib)
 880                         self.effects = EF_FULLBRIGHT;
 881                 else
 882                         self.effects = 0;
 883                 self.air_finished = time + 12;
 884                 self.dmg = 2;
 885
 886                 if(inWarmupStage)
 887                 {
 888                         self.ammo_shells = warmup_start_ammo_shells;
 889                         self.ammo_nails = warmup_start_ammo_nails;
 890                         self.ammo_rockets = warmup_start_ammo_rockets;
 891                         self.ammo_cells = warmup_start_ammo_cells;
 892                         self.ammo_fuel = warmup_start_ammo_fuel;
 893                         self.health = warmup_start_health;
 894                         self.armorvalue = warmup_start_armorvalue;
 895                         self.weapons = warmup_start_weapons;
 896                 }
 897                 else
 898                 {
 899                         self.ammo_shells = start_ammo_shells;
 900                         self.ammo_nails = start_ammo_nails;
 901                         self.ammo_rockets = start_ammo_rockets;
 902                         self.ammo_cells = start_ammo_cells;
 903                         self.ammo_fuel = start_ammo_fuel;
 904                         self.health = start_health;
 905                         self.armorvalue = start_armorvalue;
 906                         self.weapons = start_weapons;
 907                 }
 908
 909                 if(g_weaponarena_random)
 910                         self.weapons = randombits(self.weapons, g_weaponarena_random, FALSE);
 911
 912                 self.items = start_items;
 913                 self.jump_interval = time;
 914
 915                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 916                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 917                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 918                 self.pauserotfuel_finished = time + cvar("g_balance_pause_fuel_rot_spawn");
 919                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 920                 //extend the pause of rotting if client was reset at the beginning of the countdown
 921                 if(!cvar("sv_ready_restart_after_countdown") && time < game_starttime) { // TODO why is this cvar NOTted?
 922                         self.spawnshieldtime += game_starttime - time;
 923                         self.pauserotarmor_finished += game_starttime - time;
 924                         self.pauserothealth_finished += game_starttime - time;
 925                         self.pauseregen_finished += game_starttime - time;
 926                 }
 927                 self.damageforcescale = 2;
 928                 self.death_time = 0;
 929                 self.dead_frame = 0;
 930                 self.alpha = 0;
 931                 self.scale = 0;
 932                 self.fade_time = 0;
 933                 self.pain_frame = 0;
 934                 self.pain_finished = 0;
 935                 self.strength_finished = 0;
 936                 self.invincible_finished = 0;
 937                 self.pushltime = 0;
 938                 // players have no think function
 939                 self.think = SUB_Null;
 940                 self.nextthink = 0;
 941                 self.hook_time = 0;
 942                 self.dmg_team = 0;
 943                 self.ballistics_density = cvar("g_ballistics_density_player");
 944
 945                 self.metertime = 0;
 946
 947                 self.runes = 0;
 948
 949                 self.deadflag = DEAD_NO;
 950
 951                 self.angles = spot.angles;
 952
 953                 self.angles_z = 0; // never spawn tilted even if the spot says to
 954                 self.fixangle = TRUE; // turn this way immediately
 955                 self.velocity = '0 0 0';
 956                 self.avelocity = '0 0 0';
 957                 self.punchangle = '0 0 0';
 958                 self.punchvector = '0 0 0';
 959                 self.oldvelocity = self.velocity;
 960                 self.fire_endtime = -1;
 961
 962                 msg_entity = self;
 963                 WRITESPECTATABLE_MSG_ONE({
 964                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 965                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 966                 });
 967
 968                 if(sv_loddistance1)
 969                         SetCustomizer(self, Client_customizeentityforclient, Client_uncustomizeentityforclient);
 970
 971                 self.model = "";
 972                 FixPlayermodel();
 973
 974                 self.crouch = FALSE;
 975                 self.view_ofs = PL_VIEW_OFS;
 976                 setsize (self, PL_MIN, PL_MAX);
 977                 self.spawnorigin = spot.origin;
 978                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 979                 // don't reset back to last position, even if new position is stuck in solid
 980                 self.oldorigin = self.origin;
 981                 self.prevorigin = self.origin;
 982                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 983
 984                 if(g_arena)
 985                 {
 986                         Spawnqueue_Remove(self);
 987                         Spawnqueue_Mark(self);
 988                 }
 989
 990                 else if(g_ca)
 991                         self.caplayer = 1;
 992
 993                 self.event_damage = PlayerDamage;
 994
 995                 self.bot_attack = TRUE;
 996
 997                 self.statdraintime = time + 5;
 998                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 999
1000                 if(self.killcount == -666) {
1001                         PlayerScore_Clear(self);
1002                         self.killcount = 0;
1003                 }
1004
1005                 self.cnt = WEP_LASER;
1006
1007                 CL_SpawnWeaponentity();
1008                 self.alpha = default_player_alpha;
1009                 self.colormod = '1 1 1' * cvar("g_player_brightness");
1010                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1011
1012                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
1013                 self.lms_traveled_distance = 0;
1014                 self.speedrunning = FALSE;
1015
1016                 race_PostSpawn(spot);
1017
1018                 if(cvar("spawn_debug"))
1019                 {
1020                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
1021                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
1022                 }
1023
1024                 //stuffcmd(self, "chase_active 0");
1025                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1026
1027                 if (cvar("g_spawnsound"))
1028                         sound (self, CHAN_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
1029
1030                 if(g_assault) {
1031                         if(self.team == assault_attacker_team)
1032                                 centerprint(self, "You are attacking!");
1033                         else
1034                                 centerprint(self, "You are defending!");
1035                 }
1036
1037                 target_voicescript_clear(self);
1038
1039                 // reset fields the weapons may use
1040                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
1041                         weapon_action(j, WR_RESETPLAYER);
1042
1043                 oldself = self;
1044                 self = spot;
1045                         activator = oldself;
1046                                 SUB_UseTargets();
1047                         activator = world;
1048                 self = oldself;
1049
1050                 MUTATOR_CALLHOOK(PlayerSpawn);
1051
1052                 self.switchweapon = w_getbestweapon(self);
1053                 self.cnt = self.switchweapon;
1054                 self.weapon = 0;
1055         } else if(self.classname == "observer" || (g_ca && !allowed_to_spawn)) {
1056                 PutObserverInServer ();
1057         }
1058
1059         //if(g_ctf)
1060         //      ctf_playerchanged();
1061 }
1062
1063 float ClientInit_SendEntity(entity to, float sf)
1064 {
1065         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
1066         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
1067         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
1068         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
1069         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
1070         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
1071         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
1072         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
1073         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
1074         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
1075         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
1076         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
1077         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
1078         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
1079         if(sv_foginterval && world.fog != "")
1080                 WriteString(MSG_ENTITY, world.fog);
1081         else
1082                 WriteString(MSG_ENTITY, "");
1083         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
1084         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
1085         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_secondary_bouncefactor
1086         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_secondary_bouncestop
1087         WriteByte(MSG_ENTITY, cvar("g_balance_nex_secondary")); // client has to know if it should zoom or not
1088         WriteByte(MSG_ENTITY, cvar("g_balance_campingrifle_secondary")); // client has to know if it should zoom or not
1089         return TRUE;
1090 }
1091
1092 void ClientInit_CheckUpdate()
1093 {
1094         self.nextthink = time;
1095         if(self.count != cvar("g_balance_armor_blockpercent"))
1096         {
1097                 self.count = cvar("g_balance_armor_blockpercent");
1098                 self.SendFlags |= 1;
1099         }
1100         if(self.cnt != cvar("g_balance_weaponswitchdelay"))
1101         {
1102                 self.cnt = cvar("g_balance_weaponswitchdelay");
1103                 self.SendFlags |= 1;
1104         }
1105         if(self.bouncefactor != cvar("g_balance_grenadelauncher_secondary_bouncefactor"))
1106         {
1107                 self.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
1108                 self.SendFlags |= 1;
1109         }
1110         if(self.bouncestop != cvar("g_balance_grenadelauncher_secondary_bouncestop"))
1111         {
1112                 self.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
1113                 self.SendFlags |= 1;
1114         }
1115 }
1116
1117 void ClientInit_Spawn()
1118 {
1119         entity o;
1120         entity e;
1121         e = spawn();
1122         e.classname = "clientinit";
1123         e.think = ClientInit_CheckUpdate;
1124         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
1125
1126         o = self;
1127         self = e;
1128         ClientInit_CheckUpdate();
1129         self = o;
1130 }
1131
1132 /*
1133 =============
1134 SetNewParms
1135 =============
1136 */
1137 void SetNewParms (void)
1138 {
1139         // initialize parms for a new player
1140         parm1 = -(86400 * 366);
1141 }
1142
1143 /*
1144 =============
1145 SetChangeParms
1146 =============
1147 */
1148 void SetChangeParms (void)
1149 {
1150         // save parms for level change
1151         parm1 = self.parm_idlesince - time;
1152 }
1153
1154 /*
1155 =============
1156 DecodeLevelParms
1157 =============
1158 */
1159 void DecodeLevelParms (void)
1160 {
1161         // load parms
1162         self.parm_idlesince = parm1;
1163         if(self.parm_idlesince == -(86400 * 366))
1164                 self.parm_idlesince = time;
1165
1166         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1167         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1168 }
1169
1170 /*
1171 =============
1172 ClientKill
1173
1174 Called when a client types 'kill' in the console
1175 =============
1176 */
1177
1178 void ClientKill_Now_TeamChange()
1179 {
1180         if(self.killindicator_teamchange == -1)
1181         {
1182                 self.team = -1;
1183                 JoinBestTeam( self, FALSE, FALSE );
1184         }
1185         else
1186                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1187 }
1188
1189 void ClientKill_Now()
1190 {
1191         if(self.killindicator_teamchange)
1192                 ClientKill_Now_TeamChange();
1193
1194         // in any case:
1195         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1196
1197         if(self.killindicator)
1198         {
1199                 dprint("Cleaned up after a leaked kill indicator.\n");
1200                 remove(self.killindicator);
1201                 self.killindicator = world;
1202         }
1203 }
1204 void KillIndicator_Think()
1205 {
1206         if (!self.owner.modelindex)
1207         {
1208                 self.owner.killindicator = world;
1209                 remove(self);
1210                 return;
1211         }
1212
1213         if(self.cnt <= 0)
1214         {
1215                 self = self.owner;
1216                 ClientKill_Now(); // no oldself needed
1217                 return;
1218         }
1219         else
1220         {
1221                 if(self.cnt <= 10)
1222                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1223                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1224                 {
1225                         if(self.cnt <= 10)
1226                                 AnnounceTo(self.owner, strcat(ftos(self.cnt), ""));
1227                         if(self.owner.killindicator_teamchange)
1228                         {
1229                                 if(self.owner.killindicator_teamchange == -1)
1230                                         centerprint(self.owner, strcat("Changing team in ", ftos(self.cnt), " seconds"));
1231                                 else
1232                                         centerprint(self.owner, strcat("Changing to ", ColoredTeamName(self.owner.killindicator_teamchange), " in ", ftos(self.cnt), " seconds"));
1233                         }
1234                         else
1235                                 centerprint(self.owner, strcat("^1Suicide in ", ftos(self.cnt), " seconds"));
1236                 }
1237                 self.nextthink = time + 1;
1238                 self.cnt -= 1;
1239         }
1240 }
1241
1242 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto
1243 {
1244         float killtime;
1245         entity e;
1246         killtime = cvar("g_balance_kill_delay");
1247
1248         if(g_race_qualifying)
1249                 killtime = 0;
1250
1251         self.killindicator_teamchange = targetteam;
1252
1253         if(!self.killindicator)
1254         {
1255                 if(killtime <= 0 || !self.modelindex || self.deadflag != DEAD_NO)
1256                 {
1257                         ClientKill_Now();
1258                 }
1259                 else
1260                 {
1261                         self.killindicator = spawn();
1262                         self.killindicator.owner = self;
1263                         self.killindicator.scale = 0.5;
1264                         setattachment(self.killindicator, self, "");
1265                         setorigin(self.killindicator, '0 0 52');
1266                         self.killindicator.think = KillIndicator_Think;
1267                         self.killindicator.nextthink = time + (self.lip) * 0.05;
1268                         self.killindicator.cnt = ceil(killtime);
1269                         self.killindicator.count = bound(0, ceil(killtime), 10);
1270                         sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1271
1272                         for(e = world; (e = find(e, classname, "body")) != world; )
1273                         {
1274                                 if(e.enemy != self)
1275                                         continue;
1276                                 e.killindicator = spawn();
1277                                 e.killindicator.owner = e;
1278                                 e.killindicator.scale = 0.5;
1279                                 setattachment(e.killindicator, e, "");
1280                                 setorigin(e.killindicator, '0 0 52');
1281                                 e.killindicator.think = KillIndicator_Think;
1282                                 e.killindicator.nextthink = time + (e.lip) * 0.05;
1283                                 e.killindicator.cnt = ceil(killtime);
1284                         }
1285                         self.lip = 0;
1286                 }
1287         }
1288         if(self.killindicator)
1289         {
1290                 if(targetteam)
1291                         self.killindicator.colormod = TeamColor(targetteam);
1292                 else
1293                         self.killindicator.colormod = '0 0 0';
1294         }
1295 }
1296
1297 void ClientKill (void)
1298 {
1299         ClientKill_TeamChange(0);
1300 }
1301
1302 void DoTeamChange(float destteam)
1303 {
1304         float t, c0;
1305         if(!teams_matter)
1306         {
1307                 if(destteam >= 0)
1308                         SetPlayerColors(self, destteam);
1309                 return;
1310         }
1311         if(self.classname == "player")
1312         if(destteam == -1)
1313         {
1314                 CheckAllowedTeams(self);
1315                 t = FindSmallestTeam(self, TRUE);
1316                 switch(self.team)
1317                 {
1318                         case COLOR_TEAM1: c0 = c1; break;
1319                         case COLOR_TEAM2: c0 = c2; break;
1320                         case COLOR_TEAM3: c0 = c3; break;
1321                         case COLOR_TEAM4: c0 = c4; break;
1322                         default:          c0 = 999;
1323                 }
1324                 switch(t)
1325                 {
1326                         case 1:
1327                                 if(c0 > c1)
1328                                         destteam = COLOR_TEAM1;
1329                                 break;
1330                         case 2:
1331                                 if(c0 > c2)
1332                                         destteam = COLOR_TEAM2;
1333                                 break;
1334                         case 3:
1335                                 if(c0 > c3)
1336                                         destteam = COLOR_TEAM3;
1337                                 break;
1338                         case 4:
1339                                 if(c0 > c4)
1340                                         destteam = COLOR_TEAM4;
1341                                 break;
1342                 }
1343                 if(destteam == -1)
1344                         return;
1345         }
1346         if(destteam == self.team && destteam >= 0 && !self.killindicator)
1347                 return;
1348         ClientKill_TeamChange(destteam);
1349 }
1350
1351 void FixClientCvars(entity e)
1352 {
1353         // send prediction settings to the client
1354         stuffcmd(e, "\nin_bindmap 0 0\n");
1355         if(g_race || g_cts)
1356                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1357         if(cvar("g_antilag") == 3) // client side hitscan
1358                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1359         if(sv_gentle)
1360                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1361         /*
1362          * we no longer need to stuff this. Remove this comment block if you feel
1363          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1364         stuffcmd(e, strcat("cl_gravity ", ftos(cvar("sv_gravity")), "\n"));
1365         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
1366         stuffcmd(e, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
1367         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
1368         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(cvar("sv_airaccelerate")), "\n"));
1369         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
1370         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
1371         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(cvar("sv_jumpvelocity")), "\n"));
1372         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
1373         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
1374         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(cvar("sv_airaccel_qw")), "\n"));
1375         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(cvar("sv_airaccel_sideways_friction")), "\n"));
1376         stuffcmd(e, "cl_movement_edgefriction 1\n");
1377          */
1378 }
1379
1380 /*
1381 =============
1382 ClientConnect
1383
1384 Called when a client connects to the server
1385 =============
1386 */
1387 //void ctf_clientconnect();
1388 string ColoredTeamName(float t);
1389 void DecodeLevelParms (void);
1390 //void dom_player_join_team(entity pl);
1391 #ifdef UID
1392 .float uid_kicktime;
1393 .string uid;
1394 #endif
1395 void ClientConnect (void)
1396 {
1397         float t;
1398
1399         if(self.flags & FL_CLIENT)
1400         {
1401                 print("Warning: ClientConnect, but already connected!\n");
1402                 return;
1403         }
1404
1405         if(Ban_MaybeEnforceBan(self))
1406                 return;
1407
1408         DecodeLevelParms();
1409
1410 #ifdef WATERMARK
1411         sprint(self, strcat("^4SVQC Build information: ", WATERMARK(), "\n"));
1412 #endif
1413
1414         self.classname = "player_joining";
1415
1416         self.flags = FL_CLIENT;
1417         self.version_nagtime = time + 10 + random() * 10;
1418
1419         if(player_count<0)
1420         {
1421                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1422                 player_count = 0;
1423         }
1424
1425         PlayerScore_Attach(self);
1426         ClientData_Attach();
1427
1428         bot_clientconnect();
1429
1430         playerdemo_init();
1431
1432         anticheat_init();
1433
1434         race_PreSpawnObserver();
1435
1436         //if(g_domination)
1437         //      dom_player_join_team(self);
1438
1439         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1440
1441         if((cvar("sv_spectate") == 1 && !g_lms) || cvar("g_campaign")) {
1442                 self.classname = "observer";
1443         } else {
1444                 if(teams_matter)
1445                 {
1446                         if(cvar("g_balance_teams") || cvar("g_balance_teams_force"))
1447                         {
1448                                 self.classname = "player";
1449                                 campaign_bots_may_start = 1;
1450                         }
1451                         else
1452                         {
1453                                 self.classname = "observer"; // do it anyway
1454                         }
1455                 }
1456                 else
1457                 {
1458                         self.classname = "player";
1459                         campaign_bots_may_start = 1;
1460                 }
1461         }
1462
1463         self.playerid = (playerid_last = playerid_last + 1);
1464
1465         if(cvar("sv_eventlog"))
1466                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1467
1468         LogTeamchange(self.playerid, self.team, 1);
1469
1470         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1471
1472         self.netname_previous = strzone(self.netname);
1473
1474         bprint("^4", self.netname, "^4 connected");
1475
1476         if(self.classname != "observer" && (g_domination || g_ctf))
1477                 bprint(" and joined the ", ColoredTeamName(self.team));
1478
1479         bprint("\n");
1480
1481         self.welcomemessage_time = 0;
1482
1483         stuffcmd(self, strcat(clientstuff, "\n"));
1484         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
1485         stuffcmd(self, "cl_particles_reloadeffects\n");
1486
1487         FixClientCvars(self);
1488
1489         // spawnfunc_waypoint sprites
1490         WaypointSprite_InitClient(self);
1491
1492         // Wazat's grappling hook
1493         SetGrappleHookBindings();
1494
1495         // get autoswitch state from player when he toggles it
1496         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1 ; cmd autoswitch $1\"\n"); // default.cfg-ed in 2.4.1
1497
1498         // get version info from player
1499         stuffcmd(self, "cmd clientversion $gameversion\n");
1500
1501         // get other cvars from player
1502         GetCvars(0);
1503
1504         // set cvar for team scoreboard
1505         stuffcmd(self, strcat("set teamplay ", ftos(teamplay), "\n"));
1506
1507         // notify about available teams
1508         if(teams_matter)
1509         {
1510                 CheckAllowedTeams(self);
1511                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1512                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1513         }
1514         else
1515                 stuffcmd(self, "set _teams_available 0\n");
1516
1517         stuffcmd(self, strcat("set gametype ", ftos(game), "\n"));
1518
1519         if(g_arena || g_ca)
1520         {
1521                 self.classname = "observer";
1522                 if(g_arena)
1523                         Spawnqueue_Insert(self);
1524         }
1525         /*else if(g_ctf)
1526         {
1527                 ctf_clientconnect();
1528         }*/
1529
1530         if(teams_matter || radar_showennemies)
1531                 attach_entcs();
1532
1533         bot_relinkplayerlist();
1534
1535         self.spectatortime = time;
1536         if(blockSpectators)
1537         {
1538                 sprint(self, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
1539         }
1540
1541         self.jointime = time;
1542         self.allowedTimeouts = cvar("sv_timeout_number");
1543
1544         if(clienttype(self) == CLIENTTYPE_REAL)
1545         {
1546                 if(cvar("g_bugrigs") || g_weaponarena == WEPBIT_TUBA)
1547                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1548         }
1549
1550         if(g_lms)
1551         {
1552                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1553                 {
1554                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1555                         self.frags = FRAGS_SPECTATOR;
1556                 }
1557         }
1558
1559         if(!sv_foginterval && world.fog != "")
1560                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1561
1562         SoundEntity_Attach(self);
1563
1564         if(cvar("g_hitplots") || strstrofs(strcat(" ", cvar_string("g_hitplots_individuals"), " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1565         {
1566                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1567                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1568         }
1569         else
1570                 self.hitplotfh = -1;
1571
1572 #ifdef UID
1573         if(clienttype(self) == CLIENTTYPE_REAL)
1574         if not(self.uid)
1575                 self.uid_kicktime = time + 60;
1576 #endif
1577
1578         if(g_race || g_cts) {
1579                 string rr;
1580                 if(g_cts)
1581                         rr = CTS_RECORD;
1582                 else
1583                         rr = RACE_RECORD;
1584                 t = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "time")));
1585
1586                 race_send_recordtime(MSG_ONE);
1587                 race_send_speedaward(MSG_ONE);
1588
1589                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1590                 speedaward_alltimebest_holder = db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/netname"));
1591                 race_send_speedaward_alltimebest(MSG_ONE);
1592
1593                 float i;
1594                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1595                         race_SendRankings(i, 0, 0, MSG_ONE);
1596                 }
1597         }
1598         else if(cvar("sv_teamnagger") && !(cvar("bot_vs_human") && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1599                 send_CSQC_teamnagger();
1600
1601         CheatInitClient();
1602 }
1603
1604 /*
1605 =============
1606 ClientDisconnect
1607
1608 Called when a client disconnects from the server
1609 =============
1610 */
1611 .entity chatbubbleentity;
1612 .entity teambubbleentity;
1613 void ReadyCount();
1614 void ClientDisconnect (void)
1615 {
1616         if not(self.flags & FL_CLIENT)
1617         {
1618                 print("Warning: ClientDisconnect without ClientConnect\n");
1619                 return;
1620         }
1621
1622         CheatShutdownClient();
1623
1624         if(self.hitplotfh >= 0)
1625         {
1626                 fclose(self.hitplotfh);
1627                 self.hitplotfh = -1;
1628         }
1629
1630         anticheat_report();
1631         anticheat_shutdown();
1632
1633         playerdemo_shutdown();
1634
1635         bot_clientdisconnect();
1636
1637         if(self.entcs)
1638                 detach_entcs();
1639
1640         if(cvar("sv_eventlog"))
1641                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1642         bprint ("^4",self.netname);
1643         bprint ("^4 disconnected\n");
1644
1645         SoundEntity_Detach(self);
1646
1647         DropAllRunes(self);
1648         MUTATOR_CALLHOOK(ClientDisconnect);
1649
1650         Portal_ClearAll(self);
1651
1652         if(self.flagcarried)
1653                 DropFlag(self.flagcarried, world, world);
1654         if(self.ballcarried)
1655                 DropBall(self.ballcarried, self.origin + self.ballcarried.origin, self.velocity);
1656
1657         // Here, everything has been done that requires this player to be a client.
1658
1659         self.flags &~= FL_CLIENT;
1660
1661         if (self.chatbubbleentity)
1662                 remove (self.chatbubbleentity);
1663
1664         if (self.teambubbleentity)
1665                 remove (self.teambubbleentity);
1666
1667         if (self.killindicator)
1668                 remove (self.killindicator);
1669
1670         WaypointSprite_PlayerGone();
1671
1672         bot_relinkplayerlist();
1673
1674         // remove laserdot
1675         if(self.weaponentity)
1676                 if(self.weaponentity.lasertarget)
1677                         remove(self.weaponentity.lasertarget);
1678
1679         if(g_arena)
1680         {
1681                 Spawnqueue_Unmark(self);
1682                 Spawnqueue_Remove(self);
1683         }
1684
1685         ClientData_Detach();
1686         PlayerScore_Detach(self);
1687
1688         if(self.netname_previous)
1689                 strunzone(self.netname_previous);
1690         if(self.clientstatus)
1691                 strunzone(self.clientstatus);
1692
1693         ClearPlayerSounds();
1694
1695         if(self.personal)
1696                 remove(self.personal);
1697
1698         self.playerid = 0;
1699         ReadyCount();
1700
1701         // free cvars
1702         GetCvars(-1);
1703 }
1704
1705 .float BUTTON_CHAT;
1706 void ChatBubbleThink()
1707 {
1708         self.nextthink = time;
1709         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
1710         {
1711                 if(self.owner) // but why can that ever be world?
1712                         self.owner.chatbubbleentity = world;
1713                 remove(self);
1714                 return;
1715         }
1716         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1717 #ifdef TETRIS
1718                 || self.owner.tetris_on
1719 #endif
1720         )
1721                 self.model = self.mdl;
1722         else
1723                 self.model = "";
1724 };
1725
1726 void UpdateChatBubble()
1727 {
1728         if (!self.modelindex)
1729                 return;
1730         // spawn a chatbubble entity if needed
1731         if (!self.chatbubbleentity)
1732         {
1733                 self.chatbubbleentity = spawn();
1734                 self.chatbubbleentity.owner = self;
1735                 self.chatbubbleentity.exteriormodeltoclient = self;
1736                 self.chatbubbleentity.think = ChatBubbleThink;
1737                 self.chatbubbleentity.nextthink = time;
1738                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1739                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1740                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1741                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1742                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1743                 self.chatbubbleentity.model = "";
1744                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1745         }
1746 }
1747
1748
1749 void TeamBubbleThink()
1750 {
1751         self.nextthink = time;
1752         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
1753         {
1754                 if(self.owner) // but why can that ever be world?
1755                         self.owner.teambubbleentity = world;
1756                 remove(self);
1757                 return;
1758         }
1759 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
1760         if (self.owner.BUTTON_CHAT || self.owner.deadflag || self.owner.killindicator)
1761                 self.model = "";
1762         else
1763                 self.model = self.mdl;
1764
1765 };
1766
1767 float TeamBubble_customizeentityforclient()
1768 {
1769         return (self.owner != other && self.owner.team == other.team && other.killcount > -666);
1770 }
1771
1772 void UpdateTeamBubble()
1773 {
1774         if (!self.modelindex || !teams_matter)
1775                 return;
1776         // spawn a teambubble entity if needed
1777         if (!self.teambubbleentity && teams_matter)
1778         {
1779                 self.teambubbleentity = spawn();
1780                 self.teambubbleentity.owner = self;
1781                 self.teambubbleentity.exteriormodeltoclient = self;
1782                 self.teambubbleentity.think = TeamBubbleThink;
1783                 self.teambubbleentity.nextthink = time;
1784                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr"); // precision set below
1785 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1786                 setorigin(self.teambubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1787                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1788                 self.teambubbleentity.mdl = self.teambubbleentity.model;
1789                 self.teambubbleentity.model = self.teambubbleentity.mdl;
1790                 self.teambubbleentity.customizeentityforclient = TeamBubble_customizeentityforclient;
1791                 self.teambubbleentity.effects = EF_LOWPRECISION;
1792         }
1793 }
1794
1795 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1796 // added to the model skins
1797 /*void UpdateColorModHack()
1798 {
1799         local float c;
1800         c = self.clientcolors & 15;
1801         // LordHavoc: only bothering to support white, green, red, yellow, blue
1802              if (!teams_matter) self.colormod = '0 0 0';
1803         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1804         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1805         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1806         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1807         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1808         else self.colormod = '1 1 1';
1809 };*/
1810
1811 .float oldcolormap;
1812 void respawn(void)
1813 {
1814         if(self.modelindex != 0 && cvar("g_respawn_ghosts"))
1815         {
1816                 self.solid = SOLID_NOT;
1817                 self.takedamage = DAMAGE_NO;
1818                 self.movetype = MOVETYPE_FLY;
1819                 self.velocity = '0 0 1' * cvar("g_respawn_ghosts_speed");
1820                 self.avelocity = randomvec() * cvar("g_respawn_ghosts_speed") * 3 - randomvec() * cvar("g_respawn_ghosts_speed") * 3;
1821                 self.effects |= EF_ADDITIVE;
1822                 self.oldcolormap = self.colormap;
1823                 self.colormap = 512;
1824                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1825                 if(cvar("g_respawn_ghosts_maxtime"))
1826                         SUB_SetFade (self, time + cvar("g_respawn_ghosts_maxtime") / 2 + random () * (cvar("g_respawn_ghosts_maxtime") - cvar("g_respawn_ghosts_maxtime") / 2), 1.5);
1827         }
1828
1829         CopyBody(1);
1830         self.effects |= EF_NODRAW; // prevent another CopyBody
1831         if(self.oldcolormap)
1832         {
1833                 self.colormap = self.oldcolormap;
1834                 self.oldcolormap = 0;
1835         }
1836         PutClientInServer();
1837 }
1838
1839 void play_countdown(float finished, string samp)
1840 {
1841         if(clienttype(self) == CLIENTTYPE_REAL)
1842                 if(floor(finished - time - frametime) != floor(finished - time))
1843                         if(finished - time < 6)
1844                                 sound (self, CHAN_AUTO, samp, VOL_BASE, ATTN_NORM);
1845 }
1846
1847 /**
1848  * When sv_timeout is used this function returs strings like
1849  * "Timeout begins in 2 seconds!\n" or "Timeout ends in 23 seconds!\n".
1850  * Called by centerprint functions
1851  * @param addOneSecond boolean, set to 1 if the welcome-message centerprint asks for the text
1852  */
1853 string getTimeoutText(float addOneSecond) {
1854         if (!cvar("sv_timeout") || !timeoutStatus)
1855                 return "";
1856
1857         local string retStr;
1858         if (timeoutStatus == 1) {
1859                 if (addOneSecond == 1) {
1860                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime + 1), " seconds!\n");
1861                 }
1862                 else {
1863                         retStr = strcat("Timeout begins in ", ftos(remainingLeadTime), " seconds!\n");
1864                 }
1865                 return retStr;
1866         }
1867         else if (timeoutStatus == 2) {
1868                 if (addOneSecond) {
1869                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime + 1), " seconds!\n");
1870                         //don't show messages like "Timeout ends in 0 seconds"...
1871                         if ((remainingTimeoutTime + 1) > 0)
1872                                 return retStr;
1873                         else
1874                                 return "";
1875                 }
1876                 else {
1877                         retStr = strcat("Timeout ends in ", ftos(remainingTimeoutTime), " seconds!\n");
1878                         //don't show messages like "Timeout ends in 0 seconds"...
1879                         if (remainingTimeoutTime > 0)
1880                                 return retStr;
1881                         else
1882                                 return "";
1883                 }
1884         }
1885         else return "";
1886 }
1887
1888 void player_powerups (void)
1889 {
1890         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1891         {
1892                 SoundEntity_StartSound(self, CHAN_PLAYER, "misc/jetpack_fly.wav", VOL_BASE, cvar("g_jetpack_attenuation"));
1893                 self.modelflags |= MF_ROCKET;
1894         }
1895         else
1896         {
1897                 SoundEntity_StopSound(self, CHAN_PLAYER);
1898                 self.modelflags &~= MF_ROCKET;
1899         }
1900
1901         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1902
1903         if(!self.modelindex || self.deadflag) // don't apply the flags if the player is gibbed
1904                 return;
1905
1906         Fire_ApplyDamage(self);
1907         Fire_ApplyEffect(self);
1908
1909         if (g_minstagib)
1910         {
1911                 self.effects |= EF_FULLBRIGHT;
1912
1913                 if (self.items & IT_STRENGTH)
1914                 {
1915                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1916                         if (time > self.strength_finished)
1917                         {
1918                                 self.alpha = default_player_alpha;
1919                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1920                                 self.items &~= IT_STRENGTH;
1921                                 sprint(self, "^3Invisibility has worn off\n");
1922                         }
1923                 }
1924                 else
1925                 {
1926                         if (time < self.strength_finished)
1927                         {
1928                                 self.alpha = g_minstagib_invis_alpha;
1929                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1930                                 self.items |= IT_STRENGTH;
1931                                 sprint(self, "^3You are invisible\n");
1932                         }
1933                 }
1934
1935                 if (self.items & IT_INVINCIBLE)
1936                 {
1937                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1938                         if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1939                         {
1940                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1941                                 sprint(self, "^3Speed has worn off\n");
1942                         }
1943                 }
1944                 else
1945                 {
1946                         if (time < self.invincible_finished)
1947                         {
1948                                 self.items = self.items | IT_INVINCIBLE;
1949                                 sprint(self, "^3You are on speed\n");
1950                         }
1951                 }
1952                 return;
1953         }
1954
1955         if (self.items & IT_STRENGTH)
1956         {
1957                 play_countdown(self.strength_finished, "misc/poweroff.wav");
1958                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1959                 if (time > self.strength_finished && cvar("g_balance_powerup_timer"))
1960                 {
1961                         self.items = self.items - (self.items & IT_STRENGTH);
1962                         sprint(self, "^3Strength has worn off\n");
1963                 }
1964         }
1965         else
1966         {
1967                 if (time < self.strength_finished)
1968                 {
1969                         self.items = self.items | IT_STRENGTH;
1970                         sprint(self, "^3Strength infuses your weapons with devastating power\n");
1971                 }
1972         }
1973         if (self.items & IT_INVINCIBLE)
1974         {
1975                 play_countdown(self.invincible_finished, "misc/poweroff.wav");
1976                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1977                 if (time > self.invincible_finished && cvar("g_balance_powerup_timer"))
1978                 {
1979                         self.items = self.items - (self.items & IT_INVINCIBLE);
1980                         sprint(self, "^3Shield has worn off\n");
1981                 }
1982         }
1983         else
1984         {
1985                 if (time < self.invincible_finished)
1986                 {
1987                         self.items = self.items | IT_INVINCIBLE;
1988                         sprint(self, "^3Shield surrounds you\n");
1989                 }
1990         }
1991
1992         if(cvar("g_nodepthtestplayers"))
1993                 self.effects = self.effects | EF_NODEPTHTEST;
1994
1995         if(cvar("g_fullbrightplayers"))
1996                 self.effects = self.effects | EF_FULLBRIGHT;
1997
1998         // midair gamemode: damage only while in the air
1999         // if in midair mode, being on ground grants temporary invulnerability
2000         // (this is so that multishot weapon don't clear the ground flag on the
2001         // first damage in the frame, leaving the player vulnerable to the
2002         // remaining hits in the same frame)
2003         if (self.flags & FL_ONGROUND)
2004         if (g_midair)
2005                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
2006
2007         if (time >= game_starttime)
2008         if (time < self.spawnshieldtime)
2009                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
2010 }
2011
2012 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
2013 {
2014         if(current > stable)
2015                 return current;
2016         else if(current > stable - 0.25) // when close enough, "snap"
2017                 return stable;
2018         else
2019                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
2020 }
2021
2022 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
2023 {
2024         if(current < stable)
2025                 return current;
2026         else if(current < stable + 0.25) // when close enough, "snap"
2027                 return stable;
2028         else
2029                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
2030 }
2031
2032 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
2033 {
2034         if(current > rotstable)
2035         {
2036                 if(rotframetime > 0)
2037                 {
2038                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
2039                         current = max(rotstable, current - rotlinear * rotframetime);
2040                 }
2041         }
2042         else if(current < regenstable)
2043         {
2044                 if(regenframetime > 0)
2045                 {
2046                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
2047                         current = min(regenstable, current + regenlinear * regenframetime);
2048                 }
2049         }
2050
2051         if(current > limit)
2052                 current = limit;
2053
2054         return current;
2055 }
2056
2057 void player_regen (void)
2058 {
2059         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
2060         maxh = cvar("g_balance_health_rotstable");
2061         maxa = cvar("g_balance_armor_rotstable");
2062         maxf = cvar("g_balance_fuel_rotstable");
2063         minh = cvar("g_balance_health_regenstable");
2064         mina = cvar("g_balance_armor_regenstable");
2065         minf = cvar("g_balance_fuel_regenstable");
2066         limith = cvar("g_balance_health_limit");
2067         limita = cvar("g_balance_armor_limit");
2068         limitf = cvar("g_balance_fuel_limit");
2069
2070         max_mod = regen_mod = rot_mod = limit_mod = 1;
2071
2072         if (self.runes & RUNE_REGEN)
2073         {
2074                 if (self.runes & CURSE_VENOM) // do we have both rune/curse?
2075                 {
2076                         regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
2077                         max_mod = cvar("g_balance_rune_regen_combo_hpmod");
2078                         limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
2079                 }
2080                 else
2081                 {
2082                         regen_mod = cvar("g_balance_rune_regen_regenrate");
2083                         max_mod = cvar("g_balance_rune_regen_hpmod");
2084                         limit_mod = cvar("g_balance_rune_regen_limitmod");
2085                 }
2086         }
2087         else if (self.runes & CURSE_VENOM)
2088         {
2089                 max_mod = cvar("g_balance_curse_venom_hpmod");
2090                 if (self.runes & RUNE_REGEN) // do we have both rune/curse?
2091                         rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
2092                 else
2093                         rot_mod = cvar("g_balance_curse_venom_rotrate");
2094                 limit_mod = cvar("g_balance_curse_venom_limitmod");
2095                 //if (!self.runes & RUNE_REGEN)
2096                 //      rot_mod = cvar("g_balance_curse_venom_rotrate");
2097         }
2098         maxh = maxh * max_mod;
2099         //maxa = maxa * max_mod;
2100         //maxf = maxf * max_mod;
2101         minh = minh * max_mod;
2102         //mina = mina * max_mod;
2103         //minf = minf * max_mod;
2104         limith = limith * limit_mod;
2105         limita = limita * limit_mod;
2106         //limitf = limitf * limit_mod;
2107
2108         if(g_lms && g_ca)
2109                 rot_mod = 0;
2110
2111         if (!g_minstagib && !g_ca && (!g_lms || cvar("g_lms_regenerate")))
2112         {
2113                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, cvar("g_balance_armor_regen"), cvar("g_balance_armor_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxa, cvar("g_balance_armor_rot"), cvar("g_balance_armor_rotlinear"), rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2114                 self.health = CalcRotRegen(self.health, minh, cvar("g_balance_health_regen"), cvar("g_balance_health_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished), maxh, cvar("g_balance_health_rot"), cvar("g_balance_health_rotlinear"), rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2115
2116                 // if player rotted to death...  die!
2117                 if(self.health < 1)
2118                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2119         }
2120
2121         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2122                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, cvar("g_balance_fuel_regen"), cvar("g_balance_fuel_regenlinear"), regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, cvar("g_balance_fuel_rot"), cvar("g_balance_fuel_rotlinear"), rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2123 }
2124
2125 float zoomstate_set;
2126 void SetZoomState(float z)
2127 {
2128         if(z != self.zoomstate)
2129         {
2130                 self.zoomstate = z;
2131                 ClientData_Touch(self);
2132         }
2133         zoomstate_set = 1;
2134 }
2135
2136 void GetPressedKeys(void) {
2137         MUTATOR_CALLHOOK(GetPressedKeys);
2138         if (self.movement_x > 0) // get if movement keys are pressed
2139         {       // forward key pressed
2140                 self.pressedkeys |= KEY_FORWARD;
2141                 self.pressedkeys &~= KEY_BACKWARD;
2142         }
2143         else if (self.movement_x < 0)
2144         {       // backward key pressed
2145                 self.pressedkeys |= KEY_BACKWARD;
2146                 self.pressedkeys &~= KEY_FORWARD;
2147         }
2148         else
2149         {       // no x input
2150                 self.pressedkeys &~= KEY_FORWARD;
2151                 self.pressedkeys &~= KEY_BACKWARD;
2152         }
2153
2154         if (self.movement_y > 0)
2155         {       // right key pressed
2156                 self.pressedkeys |= KEY_RIGHT;
2157                 self.pressedkeys &~= KEY_LEFT;
2158         }
2159         else if (self.movement_y < 0)
2160         {       // left key pressed
2161                 self.pressedkeys |= KEY_LEFT;
2162                 self.pressedkeys &~= KEY_RIGHT;
2163         }
2164         else
2165         {       // no y input
2166                 self.pressedkeys &~= KEY_RIGHT;
2167                 self.pressedkeys &~= KEY_LEFT;
2168         }
2169
2170         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2171                 self.pressedkeys |= KEY_JUMP;
2172         else
2173                 self.pressedkeys &~= KEY_JUMP;
2174         if (self.BUTTON_CROUCH)
2175                 self.pressedkeys |= KEY_CROUCH;
2176         else
2177                 self.pressedkeys &~= KEY_CROUCH;
2178 }
2179
2180 void update_stats (float number, float hit, float fired) {
2181 // self.stat_hit   = number + ((number==0) ? 1 : 64) * hit   * sv_accuracy_data_share;
2182 // self.stat_fired = number + ((number==0) ? 1 : 64) * fired * sv_accuracy_data_share;
2183
2184         if(number) {
2185                 self.stat_hit = number + 64 * hit * sv_accuracy_data_share;
2186                 self.stat_fired = number + 64 * fired * sv_accuracy_data_share;
2187         } else {
2188                 self.stat_hit = hit * sv_accuracy_data_share;
2189                 self.stat_fired = fired * sv_accuracy_data_share;
2190         }
2191 }
2192
2193 /*
2194 ======================
2195 spectate mode routines
2196 ======================
2197 */
2198
2199 .float weapon_count;
2200 void SpectateCopy(entity spectatee) {
2201         if(spectatee.weapon_count < WEP_LAST) {
2202                 update_stats (spectatee.weapon_count, spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_hit[spectatee.weapon_count - 1]), spectatee.cvar_cl_accuracy_data_share * floor(spectatee.stats_fired[spectatee.weapon_count - 1]));
2203                 spectatee.weapon_count ++;
2204         } else
2205                 update_stats (0, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_hit, spectatee.cvar_cl_accuracy_data_share * spectatee.stat_fired);
2206
2207         other = spectatee;
2208         MUTATOR_CALLHOOK(SpectateCopy);
2209         self.armortype = spectatee.armortype;
2210         self.armorvalue = spectatee.armorvalue;
2211         self.ammo_cells = spectatee.ammo_cells;
2212         self.ammo_shells = spectatee.ammo_shells;
2213         self.ammo_nails = spectatee.ammo_nails;
2214         self.ammo_rockets = spectatee.ammo_rockets;
2215         self.ammo_fuel = spectatee.ammo_fuel;
2216         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2217         self.health = spectatee.health;
2218         self.impulse = 0;
2219         self.items = spectatee.items;
2220         self.metertime = spectatee.metertime;
2221         self.strength_finished = spectatee.strength_finished;
2222         self.invincible_finished = spectatee.invincible_finished;
2223         self.pressedkeys = spectatee.pressedkeys;
2224         self.weapons = spectatee.weapons;
2225         self.switchweapon = spectatee.switchweapon;
2226         self.weapon = spectatee.weapon;
2227         self.punchangle = spectatee.punchangle;
2228         self.view_ofs = spectatee.view_ofs;
2229         self.v_angle = spectatee.v_angle;
2230         self.velocity = spectatee.velocity;
2231         self.dmg_take = spectatee.dmg_take;
2232         self.dmg_save = spectatee.dmg_save;
2233         self.dmg_inflictor = spectatee.dmg_inflictor;
2234         self.angles = spectatee.v_angle;
2235         self.fixangle = TRUE;
2236         setorigin(self, spectatee.origin);
2237         setsize(self, spectatee.mins, spectatee.maxs);
2238         SetZoomState(spectatee.zoomstate);
2239
2240         anticheat_spectatecopy(spectatee);
2241 }
2242
2243 float SpectateUpdate() {
2244         if(!self.enemy)
2245                 return 0;
2246
2247         if (self == self.enemy)
2248                 return 0;
2249
2250         if(self.enemy.classname != "player")
2251                 return 0;
2252
2253         SpectateCopy(self.enemy);
2254
2255         return 1;
2256 }
2257
2258 float SpectateNext() {
2259         other = find(self.enemy, classname, "player");
2260
2261         if (!other)
2262                 other = find(other, classname, "player");
2263
2264         if (other)
2265                 self.enemy = other;
2266
2267         if(self.enemy.classname == "player") {
2268                 msg_entity = self;
2269                 WriteByte(MSG_ONE, SVC_SETVIEW);
2270                 WriteEntity(MSG_ONE, self.enemy);
2271                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
2272                 self.movetype = MOVETYPE_NONE;
2273
2274                 self.enemy.weapon_count = 0;
2275
2276                 if(!SpectateUpdate())
2277                         PutObserverInServer();
2278
2279                 return 1;
2280         } else {
2281                 return 0;
2282         }
2283 }
2284
2285 /*
2286 =============
2287 ShowRespawnCountdown()
2288
2289 Update a respawn countdown display.
2290 =============
2291 */
2292 void ShowRespawnCountdown()
2293 {
2294         float number;
2295         if(self.deadflag == DEAD_NO) // just respawned?
2296                 return;
2297         else
2298         {
2299                 number = ceil(self.death_time - time);
2300                 if(number <= 0)
2301                         return;
2302                 if(number <= self.respawn_countdown)
2303                 {
2304                         self.respawn_countdown = number - 1;
2305                         if(ceil(self.death_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2306                                 AnnounceTo(self, strcat(ftos(number), ""));
2307                 }
2308         }
2309 }
2310
2311 void LeaveSpectatorMode()
2312 {
2313         if(isJoinAllowed()) {
2314                 if(!teams_matter || cvar("g_campaign") || cvar("g_balance_teams") || (self.wasplayer && cvar("g_changeteam_banned"))) {
2315                         self.classname = "player";
2316
2317                         if(cvar("g_campaign") || cvar("g_balance_teams") || cvar("g_balance_teams_force"))
2318                                 JoinBestTeam(self, FALSE, TRUE);
2319
2320                         if(cvar("g_campaign"))
2321                                 campaign_bots_may_start = 1;
2322
2323                         self.stat_count = WEP_LAST;
2324
2325                         PutClientInServer();
2326
2327                         if(self.classname == "player")
2328                                 bprint ("^4", self.netname, "^4 is playing now\n");
2329
2330                         if(!cvar("g_campaign"))
2331                                 centerprint(self,""); // clear MOTD
2332
2333                         return;
2334                 } else {
2335                         if (g_ca && self.caplayer) {
2336                         }       // do nothing
2337                         else
2338                                 stuffcmd(self,"menu_showteamselect\n");
2339                         return;
2340                 }
2341         }
2342         else {
2343                 //player may not join because of g_maxplayers is set
2344                 centerprint_atprio(self, CENTERPRIO_MAPVOTE, PREVENT_JOIN_TEXT);
2345         }
2346 }
2347
2348 /**
2349  * Determines whether the player is allowed to join. This depends on cvar
2350  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2351  * it checks whether the number of currently playing players exceeds g_maxplayers.
2352  * @return bool TRUE if the player is allowed to join, false otherwise
2353  */
2354 float isJoinAllowed() {
2355         if (!cvar("g_maxplayers"))
2356                 return TRUE;
2357
2358         local entity e;
2359         local float currentlyPlaying;
2360         FOR_EACH_REALPLAYER(e) {
2361                 if(e.classname == "player")
2362                         currentlyPlaying += 1;
2363         }
2364         if(currentlyPlaying < cvar("g_maxplayers"))
2365                 return TRUE;
2366
2367         return FALSE;
2368 }
2369
2370 /**
2371  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2372  * g_maxplayers_spectator_blocktime seconds
2373  */
2374 void checkSpectatorBlock() {
2375         if(self.classname == "spectator" || self.classname == "observer") {
2376                 if( time > (self.spectatortime + cvar("g_maxplayers_spectator_blocktime")) ) {
2377                         sprint(self, "^7You were kicked from the server because you are spectator and spectators aren't allowed at the moment.\n");
2378                         dropclient(self);
2379                 }
2380         }
2381 }
2382
2383 float vercmp_recursive(string v1, string v2)
2384 {
2385         float dot1, dot2;
2386         string s1, s2;
2387         float r;
2388
2389         dot1 = strstrofs(v1, ".", 0);
2390         dot2 = strstrofs(v2, ".", 0);
2391         if(dot1 == -1)
2392                 s1 = v1;
2393         else
2394                 s1 = substring(v1, 0, dot1);
2395         if(dot2 == -1)
2396                 s2 = v2;
2397         else
2398                 s2 = substring(v2, 0, dot2);
2399
2400         r = stof(s1) - stof(s2);
2401         if(r != 0)
2402                 return r;
2403
2404         r = strcasecmp(s1, s2);
2405         if(r != 0)
2406                 return r;
2407
2408         if(dot1 == -1)
2409                 if(dot2 == -1)
2410                         return 0;
2411                 else
2412                         return -1;
2413         else
2414                 if(dot2 == -1)
2415                         return 1;
2416                 else
2417                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2418 }
2419
2420 float vercmp(string v1, string v2)
2421 {
2422         if(strcasecmp(v1, v2) == 0) // early out check
2423                 return 0;
2424         return vercmp_recursive(v1, v2);
2425 }
2426
2427 void ObserverThink()
2428 {
2429         if (self.flags & FL_JUMPRELEASED) {
2430                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2431                         self.welcomemessage_time = 0;
2432                         self.flags &~= FL_JUMPRELEASED;
2433                         self.flags |= FL_SPAWNING;
2434                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2435                         self.welcomemessage_time = 0;
2436                         self.flags &~= FL_JUMPRELEASED;
2437                         if(SpectateNext() == 1) {
2438                                 self.classname = "spectator";
2439                         }
2440                 }
2441         } else {
2442                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2443                         self.flags |= FL_JUMPRELEASED;
2444                         if(self.flags & FL_SPAWNING)
2445                         {
2446                                 self.flags &~= FL_SPAWNING;
2447                                 LeaveSpectatorMode();
2448                                 return;
2449                         }
2450                 }
2451         }
2452         PrintWelcomeMessage(self);
2453 }
2454
2455 void SpectatorThink()
2456 {
2457         if (self.flags & FL_JUMPRELEASED) {
2458                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2459                         self.welcomemessage_time = 0;
2460                         self.flags &~= FL_JUMPRELEASED;
2461                         self.flags |= FL_SPAWNING;
2462                 } else if(self.BUTTON_ATCK) {
2463                         self.welcomemessage_time = 0;
2464                         self.flags &~= FL_JUMPRELEASED;
2465                         if(SpectateNext() == 1) {
2466                                 self.classname = "spectator";
2467                         } else {
2468                                 self.classname = "observer";
2469                                 self.stat_count = WEP_LAST;
2470                                 PutClientInServer();
2471                         }
2472                 } else if (self.BUTTON_ATCK2) {
2473                         self.welcomemessage_time = 0;
2474                         self.flags &~= FL_JUMPRELEASED;
2475                         self.classname = "observer";
2476                         self.stat_count = WEP_LAST;
2477                         PutClientInServer();
2478                 } else {
2479                         if(!SpectateUpdate())
2480                                 PutObserverInServer();
2481                 }
2482         } else {
2483                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2484                         self.flags |= FL_JUMPRELEASED;
2485                         if(self.flags & FL_SPAWNING)
2486                         {
2487                                 self.flags &~= FL_SPAWNING;
2488                                 LeaveSpectatorMode();
2489                                 return;
2490                         }
2491                 }
2492         }
2493
2494         PrintWelcomeMessage(self);
2495         self.flags |= FL_CLIENT | FL_NOTARGET;
2496 }
2497
2498 .float touchexplode_time;
2499
2500 /*
2501 =============
2502 PlayerPreThink
2503
2504 Called every frame for each client before the physics are run
2505 =============
2506 */
2507 void() ctf_setstatus;
2508 void() nexball_setstatus;
2509 .float items_added;
2510 void PlayerPreThink (void)
2511 {
2512         self.stat_game_starttime = game_starttime;
2513         self.stat_allow_oldnexbeam = cvar("g_allow_oldnexbeam");
2514         self.stat_leadlimit = cvar("leadlimit");
2515
2516         if(frametime)
2517         {
2518                 // physics frames: update anticheat stuff
2519                 anticheat_prethink();
2520         }
2521
2522         if(blockSpectators && frametime)
2523                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2524                 checkSpectatorBlock();
2525
2526         zoomstate_set = 0;
2527
2528         if(self.netname_previous != self.netname)
2529         {
2530                 if(cvar("sv_eventlog"))
2531                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2532                 if(self.netname_previous)
2533                         strunzone(self.netname_previous);
2534                 self.netname_previous = strzone(self.netname);
2535         }
2536
2537         // version nagging
2538         if(self.version_nagtime)
2539                 if(self.cvar_g_xonoticversion)
2540                         if(time > self.version_nagtime)
2541                         {
2542                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0)
2543                                 {
2544                                         if(strstr(cvar_string("g_xonoticversion"), "git", 0) >= 0)
2545                                         {
2546                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2547                                                 sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2548                                         }
2549                                         else
2550                                         {
2551                                                 float r;
2552                                                 r = vercmp(self.cvar_g_xonoticversion, cvar_string("g_xonoticversion"));
2553                                                 if(r < 0)
2554                                                 {
2555                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n");
2556                                                         sprint(self, strcat("\{1}^1NOTE: ^3Xonotic ", cvar_string("g_xonoticversion"), "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.com/^1!\n"));
2557                                                 }
2558                                                 else if(r > 0)
2559                                                 {
2560                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2561                                                         sprint(self, strcat("\{1}^1NOTE: ^7the server is running ^3Xonotic ", cvar_string("g_xonoticversion"), "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n"));
2562                                                 }
2563                                         }
2564                                 }
2565                                 self.version_nagtime = 0;
2566                         }
2567
2568         // GOD MODE info
2569         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2570         {
2571                 sprint(self, strcat("godmode saved you ", ftos(self.max_armorvalue), " units of damage, cheater!\n"));
2572                 self.max_armorvalue = 0;
2573         }
2574
2575 #ifdef TETRIS
2576         if (TetrisPreFrame())
2577                 return;
2578 #endif
2579
2580         MUTATOR_CALLHOOK(PlayerPreThink);
2581
2582         if(self.classname == "player") {
2583 //              if(self.netname == "Wazat")
2584 //                      bprint(self.classname, "\n");
2585
2586                 CheckRules_Player();
2587
2588                 PrintWelcomeMessage(self);
2589
2590                 if (intermission_running)
2591                 {
2592                         IntermissionThink ();   // otherwise a button could be missed between
2593                         return;                                 // the think tics
2594                 }
2595
2596                 if(self.teleport_time)
2597                 if(time > self.teleport_time)
2598                 {
2599                         self.teleport_time = 0;
2600                         self.effects = self.effects - (self.effects & EF_NODRAW);
2601                 }
2602
2603                 if(frametime > 0) // don't do this in cl_movement frames, just in server ticks
2604                         UpdateSelectedPlayer();
2605
2606                 //don't allow the player to turn around while game is paused!
2607                 if(timeoutStatus == 2) {
2608                         self.v_angle = self.lastV_angle;
2609                         self.angles = self.lastV_angle;
2610                         self.fixangle = TRUE;
2611                 }
2612
2613                 if(frametime)
2614                 {
2615                         if(self.health <= 0 && cvar("g_deathglow"))
2616                         {
2617                                 if(self.glowmod_x > 0)
2618                                         self.glowmod_x -= cvar("g_deathglow") * frametime;
2619                                 else
2620                                         self.glowmod_x = -1;
2621                                 if(self.glowmod_y > 0)
2622                                         self.glowmod_y -= cvar("g_deathglow") * frametime;
2623                                 else
2624                                         self.glowmod_y = -1;
2625                                 if(self.glowmod_z > 0)
2626                                         self.glowmod_z -= cvar("g_deathglow") * frametime;
2627                                 else
2628                                         self.glowmod_z = -1;
2629                         }
2630                         else
2631                                 self.glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2632                         player_powerups();
2633                 }
2634
2635                 if (self.deadflag != DEAD_NO)
2636                 {
2637                         float button_pressed, force_respawn;
2638                         if(self.personal && g_race_qualifying)
2639                         {
2640                                 if(time > self.death_time)
2641                                 {
2642                                         self.death_time = time + 1; // only retry once a second
2643                                         respawn();
2644                                         self.impulse = 141;
2645                                 }
2646                         }
2647                         else
2648                         {
2649                                 if(frametime)
2650                                         player_anim();
2651                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2652                                 force_respawn = (g_lms || (g_ca) || cvar("g_forced_respawn"));
2653                                 if (self.deadflag == DEAD_DYING)
2654                                 {
2655                                         if(force_respawn)
2656                                                 self.deadflag = DEAD_RESPAWNING;
2657                                         else if(!button_pressed)
2658                                                 self.deadflag = DEAD_DEAD;
2659                                 }
2660                                 else if (self.deadflag == DEAD_DEAD)
2661                                 {
2662                                         if(button_pressed)
2663                                                 self.deadflag = DEAD_RESPAWNABLE;
2664                                 }
2665                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2666                                 {
2667                                         if(!button_pressed)
2668                                                 self.deadflag = DEAD_RESPAWNING;
2669                                 }
2670                                 else if (self.deadflag == DEAD_RESPAWNING)
2671                                 {
2672                                         if(time > self.death_time)
2673                                         {
2674                                                 self.death_time = time + 1; // only retry once a second
2675                                                 respawn();
2676                                         }
2677                                 }
2678                                 ShowRespawnCountdown();
2679                         }
2680                         return;
2681                 }
2682
2683                 if(g_touchexplode)
2684                 if(time > self.touchexplode_time)
2685                 if(self.classname == "player")
2686                 if(self.deadflag == DEAD_NO)
2687                 if not(IS_INDEPENDENT_PLAYER(self))
2688                 FOR_EACH_PLAYER(other) if(self != other)
2689                 {
2690                         if(time > other.touchexplode_time)
2691                         if(other.deadflag == DEAD_NO)
2692                         if not(IS_INDEPENDENT_PLAYER(other))
2693                         if(boxesoverlap(self.absmin, self.absmax, other.absmin, other.absmax))
2694                         {
2695                                 PlayerTouchExplode(self, other);
2696                                 self.touchexplode_time = other.touchexplode_time = time + 0.2;
2697                         }
2698                 }
2699
2700                 if(g_lms && !self.deadflag && cvar("g_lms_campcheck_interval"))
2701                 {
2702                         vector dist;
2703
2704                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2705                         dist = self.prevorigin - self.origin;
2706                         dist_z = 0;
2707                         self.lms_traveled_distance += fabs(vlen(dist));
2708
2709                         if((cvar("g_campaign") && !campaign_bots_may_start) || (time < game_starttime))
2710                         {
2711                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
2712                                 self.lms_traveled_distance = 0;
2713                         }
2714
2715                         if(time > self.lms_nextcheck)
2716                         {
2717                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2718                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
2719                                 {
2720                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
2721                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2722                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2723                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
2724                                 }
2725                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
2726                                 self.lms_traveled_distance = 0;
2727                         }
2728                 }
2729
2730                 self.prevorigin = self.origin;
2731
2732                 if ((self.BUTTON_CROUCH && !self.hook.state) || self.health <= g_bloodloss)
2733                 {
2734                         if (!self.crouch)
2735                         {
2736                                 self.crouch = TRUE;
2737                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2738                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2739                                 setanim(self, self.anim_duck, FALSE, TRUE, TRUE);
2740                         }
2741                 }
2742                 else
2743                 {
2744                         if (self.crouch)
2745                         {
2746                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2747                                 if (!trace_startsolid)
2748                                 {
2749                                         self.crouch = FALSE;
2750                                         self.view_ofs = PL_VIEW_OFS;
2751                                         setsize (self, PL_MIN, PL_MAX);
2752                                 }
2753                         }
2754                 }
2755
2756                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2757                 {
2758                         if(self.bloodloss_timer < time)
2759                         {
2760                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2761                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2762                         }
2763                 }
2764
2765                 FixPlayermodel();
2766
2767                 GrapplingHookFrame();
2768
2769                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2770                 //if(frametime)
2771                 {
2772                         self.items &~= self.items_added;
2773
2774                         W_WeaponFrame();
2775
2776                         self.items_added = 0;
2777                         if(self.items & IT_JETPACK)
2778                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2779                                         self.items_added |= IT_FUEL;
2780
2781                         self.items |= self.items_added;
2782                 }
2783
2784                 player_regen();
2785                 if(frametime)
2786                         player_anim();
2787
2788                 if (g_minstagib)
2789                         minstagib_ammocheck();
2790
2791                 ctf_setstatus();
2792                 nexball_setstatus();
2793
2794                 self.dmg_team = max(0, self.dmg_team - cvar("g_teamdamage_resetspeed") * frametime);
2795
2796                 //self.angles_y=self.v_angle_y + 90;   // temp
2797         } else if(gameover) {
2798                 if (intermission_running)
2799                         IntermissionThink ();   // otherwise a button could be missed between
2800                 return;
2801         } else if(self.classname == "observer") {
2802                 ObserverThink();
2803         } else if(self.classname == "spectator") {
2804                 SpectatorThink();
2805         }
2806
2807         if(!zoomstate_set)
2808                 SetZoomState(self.BUTTON_ZOOM || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_CAMPINGRIFLE && cvar("g_balance_campingrifle_secondary") == 0));
2809
2810         float oldspectatee_status;
2811         oldspectatee_status = self.spectatee_status;
2812         if(self.classname == "spectator")
2813                 self.spectatee_status = num_for_edict(self.enemy);
2814         else if(self.classname == "observer")
2815                 self.spectatee_status = num_for_edict(self);
2816         else
2817                 self.spectatee_status = 0;
2818         if(self.spectatee_status != oldspectatee_status)
2819         {
2820                 ClientData_Touch(self);
2821                 if(g_race || g_cts)
2822                         race_InitSpectator();
2823         }
2824
2825         if(self.teamkill_soundtime)
2826         if(time > self.teamkill_soundtime)
2827         {
2828                 self.teamkill_soundtime = 0;
2829
2830                 entity oldpusher, oldself;
2831
2832                 oldself = self; self = self.teamkill_soundsource;
2833                 oldpusher = self.pusher; self.pusher = oldself;
2834
2835                 PlayerSound(playersound_teamshoot, CHAN_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2836
2837                 self.pusher = oldpusher;
2838                 self = oldself;
2839         }
2840
2841         if(self.taunt_soundtime)
2842         if(time > self.taunt_soundtime)
2843         {
2844                 self.taunt_soundtime = 0;
2845                 PlayerSound(playersound_taunt, CHAN_VOICE, VOICETYPE_AUTOTAUNT);
2846         }
2847
2848         target_voicescript_next(self);
2849 }
2850
2851 float isInvisibleString(string s)
2852 {
2853         float i, n, c;
2854         s = strdecolorize(s);
2855         for((i = 0), (n = strlen(s)); i < n; ++i)
2856         {
2857                 c = str2chr(s, i);
2858                 switch(c)
2859                 {
2860                         case 0:
2861                         case 32: // space
2862                                 break;
2863                         case 192: // charmap space
2864                                 if (!cvar("utf8_enable"))
2865                                         break;
2866                                 return FALSE;
2867                         case 160: // space in unicode fonts
2868                         case 0xE000 + 192: // utf8 charmap space
2869                                 if (cvar("utf8_enable"))
2870                                         break;
2871                         default:
2872                                 return FALSE;
2873                 }
2874         }
2875         return TRUE;
2876 }
2877
2878 /*
2879 =============
2880 PlayerPostThink
2881
2882 Called every frame for each client after the physics are run
2883 =============
2884 */
2885 .float idlekick_lasttimeleft;
2886 .entity showheadshotbbox;
2887 void showheadshotbbox_think()
2888 {
2889         if(self.owner.showheadshotbbox != self)
2890         {
2891                 remove(self);
2892                 return;
2893         }
2894         self.nextthink = time;
2895         setorigin(self, self.owner.origin);
2896         setsize(self, GetHeadshotMins(self.owner), GetHeadshotMaxs(self.owner));
2897 }
2898 void PlayerPostThink (void)
2899 {
2900         // Savage: Check for nameless players
2901         if (isInvisibleString(self.netname)) {
2902                 self.netname = "Player";
2903                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2904         }
2905
2906         // send the clients accuracy stats to the client
2907         if(self.stat_count > 0)
2908         if(frametime)
2909         {
2910                 self.stat_hit = self.stat_count + 64 * floor(self.(stats_hit[self.stat_count - 1]));
2911                 self.stat_fired = self.stat_count + 64 * floor(self.(stats_fired[self.stat_count - 1]));
2912                 self.stat_count -= 1;
2913         }
2914
2915 #ifdef UID
2916         if(self.uid_kicktime)
2917         if(time > self.uid_kicktime)
2918         {
2919                 bprint("^3", self.netname, "^3 was kicked for missing UID.\n");
2920                 dropclient(self);
2921                 return;
2922         }
2923 #endif
2924
2925         if(sv_maxidle && frametime)
2926         {
2927                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2928                 float timeleft;
2929                 timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2930                 if(timeleft <= 0)
2931                 {
2932                         bprint("^3", self.netname, "^3 was kicked for idling.\n");
2933                         AnnounceTo(self, "terminated");
2934                         dropclient(self);
2935                         return;
2936                 }
2937                 else if(timeleft <= 10)
2938                 {
2939                         if(timeleft != self.idlekick_lasttimeleft)
2940                         {
2941                                 centerprint_atprio(self, CENTERPRIO_IDLEKICK, strcat("^3Stop idling!\n^3Disconnecting in ", ftos(timeleft), "..."));
2942                                 AnnounceTo(self, strcat(ftos(timeleft), ""));
2943                         }
2944                 }
2945                 else
2946                 {
2947                         centerprint_expire(self, CENTERPRIO_IDLEKICK);
2948                 }
2949                 self.idlekick_lasttimeleft = timeleft;
2950         }
2951
2952 #ifdef TETRIS
2953         if(self.impulse == 100)
2954                 ImpulseCommands();
2955         if (TetrisPostFrame())
2956                 return;
2957 #endif
2958
2959         CheatFrame();
2960
2961         if(self.classname == "player") {
2962                 CheckRules_Player();
2963                 UpdateChatBubble();
2964                 UpdateTeamBubble();
2965                 if (self.impulse)
2966                         ImpulseCommands();
2967                 if (intermission_running)
2968                         return;         // intermission or finale
2969                 GetPressedKeys();
2970         } else if (self.classname == "observer") {
2971                 //do nothing
2972         } else if (self.classname == "spectator") {
2973                 //do nothing
2974         }
2975
2976         /*
2977         float i;
2978         for(i = 0; i < 1000; ++i)
2979         {
2980                 vector end;
2981                 end = self.origin + '0 0 1024' + 512 * randomvec();
2982                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2983                 if(trace_fraction < 1)
2984                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2985                 {
2986                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2987                         break;
2988                 }
2989         }
2990         */
2991
2992         Arena_Warmup();
2993
2994         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2995
2996         if(self.waypointsprite_attachedforcarrier)
2997                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, cvar("g_balance_armor_blockpercent")));
2998
2999         if(self.classname == "player" && self.deadflag == DEAD_NO && cvar("r_showbboxes"))
3000         {
3001                 if(!self.showheadshotbbox)
3002                 {
3003                         self.showheadshotbbox = spawn();
3004                         self.showheadshotbbox.classname = "headshotbbox";
3005                         self.showheadshotbbox.owner = self;
3006                         self.showheadshotbbox.think = showheadshotbbox_think;
3007                         self.showheadshotbbox.nextthink = time;
3008                         self = self.showheadshotbbox;
3009                         self.think();
3010                         self = self.owner;
3011                 }
3012         }
3013         else
3014         {
3015                 if(self.showheadshotbbox)
3016                         remove(self.showheadshotbbox);
3017         }
3018
3019         playerdemo_write();
3020
3021         /*
3022         if(g_race)
3023                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3024         */
3025 }