qcsrc/server/cl_client.qc

   1 #include "cl_client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "cl_impulse.qh"
   5 #include "cl_player.qh"
   6 #include "ent_cs.qh"
   7 #include "ipban.qh"
   8 #include "miscfunctions.qh"
   9 #include "portals.qh"
  10 #include "teamplay.qh"
  11 #include "playerdemo.qh"
  12 #include "spawnpoints.qh"
  13 #include "g_damage.qh"
  14 #include "g_hook.qh"
  15 #include "command/common.qh"
  16 #include "cheats.qh"
  17 #include "g_world.qh"
  18 #include "race.qh"
  19 #include "antilag.qh"
  20 #include "campaign.qh"
  21 #include "command/common.qh"
  22
  23 #include "bot/bot.qh"
  24 #include "bot/navigation.qh"
  25
  26 #include "../common/vehicles/all.qh"
  27
  28 #include "weapons/hitplot.qh"
  29 #include "weapons/weaponsystem.qh"
  30
  31 #include "../common/net_notice.qh"
  32 #include "../common/physics.qh"
  33
  34 #include "../common/items/all.qc"
  35
  36 #include "../common/mutators/mutator/waypoints/all.qh"
  37
  38 #include "../common/triggers/subs.qh"
  39 #include "../common/triggers/triggers.qh"
  40 #include "../common/triggers/trigger/secret.qh"
  41
  42 #include "../common/minigames/sv_minigames.qh"
  43
  44 #include "../common/items/inventory.qh"
  45
  46 #include "../common/monsters/sv_monsters.qh"
  47
  48 #include "../warpzonelib/server.qh"
  49
  50
  51 void send_CSQC_teamnagger() {
  52         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  53         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  54 }
  55
  56 float ClientData_Send(entity to, int sf)
  57 {
  58         if(to != self.owner)
  59         {
  60                 error("wtf");
  61                 return false;
  62         }
  63
  64         entity e;
  65
  66         e = to;
  67         if(IS_SPEC(to))
  68                 e = to.enemy;
  69
  70         sf = 0;
  71
  72         if(e.race_completed)
  73                 sf |= 1; // forced scoreboard
  74         if(to.spectatee_status)
  75                 sf |= 2; // spectator ent number follows
  76         if(e.zoomstate)
  77                 sf |= 4; // zoomed
  78         if(e.porto_v_angle_held)
  79                 sf |= 8; // angles held
  80
  81         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  82         WriteByte(MSG_ENTITY, sf);
  83
  84         if(sf & 2)
  85                 WriteByte(MSG_ENTITY, to.spectatee_status);
  86
  87         if(sf & 8)
  88         {
  89                 WriteAngle(MSG_ENTITY, e.v_angle.x);
  90                 WriteAngle(MSG_ENTITY, e.v_angle.y);
  91         }
  92
  93         return true;
  94 }
  95
  96 void ClientData_Attach()
  97 {
  98         Net_LinkEntity(self.clientdata = spawn(), false, 0, ClientData_Send);
  99         self.clientdata.drawonlytoclient = self;
 100         self.clientdata.owner = self;
 101 }
 102
 103 void ClientData_Detach()
 104 {
 105         remove(self.clientdata);
 106         self.clientdata = world;
 107 }
 108
 109 void ClientData_Touch(entity e)
 110 {
 111         e.clientdata.SendFlags = 1;
 112
 113         // make it spectatable
 114         entity e2;
 115         FOR_EACH_REALCLIENT(e2)
 116         {
 117                 if(e2 != e)
 118                         if(IS_SPEC(e2))
 119                                 if(e2.enemy == e)
 120                                         e2.clientdata.SendFlags = 1;
 121         }
 122 }
 123
 124 .string netname_previous;
 125
 126 void SetSpectator(entity player, entity spectatee);
 127
 128
 129 /*
 130 =============
 131 CheckPlayerModel
 132
 133 Checks if the argument string can be a valid playermodel.
 134 Returns a valid one in doubt.
 135 =============
 136 */
 137 string FallbackPlayerModel;
 138 string CheckPlayerModel(string plyermodel) {
 139         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 140         {
 141                 // note: we cannot summon Don Strunzone here, some player may
 142                 // still have the model string set. In case anyone manages how
 143                 // to change a cvar default, we'll have a small leak here.
 144                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 145         }
 146         // only in right path
 147         if( substring(plyermodel,0,14) != "models/player/")
 148                 return FallbackPlayerModel;
 149         // only good file extensions
 150         if(substring(plyermodel,-4,4) != ".zym")
 151         if(substring(plyermodel,-4,4) != ".dpm")
 152         if(substring(plyermodel,-4,4) != ".iqm")
 153         if(substring(plyermodel,-4,4) != ".md3")
 154         if(substring(plyermodel,-4,4) != ".psk")
 155                 return FallbackPlayerModel;
 156         // forbid the LOD models
 157         if(substring(plyermodel, -9,5) == "_lod1")
 158                 return FallbackPlayerModel;
 159         if(substring(plyermodel, -9,5) == "_lod2")
 160                 return FallbackPlayerModel;
 161         if(plyermodel != strtolower(plyermodel))
 162                 return FallbackPlayerModel;
 163         // also, restrict to server models
 164         if(autocvar_sv_servermodelsonly)
 165         {
 166                 if(!fexists(plyermodel))
 167                         return FallbackPlayerModel;
 168         }
 169         return plyermodel;
 170 }
 171
 172 void setplayermodel(entity e, string modelname)
 173 {
 174         precache_model(modelname);
 175         setmodel(e, modelname);
 176         player_setupanimsformodel();
 177         UpdatePlayerSounds();
 178 }
 179
 180 /*
 181 =============
 182 PutObserverInServer
 183
 184 putting a client as observer in the server
 185 =============
 186 */
 187 void FixPlayermodel();
 188 void PutObserverInServer (void)
 189 {
 190         entity  spot;
 191     self.hud = HUD_NORMAL;
 192
 193         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
 194
 195         spot = SelectSpawnPoint (true);
 196         if(!spot)
 197                 error("No spawnpoints for observers?!?\n");
 198         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 199
 200         if(IS_REAL_CLIENT(self))
 201         {
 202                 msg_entity = self;
 203                 WriteByte(MSG_ONE, SVC_SETVIEW);
 204                 WriteEntity(MSG_ONE, self);
 205         }
 206
 207         self.frags = FRAGS_SPECTATOR;
 208
 209         MUTATOR_CALLHOOK(MakePlayerObserver);
 210
 211         Portal_ClearAll(self);
 212
 213         Unfreeze(self);
 214
 215         if(self.alivetime)
 216         {
 217                 if(!warmup_stage)
 218                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 219                 self.alivetime = 0;
 220         }
 221
 222         if(self.vehicle)
 223                 vehicles_exit(VHEF_RELEASE);
 224
 225         WaypointSprite_PlayerDead();
 226
 227         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 228                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 229
 230         if(self.killcount != -666)
 231         {
 232                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 233                 if(!intermission_running)
 234                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 235                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 236
 237                 if(self.just_joined == false) {
 238                         LogTeamchange(self.playerid, -1, 4);
 239                 } else
 240                         self.just_joined = false;
 241         }
 242
 243         PlayerScore_Clear(self); // clear scores when needed
 244
 245         accuracy_resend(self);
 246
 247         self.spectatortime = time;
 248
 249         self.classname = "observer";
 250         self.iscreature = false;
 251         self.teleportable = TELEPORT_SIMPLE;
 252         self.damagedbycontents = false;
 253         self.health = -666;
 254         self.takedamage = DAMAGE_NO;
 255         self.solid = SOLID_NOT;
 256         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 257         self.flags = FL_CLIENT | FL_NOTARGET;
 258         self.armorvalue = 666;
 259         self.effects = 0;
 260         self.armorvalue = autocvar_g_balance_armor_start;
 261         self.pauserotarmor_finished = 0;
 262         self.pauserothealth_finished = 0;
 263         self.pauseregen_finished = 0;
 264         self.damageforcescale = 0;
 265         self.death_time = 0;
 266         self.respawn_flags = 0;
 267         self.respawn_time = 0;
 268         self.stat_respawn_time = 0;
 269         self.alpha = 0;
 270         self.scale = 0;
 271         self.fade_time = 0;
 272         self.pain_frame = 0;
 273         self.pain_finished = 0;
 274         self.strength_finished = 0;
 275         self.invincible_finished = 0;
 276         self.superweapons_finished = 0;
 277         self.pushltime = 0;
 278         self.istypefrag = 0;
 279         self.think = func_null;
 280         self.nextthink = 0;
 281         self.hook_time = 0;
 282         self.deadflag = DEAD_NO;
 283         self.angles = spot.angles;
 284         self.angles_z = 0;
 285         self.fixangle = true;
 286         self.crouch = false;
 287         self.revival_time = 0;
 288
 289         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 290         self.prevorigin = self.origin;
 291         self.items = 0;
 292         self.weapons = '0 0 0';
 293         self.model = "";
 294         FixPlayermodel();
 295         setmodel(self, "null");
 296         self.drawonlytoclient = self;
 297
 298         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 299         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 300
 301         self.weapon = 0;
 302         self.weaponname = "";
 303         self.switchingweapon = 0;
 304         self.weaponmodel = "";
 305         self.weaponentity = world;
 306         self.exteriorweaponentity = world;
 307         self.killcount = -666;
 308         self.velocity = '0 0 0';
 309         self.avelocity = '0 0 0';
 310         self.punchangle = '0 0 0';
 311         self.punchvector = '0 0 0';
 312         self.oldvelocity = self.velocity;
 313         self.fire_endtime = -1;
 314         self.event_damage = func_null;
 315 }
 316
 317 .float model_randomizer;
 318 void FixPlayermodel()
 319 {
 320         string defaultmodel;
 321         float defaultskin, chmdl, oldskin, n, i;
 322         vector m1, m2;
 323
 324         defaultmodel = "";
 325         defaultskin = 0;
 326         chmdl = false;
 327
 328         if(autocvar_sv_defaultcharacter)
 329         {
 330                 if(teamplay)
 331                 {
 332                         string s;
 333                         s = Static_Team_ColorName_Lower(self.team);
 334                         if(s != "neutral")
 335                         {
 336                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 337                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 338                         }
 339                 }
 340
 341                 if(defaultmodel == "")
 342                 {
 343                         defaultmodel = autocvar_sv_defaultplayermodel;
 344                         defaultskin = autocvar_sv_defaultplayerskin;
 345                 }
 346
 347                 n = tokenize_console(defaultmodel);
 348                 if(n > 0)
 349                 {
 350                         defaultmodel = argv(floor(n * self.model_randomizer));
 351                         // However, do NOT randomize if the player-selected model is in the list.
 352                         for (i = 0; i < n; ++i)
 353                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 354                                         defaultmodel = argv(i);
 355                 }
 356
 357                 i = strstrofs(defaultmodel, ":", 0);
 358                 if(i >= 0)
 359                 {
 360                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 361                         defaultmodel = substring(defaultmodel, 0, i);
 362                 }
 363         }
 364
 365         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel);
 366         defaultmodel = ret_string;
 367
 368         if(defaultmodel != "")
 369         {
 370                 if (defaultmodel != self.model)
 371                 {
 372                         m1 = self.mins;
 373                         m2 = self.maxs;
 374                         setplayermodel (self, defaultmodel);
 375                         setsize (self, m1, m2);
 376                         chmdl = true;
 377                 }
 378
 379                 oldskin = self.skin;
 380                 self.skin = defaultskin;
 381         } else {
 382                 if (self.playermodel != self.model || self.playermodel == "")
 383                 {
 384                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 385                         m1 = self.mins;
 386                         m2 = self.maxs;
 387                         setplayermodel (self, self.playermodel);
 388                         setsize (self, m1, m2);
 389                         chmdl = true;
 390                 }
 391
 392                 oldskin = self.skin;
 393                 self.skin = stof(self.playerskin);
 394         }
 395
 396         if(chmdl || oldskin != self.skin) // model or skin has changed
 397         {
 398                 self.species = player_getspecies(); // update species
 399                 UpdatePlayerSounds(); // update skin sounds
 400         }
 401
 402         if(!teamplay)
 403                 if(strlen(autocvar_sv_defaultplayercolors))
 404                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 405                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 406 }
 407
 408 /*
 409 =============
 410 PutClientInServer
 411
 412 Called when a client spawns in the server
 413 =============
 414 */
 415 void PutClientInServer (void)
 416 {
 417         if(IS_BOT_CLIENT(self))
 418                 self.classname = "player";
 419         else if(IS_REAL_CLIENT(self))
 420         {
 421                 msg_entity = self;
 422                 WriteByte(MSG_ONE, SVC_SETVIEW);
 423                 WriteEntity(MSG_ONE, self);
 424         }
 425
 426         SetSpectator(self, world);
 427
 428         // reset player keys
 429         self.itemkeys = 0;
 430
 431         MUTATOR_CALLHOOK(PutClientInServer, self);
 432
 433         if(gameover)
 434                 self.classname = "observer";
 435
 436         if(IS_PLAYER(self))
 437         {
 438                 entity spot, oldself;
 439
 440                 accuracy_resend(self);
 441
 442                 if(self.team < 0)
 443                         JoinBestTeam(self, false, true);
 444
 445                 spot = SelectSpawnPoint (false);
 446                 if(!spot)
 447                 {
 448                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 449                         return; // spawn failed
 450                 }
 451
 452                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 453
 454                 self.classname = "player";
 455                 self.wasplayer = true;
 456                 self.iscreature = true;
 457                 self.teleportable = TELEPORT_NORMAL;
 458                 self.damagedbycontents = true;
 459                 self.movetype = MOVETYPE_WALK;
 460                 self.solid = SOLID_SLIDEBOX;
 461                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 462                 if(autocvar_g_playerclip_collisions)
 463                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 464                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 465                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 466                 self.frags = FRAGS_PLAYER;
 467                 if(INDEPENDENT_PLAYERS)
 468                         MAKE_INDEPENDENT_PLAYER(self);
 469                 self.flags = FL_CLIENT;
 470                 if(autocvar__notarget)
 471                         self.flags |= FL_NOTARGET;
 472                 self.takedamage = DAMAGE_AIM;
 473                 self.effects = 0;
 474                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 475                 self.air_finished = time + 12;
 476                 self.dmg = 2;
 477                 if(WEP_CVAR(vortex, charge))
 478                 {
 479                         if(WEP_CVAR_SEC(vortex, chargepool))
 480                                 self.vortex_chargepool_ammo = 1;
 481                         self.vortex_charge = WEP_CVAR(vortex, charge_start);
 482                 }
 483
 484                 if(warmup_stage)
 485                 {
 486                         self.ammo_shells = warmup_start_ammo_shells;
 487                         self.ammo_nails = warmup_start_ammo_nails;
 488                         self.ammo_rockets = warmup_start_ammo_rockets;
 489                         self.ammo_cells = warmup_start_ammo_cells;
 490                         self.ammo_plasma = warmup_start_ammo_plasma;
 491                         self.ammo_fuel = warmup_start_ammo_fuel;
 492                         self.health = warmup_start_health;
 493                         self.armorvalue = warmup_start_armorvalue;
 494                         self.weapons = WARMUP_START_WEAPONS;
 495                 }
 496                 else
 497                 {
 498                         self.ammo_shells = start_ammo_shells;
 499                         self.ammo_nails = start_ammo_nails;
 500                         self.ammo_rockets = start_ammo_rockets;
 501                         self.ammo_cells = start_ammo_cells;
 502                         self.ammo_plasma = start_ammo_plasma;
 503                         self.ammo_fuel = start_ammo_fuel;
 504                         self.health = start_health;
 505                         self.armorvalue = start_armorvalue;
 506                         self.weapons = start_weapons;
 507                 }
 508
 509                 if(self.weapons & WEPSET_SUPERWEAPONS)
 510                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 511                 else
 512                         self.superweapons_finished = 0;
 513
 514                 if(g_weaponarena_random) // WEAPONTODO: more stuff that should be in a mutator. also: rename those cvars
 515                 {
 516                         if(g_weaponarena_random_with_blaster)
 517                                 self.weapons &= ~WEPSET_BLASTER;
 518                         W_RandomWeapons(self, g_weaponarena_random);
 519                         if(g_weaponarena_random_with_blaster)
 520                                 self.weapons |= WEPSET_BLASTER;
 521                 }
 522
 523                 self.items = start_items;
 524
 525                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 526                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 527                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 528                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 529                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 530                 //extend the pause of rotting if client was reset at the beginning of the countdown
 531                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 532                         self.spawnshieldtime += game_starttime - time;
 533                         self.pauserotarmor_finished += game_starttime - time;
 534                         self.pauserothealth_finished += game_starttime - time;
 535                         self.pauseregen_finished += game_starttime - time;
 536                 }
 537                 self.damageforcescale = 2;
 538                 self.death_time = 0;
 539                 self.respawn_flags = 0;
 540                 self.respawn_time = 0;
 541                 self.stat_respawn_time = 0;
 542                 self.scale = autocvar_sv_player_scale;
 543                 self.fade_time = 0;
 544                 self.pain_frame = 0;
 545                 self.pain_finished = 0;
 546                 self.strength_finished = 0;
 547                 self.invincible_finished = 0;
 548                 self.pushltime = 0;
 549                 // players have no think function
 550                 self.think = func_null;
 551                 self.nextthink = 0;
 552                 self.hook_time = 0;
 553                 self.dmg_team = 0;
 554                 self.ballistics_density = autocvar_g_ballistics_density_player;
 555
 556                 self.metertime = 0;
 557
 558                 self.deadflag = DEAD_NO;
 559
 560                 self.angles = spot.angles;
 561
 562                 self.angles_z = 0; // never spawn tilted even if the spot says to
 563                 if(IS_BOT_CLIENT(self))
 564                         self.v_angle = self.angles;
 565                 self.fixangle = true; // turn this way immediately
 566                 self.velocity = '0 0 0';
 567                 self.avelocity = '0 0 0';
 568                 self.punchangle = '0 0 0';
 569                 self.punchvector = '0 0 0';
 570                 self.oldvelocity = self.velocity;
 571                 self.fire_endtime = -1;
 572                 self.revival_time = 0;
 573
 574                 entity spawnevent = spawn();
 575                 spawnevent.owner = self;
 576                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 577
 578                 // Cut off any still running player sounds.
 579                 stopsound(self, CH_PLAYER_SINGLE);
 580
 581                 self.model = "";
 582                 FixPlayermodel();
 583                 self.drawonlytoclient = world;
 584
 585                 self.crouch = false;
 586                 self.view_ofs = PL_VIEW_OFS;
 587                 setsize (self, PL_MIN, PL_MAX);
 588                 self.spawnorigin = spot.origin;
 589                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins.z - 24));
 590                 // don't reset back to last position, even if new position is stuck in solid
 591                 self.oldorigin = self.origin;
 592                 self.prevorigin = self.origin;
 593                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 594                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 595         self.hud = HUD_NORMAL;
 596
 597                 self.event_damage = PlayerDamage;
 598
 599                 self.bot_attack = true;
 600                 self.monster_attack = true;
 601
 602                 self.spider_slowness = 0;
 603
 604                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 605
 606                 if(self.killcount == -666) {
 607                         PlayerScore_Clear(self);
 608                         self.killcount = 0;
 609                 }
 610
 611                 CL_SpawnWeaponentity();
 612                 self.alpha = default_player_alpha;
 613                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 614                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 615
 616                 self.speedrunning = false;
 617
 618                 //stuffcmd(self, "chase_active 0");
 619                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 620
 621                 target_voicescript_clear(self);
 622
 623                 // reset fields the weapons may use
 624                 for (int j = WEP_FIRST; j <= WEP_LAST; ++j)
 625                 {
 626                         WEP_ACTION(j, WR_RESETPLAYER);
 627
 628                         // all weapons must be fully loaded when we spawn
 629                         entity e = get_weaponinfo(j);
 630                         if (e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 631                                 self.(weapon_load[j]) = e.reloading_ammo;
 632                 }
 633
 634                 oldself = self;
 635                 self = spot;
 636                         activator = oldself;
 637                                 string s;
 638                                 s = self.target;
 639                                 self.target = string_null;
 640                                 SUB_UseTargets();
 641                                 self.target = s;
 642                         activator = world;
 643                 self = oldself;
 644
 645                 Unfreeze(self);
 646
 647                 MUTATOR_CALLHOOK(PlayerSpawn, spot);
 648
 649                 if(autocvar_spawn_debug)
 650                 {
 651                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 652                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 653                 }
 654
 655                 self.switchweapon = w_getbestweapon(self);
 656                 self.cnt = -1; // W_LastWeapon will not complain
 657                 self.weapon = 0;
 658                 self.weaponname = "";
 659                 self.switchingweapon = 0;
 660
 661                 if(!warmup_stage)
 662                         if(!self.alivetime)
 663                                 self.alivetime = time;
 664
 665                 antilag_clear(self);
 666         }
 667         else if(IS_OBSERVER(self))
 668         {
 669                 PutObserverInServer ();
 670         }
 671 }
 672
 673 .float ebouncefactor, ebouncestop; // electro's values
 674 // TODO do we need all these fields, or should we stop autodetecting runtime
 675 // changes and just have a console command to update this?
 676 float ClientInit_SendEntity(entity to, int sf)
 677 {
 678         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 679         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 680         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 681         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 682         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 683         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 684         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[0]));
 685         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[1]));
 686         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[2]));
 687         WriteInt24_t(MSG_ENTITY, compressShotOrigin(arc_shotorigin[3]));
 688
 689         if(sv_foginterval && world.fog != "")
 690                 WriteString(MSG_ENTITY, world.fog);
 691         else
 692                 WriteString(MSG_ENTITY, "");
 693         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 694         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_mortar_bouncefactor // WEAPONTODO
 695         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_mortar_bouncestop
 696         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_mortar_bouncefactor
 697         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_mortar_bouncestop
 698         WriteByte(MSG_ENTITY, WEP_CVAR(vortex, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 699         WriteByte(MSG_ENTITY, WEP_CVAR(rifle, secondary)); // client has to know if it should zoom or not // WEAPONTODO
 700         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 701         WriteByte(MSG_ENTITY, WEP_CVAR(minelayer, limit)); // minelayer max mines // WEAPONTODO
 702         WriteByte(MSG_ENTITY, WEP_CVAR_SEC(hagar, load_max)); // hagar max loadable rockets // WEAPONTODO
 703         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 704         WriteByte(MSG_ENTITY, WEP_CVAR(porto, secondary)); // WEAPONTODO
 705         return true;
 706 }
 707
 708 void ClientInit_CheckUpdate()
 709 {
 710         self.nextthink = time;
 711         if(self.count != autocvar_g_balance_armor_blockpercent)
 712         {
 713                 self.count = autocvar_g_balance_armor_blockpercent;
 714                 self.SendFlags |= 1;
 715         }
 716         if(self.bouncefactor != autocvar_g_balance_mortar_bouncefactor) // WEAPONTODO
 717         {
 718                 self.bouncefactor = autocvar_g_balance_mortar_bouncefactor;
 719                 self.SendFlags |= 1;
 720         }
 721         if(self.bouncestop != autocvar_g_balance_mortar_bouncestop)
 722         {
 723                 self.bouncestop = autocvar_g_balance_mortar_bouncestop;
 724                 self.SendFlags |= 1;
 725         }
 726         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 727         {
 728                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 729                 self.SendFlags |= 1;
 730         }
 731         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 732         {
 733                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 734                 self.SendFlags |= 1;
 735         }
 736 }
 737
 738 void ClientInit_Spawn()
 739 {
 740         entity o;
 741         entity e;
 742         e = spawn();
 743         e.classname = "clientinit";
 744         e.think = ClientInit_CheckUpdate;
 745         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 746
 747         o = self;
 748         self = e;
 749         ClientInit_CheckUpdate();
 750         self = o;
 751 }
 752
 753 /*
 754 =============
 755 SetNewParms
 756 =============
 757 */
 758 void SetNewParms (void)
 759 {
 760         // initialize parms for a new player
 761         parm1 = -(86400 * 366);
 762 }
 763
 764 /*
 765 =============
 766 SetChangeParms
 767 =============
 768 */
 769 void SetChangeParms (void)
 770 {
 771         // save parms for level change
 772         parm1 = self.parm_idlesince - time;
 773 }
 774
 775 /*
 776 =============
 777 DecodeLevelParms
 778 =============
 779 */
 780 void DecodeLevelParms (void)
 781 {
 782         // load parms
 783         self.parm_idlesince = parm1;
 784         if(self.parm_idlesince == -(86400 * 366))
 785                 self.parm_idlesince = time;
 786
 787         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 788         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 789 }
 790
 791 /*
 792 =============
 793 ClientKill
 794
 795 Called when a client types 'kill' in the console
 796 =============
 797 */
 798
 799 .float clientkill_nexttime;
 800 void ClientKill_Now_TeamChange()
 801 {
 802         if(self.killindicator_teamchange == -1)
 803         {
 804                 JoinBestTeam( self, false, true );
 805         }
 806         else if(self.killindicator_teamchange == -2)
 807         {
 808                 if(blockSpectators)
 809                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 810                 PutObserverInServer();
 811         }
 812         else
 813                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 814         self.killindicator_teamchange = 0;
 815 }
 816
 817 void ClientKill_Now()
 818 {
 819         if(self.vehicle)
 820         {
 821             vehicles_exit(VHEF_RELEASE);
 822             if(!self.killindicator_teamchange)
 823             {
 824             self.vehicle_health = -1;
 825             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 826             }
 827         }
 828
 829         if(self.killindicator && !wasfreed(self.killindicator))
 830                 remove(self.killindicator);
 831
 832         self.killindicator = world;
 833
 834         if(self.killindicator_teamchange)
 835                 ClientKill_Now_TeamChange();
 836
 837         if(IS_PLAYER(self))
 838                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 839
 840         // now I am sure the player IS dead
 841 }
 842 void KillIndicator_Think()
 843 {
 844         if (gameover)
 845         {
 846                 self.owner.killindicator = world;
 847                 remove(self);
 848                 return;
 849         }
 850
 851         if (self.owner.alpha < 0 && !self.owner.vehicle)
 852         {
 853                 self.owner.killindicator = world;
 854                 remove(self);
 855                 return;
 856         }
 857
 858         if(self.cnt <= 0)
 859         {
 860                 self = self.owner;
 861                 ClientKill_Now(); // no oldself needed
 862                 return;
 863         }
 864     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 865     {
 866         self.nextthink = time + 1;
 867         self.cnt -= 1;
 868     }
 869         else
 870         {
 871                 if(self.cnt <= 10)
 872                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 873                 if(IS_REAL_CLIENT(self.owner))
 874                 {
 875                         if(self.cnt <= 10)
 876                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 877                 }
 878                 self.nextthink = time + 1;
 879                 self.cnt -= 1;
 880         }
 881 }
 882
 883 float clientkilltime;
 884 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 885 {
 886         float killtime;
 887         float starttime;
 888         entity e;
 889
 890         if (gameover)
 891                 return;
 892
 893         killtime = autocvar_g_balance_kill_delay;
 894
 895         if(g_race_qualifying || g_cts)
 896                 killtime = 0;
 897
 898     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 899     {
 900                 remove(self.killindicator);
 901                 self.killindicator = world;
 902
 903         ClientKill_Now(); // allow instant kill in this case
 904         return;
 905     }
 906
 907         self.killindicator_teamchange = targetteam;
 908
 909     if(!self.killindicator)
 910         {
 911                 if(self.deadflag == DEAD_NO)
 912                 {
 913                         killtime = max(killtime, self.clientkill_nexttime - time);
 914                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 915                 }
 916
 917                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 918                 {
 919                         ClientKill_Now();
 920                 }
 921                 else
 922                 {
 923                         starttime = max(time, clientkilltime);
 924
 925                         self.killindicator = spawn();
 926                         self.killindicator.owner = self;
 927                         self.killindicator.scale = 0.5;
 928                         setattachment(self.killindicator, self, "");
 929                         setorigin(self.killindicator, '0 0 52');
 930                         self.killindicator.think = KillIndicator_Think;
 931                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 932                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 933                         self.killindicator.cnt = ceil(killtime);
 934                         self.killindicator.count = bound(0, ceil(killtime), 10);
 935                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 936
 937                         for(e = world; (e = find(e, classname, "body")) != world; )
 938                         {
 939                                 if(e.enemy != self)
 940                                         continue;
 941                                 e.killindicator = spawn();
 942                                 e.killindicator.owner = e;
 943                                 e.killindicator.scale = 0.5;
 944                                 setattachment(e.killindicator, e, "");
 945                                 setorigin(e.killindicator, '0 0 52');
 946                                 e.killindicator.think = KillIndicator_Think;
 947                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 948                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 949                                 e.killindicator.cnt = ceil(killtime);
 950                         }
 951                         self.lip = 0;
 952                 }
 953         }
 954         if(self.killindicator)
 955         {
 956                 if(targetteam == 0) // just die
 957                 {
 958                         self.killindicator.colormod = '0 0 0';
 959                         if(IS_REAL_CLIENT(self))
 960                         if(self.killindicator.cnt > 0)
 961                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 962                 }
 963                 else if(targetteam == -1) // auto
 964                 {
 965                         self.killindicator.colormod = '0 1 0';
 966                         if(IS_REAL_CLIENT(self))
 967                         if(self.killindicator.cnt > 0)
 968                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 969                 }
 970                 else if(targetteam == -2) // spectate
 971                 {
 972                         self.killindicator.colormod = '0.5 0.5 0.5';
 973                         if(IS_REAL_CLIENT(self))
 974                         if(self.killindicator.cnt > 0)
 975                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 976                 }
 977                 else
 978                 {
 979                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 980                         if(IS_REAL_CLIENT(self))
 981                         if(self.killindicator.cnt > 0)
 982                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 983                 }
 984         }
 985
 986 }
 987
 988 void ClientKill (void)
 989 {
 990         if(gameover) return;
 991         if(self.player_blocked) return;
 992         if(self.frozen) return;
 993
 994         ClientKill_TeamChange(0);
 995 }
 996
 997 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 998 {
 999     e.killindicator = spawn();
1000     e.killindicator.owner = e;
1001     e.killindicator.think = KillIndicator_Think;
1002     e.killindicator.nextthink = time + (e.lip) * 0.05;
1003     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1004     e.killindicator.health = 1; // this is used to indicate that it should be silent
1005     e.lip = 0;
1006 }
1007
1008 void FixClientCvars(entity e)
1009 {
1010         // send prediction settings to the client
1011         stuffcmd(e, "\nin_bindmap 0 0\n");
1012         if(g_race || g_cts)
1013                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1014         if(autocvar_g_antilag == 3) // client side hitscan
1015                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1016         if(autocvar_sv_gentle)
1017                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1018 }
1019
1020 float PlayerInIDList(entity p, string idlist)
1021 {
1022         float n, i;
1023         string s;
1024
1025         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1026         if (!p.crypto_idfp)
1027                 return 0;
1028
1029         // this function allows abbreviated player IDs too!
1030         n = tokenize_console(idlist);
1031         for(i = 0; i < n; ++i)
1032         {
1033                 s = argv(i);
1034                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1035                         return 1;
1036         }
1037
1038         return 0;
1039 }
1040
1041 #ifdef DP_EXT_PRECONNECT
1042 /*
1043 =============
1044 ClientPreConnect
1045
1046 Called once (not at each match start) when a client begins a connection to the server
1047 =============
1048 */
1049 void ClientPreConnect (void)
1050 {
1051         if(autocvar_sv_eventlog)
1052         {
1053                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1054                         self.playerid,
1055                         num_for_edict(self),
1056                         ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot")
1057                 ));
1058         }
1059 }
1060 #endif
1061
1062 /*
1063 =============
1064 ClientConnect
1065
1066 Called when a client connects to the server
1067 =============
1068 */
1069 void DecodeLevelParms (void);
1070 //void dom_player_join_team(entity pl);
1071 void set_dom_state(entity e);
1072 void ClientConnect (void)
1073 {
1074         float t;
1075
1076         if(IS_CLIENT(self))
1077         {
1078                 LOG_INFO("Warning: ClientConnect, but already connected!\n");
1079                 return;
1080         }
1081
1082         if(Ban_MaybeEnforceBanOnce(self))
1083                 return;
1084
1085         DecodeLevelParms();
1086
1087 #ifdef WATERMARK
1088         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1089 #endif
1090
1091         self.classname = "player_joining";
1092
1093         self.flags = FL_CLIENT;
1094         self.version_nagtime = time + 10 + random() * 10;
1095
1096         if(player_count<0)
1097         {
1098                 LOG_TRACE("BUG player count is lower than zero, this cannot happen!\n");
1099                 player_count = 0;
1100         }
1101
1102         if(IS_REAL_CLIENT(self)) { PlayerStats_PlayerBasic_CheckUpdate(self); }
1103
1104         PlayerScore_Attach(self);
1105         ClientData_Attach();
1106         accuracy_init(self);
1107         Inventory_new(self);
1108
1109         bot_clientconnect();
1110
1111         playerdemo_init();
1112
1113         anticheat_init();
1114
1115         // identify the right forced team
1116         if(autocvar_g_campaign)
1117         {
1118                 if(IS_REAL_CLIENT(self)) // only players, not bots
1119                 {
1120                         switch(autocvar_g_campaign_forceteam)
1121                         {
1122                                 case 1: self.team_forced = NUM_TEAM_1; break;
1123                                 case 2: self.team_forced = NUM_TEAM_2; break;
1124                                 case 3: self.team_forced = NUM_TEAM_3; break;
1125                                 case 4: self.team_forced = NUM_TEAM_4; break;
1126                                 default: self.team_forced = 0;
1127                         }
1128                 }
1129         }
1130         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1131                 self.team_forced = NUM_TEAM_1;
1132         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1133                 self.team_forced = NUM_TEAM_2;
1134         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1135                 self.team_forced = NUM_TEAM_3;
1136         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1137                 self.team_forced = NUM_TEAM_4;
1138         else if(autocvar_g_forced_team_otherwise == "red")
1139                 self.team_forced = NUM_TEAM_1;
1140         else if(autocvar_g_forced_team_otherwise == "blue")
1141                 self.team_forced = NUM_TEAM_2;
1142         else if(autocvar_g_forced_team_otherwise == "yellow")
1143                 self.team_forced = NUM_TEAM_3;
1144         else if(autocvar_g_forced_team_otherwise == "pink")
1145                 self.team_forced = NUM_TEAM_4;
1146         else if(autocvar_g_forced_team_otherwise == "spectate")
1147                 self.team_forced = -1;
1148         else if(autocvar_g_forced_team_otherwise == "spectator")
1149                 self.team_forced = -1;
1150         else
1151                 self.team_forced = 0;
1152
1153         if(!teamplay)
1154                 if(self.team_forced > 0)
1155                         self.team_forced = 0;
1156
1157         JoinBestTeam(self, false, false); // if the team number is valid, keep it
1158
1159         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1160                 self.classname = "observer";
1161         } else {
1162                 if(teamplay)
1163                 {
1164                         if(autocvar_g_balance_teams)
1165                         {
1166                                 self.classname = "player";
1167                                 campaign_bots_may_start = 1;
1168                         }
1169                         else
1170                         {
1171                                 self.classname = "observer"; // do it anyway
1172                         }
1173                 }
1174                 else
1175                 {
1176                         self.classname = "player";
1177                         campaign_bots_may_start = 1;
1178                 }
1179         }
1180
1181         self.playerid = (playerid_last = playerid_last + 1);
1182
1183         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", self.playerid));
1184
1185     if(IS_BOT_CLIENT(self))
1186         PlayerStats_GameReport_AddPlayer(self);
1187
1188         if(autocvar_sv_eventlog)
1189                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1190
1191         LogTeamchange(self.playerid, self.team, 1);
1192
1193         self.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1194
1195         self.netname_previous = strzone(self.netname);
1196
1197         if(IS_PLAYER(self) && teamplay)
1198                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1199         else
1200                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1201
1202         stuffcmd(self, strcat(clientstuff, "\n"));
1203         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1204
1205         FixClientCvars(self);
1206
1207         // spawnfunc_waypoint sprites
1208         WaypointSprite_InitClient(self);
1209
1210         // Wazat's grappling hook
1211         SetGrappleHookBindings();
1212
1213         // Jetpack binds
1214         stuffcmd(self, "alias +jetpack +button10\n");
1215         stuffcmd(self, "alias -jetpack -button10\n");
1216
1217         // get version info from player
1218         stuffcmd(self, "cmd clientversion $gameversion\n");
1219
1220         // get other cvars from player
1221         GetCvars(0);
1222
1223         // notify about available teams
1224         if(teamplay)
1225         {
1226                 CheckAllowedTeams(self);
1227                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1228                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1229         }
1230         else
1231                 stuffcmd(self, "set _teams_available 0\n");
1232
1233         attach_entcs();
1234
1235         bot_relinkplayerlist();
1236
1237         self.spectatortime = time;
1238         if(blockSpectators)
1239         {
1240                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1241         }
1242
1243         self.jointime = time;
1244         self.allowed_timeouts = autocvar_sv_timeout_number;
1245
1246         if(IS_REAL_CLIENT(self))
1247         {
1248                 if(!autocvar_g_campaign)
1249                 {
1250                         self.motd_actived_time = -1;
1251                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1252                 }
1253
1254                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1255                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1256         }
1257
1258         if(!sv_foginterval && world.fog != "")
1259                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1260
1261         W_HitPlotOpen(self);
1262
1263         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1264                 send_CSQC_teamnagger();
1265
1266         CheatInitClient();
1267
1268         CSQCMODEL_AUTOINIT();
1269
1270         self.model_randomizer = random();
1271
1272         if(IS_REAL_CLIENT(self))
1273                 sv_notice_join();
1274
1275         for (entity e = world; (e = findfloat(e, init_for_player_needed, 1)); ) {
1276                 entity oldself = self;
1277                 self = e;
1278                 e.init_for_player(oldself);
1279                 self = oldself;
1280         }
1281
1282         MUTATOR_CALLHOOK(ClientConnect, self);
1283 }
1284 /*
1285 =============
1286 ClientDisconnect
1287
1288 Called when a client disconnects from the server
1289 =============
1290 */
1291 .entity chatbubbleentity;
1292 void ReadyCount();
1293 void ClientDisconnect (void)
1294 {
1295         if(self.vehicle)
1296             vehicles_exit(VHEF_RELEASE);
1297
1298         if (!IS_CLIENT(self))
1299         {
1300                 LOG_INFO("Warning: ClientDisconnect without ClientConnect\n");
1301                 return;
1302         }
1303
1304         PlayerStats_GameReport_FinalizePlayer(self);
1305
1306         if ( self.active_minigame )
1307                 part_minigame(self);
1308
1309         if(IS_PLAYER(self)) { Send_Effect(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); }
1310
1311         CheatShutdownClient();
1312
1313         W_HitPlotClose(self);
1314
1315         anticheat_report();
1316         anticheat_shutdown();
1317
1318         playerdemo_shutdown();
1319
1320         bot_clientdisconnect();
1321
1322         if(self.entcs)
1323                 detach_entcs();
1324
1325         if(autocvar_sv_eventlog)
1326                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1327
1328         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1329
1330         MUTATOR_CALLHOOK(ClientDisconnect);
1331
1332         Portal_ClearAll(self);
1333
1334         Unfreeze(self);
1335
1336         RemoveGrapplingHook(self);
1337
1338         // Here, everything has been done that requires this player to be a client.
1339
1340         self.flags &= ~FL_CLIENT;
1341
1342         if (self.chatbubbleentity)
1343                 remove (self.chatbubbleentity);
1344
1345         if (self.killindicator)
1346                 remove (self.killindicator);
1347
1348         WaypointSprite_PlayerGone();
1349
1350         bot_relinkplayerlist();
1351
1352         accuracy_free(self);
1353         Inventory_delete(self);
1354         ClientData_Detach();
1355         PlayerScore_Detach(self);
1356
1357         if(self.netname_previous)
1358                 strunzone(self.netname_previous);
1359         if(self.clientstatus)
1360                 strunzone(self.clientstatus);
1361         if(self.weaponorder_byimpulse)
1362                 strunzone(self.weaponorder_byimpulse);
1363
1364         ClearPlayerSounds();
1365
1366         if(self.personal)
1367                 remove(self.personal);
1368
1369         self.playerid = 0;
1370         ReadyCount();
1371
1372         // free cvars
1373         GetCvars(-1);
1374 }
1375
1376 .float BUTTON_CHAT;
1377 void ChatBubbleThink()
1378 {
1379         self.nextthink = time;
1380         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1381         {
1382                 if(self.owner) // but why can that ever be world?
1383                         self.owner.chatbubbleentity = world;
1384                 remove(self);
1385                 return;
1386         }
1387
1388         self.mdl = "";
1389
1390         if ( !self.owner.deadflag && IS_PLAYER(self.owner) )
1391         {
1392                 if ( self.owner.active_minigame )
1393                         self.mdl = "models/sprites/minigame_busy.iqm";
1394                 else if ( self.owner.BUTTON_CHAT )
1395                         self.mdl = "models/misc/chatbubble.spr";
1396         }
1397
1398         if ( self.model != self.mdl )
1399                 setmodel(self, self.mdl);
1400
1401 }
1402
1403 void UpdateChatBubble()
1404 {
1405         if (self.alpha < 0)
1406                 return;
1407         // spawn a chatbubble entity if needed
1408         if (!self.chatbubbleentity)
1409         {
1410                 self.chatbubbleentity = spawn();
1411                 self.chatbubbleentity.owner = self;
1412                 self.chatbubbleentity.exteriormodeltoclient = self;
1413                 self.chatbubbleentity.think = ChatBubbleThink;
1414                 self.chatbubbleentity.nextthink = time;
1415                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1416                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1417                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1418                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1419                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1420                 //self.chatbubbleentity.model = "";
1421                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1422         }
1423 }
1424
1425
1426 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1427 // added to the model skins
1428 /*void UpdateColorModHack()
1429 {
1430         float c;
1431         c = self.clientcolors & 15;
1432         // LordHavoc: only bothering to support white, green, red, yellow, blue
1433              if (!teamplay) self.colormod = '0 0 0';
1434         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1435         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1436         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1437         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1438         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1439         else self.colormod = '1 1 1';
1440 }*/
1441
1442 void respawn(void)
1443 {
1444         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1445         {
1446                 self.solid = SOLID_NOT;
1447                 self.takedamage = DAMAGE_NO;
1448                 self.movetype = MOVETYPE_FLY;
1449                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1450                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1451                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1452                 Send_Effect(EFFECT_RESPAWN_GHOST, self.origin, '0 0 0', 1);
1453                 if(autocvar_g_respawn_ghosts_maxtime)
1454                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1455         }
1456
1457         CopyBody(1);
1458
1459         self.effects |= EF_NODRAW; // prevent another CopyBody
1460         PutClientInServer();
1461 }
1462
1463 void play_countdown(float finished, string samp)
1464 {
1465         if(IS_REAL_CLIENT(self))
1466                 if(floor(finished - time - frametime) != floor(finished - time))
1467                         if(finished - time < 6)
1468                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1469 }
1470
1471 void player_powerups (void)
1472 {
1473         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1474         int items_prev = self.items;
1475
1476         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1477                 self.modelflags |= MF_ROCKET;
1478         else
1479                 self.modelflags &= ~MF_ROCKET;
1480
1481         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1482
1483         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1484                 return;
1485
1486         Fire_ApplyDamage(self);
1487         Fire_ApplyEffect(self);
1488
1489         if (!g_instagib)
1490         {
1491                 if (self.items & ITEM_Strength.m_itemid)
1492                 {
1493                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1494                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1495                         if (time > self.strength_finished)
1496                         {
1497                                 self.items = self.items - (self.items & ITEM_Strength.m_itemid);
1498                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1499                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1500                         }
1501                 }
1502                 else
1503                 {
1504                         if (time < self.strength_finished)
1505                         {
1506                                 self.items = self.items | ITEM_Strength.m_itemid;
1507                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1508                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1509                         }
1510                 }
1511                 if (self.items & ITEM_Shield.m_itemid)
1512                 {
1513                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1514                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1515                         if (time > self.invincible_finished)
1516                         {
1517                                 self.items = self.items - (self.items & ITEM_Shield.m_itemid);
1518                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1519                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1520                         }
1521                 }
1522                 else
1523                 {
1524                         if (time < self.invincible_finished)
1525                         {
1526                                 self.items = self.items | ITEM_Shield.m_itemid;
1527                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1528                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1529                         }
1530                 }
1531                 if (self.items & IT_SUPERWEAPON)
1532                 {
1533                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1534                         {
1535                                 self.superweapons_finished = 0;
1536                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1537                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1538                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1539                         }
1540                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1541                         {
1542                                 // don't let them run out
1543                         }
1544                         else
1545                         {
1546                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1547                                 if (time > self.superweapons_finished)
1548                                 {
1549                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1550                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1551                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1552                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1553                                 }
1554                         }
1555                 }
1556                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1557                 {
1558                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1559                         {
1560                                 self.items = self.items | IT_SUPERWEAPON;
1561                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1562                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1563                         }
1564                         else
1565                         {
1566                                 self.superweapons_finished = 0;
1567                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1568                         }
1569                 }
1570                 else
1571                 {
1572                         self.superweapons_finished = 0;
1573                 }
1574         }
1575
1576         if(autocvar_g_nodepthtestplayers)
1577                 self.effects = self.effects | EF_NODEPTHTEST;
1578
1579         if(autocvar_g_fullbrightplayers)
1580                 self.effects = self.effects | EF_FULLBRIGHT;
1581
1582         if (time >= game_starttime)
1583         if (time < self.spawnshieldtime)
1584                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1585
1586         MUTATOR_CALLHOOK(PlayerPowerups, self, items_prev);
1587 }
1588
1589 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1590 {
1591         if(current > stable)
1592                 return current;
1593         else if(current > stable - 0.25) // when close enough, "snap"
1594                 return stable;
1595         else
1596                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1597 }
1598
1599 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1600 {
1601         if(current < stable)
1602                 return current;
1603         else if(current < stable + 0.25) // when close enough, "snap"
1604                 return stable;
1605         else
1606                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1607 }
1608
1609 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1610 {
1611         if(current > rotstable)
1612         {
1613                 if(rotframetime > 0)
1614                 {
1615                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1616                         current = max(rotstable, current - rotlinear * rotframetime);
1617                 }
1618         }
1619         else if(current < regenstable)
1620         {
1621                 if(regenframetime > 0)
1622                 {
1623                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1624                         current = min(regenstable, current + regenlinear * regenframetime);
1625                 }
1626         }
1627
1628         if(current > limit)
1629                 current = limit;
1630
1631         return current;
1632 }
1633
1634 void player_regen (void)
1635 {
1636         float max_mod, regen_mod, rot_mod, limit_mod;
1637         max_mod = regen_mod = rot_mod = limit_mod = 1;
1638         regen_mod_max = max_mod;
1639         regen_mod_regen = regen_mod;
1640         regen_mod_rot = rot_mod;
1641         regen_mod_limit = limit_mod;
1642
1643         regen_health = autocvar_g_balance_health_regen;
1644         regen_health_linear = autocvar_g_balance_health_regenlinear;
1645         regen_health_rot = autocvar_g_balance_health_rot;
1646         regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1647         regen_health_stable = autocvar_g_balance_health_regenstable;
1648         regen_health_rotstable = autocvar_g_balance_health_rotstable;
1649         if(!MUTATOR_CALLHOOK(PlayerRegen))
1650         if(!self.frozen)
1651         {
1652                 float mina, maxa, limith, limita;
1653                 maxa = autocvar_g_balance_armor_rotstable;
1654                 mina = autocvar_g_balance_armor_regenstable;
1655                 limith = autocvar_g_balance_health_limit;
1656                 limita = autocvar_g_balance_armor_limit;
1657
1658                 max_mod = regen_mod_max;
1659                 regen_mod = regen_mod_regen;
1660                 rot_mod = regen_mod_rot;
1661                 limit_mod = regen_mod_limit;
1662
1663                 regen_health_rotstable = regen_health_rotstable * max_mod;
1664                 regen_health_stable = regen_health_stable * max_mod;
1665                 limith = limith * limit_mod;
1666                 limita = limita * limit_mod;
1667
1668                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1669                 self.health = CalcRotRegen(self.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > self.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1670         }
1671
1672         // if player rotted to death...  die!
1673         // check this outside above checks, as player may still be able to rot to death
1674         if(self.health < 1)
1675         {
1676                 if(self.vehicle)
1677                         vehicles_exit(VHEF_RELEASE);
1678                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1679         }
1680
1681         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1682         {
1683                 float minf, maxf, limitf;
1684
1685                 maxf = autocvar_g_balance_fuel_rotstable;
1686                 minf = autocvar_g_balance_fuel_regenstable;
1687                 limitf = autocvar_g_balance_fuel_limit;
1688
1689                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1690         }
1691 }
1692
1693 float zoomstate_set;
1694 void SetZoomState(float z)
1695 {
1696         if(z != self.zoomstate)
1697         {
1698                 self.zoomstate = z;
1699                 ClientData_Touch(self);
1700         }
1701         zoomstate_set = 1;
1702 }
1703
1704 void GetPressedKeys(void) {
1705         MUTATOR_CALLHOOK(GetPressedKeys);
1706         #define X(var,bit,flag) (flag ? var |= bit : var &= ~bit)
1707         X(self.pressedkeys, KEY_FORWARD,        self.movement_x > 0);
1708         X(self.pressedkeys, KEY_BACKWARD,       self.movement_x < 0);
1709         X(self.pressedkeys, KEY_RIGHT,          self.movement_y > 0);
1710         X(self.pressedkeys, KEY_LEFT,           self.movement_y < 0);
1711
1712         X(self.pressedkeys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(self));
1713         X(self.pressedkeys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(self));
1714         X(self.pressedkeys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(self));
1715         X(self.pressedkeys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(self));
1716         #undef X
1717 }
1718
1719 /*
1720 ======================
1721 spectate mode routines
1722 ======================
1723 */
1724
1725 void SpectateCopy(entity spectatee) {
1726         MUTATOR_CALLHOOK(SpectateCopy, spectatee, self);
1727         self.armortype = spectatee.armortype;
1728         self.armorvalue = spectatee.armorvalue;
1729         self.ammo_cells = spectatee.ammo_cells;
1730         self.ammo_plasma = spectatee.ammo_plasma;
1731         self.ammo_shells = spectatee.ammo_shells;
1732         self.ammo_nails = spectatee.ammo_nails;
1733         self.ammo_rockets = spectatee.ammo_rockets;
1734         self.ammo_fuel = spectatee.ammo_fuel;
1735         self.clip_load = spectatee.clip_load;
1736         self.clip_size = spectatee.clip_size;
1737         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1738         self.health = spectatee.health;
1739         self.impulse = 0;
1740         self.items = spectatee.items;
1741         self.last_pickup = spectatee.last_pickup;
1742         self.hit_time = spectatee.hit_time;
1743         self.metertime = spectatee.metertime;
1744         self.strength_finished = spectatee.strength_finished;
1745         self.invincible_finished = spectatee.invincible_finished;
1746         self.pressedkeys = spectatee.pressedkeys;
1747         self.weapons = spectatee.weapons;
1748         self.switchweapon = spectatee.switchweapon;
1749         self.switchingweapon = spectatee.switchingweapon;
1750         self.weapon = spectatee.weapon;
1751         self.vortex_charge = spectatee.vortex_charge;
1752         self.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1753         self.hagar_load = spectatee.hagar_load;
1754         self.arc_heat_percent = spectatee.arc_heat_percent;
1755         self.minelayer_mines = spectatee.minelayer_mines;
1756         self.punchangle = spectatee.punchangle;
1757         self.view_ofs = spectatee.view_ofs;
1758         self.velocity = spectatee.velocity;
1759         self.dmg_take = spectatee.dmg_take;
1760         self.dmg_save = spectatee.dmg_save;
1761         self.dmg_inflictor = spectatee.dmg_inflictor;
1762         self.v_angle = spectatee.v_angle;
1763         self.angles = spectatee.v_angle;
1764         self.frozen = spectatee.frozen;
1765         self.revive_progress = spectatee.revive_progress;
1766         if(!self.BUTTON_USE)
1767                 self.fixangle = true;
1768         setorigin(self, spectatee.origin);
1769         setsize(self, spectatee.mins, spectatee.maxs);
1770         SetZoomState(spectatee.zoomstate);
1771
1772     anticheat_spectatecopy(spectatee);
1773         self.hud = spectatee.hud;
1774         if(spectatee.vehicle)
1775     {
1776         self.fixangle = false;
1777         //self.velocity = spectatee.vehicle.velocity;
1778         self.vehicle_health = spectatee.vehicle_health;
1779         self.vehicle_shield = spectatee.vehicle_shield;
1780         self.vehicle_energy = spectatee.vehicle_energy;
1781         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1782         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1783         self.vehicle_reload1 = spectatee.vehicle_reload1;
1784         self.vehicle_reload2 = spectatee.vehicle_reload2;
1785
1786         msg_entity = self;
1787
1788         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1789             WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1790             WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1791             WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1792
1793         //WriteByte (MSG_ONE, SVC_SETVIEW);
1794         //    WriteEntity(MSG_ONE, self);
1795         //makevectors(spectatee.v_angle);
1796         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1797     }
1798 }
1799
1800 float SpectateUpdate()
1801 {
1802         if(!self.enemy)
1803             return 0;
1804
1805         if(!IS_PLAYER(self.enemy) || self == self.enemy)
1806         {
1807                 SetSpectator(self, world);
1808                 return 0;
1809         }
1810
1811         SpectateCopy(self.enemy);
1812
1813         return 1;
1814 }
1815
1816 float SpectateSet()
1817 {
1818         if(self.enemy.classname != "player")
1819                 return false;
1820         /*if(self.enemy.vehicle)
1821         {
1822
1823                 msg_entity = self;
1824                 WriteByte(MSG_ONE, SVC_SETVIEW);
1825                 WriteEntity(MSG_ONE, self.enemy);
1826                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1827
1828                 self.movetype = MOVETYPE_NONE;
1829                 accuracy_resend(self);
1830         }
1831         else
1832         {*/
1833                 msg_entity = self;
1834                 WriteByte(MSG_ONE, SVC_SETVIEW);
1835                 WriteEntity(MSG_ONE, self.enemy);
1836                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1837                 self.movetype = MOVETYPE_NONE;
1838                 accuracy_resend(self);
1839
1840                 if(!SpectateUpdate())
1841                         PutObserverInServer();
1842         //}
1843         return true;
1844 }
1845
1846 void SetSpectator(entity player, entity spectatee)
1847 {
1848         entity old_spectatee = player.enemy;
1849
1850         player.enemy = spectatee;
1851
1852         // WEAPONTODO
1853         // these are required to fix the spectator bug with arc
1854         if(old_spectatee && old_spectatee.arc_beam) { old_spectatee.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1855         if(player.enemy && player.enemy.arc_beam) { player.enemy.arc_beam.SendFlags |= ARC_SF_SETTINGS; }
1856 }
1857
1858 float Spectate(entity pl)
1859 {
1860         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1861         if(pl.team != self.team)
1862                 return 0;
1863
1864         SetSpectator(self, pl);
1865         return SpectateSet();
1866 }
1867
1868 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1869 entity CA_SpectateNext(entity start) {
1870         if (start.team == self.team) {
1871                 return start;
1872         }
1873
1874         other = start;
1875         // continue from current player
1876         while(other && other.team != self.team) {
1877                 other = find(other, classname, "player");
1878         }
1879
1880         if (!other) {
1881                 // restart from begining
1882                 other = find(other, classname, "player");
1883                 while(other && other.team != self.team) {
1884                         other = find(other, classname, "player");
1885                 }
1886         }
1887
1888         return other;
1889 }
1890
1891 float SpectateNext()
1892 {
1893         other = find(self.enemy, classname, "player");
1894
1895         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1896                 // CA and ca players when spectating enemies is forbidden
1897                 other = CA_SpectateNext(other);
1898         } else {
1899                 // other modes and ca spectators or spectating enemies is allowed
1900                 if (!other)
1901                         other = find(other, classname, "player");
1902         }
1903
1904         if(other) { SetSpectator(self, other); }
1905
1906         return SpectateSet();
1907 }
1908
1909 float SpectatePrev()
1910 {
1911         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1912         other = findchain(classname, "player");
1913         if (!other) // no player
1914                 return false;
1915
1916         entity first = other;
1917         // skip players until current spectated player
1918         if(self.enemy)
1919         while(other && other != self.enemy)
1920                 other = other.chain;
1921
1922         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1923         {
1924                 do { other = other.chain; }
1925                 while(other && other.team != self.team);
1926
1927                 if (!other)
1928                 {
1929                         other = first;
1930                         while(other.team != self.team)
1931                                 other = other.chain;
1932                         if(other == self.enemy)
1933                                 return true;
1934                 }
1935         }
1936         else
1937         {
1938                 if(other.chain)
1939                         other = other.chain;
1940                 else
1941                         other = first;
1942         }
1943         SetSpectator(self, other);
1944         return SpectateSet();
1945 }
1946
1947 /*
1948 =============
1949 ShowRespawnCountdown()
1950
1951 Update a respawn countdown display.
1952 =============
1953 */
1954 void ShowRespawnCountdown()
1955 {
1956         float number;
1957         if(self.deadflag == DEAD_NO) // just respawned?
1958                 return;
1959         else
1960         {
1961                 number = ceil(self.respawn_time - time);
1962                 if(number <= 0)
1963                         return;
1964                 if(number <= self.respawn_countdown)
1965                 {
1966                         self.respawn_countdown = number - 1;
1967                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1968                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1969                 }
1970         }
1971 }
1972
1973 void LeaveSpectatorMode()
1974 {
1975         if(self.caplayer)
1976                 return;
1977         if(nJoinAllowed(self))
1978         {
1979                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1980                 {
1981                         self.classname = "player";
1982                         nades_RemoveBonus(self);
1983
1984                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1985                                 { JoinBestTeam(self, false, true); }
1986
1987                         if(autocvar_g_campaign)
1988                                 { campaign_bots_may_start = 1; }
1989
1990                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1991
1992                         PutClientInServer();
1993
1994                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1995                 }
1996                 else
1997                         stuffcmd(self, "menu_showteamselect\n");
1998         }
1999         else
2000         {
2001                 // Player may not join because g_maxplayers is set
2002                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2003         }
2004 }
2005
2006 /**
2007  * Determines whether the player is allowed to join. This depends on cvar
2008  * g_maxplayers, if it isn't used this function always return true, otherwise
2009  * it checks whether the number of currently playing players exceeds g_maxplayers.
2010  * @return int number of free slots for players, 0 if none
2011  */
2012 float nJoinAllowed(entity ignore) {
2013         if(!ignore)
2014         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2015         // so report 0 free slots if restricted
2016         {
2017                 if(autocvar_g_forced_team_otherwise == "spectate")
2018                         return 0;
2019                 if(autocvar_g_forced_team_otherwise == "spectator")
2020                         return 0;
2021         }
2022
2023         if(self.team_forced < 0)
2024                 return 0; // forced spectators can never join
2025
2026         // TODO simplify this
2027         entity e;
2028         float totalClients = 0;
2029         FOR_EACH_CLIENT(e)
2030                 if(e != ignore)
2031                         totalClients += 1;
2032
2033         if (!autocvar_g_maxplayers)
2034                 return maxclients - totalClients;
2035
2036         float currentlyPlaying = 0;
2037         FOR_EACH_REALCLIENT(e)
2038                 if(IS_PLAYER(e) || e.caplayer)
2039                         currentlyPlaying += 1;
2040
2041         if(currentlyPlaying < autocvar_g_maxplayers)
2042                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2043
2044         return 0;
2045 }
2046
2047 /**
2048  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2049  * g_maxplayers_spectator_blocktime seconds
2050  */
2051 void checkSpectatorBlock() {
2052         if(IS_SPEC(self) || IS_OBSERVER(self))
2053         if(!self.caplayer)
2054         if(IS_REAL_CLIENT(self))
2055         {
2056                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2057                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2058                         dropclient(self);
2059                 }
2060         }
2061 }
2062
2063 void PrintWelcomeMessage()
2064 {
2065         if(self.motd_actived_time == 0)
2066         {
2067                 if (autocvar_g_campaign) {
2068                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2069                                 self.motd_actived_time = time;
2070                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2071                         }
2072                 } else {
2073                         if (self.BUTTON_INFO) {
2074                                 self.motd_actived_time = time;
2075                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2076                         }
2077                 }
2078         }
2079         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2080         {
2081                 if (autocvar_g_campaign) {
2082                         if (self.BUTTON_INFO)
2083                                 self.motd_actived_time = time;
2084                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2085                                 self.motd_actived_time = 0;
2086                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2087                         }
2088                 } else {
2089                         if (self.BUTTON_INFO)
2090                                 self.motd_actived_time = time;
2091                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2092                                 self.motd_actived_time = 0;
2093                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2094                         }
2095                 }
2096         }
2097         else //if(self.motd_actived_time < 0) // just connected, motd is active
2098         {
2099                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2100                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2101                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2102                 {
2103                         // instanctly hide MOTD
2104                         self.motd_actived_time = 0;
2105                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2106                 }
2107         }
2108 }
2109
2110 void ObserverThink()
2111 {
2112         if ( self.impulse )
2113         {
2114                 MinigameImpulse(self.impulse);
2115                 self.impulse = 0;
2116         }
2117         float prefered_movetype;
2118         if (self.flags & FL_JUMPRELEASED) {
2119                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2120                         self.flags &= ~FL_JUMPRELEASED;
2121                         self.flags |= FL_SPAWNING;
2122                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2123                         self.flags &= ~FL_JUMPRELEASED;
2124                         if(SpectateNext()) {
2125                                 self.classname = "spectator";
2126                         }
2127                 } else {
2128                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2129                         if (self.movetype != prefered_movetype)
2130                                 self.movetype = prefered_movetype;
2131                 }
2132         } else {
2133                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2134                         self.flags |= FL_JUMPRELEASED;
2135                         if(self.flags & FL_SPAWNING)
2136                         {
2137                                 self.flags &= ~FL_SPAWNING;
2138                                 LeaveSpectatorMode();
2139                                 return;
2140                         }
2141                 }
2142         }
2143 }
2144
2145 void SpectatorThink()
2146 {
2147         if ( self.impulse )
2148         {
2149                 if(MinigameImpulse(self.impulse))
2150                         self.impulse = 0;
2151         }
2152         if (self.flags & FL_JUMPRELEASED) {
2153                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2154                         self.flags &= ~FL_JUMPRELEASED;
2155                         self.flags |= FL_SPAWNING;
2156                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2157                         self.flags &= ~FL_JUMPRELEASED;
2158                         if(SpectateNext()) {
2159                                 self.classname = "spectator";
2160                         } else {
2161                                 self.classname = "observer";
2162                                 PutClientInServer();
2163                         }
2164                         self.impulse = 0;
2165                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2166                         self.flags &= ~FL_JUMPRELEASED;
2167                         if(SpectatePrev()) {
2168                                 self.classname = "spectator";
2169                         } else {
2170                                 self.classname = "observer";
2171                                 PutClientInServer();
2172                         }
2173                         self.impulse = 0;
2174                 } else if (self.BUTTON_ATCK2) {
2175                         self.flags &= ~FL_JUMPRELEASED;
2176                         self.classname = "observer";
2177                         PutClientInServer();
2178                 } else {
2179                         if(!SpectateUpdate())
2180                                 PutObserverInServer();
2181                 }
2182         } else {
2183                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2184                         self.flags |= FL_JUMPRELEASED;
2185                         if(self.flags & FL_SPAWNING)
2186                         {
2187                                 self.flags &= ~FL_SPAWNING;
2188                                 LeaveSpectatorMode();
2189                                 return;
2190                         }
2191                 }
2192                 if(!SpectateUpdate())
2193                         PutObserverInServer();
2194         }
2195
2196         self.flags |= FL_CLIENT | FL_NOTARGET;
2197 }
2198
2199 void vehicles_enter (entity pl, entity veh);
2200 void PlayerUseKey()
2201 {
2202         if (!IS_PLAYER(self))
2203                 return;
2204
2205         if(self.vehicle)
2206         {
2207                 if(!gameover)
2208                 {
2209                         vehicles_exit(VHEF_NORMAL);
2210                         return;
2211                 }
2212         }
2213         else if(autocvar_g_vehicles_enter)
2214         {
2215                 if(!self.frozen)
2216                 if(self.deadflag == DEAD_NO)
2217                 if(!gameover)
2218                 {
2219                         entity head, closest_target = world;
2220                         head = WarpZone_FindRadius(self.origin, autocvar_g_vehicles_enter_radius, TRUE);
2221
2222                         while(head) // find the closest acceptable target to enter
2223                         {
2224                                 if(head.vehicle_flags & VHF_ISVEHICLE)
2225                                 if(head.deadflag == DEAD_NO)
2226                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, self)))
2227                                 if(head.takedamage != DAMAGE_NO)
2228                                 {
2229                                         if(closest_target)
2230                                         {
2231                                                 if(vlen(self.origin - head.origin) < vlen(self.origin - closest_target.origin))
2232                                                 { closest_target = head; }
2233                                         }
2234                                         else { closest_target = head; }
2235                                 }
2236
2237                                 head = head.chain;
2238                         }
2239
2240                         if(closest_target) { vehicles_enter(self, closest_target); return; }
2241                 }
2242         }
2243
2244         // a use key was pressed; call handlers
2245         MUTATOR_CALLHOOK(PlayerUseKey);
2246 }
2247
2248 float isInvisibleString(string s)
2249 {
2250         float i, n, c;
2251         s = strdecolorize(s);
2252         for((i = 0), (n = strlen(s)); i < n; ++i)
2253         {
2254                 c = str2chr(s, i);
2255                 switch(c)
2256                 {
2257                         case 0:
2258                         case 32: // space
2259                                 break;
2260                         case 192: // charmap space
2261                                 if (!autocvar_utf8_enable)
2262                                         break;
2263                                 return false;
2264                         case 160: // space in unicode fonts
2265                         case 0xE000 + 192: // utf8 charmap space
2266                                 if (autocvar_utf8_enable)
2267                                         break;
2268                         default:
2269                                 return false;
2270                 }
2271         }
2272         return true;
2273 }
2274
2275 /*
2276 =============
2277 PlayerPreThink
2278
2279 Called every frame for each client before the physics are run
2280 =============
2281 */
2282 .float usekeypressed;
2283 void() nexball_setstatus;
2284 .float last_vehiclecheck;
2285 .int items_added;
2286 void PlayerPreThink (void)
2287 {
2288         WarpZone_PlayerPhysics_FixVAngle();
2289
2290         self.stat_game_starttime = game_starttime;
2291         self.stat_round_starttime = round_starttime;
2292         self.stat_allow_oldvortexbeam = autocvar_g_allow_oldvortexbeam;
2293         self.stat_leadlimit = autocvar_leadlimit;
2294
2295         self.weaponsinmap = weaponsInMap;
2296
2297         if(frametime)
2298         {
2299                 // physics frames: update anticheat stuff
2300                 anticheat_prethink();
2301         }
2302
2303         if(blockSpectators && frametime)
2304                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2305                 checkSpectatorBlock();
2306
2307         zoomstate_set = 0;
2308
2309         // Savage: Check for nameless players
2310         if (isInvisibleString(self.netname)) {
2311                 string new_name = strzone(strcat("Player@", self.netaddress));
2312                 if(autocvar_sv_eventlog)
2313                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", new_name));
2314                 if(self.netname_previous)
2315                         strunzone(self.netname_previous);
2316                 self.netname_previous = strzone(new_name);
2317                 self.netname = self.netname_previous;
2318                 // stuffcmd(self, strcat("name ", self.netname, "\n"));
2319         } else if(self.netname_previous != self.netname) {
2320                 if(autocvar_sv_eventlog)
2321                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2322                 if(self.netname_previous)
2323                         strunzone(self.netname_previous);
2324                 self.netname_previous = strzone(self.netname);
2325         }
2326
2327         // version nagging
2328         if(self.version_nagtime)
2329                 if(self.cvar_g_xonoticversion)
2330                         if(time > self.version_nagtime)
2331                         {
2332                                 // don't notify git users
2333                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2334                                 {
2335                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2336                                         {
2337                                                 // notify release users if connecting to git
2338                                                 LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2339                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2340                                         }
2341                                         else
2342                                         {
2343                                                 float r;
2344                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2345                                                 if(r < 0)
2346                                                 {
2347                                                         // give users new version
2348                                                         LOG_TRACE("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2349                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2350                                                 }
2351                                                 else if(r > 0)
2352                                                 {
2353                                                         // notify users about old server version
2354                                                         LOG_INFO("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2355                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2356                                                 }
2357                                         }
2358                                 }
2359                                 self.version_nagtime = 0;
2360                         }
2361
2362         // GOD MODE info
2363         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2364         {
2365                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2366                 self.max_armorvalue = 0;
2367         }
2368
2369         if(self.frozen == 2)
2370         {
2371                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2372                 self.health = max(1, self.revive_progress * start_health);
2373                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2374
2375                 if(self.revive_progress >= 1)
2376                         Unfreeze(self);
2377         }
2378         else if(self.frozen == 3)
2379         {
2380                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2381                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2382
2383                 if(self.health < 1)
2384                 {
2385                         if(self.vehicle)
2386                                 vehicles_exit(VHEF_RELEASE);
2387                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2388                 }
2389                 else if ( self.revive_progress <= 0 )
2390                         Unfreeze(self);
2391         }
2392
2393         MUTATOR_CALLHOOK(PlayerPreThink);
2394
2395         if(autocvar_g_vehicles_enter)
2396         if(time > self.last_vehiclecheck)
2397         if(IS_PLAYER(self))
2398         if(!gameover)
2399         if(!self.frozen)
2400         if(!self.vehicle)
2401         if(self.deadflag == DEAD_NO)
2402         {
2403                 entity veh;
2404                 for(veh = world; (veh = findflags(veh, vehicle_flags, VHF_ISVEHICLE)); )
2405                 if(vlen(veh.origin - self.origin) < autocvar_g_vehicles_enter_radius)
2406                 if(veh.deadflag == DEAD_NO)
2407                 if(veh.takedamage != DAMAGE_NO)
2408                 if((veh.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(veh.owner, self))
2409                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2410                 else if(!veh.owner)
2411                 if(!veh.team || SAME_TEAM(self, veh))
2412                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER);
2413                 else if(autocvar_g_vehicles_steal)
2414                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2415
2416                 self.last_vehiclecheck = time + 1;
2417         }
2418
2419         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2420         {
2421                 if(self.BUTTON_USE && !self.usekeypressed)
2422                         PlayerUseKey();
2423                 self.usekeypressed = self.BUTTON_USE;
2424         }
2425
2426         if(IS_REAL_CLIENT(self))
2427                 PrintWelcomeMessage();
2428
2429         if(IS_PLAYER(self))
2430         {
2431
2432                 CheckRules_Player();
2433
2434                 if (intermission_running)
2435                 {
2436                         IntermissionThink ();   // otherwise a button could be missed between
2437                         return;                                 // the think tics
2438                 }
2439
2440                 //don't allow the player to turn around while game is paused!
2441                 if(timeout_status == TIMEOUT_ACTIVE) {
2442                         // FIXME turn this into CSQC stuff
2443                         self.v_angle = self.lastV_angle;
2444                         self.angles = self.lastV_angle;
2445                         self.fixangle = true;
2446                 }
2447
2448                 if(frametime)
2449                 {
2450                         if(self.weapon == WEP_VORTEX.m_id && WEP_CVAR(vortex, charge))
2451                         {
2452                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2453                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2454                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.vortex_charge / WEP_CVAR(vortex, charge_animlimit));
2455
2456                                 if(self.vortex_charge > WEP_CVAR(vortex, charge_animlimit))
2457                                 {
2458                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod.x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2459                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod.y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2460                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod.z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.vortex_charge - WEP_CVAR(vortex, charge_animlimit)) / (1 - WEP_CVAR(vortex, charge_animlimit));
2461                                 }
2462                         }
2463                         else
2464                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, true) * 2;
2465
2466                         player_powerups();
2467                 }
2468
2469                 if (self.deadflag != DEAD_NO)
2470                 {
2471                         if(self.personal && g_race_qualifying)
2472                         {
2473                                 if(time > self.respawn_time)
2474                                 {
2475                                         self.respawn_time = time + 1; // only retry once a second
2476                                         self.stat_respawn_time = self.respawn_time;
2477                                         respawn();
2478                                         self.impulse = 141;
2479                                 }
2480                         }
2481                         else
2482                         {
2483                                 float button_pressed;
2484                                 if(frametime)
2485                                         player_anim();
2486                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2487
2488                                 if (self.deadflag == DEAD_DYING)
2489                                 {
2490                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2491                                                 self.deadflag = DEAD_RESPAWNING;
2492                                         else if(!button_pressed)
2493                                                 self.deadflag = DEAD_DEAD;
2494                                 }
2495                                 else if (self.deadflag == DEAD_DEAD)
2496                                 {
2497                                         if(button_pressed)
2498                                                 self.deadflag = DEAD_RESPAWNABLE;
2499                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2500                                                 self.deadflag = DEAD_RESPAWNING;
2501                                 }
2502                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2503                                 {
2504                                         if(!button_pressed)
2505                                                 self.deadflag = DEAD_RESPAWNING;
2506                                 }
2507                                 else if (self.deadflag == DEAD_RESPAWNING)
2508                                 {
2509                                         if(time > self.respawn_time)
2510                                         {
2511                                                 self.respawn_time = time + 1; // only retry once a second
2512                                                 self.respawn_time_max = self.respawn_time;
2513                                                 respawn();
2514                                         }
2515                                 }
2516
2517                                 ShowRespawnCountdown();
2518
2519                                 if(self.respawn_flags & RESPAWN_SILENT)
2520                                         self.stat_respawn_time = 0;
2521                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2522                                         self.stat_respawn_time = self.respawn_time_max;
2523                                 else
2524                                         self.stat_respawn_time = self.respawn_time;
2525                         }
2526
2527                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2528                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2529                                 self.stat_respawn_time *= -1;
2530
2531                         return;
2532                 }
2533
2534                 self.prevorigin = self.origin;
2535
2536                 float do_crouch = self.BUTTON_CROUCH;
2537                 if(self.hook.state)
2538                         do_crouch = 0;
2539                 if(self.vehicle)
2540                         do_crouch = 0;
2541                 if(self.frozen)
2542                         do_crouch = 0;
2543
2544                 // WEAPONTODO: THIS SHIT NEEDS TO GO EVENTUALLY
2545                 // It cannot be predicted by the engine!
2546                 if((self.weapon == WEP_SHOCKWAVE.m_id || self.weapon == WEP_SHOTGUN.m_id) && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2547                         do_crouch = 0;
2548
2549                 if (do_crouch)
2550                 {
2551                         if (!self.crouch)
2552                         {
2553                                 self.crouch = true;
2554                                 self.view_ofs = self.stat_pl_crouch_view_ofs;
2555                                 setsize (self, self.stat_pl_crouch_min, self.stat_pl_crouch_max);
2556                                 // setanim(self, self.anim_duck, false, true, true); // this anim is BROKEN anyway
2557                         }
2558                 }
2559                 else
2560                 {
2561                         if (self.crouch)
2562                         {
2563                                 tracebox(self.origin, self.stat_pl_min, self.stat_pl_max, self.origin, false, self);
2564                                 if (!trace_startsolid)
2565                                 {
2566                                         self.crouch = false;
2567                                         self.view_ofs = self.stat_pl_view_ofs;
2568                                         setsize (self, self.stat_pl_min, self.stat_pl_max);
2569                                 }
2570                         }
2571                 }
2572
2573                 FixPlayermodel();
2574
2575                 GrapplingHookFrame();
2576
2577                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2578                 //if(frametime)
2579                 {
2580                         self.items &= ~self.items_added;
2581
2582                         W_WeaponFrame();
2583
2584                         self.items_added = 0;
2585                         if(self.items & ITEM_Jetpack.m_itemid)
2586                                 if(self.items & ITEM_JetpackRegen.m_itemid || self.ammo_fuel >= 0.01)
2587                                         self.items_added |= IT_FUEL;
2588
2589                         self.items |= self.items_added;
2590                 }
2591
2592                 player_regen();
2593
2594                 // WEAPONTODO: Add a weapon request for this
2595                 // rot vortex charge to the charge limit
2596                 if(WEP_CVAR(vortex, charge_rot_rate) && self.vortex_charge > WEP_CVAR(vortex, charge_limit) && self.vortex_charge_rottime < time)
2597                         self.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), self.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2598
2599                 if(frametime)
2600                         player_anim();
2601
2602                 // secret status
2603                 secrets_setstatus();
2604
2605                 // monsters status
2606                 monsters_setstatus();
2607
2608                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2609
2610                 //self.angles_y=self.v_angle_y + 90;   // temp
2611         } else if(gameover) {
2612                 if (intermission_running)
2613                         IntermissionThink ();   // otherwise a button could be missed between
2614                 return;
2615         } else if(IS_OBSERVER(self)) {
2616                 ObserverThink();
2617         } else if(IS_SPEC(self)) {
2618                 SpectatorThink();
2619         }
2620
2621         // WEAPONTODO: Add weapon request for this
2622         if(!zoomstate_set)
2623                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_VORTEX.m_id) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE.m_id && WEP_CVAR(rifle, secondary) == 0)); // WEAPONTODO
2624
2625         float oldspectatee_status;
2626         oldspectatee_status = self.spectatee_status;
2627         if(IS_SPEC(self))
2628                 self.spectatee_status = num_for_edict(self.enemy);
2629         else if(IS_OBSERVER(self))
2630                 self.spectatee_status = num_for_edict(self);
2631         else
2632                 self.spectatee_status = 0;
2633         if(self.spectatee_status != oldspectatee_status)
2634         {
2635                 ClientData_Touch(self);
2636         }
2637
2638         if(self.teamkill_soundtime)
2639         if(time > self.teamkill_soundtime)
2640         {
2641                 self.teamkill_soundtime = 0;
2642
2643                 entity oldpusher, oldself;
2644
2645                 oldself = self; self = self.teamkill_soundsource;
2646                 oldpusher = self.pusher; self.pusher = oldself;
2647
2648                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2649
2650                 self.pusher = oldpusher;
2651                 self = oldself;
2652         }
2653
2654         if(self.taunt_soundtime)
2655         if(time > self.taunt_soundtime)
2656         {
2657                 self.taunt_soundtime = 0;
2658                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2659         }
2660
2661         target_voicescript_next(self);
2662
2663         // WEAPONTODO: Move into weaponsystem somehow
2664         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2665         if(!self.weapon)
2666                 self.clip_load = self.clip_size = 0;
2667 }
2668
2669 /*
2670 =============
2671 PlayerPostThink
2672
2673 Called every frame for each client after the physics are run
2674 =============
2675 */
2676 .float idlekick_lasttimeleft;
2677 void PlayerPostThink (void)
2678 {
2679         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2680         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2681         {
2682                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2683                 {
2684                         if(self.idlekick_lasttimeleft)
2685                         {
2686                                 self.idlekick_lasttimeleft = 0;
2687                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2688                         }
2689                 }
2690                 else
2691                 {
2692                         float timeleft;
2693                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2694                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2695                         {
2696                                 if(!self.idlekick_lasttimeleft)
2697                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2698                         }
2699                         if(timeleft <= 0)
2700                         {
2701                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2702                                 dropclient(self);
2703                                 return;
2704                         }
2705                         else if(timeleft <= 10)
2706                         {
2707                                 if(timeleft != self.idlekick_lasttimeleft)
2708                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2709                                 self.idlekick_lasttimeleft = timeleft;
2710                         }
2711                 }
2712         }
2713
2714         CheatFrame();
2715
2716         //CheckPlayerJump();
2717
2718         if(IS_PLAYER(self)) {
2719                 CheckRules_Player();
2720                 UpdateChatBubble();
2721                 if (self.impulse)
2722                         ImpulseCommands();
2723                 if (intermission_running)
2724                         return;         // intermission or finale
2725                 GetPressedKeys();
2726         }
2727
2728         /*
2729         float i;
2730         for(i = 0; i < 1000; ++i)
2731         {
2732                 vector end;
2733                 end = self.origin + '0 0 1024' + 512 * randomvec();
2734                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2735                 if(trace_fraction < 1)
2736                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2737                 {
2738                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2739                         break;
2740                 }
2741         }
2742         */
2743
2744         if(self.waypointsprite_attachedforcarrier)
2745                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2746
2747         playerdemo_write();
2748
2749         CSQCMODEL_AUTOUPDATE();
2750 }