qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(to.classname == "spectator")
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(e2.classname == "spectator")
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77
  78 .vector spawnpoint_score;
  79 .string netname_previous;
  80
  81 void spawnfunc_info_player_survivor (void)
  82 {
  83         spawnfunc_info_player_deathmatch();
  84 }
  85
  86 void spawnfunc_info_player_start (void)
  87 {
  88         spawnfunc_info_player_deathmatch();
  89 }
  90
  91 void spawnfunc_info_player_deathmatch (void)
  92 {
  93         self.classname = "info_player_deathmatch";
  94         relocate_spawnpoint();
  95 }
  96
  97 void spawnpoint_use()
  98 {
  99         if(teamplay)
 100         if(have_team_spawns > 0)
 101         {
 102                 self.team = activator.team;
 103                 some_spawn_has_been_used = 1;
 104         }
 105 }
 106
 107 // Returns:
 108 //   _x: prio (-1 if unusable)
 109 //   _y: weight
 110 vector Spawn_Score(entity spot, float mindist, float teamcheck)
 111 {
 112         float shortest, thisdist;
 113         float prio;
 114         entity player;
 115
 116         prio = 0;
 117
 118         // filter out spots for the wrong team
 119         if(teamcheck >= 0)
 120                 if(spot.team != teamcheck)
 121                         return '-1 0 0';
 122
 123         if(race_spawns)
 124                 if(spot.target == "")
 125                         return '-1 0 0';
 126
 127         if(clienttype(self) == CLIENTTYPE_REAL)
 128         {
 129                 if(spot.restriction == 1)
 130                         return '-1 0 0';
 131         }
 132         else
 133         {
 134                 if(spot.restriction == 2)
 135                         return '-1 0 0';
 136         }
 137
 138         shortest = vlen(world.maxs - world.mins);
 139         FOR_EACH_PLAYER(player) if (player != self)
 140         {
 141                 thisdist = vlen(player.origin - spot.origin);
 142                 if (thisdist < shortest)
 143                         shortest = thisdist;
 144         }
 145         if(shortest > mindist)
 146                 prio += SPAWN_PRIO_GOOD_DISTANCE;
 147
 148         spawn_score = prio * '1 0 0' + shortest * '0 1 0';
 149         spawn_spot = spot;
 150
 151         // filter out spots for assault
 152         if(spot.target != "") {
 153                 entity ent;
 154                 float found;
 155
 156                 found = 0;
 157                 for(ent = world; (ent = find(ent, targetname, spot.target)); )
 158                 {
 159                         ++found;
 160                         if(ent.spawn_evalfunc)
 161                         {
 162                                 entity oldself = self;
 163                                 self = ent;
 164                                 spawn_score = ent.spawn_evalfunc(oldself, spot, spawn_score);
 165                                 self = oldself;
 166                                 if(spawn_score_x < 0)
 167                                         return spawn_score;
 168                         }
 169                 }
 170
 171                 if(!found)
 172                 {
 173                         dprint("WARNING: spawnpoint at ", vtos(spot.origin), " could not find its target ", spot.target, "\n");
 174                         return '-1 0 0';
 175                 }
 176         }
 177
 178         MUTATOR_CALLHOOK(Spawn_Score);
 179         return spawn_score;
 180 }
 181
 182 void Spawn_ScoreAll(entity firstspot, float mindist, float teamcheck)
 183 {
 184         entity spot;
 185         for(spot = firstspot; spot; spot = spot.chain)
 186                 spot.spawnpoint_score = Spawn_Score(spot, mindist, teamcheck);
 187 }
 188
 189 entity Spawn_FilterOutBadSpots(entity firstspot, float mindist, float teamcheck)
 190 {
 191         entity spot, spotlist, spotlistend;
 192
 193         spotlist = world;
 194         spotlistend = world;
 195
 196         Spawn_ScoreAll(firstspot, mindist, teamcheck);
 197
 198         for(spot = firstspot; spot; spot = spot.chain)
 199         {
 200                 if(spot.spawnpoint_score_x >= 0) // spawning allowed here
 201                 {
 202                         if(spotlistend)
 203                                 spotlistend.chain = spot;
 204                         spotlistend = spot;
 205                         if(!spotlist)
 206                                 spotlist = spot;
 207                 }
 208         }
 209         if(spotlistend)
 210                 spotlistend.chain = world;
 211
 212         return spotlist;
 213 }
 214
 215 entity Spawn_WeightedPoint(entity firstspot, float lower, float upper, float exponent)
 216 {
 217         // weight of a point: bound(lower, mindisttoplayer, upper)^exponent
 218         // multiplied by spot.cnt (useful if you distribute many spawnpoints in a small area)
 219         entity spot;
 220
 221         RandomSelection_Init();
 222         for(spot = firstspot; spot; spot = spot.chain)
 223                 RandomSelection_Add(spot, 0, string_null, pow(bound(lower, spot.spawnpoint_score_y, upper), exponent) * spot.cnt, (spot.spawnpoint_score_y >= lower) * 0.5 + spot.spawnpoint_score_x);
 224
 225         return RandomSelection_chosen_ent;
 226 }
 227
 228 /*
 229 =============
 230 SelectSpawnPoint
 231
 232 Finds a point to respawn
 233 =============
 234 */
 235 entity SelectSpawnPoint (float anypoint)
 236 {
 237         float teamcheck;
 238         entity spot, firstspot;
 239
 240         spot = find (world, classname, "testplayerstart");
 241         if (spot)
 242                 return spot;
 243
 244         if(anypoint || autocvar_g_spawn_useallspawns)
 245                 teamcheck = -1;
 246         else if(have_team_spawns > 0)
 247         {
 248                 if(have_team_spawns_forteam[self.team] == 0)
 249                 {
 250                         // we request a spawn for a team, and we have team
 251                         // spawns, but that team has no spawns?
 252                         if(have_team_spawns_forteam[0])
 253                                 // try noteam spawns
 254                                 teamcheck = 0;
 255                         else
 256                                 // if not, any spawn has to do
 257                                 teamcheck = -1;
 258                 }
 259                 else
 260                         teamcheck = self.team; // MUST be team
 261         }
 262         else if(have_team_spawns == 0 && have_team_spawns_forteam[0])
 263                 teamcheck = 0; // MUST be noteam
 264         else
 265                 teamcheck = -1;
 266                 // if we get here, we either require team spawns but have none, or we require non-team spawns and have none; use any spawn then
 267
 268
 269         // get the entire list of spots
 270         firstspot = findchain(classname, "info_player_deathmatch");
 271         // filter out the bad ones
 272         // (note this returns the original list if none survived)
 273         if(anypoint)
 274         {
 275                 spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 276         }
 277         else
 278         {
 279                 float mindist;
 280                 if (arena_roundbased && !g_ca)
 281                         mindist = 800;
 282                 else
 283                         mindist = 100;
 284                 firstspot = Spawn_FilterOutBadSpots(firstspot, mindist, teamcheck);
 285
 286                 // there is 50/50 chance of choosing a random spot or the furthest spot
 287                 // (this means that roughly every other spawn will be furthest, so you
 288                 // usually won't get fragged at spawn twice in a row)
 289                 if (random() > autocvar_g_spawn_furthest)
 290                         spot = Spawn_WeightedPoint(firstspot, 1, 1, 1);
 291                 else
 292                         spot = Spawn_WeightedPoint(firstspot, 1, 5000, 5); // chooses a far far away spawnpoint
 293         }
 294
 295         if (!spot)
 296         {
 297                 if(autocvar_spawn_debug)
 298                         GotoNextMap(0);
 299                 else
 300                 {
 301                         if(some_spawn_has_been_used)
 302                                 return world; // team can't spawn any more, because of actions of other team
 303                         else
 304                                 error("Cannot find a spawn point - please fix the map!");
 305                 }
 306         }
 307
 308         return spot;
 309 }
 310
 311 /*
 312 =============
 313 CheckPlayerModel
 314
 315 Checks if the argument string can be a valid playermodel.
 316 Returns a valid one in doubt.
 317 =============
 318 */
 319 string FallbackPlayerModel;
 320 string CheckPlayerModel(string plyermodel) {
 321         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 322         {
 323                 // note: we cannot summon Don Strunzone here, some player may
 324                 // still have the model string set. In case anyone manages how
 325                 // to change a cvar default, we'll have a small leak here.
 326                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 327         }
 328         // only in right path
 329         if( substring(plyermodel,0,14) != "models/player/")
 330                 return FallbackPlayerModel;
 331         // only good file extensions
 332         if(substring(plyermodel,-4,4) != ".zym")
 333         if(substring(plyermodel,-4,4) != ".dpm")
 334         if(substring(plyermodel,-4,4) != ".iqm")
 335         if(substring(plyermodel,-4,4) != ".md3")
 336         if(substring(plyermodel,-4,4) != ".psk")
 337                 return FallbackPlayerModel;
 338         // forbid the LOD models
 339         if(substring(plyermodel, -9,5) == "_lod1")
 340                 return FallbackPlayerModel;
 341         if(substring(plyermodel, -9,5) == "_lod2")
 342                 return FallbackPlayerModel;
 343         if(plyermodel != strtolower(plyermodel))
 344                 return FallbackPlayerModel;
 345         // also, restrict to server models
 346         if(autocvar_sv_servermodelsonly)
 347         {
 348                 if(!fexists(plyermodel))
 349                         return FallbackPlayerModel;
 350         }
 351         return plyermodel;
 352 }
 353
 354 void setplayermodel(entity e, string modelname)
 355 {
 356         precache_model(modelname);
 357         setmodel(e, modelname);
 358         player_setupanimsformodel();
 359         UpdatePlayerSounds();
 360 }
 361
 362 /*
 363 =============
 364 PutObserverInServer
 365
 366 putting a client as observer in the server
 367 =============
 368 */
 369 void FixPlayermodel();
 370 void PutObserverInServer (void)
 371 {
 372         entity  spot;
 373     self.hud = HUD_NORMAL;
 374         race_PreSpawnObserver();
 375
 376         spot = SelectSpawnPoint (TRUE);
 377         if(!spot)
 378                 error("No spawnpoints for observers?!?\n");
 379         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 380
 381         if(clienttype(self) == CLIENTTYPE_REAL)
 382         {
 383                 msg_entity = self;
 384                 WriteByte(MSG_ONE, SVC_SETVIEW);
 385                 WriteEntity(MSG_ONE, self);
 386         }
 387
 388         MUTATOR_CALLHOOK(MakePlayerObserver);
 389
 390         minstagib_stop_countdown(self);
 391
 392         Portal_ClearAll(self);
 393
 394         Unfreeze(self);
 395
 396         if(self.alivetime)
 397         {
 398                 if(!inWarmupStage)
 399                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 400                 self.alivetime = 0;
 401         }
 402
 403         if(self.vehicle)
 404                 vehicles_exit(VHEF_RELESE);
 405
 406         WaypointSprite_PlayerDead();
 407
 408         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 409                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 410
 411         if(self.killcount != -666) {
 412                 if(g_lms) {
 413                         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0 && self.lms_spectate_warning != 2)
 414                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, self.netname);
 415                         else
 416                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, self.netname);
 417                 } else { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname); }
 418
 419                 if(self.just_joined == FALSE) {
 420                         LogTeamchange(self.playerid, -1, 4);
 421                 } else
 422                         self.just_joined = FALSE;
 423         }
 424
 425         PlayerScore_Clear(self); // clear scores when needed
 426
 427         accuracy_resend(self);
 428
 429         self.spectatortime = time;
 430
 431         self.classname = "observer";
 432         self.iscreature = FALSE;
 433         self.teleportable = TELEPORT_SIMPLE;
 434         self.damagedbycontents = FALSE;
 435         self.health = -666;
 436         self.takedamage = DAMAGE_NO;
 437         self.solid = SOLID_NOT;
 438         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 439         self.flags = FL_CLIENT | FL_NOTARGET;
 440         self.armorvalue = 666;
 441         self.effects = 0;
 442         self.armorvalue = autocvar_g_balance_armor_start;
 443         self.pauserotarmor_finished = 0;
 444         self.pauserothealth_finished = 0;
 445         self.pauseregen_finished = 0;
 446         self.damageforcescale = 0;
 447         self.death_time = 0;
 448         self.respawn_time = 0;
 449         self.alpha = 0;
 450         self.scale = 0;
 451         self.fade_time = 0;
 452         self.pain_frame = 0;
 453         self.pain_finished = 0;
 454         self.strength_finished = 0;
 455         self.invincible_finished = 0;
 456         self.superweapons_finished = 0;
 457         self.pushltime = 0;
 458         self.istypefrag = 0;
 459         self.think = func_null;
 460         self.nextthink = 0;
 461         self.hook_time = 0;
 462         self.deadflag = DEAD_NO;
 463         self.angles = spot.angles;
 464         self.angles_z = 0;
 465         self.fixangle = TRUE;
 466         self.crouch = FALSE;
 467
 468         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 469         self.prevorigin = self.origin;
 470         self.items = 0;
 471         WEPSET_CLEAR_E(self);
 472         self.model = "";
 473         FixPlayermodel();
 474         setmodel(self, "null");
 475         self.drawonlytoclient = self;
 476
 477         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 478         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 479
 480         self.weapon = 0;
 481         self.weaponname = "";
 482         self.switchingweapon = 0;
 483         self.weaponmodel = "";
 484         self.weaponentity = world;
 485         self.exteriorweaponentity = world;
 486         self.killcount = -666;
 487         self.velocity = '0 0 0';
 488         self.avelocity = '0 0 0';
 489         self.punchangle = '0 0 0';
 490         self.punchvector = '0 0 0';
 491         self.oldvelocity = self.velocity;
 492         self.fire_endtime = -1;
 493
 494         if(g_arena)
 495         {
 496                 if(self.version_mismatch)
 497                 {
 498                         self.frags = FRAGS_SPECTATOR;
 499                         Spawnqueue_Unmark(self);
 500                         Spawnqueue_Remove(self);
 501                 }
 502                 else
 503                 {
 504                         self.frags = FRAGS_LMS_LOSER;
 505                         Spawnqueue_Insert(self);
 506                 }
 507         }
 508         else if(g_lms)
 509         {
 510                 // Only if the player cannot play at all
 511                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) == 666)
 512                         self.frags = FRAGS_SPECTATOR;
 513                 else
 514                         self.frags = FRAGS_LMS_LOSER;
 515         }
 516         else if(g_ca)
 517         {
 518                 if(self.caplayer)
 519                         self.frags = FRAGS_LMS_LOSER;
 520                 else
 521                         self.frags = FRAGS_SPECTATOR;
 522         }
 523         else if((g_race && g_race_qualifying) || g_cts)
 524         {
 525                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 526                         self.frags = FRAGS_LMS_LOSER;
 527                 else
 528                         self.frags = FRAGS_SPECTATOR;
 529         }
 530         else
 531                 self.frags = FRAGS_SPECTATOR;
 532 }
 533
 534 .float model_randomizer;
 535 void FixPlayermodel()
 536 {
 537         string defaultmodel;
 538         float defaultskin, chmdl, oldskin, n, i;
 539         vector m1, m2;
 540
 541         defaultmodel = "";
 542         defaultskin = 0;
 543         chmdl = FALSE;
 544
 545         if(autocvar_sv_defaultcharacter == 1)
 546         {
 547                 if(teamplay)
 548                 {
 549                         string s;
 550                         s = Team_ColorName_Lower(self.team);
 551                         if(s != "neutral")
 552                         {
 553                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 554                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 555                         }
 556                 }
 557
 558                 if(defaultmodel == "")
 559                 {
 560                         defaultmodel = autocvar_sv_defaultplayermodel;
 561                         defaultskin = autocvar_sv_defaultplayerskin;
 562                 }
 563
 564                 n = tokenize_console(defaultmodel);
 565                 if(n > 0)
 566                         defaultmodel = argv(floor(n * self.model_randomizer));
 567
 568                 i = strstrofs(defaultmodel, ":", 0);
 569                 if(i >= 0)
 570                 {
 571                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 572                         defaultmodel = substring(defaultmodel, 0, i);
 573                 }
 574         }
 575
 576         if(defaultmodel != "")
 577         {
 578                 if (defaultmodel != self.model)
 579                 {
 580                         m1 = self.mins;
 581                         m2 = self.maxs;
 582                         setplayermodel (self, defaultmodel);
 583                         setsize (self, m1, m2);
 584                         chmdl = TRUE;
 585                 }
 586
 587                 oldskin = self.skin;
 588                 self.skin = defaultskin;
 589         } else {
 590                 if (self.playermodel != self.model || self.playermodel == "")
 591                 {
 592                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 593                         m1 = self.mins;
 594                         m2 = self.maxs;
 595                         setplayermodel (self, self.playermodel);
 596                         setsize (self, m1, m2);
 597                         chmdl = TRUE;
 598                 }
 599
 600                 oldskin = self.skin;
 601                 self.skin = stof(self.playerskin);
 602         }
 603
 604         if(chmdl || oldskin != self.skin) // model or skin has changed
 605         {
 606                 self.species = player_getspecies(); // update species
 607                 UpdatePlayerSounds(); // update skin sounds
 608         }
 609
 610         if(!teamplay)
 611                 if(strlen(autocvar_sv_defaultplayercolors))
 612                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 613                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 614 }
 615
 616 /*
 617 =============
 618 PutClientInServer
 619
 620 Called when a client spawns in the server
 621 =============
 622 */
 623
 624 void PutClientInServer (void)
 625 {
 626         if(clienttype(self) == CLIENTTYPE_BOT)
 627         {
 628                 self.classname = "player";
 629                 if(g_ca)
 630                         self.caplayer = 1;
 631         }
 632         else if(clienttype(self) == CLIENTTYPE_REAL)
 633         {
 634                 msg_entity = self;
 635                 WriteByte(MSG_ONE, SVC_SETVIEW);
 636                 WriteEntity(MSG_ONE, self);
 637         }
 638
 639         // reset player keys
 640         self.itemkeys = 0;
 641
 642         // player is dead and becomes observer
 643         // FIXME fix LMS scoring for new system
 644         if(g_lms)
 645         {
 646                 if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 647                         self.classname = "observer";
 648         }
 649
 650         if((g_arena && !self.spawned) || (g_ca && !allowed_to_spawn))
 651                 self.classname = "observer";
 652
 653         if(gameover)
 654                 self.classname = "observer";
 655
 656         if(self.classname == "player" && (!g_ca || (g_ca && allowed_to_spawn))) {
 657                 entity spot, oldself;
 658                 float j;
 659
 660                 accuracy_resend(self);
 661
 662                 if(self.team < 0)
 663                         JoinBestTeam(self, FALSE, TRUE);
 664
 665                 race_PreSpawn();
 666
 667                 spot = SelectSpawnPoint (FALSE);
 668                 if(!spot)
 669                 {
 670                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 671                         return; // spawn failed
 672                 }
 673
 674                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 675
 676                 self.classname = "player";
 677                 self.wasplayer = TRUE;
 678                 self.iscreature = TRUE;
 679                 self.teleportable = TELEPORT_NORMAL;
 680                 self.damagedbycontents = TRUE;
 681                 self.movetype = MOVETYPE_WALK;
 682                 self.solid = SOLID_SLIDEBOX;
 683                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 684                 if(autocvar_g_playerclip_collisions)
 685                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 686                 if(clienttype(self) == CLIENTTYPE_BOT && autocvar_g_botclip_collisions)
 687                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 688                 self.frags = FRAGS_PLAYER;
 689                 if(INDEPENDENT_PLAYERS)
 690                         MAKE_INDEPENDENT_PLAYER(self);
 691                 self.flags = FL_CLIENT;
 692                 if(autocvar__notarget)
 693                         self.flags |= FL_NOTARGET;
 694                 self.takedamage = DAMAGE_AIM;
 695                 if(g_minstagib)
 696                         self.effects = EF_FULLBRIGHT;
 697                 else
 698                         self.effects = 0;
 699                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 700                 self.air_finished = time + 12;
 701                 self.dmg = 2;
 702                 if(autocvar_g_balance_nex_charge)
 703                 {
 704                         if(autocvar_g_balance_nex_secondary_chargepool)
 705                                 self.nex_chargepool_ammo = 1;
 706                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 707                 }
 708
 709                 if(inWarmupStage)
 710                 {
 711                         self.ammo_shells = warmup_start_ammo_shells;
 712                         self.ammo_nails = warmup_start_ammo_nails;
 713                         self.ammo_rockets = warmup_start_ammo_rockets;
 714                         self.ammo_cells = warmup_start_ammo_cells;
 715                         self.ammo_fuel = warmup_start_ammo_fuel;
 716                         self.health = warmup_start_health;
 717                         self.armorvalue = warmup_start_armorvalue;
 718                         WEPSET_COPY_EA(self, warmup_start_weapons);
 719                 }
 720                 else
 721                 {
 722                         self.ammo_shells = start_ammo_shells;
 723                         self.ammo_nails = start_ammo_nails;
 724                         self.ammo_rockets = start_ammo_rockets;
 725                         self.ammo_cells = start_ammo_cells;
 726                         self.ammo_fuel = start_ammo_fuel;
 727                         self.health = start_health;
 728                         self.armorvalue = start_armorvalue;
 729                         WEPSET_COPY_EA(self, start_weapons);
 730                 }
 731
 732                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 733                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 734                 else
 735                         self.superweapons_finished = 0;
 736
 737                 if(g_weaponarena_random)
 738                 {
 739                         if(g_weaponarena_random_with_laser)
 740                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 741                         W_RandomWeapons(self, g_weaponarena_random);
 742                         if(g_weaponarena_random_with_laser)
 743                                 WEPSET_OR_EW(self, WEP_LASER);
 744                 }
 745
 746                 self.items = start_items;
 747
 748                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 749                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 750                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 751                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 752                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 753                 //extend the pause of rotting if client was reset at the beginning of the countdown
 754                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 755                         self.spawnshieldtime += game_starttime - time;
 756                         self.pauserotarmor_finished += game_starttime - time;
 757                         self.pauserothealth_finished += game_starttime - time;
 758                         self.pauseregen_finished += game_starttime - time;
 759                 }
 760                 self.damageforcescale = 2;
 761                 self.death_time = 0;
 762                 self.respawn_time = 0;
 763                 self.scale = 0;
 764                 self.fade_time = 0;
 765                 self.pain_frame = 0;
 766                 self.pain_finished = 0;
 767                 self.strength_finished = 0;
 768                 self.invincible_finished = 0;
 769                 self.pushltime = 0;
 770                 // players have no think function
 771                 self.think = func_null;
 772                 self.nextthink = 0;
 773                 self.hook_time = 0;
 774                 self.dmg_team = 0;
 775                 self.ballistics_density = autocvar_g_ballistics_density_player;
 776
 777                 self.metertime = 0;
 778
 779                 self.deadflag = DEAD_NO;
 780
 781                 self.angles = spot.angles;
 782
 783                 self.angles_z = 0; // never spawn tilted even if the spot says to
 784                 self.fixangle = TRUE; // turn this way immediately
 785                 self.velocity = '0 0 0';
 786                 self.avelocity = '0 0 0';
 787                 self.punchangle = '0 0 0';
 788                 self.punchvector = '0 0 0';
 789                 self.oldvelocity = self.velocity;
 790                 self.fire_endtime = -1;
 791
 792                 msg_entity = self;
 793                 WRITESPECTATABLE_MSG_ONE({
 794                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 795                         WriteByte(MSG_ONE, TE_CSQC_SPAWN);
 796                 });
 797
 798                 self.model = "";
 799                 FixPlayermodel();
 800                 self.drawonlytoclient = world;
 801
 802                 self.crouch = FALSE;
 803                 self.view_ofs = PL_VIEW_OFS;
 804                 setsize (self, PL_MIN, PL_MAX);
 805                 self.spawnorigin = spot.origin;
 806                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 807                 // don't reset back to last position, even if new position is stuck in solid
 808                 self.oldorigin = self.origin;
 809                 self.prevorigin = self.origin;
 810                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 811                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 812         self.hud = HUD_NORMAL;
 813
 814                 if(g_arena)
 815                 {
 816                         Spawnqueue_Remove(self);
 817                         Spawnqueue_Mark(self);
 818                 }
 819                 else if(g_ca)
 820                         self.caplayer = 1;
 821
 822                 self.event_damage = PlayerDamage;
 823
 824                 self.bot_attack = TRUE;
 825                 self.monster_attack = TRUE;
 826
 827                 self.statdraintime = time + 5;
 828                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 829
 830                 if(self.killcount == -666) {
 831                         PlayerScore_Clear(self);
 832                         self.killcount = 0;
 833                 }
 834
 835                 CL_SpawnWeaponentity();
 836                 self.alpha = default_player_alpha;
 837                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 838                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 839
 840                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
 841                 self.lms_traveled_distance = 0;
 842                 self.speedrunning = FALSE;
 843
 844                 race_PostSpawn(spot);
 845
 846                 //stuffcmd(self, "chase_active 0");
 847                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 848
 849                 if(g_assault) {
 850                         if(self.team == assault_attacker_team)
 851                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_ATTACKING);
 852                         else
 853                                 Send_Notification(NOTIF_TEAM, self, MSG_CENTER, CENTER_ASSAULT_DEFENDING);
 854                 }
 855
 856                 target_voicescript_clear(self);
 857
 858                 // reset fields the weapons may use
 859                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 860                 {
 861                         weapon_action(j, WR_RESETPLAYER);
 862
 863                         // all weapons must be fully loaded when we spawn
 864                         entity e;
 865                         e = get_weaponinfo(j);
 866                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 867                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 868                 }
 869
 870                 oldself = self;
 871                 self = spot;
 872                         activator = oldself;
 873                                 string s;
 874                                 s = self.target;
 875                                 self.target = string_null;
 876                                 SUB_UseTargets();
 877                                 self.target = s;
 878                         activator = world;
 879                 self = oldself;
 880
 881                 Unfreeze(self);
 882
 883                 spawn_spot = spot;
 884                 MUTATOR_CALLHOOK(PlayerSpawn);
 885
 886                 if(autocvar_spawn_debug)
 887                 {
 888                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 889                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 890                 }
 891
 892                 self.switchweapon = w_getbestweapon(self);
 893                 self.cnt = -1; // W_LastWeapon will not complain
 894                 self.weapon = 0;
 895                 self.weaponname = "";
 896                 self.switchingweapon = 0;
 897
 898                 if(!inWarmupStage)
 899                         if(!self.alivetime)
 900                                 self.alivetime = time;
 901
 902                 antilag_clear(self);
 903
 904                 if (autocvar_g_spawnsound)
 905                         soundat(world, self.origin, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTN_NORM);
 906         } else if(self.classname == "observer") {
 907                 PutObserverInServer ();
 908         }
 909 }
 910
 911 .float ebouncefactor, ebouncestop; // electro's values
 912 // TODO do we need all these fields, or should we stop autodetecting runtime
 913 // changes and just have a console command to update this?
 914 float ClientInit_SendEntity(entity to, float sf)
 915 {
 916         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 917         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 918         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 919         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 920         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 921         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 922         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 923         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 924         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 925         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 926         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 927         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 928         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 929         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 930         if(sv_foginterval && world.fog != "")
 931                 WriteString(MSG_ENTITY, world.fog);
 932         else
 933                 WriteString(MSG_ENTITY, "");
 934         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 935         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 936         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 937         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 938         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 939         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 940         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 941         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 942         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 943         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 944         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 945         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 946         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 947         return TRUE;
 948 }
 949
 950 void ClientInit_CheckUpdate()
 951 {
 952         self.nextthink = time;
 953         if(self.count != autocvar_g_balance_armor_blockpercent)
 954         {
 955                 self.count = autocvar_g_balance_armor_blockpercent;
 956                 self.SendFlags |= 1;
 957         }
 958         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 959         {
 960                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 961                 self.SendFlags |= 1;
 962         }
 963         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 964         {
 965                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 966                 self.SendFlags |= 1;
 967         }
 968         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 969         {
 970                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 971                 self.SendFlags |= 1;
 972         }
 973         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 974         {
 975                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 976                 self.SendFlags |= 1;
 977         }
 978         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 979         {
 980                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 981                 self.SendFlags |= 1;
 982         }
 983 }
 984
 985 void ClientInit_Spawn()
 986 {
 987         entity o;
 988         entity e;
 989         e = spawn();
 990         e.classname = "clientinit";
 991         e.think = ClientInit_CheckUpdate;
 992         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 993
 994         o = self;
 995         self = e;
 996         ClientInit_CheckUpdate();
 997         self = o;
 998 }
 999
