qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ent_cs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "spawnpoints.qh"
  13 #include "g_damage.qh"
  14 #include "g_hook.qh"
  15 #include "command/common.qh"
  16 #include "cheats.qh"
  17 #include "g_world.qh"
  18 #include "race.qh"
  19 #include "antilag.qh"
  20 #include "campaign.qh"
  21 #include "command/common.qh"
  22
  23 #include "bot/bot.qh"
  24 #include "bot/navigation.qh"
  25
  26 #include "../common/vehicles/all.qh"
  27
  28 #include "weapons/hitplot.qh"
  29 #include "weapons/weaponsystem.qh"
  30
  31 #include "../common/net_notice.qh"
  32 #include "../common/physics.qh"
  33
  34 #include "../common/items/all.qc"
  35
  36 #include "../common/mutators/mutator/waypoints/all.qh"
  37
  38 #include "../common/triggers/subs.qh"
  39 #include "../common/triggers/triggers.qh"
  40 #include "../common/triggers/trigger/secret.qh"
  41
  42 #include "../common/minigames/sv_minigames.qh"
  43
  44 #include "../common/items/inventory.qh"
  45
  46 #include "../common/monsters/sv_monsters.qh"
  47
  48 #include "../warpzonelib/server.qh"
  49
  50
  51 void send_CSQC_teamnagger() {
  52         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  53         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  54 }
  55
  56 float ClientData_Send(entity to, int sf)
  57 {SELFPARAM();
  58         if(to != self.owner)
  59         {
  60                 error("wtf");
  61                 return false;
  62         }
  63
  64         entity e;
  65
  66         e = to;
  67         if(IS_SPEC(to))
  68                 e = to.enemy;
  69
  70         sf = 0;
  71
  72         if(e.race_completed)
  73                 sf |= 1; // forced scoreboard
  74         if(to.spectatee_status)
  75                 sf |= 2; // spectator ent number follows
  76         if(e.zoomstate)
  77                 sf |= 4; // zoomed
  78         if(e.porto_v_angle_held)
  79                 sf |= 8; // angles held
  80
  81         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  82         WriteByte(MSG_ENTITY, sf);
  83
  84         if(sf & 2)
  85                 WriteByte(MSG_ENTITY, to.spectatee_status);
  86
  87         if(sf & 8)
  88         {
  89                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  90                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  91         }
  92
  93         return true;
  94 }
  95
  96 void ClientData_Attach()
  97 {SELFPARAM();
  98         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  99         self.clientdata.drawonlytoclient = self;
 100         self.clientdata.owner = self;
 101 }
 102
 103 void ClientData_Detach()
 104 {SELFPARAM();
 105         remove(self.clientdata);
 106         self.clientdata = world;
 107 }
 108
 109 void ClientData_Touch(entity e)
 110 {
 111         e.clientdata.SendFlags = 1;
 112
 113         // make it spectatable
 114         entity e2;
 115         FOR_EACH_REALCLIENT(e2)
 116         {
 117                 if(e2 != e)
 118                         if(IS_SPEC(e2))
 119                                 if(e2.enemy == e)
 120                                         e2.clientdata.SendFlags = 1;
 121         }
 122 }
 123
 124 .string netname_previous;
 125
 126 void SetSpectator(entity player, entity spectatee);
 127
 128
 129 /*
 130 =============
 131 CheckPlayerModel
 132
 133 Checks if the argument string can be a valid playermodel.
 134 Returns a valid one in doubt.
 135 =============
 136 */
 137 string FallbackPlayerModel;
 138 string CheckPlayerModel(string plyermodel) {
 139         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 140         {
 141                 // note: we cannot summon Don Strunzone here, some player may
 142                 // still have the model string set. In case anyone manages how
 143                 // to change a cvar default, we'll have a small leak here.
 144                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 145         }
 146         // only in right path
 147         if( substring(plyermodel,0,14) != "models/player/")
 148                 return FallbackPlayerModel;
 149         // only good file extensions
 150         if(substring(plyermodel,-4,4) != ".zym")
 151         if(substring(plyermodel,-4,4) != ".dpm")
 152         if(substring(plyermodel,-4,4) != ".iqm")
 153         if(substring(plyermodel,-4,4) != ".md3")
 154         if(substring(plyermodel,-4,4) != ".psk")
 155                 return FallbackPlayerModel;
 156         // forbid the LOD models
 157         if(substring(plyermodel, -9,5) == "_lod1")
 158                 return FallbackPlayerModel;
 159         if(substring(plyermodel, -9,5) == "_lod2")
 160                 return FallbackPlayerModel;
 161         if(plyermodel != strtolower(plyermodel))
 162                 return FallbackPlayerModel;
 163         // also, restrict to server models
 164         if(autocvar_sv_servermodelsonly)
 165         {
 166                 if(!fexists(plyermodel))
 167                         return FallbackPlayerModel;
 168         }
 169         return plyermodel;
 170 }
 171
 172 void setplayermodel(entity e, string modelname)
 173 {
 174         precache_model(modelname);
 175         setmodel(e, modelname);
 176         player_setupanimsformodel();
 177         UpdatePlayerSounds();
 178 }
 179
 180 /*
 181 =============
 182 PutObserverInServer
 183
 184 putting a client as observer in the server
 185 =============
 186 */
 187 void FixPlayermodel();
 188 void PutObserverInServer (void)
 189 {SELFPARAM();
 190         entity  spot;
 191     self.hud = HUD_NORMAL;
 192
 193         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
 194
 195         spot = SelectSpawnPoint (true);
 196         if(!spot)
 197                 error("No spawnpoints for observers?!?\n");
 198         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 199
 200         if(IS_REAL_CLIENT(self))
 201         {
 202                 msg_entity = self;
 203                 WriteByte(MSG_ONE, SVC_SETVIEW);
 204                 WriteEntity(MSG_ONE, self);
 205         }
 206
 207         self.frags = FRAGS_SPECTATOR;
 208
 209         MUTATOR_CALLHOOK(MakePlayerObserver);
 210
 211         Portal_ClearAll(self);
 212
 213         Unfreeze(self);
 214
 215         if(self.alivetime)
 216         {
 217                 if(!warmup_stage)
 218                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 219                 self.alivetime = 0;
 220         }
 221
 222         if(self.vehicle)
 223                 vehicles_exit(VHEF_RELEASE);
 224
 225         WaypointSprite_PlayerDead();
 226
 227         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 228                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 229
 230         if(self.killcount != -666)
 231         {
 232                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 233                 if(!intermission_running)
 234                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 235                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 236
 237                 if(self.just_joined == false) {
 238                         LogTeamchange(self.playerid, -1, 4);
 239                 } else
 240                         self.just_joined = false;
 241         }
 242
 243         PlayerScore_Clear(self); // clear scores when needed
 244
 245         accuracy_resend(self);
 246
 247         self.spectatortime = time;
 248
 249         self.classname = "observer";
 250         self.iscreature = false;
 251         self.teleportable = TELEPORT_SIMPLE;
 252         self.damagedbycontents = false;
 253         self.health = -666;
 254         self.takedamage = DAMAGE_NO;
 255         self.solid = SOLID_NOT;
 256         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 257         self.flags = FL_CLIENT | FL_NOTARGET;
 258         self.armorvalue = 666;
 259         self.effects = 0;
 260         self.armorvalue = autocvar_g_balance_armor_start;
 261         self.pauserotarmor_finished = 0;
 262         self.pauserothealth_finished = 0;
 263         self.pauseregen_finished = 0;
 264         self.damageforcescale = 0;
 265         self.death_time = 0;
 266         self.respawn_flags = 0;
 267         self.respawn_time = 0;
 268         self.stat_respawn_time = 0;
 269         self.alpha = 0;
 270         self.scale = 0;
 271         self.fade_time = 0;
 272         self.pain_frame = 0;
 273         self.pain_finished = 0;
 274         self.strength_finished = 0;
 275         self.invincible_finished = 0;
 276         self.superweapons_finished = 0;
 277         self.pushltime = 0;
 278         self.istypefrag = 0;
 279         self.think = func_null;
 280         self.nextthink = 0;
 281         self.hook_time = 0;
 282         self.deadflag = DEAD_NO;
 283         self.angles = spot.angles;
 284         self.angles_z = 0;
 285         self.fixangle = true;
 286         self.crouch = false;
 287         self.revival_time = 0;
 288
 289         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 290         self.prevorigin = self.origin;
 291         self.items = 0;
 292         self.weapons = '0 0 0';
 293         self.model = "";
 294         FixPlayermodel();
 295         setmodel(self, "null");
 296         self.drawonlytoclient = self;
 297
 298         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 299         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 300
 301         self.weapon = 0;
 302         self.weaponname = "";
 303         self.switchingweapon = 0;
 304         self.weaponmodel = "";
 305         self.weaponentity = world;
 306         self.exteriorweaponentity = world;
 307         self.killcount = -666;
 308         self.velocity = '0 0 0';
 309         self.avelocity = '0 0 0';
 310         self.punchangle = '0 0 0';
 311         self.punchvector = '0 0 0';
 312         self.oldvelocity = self.velocity;
 313         self.fire_endtime = -1;
 314         self.event_damage = func_null;
 315 }
 316
 317 .float model_randomizer;
 318 void FixPlayermodel()
 319 {SELFPARAM();
 320         string defaultmodel;
 321         float defaultskin, chmdl, oldskin, n, i;
 322         vector m1, m2;
 323
 324         defaultmodel = "";
 325         defaultskin = 0;
 326         chmdl = false;
 327
 328         if(autocvar_sv_defaultcharacter)
 329         {
 330                 if(teamplay)
 331                 {
 332                         string s;
 333                         s = Static_Team_ColorName_Lower(self.team);
 334                         if(s != "neutral")
 335                         {
 336                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 337                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 338                         }
 339                 }
 340
 341                 if(defaultmodel == "")
 342                 {
 343                         defaultmodel = autocvar_sv_defaultplayermodel;
 344                         defaultskin = autocvar_sv_defaultplayerskin;
 345                 }
 346
 347                 n = tokenize_console(defaultmodel);
 348                 if(n > 0)
 349                 {
 350                         defaultmodel = argv(floor(n * self.model_randomizer));
 351                         // However, do NOT randomize if the player-selected model is in the list.
 352                         for (i = 0; i < n; ++i)
 353                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 354                                         defaultmodel = argv(i);
 355                 }
 356
 357                 i = strstrofs(defaultmodel, ":", 0);
 358                 if(i >= 0)
 359                 {
 360                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 361                         defaultmodel = substring(defaultmodel, 0, i);
 362                 }
 363         }
 364
 365         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin);
 366         defaultmodel = ret_string;
 367         defaultskin = ret_int;
 368
 369         if(defaultmodel != "")
 370         {
 371                 if (defaultmodel != self.model)
 372                 {
 373                         m1 = self.mins;
 374                         m2 = self.maxs;
 375                         setplayermodel (self, defaultmodel);
 376                         setsize (self, m1, m2);
 377                         chmdl = true;
 378                 }
 379
 380                 oldskin = self.skin;
 381                 self.skin = defaultskin;
 382         } else {
 383                 if (self.playermodel != self.model || self.playermodel == "")
 384                 {
 385                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 386                         m1 = self.mins;
 387                         m2 = self.maxs;
 388                         setplayermodel (self, self.playermodel);
 389                         setsize (self, m1, m2);
 390                         chmdl = true;
 391                 }
 392
 393                 oldskin = self.skin;
 394                 self.skin = stof(self.playerskin);
 395         }
 396
 397         if(chmdl || oldskin != self.skin) // model or skin has changed
 398         {
 399                 self.species = player_getspecies(); // update species
 400                 UpdatePlayerSounds(); // update skin sounds
 401         }
 402
 403         if(!teamplay)
 404                 if(strlen(autocvar_sv_defaultplayercolors))
 405                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 406                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 407 }
 408
 409
 410 /** Called when a client spawns in the server */
 411 void PutClientInServer()
 412 {
 413         SELFPARAM();
 414         if(IS_BOT_CLIENT(self))
 415                 self.classname = "player";
 416         else if(IS_REAL_CLIENT(self))
 417         {
 418                 msg_entity = self;
 419                 WriteByte(MSG_ONE, SVC_SETVIEW);
 420                 WriteEntity(MSG_ONE, self);
 421         }
 422
 423         SetSpectator(self, world);
 424
 425         // reset player keys
 426         self.itemkeys = 0;
 427
 428         MUTATOR_CALLHOOK(PutClientInServer, self);
 429
 430         if(gameover)
 431                 self.classname = "observer";
 432
 433         if(IS_PLAYER(self))
 434         {
 435                 entity spot, oldself;
 436
 437                 accuracy_resend(self);
 438
 439                 if(self.team < 0)
 440                         JoinBestTeam(self, false, true);
 441
 442                 spot = SelectSpawnPoint (false);
 443                 if(!spot)
 444                 {
 445                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 446                         return; // spawn failed
 447                 }
 448
 449                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 450
 451                 self.classname = "player";
 452                 self.wasplayer = true;
 453                 self.iscreature = true;
 454                 self.teleportable = TELEPORT_NORMAL;
 455                 self.damagedbycontents = true;
 456                 self.movetype = MOVETYPE_WALK;
 457                 self.solid = SOLID_SLIDEBOX;
 458                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 459                 if(autocvar_g_playerclip_collisions)
 460                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 461                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 462                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 463                 self.frags = FRAGS_PLAYER;
 464                 if(INDEPENDENT_PLAYERS)
 465                         MAKE_INDEPENDENT_PLAYER(self);
 466                 self.flags = FL_CLIENT | FL_PICKUPITEMS;
 467                 if(autocvar__notarget)
 468                         self.flags |= FL_NOTARGET;
 469                 self.takedamage = DAMAGE_AIM;
 470                 self.effects = 0;
 471                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 472                 self.air_finished = time + 12;
 473                 self.dmg = 2;
 474                 if(WEP_CVAR(vortex, charge))
 475                 {
 476                         if(WEP_CVAR_SEC(vortex, chargepool))
 477                                 self.vortex_chargepool_ammo = 1;
 478                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 479                 }
 480
 481                 if(warmup_stage)
 482                 {
 483                         self.ammo_shells = warmup_start_ammo_shells;
 484                         self.ammo_nails = warmup_start_ammo_nails;
 485                         self.ammo_rockets = warmup_start_ammo_rockets;
 486                         self.ammo_cells = warmup_start_ammo_cells;
 487                         self.ammo_plasma = warmup_start_ammo_plasma;
 488                         self.ammo_fuel = warmup_start_ammo_fuel;
 489                         self.health = warmup_start_health;
 490                         self.armorvalue = warmup_start_armorvalue;
 491                         self.weapons = WARMUP_START_WEAPONS;
 492                 }
 493                 else
 494                 {
 495                         self.ammo_shells = start_ammo_shells;
 496                         self.ammo_nails = start_ammo_nails;
 497                         self.ammo_rockets = start_ammo_rockets;
 498                         self.ammo_cells = start_ammo_cells;
 499                         self.ammo_plasma = start_ammo_plasma;
 500                         self.ammo_fuel = start_ammo_fuel;
 501                         self.health = start_health;
 502                         self.armorvalue = start_armorvalue;
 503                         self.weapons = start_weapons;
 504                 }
 505
 506                 if(self.weapons & WEPSET_SUPERWEAPONS)
 507                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 508                 else
 509                         self.superweapons_finished = 0;
 510
 511                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 512                 {
 513                         if(g_weaponarena_random_with_blaster)
 514                                 self.weapons &= ~WEPSET_BLASTER;
 515                         W_RandomWeapons(self, g_weaponarena_random);
 516                         if(g_weaponarena_random_with_blaster)
 517                                 self.weapons |= WEPSET_BLASTER;
 518                 }
 519
 520                 self.items = start_items;
 521
 522                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 523                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 524                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 525                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 526                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 527                 //extend the pause of rotting if client was reset at the beginning of the countdown
 528                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 529                         self.spawnshieldtime += game_starttime - time;
 530                         self.pauserotarmor_finished += game_starttime - time;
 531                         self.pauserothealth_finished += game_starttime - time;
 532                         self.pauseregen_finished += game_starttime - time;
 533                 }
 534                 self.damageforcescale = 2;
 535                 self.death_time = 0;
 536                 self.respawn_flags = 0;
 537                 self.respawn_time = 0;
 538                 self.stat_respawn_time = 0;
 539                 self.scale = autocvar_sv_player_scale;
 540                 self.fade_time = 0;
 541                 self.pain_frame = 0;
 542                 self.pain_finished = 0;
 543                 self.strength_finished = 0;
 544                 self.invincible_finished = 0;
 545                 self.pushltime = 0;
 546                 // players have no think function
 547                 self.think = func_null;
 548                 self.nextthink = 0;
 549                 self.hook_time = 0;
 550                 self.dmg_team = 0;
 551                 self.ballistics_density = autocvar_g_ballistics_density_player;
 552
 553                 self.metertime = 0;
 554
 555                 self.deadflag = DEAD_NO;
 556
 557                 self.angles = spot.angles;
 558
 559                 self.angles_z = 0; // never spawn tilted even if the spot says to
 560                 if(IS_BOT_CLIENT(self))
 561                         self.v_angle = self.angles;
 562                 self.fixangle = true; // turn this way immediately
 563                 self.velocity = '0 0 0';
 564                 self.avelocity = '0 0 0';
 565                 self.punchangle = '0 0 0';
 566                 self.punchvector = '0 0 0';
 567                 self.oldvelocity = self.velocity;
 568                 self.fire_endtime = -1;
 569                 self.revival_time = 0;
 570
 571                 entity spawnevent = spawn();
 572                 spawnevent.owner = self;
 573                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 574
 575                 // Cut off any still running player sounds.
 576                 stopsound(self, CH_PLAYER_SINGLE);
 577
 578                 self.model = "";
 579                 FixPlayermodel();
 580                 self.drawonlytoclient = world;
 581
 582                 self.crouch = false;
 583                 self.view_ofs = PL_VIEW_OFS;
 584                 setsize (self, PL_MIN, PL_MAX);
 585                 self.spawnorigin = spot.origin;
 586                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 587                 // don't reset back to last position, even if new position is stuck in solid
 588                 self.oldorigin = self.origin;
 589                 self.prevorigin = self.origin;
 590                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 591                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 592         self.hud = HUD_NORMAL;
 593
 594                 self.event_damage = PlayerDamage;
 595
 596                 self.bot_attack = true;
 597                 self.monster_attack = true;
 598
 599                 self.spider_slowness = 0;
 600
 601                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 602
 603                 if(self.killcount == -666) {
 604                         PlayerScore_Clear(self);
 605                         self.killcount = 0;
 606                 }
 607
 608                 CL_SpawnWeaponentity(self);
 609                 self.alpha = default_player_alpha;
 610                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 611                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 612
 613                 self.speedrunning = false;
 614
 615                 //stuffcmd(self, "chase_active 0");
 616                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 617
 618                 target_voicescript_clear(self);
 619
 620                 // reset fields the weapons may use
 621                 for (int j = WEP_FIRST; j <= WEP_LAST; ++j)
 622                 {
 623                         WEP_ACTION(j, WR_RESETPLAYER);
 624
 625                         // all weapons must be fully loaded when we spawn
 626                         entity e = get_weaponinfo(j);
 627                         if (e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 628                                 self.(weapon_load[j]) = e.reloading_ammo;
 629                 }
 630
 631                 oldself = self;
 632                 self = spot;
 633                         activator = oldself;
 634                                 string s;
 635                                 s = self.target;
 636                                 self.target = string_null;
 637                                 SUB_UseTargets();
 638                                 self.target = s;
 639                         activator = world;
 640                 self = oldself;
 641
 642                 Unfreeze(self);
 643
 644                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 645
 646                 if(autocvar_spawn_debug)
 647                 {
 648                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 649                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 650                 }
 651
 652                 self.switchweapon = w_getbestweapon(self);
 653                 self.cnt = -1; // W_LastWeapon will not complain
 654                 self.weapon = 0;
 655                 self.weaponname = "";
 656                 self.switchingweapon = 0;
 657
 658                 if(!warmup_stage)
 659                         if(!self.alivetime)
 660                                 self.alivetime = time;
 661
 662                 antilag_clear(self);
 663         }
 664         else if(IS_OBSERVER(self))
 665         {
 666                 PutObserverInServer ();
 667         }
 668 }
 669
 670 .float ebouncefactor, ebouncestop; // electro's values
 671 // TODO do we need all these fields, or should we stop autodetecting runtime
 672 // changes and just have a console command to update this?
 673 float ClientInit_SendEntity(entity to, int sf)
 674 {SELFPARAM();
 675         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 676         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 677         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 678         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 679         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 680         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 681         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 682         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 683         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 684         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 685
 686         if(sv_foginterval && world.fog != "")
 687                 WriteString(MSG_ENTITY, world.fog);
 688         else
 689                 WriteString(MSG_ENTITY, "");
 690         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 691         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 692         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 693         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 694         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 695         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 696         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 697         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 698         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 699         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 700         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 701         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 702         return true;
 703 }
 704
 705 void ClientInit_CheckUpdate()
 706 {SELFPARAM();
 707         self.nextthink = time;
 708         if(self.count != autocvar_g_balance_armor_blockpercent)
 709         {
 710                 self.count = autocvar_g_balance_armor_blockpercent;
 711                 self.SendFlags |= 1;
 712         }
 713         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 714         {
 715                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 716                 self.SendFlags |= 1;
 717         }
 718         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 719         {
 720                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 721                 self.SendFlags |= 1;
 722         }
 723         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 724         {
 725                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 726                 self.SendFlags |= 1;
 727         }
 728         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 729         {
 730                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 731                 self.SendFlags |= 1;
 732         }
 733 }
 734
 735 void ClientInit_Spawn()
 736 {SELFPARAM();
 737         entity o;
 738         entity e;
 739         e = spawn();
 740         e.classname = "clientinit";
 741         e.think = ClientInit_CheckUpdate;
 742         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 743
 744         o = self;
 745         self = e;
 746         ClientInit_CheckUpdate();
 747         self = o;
 748 }
 749
 750 /*
 751 =============
 752 SetNewParms
 753 =============
 754 */
 755 void SetNewParms (void)
 756 {
 757         // initialize parms for a new player
 758         parm1 = -(86400 * 366);
 759 }
 760
 761 /*
 762 =============
 763 SetChangeParms
 764 =============
 765 */
 766 void SetChangeParms (void)
 767 {SELFPARAM();
 768         // save parms for level change
 769         parm1 = self.parm_idlesince - time;
 770 }
 771
 772 /*
 773 =============
 774 DecodeLevelParms
 775 =============
 776 */
 777 void DecodeLevelParms (void)
 778 {SELFPARAM();
 779         // load parms
 780         self.parm_idlesince = parm1;
 781         if(self.parm_idlesince == -(86400 * 366))
 782                 self.parm_idlesince = time;
 783
 784         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 785         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 786 }
 787
 788 /*
 789 =============
 790 ClientKill
 791
 792 Called when a client types 'kill' in the console
 793 =============
 794 */
 795
 796 .float clientkill_nexttime;
 797 void ClientKill_Now_TeamChange()
 798 {SELFPARAM();
 799         if(self.killindicator_teamchange == -1)
 800         {
 801                 JoinBestTeam( self, false, true );
 802         }
 803         else if(self.killindicator_teamchange == -2)
 804         {
 805                 if(blockSpectators)
 806                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 807                 PutObserverInServer();
 808         }
 809         else
 810                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 811         self.killindicator_teamchange = 0;
 812 }
 813
 814 void ClientKill_Now()
 815 {SELFPARAM();
 816         if(self.vehicle)
 817         {
 818             vehicles_exit(VHEF_RELEASE);
 819             if(!self.killindicator_teamchange)
 820             {
 821             self.vehicle_health = -1;
 822             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 823             }
 824         }
 825
 826         if(self.killindicator && !wasfreed(self.killindicator))
 827                 remove(self.killindicator);
 828
 829         self.killindicator = world;
 830
 831         if(self.killindicator_teamchange)
 832                 ClientKill_Now_TeamChange();
 833
 834         if(IS_PLAYER(self))
 835                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 836
 837         // now I am sure the player IS dead
 838 }
 839 void KillIndicator_Think()
 840 {SELFPARAM();
 841         if (gameover)
 842         {
 843                 self.owner.killindicator = world;
 844                 remove(self);
 845                 return;
 846         }
 847
 848         if (self.owner.alpha < 0 && !self.owner.vehicle)
 849         {
 850                 self.owner.killindicator = world;
 851                 remove(self);
 852                 return;
 853         }
 854
 855         if(self.cnt <= 0)
 856         {
 857                 self = self.owner;
 858                 ClientKill_Now(); // no oldself needed
 859                 return;
 860         }
 861     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 862     {
 863         self.nextthink = time + 1;
 864         self.cnt -= 1;
 865     }
 866         else
 867         {
 868                 if(self.cnt <= 10)
 869                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 870                 if(IS_REAL_CLIENT(self.owner))
 871                 {
 872                         if(self.cnt <= 10)
 873                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 874                 }
 875                 self.nextthink = time + 1;
 876                 self.cnt -= 1;
 877         }
 878 }
 879
 880 float clientkilltime;
 881 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 882 {SELFPARAM();
 883         float killtime;
 884         float starttime;
 885         entity e;
 886
 887         if (gameover)
 888                 return;
 889
 890         killtime = autocvar_g_balance_kill_delay;
 891
 892         if(g_race_qualifying || g_cts)
 893                 killtime = 0;
 894
 895     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 896     {
 897                 remove(self.killindicator);
 898                 self.killindicator = world;
 899
 900         ClientKill_Now(); // allow instant kill in this case
 901         return;
 902     }
 903
 904         self.killindicator_teamchange = targetteam;
 905
 906     if(!self.killindicator)
 907         {
 908                 if(self.deadflag == DEAD_NO)
 909                 {
 910                         killtime = max(killtime, self.clientkill_nexttime - time);
 911                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 912                 }
 913
 914                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 915                 {
 916                         ClientKill_Now();
 917                 }
 918                 else
 919                 {
 920                         starttime = max(time, clientkilltime);
 921
 922                         self.killindicator = spawn();
 923                         self.killindicator.owner = self;
 924                         self.killindicator.scale = 0.5;
 925                         setattachment(self.killindicator, self, "");
 926                         setorigin(self.killindicator, '0 0 52');
 927                         self.killindicator.think = KillIndicator_Think;
 928                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 929                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 930                         self.killindicator.cnt = ceil(killtime);
 931                         self.killindicator.count = bound(0, ceil(killtime), 10);
 932                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 933
 934                         for(e = world; (e = find(e, classname, "body")) != world; )
 935                         {
 936                                 if(e.enemy != self)
 937                                         continue;
 938                                 e.killindicator = spawn();
 939                                 e.killindicator.owner = e;
 940                                 e.killindicator.scale = 0.5;
 941                                 setattachment(e.killindicator, e, "");
 942                                 setorigin(e.killindicator, '0 0 52');
 943                                 e.killindicator.think = KillIndicator_Think;
 944                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 945                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 946                                 e.killindicator.cnt = ceil(killtime);
 947                         }
 948                         self.lip = 0;
 949                 }
 950         }
 951         if(self.killindicator)
 952         {
 953                 if(targetteam == 0) // just die
 954                 {
 955                         self.killindicator.colormod = '0 0 0';
 956                         if(IS_REAL_CLIENT(self))
 957                         if(self.killindicator.cnt > 0)
 958                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 959                 }
 960                 else if(targetteam == -1) // auto
 961                 {
 962                         self.killindicator.colormod = '0 1 0';
 963                         if(IS_REAL_CLIENT(self))
 964                         if(self.killindicator.cnt > 0)
 965                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 966                 }
 967                 else if(targetteam == -2) // spectate
 968                 {
 969                         self.killindicator.colormod = '0.5 0.5 0.5';
 970                         if(IS_REAL_CLIENT(self))
 971                         if(self.killindicator.cnt > 0)
 972                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 973                 }
 974                 else
 975                 {
 976                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 977                         if(IS_REAL_CLIENT(self))
 978                         if(self.killindicator.cnt > 0)
 979                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 980                 }
 981         }
 982
 983 }
 984
 985 void ClientKill (void)
 986 {SELFPARAM();
 987         if(gameover) return;
 988         if(self.player_blocked) return;
 989         if(self.frozen) return;
 990
 991         ClientKill_TeamChange(0);
 992 }
 993
 994 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 995 {
 996     e.killindicator = spawn();
 997     e.killindicator.owner = e;
 998     e.killindicator.think = KillIndicator_Think;
 999     e.killindicator.nextthink = time + (e.lip) * 0.05;
1000     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1001     e.killindicator.health = 1; // this is used to indicate that it should be silent
1002     e.lip = 0;
1003 }
1004
1005 void FixClientCvars(entity e)
1006 {
1007         // send prediction settings to the client
1008         stuffcmd(e, "\nin_bindmap 0 0\n");
1009         if(g_race || g_cts)
1010                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1011         if(autocvar_g_antilag == 3) // client side hitscan
1012                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1013         if(autocvar_sv_gentle)
1014                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1015 }
1016
1017 float PlayerInIDList(entity p, string idlist)
1018 {
1019         float n, i;
1020         string s;
1021
1022         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1023         if (!p.crypto_idfp)
1024                 return 0;
1025
1026         // this function allows abbreviated player IDs too!
1027         n = tokenize_console(idlist);
1028         for(i = 0; i < n; ++i)
1029         {
1030                 s = argv(i);
1031                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1032                         return 1;
1033         }
1034
1035         return 0;
1036 }
1037
1038 #ifdef DP_EXT_PRECONNECT
1039 /*
1040 =============
1041 ClientPreConnect
1042
1043 Called once (not at each match start) when a client begins a connection to the server
1044 =============
1045 */
1046 void ClientPreConnect (void)
1047 {SELFPARAM();
1048         if(autocvar_sv_eventlog)
1049         {
1050                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1051                         self.playerid,
1052                         num_for_edict(self),
1053                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1054                 ));
1055         }
1056 }
1057 #endif
1058
1059 /*
1060 =============
1061 ClientConnect
1062
1063 Called when a client connects to the server
1064 =============
1065 */
1066 void DecodeLevelParms (void);
1067 void ClientConnect (void)
1068 {SELFPARAM();
1069         float t;
1070
1071         if(IS_CLIENT(self))
1072         {
1073                 LOG_INFO("Warning: ClientConnect, but already connected!\n");
1074                 return;
1075         }
1076
1077         if(Ban_MaybeEnforceBanOnce(self))
1078                 return;
1079
1080         DecodeLevelParms();
1081
1082 #ifdef WATERMARK
1083         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1084 #endif
1085
1086         self.classname = "player_joining";
1087
1088         self.flags = FL_CLIENT;
1089         self.version_nagtime = time + 10 + random() * 10;
1090
1091         if(player_count<0)
1092         {
1093                 LOG_TRACE("BUG player count is lower than zero, this cannot happen!\n");
1094                 player_count = 0;
1095         }
1096
1097         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1098
1099         PlayerScore_Attach(self);
1100         ClientData_Attach();
1101         accuracy_init(self);
1102         Inventory_new(self);
1103
1104         bot_clientconnect();
1105
1106         playerdemo_init();
1107
1108         anticheat_init();
1109
1110         // identify the right forced team
1111         if(autocvar_g_campaign)
1112         {
1113                 if(IS_REAL_CLIENT(self)) // only players, not bots
1114                 {
1115                         switch(autocvar_g_campaign_forceteam)
1116                         {
1117                                 case 1: self.team_forced = NUM_TEAM_1; break;
1118                                 case 2: self.team_forced = NUM_TEAM_2; break;
1119                                 case 3: self.team_forced = NUM_TEAM_3; break;
1120                                 case 4: self.team_forced = NUM_TEAM_4; break;
1121                                 default: self.team_forced = 0;
1122                         }
1123                 }
1124         }
1125         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1126                 self.team_forced = NUM_TEAM_1;
1127         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1128                 self.team_forced = NUM_TEAM_2;
1129         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1130                 self.team_forced = NUM_TEAM_3;
1131         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1132                 self.team_forced = NUM_TEAM_4;
1133         else if(autocvar_g_forced_team_otherwise == "red")
1134                 self.team_forced = NUM_TEAM_1;
1135         else if(autocvar_g_forced_team_otherwise == "blue")
1136                 self.team_forced = NUM_TEAM_2;
1137         else if(autocvar_g_forced_team_otherwise == "yellow")
1138                 self.team_forced = NUM_TEAM_3;
1139         else if(autocvar_g_forced_team_otherwise == "pink")
1140                 self.team_forced = NUM_TEAM_4;
1141         else if(autocvar_g_forced_team_otherwise == "spectate")
1142                 self.team_forced = -1;
1143         else if(autocvar_g_forced_team_otherwise == "spectator")
1144                 self.team_forced = -1;
1145         else
1146                 self.team_forced = 0;
1147
1148         if(!teamplay)
1149                 if(self.team_forced > 0)
1150                         self.team_forced = 0;
1151
1152         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1153
1154         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1155                 self.classname = "observer";
1156         } else {
1157                 if(teamplay)
1158                 {
1159                         if(autocvar_g_balance_teams)
1160                         {
1161                                 self.classname = "player";
1162                                 campaign_bots_may_start = 1;
1163                         }
1164                         else
1165                         {
1166                                 self.classname = "observer"; // do it anyway
1167                         }
1168                 }
1169                 else
1170                 {
1171                         self.classname = "player";
1172                         campaign_bots_may_start = 1;
1173                 }
1174         }
1175
1176         self.playerid = (playerid_last = playerid_last + 1);
1177
1178         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1179
1180     if(IS_BOT_CLIENT(self))
1181         PlayerStats_GameReport_AddPlayer(self);
1182
1183         if(autocvar_sv_eventlog)
1184                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1185
1186         LogTeamchange(self.playerid, self.team, 1);
1187
1188         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1189
1190         self.netname_previous = strzone(self.netname);
1191
1192         if(IS_PLAYER(self) && teamplay)
1193                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1194         else
1195                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1196
1197         stuffcmd(self, strcat(clientstuff, "\n"));
1198         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1199
1200         FixClientCvars(self);
1201
1202         // spawnfunc_waypoint sprites
1203         WaypointSprite_InitClient(self);
1204
1205         // Wazat's grappling hook
1206         SetGrappleHookBindings();
1207
1208         // Jetpack binds
1209         stuffcmd(self, "alias +jetpack +button10\n");
1210         stuffcmd(self, "alias -jetpack -button10\n");
1211
1212         // get version info from player
1213         stuffcmd(self, "cmd clientversion $gameversion\n");
1214
1215         // get other cvars from player
1216         GetCvars(0);
1217
1218         // notify about available teams
1219         if(teamplay)
1220         {
1221                 CheckAllowedTeams(self);
1222                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1223                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1224         }
1225         else
1226                 stuffcmd(self, "set _teams_available 0\n");
1227
1228         attach_entcs();
1229
1230         bot_relinkplayerlist();
1231
1232         self.spectatortime = time;
1233         if(blockSpectators)
1234         {
1235                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1236         }
1237
1238         self.jointime = time;
1239         self.allowed_timeouts = autocvar_sv_timeout_number;
1240
1241         if(IS_REAL_CLIENT(self))
1242         {
1243                 if(!autocvar_g_campaign)
1244                 {
1245                         self.motd_actived_time = -1;
1246                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1247                 }
1248
1249                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1250                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1251         }
1252
1253         if(!sv_foginterval && world.fog != "")
1254                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1255
1256         W_HitPlotOpen(self);
1257
1258         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1259                 send_CSQC_teamnagger();
1260
1261         CheatInitClient();
1262
1263         CSQCMODEL_AUTOINIT(self);
1264
1265         self.model_randomizer = random();
1266
1267         if(IS_REAL_CLIENT(self))
1268                 sv_notice_join();
1269
1270         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1271                 entity oldself = self;
1272                 self = e;
1273                 e.init_for_player(oldself);
1274                 self = oldself;
1275         }
1276
1277         MUTATOR_CALLHOOK(ClientConnect, self);
1278 }
1279 /*
1280 =============
1281 ClientDisconnect
1282
1283 Called when a client disconnects from the server
1284 =============
1285 */
1286 .entity chatbubbleentity;
1287 void ReadyCount();
1288 void ClientDisconnect (void)
1289 {SELFPARAM();
1290         if(self.vehicle)
1291             vehicles_exit(VHEF_RELEASE);
1292
1293         if (!IS_CLIENT(self))
1294         {
1295                 LOG_INFO("Warning: ClientDisconnect without ClientConnect\n");
1296                 return;
1297         }
1298
1299         PlayerStats_GameReport_FinalizePlayer(self);
1300
1301         if ( self.active_minigame )
1302                 part_minigame(self);
1303
1304         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
1305
1306         CheatShutdownClient();
1307
1308         W_HitPlotClose(self);
1309
1310         anticheat_report();
1311         anticheat_shutdown();
1312
1313         playerdemo_shutdown();
1314
1315         bot_clientdisconnect();
1316
1317         if(self.entcs)
1318                 detach_entcs();
1319
1320         if(autocvar_sv_eventlog)
1321                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1322
1323         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1324
1325         MUTATOR_CALLHOOK(ClientDisconnect);
1326
1327         Portal_ClearAll(self);
1328
1329         Unfreeze(self);
1330
1331         RemoveGrapplingHook(self);
1332
1333         // Here, everything has been done that requires this player to be a client.
1334
1335         self.flags &= ~FL_CLIENT;
1336
1337         if (self.chatbubbleentity)
1338                 remove (self.chatbubbleentity);
1339
1340         if (self.killindicator)
1341                 remove (self.killindicator);
1342
1343         WaypointSprite_PlayerGone();
1344
1345         bot_relinkplayerlist();
1346
1347         accuracy_free(self);
1348         Inventory_delete(self);
1349         ClientData_Detach();
1350         PlayerScore_Detach(self);
1351
1352         if(self.netname_previous)
1353                 strunzone(self.netname_previous);
1354         if(self.clientstatus)
1355                 strunzone(self.clientstatus);
1356         if(self.weaponorder_byimpulse)
1357                 strunzone(self.weaponorder_byimpulse);
1358
1359         ClearPlayerSounds();
1360
1361         if(self.personal)
1362                 remove(self.personal);
1363
1364         self.playerid = 0;
1365         ReadyCount();
1366
1367         // free cvars
1368         GetCvars(-1);
1369 }
1370
1371 .float BUTTON_CHAT;
1372 void ChatBubbleThink()
1373 {SELFPARAM();
1374         self.nextthink = time;
1375         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1376         {
1377                 if(self.owner) // but why can that ever be world?
1378                         self.owner.chatbubbleentity = world;
1379                 remove(self);
1380                 return;
1381         }
1382
1383         self.mdl = "";
1384
1385         if ( !self.owner.deadflag && IS_PLAYER(self.owner) )
1386         {
1387                 if ( self.owner.active_minigame )
1388                         self.mdl = "models/sprites/minigame_busy.iqm";
1389                 else if ( self.owner.BUTTON_CHAT )
1390                         self.mdl = "models/misc/chatbubble.spr";
1391         }
1392
1393         if ( self.model != self.mdl )
1394                 setmodel(self, self.mdl);
1395
1396 }
1397
1398 void UpdateChatBubble()
1399 {SELFPARAM();
1400         if (self.alpha < 0)
1401                 return;
1402         // spawn a chatbubble entity if needed
1403         if (!self.chatbubbleentity)
1404         {
1405                 self.chatbubbleentity = spawn();
1406                 self.chatbubbleentity.owner = self;
1407                 self.chatbubbleentity.exteriormodeltoclient = self;
1408                 self.chatbubbleentity.think = ChatBubbleThink;
1409                 self.chatbubbleentity.nextthink = time;
1410                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1411                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1412                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1413                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1414                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1415                 //self.chatbubbleentity.model = "";
1416                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1417         }
1418 }
1419
1420
1421 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1422 // added to the model skins
1423 /*void UpdateColorModHack()
1424 {
1425         float c;
1426         c = self.clientcolors & 15;
1427         // LordHavoc: only bothering to support white, green, red, yellow, blue
1428              if (!teamplay) self.colormod = '0 0 0';
1429         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1430         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1431         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1432         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1433         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1434         else self.colormod = '1 1 1';
1435 }*/
1436
1437 void respawn(void)
1438 {SELFPARAM();
1439         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1440         {
1441                 self.solid = SOLID_NOT;
1442                 self.takedamage = DAMAGE_NO;
1443                 self.movetype = MOVETYPE_FLY;
1444                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1445                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1446                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1447                 Send_Effect(EFFECT_RESPAWN_GHOST, self.origin, '0 0 0', 1);
1448                 if(autocvar_g_respawn_ghosts_maxtime)
1449                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1450         }
1451
1452         CopyBody(1);
1453
1454         self.effects |= EF_NODRAW; // prevent another CopyBody
1455         PutClientInServer();
1456 }
1457
1458 void play_countdown(float finished, string samp)
1459 {SELFPARAM();
1460         if(IS_REAL_CLIENT(self))
1461                 if(floor(finished - time - frametime) != floor(finished - time))
1462                         if(finished - time < 6)
1463                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1464 }
1465
1466 void player_powerups (void)
1467 {SELFPARAM();
1468         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1469         int items_prev = self.items;
1470
1471         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1472                 self.modelflags |= MF_ROCKET;
1473         else
1474                 self.modelflags &= ~MF_ROCKET;
1475
1476         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1477
1478         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1479                 return;
1480
1481         Fire_ApplyDamage(self);
1482         Fire_ApplyEffect(self);
1483
1484         if (!g_instagib)
1485         {
1486                 if (self.items & ITEM_Strength.m_itemid)
1487                 {
1488                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1489                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1490                         if (time > self.strength_finished)
1491                         {
1492                                 self.items = self.items - (self.items & ITEM_Strength.m_itemid);
1493                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1494                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1495                         }
1496                 }
1497                 else
1498                 {
1499                         if (time < self.strength_finished)
1500                         {
1501                                 self.items = self.items | ITEM_Strength.m_itemid;
1502                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1503                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1504                         }
1505                 }
1506                 if (self.items & ITEM_Shield.m_itemid)
1507                 {
1508                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1509                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1510                         if (time > self.invincible_finished)
1511                         {
1512                                 self.items = self.items - (self.items & ITEM_Shield.m_itemid);
1513                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1514                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1515                         }
1516                 }
1517                 else
1518                 {
1519                         if (time < self.invincible_finished)
1520                         {
1521                                 self.items = self.items | ITEM_Shield.m_itemid;
1522                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1523                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1524                         }
1525                 }
1526                 if (self.items & IT_SUPERWEAPON)
1527                 {
1528                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1529                         {
1530                                 self.superweapons_finished = 0;
1531                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1532                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1533                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1534                         }
1535                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1536                         {
1537                                 // don't let them run out
1538                         }
1539                         else
1540                         {
1541                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1542                                 if (time > self.superweapons_finished)
1543                                 {
1544                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1545                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1546                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1547                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1548                                 }
1549                         }
1550                 }
1551                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1552                 {
1553                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1554                         {
1555                                 self.items = self.items | IT_SUPERWEAPON;
1556                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1557                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1558                         }
1559                         else
1560                         {
1561                                 self.superweapons_finished = 0;
1562                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1563                         }
1564                 }
1565                 else
1566                 {
1567                         self.superweapons_finished = 0;
1568                 }
1569         }
1570
1571         if(autocvar_g_nodepthtestplayers)
1572                 self.effects = self.effects | EF_NODEPTHTEST;
1573
1574         if(autocvar_g_fullbrightplayers)
1575                 self.effects = self.effects | EF_FULLBRIGHT;
1576
1577         if (time >= game_starttime)
1578         if (time < self.spawnshieldtime)
1579                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1580
1581         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1582 }
1583
1584 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1585 {
1586         if(current > stable)
1587                 return current;
1588         else if(current > stable - 0.25) // when close enough, "snap"
1589                 return stable;
1590         else
1591                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1592 }
1593
1594 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1595 {
1596         if(current < stable)
1597                 return current;
1598         else if(current < stable + 0.25) // when close enough, "snap"
1599                 return stable;
1600         else
1601                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1602 }
1603
1604 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1605 {
1606         if(current > rotstable)
1607         {
1608                 if(rotframetime > 0)
1609                 {
1610                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1611                         current = max(rotstable, current - rotlinear * rotframetime);
1612                 }
1613         }
1614         else if(current < regenstable)
1615         {
1616                 if(regenframetime > 0)
1617                 {
1618                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1619                         current = min(regenstable, current + regenlinear * regenframetime);
1620                 }
1621         }
1622
1623         if(current > limit)
1624                 current = limit;
1625
1626         return current;
1627 }
1628
1629 void player_regen (void)
1630 {SELFPARAM();
1631         float max_mod, regen_mod, rot_mod, limit_mod;
1632         max_mod = regen_mod = rot_mod = limit_mod = 1;
1633         regen_mod_max = max_mod;
1634         regen_mod_regen = regen_mod;
1635         regen_mod_rot = rot_mod;
1636         regen_mod_limit = limit_mod;
1637
1638         regen_health = autocvar_g_balance_health_regen;
1639         regen_health_linear = autocvar_g_balance_health_regenlinear;
1640         regen_health_rot = autocvar_g_balance_health_rot;
1641         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1642         regen_health_stable = autocvar_g_balance_health_regenstable;
1643         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1644         if(!MUTATOR_CALLHOOK(PlayerRegen))
1645         if(!self.frozen)
1646         {
1647                 float mina, maxa, limith, limita;
1648                 maxa = autocvar_g_balance_armor_rotstable;
1649                 mina = autocvar_g_balance_armor_regenstable;
1650                 limith = autocvar_g_balance_health_limit;
1651                 limita = autocvar_g_balance_armor_limit;
1652
1653                 max_mod = regen_mod_max;
1654                 regen_mod = regen_mod_regen;
1655                 rot_mod = regen_mod_rot;
1656                 limit_mod = regen_mod_limit;
1657
1658                 regen_health_rotstable = regen_health_rotstable * max_mod;
1659                 regen_health_stable = regen_health_stable * max_mod;
1660                 limith = limith * limit_mod;
1661                 limita = limita * limit_mod;
1662
1663                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1664                 self.health = CalcRotRegen(self.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > self.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1665         }
1666
1667         // if player rotted to death...  die!
1668         // check this outside above checks, as player may still be able to rot to death
1669         if(self.health < 1)
1670         {
1671                 if(self.vehicle)
1672                         vehicles_exit(VHEF_RELEASE);
1673                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1674         }
1675
1676         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1677         {
1678                 float minf, maxf, limitf;
1679
1680                 maxf = autocvar_g_balance_fuel_rotstable;
1681                 minf = autocvar_g_balance_fuel_regenstable;
1682                 limitf = autocvar_g_balance_fuel_limit;
1683
1684                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1685         }
1686 }
1687
1688 float zoomstate_set;
1689 void SetZoomState(float z)
1690 {SELFPARAM();
1691         if(z != self.zoomstate)
1692         {
1693                 self.zoomstate = z;
1694                 ClientData_Touch(self);
1695         }
1696         zoomstate_set = 1;
1697 }
1698
1699 void GetPressedKeys()
1700 {SELFPARAM();
1701         MUTATOR_CALLHOOK(GetPressedKeys);
1702         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1703         X(self.pressedkeys, KEY_FORWARD,        self.movement_x > 0);
1704         X(self.pressedkeys, KEY_BACKWARD,       self.movement_x < 0);
1705         X(self.pressedkeys, KEY_RIGHT,          self.movement_y > 0);
1706         X(self.pressedkeys, KEY_LEFT,           self.movement_y < 0);
1707
1708         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1709         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1710         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1711         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1712         #undef X
1713 }
1714
1715 /*
1716 ======================
1717 spectate mode routines
1718 ======================
1719 */
1720
1721 void SpectateCopy(entity spectatee)
1722 {SELFPARAM();
1723         MUTATOR_CALLHOOK(SpectateCopy, spectatee, self);
1724         self.armortype = spectatee.armortype;
1725         self.armorvalue = spectatee.armorvalue;
1726         self.ammo_cells = spectatee.ammo_cells;
1727         self.ammo_plasma = spectatee.ammo_plasma;
1728         self.ammo_shells = spectatee.ammo_shells;
1729         self.ammo_nails = spectatee.ammo_nails;
1730         self.ammo_rockets = spectatee.ammo_rockets;
1731         self.ammo_fuel = spectatee.ammo_fuel;
1732         self.clip_load = spectatee.clip_load;
1733         self.clip_size = spectatee.clip_size;
1734         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1735         self.health = spectatee.health;
1736         self.impulse = 0;
1737         self.items = spectatee.items;
1738         self.last_pickup = spectatee.last_pickup;
1739         self.hit_time = spectatee.hit_time;
1740         self.metertime = spectatee.metertime;
1741         self.strength_finished = spectatee.strength_finished;
1742         self.invincible_finished = spectatee.invincible_finished;
1743         self.pressedkeys = spectatee.pressedkeys;
1744         self.weapons = spectatee.weapons;
1745         self.switchweapon = spectatee.switchweapon;
1746         self.switchingweapon = spectatee.switchingweapon;
1747         self.weapon = spectatee.weapon;
1748         self.vortex_charge = spectatee.vortex_charge;
1749         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1750         self.hagar_load = spectatee.hagar_load;
1751         self.arc_heat_percent = spectatee.arc_heat_percent;
1752         self.minelayer_mines = spectatee.minelayer_mines;
1753         self.punchangle = spectatee.punchangle;
1754         self.view_ofs = spectatee.view_ofs;
1755         self.velocity = spectatee.velocity;
1756         self.dmg_take = spectatee.dmg_take;
1757         self.dmg_save = spectatee.dmg_save;
1758         self.dmg_inflictor = spectatee.dmg_inflictor;
1759         self.v_angle = spectatee.v_angle;
1760         self.angles = spectatee.v_angle;
1761         self.frozen = spectatee.frozen;
1762         self.revive_progress = spectatee.revive_progress;
1763         if(!self.BUTTON_USE)
1764                 self.fixangle = true;
1765         setorigin(self, spectatee.origin);
1766         setsize(self, spectatee.mins, spectatee.maxs);
1767         SetZoomState(spectatee.zoomstate);
1768
1769     anticheat_spectatecopy(spectatee);
1770         self.hud = spectatee.hud;
1771         if(spectatee.vehicle)
1772     {
1773         self.fixangle = false;
1774         //self.velocity = spectatee.vehicle.velocity;
1775         self.vehicle_health = spectatee.vehicle_health;
1776         self.vehicle_shield = spectatee.vehicle_shield;
1777         self.vehicle_energy = spectatee.vehicle_energy;
1778         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1779         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1780         self.vehicle_reload1 = spectatee.vehicle_reload1;
1781         self.vehicle_reload2 = spectatee.vehicle_reload2;
1782
1783         msg_entity = self;
1784
1785         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1786             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1787             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1788             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1789
1790         //WriteByte (MSG_ONE, SVC_SETVIEW);
1791         //    WriteEntity(MSG_ONE, self);
1792         //makevectors(spectatee.v_angle);
1793         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1794     }
1795 }
1796
1797 bool SpectateUpdate()
1798 {SELFPARAM();
1799         if(!self.enemy)
1800             return false;
1801
1802         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1803         {
1804                 SetSpectator(self, world);
1805                 return false;
1806         }
1807
1808         SpectateCopy(self.enemy);
1809
1810         return true;
1811 }
1812
1813 bool SpectateSet()
1814 {SELFPARAM();
1815         if(!IS_PLAYER(self.enemy))
1816                 return false;
1817
1818         msg_entity = self;
1819         WriteByte(MSG_ONE, SVC_SETVIEW);
1820         WriteEntity(MSG_ONE, self.enemy);
1821         self.movetype = MOVETYPE_NONE;
1822         accuracy_resend(self);
1823
1824         if(!SpectateUpdate())
1825                 PutObserverInServer();
1826
1827         return true;
1828 }
1829
1830 void SetSpectator(entity player, entity spectatee)
1831 {
1832         entity old_spectatee = player.enemy;
1833
1834         player.enemy = spectatee;
1835
1836         // WEAPONTODO
1837         // these are required to fix the spectator bug with arc
1838         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1839         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1840 }
1841
1842 bool Spectate(entity pl)
1843 {SELFPARAM();
1844         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1845         if(DIFF_TEAM(pl, self))
1846                 return false;
1847
1848         SetSpectator(self, pl);
1849         return SpectateSet();
1850 }
1851
1852 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1853 entity CA_SpectateNext(entity start)
1854 {SELFPARAM();
1855         if(SAME_TEAM(start, self))
1856                 return start;
1857
1858         other = start;
1859         // continue from current player
1860         while(other && DIFF_TEAM(other, self))
1861                 other = find(other, classname, "player");
1862
1863         if (!other)
1864         {
1865                 // restart from begining
1866                 other = find(other, classname, "player");
1867                 while(other && DIFF_TEAM(other, self))
1868                         other = find(other, classname, "player");
1869         }
1870
1871         return other;
1872 }
1873
1874 bool SpectateNext()
1875 {SELFPARAM();
1876         other = find(self.enemy, classname, "player");
1877
1878         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1879                 // CA and ca players when spectating enemies is forbidden
1880                 other = CA_SpectateNext(other);
1881         else
1882         {
1883                 // other modes and ca spectators or spectating enemies is allowed
1884                 if (!other)
1885                         other = find(other, classname, "player");
1886         }
1887
1888         if(other) { SetSpectator(self, other); }
1889
1890         return SpectateSet();
1891 }
1892
1893 bool SpectatePrev()
1894 {SELFPARAM();
1895         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1896         other = findchain(classname, "player");
1897         if (!other) // no player
1898                 return false;
1899
1900         entity first = other;
1901         // skip players until current spectated player
1902         if(self.enemy)
1903         while(other && other != self.enemy)
1904                 other = other.chain;
1905
1906         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1907         {
1908                 do { other = other.chain; }
1909                 while(other && DIFF_TEAM(other, self));
1910
1911                 if (!other)
1912                 {
1913                         other = first;
1914                         while(other && DIFF_TEAM(other, self))
1915                                 other = other.chain;
1916                         if(other == self.enemy)
1917                                 return true;
1918                 }
1919         }
1920         else
1921         {
1922                 if(other.chain)
1923                         other = other.chain;
1924                 else
1925                         other = first;
1926         }
1927         SetSpectator(self, other);
1928         return SpectateSet();
1929 }
1930
1931 /*
1932 =============
1933 ShowRespawnCountdown()
1934
1935 Update a respawn countdown display.
1936 =============
1937 */
1938 void ShowRespawnCountdown()
1939 {SELFPARAM();
1940         float number;
1941         if(self.deadflag == DEAD_NO) // just respawned?
1942                 return;
1943         else
1944         {
1945                 number = ceil(self.respawn_time - time);
1946                 if(number <= 0)
1947                         return;
1948                 if(number <= self.respawn_countdown)
1949                 {
1950                         self.respawn_countdown = number - 1;
1951                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1952                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1953                 }
1954         }
1955 }
1956
1957 void LeaveSpectatorMode()
1958 {SELFPARAM();
1959         if(self.caplayer)
1960                 return;
1961         if(nJoinAllowed(self))
1962         {
1963                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1964                 {
1965                         self.classname = "player";
1966                         nades_RemoveBonus(self);
1967
1968                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1969                                 { JoinBestTeam(self, false, true); }
1970
1971                         if(autocvar_g_campaign)
1972                                 { campaign_bots_may_start = 1; }
1973
1974                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1975
1976                         PutClientInServer();
1977
1978                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1979                 }
1980                 else
1981                         stuffcmd(self, "menu_showteamselect\n");
1982         }
1983         else
1984         {
1985                 // Player may not join because g_maxplayers is set
1986                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1987         }
1988 }
1989
1990 /**
1991  * Determines whether the player is allowed to join. This depends on cvar
1992  * g_maxplayers, if it isn't used this function always return true, otherwise
1993  * it checks whether the number of currently playing players exceeds g_maxplayers.
1994  * @return int number of free slots for players, 0 if none
1995  */
1996 float nJoinAllowed(entity ignore)
1997 {SELFPARAM();
1998         if(!ignore)
1999         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2000         // so report 0 free slots if restricted
2001         {
2002                 if(autocvar_g_forced_team_otherwise == "spectate")
2003                         return 0;
2004                 if(autocvar_g_forced_team_otherwise == "spectator")
2005                         return 0;
2006         }
2007
2008         if(self.team_forced < 0)
2009                 return 0; // forced spectators can never join
2010
2011         // TODO simplify this
2012         entity e;
2013         float totalClients = 0;
2014         FOR_EACH_CLIENT(e)
2015                 if(e != ignore)
2016                         totalClients += 1;
2017
2018         if (!autocvar_g_maxplayers)
2019                 return maxclients - totalClients;
2020
2021         float currentlyPlaying = 0;
2022         FOR_EACH_REALCLIENT(e)
2023                 if(IS_PLAYER(e) || e.caplayer)
2024                         currentlyPlaying += 1;
2025
2026         if(currentlyPlaying < autocvar_g_maxplayers)
2027                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2028
2029         return 0;
2030 }
2031
2032 /**
2033  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2034  * g_maxplayers_spectator_blocktime seconds
2035  */
2036 void checkSpectatorBlock()
2037 {SELFPARAM();
2038         if(IS_SPEC(self) || IS_OBSERVER(self))
2039         if(!self.caplayer)
2040         if(IS_REAL_CLIENT(self))
2041         {
2042                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2043                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2044                         dropclient(self);
2045                 }
2046         }
2047 }
2048
2049 void PrintWelcomeMessage()
2050 {SELFPARAM();
2051         if(self.motd_actived_time == 0)
2052         {
2053                 if (autocvar_g_campaign) {
2054                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2055                                 self.motd_actived_time = time;
2056                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2057                         }
2058                 } else {
2059                         if (self.BUTTON_INFO) {
2060                                 self.motd_actived_time = time;
2061                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2062                         }
2063                 }
2064         }
2065         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2066         {
2067                 if (autocvar_g_campaign) {
2068                         if (self.BUTTON_INFO)
2069                                 self.motd_actived_time = time;
2070                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2071                                 self.motd_actived_time = 0;
2072                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2073                         }
2074                 } else {
2075                         if (self.BUTTON_INFO)
2076                                 self.motd_actived_time = time;
2077                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2078                                 self.motd_actived_time = 0;
2079                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2080                         }
2081                 }
2082         }
2083         else //if(self.motd_actived_time < 0) // just connected, motd is active
2084         {
2085                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2086                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2087                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2088                 {
2089                         // instanctly hide MOTD
2090                         self.motd_actived_time = 0;
2091                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2092                 }
2093         }
2094 }
2095
2096 void ObserverThink()
2097 {SELFPARAM();
2098         if ( self.impulse )
2099         {
2100                 MinigameImpulse(self.impulse);
2101                 self.impulse = 0;
2102         }
2103         float prefered_movetype;
2104         if (self.flags & FL_JUMPRELEASED) {
2105                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2106                         self.flags &= ~FL_JUMPRELEASED;
2107                         self.flags |= FL_SPAWNING;
2108                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2109                         self.flags &= ~FL_JUMPRELEASED;
2110                         if(SpectateNext()) {
2111                                 self.classname = "spectator";
2112                         }
2113                 } else {
2114                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2115                         if (self.movetype != prefered_movetype)
2116                                 self.movetype = prefered_movetype;
2117                 }
2118         } else {
2119                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2120                         self.flags |= FL_JUMPRELEASED;
2121                         if(self.flags & FL_SPAWNING)
2122                         {
2123                                 self.flags &= ~FL_SPAWNING;
2124                                 LeaveSpectatorMode();
2125                                 return;
2126                         }
2127                 }
2128         }
2129 }
2130
2131 void SpectatorThink()
2132 {SELFPARAM();
2133         if ( self.impulse )
2134         {
2135                 if(MinigameImpulse(self.impulse))
2136                         self.impulse = 0;
2137         }
2138         if (self.flags & FL_JUMPRELEASED) {
2139                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2140                         self.flags &= ~FL_JUMPRELEASED;
2141                         self.flags |= FL_SPAWNING;
2142                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2143                         self.flags &= ~FL_JUMPRELEASED;
2144                         if(SpectateNext()) {
2145                                 self.classname = "spectator";
2146                         } else {
2147                                 self.classname = "observer";
2148                                 PutClientInServer();
2149                         }
2150                         self.impulse = 0;
2151                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2152                         self.flags &= ~FL_JUMPRELEASED;
2153                         if(SpectatePrev()) {
2154                                 self.classname = "spectator";
2155                         } else {
2156                                 self.classname = "observer";
2157                                 PutClientInServer();
2158                         }
2159                         self.impulse = 0;
2160                 } else if (self.BUTTON_ATCK2) {
2161                         self.flags &= ~FL_JUMPRELEASED;
2162                         self.classname = "observer";
2163                         PutClientInServer();
2164                 } else {
2165                         if(!SpectateUpdate())
2166                                 PutObserverInServer();
2167                 }
2168         } else {
2169                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2170                         self.flags |= FL_JUMPRELEASED;
2171                         if(self.flags & FL_SPAWNING)
2172                         {
2173                                 self.flags &= ~FL_SPAWNING;
2174                                 LeaveSpectatorMode();
2175                                 return;
2176                         }
2177                 }
2178                 if(!SpectateUpdate())
2179                         PutObserverInServer();
2180         }
2181
2182         self.flags |= FL_CLIENT | FL_NOTARGET;
2183 }
2184
2185 void vehicles_enter (entity pl, entity veh);
2186 void PlayerUseKey()
2187 {SELFPARAM();
2188         if (!IS_PLAYER(self))
2189                 return;
2190
2191         if(self.vehicle)
2192         {
2193                 if(!gameover)
2194                 {
2195                         vehicles_exit(VHEF_NORMAL);
2196                         return;
2197                 }
2198         }
2199         else if(autocvar_g_vehicles_enter)
2200         {
2201                 if(!self.frozen)
2202                 if(self.deadflag == DEAD_NO)
2203                 if(!gameover)
2204                 {
2205                         entity head, closest_target = world;
2206                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2207
2208                         while(head) // find the closest acceptable target to enter
2209                         {
2210                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2211                                 if(head.deadflag == DEAD_NO)
2212                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2213                                 if(head.takedamage != DAMAGE_NO)
2214                                 {
2215                                         if(closest_target)
2216                                         {
2217                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2218                                                 { closest_target = head; }
2219                                         }
2220                                         else { closest_target = head; }
2221                                 }
2222
2223                                 head = head.chain;
2224                         }
2225
2226                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2227                 }
2228         }
2229
2230         // a use key was pressed; call handlers
2231         MUTATOR_CALLHOOK(PlayerUseKey);
2232 }
2233
2234 float isInvisibleString(string s)
2235 {
2236         float i, n, c;
2237         s = strdecolorize(s);
2238         for((i = 0), (n = strlen(s)); i < n; ++i)
2239         {
2240                 c = str2chr(s, i);
2241                 switch(c)
2242                 {
2243                         case 0:
2244                         case 32: // space
2245                                 break;
2246                         case 192: // charmap space
2247                                 if (!autocvar_utf8_enable)
2248                                         break;
2249                                 return false;
2250                         case 160: // space in unicode fonts
2251                         case 0xE000 + 192: // utf8 charmap space
2252                                 if (autocvar_utf8_enable)
2253                                         break;
2254                         default:
2255                                 return false;
2256                 }
2257         }
2258         return true;
2259 }
2260
2261 /*
2262 =============
2263 PlayerPreThink
2264
2265 Called every frame for each client before the physics are run
2266 =============
2267 */
2268 .float usekeypressed;
2269 void() nexball_setstatus;
2270 .float last_vehiclecheck;
2271 .int items_added;
2272 void PlayerPreThink (void)
2273 {SELFPARAM();
2274         WarpZone_PlayerPhysics_FixVAngle();
2275
2276         self.stat_game_starttime = game_starttime;
2277         self.stat_round_starttime = round_starttime;
2278         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2279         self.stat_leadlimit = autocvar_leadlimit;
2280
2281         self.weaponsinmap = weaponsInMap;
2282
2283         if(frametime)
2284         {
2285                 // physics frames: update anticheat stuff
2286                 anticheat_prethink();
2287         }
2288
2289         if(blockSpectators && frametime)
2290                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2291                 checkSpectatorBlock();
2292
2293         zoomstate_set = 0;
2294
2295         // Savage: Check for nameless players
2296         if (isInvisibleString(self.netname)) {
2297                 string new_name = strzone(strcat("Player@", ftos(self.playerid)));
2298                 if(autocvar_sv_eventlog)
2299                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2300                 if(self.netname_previous)
2301                         strunzone(self.netname_previous);
2302                 self.netname_previous = strzone(new_name);
2303                 self.netname = self.netname_previous;
2304                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2305         } else if(self.netname_previous != self.netname) {
2306                 if(autocvar_sv_eventlog)
2307                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2308                 if(self.netname_previous)
2309                         strunzone(self.netname_previous);
2310                 self.netname_previous = strzone(self.netname);
2311         }
2312
2313         // version nagging
2314         if(self.version_nagtime)
2315                 if(self.cvar_g_xonoticversion)
2316                         if(time > self.version_nagtime)
2317                         {
2318                                 // don't notify git users
2319                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2320                                 {
2321                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2322                                         {
2323                                                 // notify release users if connecting to git
2324                                                 LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2325                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2326                                         }
2327                                         else
2328                                         {
2329                                                 float r;
2330                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2331                                                 if(r < 0)
2332                                                 {
2333                                                         // give users new version
2334                                                         LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2335                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2336                                                 }
2337                                                 else if(r > 0)
2338                                                 {
2339                                                         // notify users about old server version
2340                                                         LOG_INFO("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2341                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2342                                                 }
2343                                         }
2344                                 }
2345                                 self.version_nagtime = 0;
2346                         }
2347
2348         // GOD MODE info
2349         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2350         {
2351                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2352                 self.max_armorvalue = 0;
2353         }
2354
2355         if(self.frozen == 2)
2356         {
2357                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2358                 self.health = max(1, self.revive_progress * start_health);
2359                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2360
2361                 if(self.revive_progress >= 1)
2362                         Unfreeze(self);
2363         }
2364         else if(self.frozen == 3)
2365         {
2366                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2367                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2368
2369                 if(self.health < 1)
2370                 {
2371                         if(self.vehicle)
2372                                 vehicles_exit(VHEF_RELEASE);
2373                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2374                 }
2375                 else if ( self.revive_progress <= 0 )
2376                         Unfreeze(self);
2377         }
2378
2379         MUTATOR_CALLHOOK(PlayerPreThink);
2380
2381         if(autocvar_g_vehicles_enter)
2382         if(time > self.last_vehiclecheck)
2383         if(IS_PLAYER(self))
2384         if(!gameover)
2385         if(!self.frozen)
2386         if(!self.vehicle)
2387         if(self.deadflag == DEAD_NO)
2388         {
2389                 entity veh;
2390                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2391                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2392                 if(veh.deadflag == DEAD_NO)
2393                 if(veh.takedamage != DAMAGE_NO)
2394                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2395                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2396                 else if(!veh.owner)
2397                 if(!veh.team || SAME_TEAM(self, veh))
2398                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2399                 else if(autocvar_g_vehicles_steal)
2400                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2401
2402                 self.last_vehiclecheck = time + 1;
2403         }
2404
2405         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2406         {
2407                 if(self.BUTTON_USE && !self.usekeypressed)
2408                         PlayerUseKey();
2409                 self.usekeypressed = self.BUTTON_USE;
2410         }
2411
2412         if(IS_REAL_CLIENT(self))
2413                 PrintWelcomeMessage();
2414
2415         if(IS_PLAYER(self))
2416         {
2417
2418                 CheckRules_Player();
2419
2420                 if (intermission_running)
2421                 {
2422                         IntermissionThink ();   // otherwise a button could be missed between
2423                         return;                                 // the think tics
2424                 }
2425
2426                 //don't allow the player to turn around while game is paused!
2427                 if(timeout_status == TIMEOUT_ACTIVE) {
2428                         // FIXME turn this into CSQC stuff
2429                         self.v_angle = self.lastV_angle;
2430                         self.angles = self.lastV_angle;
2431                         self.fixangle = true;
2432                 }
2433
2434                 if(frametime)
2435                 {
2436                         if(self.weapon == WEP_VORTEX.m_id && WEP_CVAR(vortex, charge))
2437                         {
2438                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2439                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2440                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2441
2442                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2443                                 {
2444                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2445                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2446                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2447                                 }
2448                         }
2449                         else
2450                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2451
2452                         player_powerups();
2453                 }
2454
2455                 if (self.deadflag != DEAD_NO)
2456                 {
2457                         if(self.personal && g_race_qualifying)
2458                         {
2459                                 if(time > self.respawn_time)
2460                                 {
2461                                         self.respawn_time = time + 1; // only retry once a second
2462                                         self.stat_respawn_time = self.respawn_time;
2463                                         respawn();
2464                                         self.impulse = 141;
2465                                 }
2466                         }
2467                         else
2468                         {
2469                                 float button_pressed;
2470                                 if(frametime)
2471                                         player_anim();
2472                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2473
2474                                 if (self.deadflag == DEAD_DYING)
2475                                 {
2476                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2477                                                 self.deadflag = DEAD_RESPAWNING;
2478                                         else if(!button_pressed)
2479                                                 self.deadflag = DEAD_DEAD;
2480                                 }
2481                                 else if (self.deadflag == DEAD_DEAD)
2482                                 {
2483                                         if(button_pressed)
2484                                                 self.deadflag = DEAD_RESPAWNABLE;
2485                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2486                                                 self.deadflag = DEAD_RESPAWNING;
2487                                 }
2488                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2489                                 {
2490                                         if(!button_pressed)
2491                                                 self.deadflag = DEAD_RESPAWNING;
2492                                 }
2493                                 else if (self.deadflag == DEAD_RESPAWNING)
2494                                 {
2495                                         if(time > self.respawn_time)
2496                                         {
2497                                                 self.respawn_time = time + 1; // only retry once a second
2498                                                 self.respawn_time_max = self.respawn_time;
2499                                                 respawn();
2500                                         }
2501                                 }
2502
2503                                 ShowRespawnCountdown();
2504
2505                                 if(self.respawn_flags & RESPAWN_SILENT)
2506                                         self.stat_respawn_time = 0;
2507                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2508                                         self.stat_respawn_time = self.respawn_time_max;
2509                                 else
2510                                         self.stat_respawn_time = self.respawn_time;
2511                         }
2512
2513                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2514                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2515                                 self.stat_respawn_time *= -1;
2516
2517                         return;
2518                 }
2519
2520                 self.prevorigin = self.origin;
2521
2522                 float do_crouch = self.BUTTON_CROUCH;
2523                 if(self.hook.state)
2524                         do_crouch = 0;
2525                 if(self.vehicle)
2526                         do_crouch = 0;
2527                 if(self.frozen)
2528                         do_crouch = 0;
2529
2530                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2531                 // It cannot be predicted by the engine!
2532                 if((self.weapon == WEP_SHOCKWAVE.m_id || self.weapon == WEP_SHOTGUN.m_id) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2533                         do_crouch = 0;
2534
2535                 if (do_crouch)
2536                 {
2537                         if (!self.crouch)
2538                         {
2539                                 self.crouch = true;
2540                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2541                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2542                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2543                         }
2544                 }
2545                 else
2546                 {
2547                         if (self.crouch)
2548                         {
2549                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2550                                 if (!trace_startsolid)
2551                                 {
2552                                         self.crouch = false;
2553                                         self.view_ofs = self.stat_pl_view_ofs;
2554                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2555                                 }
2556                         }
2557                 }
2558
2559                 FixPlayermodel();
2560
2561                 GrapplingHookFrame();
2562
2563                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2564                 //if(frametime)
2565                 {
2566                         self.items &= ~self.items_added;
2567
2568                         W_WeaponFrame();
2569
2570                         self.items_added = 0;
2571                         if(self.items & ITEM_Jetpack.m_itemid)
2572                                 if(self.items & ITEM_JetpackRegen.m_itemid || self.ammo_fuel >= 0.01)
2573                                         self.items_added |= IT_FUEL;
2574
2575                         self.items |= self.items_added;
2576                 }
2577
2578                 player_regen();
2579
2580                 // WEAPONTODO: Add a weapon request for this
2581                 // rot vortex charge to the charge limit
2582                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2583                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2584
2585                 if(frametime)
2586                         player_anim();
2587
2588                 // secret status
2589                 secrets_setstatus();
2590
2591                 // monsters status
2592                 monsters_setstatus();
2593
2594                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2595
2596                 //self.angles_y=self.v_angle_y + 90;   // temp
2597         } else if(gameover) {
2598                 if (intermission_running)
2599                         IntermissionThink ();   // otherwise a button could be missed between
2600                 return;
2601         } else if(IS_OBSERVER(self)) {
2602                 ObserverThink();
2603         } else if(IS_SPEC(self)) {
2604                 SpectatorThink();
2605         }
2606
2607         // WEAPONTODO: Add weapon request for this
2608         if(!zoomstate_set)
2609                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX.m_id) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE.m_id && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2610
2611         float oldspectatee_status;
2612         oldspectatee_status = self.spectatee_status;
2613         if(IS_SPEC(self))
2614                 self.spectatee_status = num_for_edict(self.enemy);
2615         else if(IS_OBSERVER(self))
2616                 self.spectatee_status = num_for_edict(self);
2617         else
2618                 self.spectatee_status = 0;
2619         if(self.spectatee_status != oldspectatee_status)
2620         {
2621                 ClientData_Touch(self);
2622         }
2623
2624         if(self.teamkill_soundtime)
2625         if(time > self.teamkill_soundtime)
2626         {
2627                 self.teamkill_soundtime = 0;
2628
2629                 entity oldpusher, oldself;
2630
2631                 oldself = self; self = self.teamkill_soundsource;
2632                 oldpusher = self.pusher; self.pusher = oldself;
2633
2634                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2635
2636                 self.pusher = oldpusher;
2637                 self = oldself;
2638         }
2639
2640         if(self.taunt_soundtime)
2641         if(time > self.taunt_soundtime)
2642         {
2643                 self.taunt_soundtime = 0;
2644                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2645         }
2646
2647         target_voicescript_next(self);
2648
2649         // WEAPONTODO: Move into weaponsystem somehow
2650         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2651         if(!self.weapon)
2652                 self.clip_load = self.clip_size = 0;
2653 }
2654
2655 /*
2656 =============
2657 PlayerPostThink
2658
2659 Called every frame for each client after the physics are run
2660 =============
2661 */
2662 .float idlekick_lasttimeleft;
2663 void PlayerPostThink (void)
2664 {SELFPARAM();
2665         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2666         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2667         {
2668                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2669                 {
2670                         if(self.idlekick_lasttimeleft)
2671                         {
2672                                 self.idlekick_lasttimeleft = 0;
2673                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2674                         }
2675                 }
2676                 else
2677                 {
2678                         float timeleft;
2679                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2680                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2681                         {
2682                                 if(!self.idlekick_lasttimeleft)
2683                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2684                         }
2685                         if(timeleft <= 0)
2686                         {
2687                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2688                                 dropclient(self);
2689                                 return;
2690                         }
2691                         else if(timeleft <= 10)
2692                         {
2693                                 if(timeleft != self.idlekick_lasttimeleft)
2694                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2695                                 self.idlekick_lasttimeleft = timeleft;
2696                         }
2697                 }
2698         }
2699
2700         CheatFrame();
2701
2702         //CheckPlayerJump();
2703
2704         if(IS_PLAYER(self)) {
2705                 CheckRules_Player();
2706                 UpdateChatBubble();
2707                 if (self.impulse)
2708                         ImpulseCommands();
2709                 if (intermission_running)
2710                         return;         // intermission or finale
2711                 GetPressedKeys();
2712         }
2713
2714         /*
2715         float i;
2716         for(i = 0; i < 1000; ++i)
2717         {
2718                 vector end;
2719                 end = self.origin + '0 0 1024' + 512 * randomvec();
2720                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2721                 if(trace_fraction < 1)
2722                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2723                 {
2724                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2725                         break;
2726                 }
2727         }
2728         */
2729
2730         if(self.waypointsprite_attachedforcarrier)
2731                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2732
2733         playerdemo_write();
2734
2735         CSQCMODEL_AUTOUPDATE(self);
2736 }