1000 /*
1001 =============
1002 SetNewParms
1003 =============
1004 */
1005 void SetNewParms (void)
1006 {
1007         // initialize parms for a new player
1008         parm1 = -(86400 * 366);
1009 }
1010
1011 /*
1012 =============
1013 SetChangeParms
1014 =============
1015 */
1016 void SetChangeParms (void)
1017 {
1018         // save parms for level change
1019         parm1 = self.parm_idlesince - time;
1020 }
1021
1022 /*
1023 =============
1024 DecodeLevelParms
1025 =============
1026 */
1027 void DecodeLevelParms (void)
1028 {
1029         // load parms
1030         self.parm_idlesince = parm1;
1031         if(self.parm_idlesince == -(86400 * 366))
1032                 self.parm_idlesince = time;
1033
1034         // whatever happens, allow 60 seconds of idling directly after connect for map loading
1035         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
1036 }
1037
1038 /*
1039 =============
1040 ClientKill
1041
1042 Called when a client types 'kill' in the console
1043 =============
1044 */
1045
1046 .float clientkill_nexttime;
1047 void ClientKill_Now_TeamChange()
1048 {
1049         if(self.killindicator_teamchange == -1)
1050         {
1051                 JoinBestTeam( self, FALSE, TRUE );
1052         }
1053         else if(self.killindicator_teamchange == -2)
1054         {
1055                 if(g_ca)
1056                         self.caplayer = 0;
1057                 if(blockSpectators)
1058                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1059                 PutObserverInServer();
1060         }
1061         else
1062                 SV_ChangeTeam(self.killindicator_teamchange - 1);
1063 }
1064
1065 void ClientKill_Now()
1066 {
1067         if(self.vehicle)
1068         {
1069             vehicles_exit(VHEF_RELESE);
1070             if(!self.killindicator_teamchange)
1071             {
1072             self.vehicle_health = -1;
1073             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
1074             }
1075         }
1076
1077         if(self.killindicator && !wasfreed(self.killindicator))
1078                 remove(self.killindicator);
1079
1080         self.killindicator = world;
1081
1082         if(self.killindicator_teamchange)
1083                 ClientKill_Now_TeamChange();
1084
1085         // in any case:
1086         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
1087
1088         // now I am sure the player IS dead
1089 }
1090 void KillIndicator_Think()
1091 {
1092         if (gameover)
1093         {
1094                 self.owner.killindicator = world;
1095                 remove(self);
1096                 return;
1097         }
1098
1099         if (self.owner.alpha < 0 && !self.owner.vehicle)
1100         {
1101                 self.owner.killindicator = world;
1102                 remove(self);
1103                 return;
1104         }
1105
1106         if(self.cnt <= 0)
1107         {
1108                 self = self.owner;
1109                 ClientKill_Now(); // no oldself needed
1110                 return;
1111         }
1112     else if(g_cts && self.health == 1) // health == 1 means that it's silent
1113     {
1114         self.nextthink = time + 1;
1115         self.cnt -= 1;
1116     }
1117         else
1118         {
1119                 if(self.cnt <= 10)
1120                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
1121                 if(clienttype(self.owner) == CLIENTTYPE_REAL)
1122                 {
1123                         if(self.cnt <= 10)
1124                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
1125                 }
1126                 self.nextthink = time + 1;
1127                 self.cnt -= 1;
1128         }
1129 }
1130
1131 float clientkilltime;
1132 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1133 {
1134         float killtime;
1135         float starttime;
1136         entity e;
1137
1138         if (gameover)
1139                 return;
1140
1141         killtime = autocvar_g_balance_kill_delay;
1142
1143         if(g_race_qualifying || g_cts)
1144                 killtime = 0;
1145
1146     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
1147     {
1148                 remove(self.killindicator);
1149                 self.killindicator = world;
1150
1151         ClientKill_Now(); // allow instant kill in this case
1152         return;
1153     }
1154
1155         self.killindicator_teamchange = targetteam;
1156
1157     if(!self.killindicator)
1158         {
1159                 if(self.deadflag == DEAD_NO)
1160                 {
1161                         killtime = max(killtime, self.clientkill_nexttime - time);
1162                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1163                 }
1164
1165                 if(killtime <= 0 || self.classname != "player" || self.deadflag != DEAD_NO)
1166                 {
1167                         ClientKill_Now();
1168                 }
1169                 else
1170                 {
1171                         starttime = max(time, clientkilltime);
1172
1173                         self.killindicator = spawn();
1174                         self.killindicator.owner = self;
1175                         self.killindicator.scale = 0.5;
1176                         setattachment(self.killindicator, self, "");
1177                         setorigin(self.killindicator, '0 0 52');
1178                         self.killindicator.think = KillIndicator_Think;
1179                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
1180                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
1181                         self.killindicator.cnt = ceil(killtime);
1182                         self.killindicator.count = bound(0, ceil(killtime), 10);
1183                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
1184
1185                         for(e = world; (e = find(e, classname, "body")) != world; )
1186                         {
1187                                 if(e.enemy != self)
1188                                         continue;
1189                                 e.killindicator = spawn();
1190                                 e.killindicator.owner = e;
1191                                 e.killindicator.scale = 0.5;
1192                                 setattachment(e.killindicator, e, "");
1193                                 setorigin(e.killindicator, '0 0 52');
1194                                 e.killindicator.think = KillIndicator_Think;
1195                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
1196                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
1197                                 e.killindicator.cnt = ceil(killtime);
1198                         }
1199                         self.lip = 0;
1200                 }
1201         }
1202         if(self.killindicator)
1203         {
1204                 if(targetteam == 0) // just die
1205                 {
1206                         self.killindicator.colormod = '0 0 0';
1207                         if(clienttype(self) == CLIENTTYPE_REAL)
1208                         if(self.killindicator.cnt > 0)
1209                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
1210                 }
1211                 else if(targetteam == -1) // auto
1212                 {
1213                         self.killindicator.colormod = '0 1 0';
1214                         if(clienttype(self) == CLIENTTYPE_REAL)
1215                         if(self.killindicator.cnt > 0)
1216                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
1217                 }
1218                 else if(targetteam == -2) // spectate
1219                 {
1220                         self.killindicator.colormod = '0.5 0.5 0.5';
1221                         if(clienttype(self) == CLIENTTYPE_REAL)
1222                         if(self.killindicator.cnt > 0)
1223                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
1224                 }
1225                 else
1226                 {
1227                         self.killindicator.colormod = Team_ColorRGB(targetteam);
1228                         if(clienttype(self) == CLIENTTYPE_REAL)
1229                         if(self.killindicator.cnt > 0)
1230                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
1231                 }
1232         }
1233
1234 }
1235
1236 void ClientKill (void)
1237 {
1238         if (gameover)
1239                 return;
1240
1241         if((g_arena || g_ca) && ((champion && champion.classname == "player" && player_count > 1) || player_count == 1)) // don't allow a kill in this case either
1242         {
1243                 // do nothing
1244         }
1245     else if(self.frozen == 1)
1246     {
1247         // do nothing
1248     }
1249         else
1250                 ClientKill_TeamChange(0);
1251 }
1252
1253 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
1254 {
1255     e.killindicator = spawn();
1256     e.killindicator.owner = e;
1257     e.killindicator.think = KillIndicator_Think;
1258     e.killindicator.nextthink = time + (e.lip) * 0.05;
1259     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
1260     e.killindicator.health = 1; // this is used to indicate that it should be silent
1261     e.lip = 0;
1262 }
1263
1264 void FixClientCvars(entity e)
1265 {
1266         // send prediction settings to the client
1267         stuffcmd(e, "\nin_bindmap 0 0\n");
1268         if(g_race || g_cts)
1269                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
1270         if(autocvar_g_antilag == 3) // client side hitscan
1271                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1272         if(autocvar_sv_gentle)
1273                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1274         /*
1275          * we no longer need to stuff this. Remove this comment block if you feel
1276          * 2.3 and higher (or was it 2.2.3?) don't need these any more
1277         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
1278         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
1279         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
1280         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
1281         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
1282         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
1283         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
1284         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
1285         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
1286         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
1287         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
1288         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
1289         stuffcmd(e, "cl_movement_edgefriction 1\n");
1290          */
1291 }
1292
1293 float PlayerInIDList(entity p, string idlist)
1294 {
1295         float n, i;
1296         string s;
1297
1298         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
1299         if not(p.crypto_idfp)
1300                 return 0;
1301
1302         // this function allows abbreviated player IDs too!
1303         n = tokenize_console(idlist);
1304         for(i = 0; i < n; ++i)
1305         {
1306                 s = argv(i);
1307                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1308                         return 1;
1309         }
1310
1311         return 0;
1312 }
1313
1314 /*
1315 =============
1316 ClientConnect
1317
1318 Called when a client connects to the server
1319 =============
1320 */
1321 void DecodeLevelParms (void);
1322 //void dom_player_join_team(entity pl);
1323 void set_dom_state(entity e);
1324 void ClientConnect (void)
1325 {
1326         float t;
1327
1328         if(self.flags & FL_CLIENT)
1329         {
1330                 print("Warning: ClientConnect, but already connected!\n");
1331                 return;
1332         }
1333
1334         if(Ban_MaybeEnforceBanOnce(self))
1335                 return;
1336
1337         DecodeLevelParms();
1338
1339 #ifdef WATERMARK
1340         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1341 #endif
1342
1343         self.classname = "player_joining";
1344
1345         self.flags = FL_CLIENT;
1346         self.version_nagtime = time + 10 + random() * 10;
1347
1348         if(player_count<0)
1349         {
1350                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1351                 player_count = 0;
1352         }
1353
1354         PlayerScore_Attach(self);
1355         ClientData_Attach();
1356         accuracy_init(self);
1357
1358         bot_clientconnect();
1359
1360         playerdemo_init();
1361
1362         anticheat_init();
1363
1364         race_PreSpawnObserver();
1365
1366         // identify the right forced team
1367         if(autocvar_g_campaign)
1368         {
1369                 if(clienttype(self) == CLIENTTYPE_REAL) // only players, not bots
1370                 {
1371                         switch(autocvar_g_campaign_forceteam)
1372                         {
1373                                 case 1: self.team_forced = NUM_TEAM_1; break;
1374                                 case 2: self.team_forced = NUM_TEAM_2; break;
1375                                 case 3: self.team_forced = NUM_TEAM_3; break;
1376                                 case 4: self.team_forced = NUM_TEAM_4; break;
1377                                 default: self.team_forced = 0;
1378                         }
1379                 }
1380         }
1381         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1382                 self.team_forced = NUM_TEAM_1;
1383         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1384                 self.team_forced = NUM_TEAM_2;
1385         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1386                 self.team_forced = NUM_TEAM_3;
1387         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1388                 self.team_forced = NUM_TEAM_4;
1389         else if(autocvar_g_forced_team_otherwise == "red")
1390                 self.team_forced = NUM_TEAM_1;
1391         else if(autocvar_g_forced_team_otherwise == "blue")
1392                 self.team_forced = NUM_TEAM_2;
1393         else if(autocvar_g_forced_team_otherwise == "yellow")
1394                 self.team_forced = NUM_TEAM_3;
1395         else if(autocvar_g_forced_team_otherwise == "pink")
1396                 self.team_forced = NUM_TEAM_4;
1397         else if(autocvar_g_forced_team_otherwise == "spectate")
1398                 self.team_forced = -1;
1399         else if(autocvar_g_forced_team_otherwise == "spectator")
1400                 self.team_forced = -1;
1401         else
1402                 self.team_forced = 0;
1403
1404         if(!teamplay)
1405                 if(self.team_forced > 0)
1406                         self.team_forced = 0;
1407
1408         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1409
1410         if((autocvar_sv_spectate == 1 && !g_lms) || autocvar_g_campaign || self.team_forced < 0) {
1411                 self.classname = "observer";
1412         } else {
1413                 if(teamplay)
1414                 {
1415                         if(autocvar_g_balance_teams)
1416                         {
1417                                 self.classname = "player";
1418                                 campaign_bots_may_start = 1;
1419                         }
1420                         else
1421                         {
1422                                 self.classname = "observer"; // do it anyway
1423                         }
1424                 }
1425                 else
1426                 {
1427                         self.classname = "player";
1428                         campaign_bots_may_start = 1;
1429                 }
1430         }
1431
1432         self.playerid = (playerid_last = playerid_last + 1);
1433
1434         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1435
1436     if(clienttype(self) == CLIENTTYPE_BOT)
1437         PlayerStats_AddPlayer(self);
1438
1439         if(autocvar_sv_eventlog)
1440                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((clienttype(self) == CLIENTTYPE_REAL) ? self.netaddress : "bot"), ":", self.netname));
1441
1442         LogTeamchange(self.playerid, self.team, 1);
1443
1444         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1445
1446         self.netname_previous = strzone(self.netname);
1447
1448         if((self.classname == STR_PLAYER && teamplay))
1449                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1450         else
1451                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1452
1453         stuffcmd(self, strcat(clientstuff, "\n"));
1454         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1455
1456         FixClientCvars(self);
1457
1458         // spawnfunc_waypoint sprites
1459         WaypointSprite_InitClient(self);
1460
1461         // Wazat's grappling hook
1462         SetGrappleHookBindings();
1463
1464         // get version info from player
1465         stuffcmd(self, "cmd clientversion $gameversion\n");
1466
1467         // get other cvars from player
1468         GetCvars(0);
1469
1470         // notify about available teams
1471         if(teamplay)
1472         {
1473                 CheckAllowedTeams(self);
1474                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1475                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1476         }
1477         else
1478                 stuffcmd(self, "set _teams_available 0\n");
1479
1480         if(g_arena || g_ca)
1481         {
1482                 self.classname = "observer";
1483                 if(g_arena)
1484                         Spawnqueue_Insert(self);
1485         }
1486
1487         attach_entcs();
1488
1489         bot_relinkplayerlist();
1490
1491         self.spectatortime = time;
1492         if(blockSpectators)
1493         {
1494                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1495         }
1496
1497         self.jointime = time;
1498         self.allowed_timeouts = autocvar_sv_timeout_number;
1499
1500         if(clienttype(self) == CLIENTTYPE_REAL)
1501         {
1502                 if(!autocvar_g_campaign)
1503                 {
1504                         self.motd_actived_time = -1;
1505                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1506                 }
1507
1508                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1509                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1510         }
1511
1512         if(g_lms)
1513         {
1514                 if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
1515                 {
1516                         PlayerScore_Add(self, SP_LMS_RANK, 666);
1517                         self.frags = FRAGS_SPECTATOR;
1518                 }
1519         }
1520
1521         if(!sv_foginterval && world.fog != "")
1522                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1523
1524         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1525         {
1526                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1527                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1528         }
1529         else
1530                 self.hitplotfh = -1;
1531
1532         if(g_race || g_cts) {
1533                 string rr;
1534                 if(g_cts)
1535                         rr = CTS_RECORD;
1536                 else
1537                         rr = RACE_RECORD;
1538
1539                 msg_entity = self;
1540                 race_send_recordtime(MSG_ONE);
1541                 race_send_speedaward(MSG_ONE);
1542
1543                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1544                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1545                 race_send_speedaward_alltimebest(MSG_ONE);
1546
1547                 float i;
1548                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1549                         race_SendRankings(i, 0, 0, MSG_ONE);
1550                 }
1551         }
1552         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1553                 send_CSQC_teamnagger();
1554
1555         CheatInitClient();
1556
1557         CSQCMODEL_AUTOINIT();
1558
1559         self.model_randomizer = random();
1560
1561     if(clienttype(self) != CLIENTTYPE_REAL)
1562         return;
1563
1564     sv_notice_join();
1565
1566     MUTATOR_CALLHOOK(ClientConnect);
1567 }
1568 /*
1569 =============
1570 ClientDisconnect
1571
1572 Called when a client disconnects from the server
1573 =============
1574 */
1575 .entity chatbubbleentity;
1576 void ReadyCount();
1577 void ClientDisconnect (void)
1578 {
1579         if(self.vehicle)
1580             vehicles_exit(VHEF_RELESE);
1581
1582         if not(self.flags & FL_CLIENT)
1583         {
1584                 print("Warning: ClientDisconnect without ClientConnect\n");
1585                 return;
1586         }
1587
1588         PlayerStats_AddGlobalInfo(self);
1589
1590         CheatShutdownClient();
1591
1592         if(self.hitplotfh >= 0)
1593         {
1594                 fclose(self.hitplotfh);
1595                 self.hitplotfh = -1;
1596         }
1597
1598         anticheat_report();
1599         anticheat_shutdown();
1600
1601         playerdemo_shutdown();
1602
1603         bot_clientdisconnect();
1604
1605         if(self.entcs)
1606                 detach_entcs();
1607
1608         if(autocvar_sv_eventlog)
1609                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1610
1611         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1612
1613         MUTATOR_CALLHOOK(ClientDisconnect);
1614
1615         Portal_ClearAll(self);
1616
1617         Unfreeze(self);
1618
1619         RemoveGrapplingHook(self);
1620
1621         // Here, everything has been done that requires this player to be a client.
1622
1623         self.flags &~= FL_CLIENT;
1624
1625         if (self.chatbubbleentity)
1626                 remove (self.chatbubbleentity);
1627
1628         if (self.killindicator)
1629                 remove (self.killindicator);
1630
1631         WaypointSprite_PlayerGone();
1632
1633         bot_relinkplayerlist();
1634
1635         if(g_arena)
1636         {
1637                 Spawnqueue_Unmark(self);
1638                 Spawnqueue_Remove(self);
1639         }
1640
1641         accuracy_free(self);
1642         ClientData_Detach();
1643         PlayerScore_Detach(self);
1644
1645         if(self.netname_previous)
1646                 strunzone(self.netname_previous);
1647         if(self.clientstatus)
1648                 strunzone(self.clientstatus);
1649         if(self.weaponorder_byimpulse)
1650                 strunzone(self.weaponorder_byimpulse);
1651
1652         ClearPlayerSounds();
1653
1654         if(self.personal)
1655                 remove(self.personal);
1656
1657         self.playerid = 0;
1658         ReadyCount();
1659
1660         // free cvars
1661         GetCvars(-1);
1662 }
1663
1664 .float BUTTON_CHAT;
1665 void ChatBubbleThink()
1666 {
1667         self.nextthink = time;
1668         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1669         {
1670                 if(self.owner) // but why can that ever be world?
1671                         self.owner.chatbubbleentity = world;
1672                 remove(self);
1673                 return;
1674         }
1675         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1676 #ifdef TETRIS
1677                 || self.owner.tetris_on
1678 #endif
1679         )
1680                 self.model = self.mdl;
1681         else
1682                 self.model = "";
1683 }
1684
1685 void UpdateChatBubble()
1686 {
1687         if (self.alpha < 0)
1688                 return;
1689         // spawn a chatbubble entity if needed
1690         if (!self.chatbubbleentity)
1691         {
1692                 self.chatbubbleentity = spawn();
1693                 self.chatbubbleentity.owner = self;
1694                 self.chatbubbleentity.exteriormodeltoclient = self;
1695                 self.chatbubbleentity.think = ChatBubbleThink;
1696                 self.chatbubbleentity.nextthink = time;
1697                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1698                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1699                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1700                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1701                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1702                 self.chatbubbleentity.model = "";
1703                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1704         }
1705 }
1706
1707
1708 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1709 // added to the model skins
1710 /*void UpdateColorModHack()
1711 {
1712         float c;
1713         c = self.clientcolors & 15;
1714         // LordHavoc: only bothering to support white, green, red, yellow, blue
1715              if (!teamplay) self.colormod = '0 0 0';
1716         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1717         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1718         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1719         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1720         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1721         else self.colormod = '1 1 1';
1722 }*/
1723
1724 void respawn(void)
1725 {
1726         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1727         {
1728                 self.solid = SOLID_NOT;
1729                 self.takedamage = DAMAGE_NO;
1730                 self.movetype = MOVETYPE_FLY;
1731                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1732                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1733                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1734                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1735                 if(autocvar_g_respawn_ghosts_maxtime)
1736                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1737         }
1738
1739         CopyBody(1);
1740
1741         self.effects |= EF_NODRAW; // prevent another CopyBody
1742         PutClientInServer();
1743 }
1744
1745 void play_countdown(float finished, string samp)
1746 {
1747         if(clienttype(self) == CLIENTTYPE_REAL)
1748                 if(floor(finished - time - frametime) != floor(finished - time))
1749                         if(finished - time < 6)
1750                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1751 }
1752
1753 void player_powerups (void)
1754 {
1755         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1756         olditems = self.items;
1757
1758         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1759                 self.modelflags |= MF_ROCKET;
1760         else
1761                 self.modelflags &~= MF_ROCKET;
1762
1763         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1764
1765         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1766                 return;
1767
1768         Fire_ApplyDamage(self);
1769         Fire_ApplyEffect(self);
1770
1771         if (g_minstagib)
1772         {
1773                 self.effects |= EF_FULLBRIGHT;
1774
1775                 if (self.items & IT_STRENGTH)
1776                 {
1777                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1778                         if (time > self.strength_finished)
1779                         {
1780                                 self.alpha = default_player_alpha;
1781                                 self.exteriorweaponentity.alpha = default_weapon_alpha;
1782                                 self.items &~= IT_STRENGTH;
1783                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_INVISIBILITY, self.netname);
1784                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
1785                         }
1786                 }
1787                 else
1788                 {
1789                         if (time < self.strength_finished)
1790                         {
1791                                 self.alpha = g_minstagib_invis_alpha;
1792                                 self.exteriorweaponentity.alpha = g_minstagib_invis_alpha;
1793                                 self.items |= IT_STRENGTH;
1794                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
1795                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
1796                         }
1797                 }
1798
1799                 if (self.items & IT_INVINCIBLE)
1800                 {
1801                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1802                         if (time > self.invincible_finished)
1803                         {
1804                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1805                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SPEED, self.netname);
1806                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
1807                         }
1808                 }
1809                 else
1810                 {
1811                         if (time < self.invincible_finished)
1812                         {
1813                                 self.items = self.items | IT_INVINCIBLE;
1814                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
1815                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
1816                         }
1817                 }
1818         }
1819         else // if we're not in minstagib, continue. I added this else to replace the "return" which was here that broke the callhook for this function -- This code is nasty.
1820         {
1821                 if (self.items & IT_STRENGTH)
1822                 {
1823                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1824                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1825                         if (time > self.strength_finished)
1826                         {
1827                                 self.items = self.items - (self.items & IT_STRENGTH);
1828                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1829                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1830                         }
1831                 }
1832                 else
1833                 {
1834                         if (time < self.strength_finished)
1835                         {
1836                                 self.items = self.items | IT_STRENGTH;
1837                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1838                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1839                         }
1840                 }
1841                 if (self.items & IT_INVINCIBLE)
1842                 {
1843                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1844                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1845                         if (time > self.invincible_finished)
1846                         {
1847                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1848                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1849                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1850                         }
1851                 }
1852                 else
1853                 {
1854                         if (time < self.invincible_finished)
1855                         {
1856                                 self.items = self.items | IT_INVINCIBLE;
1857                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1858                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1859                         }
1860                 }
1861                 if (self.items & IT_SUPERWEAPON)
1862                 {
1863                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1864                         {
1865                                 self.superweapons_finished = 0;
1866                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1867                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1868                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1869                         }
1870                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1871                         {
1872                                 // don't let them run out
1873                         }
1874                         else
1875                         {
1876                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1877                                 if (time > self.superweapons_finished)
1878                                 {
1879                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1880                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1881                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1882                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1883                                 }
1884                         }
1885                 }
1886                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1887                 {
1888                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1889                         {
1890                                 self.items = self.items | IT_SUPERWEAPON;
1891                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1892                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1893                         }
1894                         else
1895                         {
1896                                 self.superweapons_finished = 0;
1897                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1898                         }
1899                 }
1900                 else
1901                 {
1902                         self.superweapons_finished = 0;
1903                 }
1904         }
1905
1906         if(autocvar_g_nodepthtestplayers)
1907                 self.effects = self.effects | EF_NODEPTHTEST;
1908
1909         if(autocvar_g_fullbrightplayers)
1910                 self.effects = self.effects | EF_FULLBRIGHT;
1911
1912         // midair gamemode: damage only while in the air
1913         // if in midair mode, being on ground grants temporary invulnerability
1914         // (this is so that multishot weapon don't clear the ground flag on the
1915         // first damage in the frame, leaving the player vulnerable to the
1916         // remaining hits in the same frame)
1917         if (self.flags & FL_ONGROUND)
1918         if (g_midair)
1919                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1920
1921         if (time >= game_starttime)
1922         if (time < self.spawnshieldtime)
1923                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1924
1925         MUTATOR_CALLHOOK(PlayerPowerups);
1926 }
1927
1928 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1929 {
1930         if(current > stable)
1931                 return current;
1932         else if(current > stable - 0.25) // when close enough, "snap"
1933                 return stable;
1934         else
1935                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1936 }
1937
1938 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1939 {
1940         if(current < stable)
1941                 return current;
1942         else if(current < stable + 0.25) // when close enough, "snap"
1943                 return stable;
1944         else
1945                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1946 }
1947
1948 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1949 {
1950         if(current > rotstable)
1951         {
1952                 if(rotframetime > 0)
1953                 {
1954                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1955                         current = max(rotstable, current - rotlinear * rotframetime);
1956                 }
1957         }
1958         else if(current < regenstable)
1959         {
1960                 if(regenframetime > 0)
1961                 {
1962                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1963                         current = min(regenstable, current + regenlinear * regenframetime);
1964                 }
1965         }
1966
1967         if(current > limit)
1968                 current = limit;
1969
1970         return current;
1971 }
1972
1973 void player_regen (void)
1974 {
1975         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1976         maxh = autocvar_g_balance_health_rotstable;
1977         maxa = autocvar_g_balance_armor_rotstable;
1978         maxf = autocvar_g_balance_fuel_rotstable;
1979         minh = autocvar_g_balance_health_regenstable;
1980         mina = autocvar_g_balance_armor_regenstable;
1981         minf = autocvar_g_balance_fuel_regenstable;
1982         limith = autocvar_g_balance_health_limit;
1983         limita = autocvar_g_balance_armor_limit;
1984         limitf = autocvar_g_balance_fuel_limit;
1985
1986         max_mod = regen_mod = rot_mod = limit_mod = 1;
1987
1988         maxh = maxh * max_mod;
1989         //maxa = maxa * max_mod;
1990         //maxf = maxf * max_mod;
1991         minh = minh * max_mod;
1992         //mina = mina * max_mod;
1993         //minf = minf * max_mod;
1994         limith = limith * limit_mod;
1995         limita = limita * limit_mod;
1996         //limitf = limitf * limit_mod;
1997
1998         if(g_lms && g_ca)
1999                 rot_mod = 0;
2000
2001         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
2002         {
2003                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
2004                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
2005
2006                 // if player rotted to death...  die!
2007                 if(self.health < 1)
2008                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2009         }
2010
2011         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
2012                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
2013 }
2014
2015 float zoomstate_set;
2016 void SetZoomState(float z)
2017 {
2018         if(z != self.zoomstate)
2019         {
2020                 self.zoomstate = z;
2021                 ClientData_Touch(self);
2022         }
2023         zoomstate_set = 1;
2024 }
2025
2026 void GetPressedKeys(void) {
2027         MUTATOR_CALLHOOK(GetPressedKeys);
2028         if (self.movement_x > 0) // get if movement keys are pressed
2029         {       // forward key pressed
2030                 self.pressedkeys |= KEY_FORWARD;
2031                 self.pressedkeys &~= KEY_BACKWARD;
2032         }
2033         else if (self.movement_x < 0)
2034         {       // backward key pressed
2035                 self.pressedkeys |= KEY_BACKWARD;
2036                 self.pressedkeys &~= KEY_FORWARD;
2037         }
2038         else
2039         {       // no x input
2040                 self.pressedkeys &~= KEY_FORWARD;
2041                 self.pressedkeys &~= KEY_BACKWARD;
2042         }
2043
2044         if (self.movement_y > 0)
2045         {       // right key pressed
2046                 self.pressedkeys |= KEY_RIGHT;
2047                 self.pressedkeys &~= KEY_LEFT;
2048         }
2049         else if (self.movement_y < 0)
2050         {       // left key pressed
2051                 self.pressedkeys |= KEY_LEFT;
2052                 self.pressedkeys &~= KEY_RIGHT;
2053         }
2054         else
2055         {       // no y input
2056                 self.pressedkeys &~= KEY_RIGHT;
2057                 self.pressedkeys &~= KEY_LEFT;
2058         }
2059
2060         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
2061                 self.pressedkeys |= KEY_JUMP;
2062         else
2063                 self.pressedkeys &~= KEY_JUMP;
2064         if (self.BUTTON_CROUCH)
2065                 self.pressedkeys |= KEY_CROUCH;
2066         else
2067                 self.pressedkeys &~= KEY_CROUCH;
2068
2069         if (self.BUTTON_ATCK)
2070                 self.pressedkeys |= KEY_ATCK;
2071         else
2072                 self.pressedkeys &~= KEY_ATCK;
2073         if (self.BUTTON_ATCK2)
2074                 self.pressedkeys |= KEY_ATCK2;
2075         else
2076                 self.pressedkeys &~= KEY_ATCK2;
2077 }
2078
2079 /*
2080 ======================
2081 spectate mode routines
2082 ======================
2083 */
2084
2085 void SpectateCopy(entity spectatee) {
2086         other = spectatee;
2087         MUTATOR_CALLHOOK(SpectateCopy);
2088         self.armortype = spectatee.armortype;
2089         self.armorvalue = spectatee.armorvalue;
2090         self.ammo_cells = spectatee.ammo_cells;
2091         self.ammo_shells = spectatee.ammo_shells;
2092         self.ammo_nails = spectatee.ammo_nails;
2093         self.ammo_rockets = spectatee.ammo_rockets;
2094         self.ammo_fuel = spectatee.ammo_fuel;
2095         self.clip_load = spectatee.clip_load;
2096         self.clip_size = spectatee.clip_size;
2097         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
2098         self.health = spectatee.health;
2099         self.impulse = 0;
2100         self.items = spectatee.items;
2101         self.last_pickup = spectatee.last_pickup;
2102         self.hit_time = spectatee.hit_time;
2103         self.metertime = spectatee.metertime;
2104         self.strength_finished = spectatee.strength_finished;
2105         self.invincible_finished = spectatee.invincible_finished;
2106         self.pressedkeys = spectatee.pressedkeys;
2107         WEPSET_COPY_EE(self, spectatee);
2108         self.switchweapon = spectatee.switchweapon;
2109         self.switchingweapon = spectatee.switchingweapon;
2110         self.weapon = spectatee.weapon;
2111         self.nex_charge = spectatee.nex_charge;
2112         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
2113         self.hagar_load = spectatee.hagar_load;
2114         self.minelayer_mines = spectatee.minelayer_mines;
2115         self.punchangle = spectatee.punchangle;
2116         self.view_ofs = spectatee.view_ofs;
2117         self.velocity = spectatee.velocity;
2118         self.dmg_take = spectatee.dmg_take;
2119         self.dmg_save = spectatee.dmg_save;
2120         self.dmg_inflictor = spectatee.dmg_inflictor;
2121         self.v_angle = spectatee.v_angle;
2122         self.angles = spectatee.v_angle;
2123         self.stat_respawn_time = spectatee.stat_respawn_time;
2124         if(!self.BUTTON_USE)
2125                 self.fixangle = TRUE;
2126         setorigin(self, spectatee.origin);
2127         setsize(self, spectatee.mins, spectatee.maxs);
2128         SetZoomState(spectatee.zoomstate);
2129
2130     anticheat_spectatecopy(spectatee);
2131         self.hud = spectatee.hud;
2132         if(spectatee.vehicle)
2133     {
2134         self.fixangle = FALSE;
2135         //self.velocity = spectatee.vehicle.velocity;
2136         self.vehicle_health = spectatee.vehicle_health;
2137         self.vehicle_shield = spectatee.vehicle_shield;
2138         self.vehicle_energy = spectatee.vehicle_energy;
2139         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
2140         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
2141         self.vehicle_reload1 = spectatee.vehicle_reload1;
2142         self.vehicle_reload2 = spectatee.vehicle_reload2;
2143
2144         msg_entity = self;
2145
2146         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
2147             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
2148             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
2149             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
2150
2151         //WriteByte (MSG_ONE, SVC_SETVIEW);
2152         //    WriteEntity(MSG_ONE, self);
2153         //makevectors(spectatee.v_angle);
2154         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
2155     }
2156 }
2157
2158 float SpectateUpdate() {
2159         if(!self.enemy)
2160             return 0;
2161
2162         if (self == self.enemy)
2163                 return 0;
2164
2165         if(self.enemy.classname != "player")
2166                 return 0;
2167
2168         SpectateCopy(self.enemy);
2169
2170         return 1;
2171 }
2172
2173
2174 // Returns next available player to spectate if g_ca_spectate_enemies == 0
2175 entity CA_SpectateNext(entity start) {
2176         if (start.team == self.team) {
2177                 return start;
2178         }
2179
2180         other = start;
2181         // continue from current player
2182         while(other && other.team != self.team) {
2183                 other = find(other, classname, "player");
2184         }
2185
2186         if (!other) {
2187                 // restart from begining
2188                 other = find(other, classname, "player");
2189                 while(other && other.team != self.team) {
2190                         other = find(other, classname, "player");
2191                 }
2192         }
2193
2194         return other;
2195 }
2196
2197 float SpectateNext(entity _prefer) {
2198
2199         if(_prefer)
2200                 other = _prefer;
2201         else
2202                 other = find(self.enemy, classname, "player");
2203
2204         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
2205                 // CA and ca players when spectating enemies is forbidden
2206                 other = CA_SpectateNext(other);
2207         } else {
2208                 // other modes and ca spectators or spectating enemies is allowed
2209                 if (!other)
2210                         other = find(other, classname, "player");
2211         }
2212
2213         if (other)
2214                 self.enemy = other;
2215
2216         if(self.enemy.classname == "player") {
2217             /*if(self.enemy.vehicle)
2218             {
2219
2220             msg_entity = self;
2221             WriteByte(MSG_ONE, SVC_SETVIEW);
2222             WriteEntity(MSG_ONE, self.enemy);
2223             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2224
2225             self.movetype = MOVETYPE_NONE;
2226             accuracy_resend(self);
2227             }
2228             else
2229             {*/
2230             msg_entity = self;
2231             WriteByte(MSG_ONE, SVC_SETVIEW);
2232             WriteEntity(MSG_ONE, self.enemy);
2233             //stuffcmd(self, "set viewsize $tmpviewsize \n");
2234             self.movetype = MOVETYPE_NONE;
2235             accuracy_resend(self);
2236
2237             if(!SpectateUpdate())
2238                 PutObserverInServer();
2239         //}
2240         return 1;
2241         } else {
2242                 return 0;
2243         }
2244 }
2245
2246 /*
2247 =============
2248 ShowRespawnCountdown()
2249
2250 Update a respawn countdown display.
2251 =============
2252 */
2253 void ShowRespawnCountdown()
2254 {
2255         float number;
2256         if(self.deadflag == DEAD_NO) // just respawned?
2257                 return;
2258         else
2259         {
2260                 number = ceil(self.respawn_time - time);
2261                 if(number <= 0)
2262                         return;
2263                 if(number <= self.respawn_countdown)
2264                 {
2265                         self.respawn_countdown = number - 1;
2266                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2267                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number));
2268                 }
2269         }
2270 }
2271
2272 void LeaveSpectatorMode()
2273 {
2274         if(nJoinAllowed(self))
2275         {
2276                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
2277                 {
2278                         self.classname = "player";
2279
2280                         if(autocvar_g_campaign || autocvar_g_balance_teams)
2281                                 { JoinBestTeam(self, FALSE, TRUE); }
2282
2283                         if(autocvar_g_campaign)
2284                                 { campaign_bots_may_start = 1; }
2285
2286                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
2287
2288                         PutClientInServer();
2289
2290                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
2291                 }
2292                 else if not(g_ca && self.caplayer) { stuffcmd(self, "menu_showteamselect\n"); }
2293         }
2294         else
2295         {
2296                 // Player may not join because g_maxplayers is set
2297                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
2298         }
2299 }
2300
2301 /**
2302  * Determines whether the player is allowed to join. This depends on cvar
2303  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
2304  * it checks whether the number of currently playing players exceeds g_maxplayers.
2305  * @return int number of free slots for players, 0 if none
2306  */
2307 float nJoinAllowed(entity ignore) {
2308         if(!ignore)
2309         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2310         // so report 0 free slots if restricted
2311         {
2312                 if(autocvar_g_forced_team_otherwise == "spectate")
2313                         return 0;
2314                 if(autocvar_g_forced_team_otherwise == "spectator")
2315                         return 0;
2316         }
2317
2318         if(self.team_forced < 0)
2319                 return 0; // forced spectators can never join
2320
2321         // TODO simplify this
2322         entity e;
2323         float totalClients = 0;
2324         FOR_EACH_CLIENT(e)
2325                 if(e != ignore)
2326                         totalClients += 1;
2327
2328         if (!autocvar_g_maxplayers)
2329                 return maxclients - totalClients;
2330
2331         float currentlyPlaying = 0;
2332         FOR_EACH_REALPLAYER(e)
2333                 currentlyPlaying += 1;
2334
2335         if(currentlyPlaying < autocvar_g_maxplayers)
2336                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2337
2338         return 0;
2339 }
2340
2341 /**
2342  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2343  * g_maxplayers_spectator_blocktime seconds
2344  */
2345 void checkSpectatorBlock() {
2346         if(self.classname == "spectator" || self.classname == "observer") {
2347                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2348                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2349                         dropclient(self);
2350                 }
2351         }
2352 }
2353
2354 void PrintWelcomeMessage()
2355 {
2356         if(self.motd_actived_time == 0)
2357         {
2358                 if (autocvar_g_campaign) {
2359                         if ((self.classname == "player" && self.BUTTON_INFO) || (self.classname != "player")) {
2360                                 self.motd_actived_time = time;
2361                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2362                         }
2363                 } else {
2364                         if (self.BUTTON_INFO) {
2365                                 self.motd_actived_time = time;
2366                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2367                         }
2368                 }
2369         }
2370         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2371         {
2372                 if (autocvar_g_campaign) {
2373                         if (self.BUTTON_INFO)
2374                                 self.motd_actived_time = time;
2375                         else if ((time - self.motd_actived_time > 2) && self.classname == "player") { // hide it some seconds after BUTTON_INFO has been released
2376                                 self.motd_actived_time = 0;
2377                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2378                         }
2379                 } else {
2380                         if (self.BUTTON_INFO)
2381                                 self.motd_actived_time = time;
2382                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2383                                 self.motd_actived_time = 0;
2384                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2385                         }
2386                 }
2387         }
2388         else //if(self.motd_actived_time < 0) // just connected, motd is active
2389         {
2390                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2391                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2392                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2393                 {
2394                         // instanctly hide MOTD
2395                         self.motd_actived_time = 0;
2396                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2397                 }
2398         }
2399 }
2400
2401 void ObserverThink()
2402 {
2403         float prefered_movetype;
2404         if (self.flags & FL_JUMPRELEASED) {
2405                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2406                         self.flags &~= FL_JUMPRELEASED;
2407                         self.flags |= FL_SPAWNING;
2408                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2409                         self.flags &~= FL_JUMPRELEASED;
2410                         if(SpectateNext(world) == 1) {
2411                                 self.classname = "spectator";
2412                         }
2413                 } else {
2414                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2415                         if (self.movetype != prefered_movetype)
2416                                 self.movetype = prefered_movetype;
2417                 }
2418         } else {
2419                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2420                         self.flags |= FL_JUMPRELEASED;
2421                         if(self.flags & FL_SPAWNING)
2422                         {
2423                                 self.flags &~= FL_SPAWNING;
2424                                 LeaveSpectatorMode();
2425                                 return;
2426                         }
2427                 }
2428         }
2429 }
2430
2431 void SpectatorThink()
2432 {
2433         if (self.flags & FL_JUMPRELEASED) {
2434                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2435                         self.flags &~= FL_JUMPRELEASED;
2436                         self.flags |= FL_SPAWNING;
2437                 } else if(self.BUTTON_ATCK) {
2438                         self.flags &~= FL_JUMPRELEASED;
2439                         if(SpectateNext(world) == 1) {
2440                                 self.classname = "spectator";
2441                         } else {
2442                                 self.classname = "observer";
2443                                 PutClientInServer();
2444                         }
2445                 } else if (self.BUTTON_ATCK2) {
2446                         self.flags &~= FL_JUMPRELEASED;
2447                         self.classname = "observer";
2448                         PutClientInServer();
2449                 } else {
2450                         if(!SpectateUpdate())
2451                                 PutObserverInServer();
2452                 }
2453         } else {
2454                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2455                         self.flags |= FL_JUMPRELEASED;
2456                         if(self.flags & FL_SPAWNING)
2457                         {
2458                                 self.flags &~= FL_SPAWNING;
2459                                 LeaveSpectatorMode();
2460                                 return;
2461                         }
2462                 }
2463                 if(!SpectateUpdate())
2464                         PutObserverInServer();
2465         }
2466
2467         self.flags |= FL_CLIENT | FL_NOTARGET;
2468 }
2469
2470 void PlayerUseKey()
2471 {
2472         if(self.classname != "player")
2473                 return;
2474
2475         if(self.vehicle)
2476         {
2477         vehicles_exit(VHEF_NORMAL);
2478         return;
2479         }
2480
2481         // a use key was pressed; call handlers
2482         MUTATOR_CALLHOOK(PlayerUseKey);
2483 }
2484
2485 /*
2486 =============
2487 PlayerPreThink
2488
2489 Called every frame for each client before the physics are run
2490 =============
2491 */
2492 .float usekeypressed;
2493 void() nexball_setstatus;
2494 .float items_added;
2495 void PlayerPreThink (void)
2496 {
2497         WarpZone_PlayerPhysics_FixVAngle();
2498
2499         self.stat_game_starttime = game_starttime;
2500         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2501         self.stat_leadlimit = autocvar_leadlimit;
2502
2503         if(g_arena || (g_ca && !allowed_to_spawn))
2504                 self.stat_respawn_time = 0;
2505         else
2506                 self.stat_respawn_time = self.respawn_time;
2507
2508         if(frametime)
2509         {
2510                 // physics frames: update anticheat stuff
2511                 anticheat_prethink();
2512         }
2513
2514         if(blockSpectators && frametime)
2515                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2516                 checkSpectatorBlock();
2517
2518         zoomstate_set = 0;
2519
2520         if(self.netname_previous != self.netname)
2521         {
2522                 if(autocvar_sv_eventlog)
2523                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2524                 if(self.netname_previous)
2525                         strunzone(self.netname_previous);
2526                 self.netname_previous = strzone(self.netname);
2527         }
2528
2529         // version nagging
2530         if(self.version_nagtime)
2531                 if(self.cvar_g_xonoticversion)
2532                         if(time > self.version_nagtime)
2533                         {
2534                                 // don't notify git users
2535                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2536                                 {
2537                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2538                                         {
2539                                                 // notify release users if connecting to git
2540                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2541                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2542                                         }
2543                                         else
2544                                         {
2545                                                 float r;
2546                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2547                                                 if(r < 0)
2548                                                 {
2549                                                         // give users new version
2550                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2551                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2552                                                 }
2553                                                 else if(r > 0)
2554                                                 {
2555                                                         // notify users about old server version
2556                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2557                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2558                                                 }
2559                                         }
2560                                 }
2561                                 self.version_nagtime = 0;
2562                         }
2563
2564         // GOD MODE info
2565         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2566         {
2567                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2568                 self.max_armorvalue = 0;
2569         }
2570
2571 #ifdef TETRIS
2572         if (TetrisPreFrame())
2573                 return;
2574 #endif
2575
2576         if(self.frozen == 2)
2577         {
2578                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2579                 self.health = max(1, self.revive_progress * autocvar_g_balance_health_start);
2580
2581                 if(self.revive_progress >= 1)
2582                         Unfreeze(self);
2583         }
2584
2585         MUTATOR_CALLHOOK(PlayerPreThink);
2586
2587         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2588         {
2589                 if(self.BUTTON_USE && !self.usekeypressed)
2590                         PlayerUseKey();
2591                 self.usekeypressed = self.BUTTON_USE;
2592         }
2593
2594         if(clienttype(self) == CLIENTTYPE_REAL)
2595                 PrintWelcomeMessage();
2596
2597         if(self.classname == "player") {
2598
2599                 CheckRules_Player();
2600
2601                 if (intermission_running)
2602                 {
2603                         IntermissionThink ();   // otherwise a button could be missed between
2604                         return;                                 // the think tics
2605                 }
2606
2607                 //don't allow the player to turn around while game is paused!
2608                 if(timeout_status == TIMEOUT_ACTIVE) {
2609                         // FIXME turn this into CSQC stuff
2610                         self.v_angle = self.lastV_angle;
2611                         self.angles = self.lastV_angle;
2612                         self.fixangle = TRUE;
2613                 }
2614
2615                 if(frametime)
2616                 {
2617                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2618                         {
2619                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2620                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2621                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2622
2623                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2624                                 {
2625                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2626                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2627                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2628                                 }
2629                         }
2630                         else
2631                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2632
2633                         player_powerups();
2634                 }
2635
2636                 if (g_minstagib)
2637                         minstagib_ammocheck();
2638
2639                 if (self.deadflag != DEAD_NO)
2640                 {
2641                         float button_pressed, force_respawn;
2642                         if(self.personal && g_race_qualifying)
2643                         {
2644                                 if(time > self.respawn_time)
2645                                 {
2646                                         self.respawn_time = time + 1; // only retry once a second
2647                                         respawn();
2648                                         self.impulse = 141;
2649                                 }
2650                         }
2651                         else
2652                         {
2653                                 if(frametime)
2654                                         player_anim();
2655                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2656                                 force_respawn = (g_lms || g_ca || g_cts || autocvar_g_forced_respawn);
2657                                 if (self.deadflag == DEAD_DYING)
2658                                 {
2659                                         if(force_respawn)
2660                                                 self.deadflag = DEAD_RESPAWNING;
2661                                         else if(!button_pressed)
2662                                                 self.deadflag = DEAD_DEAD;
2663                                 }
2664                                 else if (self.deadflag == DEAD_DEAD)
2665                                 {
2666                                         if(button_pressed)
2667                                                 self.deadflag = DEAD_RESPAWNABLE;
2668                                 }
2669                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2670                                 {
2671                                         if(!button_pressed)
2672                                                 self.deadflag = DEAD_RESPAWNING;
2673                                 }
2674                                 else if (self.deadflag == DEAD_RESPAWNING)
2675                                 {
2676                                         if(time > self.respawn_time)
2677                                         {
2678                                                 self.respawn_time = time + 1; // only retry once a second
2679                                                 respawn();
2680                                         }
2681                                 }
2682                                 ShowRespawnCountdown();
2683                         }
2684
2685                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2686                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2687                                 self.stat_respawn_time *= -1;
2688
2689                         return;
2690                 }
2691
2692                 if(g_lms && !self.deadflag && autocvar_g_lms_campcheck_interval)
2693                 {
2694                         vector dist;
2695
2696                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
2697                         dist = self.prevorigin - self.origin;
2698                         dist_z = 0;
2699                         self.lms_traveled_distance += fabs(vlen(dist));
2700
2701                         if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime))
2702                         {
2703                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval*2;
2704                                 self.lms_traveled_distance = 0;
2705                         }
2706
2707                         if(time > self.lms_nextcheck)
2708                         {
2709                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
2710                                 if(self.lms_traveled_distance < autocvar_g_lms_campcheck_distance)
2711                                 {
2712                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_CAMPCHECK);
2713                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
2714                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
2715                                         if(self.vehicle)
2716                                                 Damage(self.vehicle, self, self, autocvar_g_lms_campcheck_damage * 2, DEATH_CAMP, self.vehicle.origin, '0 0 0');
2717                                         else
2718                                                 Damage(self, self, self, bound(0, autocvar_g_lms_campcheck_damage, self.health + self.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP, self.origin, '0 0 0');
2719                                 }
2720                                 self.lms_nextcheck = time + autocvar_g_lms_campcheck_interval;
2721                                 self.lms_traveled_distance = 0;
2722                         }
2723                 }
2724
2725                 self.prevorigin = self.origin;
2726
2727                 float do_crouch = self.BUTTON_CROUCH;
2728                 if(self.hook.state)
2729                         do_crouch = 0;
2730                 if(self.health <= g_bloodloss)
2731                         do_crouch = 1;
2732                 if(self.vehicle)
2733                         do_crouch = 0;
2734                 if(self.frozen)
2735                         do_crouch = 0;
2736                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2737                         do_crouch = 0;
2738
2739                 if (do_crouch)
2740                 {
2741                         if (!self.crouch)
2742                         {
2743                                 self.crouch = TRUE;
2744                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2745                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2746                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2747                         }
2748                 }
2749                 else
2750                 {
2751                         if (self.crouch)
2752                         {
2753                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2754                                 if (!trace_startsolid)
2755                                 {
2756                                         self.crouch = FALSE;
2757                                         self.view_ofs = PL_VIEW_OFS;
2758                                         setsize (self, PL_MIN, PL_MAX);
2759                                 }
2760                         }
2761                 }
2762
2763                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2764                 {
2765                         if(self.bloodloss_timer < time)
2766                         {
2767                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2768                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2769                         }
2770                 }
2771
2772                 FixPlayermodel();
2773
2774                 GrapplingHookFrame();
2775
2776                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2777                 //if(frametime)
2778                 {
2779                         self.items &~= self.items_added;
2780
2781                         W_WeaponFrame();
2782
2783                         self.items_added = 0;
2784                         if(self.items & IT_JETPACK)
2785                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2786                                         self.items_added |= IT_FUEL;
2787
2788                         self.items |= self.items_added;
2789                 }
2790
2791                 player_regen();
2792
2793                 // rot nex charge to the charge limit
2794                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2795                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2796
2797                 if(frametime)
2798                         player_anim();
2799
2800                 if(g_nexball)
2801                         nexball_setstatus();
2802
2803                 // secret status
2804                 secrets_setstatus();
2805
2806                 // monsters status
2807                 monsters_setstatus();
2808
2809                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2810
2811                 //self.angles_y=self.v_angle_y + 90;   // temp
2812         } else if(gameover) {
2813                 if (intermission_running)
2814                         IntermissionThink ();   // otherwise a button could be missed between
2815                 return;
2816         } else if(self.classname == "observer") {
2817                 ObserverThink();
2818         } else if(self.classname == "spectator") {
2819                 SpectatorThink();
2820         }
2821
2822         if(!zoomstate_set)
2823                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2824
2825         float oldspectatee_status;
2826         oldspectatee_status = self.spectatee_status;
2827         if(self.classname == "spectator")
2828                 self.spectatee_status = num_for_edict(self.enemy);
2829         else if(self.classname == "observer")
2830                 self.spectatee_status = num_for_edict(self);
2831         else
2832                 self.spectatee_status = 0;
2833         if(self.spectatee_status != oldspectatee_status)
2834         {
2835                 ClientData_Touch(self);
2836                 if(g_race || g_cts)
2837                         race_InitSpectator();
2838         }
2839
2840         if(self.teamkill_soundtime)
2841         if(time > self.teamkill_soundtime)
2842         {
2843                 self.teamkill_soundtime = 0;
2844
2845                 entity oldpusher, oldself;
2846
2847                 oldself = self; self = self.teamkill_soundsource;
2848                 oldpusher = self.pusher; self.pusher = oldself;
2849
2850                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2851
2852                 self.pusher = oldpusher;
2853                 self = oldself;
2854         }
2855
2856         if(self.taunt_soundtime)
2857         if(time > self.taunt_soundtime)
2858         {
2859                 self.taunt_soundtime = 0;
2860                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2861         }
2862
2863         target_voicescript_next(self);
2864
2865         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2866         if(!self.weapon)
2867                 self.clip_load = self.clip_size = 0;
2868 }
2869
2870 float isInvisibleString(string s)
2871 {
2872         float i, n, c;
2873         s = strdecolorize(s);
2874         for((i = 0), (n = strlen(s)); i < n; ++i)
2875         {
2876                 c = str2chr(s, i);
2877                 switch(c)
2878                 {
2879                         case 0:
2880                         case 32: // space
2881                                 break;
2882                         case 192: // charmap space
2883                                 if (!autocvar_utf8_enable)
2884                                         break;
2885                                 return FALSE;
2886                         case 160: // space in unicode fonts
2887                         case 0xE000 + 192: // utf8 charmap space
2888                                 if (autocvar_utf8_enable)
2889                                         break;
2890                         default:
2891                                 return FALSE;
2892                 }
2893         }
2894         return TRUE;
2895 }
2896
2897 /*
2898 =============
2899 PlayerPostThink
2900
2901 Called every frame for each client after the physics are run
2902 =============
2903 */
2904 .float idlekick_lasttimeleft;
2905 void PlayerPostThink (void)
2906 {
2907         // Savage: Check for nameless players
2908         if (isInvisibleString(self.netname)) {
2909                 self.netname = "Player";
2910                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2911         }
2912
2913         if(sv_maxidle && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2914         {
2915                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2916                 {
2917                         if(self.idlekick_lasttimeleft) { self.idlekick_lasttimeleft = 0; }
2918                 }
2919                 else
2920                 {
2921                         float timeleft;
2922                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2923                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2924                         {
2925                                 if(!self.idlekick_lasttimeleft)
2926                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2927                         }
2928                         if(timeleft <= 0)
2929                         {
2930                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2931                                 dropclient(self);
2932                                 return;
2933                         }
2934                         else if(timeleft <= 10)
2935                         {
2936                                 if(timeleft != self.idlekick_lasttimeleft)
2937                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2938                                 self.idlekick_lasttimeleft = timeleft;
2939                         }
2940                 }
2941         }
2942
2943 #ifdef TETRIS
2944         if(self.impulse == 100)
2945                 ImpulseCommands();
2946         if (!TetrisPostFrame())
2947         {
2948 #endif
2949
2950         CheatFrame();
2951
2952         //CheckPlayerJump();
2953
2954         if(self.classname == "player") {
2955                 CheckRules_Player();
2956                 UpdateChatBubble();
2957                 if (self.impulse)
2958                         ImpulseCommands();
2959                 if (intermission_running)
2960                         return;         // intermission or finale
2961                 GetPressedKeys();
2962         }
2963
2964 #ifdef TETRIS
2965         }
2966 #endif
2967
2968         /*
2969         float i;
2970         for(i = 0; i < 1000; ++i)
2971         {
2972                 vector end;
2973                 end = self.origin + '0 0 1024' + 512 * randomvec();
2974                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2975                 if(trace_fraction < 1)
2976                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2977                 {
2978                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2979                         break;
2980                 }
2981         }
2982         */
2983
2984         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2985
2986         if(self.waypointsprite_attachedforcarrier)
2987                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2988
2989         playerdemo_write();
2990
2991         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2992         {
2993                 if not(self.stored_netname)
2994                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2995                 if(self.stored_netname != self.netname)
2996                 {
2997                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2998                         strunzone(self.stored_netname);
2999                         self.stored_netname = strzone(self.netname);
3000                 }
3001         }
3002
3003         /*
3004         if(g_race)
3005                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
3006         */
3007
3008         CSQCMODEL_AUTOUPDATE();
3009 }